CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0022)
   6   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
   7 endif()
   8
   9 if (POLICY CMP0051)
  10   # CMake 3.1 and higher include generator expressions of the form
  11   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  12   # stripped everywhere that access the SOURCES property, so we just
  13   # defer to the OLD behavior of not including generator expressions
  14   # in the output for now.
  15   cmake_policy(SET CMP0051 OLD)
  16 endif()
  17
  18 if(POLICY CMP0056)
  19   cmake_policy(SET CMP0056 NEW)
  20 endif()
  21
  22 if(POLICY CMP0057)
  23   cmake_policy(SET CMP0057 NEW)
  24 endif()
  25
  26 if(NOT DEFINED LLVM_VERSION_MAJOR)
  27   set(LLVM_VERSION_MAJOR 6)
  28 endif()
  29 if(NOT DEFINED LLVM_VERSION_MINOR)
  30   set(LLVM_VERSION_MINOR 0)
  31 endif()
  32 if(NOT DEFINED LLVM_VERSION_PATCH)
  33   set(LLVM_VERSION_PATCH 0)
  34 endif()
  35 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  36   set(LLVM_VERSION_SUFFIX svn)
  37 endif()
  38
  39 if (POLICY CMP0048)
  40   cmake_policy(SET CMP0048 NEW)
  41   set(cmake_3_0_PROJ_VERSION
  42     VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH})
  43   set(cmake_3_0_LANGUAGES LANGUAGES)
  44 endif()
  45
  46 if (NOT PACKAGE_VERSION)
  47   set(PACKAGE_VERSION
  48     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  49 endif()
  50
  51 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  52   message(WARNING "Visual Studio generators use the x86 host compiler by "
  53                   "default, even for 64-bit targets. This can result in linker "
  54                   "instability and out of memory errors. To use the 64-bit "
  55                   "host compiler, pass -Thost=x64 on the CMake command line.")
  56 endif()
  57
  58 project(LLVM
  59   ${cmake_3_0_PROJ_VERSION}
  60   ${cmake_3_0_LANGUAGES}
  61   C CXX ASM)
  62
  63 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  64   message(STATUS "No build type selected, default to Debug")
  65   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  66 endif()
  67
  68 # This should only apply if you are both on an Apple host, and targeting Apple.
  69 if(CMAKE_HOST_APPLE AND APPLE)
  70   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  71   if(NOT CMAKE_LIBTOOL)
  72     if(NOT CMAKE_XCRUN)
  73       find_program(CMAKE_XCRUN NAMES xcrun)
  74     endif()
  75     if(CMAKE_XCRUN)
  76       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  77         OUTPUT_VARIABLE CMAKE_LIBTOOL
  78         OUTPUT_STRIP_TRAILING_WHITESPACE)
  79     endif()
  80
  81     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  82       find_program(CMAKE_LIBTOOL NAMES libtool)
  83     endif()
  84   endif()
  85
  86   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  87   if(CMAKE_LIBTOOL)
  88     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  89     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  90
  91     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  92       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  93       OUTPUT_STRIP_TRAILING_WHITESPACE)
  94     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  95       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  96         ${LIBTOOL_V_OUTPUT})
  97       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  98         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  99       endif()
 100     endif()
 101
 102     foreach(lang ${languages})
 103       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 104         "${CMAKE_LIBTOOL} -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
 105         <LINK_FLAGS> <OBJECTS> ")
 106     endforeach()
 107   endif()
 108
 109   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
 110   if(DYLD_LIBRARY_PATH)
 111     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
 112     foreach(lang ${languages})
 113       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 114         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
 115              "${dyld_envar} ${cmd}")
 116       endforeach()
 117       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 118         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 119     endforeach()
 120   endif()
 121 endif()
 122
 123 # Side-by-side subprojects layout: automatically set the
 124 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 125 # This allows an easy way of setting up a build directory for llvm and another
 126 # one for llvm+clang+... using the same sources.
 127 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly")
 128 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 129         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 130 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 131   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 132 endif()
 133 foreach(proj ${LLVM_ENABLE_PROJECTS})
 134   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 135   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 136     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 137   endif()
 138   string(TOUPPER "${proj}" upper_proj)
 139   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 140   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 141   # There is a widely spread opinion that clang-tools-extra should be merged
 142   # into clang. The following simulates it by always enabling clang-tools-extra
 143   # when enabling clang.
 144   if (proj STREQUAL "clang")
 145     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 146   endif()
 147 endforeach()
 148
 149 # Build llvm with ccache if the package is present
 150 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 151 if(LLVM_CCACHE_BUILD)
 152   find_program(CCACHE_PROGRAM ccache)
 153   if(CCACHE_PROGRAM)
 154       set(LLVM_CCACHE_SIZE "" CACHE STRING "Size of ccache")
 155       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 156       set(CCACHE_PROGRAM "CCACHE_CPP2=yes CCACHE_HASHDIR=yes ${CCACHE_PROGRAM}")
 157       if (LLVM_CCACHE_SIZE)
 158         set(CCACHE_PROGRAM "CCACHE_SIZE=${LLVM_CCACHE_SIZE} ${CCACHE_PROGRAM}")
 159       endif()
 160       if (LLVM_CCACHE_DIR)
 161         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 162       endif()
 163       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 164   else()
 165     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 166   endif()
 167 endif()
 168
 169 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 170
 171 # Some features of the LLVM build may be disallowed when dependency debugging is
 172 # enabled. In particular you cannot use ccache because we want to force compile
 173 # operations to always happen.
 174 if(LLVM_DEPENDENCY_DEBUGGING)
 175   if(NOT CMAKE_HOST_APPLE)
 176     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 177   endif()
 178   if(LLVM_CCACHE_BUILD)
 179     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 180   endif()
 181 endif()
 182
 183 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 184
 185 # Add path for custom modules
 186 set(CMAKE_MODULE_PATH
 187   ${CMAKE_MODULE_PATH}
 188   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 189   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 190   )
 191
 192 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 193 # for use by clang_complete, YouCompleteMe, etc.
 194 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 195
 196 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 197
 198 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 199
 200 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 201 if ( LLVM_USE_FOLDERS )
 202   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 203 endif()
 204
 205 include(VersionFromVCS)
 206
 207 option(LLVM_APPEND_VC_REV
 208   "Embed the version control system revision id in LLVM" ON)
 209
 210 set(PACKAGE_NAME LLVM)
 211 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 212 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
 213
 214 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 215   "Default URL where bug reports are to be submitted.")
 216
 217 # Configure CPack.
 218 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 219 set(CPACK_PACKAGE_VENDOR "LLVM")
 220 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 221 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 222 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 223 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 224 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 225 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 226 if(WIN32 AND NOT UNIX)
 227   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 228   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 229   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 230   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 231   set(CPACK_NSIS_MODIFY_PATH "ON")
 232   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 233   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 234     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 235   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 236     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 237   if( CMAKE_CL_64 )
 238     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 239   endif()
 240 endif()
 241 include(CPack)
 242
 243 # Sanity check our source directory to make sure that we are not trying to
 244 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 245 # sure that we don't have any stray generated files lying around in the tree
 246 # (which would end up getting picked up by header search, instead of the correct
 247 # versions).
 248 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 249   message(FATAL_ERROR "In-source builds are not allowed.
 250 CMake would overwrite the makefiles distributed with LLVM.
 251 Please create a directory and run cmake from there, passing the path
 252 to this source directory as the last argument.
 253 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 254 Please delete them.")
 255 endif()
 256 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 257   file(GLOB_RECURSE
 258     tablegenned_files_on_include_dir
 259     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 260   file(GLOB_RECURSE
 261     tablegenned_files_on_lib_dir
 262     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 263   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 264     message(FATAL_ERROR "Apparently there is a previous in-source build,
 265 probably as the result of running `configure' and `make' on
 266 ${CMAKE_CURRENT_SOURCE_DIR}.
 267 This may cause problems. The suspicious files are:
 268 ${tablegenned_files_on_lib_dir}
 269 ${tablegenned_files_on_include_dir}
 270 Please clean the source directory.")
 271   endif()
 272 endif()
 273
 274 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 275
 276 if (CMAKE_BUILD_TYPE AND
 277     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 278   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 279 endif()
 280
 281 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 282
 283 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 284 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 285
 286 set(LLVM_UTILS_INSTALL_DIR "bin" CACHE STRING
 287     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 288 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 289
 290 # They are used as destination of target generators.
 291 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 292 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 293 if(WIN32 OR CYGWIN)
 294   # DLL platform -- put DLLs into bin.
 295   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 296 else()
 297   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 298 endif()
 299
 300 # Each of them corresponds to llvm-config's.
 301 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 302 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 303 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 304 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 305 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 306
 307 # Note: LLVM_CMAKE_PATH does not include generated files
 308 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 309 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 310 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 311
 312 # List of all targets to be built by default:
 313 set(LLVM_ALL_TARGETS
 314   AArch64
 315   AMDGPU
 316   ARM
 317   BPF
 318   Hexagon
 319   Lanai
 320   Mips
 321   MSP430
 322   NVPTX
 323   PowerPC
 324   Sparc
 325   SystemZ
 326   X86
 327   XCore
 328   )
 329
 330 # List of targets with JIT support:
 331 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 332
 333 set(LLVM_TARGETS_TO_BUILD "all"
 334     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 335
 336 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 337   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 338
 339 option(BUILD_SHARED_LIBS
 340   "Build all libraries as shared libraries instead of static" OFF)
 341
 342 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 343 if(LLVM_ENABLE_BACKTRACES)
 344   set(ENABLE_BACKTRACES 1)
 345 endif()
 346
 347 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 348 if(LLVM_ENABLE_CRASH_OVERRIDES)
 349   set(ENABLE_CRASH_OVERRIDES 1)
 350 endif()
 351
 352 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 353 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 354 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 355
 356 set(LLVM_TARGET_ARCH "host"
 357   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 358
 359 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 360
 361 option(LLVM_ENABLE_LIBXML2 "Use libxml2 if available." ON)
 362
 363 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 364
 365 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 366
 367 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 368
 369 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 370   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 371 endif()
 372
 373 set(LLVM_TARGETS_TO_BUILD
 374    ${LLVM_TARGETS_TO_BUILD}
 375    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 376 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 377
 378 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 379 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 380 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 381 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 382   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 383   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 384 else()
 385   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 386   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 387 endif()
 388 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 389 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 390 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 391 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 392 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 393 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 394
 395 option(LLVM_ENABLE_DUMP "Enable dump functions in release builds" OFF)
 396
 397 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 398   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 399 else()
 400   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 401 endif()
 402
 403 if( LLVM_ENABLE_ASSERTIONS )
 404   set(LLVM_ENABLE_DUMP ON)
 405 endif()
 406
 407 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 408
 409 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 410   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 411
 412 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 413        "Set to ON to force using an old, unsupported host toolchain." OFF)
 414
 415 option(LLVM_USE_INTEL_JITEVENTS
 416   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 417   OFF)
 418
 419 if( LLVM_USE_INTEL_JITEVENTS )
 420   # Verify we are on a supported platform
 421   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 422     message(FATAL_ERROR
 423       "Intel JIT API support is available on Linux and Windows only.")
 424   endif()
 425 endif( LLVM_USE_INTEL_JITEVENTS )
 426
 427 option(LLVM_USE_OPROFILE
 428   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 429
 430 option(LLVM_EXTERNALIZE_DEBUGINFO
 431   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 432
 433 # If enabled, verify we are on a platform that supports oprofile.
 434 if( LLVM_USE_OPROFILE )
 435   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 436     message(FATAL_ERROR "OProfile support is available on Linux only.")
 437   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 438 endif( LLVM_USE_OPROFILE )
 439
 440 set(LLVM_USE_SANITIZER "" CACHE STRING
 441   "Define the sanitizer used to build binaries and tests.")
 442 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 443   "Path to fuzzing library for linking with fuzz targets")
 444
 445 option(LLVM_USE_SPLIT_DWARF
 446   "Use -gsplit-dwarf when compiling llvm." OFF)
 447
 448 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 449 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 450
 451 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 452   set(POLLY_IN_TREE TRUE)
 453 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 454   set(POLLY_IN_TREE TRUE)
 455 else()
 456   set(POLLY_IN_TREE FALSE)
 457 endif()
 458
 459 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 460   set(WITH_POLLY ON)
 461 else()
 462   set(WITH_POLLY OFF)
 463 endif()
 464
 465 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 466   set(LINK_POLLY_INTO_TOOLS ON)
 467 else()
 468   set(LINK_POLLY_INTO_TOOLS OFF)
 469 endif()
 470
 471 # Define an option controlling whether we should build for 32-bit on 64-bit
 472 # platforms, where supported.
 473 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 474   # TODO: support other platforms and toolchains.
 475   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 476 endif()
 477
 478 # Define the default arguments to use with 'lit', and an option for the user to
 479 # override.
 480 set(LIT_ARGS_DEFAULT "-sv")
 481 if (MSVC_IDE OR XCODE)
 482   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 483 endif()
 484 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 485
 486 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 487 if( WIN32 AND NOT CYGWIN )
 488   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 489 endif()
 490
 491 # Define options to control the inclusion and default build behavior for
 492 # components which may not strictly be necessary (tools, examples, and tests).
 493 #
 494 # This is primarily to support building smaller or faster project files.
 495 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 496 option(LLVM_BUILD_TOOLS
 497   "Build the LLVM tools. If OFF, just generate build targets." ON)
 498
 499 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 500 option(LLVM_BUILD_UTILS
 501   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 502
 503 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 504 option(LLVM_BUILD_RUNTIMES
 505   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 506
 507 option(LLVM_BUILD_RUNTIME
 508   "Build the LLVM runtime libraries." ON)
 509 option(LLVM_BUILD_EXAMPLES
 510   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 511 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 512
 513 option(LLVM_BUILD_TESTS
 514   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 515 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 516 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 517
 518 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 519 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 520 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 521 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 522 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 523
 524 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 525     CACHE STRING "Doxygen-generated HTML documentation install directory")
 526 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 527     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 528
 529 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 530   "Build compiler-rt as an external project." OFF)
 531
 532 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 533   "Show target and host info when tools are invoked with --version." ON)
 534
 535 # You can configure which libraries from LLVM you want to include in the
 536 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 537 # list of LLVM components. All component names handled by llvm-config are valid.
 538 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 539   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 540     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 541 endif()
 542 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 543 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 544 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 545 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 546   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 547 endif()
 548 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 549
 550 option(LLVM_DYLIB_SYMBOL_VERSIONING OFF)
 551
 552 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 553 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 554   set(LLVM_USE_HOST_TOOLS ON)
 555 endif()
 556
 557 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 558   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 559 else()
 560   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 561 endif()
 562
 563 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 564     LLVM_ENABLE_IR_PGO)
 565   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 566     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 567     # for spining disks. Anything higher may only help on slower mediums.
 568     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 569   endif()
 570   if(NOT LLVM_PROFILE_FILE_PATTERN)
 571     if(NOT LLVM_PROFILE_DATA_DIR)
 572       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 573     endif()
 574                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 575   endif()
 576 endif()
 577
 578 if (LLVM_BUILD_STATIC)
 579   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 580 endif()
 581
 582 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 583 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 584 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 585
 586 # All options referred to from HandleLLVMOptions have to be specified
 587 # BEFORE this include, otherwise options will not be correctly set on
 588 # first cmake run
 589 include(config-ix)
 590
 591 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 592   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 593 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 594
 595 # By default, we target the host, but this can be overridden at CMake
 596 # invocation time.
 597 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 598   "Default target for which LLVM will generate code." )
 599 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 600 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 601 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 602
 603 include(HandleLLVMOptions)
 604
 605 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 606 # FIXME: We should support systems with only Python 3, but that requires work
 607 # on LLDB.
 608 set(Python_ADDITIONAL_VERSIONS 2.7)
 609 include(FindPythonInterp)
 610 if( NOT PYTHONINTERP_FOUND )
 611   message(FATAL_ERROR
 612 "Unable to find Python interpreter, required for builds and testing.
 613
 614 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 615 endif()
 616
 617 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 618   message(FATAL_ERROR "Python 2.7 or newer is required")
 619 endif()
 620
 621 ######
 622 # LLVMBuild Integration
 623 #
 624 # We use llvm-build to generate all the data required by the CMake based
 625 # build system in one swoop:
 626 #
 627 #  - We generate a file (a CMake fragment) in the object root which contains
 628 #    all the definitions that are required by CMake.
 629 #
 630 #  - We generate the library table used by llvm-config.
 631 #
 632 #  - We generate the dependencies for the CMake fragment, so that we will
 633 #    automatically reconfigure outselves.
 634
 635 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 636 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 637   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 638 set(LLVMBUILDCMAKEFRAG
 639   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 640
 641 # Create the list of optional components that are enabled
 642 if (LLVM_USE_INTEL_JITEVENTS)
 643   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 644 endif (LLVM_USE_INTEL_JITEVENTS)
 645 if (LLVM_USE_OPROFILE)
 646   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 647 endif (LLVM_USE_OPROFILE)
 648
 649 message(STATUS "Constructing LLVMBuild project information")
 650 execute_process(
 651   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 652             --native-target "${LLVM_NATIVE_ARCH}"
 653             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 654             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 655             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 656             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 657             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 658             ERROR_VARIABLE LLVMBUILDERRORS
 659             OUTPUT_STRIP_TRAILING_WHITESPACE
 660             ERROR_STRIP_TRAILING_WHITESPACE
 661   RESULT_VARIABLE LLVMBUILDRESULT)
 662
 663 # On Win32, CMake doesn't properly handle piping the default output/error
 664 # streams into the GUI console. So, we explicitly catch and report them.
 665 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 666   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 667 endif()
 668 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 669   message(FATAL_ERROR
 670     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 671 endif()
 672
 673 # Include the generated CMake fragment. This will define properties from the
 674 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 675 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 676 # files change.
 677 include(${LLVMBUILDCMAKEFRAG})
 678
 679 ######
 680
 681 # Configure all of the various header file fragments LLVM uses which depend on
 682 # configuration variables.
 683 set(LLVM_ENUM_TARGETS "")
 684 set(LLVM_ENUM_ASM_PRINTERS "")
 685 set(LLVM_ENUM_ASM_PARSERS "")
 686 set(LLVM_ENUM_DISASSEMBLERS "")
 687 foreach(t ${LLVM_TARGETS_TO_BUILD})
 688   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 689
 690   list(FIND LLVM_ALL_TARGETS ${t} idx)
 691   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 692   if( idx LESS 0 AND idy LESS 0 )
 693     message(FATAL_ERROR "The target `${t}' does not exist.
 694     It should be one of\n${LLVM_ALL_TARGETS}")
 695   else()
 696     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 697   endif()
 698
 699   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 700   if( asmp_file )
 701     set(LLVM_ENUM_ASM_PRINTERS
 702       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 703   endif()
 704   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 705     set(LLVM_ENUM_ASM_PARSERS
 706       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 707   endif()
 708   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 709     set(LLVM_ENUM_DISASSEMBLERS
 710       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 711   endif()
 712 endforeach(t)
 713
 714 # Produce the target definition files, which provide a way for clients to easily
 715 # include various classes of targets.
 716 configure_file(
 717   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 718   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 719   )
 720 configure_file(
 721   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 722   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 723   )
 724 configure_file(
 725   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 726   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 727   )
 728 configure_file(
 729   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 730   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 731   )
 732
 733 # Configure the three LLVM configuration header files.
 734 configure_file(
 735   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 736   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 737 configure_file(
 738   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 739   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 740 configure_file(
 741   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 742   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 743 configure_file(
 744   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 745   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 746
 747 # Add target for generating source rpm package.
 748 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 749     CACHE FILEPATH ".spec file to use for srpm generation")
 750 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 751 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 752
 753 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 754 # DUMMY_VAR contains a version string which we don't care about.
 755 add_version_info_from_vcs(DUMMY_VAR)
 756 if ( SVN_REVISION )
 757   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 758 elseif ( GIT_COMMIT )
 759   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 760 endif()
 761
 762 configure_file(
 763   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 764   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 765
 766 add_custom_target(srpm
 767   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 768   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 769
 770
 771 # They are not referenced. See set_output_directory().
 772 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 773 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 774 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 775
 776 if(APPLE AND DARWIN_LTO_LIBRARY)
 777   set(CMAKE_EXE_LINKER_FLAGS
 778     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 779   set(CMAKE_SHARED_LINKER_FLAGS
 780     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 781   set(CMAKE_MODULE_LINKER_FLAGS
 782     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 783 endif()
 784
 785 # Work around a broken bfd ld behavior. When linking a binary with a
 786 # foo.so library, it will try to find any library that foo.so uses and
 787 # check its symbols. This is wasteful (the check was done when foo.so
 788 # was created) and can fail since it is not the dynamic linker and
 789 # doesn't know how to handle search paths correctly.
 790 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 791   set(CMAKE_EXE_LINKER_FLAGS
 792       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 793 endif()
 794
 795 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 796
 797 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 798
 799 # when crosscompiling import the executable targets from a file
 800 if(LLVM_USE_HOST_TOOLS)
 801   include(CrossCompile)
 802 endif(LLVM_USE_HOST_TOOLS)
 803 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 804 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 805 # (this is a variable that CrossCompile sets on recursive invocations)
 806 endif()
 807
 808 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 809   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 810   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 811   include_directories(SYSTEM "/usr/local/include")
 812   link_directories("/usr/local/lib")
 813 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 814
 815 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 816    # special hack for Solaris to handle crazy system sys/regset.h
 817    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 818 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 819
 820 # Make sure we don't get -rdynamic in every binary. For those that need it,
 821 # use export_executable_symbols(target).
 822 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 823
 824 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 825   "Profiling data file to use when compiling in order to improve runtime performance.")
 826
 827 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 828   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 829     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 830   else()
 831     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 832   endif()
 833 endif()
 834
 835 include(AddLLVM)
 836 include(TableGen)
 837
 838 if( MINGW )
 839   # People report that -O3 is unreliable on MinGW. The traditional
 840   # build also uses -O2 for that reason:
 841   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 842 endif()
 843
 844 # Put this before tblgen. Else we have a circular dependence.
 845 add_subdirectory(lib/Demangle)
 846 add_subdirectory(lib/Support)
 847 add_subdirectory(lib/TableGen)
 848
 849 add_subdirectory(utils/TableGen)
 850
 851 add_subdirectory(include/llvm)
 852
 853 add_subdirectory(lib)
 854
 855 if( LLVM_INCLUDE_UTILS )
 856   add_subdirectory(utils/FileCheck)
 857   add_subdirectory(utils/PerfectShuffle)
 858   add_subdirectory(utils/count)
 859   add_subdirectory(utils/not)
 860   add_subdirectory(utils/yaml-bench)
 861 else()
 862   if ( LLVM_INCLUDE_TESTS )
 863     message(FATAL_ERROR "Including tests when not building utils will not work.
 864     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 865   endif()
 866 endif()
 867
 868 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 869 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 870   add_subdirectory(utils/LLVMVisualizers)
 871 endif()
 872
 873 foreach( binding ${LLVM_BINDINGS_LIST} )
 874   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 875     add_subdirectory(bindings/${binding})
 876   endif()
 877 endforeach()
 878
 879 add_subdirectory(projects)
 880
 881 if( LLVM_INCLUDE_TOOLS )
 882   add_subdirectory(tools)
 883 endif()
 884
 885 if( LLVM_INCLUDE_RUNTIMES )
 886   add_subdirectory(runtimes)
 887 endif()
 888
 889 if( LLVM_INCLUDE_EXAMPLES )
 890   add_subdirectory(examples)
 891 endif()
 892
 893 if( LLVM_INCLUDE_TESTS )
 894   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 895     include(LLVMExternalProjectUtils)
 896     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 897       USE_TOOLCHAIN
 898       EXCLUDE_FROM_ALL
 899       NO_INSTALL
 900       ALWAYS_CLEAN)
 901   endif()
 902   add_subdirectory(utils/lit)
 903   add_subdirectory(test)
 904   add_subdirectory(unittests)
 905   if( LLVM_INCLUDE_UTILS )
 906     add_subdirectory(utils/unittest)
 907   endif()
 908
 909   if (WIN32)
 910     # This utility is used to prevent crashing tests from calling Dr. Watson on
 911     # Windows.
 912     add_subdirectory(utils/KillTheDoctor)
 913   endif()
 914
 915   # Add a global check rule now that all subdirectories have been traversed
 916   # and we know the total set of lit testsuites.
 917   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 918   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 919   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 920   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 921   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 922                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 923   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 924                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 925   add_lit_target(check-all
 926     "Running all regression tests"
 927     ${LLVM_LIT_TESTSUITES}
 928     PARAMS ${LLVM_LIT_PARAMS}
 929     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 930     ARGS ${LLVM_LIT_EXTRA_ARGS}
 931     )
 932   if(TARGET check-runtimes)
 933     add_dependencies(check-all check-runtimes)
 934   endif()
 935   add_custom_target(test-depends
 936                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 937   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 938 endif()
 939
 940 if (LLVM_INCLUDE_DOCS)
 941   add_subdirectory(docs)
 942 endif()
 943
 944 add_subdirectory(cmake/modules)
 945
 946 # Do this last so that all lit targets have already been created.
 947 if (LLVM_INCLUDE_UTILS)
 948   add_subdirectory(utils/llvm-lit)
 949 endif()
 950
 951 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 952   install(DIRECTORY include/llvm include/llvm-c
 953     DESTINATION include
 954     COMPONENT llvm-headers
 955     FILES_MATCHING
 956     PATTERN "*.def"
 957     PATTERN "*.h"
 958     PATTERN "*.td"
 959     PATTERN "*.inc"
 960     PATTERN "LICENSE.TXT"
 961     PATTERN ".svn" EXCLUDE
 962     )
 963
 964   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 965     DESTINATION include
 966     COMPONENT llvm-headers
 967     FILES_MATCHING
 968     PATTERN "*.def"
 969     PATTERN "*.h"
 970     PATTERN "*.gen"
 971     PATTERN "*.inc"
 972     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 973     PATTERN "CMakeFiles" EXCLUDE
 974     PATTERN "config.h" EXCLUDE
 975     PATTERN ".svn" EXCLUDE
 976     )
 977
 978   # Installing the headers needs to depend on generating any public
 979   # tablegen'd headers.
 980   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 981
 982   if (NOT CMAKE_CONFIGURATION_TYPES)
 983     add_custom_target(install-llvm-headers
 984                       DEPENDS llvm-headers
 985                       COMMAND "${CMAKE_COMMAND}"
 986                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 987                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 988   endif()
 989 endif()
 990
 991 # This must be at the end of the LLVM root CMakeLists file because it must run
 992 # after all targets are created.
 993 if(LLVM_DISTRIBUTION_COMPONENTS)
 994   if(CMAKE_CONFIGURATION_TYPES)
 995     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 996   endif()
 997
 998   add_custom_target(distribution)
 999   add_custom_target(install-distribution)
1000   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS})
1001     if(TARGET ${target})
1002       add_dependencies(distribution ${target})
1003     else()
1004       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1005     endif()
1006
1007     if(TARGET install-${target})
1008       add_dependencies(install-distribution install-${target})
1009     else()
1010       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1011     endif()
1012   endforeach()
1013 endif()
1014
1015 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1016 if (MSVC)
1017   include(InstallRequiredSystemLibraries)
1018 endif()
1019