DownloadDeps.cmd

   1 @echo off
   2 setlocal
   3 set path="%ProgramFiles%\7-zip";"%ProgramFiles(x86)%\7-zip";%path%
   4 7z > NUL
   5 if not %ERRORLEVEL% == 0 (
   6   echo 7-Zip is not installed
   7   goto :eof
   8 )
   9 @echo on
  10
  11 set downloadsdir=%~dp0\build\WinMergeDownloadDeps
  12 set urls_destdirs=^
  13 https://github.com/WinMerge/winmerge/releases/download/winmerge_manual_another_build_tools_v2/winmerge_manual_another_build_tools_v2.zip!Docs\Manual\Tools ^
  14 https://github.com/WinMerge/winmerge/releases/download/ShellExtension-1.18.4.0/ShellExtension-1.18.4.0.zip!Build ^
  15 https://github.com/WinMerge/winmerge/releases/download/Merge7z2107.0/Merge7z2107.0-x86.zip!Build\x86\Release ^
  16 https://github.com/WinMerge/winmerge/releases/download/Merge7z2107.0/Merge7z2107.0-x64.zip!Build\X64\Release ^
  17 https://github.com/WinMerge/winmerge/releases/download/Merge7z2107.0/Merge7z2107.0-ARM.zip!Build\ARM64\Release ^
  18 https://github.com/WinMerge/winmerge/releases/download/Merge7z2107.0/Merge7z2107.0-ARM64.zip!Build\ARM64\Release ^
  19 https://github.com/WinMerge/frhed/releases/download/0.10904.2017/frhed-0.10904.2017.8-x86.zip!Build\x86\Release ^
  20 https://github.com/WinMerge/frhed/releases/download/0.10904.2017/frhed-0.10904.2017.8-x64.zip!Build\x64\Release ^
  21 https://github.com/WinMerge/frhed/releases/download/0.10904.2017/frhed-0.10904.2017.8-ARM.zip!Build\ARM\Release ^
  22 https://github.com/WinMerge/frhed/releases/download/0.10904.2017/frhed-0.10904.2017.8-ARM64.zip!Build\ARM64\Release ^
  23 https://github.com/WinMerge/winimerge/releases/download/v1.0.33/winimerge-1.0.33.0-x86.zip!Build\x86\Release ^
  24 https://github.com/WinMerge/winimerge/releases/download/v1.0.33/winimerge-1.0.33.0-x64.zip!Build\x64\Release ^
  25 https://github.com/WinMerge/winimerge/releases/download/v1.0.33/winimerge-1.0.33.0-ARM.zip!Build\ARM\Release ^
  26 https://github.com/WinMerge/winimerge/releases/download/v1.0.33/winimerge-1.0.33.0-ARM64.zip!Build\ARM64\Release ^
  27 https://github.com/WinMerge/patch/releases/download/v2.5.9-7/patch-2.5.9-7-bin.zip!Build\GnuWin32 ^
  28 https://github.com/htacg/tidy-html5/releases/download/5.4.0/tidy-5.4.0-w32-mt-XP.zip!Build\tidy-html5 ^
  29 https://github.com/htacg/tidy-html5/archive/refs/tags/5.4.0.zip!Build\tidy-html5 ^
  30 https://github.com/stedolan/jq/releases/download/jq-1.4/jq-win32.exe!Build\jq ^
  31 https://github.com/stedolan/jq/archive/refs/tags/jq-1.4.zip!Build\jq ^
  32 http://www.magicnotes.com/steelbytes/SBAppLocale_ENG.zip!Docs\Manual\Tools
  33
  34 pushd "%~dp0"
  35 mkdir %downloadsdir% 2> NUL
  36
  37 for %%p in (%urls_destdirs%) do (
  38   for /F "tokens=1,2 delims=!" %%u in ("%%p") do (
  39     if not exist %downloadsdir%\%%~nxu (
  40       powershell -command "[Net.ServicePointManager]::SecurityProtocol = [Net.SecurityProtocolType]::Tls12; Invoke-WebRequest %%u -Outfile %downloadsdir%\%%~nxu"
  41     )
  42     if "%%~xu" == ".zip" (
  43       7z x %downloadsdir%\%%~nxu -aoa -o%%v
  44     ) else (
  45       mkdir %%v > NUL
  46       copy %downloadsdir%\%%~nxu %%v
  47     )
  48   )
  49 )
  50
  51 for /d %%i in (build\tidy-html5\tidy-5.4.0-w32-mt-XP\*) do move %%i build\tidy-html5\
  52
  53 for %%i in (x86 x64 ARM ARM64) do (
  54   for %%j in (Release Debug Test) do (
  55     mkdir Build\%%i\%%j\Merge7z 2> NUL
  56     mkdir Build\%%i\%%j\WinIMerge 2> NUL
  57     mkdir Build\%%i\%%j\Frhed 2> NUL
  58     mkdir Build\%%i\%%j\Filters 2> NUL
  59     mkdir Build\%%i\%%j\ColorSchemes 2> NUL
  60     mkdir Build\%%i\%%j\MergePlugins 2> NUL
  61     mkdir Build\%%i\%%j\Commands\jq 2> NUL
  62     mkdir Build\%%i\%%j\Commands\tidy-html5 2> NUL
  63     mkdir Build\%%i\%%j\Commands\GnuWin32 2> NUL
  64     xcopy /s/y Build\%%i\Release\Merge7z Build\%%i\%%j\Merge7z\
  65     xcopy /s/y Build\%%i\Release\Frhed Build\%%i\%%j\Frhed\
  66     copy Build\%%i\Release\WinIMerge\WinIMergeLib.dll Build\%%i\%%j\WinIMerge\
  67     xcopy /s/y Build\GnuWin32 Build\%%i\%%j\Commands\GnuWin32\
  68     copy Build\jq\jq-win32.exe Build\%%i\%%j\Commands\jq\jq.exe
  69     copy Build\jq\jq-jq-1.4\COPYING Build\%%i\%%j\Commands\jq\
  70     copy Build\tidy-html5\bin\tidy.* Build\%%i\%%j\Commands\tidy-html5\
  71     copy Build\tidy-html5\tidy-html5-5.4.0\README\LICENSE.md Build\%%i\%%j\Commands\tidy-html5\
  72     xcopy /s/y Plugins\Commands Build\%%i\%%j\Commands
  73     xcopy /s/y Filters Build\%%i\%%j\Filters\
  74     xcopy /s/y ColorSchemes Build\%%i\%%j\ColorSchemes\
  75     xcopy /s/y Plugins\dlls\*.sct Build\%%i\%%j\MergePlugins\
  76     xcopy /s/y Plugins\Plugins.xml Build\%%i\%%j\MergePlugins\
  77     xcopy /s/y Build\ShellExtension\WinMergeContextMenuPackage.msix Build\%%i\%%j
  78     copy Plugins\dlls\%%i\*.dll Build\%%i\%%j\MergePlugins\
  79   )
  80 )
  81
  82 popd