JavaScriptCore/JavaScriptCore.pro

   1 # JavaScriptCore - qmake build info
   2 CONFIG += building-libs
   3 include($$PWD/../WebKit.pri)
   4
   5 TEMPLATE = lib
   6 CONFIG += staticlib
   7 TARGET = JavaScriptCore
   8
   9 CONFIG += depend_includepath
  10
  11 contains(QT_CONFIG, embedded):CONFIG += embedded
  12
  13 CONFIG(QTDIR_build) {
  14     GENERATED_SOURCES_DIR = $$PWD/generated
  15     OLDDESTDIR = $$DESTDIR
  16     include($$QT_SOURCE_TREE/src/qbase.pri)
  17     INSTALLS =
  18     DESTDIR = $$OLDDESTDIR
  19     PRECOMPILED_HEADER = $$PWD/../WebKit/qt/WebKit_pch.h
  20     DEFINES *= NDEBUG
  21 }
  22
  23 isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
  24 GENERATED_SOURCES_DIR_SLASH = $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}
  25
  26 INCLUDEPATH += $$GENERATED_SOURCES_DIR
  27
  28 !CONFIG(QTDIR_build) {
  29     CONFIG(debug, debug|release) {
  30         OBJECTS_DIR = obj/debug
  31     } else { # Release
  32         OBJECTS_DIR = obj/release
  33     }
  34 }
  35
  36 CONFIG(release):!CONFIG(QTDIR_build) {
  37     contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
  38     unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions
  39 }
  40
  41 linux-*: DEFINES += HAVE_STDINT_H
  42 freebsd-*: DEFINES += HAVE_PTHREAD_NP_H
  43
  44 DEFINES += BUILD_WEBKIT
  45
  46 win32-*: DEFINES += _HAS_TR1=0
  47
  48 # Pick up 3rdparty libraries from INCLUDE/LIB just like with MSVC
  49 win32-g++ {
  50     TMPPATH            = $$quote($$(INCLUDE))
  51     QMAKE_INCDIR_POST += $$split(TMPPATH,";")
  52     TMPPATH            = $$quote($$(LIB))
  53     QMAKE_LIBDIR_POST += $$split(TMPPATH,";")
  54 }
  55
  56 DEFINES += WTF_USE_JAVASCRIPTCORE_BINDINGS=1
  57
  58 DEFINES += WTF_CHANGES=1
  59
  60 include(JavaScriptCore.pri)
  61
  62 QMAKE_EXTRA_TARGETS += generated_files
  63
  64 lessThan(QT_MINOR_VERSION, 4) {
  65     DEFINES += QT_BEGIN_NAMESPACE="" QT_END_NAMESPACE=""
  66 }
  67
  68 *-g++*:QMAKE_CXXFLAGS_RELEASE -= -O2
  69 *-g++*:QMAKE_CXXFLAGS_RELEASE += -O3