CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 cmake_policy(SET CMP0022 NEW)
   6
   7 cmake_policy(SET CMP0048 NEW)
   8
   9 # CMake 3.1 and higher include generator expressions of the form
  10 # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  11 # stripped everywhere that access the SOURCES property, so we just
  12 # defer to the OLD behavior of not including generator expressions
  13 # in the output for now.
  14 cmake_policy(SET CMP0051 OLD)
  15
  16 cmake_policy(SET CMP0056 NEW)
  17
  18 cmake_policy(SET CMP0057 NEW)
  19
  20 if(POLICY CMP0068)
  21   cmake_policy(SET CMP0068 NEW)
  22   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
  23 endif()
  24
  25 if(NOT DEFINED LLVM_VERSION_MAJOR)
  26   set(LLVM_VERSION_MAJOR 7)
  27 endif()
  28 if(NOT DEFINED LLVM_VERSION_MINOR)
  29   set(LLVM_VERSION_MINOR 0)
  30 endif()
  31 if(NOT DEFINED LLVM_VERSION_PATCH)
  32   set(LLVM_VERSION_PATCH 0)
  33 endif()
  34 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  35   set(LLVM_VERSION_SUFFIX svn)
  36 endif()
  37
  38 if (NOT PACKAGE_VERSION)
  39   set(PACKAGE_VERSION
  40     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  41 endif()
  42
  43 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  44   message(WARNING "Visual Studio generators use the x86 host compiler by "
  45                   "default, even for 64-bit targets. This can result in linker "
  46                   "instability and out of memory errors. To use the 64-bit "
  47                   "host compiler, pass -Thost=x64 on the CMake command line.")
  48 endif()
  49
  50 project(LLVM
  51   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  52   LANGUAGES C CXX ASM)
  53
  54 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  55   message(STATUS "No build type selected, default to Debug")
  56   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  57 endif()
  58
  59 # This should only apply if you are both on an Apple host, and targeting Apple.
  60 if(CMAKE_HOST_APPLE AND APPLE)
  61   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  62   if(NOT CMAKE_LIBTOOL)
  63     if(NOT CMAKE_XCRUN)
  64       find_program(CMAKE_XCRUN NAMES xcrun)
  65     endif()
  66     if(CMAKE_XCRUN)
  67       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  68         OUTPUT_VARIABLE CMAKE_LIBTOOL
  69         OUTPUT_STRIP_TRAILING_WHITESPACE)
  70     endif()
  71
  72     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  73       find_program(CMAKE_LIBTOOL NAMES libtool)
  74     endif()
  75   endif()
  76
  77   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  78   if(CMAKE_LIBTOOL)
  79     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  80     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  81
  82     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  83       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  84       OUTPUT_STRIP_TRAILING_WHITESPACE)
  85     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  86       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  87         ${LIBTOOL_V_OUTPUT})
  88       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  89         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  90       endif()
  91     endif()
  92
  93     foreach(lang ${languages})
  94       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  95         "\"${CMAKE_LIBTOOL}\" -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  96         <LINK_FLAGS> <OBJECTS> ")
  97     endforeach()
  98   endif()
  99
 100   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
 101   if(DYLD_LIBRARY_PATH)
 102     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
 103     foreach(lang ${languages})
 104       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 105         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
 106              "${dyld_envar} ${cmd}")
 107       endforeach()
 108       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 109         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 110     endforeach()
 111   endif()
 112 endif()
 113
 114 # Side-by-side subprojects layout: automatically set the
 115 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 116 # This allows an easy way of setting up a build directory for llvm and another
 117 # one for llvm+clang+... using the same sources.
 118 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly;debuginfo-tests")
 119 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 120         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 121 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 122   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 123 endif()
 124 foreach(proj ${LLVM_ENABLE_PROJECTS})
 125   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 126   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 127     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 128   endif()
 129   string(TOUPPER "${proj}" upper_proj)
 130   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 131   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 132   # There is a widely spread opinion that clang-tools-extra should be merged
 133   # into clang. The following simulates it by always enabling clang-tools-extra
 134   # when enabling clang.
 135   if (proj STREQUAL "clang")
 136     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 137   endif()
 138 endforeach()
 139
 140 # Build llvm with ccache if the package is present
 141 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 142 if(LLVM_CCACHE_BUILD)
 143   find_program(CCACHE_PROGRAM ccache)
 144   if(CCACHE_PROGRAM)
 145       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 146       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 147       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 148           CACHE STRING "Parameters to pass through to ccache")
 149
 150       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 151       if (LLVM_CCACHE_MAXSIZE)
 152         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 153       endif()
 154       if (LLVM_CCACHE_DIR)
 155         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 156       endif()
 157       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 158   else()
 159     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 160   endif()
 161 endif()
 162
 163 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 164
 165 # Some features of the LLVM build may be disallowed when dependency debugging is
 166 # enabled. In particular you cannot use ccache because we want to force compile
 167 # operations to always happen.
 168 if(LLVM_DEPENDENCY_DEBUGGING)
 169   if(NOT CMAKE_HOST_APPLE)
 170     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 171   endif()
 172   if(LLVM_CCACHE_BUILD)
 173     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 174   endif()
 175 endif()
 176
 177 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 178 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 179 if(LLVM_ENABLE_GISEL_COV)
 180   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 181 endif()
 182
 183 # Add path for custom modules
 184 set(CMAKE_MODULE_PATH
 185   ${CMAKE_MODULE_PATH}
 186   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 187   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 188   )
 189
 190 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 191 # for use by clang_complete, YouCompleteMe, etc.
 192 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 193
 194 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 195   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 196
 197 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 198
 199 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 200
 201 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 202 if ( LLVM_USE_FOLDERS )
 203   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 204 endif()
 205
 206 include(VersionFromVCS)
 207
 208 option(LLVM_APPEND_VC_REV
 209   "Embed the version control system revision id in LLVM" ON)
 210
 211 set(PACKAGE_NAME LLVM)
 212 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 213 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 214
 215 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 216   "Default URL where bug reports are to be submitted.")
 217
 218 # Configure CPack.
 219 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 220 set(CPACK_PACKAGE_VENDOR "LLVM")
 221 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 222 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 223 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 224 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 225 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 226 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 227 if(WIN32 AND NOT UNIX)
 228   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 229   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 230   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 231   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 232   set(CPACK_NSIS_MODIFY_PATH "ON")
 233   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 234   if( CMAKE_CL_64 )
 235     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 236   endif()
 237 endif()
 238 include(CPack)
 239
 240 # Sanity check our source directory to make sure that we are not trying to
 241 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 242 # sure that we don't have any stray generated files lying around in the tree
 243 # (which would end up getting picked up by header search, instead of the correct
 244 # versions).
 245 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 246   message(FATAL_ERROR "In-source builds are not allowed.
 247 CMake would overwrite the makefiles distributed with LLVM.
 248 Please create a directory and run cmake from there, passing the path
 249 to this source directory as the last argument.
 250 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 251 Please delete them.")
 252 endif()
 253 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 254   file(GLOB_RECURSE
 255     tablegenned_files_on_include_dir
 256     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 257   file(GLOB_RECURSE
 258     tablegenned_files_on_lib_dir
 259     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 260   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 261     message(FATAL_ERROR "Apparently there is a previous in-source build,
 262 probably as the result of running `configure' and `make' on
 263 ${CMAKE_CURRENT_SOURCE_DIR}.
 264 This may cause problems. The suspicious files are:
 265 ${tablegenned_files_on_lib_dir}
 266 ${tablegenned_files_on_include_dir}
 267 Please clean the source directory.")
 268   endif()
 269 endif()
 270
 271 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 272
 273 if (CMAKE_BUILD_TYPE AND
 274     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 275   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 276 endif()
 277
 278 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 279
 280 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 281 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 282
 283 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 284     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 285 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 286
 287 # They are used as destination of target generators.
 288 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 289 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 290 if(WIN32 OR CYGWIN)
 291   # DLL platform -- put DLLs into bin.
 292   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 293 else()
 294   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 295 endif()
 296
 297 # Each of them corresponds to llvm-config's.
 298 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 299 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 300 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 301 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 302 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 303
 304 # Note: LLVM_CMAKE_PATH does not include generated files
 305 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 306 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 307 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 308
 309 # List of all targets to be built by default:
 310 set(LLVM_ALL_TARGETS
 311   AArch64
 312   AMDGPU
 313   ARM
 314   BPF
 315   Hexagon
 316   Lanai
 317   Mips
 318   MSP430
 319   NVPTX
 320   PowerPC
 321   Sparc
 322   SystemZ
 323   X86
 324   XCore
 325   )
 326
 327 # List of targets with JIT support:
 328 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 329
 330 set(LLVM_TARGETS_TO_BUILD "all"
 331     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 332
 333 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 334   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 335
 336 option(BUILD_SHARED_LIBS
 337   "Build all libraries as shared libraries instead of static" OFF)
 338
 339 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 340 if(LLVM_ENABLE_BACKTRACES)
 341   set(ENABLE_BACKTRACES 1)
 342 endif()
 343
 344 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 345 if(LLVM_ENABLE_CRASH_OVERRIDES)
 346   set(ENABLE_CRASH_OVERRIDES 1)
 347 endif()
 348
 349 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 350 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 351 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 352
 353 set(LLVM_TARGET_ARCH "host"
 354   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 355
 356 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 357
 358 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 359
 360 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 361
 362 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 363
 364 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 365
 366 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 367
 368 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 369   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 370 endif()
 371
 372 set(LLVM_TARGETS_TO_BUILD
 373    ${LLVM_TARGETS_TO_BUILD}
 374    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 375 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 376
 377 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 378 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 379 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 380 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 381   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 382   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 383 else()
 384   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 385   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 386 endif()
 387 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 388 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 389 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 390 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 391 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 392 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 393
 394 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 395
 396 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 397   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 398 else()
 399   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 400 endif()
 401
 402 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 403
 404 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 405   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 406
 407 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 408        "Set to ON to force using an old, unsupported host toolchain." OFF)
 409
 410 option(LLVM_USE_INTEL_JITEVENTS
 411   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 412   OFF)
 413
 414 if( LLVM_USE_INTEL_JITEVENTS )
 415   # Verify we are on a supported platform
 416   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 417     message(FATAL_ERROR
 418       "Intel JIT API support is available on Linux and Windows only.")
 419   endif()
 420 endif( LLVM_USE_INTEL_JITEVENTS )
 421
 422 option(LLVM_USE_OPROFILE
 423   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 424
 425 option(LLVM_EXTERNALIZE_DEBUGINFO
 426   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 427
 428 option(LLVM_CODESIGNING_IDENTITY
 429   "Sign executables and dylibs with the given identity (Darwin Only)" OFF)
 430
 431 # If enabled, verify we are on a platform that supports oprofile.
 432 if( LLVM_USE_OPROFILE )
 433   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 434     message(FATAL_ERROR "OProfile support is available on Linux only.")
 435   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 436 endif( LLVM_USE_OPROFILE )
 437
 438 set(LLVM_USE_SANITIZER "" CACHE STRING
 439   "Define the sanitizer used to build binaries and tests.")
 440 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 441 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 442   "Path to fuzzing library for linking with fuzz targets")
 443
 444 option(LLVM_USE_SPLIT_DWARF
 445   "Use -gsplit-dwarf when compiling llvm." OFF)
 446
 447 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 448 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 449
 450 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 451   set(POLLY_IN_TREE TRUE)
 452 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 453   set(POLLY_IN_TREE TRUE)
 454 else()
 455   set(POLLY_IN_TREE FALSE)
 456 endif()
 457
 458 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 459   set(WITH_POLLY ON)
 460 else()
 461   set(WITH_POLLY OFF)
 462 endif()
 463
 464 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 465   set(LINK_POLLY_INTO_TOOLS ON)
 466 else()
 467   set(LINK_POLLY_INTO_TOOLS OFF)
 468 endif()
 469
 470 # Define an option controlling whether we should build for 32-bit on 64-bit
 471 # platforms, where supported.
 472 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 473   # TODO: support other platforms and toolchains.
 474   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 475 endif()
 476
 477 # Define the default arguments to use with 'lit', and an option for the user to
 478 # override.
 479 set(LIT_ARGS_DEFAULT "-sv")
 480 if (MSVC_IDE OR XCODE)
 481   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 482 endif()
 483 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 484
 485 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 486 if( WIN32 AND NOT CYGWIN )
 487   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 488 endif()
 489
 490 # Define options to control the inclusion and default build behavior for
 491 # components which may not strictly be necessary (tools, examples, and tests).
 492 #
 493 # This is primarily to support building smaller or faster project files.
 494 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 495 option(LLVM_BUILD_TOOLS
 496   "Build the LLVM tools. If OFF, just generate build targets." ON)
 497
 498 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 499 option(LLVM_BUILD_UTILS
 500   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 501
 502 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 503 option(LLVM_BUILD_RUNTIMES
 504   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 505
 506 option(LLVM_BUILD_RUNTIME
 507   "Build the LLVM runtime libraries." ON)
 508 option(LLVM_BUILD_EXAMPLES
 509   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 510 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 511
 512 option(LLVM_BUILD_TESTS
 513   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 514 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 515 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 516
 517 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 518 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 519 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 520 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 521 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 522 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 523
 524 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 525     CACHE STRING "Doxygen-generated HTML documentation install directory")
 526 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 527     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 528
 529 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 530   "Build compiler-rt as an external project." OFF)
 531
 532 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 533   "Show target and host info when tools are invoked with --version." ON)
 534
 535 # You can configure which libraries from LLVM you want to include in the
 536 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 537 # list of LLVM components. All component names handled by llvm-config are valid.
 538 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 539   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 540     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 541 endif()
 542 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 543 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 544 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 545 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 546   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 547 endif()
 548 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 549
 550 option(LLVM_DYLIB_SYMBOL_VERSIONING OFF)
 551
 552 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 553 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 554   set(LLVM_USE_HOST_TOOLS ON)
 555 endif()
 556
 557 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 558   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 559 else()
 560   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 561 endif()
 562
 563 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 564     LLVM_ENABLE_IR_PGO)
 565   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 566     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 567     # for spining disks. Anything higher may only help on slower mediums.
 568     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 569   endif()
 570   if(NOT LLVM_PROFILE_FILE_PATTERN)
 571     if(NOT LLVM_PROFILE_DATA_DIR)
 572       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 573     endif()
 574                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 575   endif()
 576 endif()
 577
 578 if (LLVM_BUILD_STATIC)
 579   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 580 endif()
 581
 582 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 583 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 584 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 585
 586 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 587   "Enable per-target runtimes directory")
 588
 589 # All options referred to from HandleLLVMOptions have to be specified
 590 # BEFORE this include, otherwise options will not be correctly set on
 591 # first cmake run
 592 include(config-ix)
 593
 594 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 595   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 596 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 597
 598 # By default, we target the host, but this can be overridden at CMake
 599 # invocation time.
 600 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 601   "Default target for which LLVM will generate code." )
 602 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 603 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 604 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 605
 606 include(HandleLLVMOptions)
 607
 608 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 609 # FIXME: We should support systems with only Python 3, but that requires work
 610 # on LLDB.
 611 set(Python_ADDITIONAL_VERSIONS 2.7)
 612 include(FindPythonInterp)
 613 if( NOT PYTHONINTERP_FOUND )
 614   message(FATAL_ERROR
 615 "Unable to find Python interpreter, required for builds and testing.
 616
 617 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 618 endif()
 619
 620 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 621   message(FATAL_ERROR "Python 2.7 or newer is required")
 622 endif()
 623
 624 ######
 625 # LLVMBuild Integration
 626 #
 627 # We use llvm-build to generate all the data required by the CMake based
 628 # build system in one swoop:
 629 #
 630 #  - We generate a file (a CMake fragment) in the object root which contains
 631 #    all the definitions that are required by CMake.
 632 #
 633 #  - We generate the library table used by llvm-config.
 634 #
 635 #  - We generate the dependencies for the CMake fragment, so that we will
 636 #    automatically reconfigure outselves.
 637
 638 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 639 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 640   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 641 set(LLVMBUILDCMAKEFRAG
 642   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 643
 644 # Create the list of optional components that are enabled
 645 if (LLVM_USE_INTEL_JITEVENTS)
 646   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 647 endif (LLVM_USE_INTEL_JITEVENTS)
 648 if (LLVM_USE_OPROFILE)
 649   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 650 endif (LLVM_USE_OPROFILE)
 651
 652 message(STATUS "Constructing LLVMBuild project information")
 653 execute_process(
 654   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 655             --native-target "${LLVM_NATIVE_ARCH}"
 656             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 657             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 658             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 659             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 660             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 661             ERROR_VARIABLE LLVMBUILDERRORS
 662             OUTPUT_STRIP_TRAILING_WHITESPACE
 663             ERROR_STRIP_TRAILING_WHITESPACE
 664   RESULT_VARIABLE LLVMBUILDRESULT)
 665
 666 # On Win32, CMake doesn't properly handle piping the default output/error
 667 # streams into the GUI console. So, we explicitly catch and report them.
 668 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 669   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 670 endif()
 671 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 672   message(FATAL_ERROR
 673     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 674 endif()
 675
 676 # Include the generated CMake fragment. This will define properties from the
 677 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 678 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 679 # files change.
 680 include(${LLVMBUILDCMAKEFRAG})
 681
 682 ######
 683
 684 # Configure all of the various header file fragments LLVM uses which depend on
 685 # configuration variables.
 686 set(LLVM_ENUM_TARGETS "")
 687 set(LLVM_ENUM_ASM_PRINTERS "")
 688 set(LLVM_ENUM_ASM_PARSERS "")
 689 set(LLVM_ENUM_DISASSEMBLERS "")
 690 foreach(t ${LLVM_TARGETS_TO_BUILD})
 691   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 692
 693   list(FIND LLVM_ALL_TARGETS ${t} idx)
 694   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 695   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 696   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 697   # this test just makes sure that any experimental targets were passed via
 698   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 699   if( idx LESS 0 AND idy LESS 0 )
 700     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 701       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 702   else()
 703     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 704   endif()
 705
 706   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 707   if( asmp_file )
 708     set(LLVM_ENUM_ASM_PRINTERS
 709       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 710   endif()
 711   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 712     set(LLVM_ENUM_ASM_PARSERS
 713       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 714   endif()
 715   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 716     set(LLVM_ENUM_DISASSEMBLERS
 717       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 718   endif()
 719 endforeach(t)
 720
 721 # Produce the target definition files, which provide a way for clients to easily
 722 # include various classes of targets.
 723 configure_file(
 724   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 725   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 726   )
 727 configure_file(
 728   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 729   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 730   )
 731 configure_file(
 732   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 733   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 734   )
 735 configure_file(
 736   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 737   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 738   )
 739
 740 # Configure the three LLVM configuration header files.
 741 configure_file(
 742   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 743   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 744 configure_file(
 745   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 746   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 747 configure_file(
 748   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 749   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 750
 751 # Add target for generating source rpm package.
 752 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 753     CACHE FILEPATH ".spec file to use for srpm generation")
 754 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 755 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 756
 757 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 758 # DUMMY_VAR contains a version string which we don't care about.
 759 add_version_info_from_vcs(DUMMY_VAR)
 760 if ( SVN_REVISION )
 761   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 762 elseif ( GIT_COMMIT )
 763   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 764 endif()
 765
 766 configure_file(
 767   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 768   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 769
 770 add_custom_target(srpm
 771   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 772   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 773 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 774
 775
 776 # They are not referenced. See set_output_directory().
 777 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 778 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 779 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 780
 781 if(APPLE AND DARWIN_LTO_LIBRARY)
 782   set(CMAKE_EXE_LINKER_FLAGS
 783     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 784   set(CMAKE_SHARED_LINKER_FLAGS
 785     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 786   set(CMAKE_MODULE_LINKER_FLAGS
 787     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 788 endif()
 789
 790 # Work around a broken bfd ld behavior. When linking a binary with a
 791 # foo.so library, it will try to find any library that foo.so uses and
 792 # check its symbols. This is wasteful (the check was done when foo.so
 793 # was created) and can fail since it is not the dynamic linker and
 794 # doesn't know how to handle search paths correctly.
 795 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 796   set(CMAKE_EXE_LINKER_FLAGS
 797       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 798 endif()
 799
 800 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 801
 802 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 803
 804 # when crosscompiling import the executable targets from a file
 805 if(LLVM_USE_HOST_TOOLS)
 806   include(CrossCompile)
 807 endif(LLVM_USE_HOST_TOOLS)
 808 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 809 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 810 # (this is a variable that CrossCompile sets on recursive invocations)
 811 endif()
 812
 813 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 814   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 815   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 816   include_directories(SYSTEM "/usr/local/include")
 817   link_directories("/usr/local/lib")
 818 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 819
 820 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 821    # special hack for Solaris to handle crazy system sys/regset.h
 822    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 823 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 824
 825 # Make sure we don't get -rdynamic in every binary. For those that need it,
 826 # use export_executable_symbols(target).
 827 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 828
 829 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 830   "Profiling data file to use when compiling in order to improve runtime performance.")
 831
 832 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 833   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 834     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 835   else()
 836     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 837   endif()
 838 endif()
 839
 840 include(AddLLVM)
 841 include(TableGen)
 842
 843 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 844   # People report that -O3 is unreliable on MinGW. The traditional
 845   # build also uses -O2 for that reason:
 846   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 847 endif()
 848
 849 # Put this before tblgen. Else we have a circular dependence.
 850 add_subdirectory(lib/Demangle)
 851 add_subdirectory(lib/Support)
 852 add_subdirectory(lib/TableGen)
 853
 854 add_subdirectory(utils/TableGen)
 855
 856 add_subdirectory(include/llvm)
 857
 858 add_subdirectory(lib)
 859
 860 if( LLVM_INCLUDE_UTILS )
 861   add_subdirectory(utils/FileCheck)
 862   add_subdirectory(utils/PerfectShuffle)
 863   add_subdirectory(utils/count)
 864   add_subdirectory(utils/not)
 865   add_subdirectory(utils/yaml-bench)
 866 else()
 867   if ( LLVM_INCLUDE_TESTS )
 868     message(FATAL_ERROR "Including tests when not building utils will not work.
 869     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 870   endif()
 871 endif()
 872
 873 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 874 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 875   add_subdirectory(utils/LLVMVisualizers)
 876 endif()
 877
 878 foreach( binding ${LLVM_BINDINGS_LIST} )
 879   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 880     add_subdirectory(bindings/${binding})
 881   endif()
 882 endforeach()
 883
 884 add_subdirectory(projects)
 885
 886 if( LLVM_INCLUDE_TOOLS )
 887   add_subdirectory(tools)
 888 endif()
 889
 890 if( LLVM_INCLUDE_RUNTIMES )
 891   add_subdirectory(runtimes)
 892 endif()
 893
 894 if( LLVM_INCLUDE_EXAMPLES )
 895   add_subdirectory(examples)
 896 endif()
 897
 898 if( LLVM_INCLUDE_TESTS )
 899   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 900     include(LLVMExternalProjectUtils)
 901     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 902       USE_TOOLCHAIN
 903       EXCLUDE_FROM_ALL
 904       NO_INSTALL
 905       ALWAYS_CLEAN)
 906   endif()
 907   add_subdirectory(utils/lit)
 908   add_subdirectory(test)
 909   add_subdirectory(unittests)
 910   if( LLVM_INCLUDE_UTILS )
 911     add_subdirectory(utils/unittest)
 912   endif()
 913
 914   if (WIN32)
 915     # This utility is used to prevent crashing tests from calling Dr. Watson on
 916     # Windows.
 917     add_subdirectory(utils/KillTheDoctor)
 918   endif()
 919
 920   # Add a global check rule now that all subdirectories have been traversed
 921   # and we know the total set of lit testsuites.
 922   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 923   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 924   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 925   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 926   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 927                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 928   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 929                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 930   add_lit_target(check-all
 931     "Running all regression tests"
 932     ${LLVM_LIT_TESTSUITES}
 933     PARAMS ${LLVM_LIT_PARAMS}
 934     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 935     ARGS ${LLVM_LIT_EXTRA_ARGS}
 936     )
 937   if(TARGET check-runtimes)
 938     add_dependencies(check-all check-runtimes)
 939   endif()
 940   add_custom_target(test-depends
 941                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 942   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 943 endif()
 944
 945 if (LLVM_INCLUDE_DOCS)
 946   add_subdirectory(docs)
 947 endif()
 948
 949 add_subdirectory(cmake/modules)
 950
 951 # Do this last so that all lit targets have already been created.
 952 if (LLVM_INCLUDE_UTILS)
 953   add_subdirectory(utils/llvm-lit)
 954 endif()
 955
 956 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 957   install(DIRECTORY include/llvm include/llvm-c
 958     DESTINATION include
 959     COMPONENT llvm-headers
 960     FILES_MATCHING
 961     PATTERN "*.def"
 962     PATTERN "*.h"
 963     PATTERN "*.td"
 964     PATTERN "*.inc"
 965     PATTERN "LICENSE.TXT"
 966     PATTERN ".svn" EXCLUDE
 967     )
 968
 969   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
 970     DESTINATION include
 971     COMPONENT llvm-headers
 972     FILES_MATCHING
 973     PATTERN "*.def"
 974     PATTERN "*.h"
 975     PATTERN "*.gen"
 976     PATTERN "*.inc"
 977     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 978     PATTERN "CMakeFiles" EXCLUDE
 979     PATTERN "config.h" EXCLUDE
 980     PATTERN ".svn" EXCLUDE
 981     )
 982
 983   # Installing the headers needs to depend on generating any public
 984   # tablegen'd headers.
 985   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 986   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
 987
 988   if (NOT CMAKE_CONFIGURATION_TYPES)
 989     add_llvm_install_targets(install-llvm-headers
 990                              DEPENDS llvm-headers
 991                              COMPONENT llvm-headers)
 992   endif()
 993 endif()
 994
 995 # This must be at the end of the LLVM root CMakeLists file because it must run
 996 # after all targets are created.
 997 if(LLVM_DISTRIBUTION_COMPONENTS)
 998   if(CMAKE_CONFIGURATION_TYPES)
 999     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
1000   endif()
1001
1002   add_custom_target(distribution)
1003   add_custom_target(install-distribution)
1004   add_custom_target(install-distribution-stripped)
1005   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS} ${LLVM_RUNTIME_DISTRIBUTION_COMPONENTS})
1006     if(TARGET ${target})
1007       add_dependencies(distribution ${target})
1008     else()
1009       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1010     endif()
1011
1012     if(TARGET install-${target})
1013       add_dependencies(install-distribution install-${target})
1014     else()
1015       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1016     endif()
1017
1018     if(TARGET install-${target}-stripped)
1019       add_dependencies(install-distribution-stripped install-${target}-stripped)
1020     else()
1021       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1022                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1023                          " or you should manually create the 'install-${target}-stripped' target.")
1024     endif()
1025   endforeach()
1026 endif()
1027
1028 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1029 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows")
1030   include(InstallRequiredSystemLibraries)
1031 endif()