JavaScriptCore/JavaScriptCore.pri

   1 # JavaScriptCore - Qt4 build info
   2
   3 include(../common.pri)
   4
   5 VPATH += $$PWD
   6
   7 # Use a config-specific target to prevent parallel builds file clashes on Mac
   8 mac: CONFIG(debug, debug|release): JAVASCRIPTCORE_TARGET = jscored
   9 else: JAVASCRIPTCORE_TARGET = jscore
  10
  11 # Output in JavaScriptCore/<config>
  12 CONFIG(debug, debug|release) : JAVASCRIPTCORE_DESTDIR = debug
  13 else: JAVASCRIPTCORE_DESTDIR = release
  14
  15 CONFIG(standalone_package) {
  16     isEmpty(JSC_GENERATED_SOURCES_DIR):JSC_GENERATED_SOURCES_DIR = $$PWD/generated
  17 } else {
  18     isEmpty(JSC_GENERATED_SOURCES_DIR):JSC_GENERATED_SOURCES_DIR = generated
  19 }
  20
  21 CONFIG(standalone_package): DEFINES *= NDEBUG
  22
  23 symbian: {
  24     # Need to guarantee this comes before system includes of /epoc32/include
  25     MMP_RULES += "USERINCLUDE ../JavaScriptCore/profiler"
  26     LIBS += -lhal
  27     # For hal.h
  28     INCLUDEPATH *= $$MW_LAYER_SYSTEMINCLUDE
  29 }
  30
  31 INCLUDEPATH = \
  32     $$PWD \
  33     $$PWD/.. \
  34     $$PWD/assembler \
  35     $$PWD/bytecode \
  36     $$PWD/bytecompiler \
  37     $$PWD/debugger \
  38     $$PWD/interpreter \
  39     $$PWD/jit \
  40     $$PWD/parser \
  41     $$PWD/pcre \
  42     $$PWD/profiler \
  43     $$PWD/runtime \
  44     $$PWD/wtf \
  45     $$PWD/wtf/gobject \
  46     $$PWD/wtf/symbian \
  47     $$PWD/wtf/unicode \
  48     $$PWD/yarr \
  49     $$PWD/API \
  50     $$PWD/ForwardingHeaders \
  51     $$JSC_GENERATED_SOURCES_DIR \
  52     $$INCLUDEPATH
  53
  54 win32-*: DEFINES += _HAS_TR1=0
  55
  56 DEFINES += BUILDING_QT__ BUILDING_JavaScriptCore BUILDING_WTF
  57
  58 # CONFIG += text_breaking_with_icu
  59
  60 contains (CONFIG, text_breaking_with_icu) {
  61     DEFINES += WTF_USE_QT_ICU_TEXT_BREAKING=1
  62 }
  63
  64 wince* {
  65     INCLUDEPATH += $$QT_SOURCE_TREE/src/3rdparty/ce-compat
  66     INCLUDEPATH += $$PWD/../JavaScriptCore/os-win32
  67 }
  68
  69
  70 defineTest(addJavaScriptCoreLib) {
  71     # Argument is the relative path to JavaScriptCore.pro's qmake output
  72     pathToJavaScriptCoreOutput = $$ARGS/$$JAVASCRIPTCORE_DESTDIR
  73
  74     win32-msvc*|wince* {
  75         LIBS += -L$$pathToJavaScriptCoreOutput
  76         LIBS += -l$$JAVASCRIPTCORE_TARGET
  77         POST_TARGETDEPS += $${pathToJavaScriptCoreOutput}$${QMAKE_DIR_SEP}$${JAVASCRIPTCORE_TARGET}.lib
  78     } else:symbian {
  79         LIBS += -l$${JAVASCRIPTCORE_TARGET}.lib
  80         # The default symbian build system does not use library paths at all. However when building with
  81         # qmake's symbian makespec that uses Makefiles
  82         QMAKE_LIBDIR += $$pathToJavaScriptCoreOutput
  83         POST_TARGETDEPS += $${pathToJavaScriptCoreOutput}$${QMAKE_DIR_SEP}$${JAVASCRIPTCORE_TARGET}.lib
  84     } else {
  85         # Make sure jscore will be early in the list of libraries to workaround a bug in MinGW
  86         # that can't resolve symbols from QtCore if libjscore comes after.
  87         QMAKE_LIBDIR = $$pathToJavaScriptCoreOutput $$QMAKE_LIBDIR
  88         LIBS += -l$$JAVASCRIPTCORE_TARGET
  89         POST_TARGETDEPS += $${pathToJavaScriptCoreOutput}$${QMAKE_DIR_SEP}lib$${JAVASCRIPTCORE_TARGET}.a
  90     }
  91
  92     win32-* {
  93         LIBS += -lwinmm
  94     }
  95
  96     # The following line is to prevent qmake from adding jscore to libQtWebKit's prl dependencies.
  97     # The compromise we have to accept by disabling explicitlib is to drop support to link QtWebKit and QtScript
  98     # statically in applications (which isn't used often because, among other things, of licensing obstacles).
  99     CONFIG -= explicitlib
 100
 101     export(QMAKE_LIBDIR)
 102     export(LIBS)
 103     export(POST_TARGETDEPS)
 104     export(CONFIG)
 105
 106     return(true)
 107 }