CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 cmake_policy(SET CMP0022 NEW)
   6
   7 cmake_policy(SET CMP0048 NEW)
   8
   9 # CMake 3.1 and higher include generator expressions of the form
  10 # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  11 # stripped everywhere that access the SOURCES property, so we just
  12 # defer to the OLD behavior of not including generator expressions
  13 # in the output for now.
  14 cmake_policy(SET CMP0051 OLD)
  15
  16 cmake_policy(SET CMP0056 NEW)
  17
  18 cmake_policy(SET CMP0057 NEW)
  19
  20 if(POLICY CMP0068)
  21   cmake_policy(SET CMP0068 NEW)
  22   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
  23 endif()
  24
  25 if(NOT DEFINED LLVM_VERSION_MAJOR)
  26   set(LLVM_VERSION_MAJOR 7)
  27 endif()
  28 if(NOT DEFINED LLVM_VERSION_MINOR)
  29   set(LLVM_VERSION_MINOR 0)
  30 endif()
  31 if(NOT DEFINED LLVM_VERSION_PATCH)
  32   set(LLVM_VERSION_PATCH 0)
  33 endif()
  34 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  35   set(LLVM_VERSION_SUFFIX svn)
  36 endif()
  37
  38 if (NOT PACKAGE_VERSION)
  39   set(PACKAGE_VERSION
  40     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  41 endif()
  42
  43 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  44   message(WARNING "Visual Studio generators use the x86 host compiler by "
  45                   "default, even for 64-bit targets. This can result in linker "
  46                   "instability and out of memory errors. To use the 64-bit "
  47                   "host compiler, pass -Thost=x64 on the CMake command line.")
  48 endif()
  49
  50 project(LLVM
  51   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  52   LANGUAGES C CXX ASM)
  53
  54 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  55   message(STATUS "No build type selected, default to Debug")
  56   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  57 endif()
  58
  59 # This should only apply if you are both on an Apple host, and targeting Apple.
  60 if(CMAKE_HOST_APPLE AND APPLE)
  61   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  62   if(NOT CMAKE_LIBTOOL)
  63     if(NOT CMAKE_XCRUN)
  64       find_program(CMAKE_XCRUN NAMES xcrun)
  65     endif()
  66     if(CMAKE_XCRUN)
  67       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  68         OUTPUT_VARIABLE CMAKE_LIBTOOL
  69         OUTPUT_STRIP_TRAILING_WHITESPACE)
  70     endif()
  71
  72     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  73       find_program(CMAKE_LIBTOOL NAMES libtool)
  74     endif()
  75   endif()
  76
  77   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  78   if(CMAKE_LIBTOOL)
  79     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  80     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  81
  82     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  83       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  84       OUTPUT_STRIP_TRAILING_WHITESPACE)
  85     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  86       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  87         ${LIBTOOL_V_OUTPUT})
  88       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  89         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  90       endif()
  91     endif()
  92
  93     foreach(lang ${languages})
  94       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  95         "${CMAKE_LIBTOOL} -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  96         <LINK_FLAGS> <OBJECTS> ")
  97     endforeach()
  98   endif()
  99
 100   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
 101   if(DYLD_LIBRARY_PATH)
 102     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
 103     foreach(lang ${languages})
 104       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 105         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
 106              "${dyld_envar} ${cmd}")
 107       endforeach()
 108       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 109         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 110     endforeach()
 111   endif()
 112 endif()
 113
 114 # Side-by-side subprojects layout: automatically set the
 115 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 116 # This allows an easy way of setting up a build directory for llvm and another
 117 # one for llvm+clang+... using the same sources.
 118 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly;debuginfo-tests")
 119 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 120         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 121 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 122   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 123 endif()
 124 foreach(proj ${LLVM_ENABLE_PROJECTS})
 125   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 126   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 127     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 128   endif()
 129   string(TOUPPER "${proj}" upper_proj)
 130   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 131   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 132   # There is a widely spread opinion that clang-tools-extra should be merged
 133   # into clang. The following simulates it by always enabling clang-tools-extra
 134   # when enabling clang.
 135   if (proj STREQUAL "clang")
 136     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 137   endif()
 138 endforeach()
 139
 140 # Build llvm with ccache if the package is present
 141 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 142 if(LLVM_CCACHE_BUILD)
 143   find_program(CCACHE_PROGRAM ccache)
 144   if(CCACHE_PROGRAM)
 145       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 146       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 147       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 148           CACHE STRING "Parameters to pass through to ccache")
 149
 150       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 151       if (LLVM_CCACHE_MAXSIZE)
 152         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 153       endif()
 154       if (LLVM_CCACHE_DIR)
 155         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 156       endif()
 157       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 158   else()
 159     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 160   endif()
 161 endif()
 162
 163 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 164
 165 # Some features of the LLVM build may be disallowed when dependency debugging is
 166 # enabled. In particular you cannot use ccache because we want to force compile
 167 # operations to always happen.
 168 if(LLVM_DEPENDENCY_DEBUGGING)
 169   if(NOT CMAKE_HOST_APPLE)
 170     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 171   endif()
 172   if(LLVM_CCACHE_BUILD)
 173     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 174   endif()
 175 endif()
 176
 177 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 178 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 179 if(LLVM_ENABLE_GISEL_COV)
 180   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 181 endif()
 182
 183 # Add path for custom modules
 184 set(CMAKE_MODULE_PATH
 185   ${CMAKE_MODULE_PATH}
 186   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 187   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 188   )
 189
 190 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 191 # for use by clang_complete, YouCompleteMe, etc.
 192 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 193
 194 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 195   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 196
 197 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 198
 199 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 200
 201 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 202 if ( LLVM_USE_FOLDERS )
 203   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 204 endif()
 205
 206 include(VersionFromVCS)
 207
 208 option(LLVM_APPEND_VC_REV
 209   "Embed the version control system revision id in LLVM" ON)
 210
 211 set(PACKAGE_NAME LLVM)
 212 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 213 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 214
 215 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 216   "Default URL where bug reports are to be submitted.")
 217
 218 # Configure CPack.
 219 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 220 set(CPACK_PACKAGE_VENDOR "LLVM")
 221 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 222 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 223 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 224 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 225 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 226 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 227 if(WIN32 AND NOT UNIX)
 228   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 229   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 230   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 231   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 232   set(CPACK_NSIS_MODIFY_PATH "ON")
 233   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 234   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 235     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 236   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 237     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 238   if( CMAKE_CL_64 )
 239     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 240   endif()
 241 endif()
 242 include(CPack)
 243
 244 # Sanity check our source directory to make sure that we are not trying to
 245 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 246 # sure that we don't have any stray generated files lying around in the tree
 247 # (which would end up getting picked up by header search, instead of the correct
 248 # versions).
 249 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 250   message(FATAL_ERROR "In-source builds are not allowed.
 251 CMake would overwrite the makefiles distributed with LLVM.
 252 Please create a directory and run cmake from there, passing the path
 253 to this source directory as the last argument.
 254 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 255 Please delete them.")
 256 endif()
 257 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 258   file(GLOB_RECURSE
 259     tablegenned_files_on_include_dir
 260     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 261   file(GLOB_RECURSE
 262     tablegenned_files_on_lib_dir
 263     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 264   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 265     message(FATAL_ERROR "Apparently there is a previous in-source build,
 266 probably as the result of running `configure' and `make' on
 267 ${CMAKE_CURRENT_SOURCE_DIR}.
 268 This may cause problems. The suspicious files are:
 269 ${tablegenned_files_on_lib_dir}
 270 ${tablegenned_files_on_include_dir}
 271 Please clean the source directory.")
 272   endif()
 273 endif()
 274
 275 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 276
 277 if (CMAKE_BUILD_TYPE AND
 278     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 279   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 280 endif()
 281
 282 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 283
 284 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 285 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 286
 287 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 288     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 289 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 290
 291 # They are used as destination of target generators.
 292 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 293 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 294 if(WIN32 OR CYGWIN)
 295   # DLL platform -- put DLLs into bin.
 296   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 297 else()
 298   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 299 endif()
 300
 301 # Each of them corresponds to llvm-config's.
 302 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 303 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 304 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 305 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 306 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 307
 308 # Note: LLVM_CMAKE_PATH does not include generated files
 309 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 310 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 311 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 312
 313 # List of all targets to be built by default:
 314 set(LLVM_ALL_TARGETS
 315   AArch64
 316   AMDGPU
 317   ARM
 318   BPF
 319   Hexagon
 320   Lanai
 321   Mips
 322   MSP430
 323   NVPTX
 324   PowerPC
 325   Sparc
 326   SystemZ
 327   X86
 328   XCore
 329   )
 330
 331 # List of targets with JIT support:
 332 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 333
 334 set(LLVM_TARGETS_TO_BUILD "all"
 335     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 336
 337 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 338   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 339
 340 option(BUILD_SHARED_LIBS
 341   "Build all libraries as shared libraries instead of static" OFF)
 342
 343 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 344 if(LLVM_ENABLE_BACKTRACES)
 345   set(ENABLE_BACKTRACES 1)
 346 endif()
 347
 348 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 349 if(LLVM_ENABLE_CRASH_OVERRIDES)
 350   set(ENABLE_CRASH_OVERRIDES 1)
 351 endif()
 352
 353 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 354 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 355 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 356
 357 set(LLVM_TARGET_ARCH "host"
 358   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 359
 360 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 361
 362 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 363
 364 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 365
 366 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 367
 368 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 369
 370 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 371   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 372 endif()
 373
 374 set(LLVM_TARGETS_TO_BUILD
 375    ${LLVM_TARGETS_TO_BUILD}
 376    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 377 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 378
 379 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 380 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 381 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 382 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 383   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 384   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 385 else()
 386   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 387   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 388 endif()
 389 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 390 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 391 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 392 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 393 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 394 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 395
 396 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 397
 398 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 399   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 400 else()
 401   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 402 endif()
 403
 404 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 405
 406 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 407   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 408
 409 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 410        "Set to ON to force using an old, unsupported host toolchain." OFF)
 411
 412 option(LLVM_USE_INTEL_JITEVENTS
 413   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 414   OFF)
 415
 416 if( LLVM_USE_INTEL_JITEVENTS )
 417   # Verify we are on a supported platform
 418   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 419     message(FATAL_ERROR
 420       "Intel JIT API support is available on Linux and Windows only.")
 421   endif()
 422 endif( LLVM_USE_INTEL_JITEVENTS )
 423
 424 option(LLVM_USE_OPROFILE
 425   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 426
 427 option(LLVM_EXTERNALIZE_DEBUGINFO
 428   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 429
 430 # If enabled, verify we are on a platform that supports oprofile.
 431 if( LLVM_USE_OPROFILE )
 432   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 433     message(FATAL_ERROR "OProfile support is available on Linux only.")
 434   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 435 endif( LLVM_USE_OPROFILE )
 436
 437 set(LLVM_USE_SANITIZER "" CACHE STRING
 438   "Define the sanitizer used to build binaries and tests.")
 439 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 440   "Path to fuzzing library for linking with fuzz targets")
 441
 442 option(LLVM_USE_SPLIT_DWARF
 443   "Use -gsplit-dwarf when compiling llvm." OFF)
 444
 445 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 446 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 447
 448 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 449   set(POLLY_IN_TREE TRUE)
 450 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 451   set(POLLY_IN_TREE TRUE)
 452 else()
 453   set(POLLY_IN_TREE FALSE)
 454 endif()
 455
 456 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 457   set(WITH_POLLY ON)
 458 else()
 459   set(WITH_POLLY OFF)
 460 endif()
 461
 462 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 463   set(LINK_POLLY_INTO_TOOLS ON)
 464 else()
 465   set(LINK_POLLY_INTO_TOOLS OFF)
 466 endif()
 467
 468 # Define an option controlling whether we should build for 32-bit on 64-bit
 469 # platforms, where supported.
 470 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 471   # TODO: support other platforms and toolchains.
 472   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 473 endif()
 474
 475 # Define the default arguments to use with 'lit', and an option for the user to
 476 # override.
 477 set(LIT_ARGS_DEFAULT "-sv")
 478 if (MSVC_IDE OR XCODE)
 479   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 480 endif()
 481 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 482
 483 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 484 if( WIN32 AND NOT CYGWIN )
 485   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 486 endif()
 487
 488 # Define options to control the inclusion and default build behavior for
 489 # components which may not strictly be necessary (tools, examples, and tests).
 490 #
 491 # This is primarily to support building smaller or faster project files.
 492 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 493 option(LLVM_BUILD_TOOLS
 494   "Build the LLVM tools. If OFF, just generate build targets." ON)
 495
 496 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 497 option(LLVM_BUILD_UTILS
 498   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 499
 500 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 501 option(LLVM_BUILD_RUNTIMES
 502   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 503
 504 option(LLVM_BUILD_RUNTIME
 505   "Build the LLVM runtime libraries." ON)
 506 option(LLVM_BUILD_EXAMPLES
 507   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 508 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 509
 510 option(LLVM_BUILD_TESTS
 511   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 512 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 513 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 514
 515 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 516 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 517 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 518 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 519 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 520
 521 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 522     CACHE STRING "Doxygen-generated HTML documentation install directory")
 523 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 524     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 525
 526 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 527   "Build compiler-rt as an external project." OFF)
 528
 529 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 530   "Show target and host info when tools are invoked with --version." ON)
 531
 532 # You can configure which libraries from LLVM you want to include in the
 533 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 534 # list of LLVM components. All component names handled by llvm-config are valid.
 535 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 536   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 537     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 538 endif()
 539 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 540 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 541 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 542 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 543   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 544 endif()
 545 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 546
 547 option(LLVM_DYLIB_SYMBOL_VERSIONING OFF)
 548
 549 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 550 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 551   set(LLVM_USE_HOST_TOOLS ON)
 552 endif()
 553
 554 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 555   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 556 else()
 557   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 558 endif()
 559
 560 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 561     LLVM_ENABLE_IR_PGO)
 562   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 563     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 564     # for spining disks. Anything higher may only help on slower mediums.
 565     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 566   endif()
 567   if(NOT LLVM_PROFILE_FILE_PATTERN)
 568     if(NOT LLVM_PROFILE_DATA_DIR)
 569       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 570     endif()
 571                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 572   endif()
 573 endif()
 574
 575 if (LLVM_BUILD_STATIC)
 576   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 577 endif()
 578
 579 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 580 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 581 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 582
 583 # All options referred to from HandleLLVMOptions have to be specified
 584 # BEFORE this include, otherwise options will not be correctly set on
 585 # first cmake run
 586 include(config-ix)
 587
 588 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 589   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 590 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 591
 592 # By default, we target the host, but this can be overridden at CMake
 593 # invocation time.
 594 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 595   "Default target for which LLVM will generate code." )
 596 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 597 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 598 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 599
 600 include(HandleLLVMOptions)
 601
 602 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 603 # FIXME: We should support systems with only Python 3, but that requires work
 604 # on LLDB.
 605 set(Python_ADDITIONAL_VERSIONS 2.7)
 606 include(FindPythonInterp)
 607 if( NOT PYTHONINTERP_FOUND )
 608   message(FATAL_ERROR
 609 "Unable to find Python interpreter, required for builds and testing.
 610
 611 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 612 endif()
 613
 614 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 615   message(FATAL_ERROR "Python 2.7 or newer is required")
 616 endif()
 617
 618 ######
 619 # LLVMBuild Integration
 620 #
 621 # We use llvm-build to generate all the data required by the CMake based
 622 # build system in one swoop:
 623 #
 624 #  - We generate a file (a CMake fragment) in the object root which contains
 625 #    all the definitions that are required by CMake.
 626 #
 627 #  - We generate the library table used by llvm-config.
 628 #
 629 #  - We generate the dependencies for the CMake fragment, so that we will
 630 #    automatically reconfigure outselves.
 631
 632 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 633 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 634   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 635 set(LLVMBUILDCMAKEFRAG
 636   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 637
 638 # Create the list of optional components that are enabled
 639 if (LLVM_USE_INTEL_JITEVENTS)
 640   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 641 endif (LLVM_USE_INTEL_JITEVENTS)
 642 if (LLVM_USE_OPROFILE)
 643   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 644 endif (LLVM_USE_OPROFILE)
 645
 646 message(STATUS "Constructing LLVMBuild project information")
 647 execute_process(
 648   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 649             --native-target "${LLVM_NATIVE_ARCH}"
 650             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 651             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 652             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 653             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 654             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 655             ERROR_VARIABLE LLVMBUILDERRORS
 656             OUTPUT_STRIP_TRAILING_WHITESPACE
 657             ERROR_STRIP_TRAILING_WHITESPACE
 658   RESULT_VARIABLE LLVMBUILDRESULT)
 659
 660 # On Win32, CMake doesn't properly handle piping the default output/error
 661 # streams into the GUI console. So, we explicitly catch and report them.
 662 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 663   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 664 endif()
 665 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 666   message(FATAL_ERROR
 667     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 668 endif()
 669
 670 # Include the generated CMake fragment. This will define properties from the
 671 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 672 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 673 # files change.
 674 include(${LLVMBUILDCMAKEFRAG})
 675
 676 ######
 677
 678 # Configure all of the various header file fragments LLVM uses which depend on
 679 # configuration variables.
 680 set(LLVM_ENUM_TARGETS "")
 681 set(LLVM_ENUM_ASM_PRINTERS "")
 682 set(LLVM_ENUM_ASM_PARSERS "")
 683 set(LLVM_ENUM_DISASSEMBLERS "")
 684 foreach(t ${LLVM_TARGETS_TO_BUILD})
 685   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 686
 687   list(FIND LLVM_ALL_TARGETS ${t} idx)
 688   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 689   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 690   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 691   # this test just makes sure that any experimental targets were passed via
 692   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 693   if( idx LESS 0 AND idy LESS 0 )
 694     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 695       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 696   else()
 697     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 698   endif()
 699
 700   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 701   if( asmp_file )
 702     set(LLVM_ENUM_ASM_PRINTERS
 703       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 704   endif()
 705   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 706     set(LLVM_ENUM_ASM_PARSERS
 707       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 708   endif()
 709   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 710     set(LLVM_ENUM_DISASSEMBLERS
 711       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 712   endif()
 713 endforeach(t)
 714
 715 # Produce the target definition files, which provide a way for clients to easily
 716 # include various classes of targets.
 717 configure_file(
 718   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 719   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 720   )
 721 configure_file(
 722   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 723   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 724   )
 725 configure_file(
 726   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 727   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 728   )
 729 configure_file(
 730   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 731   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 732   )
 733
 734 # Configure the three LLVM configuration header files.
 735 configure_file(
 736   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 737   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 738 configure_file(
 739   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 740   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 741 configure_file(
 742   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 743   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 744 configure_file(
 745   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 746   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 747
 748 # Add target for generating source rpm package.
 749 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 750     CACHE FILEPATH ".spec file to use for srpm generation")
 751 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 752 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 753
 754 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 755 # DUMMY_VAR contains a version string which we don't care about.
 756 add_version_info_from_vcs(DUMMY_VAR)
 757 if ( SVN_REVISION )
 758   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 759 elseif ( GIT_COMMIT )
 760   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 761 endif()
 762
 763 configure_file(
 764   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 765   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 766
 767 add_custom_target(srpm
 768   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 769   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 770 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 771
 772
 773 # They are not referenced. See set_output_directory().
 774 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 775 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 776 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 777
 778 if(APPLE AND DARWIN_LTO_LIBRARY)
 779   set(CMAKE_EXE_LINKER_FLAGS
 780     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 781   set(CMAKE_SHARED_LINKER_FLAGS
 782     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 783   set(CMAKE_MODULE_LINKER_FLAGS
 784     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 785 endif()
 786
 787 # Work around a broken bfd ld behavior. When linking a binary with a
 788 # foo.so library, it will try to find any library that foo.so uses and
 789 # check its symbols. This is wasteful (the check was done when foo.so
 790 # was created) and can fail since it is not the dynamic linker and
 791 # doesn't know how to handle search paths correctly.
 792 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 793   set(CMAKE_EXE_LINKER_FLAGS
 794       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 795 endif()
 796
 797 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 798
 799 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 800
 801 # when crosscompiling import the executable targets from a file
 802 if(LLVM_USE_HOST_TOOLS)
 803   include(CrossCompile)
 804 endif(LLVM_USE_HOST_TOOLS)
 805 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 806 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 807 # (this is a variable that CrossCompile sets on recursive invocations)
 808 endif()
 809
 810 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 811   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 812   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 813   include_directories(SYSTEM "/usr/local/include")
 814   link_directories("/usr/local/lib")
 815 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 816
 817 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 818    # special hack for Solaris to handle crazy system sys/regset.h
 819    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 820 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 821
 822 # Make sure we don't get -rdynamic in every binary. For those that need it,
 823 # use export_executable_symbols(target).
 824 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 825
 826 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 827   "Profiling data file to use when compiling in order to improve runtime performance.")
 828
 829 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 830   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 831     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 832   else()
 833     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 834   endif()
 835 endif()
 836
 837 include(AddLLVM)
 838 include(TableGen)
 839
 840 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 841   # People report that -O3 is unreliable on MinGW. The traditional
 842   # build also uses -O2 for that reason:
 843   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 844 endif()
 845
 846 # Put this before tblgen. Else we have a circular dependence.
 847 add_subdirectory(lib/Demangle)
 848 add_subdirectory(lib/Support)
 849 add_subdirectory(lib/TableGen)
 850
 851 add_subdirectory(utils/TableGen)
 852
 853 add_subdirectory(include/llvm)
 854
 855 add_subdirectory(lib)
 856
 857 if( LLVM_INCLUDE_UTILS )
 858   add_subdirectory(utils/FileCheck)
 859   add_subdirectory(utils/PerfectShuffle)
 860   add_subdirectory(utils/count)
 861   add_subdirectory(utils/not)
 862   add_subdirectory(utils/yaml-bench)
 863 else()
 864   if ( LLVM_INCLUDE_TESTS )
 865     message(FATAL_ERROR "Including tests when not building utils will not work.
 866     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 867   endif()
 868 endif()
 869
 870 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 871 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 872   add_subdirectory(utils/LLVMVisualizers)
 873 endif()
 874
 875 foreach( binding ${LLVM_BINDINGS_LIST} )
 876   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 877     add_subdirectory(bindings/${binding})
 878   endif()
 879 endforeach()
 880
 881 add_subdirectory(projects)
 882
 883 if( LLVM_INCLUDE_TOOLS )
 884   add_subdirectory(tools)
 885 endif()
 886
 887 if( LLVM_INCLUDE_RUNTIMES )
 888   add_subdirectory(runtimes)
 889 endif()
 890
 891 if( LLVM_INCLUDE_EXAMPLES )
 892   add_subdirectory(examples)
 893 endif()
 894
 895 if( LLVM_INCLUDE_TESTS )
 896   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 897     include(LLVMExternalProjectUtils)
 898     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 899       USE_TOOLCHAIN
 900       EXCLUDE_FROM_ALL
 901       NO_INSTALL
 902       ALWAYS_CLEAN)
 903   endif()
 904   add_subdirectory(utils/lit)
 905   add_subdirectory(test)
 906   add_subdirectory(unittests)
 907   if( LLVM_INCLUDE_UTILS )
 908     add_subdirectory(utils/unittest)
 909   endif()
 910
 911   if (WIN32)
 912     # This utility is used to prevent crashing tests from calling Dr. Watson on
 913     # Windows.
 914     add_subdirectory(utils/KillTheDoctor)
 915   endif()
 916
 917   # Add a global check rule now that all subdirectories have been traversed
 918   # and we know the total set of lit testsuites.
 919   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 920   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 921   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 922   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 923   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 924                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 925   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 926                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 927   add_lit_target(check-all
 928     "Running all regression tests"
 929     ${LLVM_LIT_TESTSUITES}
 930     PARAMS ${LLVM_LIT_PARAMS}
 931     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 932     ARGS ${LLVM_LIT_EXTRA_ARGS}
 933     )
 934   if(TARGET check-runtimes)
 935     add_dependencies(check-all check-runtimes)
 936   endif()
 937   add_custom_target(test-depends
 938                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 939   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 940 endif()
 941
 942 if (LLVM_INCLUDE_DOCS)
 943   add_subdirectory(docs)
 944 endif()
 945
 946 add_subdirectory(cmake/modules)
 947
 948 # Do this last so that all lit targets have already been created.
 949 if (LLVM_INCLUDE_UTILS)
 950   add_subdirectory(utils/llvm-lit)
 951 endif()
 952
 953 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 954   install(DIRECTORY include/llvm include/llvm-c
 955     DESTINATION include
 956     COMPONENT llvm-headers
 957     FILES_MATCHING
 958     PATTERN "*.def"
 959     PATTERN "*.h"
 960     PATTERN "*.td"
 961     PATTERN "*.inc"
 962     PATTERN "LICENSE.TXT"
 963     PATTERN ".svn" EXCLUDE
 964     )
 965
 966   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 967     DESTINATION include
 968     COMPONENT llvm-headers
 969     FILES_MATCHING
 970     PATTERN "*.def"
 971     PATTERN "*.h"
 972     PATTERN "*.gen"
 973     PATTERN "*.inc"
 974     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 975     PATTERN "CMakeFiles" EXCLUDE
 976     PATTERN "config.h" EXCLUDE
 977     PATTERN ".svn" EXCLUDE
 978     )
 979
 980   # Installing the headers needs to depend on generating any public
 981   # tablegen'd headers.
 982   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 983   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
 984
 985   if (NOT CMAKE_CONFIGURATION_TYPES)
 986     add_llvm_install_targets(install-llvm-headers
 987                              COMPONENT llvm-headers)
 988   endif()
 989 endif()
 990
 991 # This must be at the end of the LLVM root CMakeLists file because it must run
 992 # after all targets are created.
 993 if(LLVM_DISTRIBUTION_COMPONENTS)
 994   if(CMAKE_CONFIGURATION_TYPES)
 995     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 996   endif()
 997
 998   add_custom_target(distribution)
 999   add_custom_target(install-distribution)
1000   add_custom_target(install-distribution-stripped)
1001   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS})
1002     if(TARGET ${target})
1003       add_dependencies(distribution ${target})
1004     else()
1005       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1006     endif()
1007
1008     if(TARGET install-${target})
1009       add_dependencies(install-distribution install-${target})
1010     else()
1011       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1012     endif()
1013
1014     if(TARGET install-${target}-stripped)
1015       add_dependencies(install-distribution-stripped install-${target}-stripped)
1016     else()
1017       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1018                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1019                          " or you should manually create the 'install-${target}-stripped' target.")
1020     endif()
1021   endforeach()
1022 endif()
1023
1024 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1025 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows")
1026   include(InstallRequiredSystemLibraries)
1027 endif()