CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(POLICY CMP0077)
  15   cmake_policy(SET CMP0077 NEW)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 9)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX svn)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  37   message(WARNING "Visual Studio generators use the x86 host compiler by "
  38                   "default, even for 64-bit targets. This can result in linker "
  39                   "instability and out of memory errors. To use the 64-bit "
  40                   "host compiler, pass -Thost=x64 on the CMake command line.")
  41 endif()
  42
  43 project(LLVM
  44   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  45   LANGUAGES C CXX ASM)
  46
  47 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  48   message(STATUS "No build type selected, default to Debug")
  49   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  50 endif()
  51
  52 # Side-by-side subprojects layout: automatically set the
  53 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
  54 # This allows an easy way of setting up a build directory for llvm and another
  55 # one for llvm+clang+... using the same sources.
  56 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;openmp;parallel-libs;polly;pstl")
  57 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
  58         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
  59 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
  60   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
  61 endif()
  62
  63 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
  64 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
  65 # several reasons:
  66 #
  67 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
  68 # source of truth for which projects to build. This means we will ignore user
  69 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
  70 # them.
  71 #
  72 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
  73 # non-empty list but now the user wishes to disable building all other projects
  74 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
  75 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
  76 # building all the projects that were previously enabled.
  77 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
  78 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
  79
  80 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
  81   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
  82   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
  83     string(TOUPPER "${proj}" upper_proj)
  84     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
  85     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
  86       message(STATUS "${proj} project is enabled")
  87       set(SHOULD_ENABLE_PROJECT TRUE)
  88       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
  89       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
  90         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
  91       endif()
  92       set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE STRING "")
  93     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
  94       message(STATUS "${proj} project is enabled")
  95       set(SHOULD_ENABLE_PROJECT TRUE)
  96     else()
  97       message(STATUS "${proj} project is disabled")
  98       set(SHOULD_ENABLE_PROJECT FALSE)
  99     endif()
 100     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 101     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 102     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 103     # we should deprecate allowing users to set these variables by turning them
 104     # into normal CMake variables rather than cache variables.
 105     set(LLVM_TOOL_${upper_proj}_BUILD
 106       ${SHOULD_ENABLE_PROJECT}
 107       CACHE
 108       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 109     )
 110   endforeach()
 111 endif()
 112 unset(SHOULD_ENABLE_PROJECT)
 113
 114 # Build llvm with ccache if the package is present
 115 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 116 if(LLVM_CCACHE_BUILD)
 117   find_program(CCACHE_PROGRAM ccache)
 118   if(CCACHE_PROGRAM)
 119       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 120       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 121       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 122           CACHE STRING "Parameters to pass through to ccache")
 123
 124       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 125       if (LLVM_CCACHE_MAXSIZE)
 126         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 127       endif()
 128       if (LLVM_CCACHE_DIR)
 129         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 130       endif()
 131       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 132   else()
 133     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 134   endif()
 135 endif()
 136
 137 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 138
 139 # Some features of the LLVM build may be disallowed when dependency debugging is
 140 # enabled. In particular you cannot use ccache because we want to force compile
 141 # operations to always happen.
 142 if(LLVM_DEPENDENCY_DEBUGGING)
 143   if(NOT CMAKE_HOST_APPLE)
 144     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 145   endif()
 146   if(LLVM_CCACHE_BUILD)
 147     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 148   endif()
 149 endif()
 150
 151 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 152 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 153 if(LLVM_ENABLE_GISEL_COV)
 154   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 155 endif()
 156
 157 # Add path for custom modules
 158 set(CMAKE_MODULE_PATH
 159   ${CMAKE_MODULE_PATH}
 160   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 161   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 162   )
 163
 164 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 165 # for use by clang_complete, YouCompleteMe, etc.
 166 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 167
 168 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 169   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 170
 171 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 172
 173 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 174
 175 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 176 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 177 # the installation by default. See llvm.org/PR31905.
 178 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 179
 180 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 181 if ( LLVM_USE_FOLDERS )
 182   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 183 endif()
 184
 185 include(VersionFromVCS)
 186
 187 option(LLVM_APPEND_VC_REV
 188   "Embed the version control system revision in LLVM" ON)
 189
 190 set(PACKAGE_NAME LLVM)
 191 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 192 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 193
 194 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 195   "Default URL where bug reports are to be submitted.")
 196
 197 # Configure CPack.
 198 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 199 set(CPACK_PACKAGE_VENDOR "LLVM")
 200 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 201 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 202 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 203 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 204 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 205 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 206 if(WIN32 AND NOT UNIX)
 207   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 208   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 209   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 210   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 211   set(CPACK_NSIS_MODIFY_PATH "ON")
 212   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 213   if( CMAKE_CL_64 )
 214     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 215   endif()
 216 endif()
 217 include(CPack)
 218
 219 # Sanity check our source directory to make sure that we are not trying to
 220 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 221 # sure that we don't have any stray generated files lying around in the tree
 222 # (which would end up getting picked up by header search, instead of the correct
 223 # versions).
 224 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 225   message(FATAL_ERROR "In-source builds are not allowed.
 226 Please create a directory and run cmake from there, passing the path
 227 to this source directory as the last argument.
 228 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 229 Please delete them.")
 230 endif()
 231
 232 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 233
 234 if (CMAKE_BUILD_TYPE AND
 235     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 236   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 237 endif()
 238
 239 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 240
 241 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 242 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 243
 244 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 245     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 246 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 247
 248 # They are used as destination of target generators.
 249 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 250 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 251 if(WIN32 OR CYGWIN)
 252   # DLL platform -- put DLLs into bin.
 253   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 254 else()
 255   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 256 endif()
 257
 258 # Each of them corresponds to llvm-config's.
 259 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 260 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 261 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 262 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 263 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 264
 265 # Note: LLVM_CMAKE_PATH does not include generated files
 266 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 267 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 268 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 269
 270 # List of all targets to be built by default:
 271 set(LLVM_ALL_TARGETS
 272   AArch64
 273   AMDGPU
 274   ARM
 275   BPF
 276   Hexagon
 277   Lanai
 278   Mips
 279   MSP430
 280   NVPTX
 281   PowerPC
 282   Sparc
 283   SystemZ
 284   WebAssembly
 285   X86
 286   XCore
 287   )
 288
 289 # List of targets with JIT support:
 290 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 291
 292 set(LLVM_TARGETS_TO_BUILD "all"
 293     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 294
 295 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 296   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 297
 298 option(BUILD_SHARED_LIBS
 299   "Build all libraries as shared libraries instead of static" OFF)
 300
 301 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 302 if(LLVM_ENABLE_BACKTRACES)
 303   set(ENABLE_BACKTRACES 1)
 304 endif()
 305
 306 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 307
 308 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 309 if(LLVM_ENABLE_CRASH_OVERRIDES)
 310   set(ENABLE_CRASH_OVERRIDES 1)
 311 endif()
 312
 313 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 314
 315 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 316 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 317 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 318
 319 set(LLVM_TARGET_ARCH "host"
 320   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 321
 322 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 323
 324 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 325
 326 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 327
 328 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 329
 330 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 331
 332 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 333
 334 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 335
 336 find_package(Z3 4.7.1)
 337
 338 if (LLVM_Z3_INSTALL_DIR)
 339   if (NOT Z3_FOUND)
 340     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 341   endif()
 342 endif()
 343
 344 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 345
 346 option(LLVM_ENABLE_Z3_SOLVER
 347   "Enable Support for the Z3 constraint solver in LLVM."
 348   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 349 )
 350
 351 if (LLVM_ENABLE_Z3_SOLVER)
 352   if (NOT Z3_FOUND)
 353     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 354   endif()
 355
 356   set(LLVM_WITH_Z3 1)
 357 endif()
 358
 359 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 360   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 361 endif()
 362
 363 set(LLVM_TARGETS_TO_BUILD
 364    ${LLVM_TARGETS_TO_BUILD}
 365    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 366 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 367
 368 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 369 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 370 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 371 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 372   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 373   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 374 else()
 375   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 376   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 377 endif()
 378 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 379 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 380 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 381 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 382
 383 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 384
 385 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 386   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 387 else()
 388   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 389 endif()
 390
 391 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 392
 393 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 394   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 395
 396 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 397        "Set to ON to force using an old, unsupported host toolchain." OFF)
 398
 399 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 400        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 401
 402 option(LLVM_USE_INTEL_JITEVENTS
 403   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 404   OFF)
 405
 406 if( LLVM_USE_INTEL_JITEVENTS )
 407   # Verify we are on a supported platform
 408   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 409     message(FATAL_ERROR
 410       "Intel JIT API support is available on Linux and Windows only.")
 411   endif()
 412 endif( LLVM_USE_INTEL_JITEVENTS )
 413
 414 option(LLVM_USE_OPROFILE
 415   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 416
 417 option(LLVM_EXTERNALIZE_DEBUGINFO
 418   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 419
 420 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 421   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 422
 423 # If enabled, verify we are on a platform that supports oprofile.
 424 if( LLVM_USE_OPROFILE )
 425   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 426     message(FATAL_ERROR "OProfile support is available on Linux only.")
 427   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 428 endif( LLVM_USE_OPROFILE )
 429
 430 option(LLVM_USE_PERF
 431   "Use perf JIT interface to inform perf about JIT code" OFF)
 432
 433 # If enabled, verify we are on a platform that supports perf.
 434 if( LLVM_USE_PERF )
 435   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 436     message(FATAL_ERROR "perf support is available on Linux only.")
 437   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 438 endif( LLVM_USE_PERF )
 439
 440 set(LLVM_USE_SANITIZER "" CACHE STRING
 441   "Define the sanitizer used to build binaries and tests.")
 442 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 443 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 444   "Path to fuzzing library for linking with fuzz targets")
 445
 446 option(LLVM_USE_SPLIT_DWARF
 447   "Use -gsplit-dwarf when compiling llvm." OFF)
 448
 449 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 450 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 451
 452 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 453   set(POLLY_IN_TREE TRUE)
 454 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 455   set(POLLY_IN_TREE TRUE)
 456 else()
 457   set(POLLY_IN_TREE FALSE)
 458 endif()
 459
 460 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 461   set(WITH_POLLY ON)
 462 else()
 463   set(WITH_POLLY OFF)
 464 endif()
 465
 466 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 467   set(LINK_POLLY_INTO_TOOLS ON)
 468 else()
 469   set(LINK_POLLY_INTO_TOOLS OFF)
 470 endif()
 471
 472 # Define an option controlling whether we should build for 32-bit on 64-bit
 473 # platforms, where supported.
 474 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 475   # TODO: support other platforms and toolchains.
 476   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 477 endif()
 478
 479 # Define the default arguments to use with 'lit', and an option for the user to
 480 # override.
 481 set(LIT_ARGS_DEFAULT "-sv")
 482 if (MSVC_IDE OR XCODE)
 483   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 484 endif()
 485 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 486
 487 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 488 if( WIN32 AND NOT CYGWIN )
 489   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 490 endif()
 491
 492 # Define options to control the inclusion and default build behavior for
 493 # components which may not strictly be necessary (tools, examples, and tests).
 494 #
 495 # This is primarily to support building smaller or faster project files.
 496 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 497 option(LLVM_BUILD_TOOLS
 498   "Build the LLVM tools. If OFF, just generate build targets." ON)
 499
 500 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 501 option(LLVM_BUILD_UTILS
 502   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 503
 504 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 505 option(LLVM_BUILD_RUNTIMES
 506   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 507
 508 option(LLVM_BUILD_RUNTIME
 509   "Build the LLVM runtime libraries." ON)
 510 option(LLVM_BUILD_EXAMPLES
 511   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 512 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 513
 514 option(LLVM_BUILD_TESTS
 515   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 516 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 517 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 518
 519 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 520 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 521 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 522
 523 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 524 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 525 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 526 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 527 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 528 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 529
 530 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 531     CACHE STRING "Doxygen-generated HTML documentation install directory")
 532 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 533     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 534
 535 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 536   "Build compiler-rt as an external project." OFF)
 537
 538 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 539   "Show target and host info when tools are invoked with --version." ON)
 540
 541 # You can configure which libraries from LLVM you want to include in the
 542 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 543 # list of LLVM components. All component names handled by llvm-config are valid.
 544 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 545   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 546     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 547 endif()
 548 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 549 if(MSVC)
 550   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 551 else()
 552   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 553 endif()
 554 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 555 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 556   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 557 endif()
 558 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 559
 560 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 561 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 562   set(LLVM_USE_HOST_TOOLS ON)
 563 endif()
 564
 565 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 566   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 567 else()
 568   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 569 endif()
 570
 571 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 572     LLVM_ENABLE_IR_PGO)
 573   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 574     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 575     # for spining disks. Anything higher may only help on slower mediums.
 576     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 577   endif()
 578   if(NOT LLVM_PROFILE_FILE_PATTERN)
 579     if(NOT LLVM_PROFILE_DATA_DIR)
 580       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 581     endif()
 582                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 583   endif()
 584   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 585     if(NOT LLVM_CSPROFILE_DATA_DIR)
 586       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 587     endif()
 588     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 589   endif()
 590 endif()
 591
 592 if (LLVM_BUILD_STATIC)
 593   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 594 endif()
 595
 596 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 597 if(CMAKE_HOST_APPLE AND APPLE)
 598   include(UseLibtool)
 599 endif()
 600
 601 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 602 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 603 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 604
 605 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 606   "Enable per-target runtimes directory")
 607
 608 # All options referred to from HandleLLVMOptions have to be specified
 609 # BEFORE this include, otherwise options will not be correctly set on
 610 # first cmake run
 611 include(config-ix)
 612
 613 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 614   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 615 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 616
 617 # By default, we target the host, but this can be overridden at CMake
 618 # invocation time.
 619 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 620   "Default target for which LLVM will generate code." )
 621 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 622 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 623 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 624
 625 if(WIN32 OR CYGWIN)
 626   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 627     set(LLVM_ENABLE_PLUGINS_default ON)
 628   else()
 629     set(LLVM_ENABLE_PLUGINS_default OFF)
 630   endif()
 631 else()
 632   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 633 endif()
 634 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 635
 636 include(HandleLLVMOptions)
 637
 638 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 639 # FIXME: We should support systems with only Python 3, but that requires work
 640 # on LLDB.
 641 set(Python_ADDITIONAL_VERSIONS 2.7)
 642 include(FindPythonInterp)
 643 if( NOT PYTHONINTERP_FOUND )
 644   message(FATAL_ERROR
 645 "Unable to find Python interpreter, required for builds and testing.
 646
 647 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 648 endif()
 649
 650 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 651   message(FATAL_ERROR "Python 2.7 or newer is required")
 652 endif()
 653
 654 ######
 655 # LLVMBuild Integration
 656 #
 657 # We use llvm-build to generate all the data required by the CMake based
 658 # build system in one swoop:
 659 #
 660 #  - We generate a file (a CMake fragment) in the object root which contains
 661 #    all the definitions that are required by CMake.
 662 #
 663 #  - We generate the library table used by llvm-config.
 664 #
 665 #  - We generate the dependencies for the CMake fragment, so that we will
 666 #    automatically reconfigure ourselves.
 667
 668 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 669 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 670   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 671 set(LLVMBUILDCMAKEFRAG
 672   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 673
 674 # Create the list of optional components that are enabled
 675 if (LLVM_USE_INTEL_JITEVENTS)
 676   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 677 endif (LLVM_USE_INTEL_JITEVENTS)
 678 if (LLVM_USE_OPROFILE)
 679   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 680 endif (LLVM_USE_OPROFILE)
 681 if (LLVM_USE_PERF)
 682   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 683 endif (LLVM_USE_PERF)
 684
 685 message(STATUS "Constructing LLVMBuild project information")
 686 execute_process(
 687   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 688             --native-target "${LLVM_NATIVE_ARCH}"
 689             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 690             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 691             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 692             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 693             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 694             ERROR_VARIABLE LLVMBUILDERRORS
 695             OUTPUT_STRIP_TRAILING_WHITESPACE
 696             ERROR_STRIP_TRAILING_WHITESPACE
 697   RESULT_VARIABLE LLVMBUILDRESULT)
 698
 699 # On Win32, CMake doesn't properly handle piping the default output/error
 700 # streams into the GUI console. So, we explicitly catch and report them.
 701 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 702   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 703 endif()
 704 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 705   message(FATAL_ERROR
 706     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 707 endif()
 708
 709 # Include the generated CMake fragment. This will define properties from the
 710 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 711 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 712 # files change.
 713 include(${LLVMBUILDCMAKEFRAG})
 714
 715 ######
 716
 717 # Configure all of the various header file fragments LLVM uses which depend on
 718 # configuration variables.
 719 set(LLVM_ENUM_TARGETS "")
 720 set(LLVM_ENUM_ASM_PRINTERS "")
 721 set(LLVM_ENUM_ASM_PARSERS "")
 722 set(LLVM_ENUM_DISASSEMBLERS "")
 723 foreach(t ${LLVM_TARGETS_TO_BUILD})
 724   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 725
 726   list(FIND LLVM_ALL_TARGETS ${t} idx)
 727   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 728   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 729   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 730   # this test just makes sure that any experimental targets were passed via
 731   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 732   if( idx LESS 0 AND idy LESS 0 )
 733     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 734       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 735   else()
 736     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 737   endif()
 738
 739   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 740   if( asmp_file )
 741     set(LLVM_ENUM_ASM_PRINTERS
 742       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 743   endif()
 744   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 745     set(LLVM_ENUM_ASM_PARSERS
 746       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 747   endif()
 748   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 749     set(LLVM_ENUM_DISASSEMBLERS
 750       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 751   endif()
 752 endforeach(t)
 753
 754 # Produce the target definition files, which provide a way for clients to easily
 755 # include various classes of targets.
 756 configure_file(
 757   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 758   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 759   )
 760 configure_file(
 761   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 762   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 763   )
 764 configure_file(
 765   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 766   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 767   )
 768 configure_file(
 769   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 770   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 771   )
 772
 773 # Configure the three LLVM configuration header files.
 774 configure_file(
 775   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 776   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 777 configure_file(
 778   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 779   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 780 configure_file(
 781   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 782   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 783
 784 # Add target for generating source rpm package.
 785 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 786     CACHE FILEPATH ".spec file to use for srpm generation")
 787 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 788 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 789
 790 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 791 string(LENGTH "${revision}" revision_length)
 792 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 793   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 794 else()
 795   set(LLVM_RPM_SPEC_REVISION "${revision}")
 796 endif()
 797
 798 configure_file(
 799   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 800   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 801
 802 add_custom_target(srpm
 803   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 804   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 805 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 806
 807
 808 # They are not referenced. See set_output_directory().
 809 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 810 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 811 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 812
 813 if(APPLE AND DARWIN_LTO_LIBRARY)
 814   set(CMAKE_EXE_LINKER_FLAGS
 815     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 816   set(CMAKE_SHARED_LINKER_FLAGS
 817     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 818   set(CMAKE_MODULE_LINKER_FLAGS
 819     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 820 endif()
 821
 822 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
 823 # break things. In this case we need to enable the large-file API as well.
 824 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 825           add_definitions("-D_XOPEN_SOURCE=700")
 826           add_definitions("-D_LARGE_FILE_API")
 827 endif()
 828
 829 # Work around a broken bfd ld behavior. When linking a binary with a
 830 # foo.so library, it will try to find any library that foo.so uses and
 831 # check its symbols. This is wasteful (the check was done when foo.so
 832 # was created) and can fail since it is not the dynamic linker and
 833 # doesn't know how to handle search paths correctly.
 834 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 835   set(CMAKE_EXE_LINKER_FLAGS
 836       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 837 endif()
 838
 839 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 840
 841 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 842
 843 # when crosscompiling import the executable targets from a file
 844 if(LLVM_USE_HOST_TOOLS)
 845   include(CrossCompile)
 846 endif(LLVM_USE_HOST_TOOLS)
 847 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 848 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 849 # (this is a variable that CrossCompile sets on recursive invocations)
 850 endif()
 851
 852 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 853   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 854   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 855   include_directories(SYSTEM "/usr/local/include")
 856   link_directories("/usr/local/lib")
 857 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 858
 859 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 860    # special hack for Solaris to handle crazy system sys/regset.h
 861    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 862 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 863
 864 # Make sure we don't get -rdynamic in every binary. For those that need it,
 865 # use export_executable_symbols(target).
 866 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 867
 868 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 869   "Profiling data file to use when compiling in order to improve runtime performance.")
 870
 871 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 872   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 873     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 874   else()
 875     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 876   endif()
 877 endif()
 878
 879 include(AddLLVM)
 880 include(TableGen)
 881
 882 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 883   # People report that -O3 is unreliable on MinGW. The traditional
 884   # build also uses -O2 for that reason:
 885   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 886 endif()
 887
 888 # Put this before tblgen. Else we have a circular dependence.
 889 add_subdirectory(lib/Demangle)
 890 add_subdirectory(lib/Support)
 891 add_subdirectory(lib/TableGen)
 892
 893 add_subdirectory(utils/TableGen)
 894
 895 add_subdirectory(include/llvm)
 896
 897 add_subdirectory(lib)
 898
 899 if( LLVM_INCLUDE_UTILS )
 900   add_subdirectory(utils/FileCheck)
 901   add_subdirectory(utils/PerfectShuffle)
 902   add_subdirectory(utils/count)
 903   add_subdirectory(utils/not)
 904   add_subdirectory(utils/yaml-bench)
 905 else()
 906   if ( LLVM_INCLUDE_TESTS )
 907     message(FATAL_ERROR "Including tests when not building utils will not work.
 908     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 909   endif()
 910 endif()
 911
 912 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 913 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 914   add_subdirectory(utils/LLVMVisualizers)
 915 endif()
 916
 917 foreach( binding ${LLVM_BINDINGS_LIST} )
 918   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 919     add_subdirectory(bindings/${binding})
 920   endif()
 921 endforeach()
 922
 923 add_subdirectory(projects)
 924
 925 if( LLVM_INCLUDE_TOOLS )
 926   add_subdirectory(tools)
 927 endif()
 928
 929 if( LLVM_INCLUDE_RUNTIMES )
 930   add_subdirectory(runtimes)
 931 endif()
 932
 933 if( LLVM_INCLUDE_EXAMPLES )
 934   add_subdirectory(examples)
 935 endif()
 936
 937 if( LLVM_INCLUDE_TESTS )
 938   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 939     include(LLVMExternalProjectUtils)
 940     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 941       USE_TOOLCHAIN
 942       EXCLUDE_FROM_ALL
 943       NO_INSTALL
 944       ALWAYS_CLEAN)
 945   endif()
 946   add_subdirectory(utils/lit)
 947   add_subdirectory(test)
 948   add_subdirectory(unittests)
 949   if( LLVM_INCLUDE_UTILS )
 950     add_subdirectory(utils/unittest)
 951   endif()
 952
 953   if (WIN32)
 954     # This utility is used to prevent crashing tests from calling Dr. Watson on
 955     # Windows.
 956     add_subdirectory(utils/KillTheDoctor)
 957   endif()
 958
 959   # Add a global check rule now that all subdirectories have been traversed
 960   # and we know the total set of lit testsuites.
 961   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 962   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 963   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 964   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 965   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 966                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 967   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 968                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 969   add_lit_target(check-all
 970     "Running all regression tests"
 971     ${LLVM_LIT_TESTSUITES}
 972     PARAMS ${LLVM_LIT_PARAMS}
 973     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 974     ARGS ${LLVM_LIT_EXTRA_ARGS}
 975     )
 976   if(TARGET check-runtimes)
 977     add_dependencies(check-all check-runtimes)
 978   endif()
 979   add_custom_target(test-depends
 980                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 981   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 982 endif()
 983
 984 if (LLVM_INCLUDE_DOCS)
 985   add_subdirectory(docs)
 986 endif()
 987
 988 add_subdirectory(cmake/modules)
 989
 990 # Do this last so that all lit targets have already been created.
 991 if (LLVM_INCLUDE_UTILS)
 992   add_subdirectory(utils/llvm-lit)
 993 endif()
 994
 995 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 996   install(DIRECTORY include/llvm include/llvm-c
 997     DESTINATION include
 998     COMPONENT llvm-headers
 999     FILES_MATCHING
1000     PATTERN "*.def"
1001     PATTERN "*.h"
1002     PATTERN "*.td"
1003     PATTERN "*.inc"
1004     PATTERN "LICENSE.TXT"
1005     PATTERN ".svn" EXCLUDE
1006     )
1007
1008   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1009     DESTINATION include
1010     COMPONENT llvm-headers
1011     FILES_MATCHING
1012     PATTERN "*.def"
1013     PATTERN "*.h"
1014     PATTERN "*.gen"
1015     PATTERN "*.inc"
1016     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1017     PATTERN "CMakeFiles" EXCLUDE
1018     PATTERN "config.h" EXCLUDE
1019     PATTERN ".svn" EXCLUDE
1020     )
1021
1022   if (LLVM_INSTALL_MODULEMAPS)
1023     install(DIRECTORY include/llvm include/llvm-c
1024             DESTINATION include
1025             COMPONENT llvm-headers
1026             FILES_MATCHING
1027             PATTERN "module.modulemap"
1028             )
1029     install(FILES include/llvm/module.install.modulemap
1030             DESTINATION include/llvm
1031             COMPONENT llvm-headers
1032             RENAME "module.extern.modulemap"
1033             )
1034   endif(LLVM_INSTALL_MODULEMAPS)
1035
1036   # Installing the headers needs to depend on generating any public
1037   # tablegen'd headers.
1038   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1039   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1040
1041   if (NOT LLVM_ENABLE_IDE)
1042     add_llvm_install_targets(install-llvm-headers
1043                              DEPENDS llvm-headers
1044                              COMPONENT llvm-headers)
1045   endif()
1046
1047   # Custom target to install all libraries.
1048   add_custom_target(llvm-libraries)
1049   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1050
1051   if (NOT LLVM_ENABLE_IDE)
1052     add_llvm_install_targets(install-llvm-libraries
1053                              DEPENDS llvm-libraries
1054                              COMPONENT llvm-libraries)
1055   endif()
1056
1057   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1058   if(LLVM_LIBS)
1059     list(REMOVE_DUPLICATES LLVM_LIBS)
1060     foreach(lib ${LLVM_LIBS})
1061       add_dependencies(llvm-libraries ${lib})
1062       if (NOT LLVM_ENABLE_IDE)
1063         add_dependencies(install-llvm-libraries install-${lib})
1064       endif()
1065     endforeach()
1066   endif()
1067 endif()
1068
1069 # This must be at the end of the LLVM root CMakeLists file because it must run
1070 # after all targets are created.
1071 include(LLVMDistributionSupport)
1072 llvm_distribution_add_targets()
1073
1074 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1075 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1076   include(InstallRequiredSystemLibraries)
1077 endif()
1078
1079 if (LLVM_INCLUDE_BENCHMARKS)
1080   # Override benchmark defaults so that when the library itself is updated these
1081   # modifications are not lost.
1082   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1083   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1084   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1085   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1086   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1087   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1088   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1089
1090   add_subdirectory(utils/benchmark)
1091   add_subdirectory(benchmarks)
1092 endif()