CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(NOT DEFINED LLVM_VERSION_MAJOR)
  15   set(LLVM_VERSION_MAJOR 9)
  16 endif()
  17 if(NOT DEFINED LLVM_VERSION_MINOR)
  18   set(LLVM_VERSION_MINOR 0)
  19 endif()
  20 if(NOT DEFINED LLVM_VERSION_PATCH)
  21   set(LLVM_VERSION_PATCH 0)
  22 endif()
  23 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  24   set(LLVM_VERSION_SUFFIX svn)
  25 endif()
  26
  27 if (NOT PACKAGE_VERSION)
  28   set(PACKAGE_VERSION
  29     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  30 endif()
  31
  32 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  33   message(WARNING "Visual Studio generators use the x86 host compiler by "
  34                   "default, even for 64-bit targets. This can result in linker "
  35                   "instability and out of memory errors. To use the 64-bit "
  36                   "host compiler, pass -Thost=x64 on the CMake command line.")
  37 endif()
  38
  39 project(LLVM
  40   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  41   LANGUAGES C CXX ASM)
  42
  43 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  44   message(STATUS "No build type selected, default to Debug")
  45   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  46 endif()
  47
  48 # This should only apply if you are both on an Apple host, and targeting Apple.
  49 if(CMAKE_HOST_APPLE AND APPLE)
  50   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  51   if(NOT CMAKE_LIBTOOL)
  52     if(NOT CMAKE_XCRUN)
  53       find_program(CMAKE_XCRUN NAMES xcrun)
  54     endif()
  55     if(CMAKE_XCRUN)
  56       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  57         OUTPUT_VARIABLE CMAKE_LIBTOOL
  58         OUTPUT_STRIP_TRAILING_WHITESPACE)
  59     endif()
  60
  61     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  62       find_program(CMAKE_LIBTOOL NAMES libtool)
  63     endif()
  64   endif()
  65
  66   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  67   if(CMAKE_LIBTOOL)
  68     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  69     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  70
  71     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  72       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  73       OUTPUT_STRIP_TRAILING_WHITESPACE)
  74     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  75       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  76         ${LIBTOOL_V_OUTPUT})
  77       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  78         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  79       endif()
  80     endif()
  81
  82     foreach(lang ${languages})
  83       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  84         "\"${CMAKE_LIBTOOL}\" -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  85         <LINK_FLAGS> <OBJECTS> ")
  86     endforeach()
  87   endif()
  88
  89   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  90   if(DYLD_LIBRARY_PATH)
  91     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  92     foreach(lang ${languages})
  93       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
  94         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
  95              "${dyld_envar} ${cmd}")
  96       endforeach()
  97       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  98         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
  99     endforeach()
 100   endif()
 101 endif()
 102
 103 # Side-by-side subprojects layout: automatically set the
 104 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 105 # This allows an easy way of setting up a build directory for llvm and another
 106 # one for llvm+clang+... using the same sources.
 107 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;llvm;openmp;parallel-libs;polly;pstl")
 108 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 109         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 110 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 111   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 112 endif()
 113
 114 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
 115 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
 116 # several reasons:
 117 #
 118 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
 119 # source of truth for which projects to build. This means we will ignore user
 120 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
 121 # them.
 122 #
 123 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
 124 # non-empty list but now the user wishes to disable building all other projects
 125 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
 126 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
 127 # building all the projects that were previously enabled.
 128 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
 129 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
 130
 131 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
 132   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
 133   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
 134     string(TOUPPER "${proj}" upper_proj)
 135     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 136     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
 137       message(STATUS "${proj} project is enabled")
 138       set(SHOULD_ENABLE_PROJECT TRUE)
 139       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 140       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 141         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 142       endif()
 143       set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 144     else()
 145       message(STATUS "${proj} project is disabled")
 146       set(SHOULD_ENABLE_PROJECT FALSE)
 147     endif()
 148     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 149     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 150     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 151     # we should deprecate allowing users to set these variables by turning them
 152     # into normal CMake variables rather than cache variables.
 153     set(LLVM_TOOL_${upper_proj}_BUILD
 154       ${SHOULD_ENABLE_PROJECT}
 155       CACHE
 156       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 157     )
 158   endforeach()
 159 endif()
 160 unset(SHOULD_ENABLE_PROJECT)
 161
 162 # Build llvm with ccache if the package is present
 163 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 164 if(LLVM_CCACHE_BUILD)
 165   find_program(CCACHE_PROGRAM ccache)
 166   if(CCACHE_PROGRAM)
 167       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 168       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 169       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 170           CACHE STRING "Parameters to pass through to ccache")
 171
 172       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 173       if (LLVM_CCACHE_MAXSIZE)
 174         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 175       endif()
 176       if (LLVM_CCACHE_DIR)
 177         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 178       endif()
 179       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 180   else()
 181     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 182   endif()
 183 endif()
 184
 185 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 186
 187 # Some features of the LLVM build may be disallowed when dependency debugging is
 188 # enabled. In particular you cannot use ccache because we want to force compile
 189 # operations to always happen.
 190 if(LLVM_DEPENDENCY_DEBUGGING)
 191   if(NOT CMAKE_HOST_APPLE)
 192     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 193   endif()
 194   if(LLVM_CCACHE_BUILD)
 195     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 196   endif()
 197 endif()
 198
 199 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 200 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 201 if(LLVM_ENABLE_GISEL_COV)
 202   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 203 endif()
 204
 205 # Add path for custom modules
 206 set(CMAKE_MODULE_PATH
 207   ${CMAKE_MODULE_PATH}
 208   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 209   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 210   )
 211
 212 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 213 # for use by clang_complete, YouCompleteMe, etc.
 214 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 215
 216 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 217   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 218
 219 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 220
 221 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 222
 223 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 224 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 225 # the installation by default. See llvm.org/PR31905.
 226 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 227
 228 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 229 if ( LLVM_USE_FOLDERS )
 230   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 231 endif()
 232
 233 include(VersionFromVCS)
 234
 235 option(LLVM_APPEND_VC_REV
 236   "Embed the version control system revision in LLVM" ON)
 237
 238 set(PACKAGE_NAME LLVM)
 239 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 240 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 241
 242 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 243   "Default URL where bug reports are to be submitted.")
 244
 245 # Configure CPack.
 246 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 247 set(CPACK_PACKAGE_VENDOR "LLVM")
 248 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 249 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 250 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 251 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 252 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 253 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 254 if(WIN32 AND NOT UNIX)
 255   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 256   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 257   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 258   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 259   set(CPACK_NSIS_MODIFY_PATH "ON")
 260   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 261   if( CMAKE_CL_64 )
 262     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 263   endif()
 264 endif()
 265 include(CPack)
 266
 267 # Sanity check our source directory to make sure that we are not trying to
 268 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 269 # sure that we don't have any stray generated files lying around in the tree
 270 # (which would end up getting picked up by header search, instead of the correct
 271 # versions).
 272 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 273   message(FATAL_ERROR "In-source builds are not allowed.
 274 Please create a directory and run cmake from there, passing the path
 275 to this source directory as the last argument.
 276 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 277 Please delete them.")
 278 endif()
 279
 280 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 281
 282 if (CMAKE_BUILD_TYPE AND
 283     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 284   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 285 endif()
 286
 287 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 288
 289 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 290 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 291
 292 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 293     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 294 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 295
 296 # They are used as destination of target generators.
 297 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 298 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 299 if(WIN32 OR CYGWIN)
 300   # DLL platform -- put DLLs into bin.
 301   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 302 else()
 303   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 304 endif()
 305
 306 # Each of them corresponds to llvm-config's.
 307 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 308 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 309 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 310 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 311 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 312
 313 # Note: LLVM_CMAKE_PATH does not include generated files
 314 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 315 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 316 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 317
 318 # List of all targets to be built by default:
 319 set(LLVM_ALL_TARGETS
 320   AArch64
 321   AMDGPU
 322   ARM
 323   BPF
 324   Hexagon
 325   Lanai
 326   Mips
 327   MSP430
 328   NVPTX
 329   PowerPC
 330   Sparc
 331   SystemZ
 332   WebAssembly
 333   X86
 334   XCore
 335   )
 336
 337 # List of targets with JIT support:
 338 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 339
 340 set(LLVM_TARGETS_TO_BUILD "all"
 341     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 342
 343 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 344   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 345
 346 option(BUILD_SHARED_LIBS
 347   "Build all libraries as shared libraries instead of static" OFF)
 348
 349 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 350 if(LLVM_ENABLE_BACKTRACES)
 351   set(ENABLE_BACKTRACES 1)
 352 endif()
 353
 354 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 355 if(LLVM_ENABLE_CRASH_OVERRIDES)
 356   set(ENABLE_CRASH_OVERRIDES 1)
 357 endif()
 358
 359 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 360
 361 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 362 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 363 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 364
 365 set(LLVM_TARGET_ARCH "host"
 366   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 367
 368 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 369
 370 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 371
 372 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 373
 374 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 375
 376 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 377
 378 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 379
 380 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 381   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 382 endif()
 383
 384 set(LLVM_TARGETS_TO_BUILD
 385    ${LLVM_TARGETS_TO_BUILD}
 386    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 387 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 388
 389 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 390 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 391 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 392 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 393   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 394   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 395 else()
 396   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 397   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 398 endif()
 399 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 400 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 401 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 402 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 403 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 404 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 405
 406 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 407
 408 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 409   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 410 else()
 411   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 412 endif()
 413
 414 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 415
 416 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 417   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 418
 419 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 420        "Set to ON to force using an old, unsupported host toolchain." OFF)
 421
 422 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 423        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 424
 425 option(LLVM_USE_INTEL_JITEVENTS
 426   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 427   OFF)
 428
 429 if( LLVM_USE_INTEL_JITEVENTS )
 430   # Verify we are on a supported platform
 431   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 432     message(FATAL_ERROR
 433       "Intel JIT API support is available on Linux and Windows only.")
 434   endif()
 435 endif( LLVM_USE_INTEL_JITEVENTS )
 436
 437 option(LLVM_USE_OPROFILE
 438   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 439
 440 option(LLVM_EXTERNALIZE_DEBUGINFO
 441   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 442
 443 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 444   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 445
 446 # If enabled, verify we are on a platform that supports oprofile.
 447 if( LLVM_USE_OPROFILE )
 448   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 449     message(FATAL_ERROR "OProfile support is available on Linux only.")
 450   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 451 endif( LLVM_USE_OPROFILE )
 452
 453 option(LLVM_USE_PERF
 454   "Use perf JIT interface to inform perf about JIT code" OFF)
 455
 456 # If enabled, verify we are on a platform that supports perf.
 457 if( LLVM_USE_PERF )
 458   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 459     message(FATAL_ERROR "perf support is available on Linux only.")
 460   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 461 endif( LLVM_USE_PERF )
 462
 463 set(LLVM_USE_SANITIZER "" CACHE STRING
 464   "Define the sanitizer used to build binaries and tests.")
 465 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 466 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 467   "Path to fuzzing library for linking with fuzz targets")
 468
 469 option(LLVM_USE_SPLIT_DWARF
 470   "Use -gsplit-dwarf when compiling llvm." OFF)
 471
 472 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 473 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 474
 475 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 476   set(POLLY_IN_TREE TRUE)
 477 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 478   set(POLLY_IN_TREE TRUE)
 479 else()
 480   set(POLLY_IN_TREE FALSE)
 481 endif()
 482
 483 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 484   set(WITH_POLLY ON)
 485 else()
 486   set(WITH_POLLY OFF)
 487 endif()
 488
 489 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 490   set(LINK_POLLY_INTO_TOOLS ON)
 491 else()
 492   set(LINK_POLLY_INTO_TOOLS OFF)
 493 endif()
 494
 495 # Define an option controlling whether we should build for 32-bit on 64-bit
 496 # platforms, where supported.
 497 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 498   # TODO: support other platforms and toolchains.
 499   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 500 endif()
 501
 502 # Define the default arguments to use with 'lit', and an option for the user to
 503 # override.
 504 set(LIT_ARGS_DEFAULT "-sv")
 505 if (MSVC_IDE OR XCODE)
 506   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 507 endif()
 508 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 509
 510 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 511 if( WIN32 AND NOT CYGWIN )
 512   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 513 endif()
 514
 515 # Define options to control the inclusion and default build behavior for
 516 # components which may not strictly be necessary (tools, examples, and tests).
 517 #
 518 # This is primarily to support building smaller or faster project files.
 519 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 520 option(LLVM_BUILD_TOOLS
 521   "Build the LLVM tools. If OFF, just generate build targets." ON)
 522
 523 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 524 option(LLVM_BUILD_UTILS
 525   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 526
 527 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 528 option(LLVM_BUILD_RUNTIMES
 529   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 530
 531 option(LLVM_BUILD_RUNTIME
 532   "Build the LLVM runtime libraries." ON)
 533 option(LLVM_BUILD_EXAMPLES
 534   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 535 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 536
 537 option(LLVM_BUILD_TESTS
 538   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 539 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 540 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 541
 542 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 543 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 544 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 545
 546 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 547 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 548 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 549 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 550 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 551 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 552
 553 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 554     CACHE STRING "Doxygen-generated HTML documentation install directory")
 555 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 556     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 557
 558 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 559   "Build compiler-rt as an external project." OFF)
 560
 561 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 562   "Show target and host info when tools are invoked with --version." ON)
 563
 564 # You can configure which libraries from LLVM you want to include in the
 565 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 566 # list of LLVM components. All component names handled by llvm-config are valid.
 567 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 568   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 569     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 570 endif()
 571 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 572 if(MSVC)
 573   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" OFF)
 574 else()
 575   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 576 endif()
 577 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 578 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 579   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 580 endif()
 581 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 582
 583 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 584 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 585   set(LLVM_USE_HOST_TOOLS ON)
 586 endif()
 587
 588 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 589   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 590 else()
 591   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 592 endif()
 593
 594 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 595     LLVM_ENABLE_IR_PGO)
 596   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 597     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 598     # for spining disks. Anything higher may only help on slower mediums.
 599     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 600   endif()
 601   if(NOT LLVM_PROFILE_FILE_PATTERN)
 602     if(NOT LLVM_PROFILE_DATA_DIR)
 603       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 604     endif()
 605                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 606   endif()
 607 endif()
 608
 609 if (LLVM_BUILD_STATIC)
 610   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 611 endif()
 612
 613 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 614 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 615 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 616
 617 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 618   "Enable per-target runtimes directory")
 619
 620 # All options referred to from HandleLLVMOptions have to be specified
 621 # BEFORE this include, otherwise options will not be correctly set on
 622 # first cmake run
 623 include(config-ix)
 624
 625 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 626   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 627 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 628
 629 # By default, we target the host, but this can be overridden at CMake
 630 # invocation time.
 631 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 632   "Default target for which LLVM will generate code." )
 633 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 634 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 635 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 636
 637 include(HandleLLVMOptions)
 638
 639 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 640 # FIXME: We should support systems with only Python 3, but that requires work
 641 # on LLDB.
 642 set(Python_ADDITIONAL_VERSIONS 2.7)
 643 include(FindPythonInterp)
 644 if( NOT PYTHONINTERP_FOUND )
 645   message(FATAL_ERROR
 646 "Unable to find Python interpreter, required for builds and testing.
 647
 648 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 649 endif()
 650
 651 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 652   message(FATAL_ERROR "Python 2.7 or newer is required")
 653 endif()
 654
 655 ######
 656 # LLVMBuild Integration
 657 #
 658 # We use llvm-build to generate all the data required by the CMake based
 659 # build system in one swoop:
 660 #
 661 #  - We generate a file (a CMake fragment) in the object root which contains
 662 #    all the definitions that are required by CMake.
 663 #
 664 #  - We generate the library table used by llvm-config.
 665 #
 666 #  - We generate the dependencies for the CMake fragment, so that we will
 667 #    automatically reconfigure ourselves.
 668
 669 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 670 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 671   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 672 set(LLVMBUILDCMAKEFRAG
 673   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 674
 675 # Create the list of optional components that are enabled
 676 if (LLVM_USE_INTEL_JITEVENTS)
 677   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 678 endif (LLVM_USE_INTEL_JITEVENTS)
 679 if (LLVM_USE_OPROFILE)
 680   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 681 endif (LLVM_USE_OPROFILE)
 682 if (LLVM_USE_PERF)
 683   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 684 endif (LLVM_USE_PERF)
 685
 686 message(STATUS "Constructing LLVMBuild project information")
 687 execute_process(
 688   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 689             --native-target "${LLVM_NATIVE_ARCH}"
 690             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 691             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 692             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 693             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 694             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 695             ERROR_VARIABLE LLVMBUILDERRORS
 696             OUTPUT_STRIP_TRAILING_WHITESPACE
 697             ERROR_STRIP_TRAILING_WHITESPACE
 698   RESULT_VARIABLE LLVMBUILDRESULT)
 699
 700 # On Win32, CMake doesn't properly handle piping the default output/error
 701 # streams into the GUI console. So, we explicitly catch and report them.
 702 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 703   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 704 endif()
 705 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 706   message(FATAL_ERROR
 707     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 708 endif()
 709
 710 # Include the generated CMake fragment. This will define properties from the
 711 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 712 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 713 # files change.
 714 include(${LLVMBUILDCMAKEFRAG})
 715
 716 ######
 717
 718 # Configure all of the various header file fragments LLVM uses which depend on
 719 # configuration variables.
 720 set(LLVM_ENUM_TARGETS "")
 721 set(LLVM_ENUM_ASM_PRINTERS "")
 722 set(LLVM_ENUM_ASM_PARSERS "")
 723 set(LLVM_ENUM_DISASSEMBLERS "")
 724 foreach(t ${LLVM_TARGETS_TO_BUILD})
 725   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 726
 727   list(FIND LLVM_ALL_TARGETS ${t} idx)
 728   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 729   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 730   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 731   # this test just makes sure that any experimental targets were passed via
 732   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 733   if( idx LESS 0 AND idy LESS 0 )
 734     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 735       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 736   else()
 737     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 738   endif()
 739
 740   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 741   if( asmp_file )
 742     set(LLVM_ENUM_ASM_PRINTERS
 743       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 744   endif()
 745   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 746     set(LLVM_ENUM_ASM_PARSERS
 747       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 748   endif()
 749   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 750     set(LLVM_ENUM_DISASSEMBLERS
 751       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 752   endif()
 753 endforeach(t)
 754
 755 # Produce the target definition files, which provide a way for clients to easily
 756 # include various classes of targets.
 757 configure_file(
 758   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 759   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 760   )
 761 configure_file(
 762   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 763   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 764   )
 765 configure_file(
 766   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 767   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 768   )
 769 configure_file(
 770   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 771   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 772   )
 773
 774 # Configure the three LLVM configuration header files.
 775 configure_file(
 776   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 777   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 778 configure_file(
 779   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 780   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 781 configure_file(
 782   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 783   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 784
 785 # Add target for generating source rpm package.
 786 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 787     CACHE FILEPATH ".spec file to use for srpm generation")
 788 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 789 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 790
 791 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 792 string(LENGTH "${revision}" revision_length)
 793 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 794   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 795 else()
 796   set(LLVM_RPM_SPEC_REVISION "${revision}")
 797 endif()
 798
 799 configure_file(
 800   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 801   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 802
 803 add_custom_target(srpm
 804   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 805   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 806 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 807
 808
 809 # They are not referenced. See set_output_directory().
 810 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 811 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 812 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 813
 814 if(APPLE AND DARWIN_LTO_LIBRARY)
 815   set(CMAKE_EXE_LINKER_FLAGS
 816     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 817   set(CMAKE_SHARED_LINKER_FLAGS
 818     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 819   set(CMAKE_MODULE_LINKER_FLAGS
 820     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 821 endif()
 822
 823 # Work around a broken bfd ld behavior. When linking a binary with a
 824 # foo.so library, it will try to find any library that foo.so uses and
 825 # check its symbols. This is wasteful (the check was done when foo.so
 826 # was created) and can fail since it is not the dynamic linker and
 827 # doesn't know how to handle search paths correctly.
 828 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 829   set(CMAKE_EXE_LINKER_FLAGS
 830       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 831 endif()
 832
 833 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 834
 835 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 836
 837 # when crosscompiling import the executable targets from a file
 838 if(LLVM_USE_HOST_TOOLS)
 839   include(CrossCompile)
 840 endif(LLVM_USE_HOST_TOOLS)
 841 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 842 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 843 # (this is a variable that CrossCompile sets on recursive invocations)
 844 endif()
 845
 846 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 847   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 848   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 849   include_directories(SYSTEM "/usr/local/include")
 850   link_directories("/usr/local/lib")
 851 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 852
 853 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 854    # special hack for Solaris to handle crazy system sys/regset.h
 855    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 856 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 857
 858 # Make sure we don't get -rdynamic in every binary. For those that need it,
 859 # use export_executable_symbols(target).
 860 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 861
 862 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 863   "Profiling data file to use when compiling in order to improve runtime performance.")
 864
 865 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 866   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 867     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 868   else()
 869     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 870   endif()
 871 endif()
 872
 873 include(AddLLVM)
 874 include(TableGen)
 875
 876 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 877   # People report that -O3 is unreliable on MinGW. The traditional
 878   # build also uses -O2 for that reason:
 879   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 880 endif()
 881
 882 # Put this before tblgen. Else we have a circular dependence.
 883 add_subdirectory(lib/Demangle)
 884 add_subdirectory(lib/Support)
 885 add_subdirectory(lib/TableGen)
 886
 887 add_subdirectory(utils/TableGen)
 888
 889 add_subdirectory(include/llvm)
 890
 891 add_subdirectory(lib)
 892
 893 if( LLVM_INCLUDE_UTILS )
 894   add_subdirectory(utils/FileCheck)
 895   add_subdirectory(utils/PerfectShuffle)
 896   add_subdirectory(utils/count)
 897   add_subdirectory(utils/not)
 898   add_subdirectory(utils/yaml-bench)
 899 else()
 900   if ( LLVM_INCLUDE_TESTS )
 901     message(FATAL_ERROR "Including tests when not building utils will not work.
 902     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 903   endif()
 904 endif()
 905
 906 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 907 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 908   add_subdirectory(utils/LLVMVisualizers)
 909 endif()
 910
 911 foreach( binding ${LLVM_BINDINGS_LIST} )
 912   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 913     add_subdirectory(bindings/${binding})
 914   endif()
 915 endforeach()
 916
 917 add_subdirectory(projects)
 918
 919 if( LLVM_INCLUDE_TOOLS )
 920   add_subdirectory(tools)
 921 endif()
 922
 923 if( LLVM_INCLUDE_RUNTIMES )
 924   add_subdirectory(runtimes)
 925 endif()
 926
 927 if( LLVM_INCLUDE_EXAMPLES )
 928   add_subdirectory(examples)
 929 endif()
 930
 931 if( LLVM_INCLUDE_TESTS )
 932   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 933     include(LLVMExternalProjectUtils)
 934     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 935       USE_TOOLCHAIN
 936       EXCLUDE_FROM_ALL
 937       NO_INSTALL
 938       ALWAYS_CLEAN)
 939   endif()
 940   add_subdirectory(utils/lit)
 941   add_subdirectory(test)
 942   add_subdirectory(unittests)
 943   if( LLVM_INCLUDE_UTILS )
 944     add_subdirectory(utils/unittest)
 945   endif()
 946
 947   if (WIN32)
 948     # This utility is used to prevent crashing tests from calling Dr. Watson on
 949     # Windows.
 950     add_subdirectory(utils/KillTheDoctor)
 951   endif()
 952
 953   # Add a global check rule now that all subdirectories have been traversed
 954   # and we know the total set of lit testsuites.
 955   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 956   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 957   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 958   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 959   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 960                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 961   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 962                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 963   add_lit_target(check-all
 964     "Running all regression tests"
 965     ${LLVM_LIT_TESTSUITES}
 966     PARAMS ${LLVM_LIT_PARAMS}
 967     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 968     ARGS ${LLVM_LIT_EXTRA_ARGS}
 969     )
 970   if(TARGET check-runtimes)
 971     add_dependencies(check-all check-runtimes)
 972   endif()
 973   add_custom_target(test-depends
 974                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 975   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 976 endif()
 977
 978 if (LLVM_INCLUDE_DOCS)
 979   add_subdirectory(docs)
 980 endif()
 981
 982 add_subdirectory(cmake/modules)
 983
 984 # Do this last so that all lit targets have already been created.
 985 if (LLVM_INCLUDE_UTILS)
 986   add_subdirectory(utils/llvm-lit)
 987 endif()
 988
 989 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 990   install(DIRECTORY include/llvm include/llvm-c
 991     DESTINATION include
 992     COMPONENT llvm-headers
 993     FILES_MATCHING
 994     PATTERN "*.def"
 995     PATTERN "*.h"
 996     PATTERN "*.td"
 997     PATTERN "*.inc"
 998     PATTERN "LICENSE.TXT"
 999     PATTERN ".svn" EXCLUDE
1000     )
1001
1002   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1003     DESTINATION include
1004     COMPONENT llvm-headers
1005     FILES_MATCHING
1006     PATTERN "*.def"
1007     PATTERN "*.h"
1008     PATTERN "*.gen"
1009     PATTERN "*.inc"
1010     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1011     PATTERN "CMakeFiles" EXCLUDE
1012     PATTERN "config.h" EXCLUDE
1013     PATTERN ".svn" EXCLUDE
1014     )
1015
1016   if (LLVM_INSTALL_MODULEMAPS)
1017     install(DIRECTORY include/llvm include/llvm-c
1018             DESTINATION include
1019             COMPONENT llvm-headers
1020             FILES_MATCHING
1021             PATTERN "module.modulemap"
1022             )
1023     install(FILES include/llvm/module.install.modulemap
1024             DESTINATION include/llvm
1025             COMPONENT llvm-headers
1026             RENAME "module.extern.modulemap"
1027             )
1028   endif(LLVM_INSTALL_MODULEMAPS)
1029
1030   # Installing the headers needs to depend on generating any public
1031   # tablegen'd headers.
1032   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1033   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1034
1035   if (NOT LLVM_ENABLE_IDE)
1036     add_llvm_install_targets(install-llvm-headers
1037                              DEPENDS llvm-headers
1038                              COMPONENT llvm-headers)
1039   endif()
1040
1041   # Custom target to install all libraries.
1042   add_custom_target(llvm-libraries)
1043   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1044
1045   if (NOT LLVM_ENABLE_IDE)
1046     add_llvm_install_targets(install-llvm-libraries
1047                              DEPENDS llvm-libraries
1048                              COMPONENT llvm-libraries)
1049   endif()
1050
1051   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1052   if(LLVM_LIBS)
1053     list(REMOVE_DUPLICATES LLVM_LIBS)
1054     foreach(lib ${LLVM_LIBS})
1055       add_dependencies(llvm-libraries ${lib})
1056       if (NOT LLVM_ENABLE_IDE)
1057         add_dependencies(install-llvm-libraries install-${lib})
1058       endif()
1059     endforeach()
1060   endif()
1061 endif()
1062
1063 # This must be at the end of the LLVM root CMakeLists file because it must run
1064 # after all targets are created.
1065 if(LLVM_DISTRIBUTION_COMPONENTS)
1066   if(LLVM_ENABLE_IDE)
1067     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
1068   endif()
1069
1070   add_custom_target(distribution)
1071   add_custom_target(install-distribution)
1072   add_custom_target(install-distribution-stripped)
1073   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS} ${LLVM_RUNTIME_DISTRIBUTION_COMPONENTS})
1074     if(TARGET ${target})
1075       add_dependencies(distribution ${target})
1076     else()
1077       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1078     endif()
1079
1080     if(TARGET install-${target})
1081       add_dependencies(install-distribution install-${target})
1082     else()
1083       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1084     endif()
1085
1086     if(TARGET install-${target}-stripped)
1087       add_dependencies(install-distribution-stripped install-${target}-stripped)
1088     else()
1089       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1090                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1091                          " or you should manually create the 'install-${target}-stripped' target.")
1092     endif()
1093   endforeach()
1094 endif()
1095
1096 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1097 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1098   include(InstallRequiredSystemLibraries)
1099 endif()
1100
1101 if (LLVM_INCLUDE_BENCHMARKS)
1102   # Override benchmark defaults so that when the library itself is updated these
1103   # modifications are not lost.
1104   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1105   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1106   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1107   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1108   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1109   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1110   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1111
1112   add_subdirectory(utils/benchmark)
1113   add_subdirectory(benchmarks)
1114 endif()