CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0022)
   6   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
   7 endif()
   8
   9 if (POLICY CMP0051)
  10   # CMake 3.1 and higher include generator expressions of the form
  11   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  12   # stripped everywhere that access the SOURCES property, so we just
  13   # defer to the OLD behavior of not including generator expressions
  14   # in the output for now.
  15   cmake_policy(SET CMP0051 OLD)
  16 endif()
  17
  18 if(POLICY CMP0057)
  19   cmake_policy(SET CMP0057 NEW)
  20 endif()
  21
  22 if(NOT DEFINED LLVM_VERSION_MAJOR)
  23   set(LLVM_VERSION_MAJOR 6)
  24 endif()
  25 if(NOT DEFINED LLVM_VERSION_MINOR)
  26   set(LLVM_VERSION_MINOR 0)
  27 endif()
  28 if(NOT DEFINED LLVM_VERSION_PATCH)
  29   set(LLVM_VERSION_PATCH 0)
  30 endif()
  31 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  32   set(LLVM_VERSION_SUFFIX svn)
  33 endif()
  34
  35 if (POLICY CMP0048)
  36   cmake_policy(SET CMP0048 NEW)
  37   set(cmake_3_0_PROJ_VERSION
  38     VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH})
  39   set(cmake_3_0_LANGUAGES LANGUAGES)
  40 endif()
  41
  42 if (NOT PACKAGE_VERSION)
  43   set(PACKAGE_VERSION
  44     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  45 endif()
  46
  47 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  48   message(WARNING "Visual Studio generators use the x86 host compiler by "
  49                   "default, even for 64-bit targets. This can result in linker "
  50                   "instability and out of memory errors. To use the 64-bit "
  51                   "host compiler, pass -Thost=x64 on the CMake command line.")
  52 endif()
  53
  54 project(LLVM
  55   ${cmake_3_0_PROJ_VERSION}
  56   ${cmake_3_0_LANGUAGES}
  57   C CXX ASM)
  58
  59 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  60   message(STATUS "No build type selected, default to Debug")
  61   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  62 endif()
  63
  64 # This should only apply if you are both on an Apple host, and targeting Apple.
  65 if(CMAKE_HOST_APPLE AND APPLE)
  66   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  67   if(NOT CMAKE_LIBTOOL)
  68     if(NOT CMAKE_XCRUN)
  69       find_program(CMAKE_XCRUN NAMES xcrun)
  70     endif()
  71     if(CMAKE_XCRUN)
  72       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  73         OUTPUT_VARIABLE CMAKE_LIBTOOL
  74         OUTPUT_STRIP_TRAILING_WHITESPACE)
  75     endif()
  76
  77     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  78       find_program(CMAKE_LIBTOOL NAMES libtool)
  79     endif()
  80   endif()
  81
  82   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  83   if(CMAKE_LIBTOOL)
  84     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  85     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  86
  87     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  88       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  89       OUTPUT_STRIP_TRAILING_WHITESPACE)
  90     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  91       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  92         ${LIBTOOL_V_OUTPUT})
  93       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  94         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  95       endif()
  96     endif()
  97
  98     foreach(lang ${languages})
  99       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 100         "${CMAKE_LIBTOOL} -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
 101         <LINK_FLAGS> <OBJECTS> ")
 102     endforeach()
 103   endif()
 104
 105   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
 106   if(DYLD_LIBRARY_PATH)
 107     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
 108     foreach(lang ${languages})
 109       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 110         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
 111              "${dyld_envar} ${cmd}")
 112       endforeach()
 113       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 114         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 115     endforeach()
 116   endif()
 117 endif()
 118
 119 # Side-by-side subprojects layout: automatically set the
 120 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 121 # This allows an easy way of setting up a build directory for llvm and another
 122 # one for llvm+clang+... using the same sources.
 123 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly")
 124 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 125         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 126 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 127   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 128 endif()
 129 foreach(proj ${LLVM_ENABLE_PROJECTS})
 130   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 131   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 132     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 133   endif()
 134   string(TOUPPER "${proj}" upper_proj)
 135   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 136   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 137   # There is a widely spread opinion that clang-tools-extra should be merged
 138   # into clang. The following simulates it by always enabling clang-tools-extra
 139   # when enabling clang.
 140   if (proj STREQUAL "clang")
 141     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 142   endif()
 143 endforeach()
 144
 145 # Build llvm with ccache if the package is present
 146 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 147 if(LLVM_CCACHE_BUILD)
 148   find_program(CCACHE_PROGRAM ccache)
 149   if(CCACHE_PROGRAM)
 150       set(LLVM_CCACHE_SIZE "" CACHE STRING "Size of ccache")
 151       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 152       set(CCACHE_PROGRAM "CCACHE_CPP2=yes CCACHE_HASHDIR=yes ${CCACHE_PROGRAM}")
 153       if (LLVM_CCACHE_SIZE)
 154         set(CCACHE_PROGRAM "CCACHE_SIZE=${LLVM_CCACHE_SIZE} ${CCACHE_PROGRAM}")
 155       endif()
 156       if (LLVM_CCACHE_DIR)
 157         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 158       endif()
 159       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 160   else()
 161     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 162   endif()
 163 endif()
 164
 165 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 166
 167 # Some features of the LLVM build may be disallowed when dependency debugging is
 168 # enabled. In particular you cannot use ccache because we want to force compile
 169 # operations to always happen.
 170 if(LLVM_DEPENDENCY_DEBUGGING)
 171   if(NOT CMAKE_HOST_APPLE)
 172     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 173   endif()
 174   if(LLVM_CCACHE_BUILD)
 175     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 176   endif()
 177 endif()
 178
 179 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 180
 181 # Add path for custom modules
 182 set(CMAKE_MODULE_PATH
 183   ${CMAKE_MODULE_PATH}
 184   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 185   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 186   )
 187
 188 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 189 # for use by clang_complete, YouCompleteMe, etc.
 190 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 191
 192 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 193
 194 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 195
 196 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 197 if ( LLVM_USE_FOLDERS )
 198   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 199 endif()
 200
 201 include(VersionFromVCS)
 202
 203 option(LLVM_APPEND_VC_REV
 204   "Embed the version control system revision id in LLVM" ON)
 205
 206 set(PACKAGE_NAME LLVM)
 207 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 208 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
 209
 210 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 211   "Default URL where bug reports are to be submitted.")
 212
 213 # Configure CPack.
 214 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 215 set(CPACK_PACKAGE_VENDOR "LLVM")
 216 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 217 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 218 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 219 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 220 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 221 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 222 if(WIN32 AND NOT UNIX)
 223   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 224   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 225   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 226   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 227   set(CPACK_NSIS_MODIFY_PATH "ON")
 228   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 229   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 230     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 231   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 232     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 233   if( CMAKE_CL_64 )
 234     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 235   endif()
 236 endif()
 237 include(CPack)
 238
 239 # Sanity check our source directory to make sure that we are not trying to
 240 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 241 # sure that we don't have any stray generated files lying around in the tree
 242 # (which would end up getting picked up by header search, instead of the correct
 243 # versions).
 244 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 245   message(FATAL_ERROR "In-source builds are not allowed.
 246 CMake would overwrite the makefiles distributed with LLVM.
 247 Please create a directory and run cmake from there, passing the path
 248 to this source directory as the last argument.
 249 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 250 Please delete them.")
 251 endif()
 252 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 253   file(GLOB_RECURSE
 254     tablegenned_files_on_include_dir
 255     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 256   file(GLOB_RECURSE
 257     tablegenned_files_on_lib_dir
 258     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 259   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 260     message(FATAL_ERROR "Apparently there is a previous in-source build,
 261 probably as the result of running `configure' and `make' on
 262 ${CMAKE_CURRENT_SOURCE_DIR}.
 263 This may cause problems. The suspicious files are:
 264 ${tablegenned_files_on_lib_dir}
 265 ${tablegenned_files_on_include_dir}
 266 Please clean the source directory.")
 267   endif()
 268 endif()
 269
 270 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 271
 272 if (CMAKE_BUILD_TYPE AND
 273     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 274   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 275 endif()
 276
 277 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 278
 279 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 280 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 281
 282 set(LLVM_UTILS_INSTALL_DIR "bin" CACHE STRING
 283     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 284 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 285
 286 # They are used as destination of target generators.
 287 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 288 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 289 if(WIN32 OR CYGWIN)
 290   # DLL platform -- put DLLs into bin.
 291   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 292 else()
 293   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 294 endif()
 295
 296 # Each of them corresponds to llvm-config's.
 297 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 298 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 299 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 300 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 301 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 302
 303 # Note: LLVM_CMAKE_PATH does not include generated files
 304 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 305 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 306 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 307
 308 # List of all targets to be built by default:
 309 set(LLVM_ALL_TARGETS
 310   AArch64
 311   AMDGPU
 312   ARM
 313   BPF
 314   Hexagon
 315   Lanai
 316   Mips
 317   MSP430
 318   NVPTX
 319   PowerPC
 320   Sparc
 321   SystemZ
 322   X86
 323   XCore
 324   )
 325
 326 # List of targets with JIT support:
 327 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 328
 329 set(LLVM_TARGETS_TO_BUILD "all"
 330     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 331
 332 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 333   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 334
 335 option(BUILD_SHARED_LIBS
 336   "Build all libraries as shared libraries instead of static" OFF)
 337
 338 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 339 if(LLVM_ENABLE_BACKTRACES)
 340   set(ENABLE_BACKTRACES 1)
 341 endif()
 342
 343 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 344 if(LLVM_ENABLE_CRASH_OVERRIDES)
 345   set(ENABLE_CRASH_OVERRIDES 1)
 346 endif()
 347
 348 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 349 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 350 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 351
 352 set(LLVM_TARGET_ARCH "host"
 353   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 354
 355 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 356
 357 option(LLVM_ENABLE_LIBXML2 "Use libxml2 if available." ON)
 358
 359 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 360
 361 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 362
 363 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 364
 365 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 366   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 367 endif()
 368
 369 set(LLVM_TARGETS_TO_BUILD
 370    ${LLVM_TARGETS_TO_BUILD}
 371    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 372 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 373
 374 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 375 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 376 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 377 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 378   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 379   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 380 else()
 381   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 382   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 383 endif()
 384 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 385 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 386 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 387 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 388 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 389 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 390
 391 option(LLVM_ENABLE_DUMP "Enable dump functions in release builds" OFF)
 392
 393 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 394   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 395 else()
 396   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 397 endif()
 398
 399 if( LLVM_ENABLE_ASSERTIONS )
 400   set(LLVM_ENABLE_DUMP ON)
 401 endif()
 402
 403 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 404
 405 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 406   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 407
 408 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 409        "Set to ON to force using an old, unsupported host toolchain." OFF)
 410
 411 option(LLVM_USE_INTEL_JITEVENTS
 412   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 413   OFF)
 414
 415 if( LLVM_USE_INTEL_JITEVENTS )
 416   # Verify we are on a supported platform
 417   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 418     message(FATAL_ERROR
 419       "Intel JIT API support is available on Linux and Windows only.")
 420   endif()
 421 endif( LLVM_USE_INTEL_JITEVENTS )
 422
 423 option(LLVM_USE_OPROFILE
 424   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 425
 426 option(LLVM_EXTERNALIZE_DEBUGINFO
 427   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 428
 429 # If enabled, verify we are on a platform that supports oprofile.
 430 if( LLVM_USE_OPROFILE )
 431   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 432     message(FATAL_ERROR "OProfile support is available on Linux only.")
 433   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 434 endif( LLVM_USE_OPROFILE )
 435
 436 set(LLVM_USE_SANITIZER "" CACHE STRING
 437   "Define the sanitizer used to build binaries and tests.")
 438
 439 option(LLVM_USE_SPLIT_DWARF
 440   "Use -gsplit-dwarf when compiling llvm." OFF)
 441
 442 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 443 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 444
 445 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 446   set(POLLY_IN_TREE TRUE)
 447 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 448   set(POLLY_IN_TREE TRUE)
 449 else()
 450   set(POLLY_IN_TREE FALSE)
 451 endif()
 452
 453 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 454   set(WITH_POLLY ON)
 455 else()
 456   set(WITH_POLLY OFF)
 457 endif()
 458
 459 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 460   set(LINK_POLLY_INTO_TOOLS ON)
 461 else()
 462   set(LINK_POLLY_INTO_TOOLS OFF)
 463 endif()
 464
 465 # Define an option controlling whether we should build for 32-bit on 64-bit
 466 # platforms, where supported.
 467 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 468   # TODO: support other platforms and toolchains.
 469   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 470 endif()
 471
 472 # Define the default arguments to use with 'lit', and an option for the user to
 473 # override.
 474 set(LIT_ARGS_DEFAULT "-sv")
 475 if (MSVC_IDE OR XCODE)
 476   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 477 endif()
 478 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 479
 480 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 481 if( WIN32 AND NOT CYGWIN )
 482   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 483 endif()
 484
 485 # Define options to control the inclusion and default build behavior for
 486 # components which may not strictly be necessary (tools, examples, and tests).
 487 #
 488 # This is primarily to support building smaller or faster project files.
 489 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 490 option(LLVM_BUILD_TOOLS
 491   "Build the LLVM tools. If OFF, just generate build targets." ON)
 492
 493 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 494 option(LLVM_BUILD_UTILS
 495   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 496
 497 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 498 option(LLVM_BUILD_RUNTIMES
 499   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 500
 501 option(LLVM_BUILD_RUNTIME
 502   "Build the LLVM runtime libraries." ON)
 503 option(LLVM_BUILD_EXAMPLES
 504   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 505 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 506
 507 option(LLVM_BUILD_TESTS
 508   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 509 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 510 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 511
 512 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 513 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 514 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 515 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 516 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 517
 518 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 519     CACHE STRING "Doxygen-generated HTML documentation install directory")
 520 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 521     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 522
 523 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 524   "Build compiler-rt as an external project." OFF)
 525
 526 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 527   "Show target and host info when tools are invoked with --version." ON)
 528
 529 # You can configure which libraries from LLVM you want to include in the
 530 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 531 # list of LLVM components. All component names handled by llvm-config are valid.
 532 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 533   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 534     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 535 endif()
 536 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 537 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 538 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 539 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 540   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 541 endif()
 542 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 543
 544 option(LLVM_DYLIB_SYMBOL_VERSIONING OFF)
 545
 546 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 547 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 548   set(LLVM_USE_HOST_TOOLS ON)
 549 endif()
 550
 551 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 552   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 553 else()
 554   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 555 endif()
 556
 557 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 558     LLVM_ENABLE_IR_PGO)
 559   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 560     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 561     # for spining disks. Anything higher may only help on slower mediums.
 562     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 563   endif()
 564   if(NOT LLVM_PROFILE_FILE_PATTERN)
 565     if(NOT LLVM_PROFILE_DATA_DIR)
 566       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 567     endif()
 568                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 569   endif()
 570 endif()
 571
 572 if (LLVM_BUILD_STATIC)
 573   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 574 endif()
 575
 576 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 577 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 578 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 579
 580 # All options referred to from HandleLLVMOptions have to be specified
 581 # BEFORE this include, otherwise options will not be correctly set on
 582 # first cmake run
 583 include(config-ix)
 584
 585 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 586   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 587 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 588
 589 # By default, we target the host, but this can be overridden at CMake
 590 # invocation time.
 591 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 592   "Default target for which LLVM will generate code." )
 593 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 594 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 595 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 596
 597 include(HandleLLVMOptions)
 598
 599 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 600 # FIXME: We should support systems with only Python 3, but that requires work
 601 # on LLDB.
 602 set(Python_ADDITIONAL_VERSIONS 2.7)
 603 include(FindPythonInterp)
 604 if( NOT PYTHONINTERP_FOUND )
 605   message(FATAL_ERROR
 606 "Unable to find Python interpreter, required for builds and testing.
 607
 608 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 609 endif()
 610
 611 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 612   message(FATAL_ERROR "Python 2.7 or newer is required")
 613 endif()
 614
 615 ######
 616 # LLVMBuild Integration
 617 #
 618 # We use llvm-build to generate all the data required by the CMake based
 619 # build system in one swoop:
 620 #
 621 #  - We generate a file (a CMake fragment) in the object root which contains
 622 #    all the definitions that are required by CMake.
 623 #
 624 #  - We generate the library table used by llvm-config.
 625 #
 626 #  - We generate the dependencies for the CMake fragment, so that we will
 627 #    automatically reconfigure outselves.
 628
 629 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 630 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 631   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 632 set(LLVMBUILDCMAKEFRAG
 633   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 634
 635 # Create the list of optional components that are enabled
 636 if (LLVM_USE_INTEL_JITEVENTS)
 637   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 638 endif (LLVM_USE_INTEL_JITEVENTS)
 639 if (LLVM_USE_OPROFILE)
 640   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 641 endif (LLVM_USE_OPROFILE)
 642
 643 message(STATUS "Constructing LLVMBuild project information")
 644 execute_process(
 645   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 646             --native-target "${LLVM_NATIVE_ARCH}"
 647             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 648             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 649             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 650             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 651             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 652             ERROR_VARIABLE LLVMBUILDERRORS
 653             OUTPUT_STRIP_TRAILING_WHITESPACE
 654             ERROR_STRIP_TRAILING_WHITESPACE
 655   RESULT_VARIABLE LLVMBUILDRESULT)
 656
 657 # On Win32, CMake doesn't properly handle piping the default output/error
 658 # streams into the GUI console. So, we explicitly catch and report them.
 659 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 660   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 661 endif()
 662 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 663   message(FATAL_ERROR
 664     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 665 endif()
 666
 667 # Include the generated CMake fragment. This will define properties from the
 668 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 669 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 670 # files change.
 671 include(${LLVMBUILDCMAKEFRAG})
 672
 673 ######
 674
 675 # Configure all of the various header file fragments LLVM uses which depend on
 676 # configuration variables.
 677 set(LLVM_ENUM_TARGETS "")
 678 set(LLVM_ENUM_ASM_PRINTERS "")
 679 set(LLVM_ENUM_ASM_PARSERS "")
 680 set(LLVM_ENUM_DISASSEMBLERS "")
 681 foreach(t ${LLVM_TARGETS_TO_BUILD})
 682   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 683
 684   list(FIND LLVM_ALL_TARGETS ${t} idx)
 685   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 686   if( idx LESS 0 AND idy LESS 0 )
 687     message(FATAL_ERROR "The target `${t}' does not exist.
 688     It should be one of\n${LLVM_ALL_TARGETS}")
 689   else()
 690     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 691   endif()
 692
 693   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 694   if( asmp_file )
 695     set(LLVM_ENUM_ASM_PRINTERS
 696       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 697   endif()
 698   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 699     set(LLVM_ENUM_ASM_PARSERS
 700       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 701   endif()
 702   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 703     set(LLVM_ENUM_DISASSEMBLERS
 704       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 705   endif()
 706 endforeach(t)
 707
 708 # Produce the target definition files, which provide a way for clients to easily
 709 # include various classes of targets.
 710 configure_file(
 711   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 712   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 713   )
 714 configure_file(
 715   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 716   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 717   )
 718 configure_file(
 719   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 720   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 721   )
 722 configure_file(
 723   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 724   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 725   )
 726
 727 # Configure the three LLVM configuration header files.
 728 configure_file(
 729   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 730   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 731 configure_file(
 732   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 733   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 734 configure_file(
 735   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 736   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 737 configure_file(
 738   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 739   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 740
 741 # Add target for generating source rpm package.
 742 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 743     CACHE FILEPATH ".spec file to use for srpm generation")
 744 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 745 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 746
 747 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 748 # DUMMY_VAR contains a version string which we don't care about.
 749 add_version_info_from_vcs(DUMMY_VAR)
 750 if ( SVN_REVISION )
 751   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 752 elseif ( GIT_COMMIT )
 753   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 754 endif()
 755
 756 configure_file(
 757   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 758   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 759
 760 add_custom_target(srpm
 761   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 762   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 763
 764
 765 # They are not referenced. See set_output_directory().
 766 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 767 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 768 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 769
 770 if(APPLE AND DARWIN_LTO_LIBRARY)
 771   set(CMAKE_EXE_LINKER_FLAGS
 772     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 773   set(CMAKE_SHARED_LINKER_FLAGS
 774     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 775   set(CMAKE_MODULE_LINKER_FLAGS
 776     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 777 endif()
 778
 779 # Work around a broken bfd ld behavior. When linking a binary with a
 780 # foo.so library, it will try to find any library that foo.so uses and
 781 # check its symbols. This is wasteful (the check was done when foo.so
 782 # was created) and can fail since it is not the dynamic linker and
 783 # doesn't know how to handle search paths correctly.
 784 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 785   set(CMAKE_EXE_LINKER_FLAGS
 786       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 787 endif()
 788
 789 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 790
 791 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 792
 793 # when crosscompiling import the executable targets from a file
 794 if(LLVM_USE_HOST_TOOLS)
 795   include(CrossCompile)
 796 endif(LLVM_USE_HOST_TOOLS)
 797 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 798 # Dummy use to avoid CMake Wraning: Manually-specified variables were not used
 799 # (this is a variable that CrossCompile sets on recursive invocations)
 800 endif()
 801
 802 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 803   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 804   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 805   include_directories("/usr/local/include")
 806   link_directories("/usr/local/lib")
 807 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 808
 809 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 810    # special hack for Solaris to handle crazy system sys/regset.h
 811    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 812 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 813
 814 # Make sure we don't get -rdynamic in every binary. For those that need it,
 815 # use export_executable_symbols(target).
 816 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 817
 818 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 819   "Profiling data file to use when compiling in order to improve runtime performance.")
 820
 821 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 822   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 823     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 824   else()
 825     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 826   endif()
 827 endif()
 828
 829 include(AddLLVM)
 830 include(TableGen)
 831
 832 if( MINGW )
 833   # People report that -O3 is unreliable on MinGW. The traditional
 834   # build also uses -O2 for that reason:
 835   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 836 endif()
 837
 838 # Put this before tblgen. Else we have a circular dependence.
 839 add_subdirectory(lib/Demangle)
 840 add_subdirectory(lib/Support)
 841 add_subdirectory(lib/TableGen)
 842
 843 add_subdirectory(utils/TableGen)
 844
 845 add_subdirectory(include/llvm)
 846
 847 add_subdirectory(lib)
 848
 849 if( LLVM_INCLUDE_UTILS )
 850   add_subdirectory(utils/FileCheck)
 851   add_subdirectory(utils/PerfectShuffle)
 852   add_subdirectory(utils/count)
 853   add_subdirectory(utils/not)
 854   add_subdirectory(utils/yaml-bench)
 855 else()
 856   if ( LLVM_INCLUDE_TESTS )
 857     message(FATAL_ERROR "Including tests when not building utils will not work.
 858     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 859   endif()
 860 endif()
 861
 862 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 863 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 864   add_subdirectory(utils/LLVMVisualizers)
 865 endif()
 866
 867 foreach( binding ${LLVM_BINDINGS_LIST} )
 868   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 869     add_subdirectory(bindings/${binding})
 870   endif()
 871 endforeach()
 872
 873 add_subdirectory(projects)
 874
 875 if( LLVM_INCLUDE_TOOLS )
 876   add_subdirectory(tools)
 877 endif()
 878
 879 if( LLVM_INCLUDE_RUNTIMES )
 880   add_subdirectory(runtimes)
 881 endif()
 882
 883 if( LLVM_INCLUDE_EXAMPLES )
 884   add_subdirectory(examples)
 885 endif()
 886
 887 if( LLVM_INCLUDE_TESTS )
 888   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 889     include(LLVMExternalProjectUtils)
 890     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 891       USE_TOOLCHAIN
 892       EXCLUDE_FROM_ALL
 893       NO_INSTALL
 894       ALWAYS_CLEAN)
 895   endif()
 896   add_subdirectory(utils/lit)
 897   add_subdirectory(test)
 898   add_subdirectory(unittests)
 899   if( LLVM_INCLUDE_UTILS )
 900     add_subdirectory(utils/unittest)
 901   endif()
 902
 903   if (WIN32)
 904     # This utility is used to prevent crashing tests from calling Dr. Watson on
 905     # Windows.
 906     add_subdirectory(utils/KillTheDoctor)
 907   endif()
 908
 909   # Add a global check rule now that all subdirectories have been traversed
 910   # and we know the total set of lit testsuites.
 911   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 912   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 913   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 914   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 915   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 916                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 917   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 918                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 919   add_lit_target(check-all
 920     "Running all regression tests"
 921     ${LLVM_LIT_TESTSUITES}
 922     PARAMS ${LLVM_LIT_PARAMS}
 923     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 924     ARGS ${LLVM_LIT_EXTRA_ARGS}
 925     )
 926   if(TARGET check-runtimes)
 927     add_dependencies(check-all check-runtimes)
 928   endif()
 929   add_custom_target(test-depends
 930                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 931   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 932 endif()
 933
 934 if (LLVM_INCLUDE_DOCS)
 935   add_subdirectory(docs)
 936 endif()
 937
 938 add_subdirectory(cmake/modules)
 939
 940 # Do this last so that all lit targets have already been created.
 941 if (LLVM_INCLUDE_UTILS)
 942   add_subdirectory(utils/llvm-lit)
 943 endif()
 944
 945 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 946   install(DIRECTORY include/llvm include/llvm-c
 947     DESTINATION include
 948     COMPONENT llvm-headers
 949     FILES_MATCHING
 950     PATTERN "*.def"
 951     PATTERN "*.h"
 952     PATTERN "*.td"
 953     PATTERN "*.inc"
 954     PATTERN "LICENSE.TXT"
 955     PATTERN ".svn" EXCLUDE
 956     )
 957
 958   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 959     DESTINATION include
 960     COMPONENT llvm-headers
 961     FILES_MATCHING
 962     PATTERN "*.def"
 963     PATTERN "*.h"
 964     PATTERN "*.gen"
 965     PATTERN "*.inc"
 966     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 967     PATTERN "CMakeFiles" EXCLUDE
 968     PATTERN "config.h" EXCLUDE
 969     PATTERN ".svn" EXCLUDE
 970     )
 971
 972   # Installing the headers needs to depend on generating any public
 973   # tablegen'd headers.
 974   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 975
 976   if (NOT CMAKE_CONFIGURATION_TYPES)
 977     add_custom_target(install-llvm-headers
 978                       DEPENDS llvm-headers
 979                       COMMAND "${CMAKE_COMMAND}"
 980                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 981                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 982   endif()
 983 endif()
 984
 985 # This must be at the end of the LLVM root CMakeLists file because it must run
 986 # after all targets are created.
 987 if(LLVM_DISTRIBUTION_COMPONENTS)
 988   if(CMAKE_CONFIGURATION_TYPES)
 989     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 990   endif()
 991
 992   add_custom_target(distribution)
 993   add_custom_target(install-distribution)
 994   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS})
 995     if(TARGET ${target})
 996       add_dependencies(distribution ${target})
 997     else()
 998       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have a target")
 999     endif()
1000
1001     if(TARGET install-${target})
1002       add_dependencies(install-distribution install-${target})
1003     else()
1004       message(FATAL_ERROR "Specified distribution component '${target}' doesn't have an install target")
1005     endif()
1006   endforeach()
1007 endif()
1008
1009 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1010 if (MSVC)
1011   include(InstallRequiredSystemLibraries)
1012 endif()