CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0022)
   6   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
   7 endif()
   8
   9 if (POLICY CMP0051)
  10   # CMake 3.1 and higher include generator expressions of the form
  11   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  12   # stripped everywhere that access the SOURCES property, so we just
  13   # defer to the OLD behavior of not including generator expressions
  14   # in the output for now.
  15   cmake_policy(SET CMP0051 OLD)
  16 endif()
  17
  18 if(POLICY CMP0057)
  19   cmake_policy(SET CMP0057 NEW)
  20 endif()
  21
  22 if(NOT DEFINED LLVM_VERSION_MAJOR)
  23   set(LLVM_VERSION_MAJOR 4)
  24 endif()
  25 if(NOT DEFINED LLVM_VERSION_MINOR)
  26   set(LLVM_VERSION_MINOR 0)
  27 endif()
  28 if(NOT DEFINED LLVM_VERSION_PATCH)
  29   set(LLVM_VERSION_PATCH 0)
  30 endif()
  31 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  32   set(LLVM_VERSION_SUFFIX svn)
  33 endif()
  34
  35 if (POLICY CMP0048)
  36   cmake_policy(SET CMP0048 NEW)
  37   set(cmake_3_0_PROJ_VERSION
  38     VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH})
  39   set(cmake_3_0_LANGUAGES LANGUAGES)
  40 endif()
  41
  42 if (NOT PACKAGE_VERSION)
  43   set(PACKAGE_VERSION
  44     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  45 endif()
  46
  47 project(LLVM
  48   ${cmake_3_0_PROJ_VERSION}
  49   ${cmake_3_0_LANGUAGES}
  50   C CXX ASM)
  51
  52 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  53   message(STATUS "No build type selected, default to Debug")
  54   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)")
  55 endif()
  56
  57 # This should only apply if you are both on an Apple host, and targeting Apple.
  58 if(CMAKE_HOST_APPLE AND APPLE)
  59   if(NOT CMAKE_XCRUN)
  60     find_program(CMAKE_XCRUN NAMES xcrun)
  61   endif()
  62   if(CMAKE_XCRUN)
  63     execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  64       OUTPUT_VARIABLE CMAKE_LIBTOOL
  65       OUTPUT_STRIP_TRAILING_WHITESPACE)
  66   endif()
  67
  68   if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  69     find_program(CMAKE_LIBTOOL NAMES libtool)
  70   endif()
  71
  72   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  73   if(CMAKE_LIBTOOL)
  74     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  75     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  76     foreach(lang ${languages})
  77       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  78         "${CMAKE_LIBTOOL} -static -o <TARGET> <LINK_FLAGS> <OBJECTS> ")
  79     endforeach()
  80   endif()
  81
  82   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  83   if(DYLD_LIBRARY_PATH)
  84     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  85     foreach(lang ${languages})
  86       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
  87         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
  88              "${dyld_envar} ${cmd}")
  89       endforeach()
  90       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  91         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
  92     endforeach()
  93   endif()
  94 endif()
  95
  96 # The following only works with the Ninja generator in CMake >= 3.0.
  97 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  98   "Define the maximum number of concurrent compilation jobs.")
  99 if(LLVM_PARALLEL_COMPILE_JOBS)
 100   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
 101     message(WARNING "Job pooling is only available with Ninja generators.")
 102   else()
 103     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
 104     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
 105   endif()
 106 endif()
 107
 108 # Build llvm with ccache if the package is present
 109 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 110 if(LLVM_CCACHE_BUILD)
 111   find_program(CCACHE_PROGRAM ccache)
 112   if(CCACHE_PROGRAM)
 113       set(LLVM_CCACHE_SIZE "" CACHE STRING "Size of ccache")
 114       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 115       set(CCACHE_PROGRAM "CCACHE_CPP2=yes CCACHE_HASHDIR=yes ${CCACHE_PROGRAM}")
 116       if (LLVM_CCACHE_SIZE)
 117         set(CCACHE_PROGRAM "CCACHE_SIZE=${LLVM_CCACHE_SIZE} ${CCACHE_PROGRAM}")
 118       endif()
 119       if (LLVM_CCACHE_DIR)
 120         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 121       endif()
 122       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 123   else()
 124     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 125   endif()
 126 endif()
 127
 128 option(LLVM_BUILD_GLOBAL_ISEL "Experimental: Build GlobalISel" OFF)
 129 if(LLVM_BUILD_GLOBAL_ISEL)
 130   add_definitions(-DLLVM_BUILD_GLOBAL_ISEL)
 131 endif()
 132
 133 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
 134   "Define the maximum number of concurrent link jobs.")
 135 if(LLVM_PARALLEL_LINK_JOBS)
 136   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
 137     message(WARNING "Job pooling is only available with Ninja generators.")
 138   else()
 139     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
 140     set(CMAKE_JOB_POOL_LINK link_job_pool)
 141   endif()
 142 endif()
 143
 144 # Add path for custom modules
 145 set(CMAKE_MODULE_PATH
 146   ${CMAKE_MODULE_PATH}
 147   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 148   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 149   )
 150
 151 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 152 # for use by clang_complete, YouCompleteMe, etc.
 153 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 154
 155 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 156
 157 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 158
 159 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 160 if ( LLVM_USE_FOLDERS )
 161   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 162 endif()
 163
 164 include(VersionFromVCS)
 165
 166 option(LLVM_APPEND_VC_REV
 167   "Append the version control system revision id to LLVM version" OFF)
 168
 169 if( LLVM_APPEND_VC_REV )
 170   add_version_info_from_vcs(PACKAGE_VERSION)
 171 endif()
 172
 173 set(PACKAGE_NAME LLVM)
 174 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 175 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
 176
 177 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 178   "Default URL where bug reports are to be submitted.")
 179
 180 # Configure CPack.
 181 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 182 set(CPACK_PACKAGE_VENDOR "LLVM")
 183 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 184 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 185 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 186 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 187 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 188 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 189 if(WIN32 AND NOT UNIX)
 190   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 191   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 192   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 193   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 194   set(CPACK_NSIS_MODIFY_PATH "ON")
 195   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 196   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 197     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 198   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 199     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 200   if( CMAKE_CL_64 )
 201     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 202   endif()
 203 endif()
 204 include(CPack)
 205
 206 # Sanity check our source directory to make sure that we are not trying to
 207 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 208 # sure that we don't have any stray generated files lying around in the tree
 209 # (which would end up getting picked up by header search, instead of the correct
 210 # versions).
 211 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 212   message(FATAL_ERROR "In-source builds are not allowed.
 213 CMake would overwrite the makefiles distributed with LLVM.
 214 Please create a directory and run cmake from there, passing the path
 215 to this source directory as the last argument.
 216 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 217 Please delete them.")
 218 endif()
 219 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 220   file(GLOB_RECURSE
 221     tablegenned_files_on_include_dir
 222     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 223   file(GLOB_RECURSE
 224     tablegenned_files_on_lib_dir
 225     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 226   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 227     message(FATAL_ERROR "Apparently there is a previous in-source build,
 228 probably as the result of running `configure' and `make' on
 229 ${CMAKE_CURRENT_SOURCE_DIR}.
 230 This may cause problems. The suspicious files are:
 231 ${tablegenned_files_on_lib_dir}
 232 ${tablegenned_files_on_include_dir}
 233 Please clean the source directory.")
 234   endif()
 235 endif()
 236
 237 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 238
 239 if (CMAKE_BUILD_TYPE AND
 240     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 241   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 242 endif()
 243
 244 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 245
 246 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 247 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 248
 249 # They are used as destination of target generators.
 250 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 251 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 252 if(WIN32 OR CYGWIN)
 253   # DLL platform -- put DLLs into bin.
 254   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 255 else()
 256   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 257 endif()
 258
 259 # Each of them corresponds to llvm-config's.
 260 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 261 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 262 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 263 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 264 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 265
 266 # Note: LLVM_CMAKE_PATH does not include generated files
 267 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 268 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 269 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 270
 271 set(LLVM_ALL_TARGETS
 272   AArch64
 273   AMDGPU
 274   ARM
 275   BPF
 276   Hexagon
 277   Lanai
 278   Mips
 279   MSP430
 280   NVPTX
 281   PowerPC
 282   Sparc
 283   SystemZ
 284   X86
 285   XCore
 286   )
 287
 288 # List of targets with JIT support:
 289 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 290
 291 set(LLVM_TARGETS_TO_BUILD "all"
 292     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 293
 294 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 295   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 296
 297 option(BUILD_SHARED_LIBS
 298   "Build all libraries as shared libraries instead of static" OFF)
 299
 300 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 301 if(LLVM_ENABLE_BACKTRACES)
 302   set(ENABLE_BACKTRACES 1)
 303 endif()
 304
 305 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 306 if(LLVM_ENABLE_CRASH_OVERRIDES)
 307   set(ENABLE_CRASH_OVERRIDES 1)
 308 endif()
 309
 310 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 311 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 312 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 313
 314 set(LLVM_TARGET_ARCH "host"
 315   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 316
 317 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 318
 319 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 320
 321 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 322
 323 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 324   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 325 endif()
 326
 327 set(LLVM_TARGETS_TO_BUILD
 328    ${LLVM_TARGETS_TO_BUILD}
 329    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 330 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 331
 332 include(AddLLVMDefinitions)
 333
 334 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 335 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 336 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 337 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 338   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 339   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 340 else()
 341   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 342   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 343 endif()
 344 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 345 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 346 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 347 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 348 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 349
 350 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 351   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 352 else()
 353   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 354 endif()
 355
 356 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 357
 358 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 359   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 360
 361 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 362        "Set to ON to force using an old, unsupported host toolchain." OFF)
 363
 364 option(LLVM_USE_INTEL_JITEVENTS
 365   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 366   OFF)
 367
 368 if( LLVM_USE_INTEL_JITEVENTS )
 369   # Verify we are on a supported platform
 370   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 371     message(FATAL_ERROR
 372       "Intel JIT API support is available on Linux and Windows only.")
 373   endif()
 374 endif( LLVM_USE_INTEL_JITEVENTS )
 375
 376 option(LLVM_USE_OPROFILE
 377   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 378
 379 option(LLVM_EXTERNALIZE_DEBUGINFO
 380   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 381
 382 # If enabled, verify we are on a platform that supports oprofile.
 383 if( LLVM_USE_OPROFILE )
 384   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 385     message(FATAL_ERROR "OProfile support is available on Linux only.")
 386   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 387 endif( LLVM_USE_OPROFILE )
 388
 389 set(LLVM_USE_SANITIZER "" CACHE STRING
 390   "Define the sanitizer used to build binaries and tests.")
 391
 392 option(LLVM_USE_SPLIT_DWARF
 393   "Use -gsplit-dwarf when compiling llvm." OFF)
 394
 395 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 396 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 397
 398 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 399   set(POLLY_IN_TREE TRUE)
 400 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 401   set(POLLY_IN_TREE TRUE)
 402 else()
 403   set(POLLY_IN_TREE FALSE)
 404 endif()
 405
 406 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 407   set(WITH_POLLY ON)
 408 else()
 409   set(WITH_POLLY OFF)
 410 endif()
 411
 412 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 413   set(LINK_POLLY_INTO_TOOLS ON)
 414 else()
 415   set(LINK_POLLY_INTO_TOOLS OFF)
 416 endif()
 417
 418 # Define an option controlling whether we should build for 32-bit on 64-bit
 419 # platforms, where supported.
 420 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 421   # TODO: support other platforms and toolchains.
 422   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 423 endif()
 424
 425 # Define the default arguments to use with 'lit', and an option for the user to
 426 # override.
 427 set(LIT_ARGS_DEFAULT "-sv")
 428 if (MSVC_IDE OR XCODE)
 429   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 430 endif()
 431 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 432
 433 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 434 if( WIN32 AND NOT CYGWIN )
 435   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 436 endif()
 437
 438 # Define options to control the inclusion and default build behavior for
 439 # components which may not strictly be necessary (tools, examples, and tests).
 440 #
 441 # This is primarily to support building smaller or faster project files.
 442 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 443 option(LLVM_BUILD_TOOLS
 444   "Build the LLVM tools. If OFF, just generate build targets." ON)
 445
 446 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 447 option(LLVM_BUILD_UTILS
 448   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 449
 450 option(LLVM_BUILD_RUNTIME
 451   "Build the LLVM runtime libraries." ON)
 452 option(LLVM_BUILD_EXAMPLES
 453   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 454 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 455
 456 option(LLVM_BUILD_TESTS
 457   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 458 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 459 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 460
 461 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 462 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 463 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 464 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 465 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 466
 467 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 468     CACHE STRING "Doxygen-generated HTML documentation install directory")
 469 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 470     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 471
 472 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 473   "Build compiler-rt as an external project." OFF)
 474
 475 # You can configure which libraries from LLVM you want to include in the
 476 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 477 # list of LLVM components. All component names handled by llvm-config are valid.
 478 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 479   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 480     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 481 endif()
 482 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 483 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 484 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 485 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 486   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 487 endif()
 488 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 489
 490 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 491 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 492   set(LLVM_USE_HOST_TOOLS ON)
 493 endif()
 494
 495 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 496   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 497 else()
 498   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 499 endif()
 500
 501 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE)
 502   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 503     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 504     # for spining disks. Anything higher may only help on slower mediums.
 505     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 506   endif()
 507   if(NOT LLVM_PROFILE_FILE_PATTERN)
 508     if(NOT LLVM_PROFILE_DATA_DIR)
 509       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 510     else()
 511       file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 512     endif()
 513   endif()
 514 endif()
 515
 516 # All options referred to from HandleLLVMOptions have to be specified
 517 # BEFORE this include, otherwise options will not be correctly set on
 518 # first cmake run
 519 include(config-ix)
 520
 521 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 522   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 523 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 524
 525 # By default, we target the host, but this can be overridden at CMake
 526 # invocation time.
 527 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 528   "Default target for which LLVM will generate code." )
 529 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 530 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 531 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 532
 533 include(HandleLLVMOptions)
 534
 535 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 536 # FIXME: We should support systems with only Python 3, but that requires work
 537 # on LLDB.
 538 set(Python_ADDITIONAL_VERSIONS 2.7)
 539 include(FindPythonInterp)
 540 if( NOT PYTHONINTERP_FOUND )
 541   message(FATAL_ERROR
 542 "Unable to find Python interpreter, required for builds and testing.
 543
 544 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 545 endif()
 546
 547 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 548   message(FATAL_ERROR "Python 2.7 or newer is required")
 549 endif()
 550
 551 ######
 552 # LLVMBuild Integration
 553 #
 554 # We use llvm-build to generate all the data required by the CMake based
 555 # build system in one swoop:
 556 #
 557 #  - We generate a file (a CMake fragment) in the object root which contains
 558 #    all the definitions that are required by CMake.
 559 #
 560 #  - We generate the library table used by llvm-config.
 561 #
 562 #  - We generate the dependencies for the CMake fragment, so that we will
 563 #    automatically reconfigure outselves.
 564
 565 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 566 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 567   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 568 set(LLVMBUILDCMAKEFRAG
 569   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 570
 571 # Create the list of optional components that are enabled
 572 if (LLVM_USE_INTEL_JITEVENTS)
 573   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 574 endif (LLVM_USE_INTEL_JITEVENTS)
 575 if (LLVM_USE_OPROFILE)
 576   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 577 endif (LLVM_USE_OPROFILE)
 578
 579 message(STATUS "Constructing LLVMBuild project information")
 580 execute_process(
 581   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 582             --native-target "${LLVM_NATIVE_ARCH}"
 583             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 584             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 585             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 586             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 587             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 588             ERROR_VARIABLE LLVMBUILDERRORS
 589             OUTPUT_STRIP_TRAILING_WHITESPACE
 590             ERROR_STRIP_TRAILING_WHITESPACE
 591   RESULT_VARIABLE LLVMBUILDRESULT)
 592
 593 # On Win32, CMake doesn't properly handle piping the default output/error
 594 # streams into the GUI console. So, we explicitly catch and report them.
 595 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 596   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 597 endif()
 598 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 599   message(FATAL_ERROR
 600     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 601 endif()
 602
 603 # Include the generated CMake fragment. This will define properties from the
 604 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 605 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 606 # files change.
 607 include(${LLVMBUILDCMAKEFRAG})
 608
 609 ######
 610
 611 # Configure all of the various header file fragments LLVM uses which depend on
 612 # configuration variables.
 613 set(LLVM_ENUM_TARGETS "")
 614 set(LLVM_ENUM_ASM_PRINTERS "")
 615 set(LLVM_ENUM_ASM_PARSERS "")
 616 set(LLVM_ENUM_DISASSEMBLERS "")
 617 foreach(t ${LLVM_TARGETS_TO_BUILD})
 618   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 619
 620   list(FIND LLVM_ALL_TARGETS ${t} idx)
 621   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 622   if( idx LESS 0 AND idy LESS 0 )
 623     message(FATAL_ERROR "The target `${t}' does not exist.
 624     It should be one of\n${LLVM_ALL_TARGETS}")
 625   else()
 626     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 627   endif()
 628
 629   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 630   if( asmp_file )
 631     set(LLVM_ENUM_ASM_PRINTERS
 632       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 633   endif()
 634   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 635     set(LLVM_ENUM_ASM_PARSERS
 636       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 637   endif()
 638   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 639     set(LLVM_ENUM_DISASSEMBLERS
 640       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 641   endif()
 642 endforeach(t)
 643
 644 # Produce the target definition files, which provide a way for clients to easily
 645 # include various classes of targets.
 646 configure_file(
 647   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 648   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 649   )
 650 configure_file(
 651   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 652   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 653   )
 654 configure_file(
 655   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 656   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 657   )
 658 configure_file(
 659   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 660   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 661   )
 662
 663 # Configure the three LLVM configuration header files.
 664 configure_file(
 665   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 666   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 667 configure_file(
 668   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 669   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 670 configure_file(
 671   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 672   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 673
 674 # They are not referenced. See set_output_directory().
 675 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 676 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 677 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 678
 679 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 680 if (APPLE)
 681   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 682   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 683 else(UNIX)
 684   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 685     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 686     if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 687       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 688       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 689     endif()
 690   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 691 endif()
 692
 693 if(APPLE AND DARWIN_LTO_LIBRARY)
 694   set(CMAKE_EXE_LINKER_FLAGS
 695     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 696   set(CMAKE_SHARED_LINKER_FLAGS
 697     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 698   set(CMAKE_MODULE_LINKER_FLAGS
 699     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 700 endif()
 701
 702 # Work around a broken bfd ld behavior. When linking a binary with a
 703 # foo.so library, it will try to find any library that foo.so uses and
 704 # check its symbols. This is wasteful (the check was done when foo.so
 705 # was created) and can fail since it is not the dynamic linker and
 706 # doesn't know how to handle search paths correctly.
 707 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 708   set(CMAKE_EXE_LINKER_FLAGS
 709       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 710 endif()
 711
 712 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 713
 714 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 715
 716 # when crosscompiling import the executable targets from a file
 717 if(LLVM_USE_HOST_TOOLS)
 718   include(CrossCompile)
 719 endif(LLVM_USE_HOST_TOOLS)
 720 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 721 # Dummy use to avoid CMake Wraning: Manually-specified variables were not used
 722 # (this is a variable that CrossCompile sets on recursive invocations)
 723 endif()
 724
 725 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 726   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 727   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 728   include_directories("/usr/local/include")
 729   link_directories("/usr/local/lib")
 730 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 731
 732 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 733    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 734 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 735
 736 # Make sure we don't get -rdynamic in every binary. For those that need it,
 737 # use export_executable_symbols(target).
 738 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 739
 740 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 741   "Profiling data file to use when compiling in order to improve runtime performance.")
 742
 743 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 744   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 745     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 746   else()
 747     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 748   endif()
 749 endif()
 750
 751 include(AddLLVM)
 752 include(TableGen)
 753
 754 if( MINGW )
 755   # People report that -O3 is unreliable on MinGW. The traditional
 756   # build also uses -O2 for that reason:
 757   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 758 endif()
 759
 760 # Put this before tblgen. Else we have a circular dependence.
 761 add_subdirectory(lib/Demangle)
 762 add_subdirectory(lib/Support)
 763 add_subdirectory(lib/TableGen)
 764
 765 add_subdirectory(utils/TableGen)
 766
 767 # Force target to be built as soon as possible. Clang modules builds depend
 768 # header-wise on it as they ship all headers from the umbrella folders. Building
 769 # an entire module might include header, which depends on intrinsics_gen. This
 770 # should be right after LLVMSupport and LLVMTableGen otherwise we introduce a
 771 # circular dependence.
 772 if (LLVM_ENABLE_MODULES)
 773   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 774 endif(LLVM_ENABLE_MODULES)
 775
 776 add_subdirectory(include/llvm)
 777
 778 add_subdirectory(lib)
 779
 780 if( LLVM_INCLUDE_UTILS )
 781   add_subdirectory(utils/FileCheck)
 782   add_subdirectory(utils/PerfectShuffle)
 783   add_subdirectory(utils/count)
 784   add_subdirectory(utils/not)
 785   add_subdirectory(utils/llvm-lit)
 786   add_subdirectory(utils/yaml-bench)
 787   add_subdirectory(utils/unittest)
 788 else()
 789   if ( LLVM_INCLUDE_TESTS )
 790     message(FATAL_ERROR "Including tests when not building utils will not work.
 791     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 792   endif()
 793 endif()
 794
 795 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 796 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 797   add_subdirectory(utils/LLVMVisualizers)
 798 endif()
 799
 800 foreach( binding ${LLVM_BINDINGS_LIST} )
 801   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 802     add_subdirectory(bindings/${binding})
 803   endif()
 804 endforeach()
 805
 806 add_subdirectory(projects)
 807
 808 if( LLVM_INCLUDE_TOOLS )
 809   add_subdirectory(tools)
 810 endif()
 811
 812 add_subdirectory(runtimes)
 813
 814 if( LLVM_INCLUDE_EXAMPLES )
 815   add_subdirectory(examples)
 816 endif()
 817
 818 if( LLVM_INCLUDE_TESTS )
 819   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 820     include(LLVMExternalProjectUtils)
 821     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 822       USE_TOOLCHAIN
 823       EXCLUDE_FROM_ALL
 824       NO_INSTALL
 825       ALWAYS_CLEAN)
 826   endif()
 827   add_subdirectory(test)
 828   add_subdirectory(unittests)
 829   if (MSVC)
 830     # This utility is used to prevent crashing tests from calling Dr. Watson on
 831     # Windows.
 832     add_subdirectory(utils/KillTheDoctor)
 833   endif()
 834
 835   # Add a global check rule now that all subdirectories have been traversed
 836   # and we know the total set of lit testsuites.
 837   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 838   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 839   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 840   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 841   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 842                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 843   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 844                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 845   add_lit_target(check-all
 846     "Running all regression tests"
 847     ${LLVM_LIT_TESTSUITES}
 848     PARAMS ${LLVM_LIT_PARAMS}
 849     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 850     ARGS ${LLVM_LIT_EXTRA_ARGS}
 851     )
 852   if(TARGET check-runtimes)
 853     add_dependencies(check-all check-runtimes)
 854   endif()
 855   add_custom_target(test-depends
 856                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 857   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 858 endif()
 859
 860 if (LLVM_INCLUDE_DOCS)
 861   add_subdirectory(docs)
 862 endif()
 863
 864 add_subdirectory(cmake/modules)
 865
 866 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 867   install(DIRECTORY include/llvm include/llvm-c
 868     DESTINATION include
 869     COMPONENT llvm-headers
 870     FILES_MATCHING
 871     PATTERN "*.def"
 872     PATTERN "*.h"
 873     PATTERN "*.td"
 874     PATTERN "*.inc"
 875     PATTERN "LICENSE.TXT"
 876     PATTERN ".svn" EXCLUDE
 877     )
 878
 879   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 880     DESTINATION include
 881     COMPONENT llvm-headers
 882     FILES_MATCHING
 883     PATTERN "*.def"
 884     PATTERN "*.h"
 885     PATTERN "*.gen"
 886     PATTERN "*.inc"
 887     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 888     PATTERN "CMakeFiles" EXCLUDE
 889     PATTERN "config.h" EXCLUDE
 890     PATTERN ".svn" EXCLUDE
 891     )
 892
 893   # Installing the headers needs to depend on generating any public
 894   # tablegen'd headers.
 895   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 896
 897   if (NOT CMAKE_CONFIGURATION_TYPES)
 898     add_custom_target(install-llvm-headers
 899                       DEPENDS llvm-headers
 900                       COMMAND "${CMAKE_COMMAND}"
 901                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 902                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 903   endif()
 904 endif()
 905
 906 # This must be at the end of the LLVM root CMakeLists file because it must run
 907 # after all targets are created.
 908 if(LLVM_DISTRIBUTION_COMPONENTS)
 909   if(CMAKE_CONFIGURATION_TYPES)
 910     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 911   endif()
 912
 913   add_custom_target(distribution)
 914   add_custom_target(install-distribution)
 915   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS})
 916     if(TARGET ${target})
 917       add_dependencies(distribution ${target})
 918     else()
 919       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have a target")
 920     endif()
 921
 922     if(TARGET install-${target})
 923       add_dependencies(install-distribution install-${target})
 924     else()
 925       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have an install target")
 926     endif()
 927   endforeach()
 928 endif()