CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 cmake_policy(SET CMP0022 NEW)
   6
   7 cmake_policy(SET CMP0048 NEW)
   8
   9 # CMake 3.1 and higher include generator expressions of the form
  10 # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  11 # stripped everywhere that access the SOURCES property, so we just
  12 # defer to the OLD behavior of not including generator expressions
  13 # in the output for now.
  14 cmake_policy(SET CMP0051 OLD)
  15
  16 cmake_policy(SET CMP0056 NEW)
  17
  18 cmake_policy(SET CMP0057 NEW)
  19
  20 if(POLICY CMP0068)
  21   cmake_policy(SET CMP0068 NEW)
  22   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
  23 endif()
  24
  25 if(NOT DEFINED LLVM_VERSION_MAJOR)
  26   set(LLVM_VERSION_MAJOR 7)
  27 endif()
  28 if(NOT DEFINED LLVM_VERSION_MINOR)
  29   set(LLVM_VERSION_MINOR 0)
  30 endif()
  31 if(NOT DEFINED LLVM_VERSION_PATCH)
  32   set(LLVM_VERSION_PATCH 0)
  33 endif()
  34 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  35   set(LLVM_VERSION_SUFFIX svn)
  36 endif()
  37
  38 if (NOT PACKAGE_VERSION)
  39   set(PACKAGE_VERSION
  40     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  41 endif()
  42
  43 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  44   message(WARNING "Visual Studio generators use the x86 host compiler by "
  45                   "default, even for 64-bit targets. This can result in linker "
  46                   "instability and out of memory errors. To use the 64-bit "
  47                   "host compiler, pass -Thost=x64 on the CMake command line.")
  48 endif()
  49
  50 project(LLVM
  51   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  52   LANGUAGES C CXX ASM)
  53
  54 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  55   message(STATUS "No build type selected, default to Debug")
  56   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  57 endif()
  58
  59 # This should only apply if you are both on an Apple host, and targeting Apple.
  60 if(CMAKE_HOST_APPLE AND APPLE)
  61   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  62   if(NOT CMAKE_LIBTOOL)
  63     if(NOT CMAKE_XCRUN)
  64       find_program(CMAKE_XCRUN NAMES xcrun)
  65     endif()
  66     if(CMAKE_XCRUN)
  67       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  68         OUTPUT_VARIABLE CMAKE_LIBTOOL
  69         OUTPUT_STRIP_TRAILING_WHITESPACE)
  70     endif()
  71
  72     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  73       find_program(CMAKE_LIBTOOL NAMES libtool)
  74     endif()
  75   endif()
  76
  77   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  78   if(CMAKE_LIBTOOL)
  79     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  80     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  81
  82     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  83       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  84       OUTPUT_STRIP_TRAILING_WHITESPACE)
  85     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  86       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  87         ${LIBTOOL_V_OUTPUT})
  88       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  89         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  90       endif()
  91     endif()
  92
  93     foreach(lang ${languages})
  94       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  95         "\"${CMAKE_LIBTOOL}\" -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  96         <LINK_FLAGS> <OBJECTS> ")
  97     endforeach()
  98   endif()
  99
 100   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
 101   if(DYLD_LIBRARY_PATH)
 102     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
 103     foreach(lang ${languages})
 104       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 105         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
 106              "${dyld_envar} ${cmd}")
 107       endforeach()
 108       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 109         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 110     endforeach()
 111   endif()
 112 endif()
 113
 114 # Side-by-side subprojects layout: automatically set the
 115 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 116 # This allows an easy way of setting up a build directory for llvm and another
 117 # one for llvm+clang+... using the same sources.
 118 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly;debuginfo-tests")
 119 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 120         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 121 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 122   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 123 endif()
 124 foreach(proj ${LLVM_ENABLE_PROJECTS})
 125   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 126   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 127     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 128   endif()
 129   string(TOUPPER "${proj}" upper_proj)
 130   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 131   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 132   # There is a widely spread opinion that clang-tools-extra should be merged
 133   # into clang. The following simulates it by always enabling clang-tools-extra
 134   # when enabling clang.
 135   if (proj STREQUAL "clang")
 136     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 137   endif()
 138 endforeach()
 139
 140 # Build llvm with ccache if the package is present
 141 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 142 if(LLVM_CCACHE_BUILD)
 143   find_program(CCACHE_PROGRAM ccache)
 144   if(CCACHE_PROGRAM)
 145       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 146       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 147       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 148           CACHE STRING "Parameters to pass through to ccache")
 149
 150       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 151       if (LLVM_CCACHE_MAXSIZE)
 152         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 153       endif()
 154       if (LLVM_CCACHE_DIR)
 155         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 156       endif()
 157       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 158   else()
 159     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 160   endif()
 161 endif()
 162
 163 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 164
 165 # Some features of the LLVM build may be disallowed when dependency debugging is
 166 # enabled. In particular you cannot use ccache because we want to force compile
 167 # operations to always happen.
 168 if(LLVM_DEPENDENCY_DEBUGGING)
 169   if(NOT CMAKE_HOST_APPLE)
 170     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 171   endif()
 172   if(LLVM_CCACHE_BUILD)
 173     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 174   endif()
 175 endif()
 176
 177 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 178 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 179 if(LLVM_ENABLE_GISEL_COV)
 180   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 181 endif()
 182
 183 # Add path for custom modules
 184 set(CMAKE_MODULE_PATH
 185   ${CMAKE_MODULE_PATH}
 186   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 187   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 188   )
 189
 190 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 191 # for use by clang_complete, YouCompleteMe, etc.
 192 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 193
 194 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 195   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 196
 197 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 198
 199 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 200
 201 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 202 if ( LLVM_USE_FOLDERS )
 203   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 204 endif()
 205
 206 include(VersionFromVCS)
 207
 208 option(LLVM_APPEND_VC_REV
 209   "Embed the version control system revision id in LLVM" ON)
 210
 211 set(PACKAGE_NAME LLVM)
 212 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 213 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 214
 215 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 216   "Default URL where bug reports are to be submitted.")
 217
 218 # Configure CPack.
 219 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 220 set(CPACK_PACKAGE_VENDOR "LLVM")
 221 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 222 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 223 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 224 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 225 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 226 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 227 if(WIN32 AND NOT UNIX)
 228   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 229   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 230   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 231   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 232   set(CPACK_NSIS_MODIFY_PATH "ON")
 233   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 234   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 235     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 236   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 237     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 238   if( CMAKE_CL_64 )
 239     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 240   endif()
 241 endif()
 242 include(CPack)
 243
 244 # Sanity check our source directory to make sure that we are not trying to
 245 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 246 # sure that we don't have any stray generated files lying around in the tree
 247 # (which would end up getting picked up by header search, instead of the correct
 248 # versions).
 249 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 250   message(FATAL_ERROR "In-source builds are not allowed.
 251 CMake would overwrite the makefiles distributed with LLVM.
 252 Please create a directory and run cmake from there, passing the path
 253 to this source directory as the last argument.
 254 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 255 Please delete them.")
 256 endif()
 257 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 258   file(GLOB_RECURSE
 259     tablegenned_files_on_include_dir
 260     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 261   file(GLOB_RECURSE
 262     tablegenned_files_on_lib_dir
 263     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 264   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 265     message(FATAL_ERROR "Apparently there is a previous in-source build,
 266 probably as the result of running `configure' and `make' on
 267 ${CMAKE_CURRENT_SOURCE_DIR}.
 268 This may cause problems. The suspicious files are:
 269 ${tablegenned_files_on_lib_dir}
 270 ${tablegenned_files_on_include_dir}
 271 Please clean the source directory.")
 272   endif()
 273 endif()
 274
 275 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 276
 277 if (CMAKE_BUILD_TYPE AND
 278     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 279   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 280 endif()
 281
 282 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 283
 284 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 285 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 286
 287 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 288     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 289 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 290
 291 # They are used as destination of target generators.
 292 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 293 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 294 if(WIN32 OR CYGWIN)
 295   # DLL platform -- put DLLs into bin.
 296   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 297 else()
 298   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 299 endif()
 300
 301 # Each of them corresponds to llvm-config's.
 302 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 303 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 304 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 305 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 306 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 307
 308 # Note: LLVM_CMAKE_PATH does not include generated files
 309 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 310 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 311 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 312
 313 # List of all targets to be built by default:
 314 set(LLVM_ALL_TARGETS
 315   AArch64
 316   AMDGPU
 317   ARM
 318   BPF
 319   Hexagon
 320   Lanai
 321   Mips
 322   MSP430
 323   NVPTX
 324   PowerPC
 325   Sparc
 326   SystemZ
 327   X86
 328   XCore
 329   )
 330
 331 # List of targets with JIT support:
 332 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 333
 334 set(LLVM_TARGETS_TO_BUILD "all"
 335     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 336
 337 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 338   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 339
 340 option(BUILD_SHARED_LIBS
 341   "Build all libraries as shared libraries instead of static" OFF)
 342
 343 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 344 if(LLVM_ENABLE_BACKTRACES)
 345   set(ENABLE_BACKTRACES 1)
 346 endif()
 347
 348 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 349 if(LLVM_ENABLE_CRASH_OVERRIDES)
 350   set(ENABLE_CRASH_OVERRIDES 1)
 351 endif()
 352
 353 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 354 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 355 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 356
 357 set(LLVM_TARGET_ARCH "host"
 358   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 359
 360 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 361
 362 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 363
 364 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 365
 366 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 367
 368 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 369
 370 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 371
 372 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 373   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 374 endif()
 375
 376 set(LLVM_TARGETS_TO_BUILD
 377    ${LLVM_TARGETS_TO_BUILD}
 378    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 379 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 380
 381 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 382 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 383 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 384 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 385   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 386   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 387 else()
 388   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 389   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 390 endif()
 391 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 392 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 393 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 394 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 395 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 396 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 397
 398 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 399
 400 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 401   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 402 else()
 403   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 404 endif()
 405
 406 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 407
 408 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 409   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 410
 411 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 412        "Set to ON to force using an old, unsupported host toolchain." OFF)
 413
 414 option(LLVM_USE_INTEL_JITEVENTS
 415   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 416   OFF)
 417
 418 if( LLVM_USE_INTEL_JITEVENTS )
 419   # Verify we are on a supported platform
 420   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 421     message(FATAL_ERROR
 422       "Intel JIT API support is available on Linux and Windows only.")
 423   endif()
 424 endif( LLVM_USE_INTEL_JITEVENTS )
 425
 426 option(LLVM_USE_OPROFILE
 427   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 428
 429 option(LLVM_EXTERNALIZE_DEBUGINFO
 430   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 431
 432 option(LLVM_CODESIGNING_IDENTITY
 433   "Sign executables and dylibs with the given identity (Darwin Only)" OFF)
 434
 435 # If enabled, verify we are on a platform that supports oprofile.
 436 if( LLVM_USE_OPROFILE )
 437   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 438     message(FATAL_ERROR "OProfile support is available on Linux only.")
 439   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 440 endif( LLVM_USE_OPROFILE )
 441
 442 set(LLVM_USE_SANITIZER "" CACHE STRING
 443   "Define the sanitizer used to build binaries and tests.")
 444 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 445 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 446   "Path to fuzzing library for linking with fuzz targets")
 447
 448 option(LLVM_USE_SPLIT_DWARF
 449   "Use -gsplit-dwarf when compiling llvm." OFF)
 450
 451 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 452 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 453
 454 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 455   set(POLLY_IN_TREE TRUE)
 456 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 457   set(POLLY_IN_TREE TRUE)
 458 else()
 459   set(POLLY_IN_TREE FALSE)
 460 endif()
 461
 462 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 463   set(WITH_POLLY ON)
 464 else()
 465   set(WITH_POLLY OFF)
 466 endif()
 467
 468 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 469   set(LINK_POLLY_INTO_TOOLS ON)
 470 else()
 471   set(LINK_POLLY_INTO_TOOLS OFF)
 472 endif()
 473
 474 # Define an option controlling whether we should build for 32-bit on 64-bit
 475 # platforms, where supported.
 476 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 477   # TODO: support other platforms and toolchains.
 478   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 479 endif()
 480
 481 # Define the default arguments to use with 'lit', and an option for the user to
 482 # override.
 483 set(LIT_ARGS_DEFAULT "-sv")
 484 if (MSVC_IDE OR XCODE)
 485   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 486 endif()
 487 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 488
 489 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 490 if( WIN32 AND NOT CYGWIN )
 491   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 492 endif()
 493
 494 # Define options to control the inclusion and default build behavior for
 495 # components which may not strictly be necessary (tools, examples, and tests).
 496 #
 497 # This is primarily to support building smaller or faster project files.
 498 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 499 option(LLVM_BUILD_TOOLS
 500   "Build the LLVM tools. If OFF, just generate build targets." ON)
 501
 502 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 503 option(LLVM_BUILD_UTILS
 504   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 505
 506 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 507 option(LLVM_BUILD_RUNTIMES
 508   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 509
 510 option(LLVM_BUILD_RUNTIME
 511   "Build the LLVM runtime libraries." ON)
 512 option(LLVM_BUILD_EXAMPLES
 513   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 514 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 515
 516 option(LLVM_BUILD_TESTS
 517   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 518 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 519 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 520
 521 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 522 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 523 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 524 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 525 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 526 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 527
 528 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 529     CACHE STRING "Doxygen-generated HTML documentation install directory")
 530 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 531     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 532
 533 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 534   "Build compiler-rt as an external project." OFF)
 535
 536 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 537   "Show target and host info when tools are invoked with --version." ON)
 538
 539 # You can configure which libraries from LLVM you want to include in the
 540 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 541 # list of LLVM components. All component names handled by llvm-config are valid.
 542 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 543   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 544     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 545 endif()
 546 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 547 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 548 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 549 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 550   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 551 endif()
 552 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 553
 554 option(LLVM_DYLIB_SYMBOL_VERSIONING OFF)
 555
 556 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 557 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 558   set(LLVM_USE_HOST_TOOLS ON)
 559 endif()
 560
 561 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 562   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 563 else()
 564   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 565 endif()
 566
 567 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 568     LLVM_ENABLE_IR_PGO)
 569   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 570     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 571     # for spining disks. Anything higher may only help on slower mediums.
 572     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 573   endif()
 574   if(NOT LLVM_PROFILE_FILE_PATTERN)
 575     if(NOT LLVM_PROFILE_DATA_DIR)
 576       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 577     endif()
 578                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 579   endif()
 580 endif()
 581
 582 if (LLVM_BUILD_STATIC)
 583   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 584 endif()
 585
 586 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 587 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 588 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 589
 590 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 591   "Enable per-target runtimes directory")
 592
 593 # All options referred to from HandleLLVMOptions have to be specified
 594 # BEFORE this include, otherwise options will not be correctly set on
 595 # first cmake run
 596 include(config-ix)
 597
 598 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 599   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 600 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 601
 602 # By default, we target the host, but this can be overridden at CMake
 603 # invocation time.
 604 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 605   "Default target for which LLVM will generate code." )
 606 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 607 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 608 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 609
 610 include(HandleLLVMOptions)
 611
 612 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 613 # FIXME: We should support systems with only Python 3, but that requires work
 614 # on LLDB.
 615 set(Python_ADDITIONAL_VERSIONS 2.7)
 616 include(FindPythonInterp)
 617 if( NOT PYTHONINTERP_FOUND )
 618   message(FATAL_ERROR
 619 "Unable to find Python interpreter, required for builds and testing.
 620
 621 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 622 endif()
 623
 624 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 625   message(FATAL_ERROR "Python 2.7 or newer is required")
 626 endif()
 627
 628 ######
 629 # LLVMBuild Integration
 630 #
 631 # We use llvm-build to generate all the data required by the CMake based
 632 # build system in one swoop:
 633 #
 634 #  - We generate a file (a CMake fragment) in the object root which contains
 635 #    all the definitions that are required by CMake.
 636 #
 637 #  - We generate the library table used by llvm-config.
 638 #
 639 #  - We generate the dependencies for the CMake fragment, so that we will
 640 #    automatically reconfigure outselves.
 641
 642 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 643 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 644   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 645 set(LLVMBUILDCMAKEFRAG
 646   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 647
 648 # Create the list of optional components that are enabled
 649 if (LLVM_USE_INTEL_JITEVENTS)
 650   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 651 endif (LLVM_USE_INTEL_JITEVENTS)
 652 if (LLVM_USE_OPROFILE)
 653   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 654 endif (LLVM_USE_OPROFILE)
 655
 656 message(STATUS "Constructing LLVMBuild project information")
 657 execute_process(
 658   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 659             --native-target "${LLVM_NATIVE_ARCH}"
 660             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 661             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 662             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 663             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 664             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 665             ERROR_VARIABLE LLVMBUILDERRORS
 666             OUTPUT_STRIP_TRAILING_WHITESPACE
 667             ERROR_STRIP_TRAILING_WHITESPACE
 668   RESULT_VARIABLE LLVMBUILDRESULT)
 669
 670 # On Win32, CMake doesn't properly handle piping the default output/error
 671 # streams into the GUI console. So, we explicitly catch and report them.
 672 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 673   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 674 endif()
 675 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 676   message(FATAL_ERROR
 677     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 678 endif()
 679
 680 # Include the generated CMake fragment. This will define properties from the
 681 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 682 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 683 # files change.
 684 include(${LLVMBUILDCMAKEFRAG})
 685
 686 ######
 687
 688 # Configure all of the various header file fragments LLVM uses which depend on
 689 # configuration variables.
 690 set(LLVM_ENUM_TARGETS "")
 691 set(LLVM_ENUM_ASM_PRINTERS "")
 692 set(LLVM_ENUM_ASM_PARSERS "")
 693 set(LLVM_ENUM_DISASSEMBLERS "")
 694 foreach(t ${LLVM_TARGETS_TO_BUILD})
 695   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 696
 697   list(FIND LLVM_ALL_TARGETS ${t} idx)
 698   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 699   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 700   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 701   # this test just makes sure that any experimental targets were passed via
 702   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 703   if( idx LESS 0 AND idy LESS 0 )
 704     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 705       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 706   else()
 707     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 708   endif()
 709
 710   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 711   if( asmp_file )
 712     set(LLVM_ENUM_ASM_PRINTERS
 713       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 714   endif()
 715   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 716     set(LLVM_ENUM_ASM_PARSERS
 717       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 718   endif()
 719   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 720     set(LLVM_ENUM_DISASSEMBLERS
 721       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 722   endif()
 723 endforeach(t)
 724
 725 # Produce the target definition files, which provide a way for clients to easily
 726 # include various classes of targets.
 727 configure_file(
 728   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 729   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 730   )
 731 configure_file(
 732   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 733   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 734   )
 735 configure_file(
 736   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 737   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 738   )
 739 configure_file(
 740   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 741   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 742   )
 743
 744 # Configure the three LLVM configuration header files.
 745 configure_file(
 746   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 747   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 748 configure_file(
 749   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 750   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 751 configure_file(
 752   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 753   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 754
 755 # Add target for generating source rpm package.
 756 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 757     CACHE FILEPATH ".spec file to use for srpm generation")
 758 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 759 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 760
 761 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 762 # DUMMY_VAR contains a version string which we don't care about.
 763 add_version_info_from_vcs(DUMMY_VAR)
 764 if ( SVN_REVISION )
 765   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 766 elseif ( GIT_COMMIT )
 767   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 768 endif()
 769
 770 configure_file(
 771   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 772   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 773
 774 add_custom_target(srpm
 775   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 776   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 777 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 778
 779
 780 # They are not referenced. See set_output_directory().
 781 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 782 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 783 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 784
 785 if(APPLE AND DARWIN_LTO_LIBRARY)
 786   set(CMAKE_EXE_LINKER_FLAGS
 787     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 788   set(CMAKE_SHARED_LINKER_FLAGS
 789     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 790   set(CMAKE_MODULE_LINKER_FLAGS
 791     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 792 endif()
 793
 794 # Work around a broken bfd ld behavior. When linking a binary with a
 795 # foo.so library, it will try to find any library that foo.so uses and
 796 # check its symbols. This is wasteful (the check was done when foo.so
 797 # was created) and can fail since it is not the dynamic linker and
 798 # doesn't know how to handle search paths correctly.
 799 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 800   set(CMAKE_EXE_LINKER_FLAGS
 801       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 802 endif()
 803
 804 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 805
 806 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 807
 808 # when crosscompiling import the executable targets from a file
 809 if(LLVM_USE_HOST_TOOLS)
 810   include(CrossCompile)
 811 endif(LLVM_USE_HOST_TOOLS)
 812 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 813 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 814 # (this is a variable that CrossCompile sets on recursive invocations)
 815 endif()
 816
 817 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 818   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 819   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 820   include_directories(SYSTEM "/usr/local/include")
 821   link_directories("/usr/local/lib")
 822 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 823
 824 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 825    # special hack for Solaris to handle crazy system sys/regset.h
 826    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 827 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 828
 829 # Make sure we don't get -rdynamic in every binary. For those that need it,
 830 # use export_executable_symbols(target).
 831 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 832
 833 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 834   "Profiling data file to use when compiling in order to improve runtime performance.")
 835
 836 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 837   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 838     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 839   else()
 840     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 841   endif()
 842 endif()
 843
 844 include(AddLLVM)
 845 include(TableGen)
 846
 847 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 848   # People report that -O3 is unreliable on MinGW. The traditional
 849   # build also uses -O2 for that reason:
 850   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 851 endif()
 852
 853 # Put this before tblgen. Else we have a circular dependence.
 854 add_subdirectory(lib/Demangle)
 855 add_subdirectory(lib/Support)
 856 add_subdirectory(lib/TableGen)
 857
 858 add_subdirectory(utils/TableGen)
 859
 860 add_subdirectory(include/llvm)
 861
 862 add_subdirectory(lib)
 863
 864 if( LLVM_INCLUDE_UTILS )
 865   add_subdirectory(utils/FileCheck)
 866   add_subdirectory(utils/PerfectShuffle)
 867   add_subdirectory(utils/count)
 868   add_subdirectory(utils/not)
 869   add_subdirectory(utils/yaml-bench)
 870 else()
 871   if ( LLVM_INCLUDE_TESTS )
 872     message(FATAL_ERROR "Including tests when not building utils will not work.
 873     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 874   endif()
 875 endif()
 876
 877 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 878 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 879   add_subdirectory(utils/LLVMVisualizers)
 880 endif()
 881
 882 foreach( binding ${LLVM_BINDINGS_LIST} )
 883   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 884     add_subdirectory(bindings/${binding})
 885   endif()
 886 endforeach()
 887
 888 add_subdirectory(projects)
 889
 890 if( LLVM_INCLUDE_TOOLS )
 891   add_subdirectory(tools)
 892 endif()
 893
 894 if( LLVM_INCLUDE_RUNTIMES )
 895   add_subdirectory(runtimes)
 896 endif()
 897
 898 if( LLVM_INCLUDE_EXAMPLES )
 899   add_subdirectory(examples)
 900 endif()
 901
 902 if( LLVM_INCLUDE_TESTS )
 903   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 904     include(LLVMExternalProjectUtils)
 905     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 906       USE_TOOLCHAIN
 907       EXCLUDE_FROM_ALL
 908       NO_INSTALL
 909       ALWAYS_CLEAN)
 910   endif()
 911   add_subdirectory(utils/lit)
 912   add_subdirectory(test)
 913   add_subdirectory(unittests)
 914   if( LLVM_INCLUDE_UTILS )
 915     add_subdirectory(utils/unittest)
 916   endif()
 917
 918   if (WIN32)
 919     # This utility is used to prevent crashing tests from calling Dr. Watson on
 920     # Windows.
 921     add_subdirectory(utils/KillTheDoctor)
 922   endif()
 923
 924   # Add a global check rule now that all subdirectories have been traversed
 925   # and we know the total set of lit testsuites.
 926   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 927   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 928   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 929   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 930   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 931                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 932   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 933                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 934   add_lit_target(check-all
 935     "Running all regression tests"
 936     ${LLVM_LIT_TESTSUITES}
 937     PARAMS ${LLVM_LIT_PARAMS}
 938     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 939     ARGS ${LLVM_LIT_EXTRA_ARGS}
 940     )
 941   if(TARGET check-runtimes)
 942     add_dependencies(check-all check-runtimes)
 943   endif()
 944   add_custom_target(test-depends
 945                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 946   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 947 endif()
 948
 949 if (LLVM_INCLUDE_DOCS)
 950   add_subdirectory(docs)
 951 endif()
 952
 953 add_subdirectory(cmake/modules)
 954
 955 # Do this last so that all lit targets have already been created.
 956 if (LLVM_INCLUDE_UTILS)
 957   add_subdirectory(utils/llvm-lit)
 958 endif()
 959
 960 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 961   install(DIRECTORY include/llvm include/llvm-c
 962     DESTINATION include
 963     COMPONENT llvm-headers
 964     FILES_MATCHING
 965     PATTERN "*.def"
 966     PATTERN "*.h"
 967     PATTERN "*.td"
 968     PATTERN "*.inc"
 969     PATTERN "LICENSE.TXT"
 970     PATTERN ".svn" EXCLUDE
 971     )
 972
 973   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
 974     DESTINATION include
 975     COMPONENT llvm-headers
 976     FILES_MATCHING
 977     PATTERN "*.def"
 978     PATTERN "*.h"
 979     PATTERN "*.gen"
 980     PATTERN "*.inc"
 981     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 982     PATTERN "CMakeFiles" EXCLUDE
 983     PATTERN "config.h" EXCLUDE
 984     PATTERN ".svn" EXCLUDE
 985     )
 986
 987   # Installing the headers needs to depend on generating any public
 988   # tablegen'd headers.
 989   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 990   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
 991
 992   if (NOT CMAKE_CONFIGURATION_TYPES)
 993     add_llvm_install_targets(install-llvm-headers
 994                              DEPENDS llvm-headers
 995                              COMPONENT llvm-headers)
 996   endif()
 997 endif()
 998
 999 # This must be at the end of the LLVM root CMakeLists file because it must run
1000 # after all targets are created.
1001 if(LLVM_DISTRIBUTION_COMPONENTS)
1002   if(CMAKE_CONFIGURATION_TYPES)
1003     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
1004   endif()
1005
1006   add_custom_target(distribution)
1007   add_custom_target(install-distribution)
1008   add_custom_target(install-distribution-stripped)
1009   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS} ${LLVM_RUNTIME_DISTRIBUTION_COMPONENTS})
1010     if(TARGET ${target})
1011       add_dependencies(distribution ${target})
1012     else()
1013       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1014     endif()
1015
1016     if(TARGET install-${target})
1017       add_dependencies(install-distribution install-${target})
1018     else()
1019       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1020     endif()
1021
1022     if(TARGET install-${target}-stripped)
1023       add_dependencies(install-distribution-stripped install-${target}-stripped)
1024     else()
1025       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1026                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1027                          " or you should manually create the 'install-${target}-stripped' target.")
1028     endif()
1029   endforeach()
1030 endif()
1031
1032 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1033 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows")
1034   include(InstallRequiredSystemLibraries)
1035 endif()