CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(NOT DEFINED LLVM_VERSION_MAJOR)
  15   set(LLVM_VERSION_MAJOR 9)
  16 endif()
  17 if(NOT DEFINED LLVM_VERSION_MINOR)
  18   set(LLVM_VERSION_MINOR 0)
  19 endif()
  20 if(NOT DEFINED LLVM_VERSION_PATCH)
  21   set(LLVM_VERSION_PATCH 0)
  22 endif()
  23 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  24   set(LLVM_VERSION_SUFFIX svn)
  25 endif()
  26
  27 if (NOT PACKAGE_VERSION)
  28   set(PACKAGE_VERSION
  29     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  30 endif()
  31
  32 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  33   message(WARNING "Visual Studio generators use the x86 host compiler by "
  34                   "default, even for 64-bit targets. This can result in linker "
  35                   "instability and out of memory errors. To use the 64-bit "
  36                   "host compiler, pass -Thost=x64 on the CMake command line.")
  37 endif()
  38
  39 project(LLVM
  40   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  41   LANGUAGES C CXX ASM)
  42
  43 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  44   message(STATUS "No build type selected, default to Debug")
  45   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  46 endif()
  47
  48 # This should only apply if you are both on an Apple host, and targeting Apple.
  49 if(CMAKE_HOST_APPLE AND APPLE)
  50   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  51   if(NOT CMAKE_LIBTOOL)
  52     if(NOT CMAKE_XCRUN)
  53       find_program(CMAKE_XCRUN NAMES xcrun)
  54     endif()
  55     if(CMAKE_XCRUN)
  56       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  57         OUTPUT_VARIABLE CMAKE_LIBTOOL
  58         OUTPUT_STRIP_TRAILING_WHITESPACE)
  59     endif()
  60
  61     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  62       find_program(CMAKE_LIBTOOL NAMES libtool)
  63     endif()
  64   endif()
  65
  66   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  67   if(CMAKE_LIBTOOL)
  68     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  69     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  70
  71     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  72       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  73       OUTPUT_STRIP_TRAILING_WHITESPACE)
  74     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  75       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  76         ${LIBTOOL_V_OUTPUT})
  77       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  78         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  79       endif()
  80     endif()
  81
  82     foreach(lang ${languages})
  83       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  84         "\"${CMAKE_LIBTOOL}\" -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  85         <LINK_FLAGS> <OBJECTS> ")
  86     endforeach()
  87   endif()
  88
  89   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  90   if(DYLD_LIBRARY_PATH)
  91     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  92     foreach(lang ${languages})
  93       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
  94         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
  95              "${dyld_envar} ${cmd}")
  96       endforeach()
  97       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  98         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
  99     endforeach()
 100   endif()
 101 endif()
 102
 103 # Side-by-side subprojects layout: automatically set the
 104 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 105 # This allows an easy way of setting up a build directory for llvm and another
 106 # one for llvm+clang+... using the same sources.
 107 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;openmp;parallel-libs;polly;pstl")
 108 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 109         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 110 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 111   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 112 endif()
 113
 114 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
 115 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
 116 # several reasons:
 117 #
 118 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
 119 # source of truth for which projects to build. This means we will ignore user
 120 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
 121 # them.
 122 #
 123 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
 124 # non-empty list but now the user wishes to disable building all other projects
 125 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
 126 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
 127 # building all the projects that were previously enabled.
 128 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
 129 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
 130
 131 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
 132   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
 133   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
 134     string(TOUPPER "${proj}" upper_proj)
 135     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 136     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
 137       message(STATUS "${proj} project is enabled")
 138       set(SHOULD_ENABLE_PROJECT TRUE)
 139       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 140       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 141         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 142       endif()
 143       set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE STRING "")
 144     else()
 145       message(STATUS "${proj} project is disabled")
 146       set(SHOULD_ENABLE_PROJECT FALSE)
 147     endif()
 148     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 149     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 150     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 151     # we should deprecate allowing users to set these variables by turning them
 152     # into normal CMake variables rather than cache variables.
 153     set(LLVM_TOOL_${upper_proj}_BUILD
 154       ${SHOULD_ENABLE_PROJECT}
 155       CACHE
 156       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 157     )
 158   endforeach()
 159 endif()
 160 unset(SHOULD_ENABLE_PROJECT)
 161
 162 # Build llvm with ccache if the package is present
 163 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 164 if(LLVM_CCACHE_BUILD)
 165   find_program(CCACHE_PROGRAM ccache)
 166   if(CCACHE_PROGRAM)
 167       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 168       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 169       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 170           CACHE STRING "Parameters to pass through to ccache")
 171
 172       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 173       if (LLVM_CCACHE_MAXSIZE)
 174         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 175       endif()
 176       if (LLVM_CCACHE_DIR)
 177         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 178       endif()
 179       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 180   else()
 181     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 182   endif()
 183 endif()
 184
 185 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 186
 187 # Some features of the LLVM build may be disallowed when dependency debugging is
 188 # enabled. In particular you cannot use ccache because we want to force compile
 189 # operations to always happen.
 190 if(LLVM_DEPENDENCY_DEBUGGING)
 191   if(NOT CMAKE_HOST_APPLE)
 192     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 193   endif()
 194   if(LLVM_CCACHE_BUILD)
 195     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 196   endif()
 197 endif()
 198
 199 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 200 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 201 if(LLVM_ENABLE_GISEL_COV)
 202   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 203 endif()
 204
 205 # Add path for custom modules
 206 set(CMAKE_MODULE_PATH
 207   ${CMAKE_MODULE_PATH}
 208   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 209   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 210   )
 211
 212 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 213 # for use by clang_complete, YouCompleteMe, etc.
 214 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 215
 216 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 217   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 218
 219 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 220
 221 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 222
 223 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 224 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 225 # the installation by default. See llvm.org/PR31905.
 226 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 227
 228 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 229 if ( LLVM_USE_FOLDERS )
 230   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 231 endif()
 232
 233 include(VersionFromVCS)
 234
 235 option(LLVM_APPEND_VC_REV
 236   "Embed the version control system revision in LLVM" ON)
 237
 238 set(PACKAGE_NAME LLVM)
 239 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 240 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 241
 242 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 243   "Default URL where bug reports are to be submitted.")
 244
 245 # Configure CPack.
 246 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 247 set(CPACK_PACKAGE_VENDOR "LLVM")
 248 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 249 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 250 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 251 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 252 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 253 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 254 if(WIN32 AND NOT UNIX)
 255   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 256   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 257   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 258   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 259   set(CPACK_NSIS_MODIFY_PATH "ON")
 260   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 261   if( CMAKE_CL_64 )
 262     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 263   endif()
 264 endif()
 265 include(CPack)
 266
 267 # Sanity check our source directory to make sure that we are not trying to
 268 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 269 # sure that we don't have any stray generated files lying around in the tree
 270 # (which would end up getting picked up by header search, instead of the correct
 271 # versions).
 272 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 273   message(FATAL_ERROR "In-source builds are not allowed.
 274 Please create a directory and run cmake from there, passing the path
 275 to this source directory as the last argument.
 276 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 277 Please delete them.")
 278 endif()
 279
 280 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 281
 282 if (CMAKE_BUILD_TYPE AND
 283     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 284   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 285 endif()
 286
 287 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 288
 289 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 290 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 291
 292 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 293     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 294 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 295
 296 # They are used as destination of target generators.
 297 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 298 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 299 if(WIN32 OR CYGWIN)
 300   # DLL platform -- put DLLs into bin.
 301   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 302 else()
 303   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 304 endif()
 305
 306 # Each of them corresponds to llvm-config's.
 307 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 308 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 309 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 310 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 311 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 312
 313 # Note: LLVM_CMAKE_PATH does not include generated files
 314 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 315 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 316 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 317
 318 # List of all targets to be built by default:
 319 set(LLVM_ALL_TARGETS
 320   AArch64
 321   AMDGPU
 322   ARM
 323   BPF
 324   Hexagon
 325   Lanai
 326   Mips
 327   MSP430
 328   NVPTX
 329   PowerPC
 330   Sparc
 331   SystemZ
 332   WebAssembly
 333   X86
 334   XCore
 335   )
 336
 337 # List of targets with JIT support:
 338 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 339
 340 set(LLVM_TARGETS_TO_BUILD "all"
 341     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 342
 343 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 344   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 345
 346 option(BUILD_SHARED_LIBS
 347   "Build all libraries as shared libraries instead of static" OFF)
 348
 349 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 350 if(LLVM_ENABLE_BACKTRACES)
 351   set(ENABLE_BACKTRACES 1)
 352 endif()
 353
 354 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 355 if(LLVM_ENABLE_CRASH_OVERRIDES)
 356   set(ENABLE_CRASH_OVERRIDES 1)
 357 endif()
 358
 359 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 360
 361 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 362 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 363 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 364
 365 set(LLVM_TARGET_ARCH "host"
 366   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 367
 368 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 369
 370 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 371
 372 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 373
 374 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 375
 376 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 377
 378 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 379
 380 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 381
 382 find_package(Z3 4.7.1)
 383
 384 if (LLVM_Z3_INSTALL_DIR)
 385   if (NOT Z3_FOUND)
 386     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 387   endif()
 388 endif()
 389
 390 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 391
 392 option(LLVM_ENABLE_Z3_SOLVER
 393   "Enable Support for the Z3 constraint solver in LLVM."
 394   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 395 )
 396
 397 if (LLVM_ENABLE_Z3_SOLVER)
 398   if (NOT Z3_FOUND)
 399     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 400   endif()
 401
 402   set(LLVM_WITH_Z3 1)
 403 endif()
 404
 405 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 406   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 407 endif()
 408
 409 set(LLVM_TARGETS_TO_BUILD
 410    ${LLVM_TARGETS_TO_BUILD}
 411    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 412 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 413
 414 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 415 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 416 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 417 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 418   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 419   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 420 else()
 421   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 422   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 423 endif()
 424 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 425 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 426 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 427 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 428
 429 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 430
 431 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 432   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 433 else()
 434   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 435 endif()
 436
 437 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 438
 439 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 440   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 441
 442 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 443        "Set to ON to force using an old, unsupported host toolchain." OFF)
 444
 445 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 446        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 447
 448 option(LLVM_USE_INTEL_JITEVENTS
 449   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 450   OFF)
 451
 452 if( LLVM_USE_INTEL_JITEVENTS )
 453   # Verify we are on a supported platform
 454   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 455     message(FATAL_ERROR
 456       "Intel JIT API support is available on Linux and Windows only.")
 457   endif()
 458 endif( LLVM_USE_INTEL_JITEVENTS )
 459
 460 option(LLVM_USE_OPROFILE
 461   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 462
 463 option(LLVM_EXTERNALIZE_DEBUGINFO
 464   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 465
 466 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 467   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 468
 469 # If enabled, verify we are on a platform that supports oprofile.
 470 if( LLVM_USE_OPROFILE )
 471   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 472     message(FATAL_ERROR "OProfile support is available on Linux only.")
 473   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 474 endif( LLVM_USE_OPROFILE )
 475
 476 option(LLVM_USE_PERF
 477   "Use perf JIT interface to inform perf about JIT code" OFF)
 478
 479 # If enabled, verify we are on a platform that supports perf.
 480 if( LLVM_USE_PERF )
 481   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 482     message(FATAL_ERROR "perf support is available on Linux only.")
 483   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 484 endif( LLVM_USE_PERF )
 485
 486 set(LLVM_USE_SANITIZER "" CACHE STRING
 487   "Define the sanitizer used to build binaries and tests.")
 488 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 489 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 490   "Path to fuzzing library for linking with fuzz targets")
 491
 492 option(LLVM_USE_SPLIT_DWARF
 493   "Use -gsplit-dwarf when compiling llvm." OFF)
 494
 495 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 496 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 497
 498 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 499   set(POLLY_IN_TREE TRUE)
 500 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 501   set(POLLY_IN_TREE TRUE)
 502 else()
 503   set(POLLY_IN_TREE FALSE)
 504 endif()
 505
 506 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 507   set(WITH_POLLY ON)
 508 else()
 509   set(WITH_POLLY OFF)
 510 endif()
 511
 512 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 513   set(LINK_POLLY_INTO_TOOLS ON)
 514 else()
 515   set(LINK_POLLY_INTO_TOOLS OFF)
 516 endif()
 517
 518 # Define an option controlling whether we should build for 32-bit on 64-bit
 519 # platforms, where supported.
 520 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 521   # TODO: support other platforms and toolchains.
 522   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 523 endif()
 524
 525 # Define the default arguments to use with 'lit', and an option for the user to
 526 # override.
 527 set(LIT_ARGS_DEFAULT "-sv")
 528 if (MSVC_IDE OR XCODE)
 529   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 530 endif()
 531 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 532
 533 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 534 if( WIN32 AND NOT CYGWIN )
 535   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 536 endif()
 537
 538 # Define options to control the inclusion and default build behavior for
 539 # components which may not strictly be necessary (tools, examples, and tests).
 540 #
 541 # This is primarily to support building smaller or faster project files.
 542 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 543 option(LLVM_BUILD_TOOLS
 544   "Build the LLVM tools. If OFF, just generate build targets." ON)
 545
 546 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 547 option(LLVM_BUILD_UTILS
 548   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 549
 550 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 551 option(LLVM_BUILD_RUNTIMES
 552   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 553
 554 option(LLVM_BUILD_RUNTIME
 555   "Build the LLVM runtime libraries." ON)
 556 option(LLVM_BUILD_EXAMPLES
 557   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 558 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 559
 560 option(LLVM_BUILD_TESTS
 561   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 562 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 563 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 564
 565 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 566 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 567 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 568
 569 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 570 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 571 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 572 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 573 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 574 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 575
 576 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 577     CACHE STRING "Doxygen-generated HTML documentation install directory")
 578 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 579     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 580
 581 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 582   "Build compiler-rt as an external project." OFF)
 583
 584 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 585   "Show target and host info when tools are invoked with --version." ON)
 586
 587 # You can configure which libraries from LLVM you want to include in the
 588 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 589 # list of LLVM components. All component names handled by llvm-config are valid.
 590 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 591   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 592     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 593 endif()
 594 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 595 if(MSVC)
 596   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 597 else()
 598   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 599 endif()
 600 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 601 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 602   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 603 endif()
 604 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 605
 606 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 607 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 608   set(LLVM_USE_HOST_TOOLS ON)
 609 endif()
 610
 611 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 612   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 613 else()
 614   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 615 endif()
 616
 617 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 618     LLVM_ENABLE_IR_PGO)
 619   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 620     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 621     # for spining disks. Anything higher may only help on slower mediums.
 622     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 623   endif()
 624   if(NOT LLVM_PROFILE_FILE_PATTERN)
 625     if(NOT LLVM_PROFILE_DATA_DIR)
 626       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 627     endif()
 628                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 629   endif()
 630   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 631     if(NOT LLVM_CSPROFILE_DATA_DIR)
 632       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 633     endif()
 634     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 635   endif()
 636 endif()
 637
 638 if (LLVM_BUILD_STATIC)
 639   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 640 endif()
 641
 642 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 643 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 644 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 645
 646 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 647   "Enable per-target runtimes directory")
 648
 649 # All options referred to from HandleLLVMOptions have to be specified
 650 # BEFORE this include, otherwise options will not be correctly set on
 651 # first cmake run
 652 include(config-ix)
 653
 654 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 655   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 656 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 657
 658 # By default, we target the host, but this can be overridden at CMake
 659 # invocation time.
 660 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 661   "Default target for which LLVM will generate code." )
 662 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 663 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 664 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 665
 666 include(HandleLLVMOptions)
 667
 668 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 669 # FIXME: We should support systems with only Python 3, but that requires work
 670 # on LLDB.
 671 set(Python_ADDITIONAL_VERSIONS 2.7)
 672 include(FindPythonInterp)
 673 if( NOT PYTHONINTERP_FOUND )
 674   message(FATAL_ERROR
 675 "Unable to find Python interpreter, required for builds and testing.
 676
 677 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 678 endif()
 679
 680 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 681   message(FATAL_ERROR "Python 2.7 or newer is required")
 682 endif()
 683
 684 ######
 685 # LLVMBuild Integration
 686 #
 687 # We use llvm-build to generate all the data required by the CMake based
 688 # build system in one swoop:
 689 #
 690 #  - We generate a file (a CMake fragment) in the object root which contains
 691 #    all the definitions that are required by CMake.
 692 #
 693 #  - We generate the library table used by llvm-config.
 694 #
 695 #  - We generate the dependencies for the CMake fragment, so that we will
 696 #    automatically reconfigure ourselves.
 697
 698 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 699 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 700   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 701 set(LLVMBUILDCMAKEFRAG
 702   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 703
 704 # Create the list of optional components that are enabled
 705 if (LLVM_USE_INTEL_JITEVENTS)
 706   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 707 endif (LLVM_USE_INTEL_JITEVENTS)
 708 if (LLVM_USE_OPROFILE)
 709   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 710 endif (LLVM_USE_OPROFILE)
 711 if (LLVM_USE_PERF)
 712   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 713 endif (LLVM_USE_PERF)
 714
 715 message(STATUS "Constructing LLVMBuild project information")
 716 execute_process(
 717   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 718             --native-target "${LLVM_NATIVE_ARCH}"
 719             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 720             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 721             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 722             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 723             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 724             ERROR_VARIABLE LLVMBUILDERRORS
 725             OUTPUT_STRIP_TRAILING_WHITESPACE
 726             ERROR_STRIP_TRAILING_WHITESPACE
 727   RESULT_VARIABLE LLVMBUILDRESULT)
 728
 729 # On Win32, CMake doesn't properly handle piping the default output/error
 730 # streams into the GUI console. So, we explicitly catch and report them.
 731 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 732   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 733 endif()
 734 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 735   message(FATAL_ERROR
 736     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 737 endif()
 738
 739 # Include the generated CMake fragment. This will define properties from the
 740 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 741 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 742 # files change.
 743 include(${LLVMBUILDCMAKEFRAG})
 744
 745 ######
 746
 747 # Configure all of the various header file fragments LLVM uses which depend on
 748 # configuration variables.
 749 set(LLVM_ENUM_TARGETS "")
 750 set(LLVM_ENUM_ASM_PRINTERS "")
 751 set(LLVM_ENUM_ASM_PARSERS "")
 752 set(LLVM_ENUM_DISASSEMBLERS "")
 753 foreach(t ${LLVM_TARGETS_TO_BUILD})
 754   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 755
 756   list(FIND LLVM_ALL_TARGETS ${t} idx)
 757   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 758   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 759   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 760   # this test just makes sure that any experimental targets were passed via
 761   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 762   if( idx LESS 0 AND idy LESS 0 )
 763     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 764       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 765   else()
 766     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 767   endif()
 768
 769   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 770   if( asmp_file )
 771     set(LLVM_ENUM_ASM_PRINTERS
 772       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 773   endif()
 774   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 775     set(LLVM_ENUM_ASM_PARSERS
 776       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 777   endif()
 778   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 779     set(LLVM_ENUM_DISASSEMBLERS
 780       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 781   endif()
 782 endforeach(t)
 783
 784 # Produce the target definition files, which provide a way for clients to easily
 785 # include various classes of targets.
 786 configure_file(
 787   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 788   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 789   )
 790 configure_file(
 791   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 792   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 793   )
 794 configure_file(
 795   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 796   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 797   )
 798 configure_file(
 799   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 800   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 801   )
 802
 803 # Configure the three LLVM configuration header files.
 804 configure_file(
 805   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 806   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 807 configure_file(
 808   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 809   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 810 configure_file(
 811   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 812   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 813
 814 # Add target for generating source rpm package.
 815 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 816     CACHE FILEPATH ".spec file to use for srpm generation")
 817 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 818 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 819
 820 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 821 string(LENGTH "${revision}" revision_length)
 822 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 823   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 824 else()
 825   set(LLVM_RPM_SPEC_REVISION "${revision}")
 826 endif()
 827
 828 configure_file(
 829   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 830   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 831
 832 add_custom_target(srpm
 833   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 834   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 835 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 836
 837
 838 # They are not referenced. See set_output_directory().
 839 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 840 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 841 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 842
 843 if(APPLE AND DARWIN_LTO_LIBRARY)
 844   set(CMAKE_EXE_LINKER_FLAGS
 845     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 846   set(CMAKE_SHARED_LINKER_FLAGS
 847     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 848   set(CMAKE_MODULE_LINKER_FLAGS
 849     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 850 endif()
 851
 852 # Work around a broken bfd ld behavior. When linking a binary with a
 853 # foo.so library, it will try to find any library that foo.so uses and
 854 # check its symbols. This is wasteful (the check was done when foo.so
 855 # was created) and can fail since it is not the dynamic linker and
 856 # doesn't know how to handle search paths correctly.
 857 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 858   set(CMAKE_EXE_LINKER_FLAGS
 859       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 860 endif()
 861
 862 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 863
 864 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 865
 866 # when crosscompiling import the executable targets from a file
 867 if(LLVM_USE_HOST_TOOLS)
 868   include(CrossCompile)
 869 endif(LLVM_USE_HOST_TOOLS)
 870 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 871 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 872 # (this is a variable that CrossCompile sets on recursive invocations)
 873 endif()
 874
 875 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 876   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 877   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 878   include_directories(SYSTEM "/usr/local/include")
 879   link_directories("/usr/local/lib")
 880 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 881
 882 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 883    # special hack for Solaris to handle crazy system sys/regset.h
 884    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 885 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 886
 887 # Make sure we don't get -rdynamic in every binary. For those that need it,
 888 # use export_executable_symbols(target).
 889 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 890
 891 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 892   "Profiling data file to use when compiling in order to improve runtime performance.")
 893
 894 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 895   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 896     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 897   else()
 898     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 899   endif()
 900 endif()
 901
 902 include(AddLLVM)
 903 include(TableGen)
 904
 905 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 906   # People report that -O3 is unreliable on MinGW. The traditional
 907   # build also uses -O2 for that reason:
 908   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 909 endif()
 910
 911 # Put this before tblgen. Else we have a circular dependence.
 912 add_subdirectory(lib/Demangle)
 913 add_subdirectory(lib/Support)
 914 add_subdirectory(lib/TableGen)
 915
 916 add_subdirectory(utils/TableGen)
 917
 918 add_subdirectory(include/llvm)
 919
 920 add_subdirectory(lib)
 921
 922 if( LLVM_INCLUDE_UTILS )
 923   add_subdirectory(utils/FileCheck)
 924   add_subdirectory(utils/PerfectShuffle)
 925   add_subdirectory(utils/count)
 926   add_subdirectory(utils/not)
 927   add_subdirectory(utils/yaml-bench)
 928 else()
 929   if ( LLVM_INCLUDE_TESTS )
 930     message(FATAL_ERROR "Including tests when not building utils will not work.
 931     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 932   endif()
 933 endif()
 934
 935 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 936 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 937   add_subdirectory(utils/LLVMVisualizers)
 938 endif()
 939
 940 foreach( binding ${LLVM_BINDINGS_LIST} )
 941   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 942     add_subdirectory(bindings/${binding})
 943   endif()
 944 endforeach()
 945
 946 add_subdirectory(projects)
 947
 948 if( LLVM_INCLUDE_TOOLS )
 949   add_subdirectory(tools)
 950 endif()
 951
 952 if( LLVM_INCLUDE_RUNTIMES )
 953   add_subdirectory(runtimes)
 954 endif()
 955
 956 if( LLVM_INCLUDE_EXAMPLES )
 957   add_subdirectory(examples)
 958 endif()
 959
 960 if( LLVM_INCLUDE_TESTS )
 961   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 962     include(LLVMExternalProjectUtils)
 963     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 964       USE_TOOLCHAIN
 965       EXCLUDE_FROM_ALL
 966       NO_INSTALL
 967       ALWAYS_CLEAN)
 968   endif()
 969   add_subdirectory(utils/lit)
 970   add_subdirectory(test)
 971   add_subdirectory(unittests)
 972   if( LLVM_INCLUDE_UTILS )
 973     add_subdirectory(utils/unittest)
 974   endif()
 975
 976   if (WIN32)
 977     # This utility is used to prevent crashing tests from calling Dr. Watson on
 978     # Windows.
 979     add_subdirectory(utils/KillTheDoctor)
 980   endif()
 981
 982   # Add a global check rule now that all subdirectories have been traversed
 983   # and we know the total set of lit testsuites.
 984   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 985   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 986   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 987   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 988   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 989                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 990   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 991                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 992   add_lit_target(check-all
 993     "Running all regression tests"
 994     ${LLVM_LIT_TESTSUITES}
 995     PARAMS ${LLVM_LIT_PARAMS}
 996     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 997     ARGS ${LLVM_LIT_EXTRA_ARGS}
 998     )
 999   if(TARGET check-runtimes)
1000     add_dependencies(check-all check-runtimes)
1001   endif()
1002   add_custom_target(test-depends
1003                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
1004   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
1005 endif()
1006
1007 if (LLVM_INCLUDE_DOCS)
1008   add_subdirectory(docs)
1009 endif()
1010
1011 add_subdirectory(cmake/modules)
1012
1013 # Do this last so that all lit targets have already been created.
1014 if (LLVM_INCLUDE_UTILS)
1015   add_subdirectory(utils/llvm-lit)
1016 endif()
1017
1018 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1019   install(DIRECTORY include/llvm include/llvm-c
1020     DESTINATION include
1021     COMPONENT llvm-headers
1022     FILES_MATCHING
1023     PATTERN "*.def"
1024     PATTERN "*.h"
1025     PATTERN "*.td"
1026     PATTERN "*.inc"
1027     PATTERN "LICENSE.TXT"
1028     PATTERN ".svn" EXCLUDE
1029     )
1030
1031   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1032     DESTINATION include
1033     COMPONENT llvm-headers
1034     FILES_MATCHING
1035     PATTERN "*.def"
1036     PATTERN "*.h"
1037     PATTERN "*.gen"
1038     PATTERN "*.inc"
1039     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1040     PATTERN "CMakeFiles" EXCLUDE
1041     PATTERN "config.h" EXCLUDE
1042     PATTERN ".svn" EXCLUDE
1043     )
1044
1045   if (LLVM_INSTALL_MODULEMAPS)
1046     install(DIRECTORY include/llvm include/llvm-c
1047             DESTINATION include
1048             COMPONENT llvm-headers
1049             FILES_MATCHING
1050             PATTERN "module.modulemap"
1051             )
1052     install(FILES include/llvm/module.install.modulemap
1053             DESTINATION include/llvm
1054             COMPONENT llvm-headers
1055             RENAME "module.extern.modulemap"
1056             )
1057   endif(LLVM_INSTALL_MODULEMAPS)
1058
1059   # Installing the headers needs to depend on generating any public
1060   # tablegen'd headers.
1061   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1062   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1063
1064   if (NOT LLVM_ENABLE_IDE)
1065     add_llvm_install_targets(install-llvm-headers
1066                              DEPENDS llvm-headers
1067                              COMPONENT llvm-headers)
1068   endif()
1069
1070   # Custom target to install all libraries.
1071   add_custom_target(llvm-libraries)
1072   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1073
1074   if (NOT LLVM_ENABLE_IDE)
1075     add_llvm_install_targets(install-llvm-libraries
1076                              DEPENDS llvm-libraries
1077                              COMPONENT llvm-libraries)
1078   endif()
1079
1080   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1081   if(LLVM_LIBS)
1082     list(REMOVE_DUPLICATES LLVM_LIBS)
1083     foreach(lib ${LLVM_LIBS})
1084       add_dependencies(llvm-libraries ${lib})
1085       if (NOT LLVM_ENABLE_IDE)
1086         add_dependencies(install-llvm-libraries install-${lib})
1087       endif()
1088     endforeach()
1089   endif()
1090 endif()
1091
1092 # This must be at the end of the LLVM root CMakeLists file because it must run
1093 # after all targets are created.
1094 if(LLVM_DISTRIBUTION_COMPONENTS)
1095   if(LLVM_ENABLE_IDE)
1096     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
1097   endif()
1098
1099   add_custom_target(distribution)
1100   add_custom_target(install-distribution)
1101   add_custom_target(install-distribution-stripped)
1102   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS} ${LLVM_RUNTIME_DISTRIBUTION_COMPONENTS})
1103     if(TARGET ${target})
1104       add_dependencies(distribution ${target})
1105     else()
1106       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1107     endif()
1108
1109     if(TARGET install-${target})
1110       add_dependencies(install-distribution install-${target})
1111     else()
1112       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1113     endif()
1114
1115     if(TARGET install-${target}-stripped)
1116       add_dependencies(install-distribution-stripped install-${target}-stripped)
1117     else()
1118       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1119                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1120                          " or you should manually create the 'install-${target}-stripped' target.")
1121     endif()
1122   endforeach()
1123 endif()
1124
1125 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1126 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1127   include(InstallRequiredSystemLibraries)
1128 endif()
1129
1130 if (LLVM_INCLUDE_BENCHMARKS)
1131   # Override benchmark defaults so that when the library itself is updated these
1132   # modifications are not lost.
1133   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1134   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1135   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1136   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1137   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1138   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1139   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1140
1141   add_subdirectory(utils/benchmark)
1142   add_subdirectory(benchmarks)
1143 endif()