CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0022)
   6   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
   7 endif()
   8
   9 if (POLICY CMP0051)
  10   # CMake 3.1 and higher include generator expressions of the form
  11   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  12   # stripped everywhere that access the SOURCES property, so we just
  13   # defer to the OLD behavior of not including generator expressions
  14   # in the output for now.
  15   cmake_policy(SET CMP0051 OLD)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 4)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX svn)
  29 endif()
  30
  31 if (POLICY CMP0048)
  32   cmake_policy(SET CMP0048 NEW)
  33   set(cmake_3_0_PROJ_VERSION
  34     VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH})
  35   set(cmake_3_0_LANGUAGES LANGUAGES)
  36 endif()
  37
  38 if (NOT PACKAGE_VERSION)
  39   set(PACKAGE_VERSION
  40     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  41 endif()
  42
  43 project(LLVM
  44   ${cmake_3_0_PROJ_VERSION}
  45   ${cmake_3_0_LANGUAGES}
  46   C CXX ASM)
  47
  48 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  49   message(STATUS "No build type selected, default to Debug")
  50   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)")
  51 endif()
  52
  53 # This should only apply if you are both on an Apple host, and targeting Apple.
  54 if(CMAKE_HOST_APPLE AND APPLE)
  55   if(NOT CMAKE_XCRUN)
  56     find_program(CMAKE_XCRUN NAMES xcrun)
  57   endif()
  58   if(CMAKE_XCRUN)
  59     execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  60       OUTPUT_VARIABLE CMAKE_LIBTOOL
  61       OUTPUT_STRIP_TRAILING_WHITESPACE)
  62   endif()
  63
  64   if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  65     find_program(CMAKE_LIBTOOL NAMES libtool)
  66   endif()
  67
  68   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  69   if(CMAKE_LIBTOOL)
  70     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  71     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  72     foreach(lang ${languages})
  73       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  74         "${CMAKE_LIBTOOL} -static -o <TARGET> <LINK_FLAGS> <OBJECTS> ")
  75     endforeach()
  76   endif()
  77
  78   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  79   if(DYLD_LIBRARY_PATH)
  80     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  81     foreach(lang ${languages})
  82       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
  83         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
  84              "${dyld_envar} ${cmd}")
  85       endforeach()
  86       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  87         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
  88     endforeach()
  89   endif()
  90 endif()
  91
  92 # The following only works with the Ninja generator in CMake >= 3.0.
  93 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  94   "Define the maximum number of concurrent compilation jobs.")
  95 if(LLVM_PARALLEL_COMPILE_JOBS)
  96   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
  97     message(WARNING "Job pooling is only available with Ninja generators.")
  98   else()
  99     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
 100     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
 101   endif()
 102 endif()
 103
 104 # Build llvm with ccache if the package is present
 105 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 106 if(LLVM_CCACHE_BUILD)
 107   find_program(CCACHE_PROGRAM ccache)
 108   if(CCACHE_PROGRAM)
 109       set(LLVM_CCACHE_SIZE "" CACHE STRING "Size of ccache")
 110       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 111       set(CCACHE_PROGRAM "CCACHE_CPP2=yes CCACHE_HASHDIR=yes ${CCACHE_PROGRAM}")
 112       if (LLVM_CCACHE_SIZE)
 113         set(CCACHE_PROGRAM "CCACHE_SIZE=${LLVM_CCACHE_SIZE} ${CCACHE_PROGRAM}")
 114       endif()
 115       if (LLVM_CCACHE_DIR)
 116         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 117       endif()
 118       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 119   else()
 120     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 121   endif()
 122 endif()
 123
 124 option(LLVM_BUILD_GLOBAL_ISEL "Experimental: Build GlobalISel" OFF)
 125 if(LLVM_BUILD_GLOBAL_ISEL)
 126   add_definitions(-DLLVM_BUILD_GLOBAL_ISEL)
 127 endif()
 128
 129 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
 130   "Define the maximum number of concurrent link jobs.")
 131 if(LLVM_PARALLEL_LINK_JOBS)
 132   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
 133     message(WARNING "Job pooling is only available with Ninja generators.")
 134   else()
 135     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
 136     set(CMAKE_JOB_POOL_LINK link_job_pool)
 137   endif()
 138 endif()
 139
 140 # Add path for custom modules
 141 set(CMAKE_MODULE_PATH
 142   ${CMAKE_MODULE_PATH}
 143   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 144   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 145   )
 146
 147 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 148 # for use by clang_complete, YouCompleteMe, etc.
 149 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 150
 151 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 152
 153 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 154
 155 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 156 if ( LLVM_USE_FOLDERS )
 157   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 158 endif()
 159
 160 include(VersionFromVCS)
 161
 162 option(LLVM_APPEND_VC_REV
 163   "Append the version control system revision id to LLVM version" OFF)
 164
 165 if( LLVM_APPEND_VC_REV )
 166   add_version_info_from_vcs(PACKAGE_VERSION)
 167 endif()
 168
 169 set(PACKAGE_NAME LLVM)
 170 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 171 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
 172
 173 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 174   "Default URL where bug reports are to be submitted.")
 175
 176 # Configure CPack.
 177 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 178 set(CPACK_PACKAGE_VENDOR "LLVM")
 179 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 180 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 181 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 182 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 183 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 184 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 185 if(WIN32 AND NOT UNIX)
 186   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 187   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 188   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 189   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 190   set(CPACK_NSIS_MODIFY_PATH "ON")
 191   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 192   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 193     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 194   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 195     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 196   if( CMAKE_CL_64 )
 197     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 198   endif()
 199 endif()
 200 include(CPack)
 201
 202 # Sanity check our source directory to make sure that we are not trying to
 203 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 204 # sure that we don't have any stray generated files lying around in the tree
 205 # (which would end up getting picked up by header search, instead of the correct
 206 # versions).
 207 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 208   message(FATAL_ERROR "In-source builds are not allowed.
 209 CMake would overwrite the makefiles distributed with LLVM.
 210 Please create a directory and run cmake from there, passing the path
 211 to this source directory as the last argument.
 212 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 213 Please delete them.")
 214 endif()
 215 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 216   file(GLOB_RECURSE
 217     tablegenned_files_on_include_dir
 218     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 219   file(GLOB_RECURSE
 220     tablegenned_files_on_lib_dir
 221     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 222   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 223     message(FATAL_ERROR "Apparently there is a previous in-source build,
 224 probably as the result of running `configure' and `make' on
 225 ${CMAKE_CURRENT_SOURCE_DIR}.
 226 This may cause problems. The suspicious files are:
 227 ${tablegenned_files_on_lib_dir}
 228 ${tablegenned_files_on_include_dir}
 229 Please clean the source directory.")
 230   endif()
 231 endif()
 232
 233 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 234
 235 if (CMAKE_BUILD_TYPE AND
 236     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 237   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 238 endif()
 239
 240 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 241
 242 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 243 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 244
 245 # They are used as destination of target generators.
 246 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 247 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 248 if(WIN32 OR CYGWIN)
 249   # DLL platform -- put DLLs into bin.
 250   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 251 else()
 252   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 253 endif()
 254
 255 # Each of them corresponds to llvm-config's.
 256 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 257 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 258 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 259 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 260 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 261
 262 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 263 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 264
 265 set(LLVM_ALL_TARGETS
 266   AArch64
 267   AMDGPU
 268   ARM
 269   BPF
 270   Hexagon
 271   Lanai
 272   Mips
 273   MSP430
 274   NVPTX
 275   PowerPC
 276   Sparc
 277   SystemZ
 278   X86
 279   XCore
 280   )
 281
 282 # List of targets with JIT support:
 283 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 284
 285 set(LLVM_TARGETS_TO_BUILD "all"
 286     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 287
 288 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 289   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 290
 291 option(BUILD_SHARED_LIBS
 292   "Build all libraries as shared libraries instead of static" OFF)
 293
 294 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 295 if(LLVM_ENABLE_BACKTRACES)
 296   set(ENABLE_BACKTRACES 1)
 297 endif()
 298
 299 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 300 if(LLVM_ENABLE_CRASH_OVERRIDES)
 301   set(ENABLE_CRASH_OVERRIDES 1)
 302 endif()
 303
 304 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 305 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 306 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 307
 308 set(LLVM_TARGET_ARCH "host"
 309   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 310
 311 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 312
 313 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 314
 315 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 316
 317 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 318   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 319 endif()
 320
 321 set(LLVM_TARGETS_TO_BUILD
 322    ${LLVM_TARGETS_TO_BUILD}
 323    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 324 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 325
 326 include(AddLLVMDefinitions)
 327
 328 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 329 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 330 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 331 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 332   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 333   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 334 else()
 335   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 336   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 337 endif()
 338 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 339 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 340 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 341 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 342 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 343
 344 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 345   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 346 else()
 347   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 348 endif()
 349
 350 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 351
 352 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 353   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 354
 355 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 356        "Set to ON to force using an old, unsupported host toolchain." OFF)
 357
 358 option(LLVM_USE_INTEL_JITEVENTS
 359   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 360   OFF)
 361
 362 if( LLVM_USE_INTEL_JITEVENTS )
 363   # Verify we are on a supported platform
 364   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 365     message(FATAL_ERROR
 366       "Intel JIT API support is available on Linux and Windows only.")
 367   endif()
 368 endif( LLVM_USE_INTEL_JITEVENTS )
 369
 370 option(LLVM_USE_OPROFILE
 371   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 372
 373 option(LLVM_EXTERNALIZE_DEBUGINFO
 374   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 375
 376 # If enabled, verify we are on a platform that supports oprofile.
 377 if( LLVM_USE_OPROFILE )
 378   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 379     message(FATAL_ERROR "OProfile support is available on Linux only.")
 380   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 381 endif( LLVM_USE_OPROFILE )
 382
 383 set(LLVM_USE_SANITIZER "" CACHE STRING
 384   "Define the sanitizer used to build binaries and tests.")
 385
 386 option(LLVM_USE_SPLIT_DWARF
 387   "Use -gsplit-dwarf when compiling llvm." OFF)
 388
 389 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 390 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 391
 392 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 393   set(POLLY_IN_TREE TRUE)
 394 else()
 395   set(POLLY_IN_TREE FALSE)
 396 endif()
 397
 398 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 399   set(WITH_POLLY ON)
 400 else()
 401   set(WITH_POLLY OFF)
 402 endif()
 403
 404 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 405   set(LINK_POLLY_INTO_TOOLS ON)
 406 else()
 407   set(LINK_POLLY_INTO_TOOLS OFF)
 408 endif()
 409
 410 # Define an option controlling whether we should build for 32-bit on 64-bit
 411 # platforms, where supported.
 412 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 413   # TODO: support other platforms and toolchains.
 414   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 415 endif()
 416
 417 # Define the default arguments to use with 'lit', and an option for the user to
 418 # override.
 419 set(LIT_ARGS_DEFAULT "-sv")
 420 if (MSVC_IDE OR XCODE)
 421   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 422 endif()
 423 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 424
 425 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 426 if( WIN32 AND NOT CYGWIN )
 427   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 428 endif()
 429
 430 # Define options to control the inclusion and default build behavior for
 431 # components which may not strictly be necessary (tools, examples, and tests).
 432 #
 433 # This is primarily to support building smaller or faster project files.
 434 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 435 option(LLVM_BUILD_TOOLS
 436   "Build the LLVM tools. If OFF, just generate build targets." ON)
 437
 438 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 439 option(LLVM_BUILD_UTILS
 440   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 441
 442 option(LLVM_BUILD_RUNTIME
 443   "Build the LLVM runtime libraries." ON)
 444 option(LLVM_BUILD_EXAMPLES
 445   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 446 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 447
 448 option(LLVM_BUILD_TESTS
 449   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 450 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 451 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 452
 453 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 454 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 455 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 456 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 457 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 458
 459 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 460     CACHE STRING "Doxygen-generated HTML documentation install directory")
 461 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 462     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 463
 464 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 465   "Build compiler-rt as an external project." OFF)
 466
 467 # You can configure which libraries from LLVM you want to include in the
 468 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 469 # list of LLVM components. All component names handled by llvm-config are valid.
 470 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 471   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 472     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 473 endif()
 474 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 475 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 476 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 477 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 478   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 479 endif()
 480 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 481
 482 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 483 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 484   set(LLVM_USE_HOST_TOOLS ON)
 485 endif()
 486
 487 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 488   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 489 else()
 490   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 491 endif()
 492
 493 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE)
 494   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 495     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 496     # for spining disks. Anything higher may only help on slower mediums.
 497     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 498   endif()
 499   if(NOT LLVM_PROFILE_FILE_PATTERN)
 500     if(NOT LLVM_PROFILE_DATA_DIR)
 501       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 502     else()
 503       file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 504     endif()
 505   endif()
 506 endif()
 507
 508 # All options referred to from HandleLLVMOptions have to be specified
 509 # BEFORE this include, otherwise options will not be correctly set on
 510 # first cmake run
 511 include(config-ix)
 512
 513 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 514   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 515 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 516
 517 # By default, we target the host, but this can be overridden at CMake
 518 # invocation time.
 519 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 520   "Default target for which LLVM will generate code." )
 521 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 522 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 523 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 524
 525 include(HandleLLVMOptions)
 526
 527 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 528 # FIXME: We should support systems with only Python 3, but that requires work
 529 # on LLDB.
 530 set(Python_ADDITIONAL_VERSIONS 2.7)
 531 include(FindPythonInterp)
 532 if( NOT PYTHONINTERP_FOUND )
 533   message(FATAL_ERROR
 534 "Unable to find Python interpreter, required for builds and testing.
 535
 536 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 537 endif()
 538
 539 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 540   message(FATAL_ERROR "Python 2.7 or newer is required")
 541 endif()
 542
 543 ######
 544 # LLVMBuild Integration
 545 #
 546 # We use llvm-build to generate all the data required by the CMake based
 547 # build system in one swoop:
 548 #
 549 #  - We generate a file (a CMake fragment) in the object root which contains
 550 #    all the definitions that are required by CMake.
 551 #
 552 #  - We generate the library table used by llvm-config.
 553 #
 554 #  - We generate the dependencies for the CMake fragment, so that we will
 555 #    automatically reconfigure outselves.
 556
 557 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 558 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 559   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 560 set(LLVMBUILDCMAKEFRAG
 561   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 562
 563 # Create the list of optional components that are enabled
 564 if (LLVM_USE_INTEL_JITEVENTS)
 565   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 566 endif (LLVM_USE_INTEL_JITEVENTS)
 567 if (LLVM_USE_OPROFILE)
 568   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 569 endif (LLVM_USE_OPROFILE)
 570
 571 message(STATUS "Constructing LLVMBuild project information")
 572 execute_process(
 573   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 574             --native-target "${LLVM_NATIVE_ARCH}"
 575             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 576             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 577             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 578             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 579             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 580             ERROR_VARIABLE LLVMBUILDERRORS
 581             OUTPUT_STRIP_TRAILING_WHITESPACE
 582             ERROR_STRIP_TRAILING_WHITESPACE
 583   RESULT_VARIABLE LLVMBUILDRESULT)
 584
 585 # On Win32, CMake doesn't properly handle piping the default output/error
 586 # streams into the GUI console. So, we explicitly catch and report them.
 587 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 588   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 589 endif()
 590 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 591   message(FATAL_ERROR
 592     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 593 endif()
 594
 595 # Include the generated CMake fragment. This will define properties from the
 596 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 597 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 598 # files change.
 599 include(${LLVMBUILDCMAKEFRAG})
 600
 601 ######
 602
 603 # Configure all of the various header file fragments LLVM uses which depend on
 604 # configuration variables.
 605 set(LLVM_ENUM_TARGETS "")
 606 set(LLVM_ENUM_ASM_PRINTERS "")
 607 set(LLVM_ENUM_ASM_PARSERS "")
 608 set(LLVM_ENUM_DISASSEMBLERS "")
 609 foreach(t ${LLVM_TARGETS_TO_BUILD})
 610   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 611
 612   list(FIND LLVM_ALL_TARGETS ${t} idx)
 613   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 614   if( idx LESS 0 AND idy LESS 0 )
 615     message(FATAL_ERROR "The target `${t}' does not exist.
 616     It should be one of\n${LLVM_ALL_TARGETS}")
 617   else()
 618     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 619   endif()
 620
 621   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 622   if( asmp_file )
 623     set(LLVM_ENUM_ASM_PRINTERS
 624       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 625   endif()
 626   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 627     set(LLVM_ENUM_ASM_PARSERS
 628       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 629   endif()
 630   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 631     set(LLVM_ENUM_DISASSEMBLERS
 632       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 633   endif()
 634 endforeach(t)
 635
 636 # Produce the target definition files, which provide a way for clients to easily
 637 # include various classes of targets.
 638 configure_file(
 639   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 640   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 641   )
 642 configure_file(
 643   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 644   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 645   )
 646 configure_file(
 647   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 648   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 649   )
 650 configure_file(
 651   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 652   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 653   )
 654
 655 # Configure the three LLVM configuration header files.
 656 configure_file(
 657   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 658   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 659 configure_file(
 660   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 661   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 662 configure_file(
 663   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 664   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 665
 666 # They are not referenced. See set_output_directory().
 667 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 668 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 669 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 670
 671 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 672 if (APPLE)
 673   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 674   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 675 else(UNIX)
 676   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 677     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 678     if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 679       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 680       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 681     endif()
 682   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 683 endif()
 684
 685 if(APPLE AND DARWIN_LTO_LIBRARY)
 686   set(CMAKE_EXE_LINKER_FLAGS
 687     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 688   set(CMAKE_SHARED_LINKER_FLAGS
 689     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 690   set(CMAKE_MODULE_LINKER_FLAGS
 691     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 692 endif()
 693
 694 # Work around a broken bfd ld behavior. When linking a binary with a
 695 # foo.so library, it will try to find any library that foo.so uses and
 696 # check its symbols. This is wasteful (the check was done when foo.so
 697 # was created) and can fail since it is not the dynamic linker and
 698 # doesn't know how to handle search paths correctly.
 699 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 700   set(CMAKE_EXE_LINKER_FLAGS
 701       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 702 endif()
 703
 704 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 705
 706 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 707
 708 # when crosscompiling import the executable targets from a file
 709 if(LLVM_USE_HOST_TOOLS)
 710   include(CrossCompile)
 711 endif(LLVM_USE_HOST_TOOLS)
 712 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 713 # Dummy use to avoid CMake Wraning: Manually-specified variables were not used
 714 # (this is a variable that CrossCompile sets on recursive invocations)
 715 endif()
 716
 717 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 718   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 719   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 720   include_directories("/usr/local/include")
 721   link_directories("/usr/local/lib")
 722 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 723
 724 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 725    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 726 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 727
 728 # Make sure we don't get -rdynamic in every binary. For those that need it,
 729 # use export_executable_symbols(target).
 730 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 731
 732 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 733   "Profiling data file to use when compiling in order to improve runtime performance.")
 734
 735 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 736   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 737     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 738   else()
 739     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 740   endif()
 741 endif()
 742
 743 include(AddLLVM)
 744 include(TableGen)
 745
 746 if( MINGW )
 747   # People report that -O3 is unreliable on MinGW. The traditional
 748   # build also uses -O2 for that reason:
 749   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 750 endif()
 751
 752 # Put this before tblgen. Else we have a circular dependence.
 753 add_subdirectory(lib/Demangle)
 754 add_subdirectory(lib/Support)
 755 add_subdirectory(lib/TableGen)
 756
 757 add_subdirectory(utils/TableGen)
 758
 759 # Force target to be built as soon as possible. Clang modules builds depend
 760 # header-wise on it as they ship all headers from the umbrella folders. Building
 761 # an entire module might include header, which depends on intrinsics_gen. This
 762 # should be right after LLVMSupport and LLVMTableGen otherwise we introduce a
 763 # circular dependence.
 764 if (LLVM_ENABLE_MODULES)
 765   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 766 endif(LLVM_ENABLE_MODULES)
 767
 768 add_subdirectory(include/llvm)
 769
 770 add_subdirectory(lib)
 771
 772 if( LLVM_INCLUDE_UTILS )
 773   add_subdirectory(utils/FileCheck)
 774   add_subdirectory(utils/PerfectShuffle)
 775   add_subdirectory(utils/count)
 776   add_subdirectory(utils/not)
 777   add_subdirectory(utils/llvm-lit)
 778   add_subdirectory(utils/yaml-bench)
 779   add_subdirectory(utils/unittest)
 780 else()
 781   if ( LLVM_INCLUDE_TESTS )
 782     message(FATAL_ERROR "Including tests when not building utils will not work.
 783     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 784   endif()
 785 endif()
 786
 787 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 788 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 789   add_subdirectory(utils/LLVMVisualizers)
 790 endif()
 791
 792 foreach( binding ${LLVM_BINDINGS_LIST} )
 793   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 794     add_subdirectory(bindings/${binding})
 795   endif()
 796 endforeach()
 797
 798 add_subdirectory(projects)
 799
 800 if( LLVM_INCLUDE_TOOLS )
 801   add_subdirectory(tools)
 802 endif()
 803
 804 add_subdirectory(runtimes)
 805
 806 if( LLVM_INCLUDE_EXAMPLES )
 807   add_subdirectory(examples)
 808 endif()
 809
 810 if( LLVM_INCLUDE_TESTS )
 811   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 812     include(LLVMExternalProjectUtils)
 813     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 814       USE_TOOLCHAIN
 815       EXCLUDE_FROM_ALL
 816       NO_INSTALL
 817       ALWAYS_CLEAN)
 818   endif()
 819   add_subdirectory(test)
 820   add_subdirectory(unittests)
 821   if (MSVC)
 822     # This utility is used to prevent crashing tests from calling Dr. Watson on
 823     # Windows.
 824     add_subdirectory(utils/KillTheDoctor)
 825   endif()
 826
 827   # Add a global check rule now that all subdirectories have been traversed
 828   # and we know the total set of lit testsuites.
 829   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 830   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 831   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 832   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 833   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 834                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 835   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 836                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 837   add_lit_target(check-all
 838     "Running all regression tests"
 839     ${LLVM_LIT_TESTSUITES}
 840     PARAMS ${LLVM_LIT_PARAMS}
 841     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 842     ARGS ${LLVM_LIT_EXTRA_ARGS}
 843     )
 844   if(TARGET check-runtimes)
 845     add_dependencies(check-all check-runtimes)
 846   endif()
 847   add_custom_target(test-depends
 848                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 849   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 850 endif()
 851
 852 if (LLVM_INCLUDE_DOCS)
 853   add_subdirectory(docs)
 854 endif()
 855
 856 add_subdirectory(cmake/modules)
 857
 858 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 859   install(DIRECTORY include/llvm include/llvm-c
 860     DESTINATION include
 861     COMPONENT llvm-headers
 862     FILES_MATCHING
 863     PATTERN "*.def"
 864     PATTERN "*.h"
 865     PATTERN "*.td"
 866     PATTERN "*.inc"
 867     PATTERN "LICENSE.TXT"
 868     PATTERN ".svn" EXCLUDE
 869     )
 870
 871   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 872     DESTINATION include
 873     COMPONENT llvm-headers
 874     FILES_MATCHING
 875     PATTERN "*.def"
 876     PATTERN "*.h"
 877     PATTERN "*.gen"
 878     PATTERN "*.inc"
 879     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 880     PATTERN "CMakeFiles" EXCLUDE
 881     PATTERN "config.h" EXCLUDE
 882     PATTERN ".svn" EXCLUDE
 883     )
 884
 885   if (NOT CMAKE_CONFIGURATION_TYPES)
 886     add_custom_target(installhdrs
 887                       DEPENDS ${name}
 888                       COMMAND "${CMAKE_COMMAND}"
 889                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 890                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 891   endif()
 892 endif()
 893
 894 # This must be at the end of the LLVM root CMakeLists file because it must run
 895 # after all targets are created.
 896 if(LLVM_DISTRIBUTION_COMPONENTS)
 897   if(CMAKE_CONFIGURATION_TYPES)
 898     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 899   endif()
 900
 901   add_custom_target(distribution)
 902   add_custom_target(install-distribution)
 903   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS})
 904     if(TARGET ${target})
 905       add_dependencies(distribution ${target})
 906     else()
 907       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have a target")
 908     endif()
 909
 910     if(TARGET install-${target})
 911       add_dependencies(install-distribution install-${target})
 912     else()
 913       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have an install target")
 914     endif()
 915   endforeach()
 916 endif()