CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0022)
   6   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
   7 endif()
   8
   9 if (POLICY CMP0051)
  10   # CMake 3.1 and higher include generator expressions of the form
  11   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  12   # stripped everywhere that access the SOURCES property, so we just
  13   # defer to the OLD behavior of not including generator expressions
  14   # in the output for now.
  15   cmake_policy(SET CMP0051 OLD)
  16 endif()
  17
  18 if(POLICY CMP0057)
  19   cmake_policy(SET CMP0057 NEW)
  20 endif()
  21
  22 if(NOT DEFINED LLVM_VERSION_MAJOR)
  23   set(LLVM_VERSION_MAJOR 6)
  24 endif()
  25 if(NOT DEFINED LLVM_VERSION_MINOR)
  26   set(LLVM_VERSION_MINOR 0)
  27 endif()
  28 if(NOT DEFINED LLVM_VERSION_PATCH)
  29   set(LLVM_VERSION_PATCH 0)
  30 endif()
  31 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  32   set(LLVM_VERSION_SUFFIX svn)
  33 endif()
  34
  35 if (POLICY CMP0048)
  36   cmake_policy(SET CMP0048 NEW)
  37   set(cmake_3_0_PROJ_VERSION
  38     VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH})
  39   set(cmake_3_0_LANGUAGES LANGUAGES)
  40 endif()
  41
  42 if (NOT PACKAGE_VERSION)
  43   set(PACKAGE_VERSION
  44     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  45 endif()
  46
  47 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  48   message(WARNING "Visual Studio generators use the x86 host compiler by "
  49                   "default, even for 64-bit targets. This can result in linker "
  50                   "instability and out of memory errors. To use the 64-bit "
  51                   "host compiler, pass -Thost=x64 on the CMake command line.")
  52 endif()
  53
  54 project(LLVM
  55   ${cmake_3_0_PROJ_VERSION}
  56   ${cmake_3_0_LANGUAGES}
  57   C CXX ASM)
  58
  59 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  60   message(STATUS "No build type selected, default to Debug")
  61   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  62 endif()
  63
  64 # This should only apply if you are both on an Apple host, and targeting Apple.
  65 if(CMAKE_HOST_APPLE AND APPLE)
  66   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  67   if(NOT CMAKE_LIBTOOL)
  68     if(NOT CMAKE_XCRUN)
  69       find_program(CMAKE_XCRUN NAMES xcrun)
  70     endif()
  71     if(CMAKE_XCRUN)
  72       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  73         OUTPUT_VARIABLE CMAKE_LIBTOOL
  74         OUTPUT_STRIP_TRAILING_WHITESPACE)
  75     endif()
  76
  77     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  78       find_program(CMAKE_LIBTOOL NAMES libtool)
  79     endif()
  80   endif()
  81
  82   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  83   if(CMAKE_LIBTOOL)
  84     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  85     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  86
  87     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  88       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  89       OUTPUT_STRIP_TRAILING_WHITESPACE)
  90     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  91       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  92         ${LIBTOOL_V_OUTPUT})
  93       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  94         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  95       endif()
  96     endif()
  97
  98     foreach(lang ${languages})
  99       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 100         "${CMAKE_LIBTOOL} -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
 101         <LINK_FLAGS> <OBJECTS> ")
 102     endforeach()
 103   endif()
 104
 105   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
 106   if(DYLD_LIBRARY_PATH)
 107     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
 108     foreach(lang ${languages})
 109       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 110         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
 111              "${dyld_envar} ${cmd}")
 112       endforeach()
 113       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 114         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 115     endforeach()
 116   endif()
 117 endif()
 118
 119 # Side-by-side subprojects layout: automatically set the
 120 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 121 # This allows an easy way of setting up a build directory for llvm and another
 122 # one for llvm+clang+... using the same sources.
 123 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly")
 124 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 125         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 126 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 127   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 128 endif()
 129 foreach(proj ${LLVM_ENABLE_PROJECTS})
 130   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 131   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 132     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 133   endif()
 134   string(TOUPPER "${proj}" upper_proj)
 135   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 136   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 137   # There is a widely spread opinion that clang-tools-extra should be merged
 138   # into clang. The following simulates it by always enabling clang-tools-extra
 139   # when enabling clang.
 140   if (proj STREQUAL "clang")
 141     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 142   endif()
 143 endforeach()
 144
 145 # Build llvm with ccache if the package is present
 146 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 147 if(LLVM_CCACHE_BUILD)
 148   find_program(CCACHE_PROGRAM ccache)
 149   if(CCACHE_PROGRAM)
 150       set(LLVM_CCACHE_SIZE "" CACHE STRING "Size of ccache")
 151       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 152       set(CCACHE_PROGRAM "CCACHE_CPP2=yes CCACHE_HASHDIR=yes ${CCACHE_PROGRAM}")
 153       if (LLVM_CCACHE_SIZE)
 154         set(CCACHE_PROGRAM "CCACHE_SIZE=${LLVM_CCACHE_SIZE} ${CCACHE_PROGRAM}")
 155       endif()
 156       if (LLVM_CCACHE_DIR)
 157         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 158       endif()
 159       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 160   else()
 161     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 162   endif()
 163 endif()
 164
 165 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 166
 167 # Some features of the LLVM build may be disallowed when dependency debugging is
 168 # enabled. In particular you cannot use ccache because we want to force compile
 169 # operations to always happen.
 170 if(LLVM_DEPENDENCY_DEBUGGING)
 171   if(NOT CMAKE_HOST_APPLE)
 172     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 173   endif()
 174   if(LLVM_CCACHE_BUILD)
 175     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 176   endif()
 177 endif()
 178
 179 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 180
 181 # Add path for custom modules
 182 set(CMAKE_MODULE_PATH
 183   ${CMAKE_MODULE_PATH}
 184   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 185   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 186   )
 187
 188 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 189 # for use by clang_complete, YouCompleteMe, etc.
 190 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 191
 192 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 193
 194 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 195
 196 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 197 if ( LLVM_USE_FOLDERS )
 198   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 199 endif()
 200
 201 include(VersionFromVCS)
 202
 203 option(LLVM_APPEND_VC_REV
 204   "Embed the version control system revision id in LLVM" ON)
 205
 206 if( LLVM_APPEND_VC_REV )
 207   add_version_info_from_vcs(PACKAGE_VERSION)
 208 endif()
 209
 210 set(PACKAGE_NAME LLVM)
 211 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 212 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
 213
 214 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 215   "Default URL where bug reports are to be submitted.")
 216
 217 # Configure CPack.
 218 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 219 set(CPACK_PACKAGE_VENDOR "LLVM")
 220 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 221 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 222 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 223 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 224 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 225 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 226 if(WIN32 AND NOT UNIX)
 227   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 228   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 229   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 230   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 231   set(CPACK_NSIS_MODIFY_PATH "ON")
 232   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 233   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 234     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 235   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 236     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 237   if( CMAKE_CL_64 )
 238     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 239   endif()
 240 endif()
 241 include(CPack)
 242
 243 # Sanity check our source directory to make sure that we are not trying to
 244 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 245 # sure that we don't have any stray generated files lying around in the tree
 246 # (which would end up getting picked up by header search, instead of the correct
 247 # versions).
 248 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 249   message(FATAL_ERROR "In-source builds are not allowed.
 250 CMake would overwrite the makefiles distributed with LLVM.
 251 Please create a directory and run cmake from there, passing the path
 252 to this source directory as the last argument.
 253 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 254 Please delete them.")
 255 endif()
 256 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 257   file(GLOB_RECURSE
 258     tablegenned_files_on_include_dir
 259     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 260   file(GLOB_RECURSE
 261     tablegenned_files_on_lib_dir
 262     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 263   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 264     message(FATAL_ERROR "Apparently there is a previous in-source build,
 265 probably as the result of running `configure' and `make' on
 266 ${CMAKE_CURRENT_SOURCE_DIR}.
 267 This may cause problems. The suspicious files are:
 268 ${tablegenned_files_on_lib_dir}
 269 ${tablegenned_files_on_include_dir}
 270 Please clean the source directory.")
 271   endif()
 272 endif()
 273
 274 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 275
 276 if (CMAKE_BUILD_TYPE AND
 277     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 278   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 279 endif()
 280
 281 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 282
 283 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 284 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 285
 286 set(LLVM_UTILS_INSTALL_DIR "bin" CACHE STRING
 287     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 288 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 289
 290 # They are used as destination of target generators.
 291 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 292 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 293 if(WIN32 OR CYGWIN)
 294   # DLL platform -- put DLLs into bin.
 295   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 296 else()
 297   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 298 endif()
 299
 300 # Each of them corresponds to llvm-config's.
 301 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 302 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 303 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 304 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 305 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 306
 307 # Note: LLVM_CMAKE_PATH does not include generated files
 308 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 309 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 310 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 311
 312 # List of all targets to be built by default:
 313 set(LLVM_ALL_TARGETS
 314   AArch64
 315   AMDGPU
 316   ARM
 317   BPF
 318   Hexagon
 319   Lanai
 320   Mips
 321   MSP430
 322   NVPTX
 323   PowerPC
 324   Sparc
 325   SystemZ
 326   X86
 327   XCore
 328   )
 329
 330 # List of targets with JIT support:
 331 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 332
 333 set(LLVM_TARGETS_TO_BUILD "all"
 334     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 335
 336 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 337   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 338
 339 option(BUILD_SHARED_LIBS
 340   "Build all libraries as shared libraries instead of static" OFF)
 341
 342 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 343 if(LLVM_ENABLE_BACKTRACES)
 344   set(ENABLE_BACKTRACES 1)
 345 endif()
 346
 347 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 348 if(LLVM_ENABLE_CRASH_OVERRIDES)
 349   set(ENABLE_CRASH_OVERRIDES 1)
 350 endif()
 351
 352 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 353 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 354 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 355
 356 set(LLVM_TARGET_ARCH "host"
 357   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 358
 359 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 360
 361 option(LLVM_ENABLE_LIBXML2 "Use libxml2 if available." ON)
 362
 363 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 364
 365 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 366
 367 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 368
 369 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 370   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 371 endif()
 372
 373 set(LLVM_TARGETS_TO_BUILD
 374    ${LLVM_TARGETS_TO_BUILD}
 375    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 376 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 377
 378 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 379 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 380 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 381 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 382   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 383   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 384 else()
 385   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 386   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 387 endif()
 388 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 389 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 390 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 391 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 392 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 393 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 394
 395 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 396   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 397 else()
 398   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 399 endif()
 400
 401 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 402
 403 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 404   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 405
 406 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 407        "Set to ON to force using an old, unsupported host toolchain." OFF)
 408
 409 option(LLVM_USE_INTEL_JITEVENTS
 410   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 411   OFF)
 412
 413 if( LLVM_USE_INTEL_JITEVENTS )
 414   # Verify we are on a supported platform
 415   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 416     message(FATAL_ERROR
 417       "Intel JIT API support is available on Linux and Windows only.")
 418   endif()
 419 endif( LLVM_USE_INTEL_JITEVENTS )
 420
 421 option(LLVM_USE_OPROFILE
 422   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 423
 424 option(LLVM_EXTERNALIZE_DEBUGINFO
 425   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 426
 427 # If enabled, verify we are on a platform that supports oprofile.
 428 if( LLVM_USE_OPROFILE )
 429   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 430     message(FATAL_ERROR "OProfile support is available on Linux only.")
 431   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 432 endif( LLVM_USE_OPROFILE )
 433
 434 set(LLVM_USE_SANITIZER "" CACHE STRING
 435   "Define the sanitizer used to build binaries and tests.")
 436
 437 option(LLVM_USE_SPLIT_DWARF
 438   "Use -gsplit-dwarf when compiling llvm." OFF)
 439
 440 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 441 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 442
 443 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 444   set(POLLY_IN_TREE TRUE)
 445 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 446   set(POLLY_IN_TREE TRUE)
 447 else()
 448   set(POLLY_IN_TREE FALSE)
 449 endif()
 450
 451 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 452   set(WITH_POLLY ON)
 453 else()
 454   set(WITH_POLLY OFF)
 455 endif()
 456
 457 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 458   set(LINK_POLLY_INTO_TOOLS ON)
 459 else()
 460   set(LINK_POLLY_INTO_TOOLS OFF)
 461 endif()
 462
 463 # Define an option controlling whether we should build for 32-bit on 64-bit
 464 # platforms, where supported.
 465 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 466   # TODO: support other platforms and toolchains.
 467   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 468 endif()
 469
 470 # Define the default arguments to use with 'lit', and an option for the user to
 471 # override.
 472 set(LIT_ARGS_DEFAULT "-sv")
 473 if (MSVC_IDE OR XCODE)
 474   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 475 endif()
 476 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 477
 478 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 479 if( WIN32 AND NOT CYGWIN )
 480   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 481 endif()
 482
 483 # Define options to control the inclusion and default build behavior for
 484 # components which may not strictly be necessary (tools, examples, and tests).
 485 #
 486 # This is primarily to support building smaller or faster project files.
 487 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 488 option(LLVM_BUILD_TOOLS
 489   "Build the LLVM tools. If OFF, just generate build targets." ON)
 490
 491 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 492 option(LLVM_BUILD_UTILS
 493   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 494
 495 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 496 option(LLVM_BUILD_RUNTIMES
 497   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 498
 499 option(LLVM_BUILD_RUNTIME
 500   "Build the LLVM runtime libraries." ON)
 501 option(LLVM_BUILD_EXAMPLES
 502   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 503 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 504
 505 option(LLVM_BUILD_TESTS
 506   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 507 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 508 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 509
 510 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 511 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 512 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 513 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 514 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 515
 516 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 517     CACHE STRING "Doxygen-generated HTML documentation install directory")
 518 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 519     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 520
 521 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 522   "Build compiler-rt as an external project." OFF)
 523
 524 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 525   "Show target and host info when tools are invoked with --version." ON)
 526
 527 # You can configure which libraries from LLVM you want to include in the
 528 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 529 # list of LLVM components. All component names handled by llvm-config are valid.
 530 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 531   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 532     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 533 endif()
 534 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 535 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 536 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 537 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 538   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 539 endif()
 540 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 541
 542 option(LLVM_DYLIB_SYMBOL_VERSIONING OFF)
 543
 544 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 545 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 546   set(LLVM_USE_HOST_TOOLS ON)
 547 endif()
 548
 549 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 550   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 551 else()
 552   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 553 endif()
 554
 555 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE)
 556   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 557     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 558     # for spining disks. Anything higher may only help on slower mediums.
 559     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 560   endif()
 561   if(NOT LLVM_PROFILE_FILE_PATTERN)
 562     if(NOT LLVM_PROFILE_DATA_DIR)
 563       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 564     else()
 565       file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 566     endif()
 567   endif()
 568 endif()
 569
 570 if (LLVM_BUILD_STATIC)
 571   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 572 endif()
 573
 574 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 575 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 576 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 577
 578 # All options referred to from HandleLLVMOptions have to be specified
 579 # BEFORE this include, otherwise options will not be correctly set on
 580 # first cmake run
 581 include(config-ix)
 582
 583 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 584   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 585 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 586
 587 # By default, we target the host, but this can be overridden at CMake
 588 # invocation time.
 589 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 590   "Default target for which LLVM will generate code." )
 591 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 592 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 593 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 594
 595 include(HandleLLVMOptions)
 596
 597 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 598 # FIXME: We should support systems with only Python 3, but that requires work
 599 # on LLDB.
 600 set(Python_ADDITIONAL_VERSIONS 2.7)
 601 include(FindPythonInterp)
 602 if( NOT PYTHONINTERP_FOUND )
 603   message(FATAL_ERROR
 604 "Unable to find Python interpreter, required for builds and testing.
 605
 606 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 607 endif()
 608
 609 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 610   message(FATAL_ERROR "Python 2.7 or newer is required")
 611 endif()
 612
 613 ######
 614 # LLVMBuild Integration
 615 #
 616 # We use llvm-build to generate all the data required by the CMake based
 617 # build system in one swoop:
 618 #
 619 #  - We generate a file (a CMake fragment) in the object root which contains
 620 #    all the definitions that are required by CMake.
 621 #
 622 #  - We generate the library table used by llvm-config.
 623 #
 624 #  - We generate the dependencies for the CMake fragment, so that we will
 625 #    automatically reconfigure outselves.
 626
 627 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 628 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 629   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 630 set(LLVMBUILDCMAKEFRAG
 631   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 632
 633 # Create the list of optional components that are enabled
 634 if (LLVM_USE_INTEL_JITEVENTS)
 635   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 636 endif (LLVM_USE_INTEL_JITEVENTS)
 637 if (LLVM_USE_OPROFILE)
 638   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 639 endif (LLVM_USE_OPROFILE)
 640
 641 message(STATUS "Constructing LLVMBuild project information")
 642 execute_process(
 643   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 644             --native-target "${LLVM_NATIVE_ARCH}"
 645             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 646             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 647             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 648             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 649             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 650             ERROR_VARIABLE LLVMBUILDERRORS
 651             OUTPUT_STRIP_TRAILING_WHITESPACE
 652             ERROR_STRIP_TRAILING_WHITESPACE
 653   RESULT_VARIABLE LLVMBUILDRESULT)
 654
 655 # On Win32, CMake doesn't properly handle piping the default output/error
 656 # streams into the GUI console. So, we explicitly catch and report them.
 657 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 658   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 659 endif()
 660 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 661   message(FATAL_ERROR
 662     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 663 endif()
 664
 665 # Include the generated CMake fragment. This will define properties from the
 666 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 667 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 668 # files change.
 669 include(${LLVMBUILDCMAKEFRAG})
 670
 671 ######
 672
 673 # Configure all of the various header file fragments LLVM uses which depend on
 674 # configuration variables.
 675 set(LLVM_ENUM_TARGETS "")
 676 set(LLVM_ENUM_ASM_PRINTERS "")
 677 set(LLVM_ENUM_ASM_PARSERS "")
 678 set(LLVM_ENUM_DISASSEMBLERS "")
 679 foreach(t ${LLVM_TARGETS_TO_BUILD})
 680   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 681
 682   list(FIND LLVM_ALL_TARGETS ${t} idx)
 683   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 684   if( idx LESS 0 AND idy LESS 0 )
 685     message(FATAL_ERROR "The target `${t}' does not exist.
 686     It should be one of\n${LLVM_ALL_TARGETS}")
 687   else()
 688     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 689   endif()
 690
 691   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 692   if( asmp_file )
 693     set(LLVM_ENUM_ASM_PRINTERS
 694       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 695   endif()
 696   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 697     set(LLVM_ENUM_ASM_PARSERS
 698       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 699   endif()
 700   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 701     set(LLVM_ENUM_DISASSEMBLERS
 702       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 703   endif()
 704 endforeach(t)
 705
 706 # Produce the target definition files, which provide a way for clients to easily
 707 # include various classes of targets.
 708 configure_file(
 709   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 710   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 711   )
 712 configure_file(
 713   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 714   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 715   )
 716 configure_file(
 717   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 718   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 719   )
 720 configure_file(
 721   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 722   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 723   )
 724
 725 # Configure the three LLVM configuration header files.
 726 configure_file(
 727   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 728   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 729 configure_file(
 730   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 731   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 732 configure_file(
 733   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 734   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 735 configure_file(
 736   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 737   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 738
 739 # Add target for generating source rpm package.
 740 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 741     CACHE FILEPATH ".spec file to use for srpm generation")
 742 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 743 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 744
 745 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 746 # DUMMY_VAR contains a version string which we don't care about.
 747 add_version_info_from_vcs(DUMMY_VAR)
 748 if ( SVN_REVISION )
 749   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 750 elseif ( GIT_COMMIT )
 751   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 752 endif()
 753
 754 configure_file(
 755   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 756   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 757
 758 add_custom_target(srpm
 759   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 760   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 761
 762
 763 # They are not referenced. See set_output_directory().
 764 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 765 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 766 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 767
 768 if(APPLE AND DARWIN_LTO_LIBRARY)
 769   set(CMAKE_EXE_LINKER_FLAGS
 770     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 771   set(CMAKE_SHARED_LINKER_FLAGS
 772     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 773   set(CMAKE_MODULE_LINKER_FLAGS
 774     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 775 endif()
 776
 777 # Work around a broken bfd ld behavior. When linking a binary with a
 778 # foo.so library, it will try to find any library that foo.so uses and
 779 # check its symbols. This is wasteful (the check was done when foo.so
 780 # was created) and can fail since it is not the dynamic linker and
 781 # doesn't know how to handle search paths correctly.
 782 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 783   set(CMAKE_EXE_LINKER_FLAGS
 784       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 785 endif()
 786
 787 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 788
 789 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 790
 791 # when crosscompiling import the executable targets from a file
 792 if(LLVM_USE_HOST_TOOLS)
 793   include(CrossCompile)
 794 endif(LLVM_USE_HOST_TOOLS)
 795 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 796 # Dummy use to avoid CMake Wraning: Manually-specified variables were not used
 797 # (this is a variable that CrossCompile sets on recursive invocations)
 798 endif()
 799
 800 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 801   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 802   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 803   include_directories("/usr/local/include")
 804   link_directories("/usr/local/lib")
 805 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 806
 807 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 808    # special hack for Solaris to handle crazy system sys/regset.h
 809    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 810 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 811
 812 # Make sure we don't get -rdynamic in every binary. For those that need it,
 813 # use export_executable_symbols(target).
 814 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 815
 816 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 817   "Profiling data file to use when compiling in order to improve runtime performance.")
 818
 819 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 820   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 821     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 822   else()
 823     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 824   endif()
 825 endif()
 826
 827 include(AddLLVM)
 828 include(TableGen)
 829
 830 if( MINGW )
 831   # People report that -O3 is unreliable on MinGW. The traditional
 832   # build also uses -O2 for that reason:
 833   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 834 endif()
 835
 836 # Put this before tblgen. Else we have a circular dependence.
 837 add_subdirectory(lib/Demangle)
 838 add_subdirectory(lib/Support)
 839 add_subdirectory(lib/TableGen)
 840
 841 add_subdirectory(utils/TableGen)
 842
 843 add_subdirectory(include/llvm)
 844
 845 add_subdirectory(lib)
 846
 847 if( LLVM_INCLUDE_UTILS )
 848   add_subdirectory(utils/FileCheck)
 849   add_subdirectory(utils/PerfectShuffle)
 850   add_subdirectory(utils/count)
 851   add_subdirectory(utils/not)
 852   add_subdirectory(utils/llvm-lit)
 853   add_subdirectory(utils/yaml-bench)
 854 else()
 855   if ( LLVM_INCLUDE_TESTS )
 856     message(FATAL_ERROR "Including tests when not building utils will not work.
 857     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 858   endif()
 859 endif()
 860
 861 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 862 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 863   add_subdirectory(utils/LLVMVisualizers)
 864 endif()
 865
 866 foreach( binding ${LLVM_BINDINGS_LIST} )
 867   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 868     add_subdirectory(bindings/${binding})
 869   endif()
 870 endforeach()
 871
 872 add_subdirectory(projects)
 873
 874 if( LLVM_INCLUDE_TOOLS )
 875   add_subdirectory(tools)
 876 endif()
 877
 878 if( LLVM_INCLUDE_RUNTIMES )
 879   add_subdirectory(runtimes)
 880 endif()
 881
 882 if( LLVM_INCLUDE_EXAMPLES )
 883   add_subdirectory(examples)
 884 endif()
 885
 886 if( LLVM_INCLUDE_TESTS )
 887   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 888     include(LLVMExternalProjectUtils)
 889     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 890       USE_TOOLCHAIN
 891       EXCLUDE_FROM_ALL
 892       NO_INSTALL
 893       ALWAYS_CLEAN)
 894   endif()
 895   add_subdirectory(utils/lit)
 896   add_subdirectory(test)
 897   add_subdirectory(unittests)
 898   if( LLVM_INCLUDE_UTILS )
 899     add_subdirectory(utils/unittest)
 900   endif()
 901
 902   if (WIN32)
 903     # This utility is used to prevent crashing tests from calling Dr. Watson on
 904     # Windows.
 905     add_subdirectory(utils/KillTheDoctor)
 906   endif()
 907
 908   # Add a global check rule now that all subdirectories have been traversed
 909   # and we know the total set of lit testsuites.
 910   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 911   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 912   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 913   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 914   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 915                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 916   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 917                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 918   add_lit_target(check-all
 919     "Running all regression tests"
 920     ${LLVM_LIT_TESTSUITES}
 921     PARAMS ${LLVM_LIT_PARAMS}
 922     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 923     ARGS ${LLVM_LIT_EXTRA_ARGS}
 924     )
 925   if(TARGET check-runtimes)
 926     add_dependencies(check-all check-runtimes)
 927   endif()
 928   add_custom_target(test-depends
 929                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 930   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 931 endif()
 932
 933 if (LLVM_INCLUDE_DOCS)
 934   add_subdirectory(docs)
 935 endif()
 936
 937 add_subdirectory(cmake/modules)
 938
 939 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 940   install(DIRECTORY include/llvm include/llvm-c
 941     DESTINATION include
 942     COMPONENT llvm-headers
 943     FILES_MATCHING
 944     PATTERN "*.def"
 945     PATTERN "*.h"
 946     PATTERN "*.td"
 947     PATTERN "*.inc"
 948     PATTERN "LICENSE.TXT"
 949     PATTERN ".svn" EXCLUDE
 950     )
 951
 952   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 953     DESTINATION include
 954     COMPONENT llvm-headers
 955     FILES_MATCHING
 956     PATTERN "*.def"
 957     PATTERN "*.h"
 958     PATTERN "*.gen"
 959     PATTERN "*.inc"
 960     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 961     PATTERN "CMakeFiles" EXCLUDE
 962     PATTERN "config.h" EXCLUDE
 963     PATTERN ".svn" EXCLUDE
 964     )
 965
 966   # Installing the headers needs to depend on generating any public
 967   # tablegen'd headers.
 968   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 969
 970   if (NOT CMAKE_CONFIGURATION_TYPES)
 971     add_custom_target(install-llvm-headers
 972                       DEPENDS llvm-headers
 973                       COMMAND "${CMAKE_COMMAND}"
 974                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 975                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 976   endif()
 977 endif()
 978
 979 # This must be at the end of the LLVM root CMakeLists file because it must run
 980 # after all targets are created.
 981 if(LLVM_DISTRIBUTION_COMPONENTS)
 982   if(CMAKE_CONFIGURATION_TYPES)
 983     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 984   endif()
 985
 986   add_custom_target(distribution)
 987   add_custom_target(install-distribution)
 988   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS})
 989     if(TARGET ${target})
 990       add_dependencies(distribution ${target})
 991     else()
 992       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have a target")
 993     endif()
 994
 995     if(TARGET install-${target})
 996       add_dependencies(install-distribution install-${target})
 997     else()
 998       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have an install target")
 999     endif()
1000   endforeach()
1001 endif()
1002
1003 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1004 if (MSVC)
1005   include(InstallRequiredSystemLibraries)
1006 endif()