MSP_EXP430FR4133.asm

   1 ; -*- coding: utf-8 -*-
   2
   3 ; Fast Forth For Texas Instrument MSP430FR4133
   4 ;
   5 ; Copyright (C) <2016>  <J.M. THOORENS>
   6 ;
   7 ; This program is free software: you can redistribute it and/or modify
   8 ; it under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; This program is distributed in the hope that it will be useful,
  13 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ; GNU General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ; ======================================================================
  21 ; INIT MSP-EXP430FR4133 board
  22 ; ======================================================================
  23
  24 ; my USBtoUart :
  25 ; http://www.ebay.fr/itm/CP2102-USB-UART-Board-mini-Data-Transfer-Convertor-Module-Development-Board-/251433941479
  26
  27 ; for sd card socket be carefull : pin CD must be present !
  28 ; http://www.ebay.com/itm/2-PCS-SD-Card-Module-Slot-Socket-Reader-For-Arduino-MCU-/181211954262?pt=LH_DefaultDomain_0&hash=item2a3112fc56
  29
  30
  31 ; J101   eZ-FET <-> target
  32 ; -----------------------
  33 ; P1 <-> P2 - NC
  34 ; P3 <-> P4 - TEST  - TEST
  35 ; P5 <-> P6 - RST   - RST
  36 ; P7 <-> P8 - TX1   - P1.0 UCA0 TXD ---> RX UARTtoUSB module
  37 ; P9 <->P10 - RX1   - P1.1 UCA0 RXD <--- TX UARTtoUSB module
  38 ; P11<->P12 - CTS   - P2.4
  39 ; P13<->P14 - RTS   - P2.3
  40 ; P15<->P16 - VCC   - 3V3
  41 ; P17<->P18 - 5V
  42 ; P19<->P20 - GND   - VSS
  43
  44 ; Launchpad Header Left J1
  45 ; ------------------------
  46 ; P1 - 3V3
  47 ; P2 - P8.1 ACLK/A9
  48 ; P3 - P1.1 UCA0 RXD
  49 ; P4 - P1.0 UCA0 TXD
  50 ; P5 - P2.7
  51 ; P6 - P8.0 SMCLK/A8
  52 ; P7 - P5.1 UCB0 CLK
  53 ; P8 - P2.5
  54 ; P9 - P8.2 TA1CLK
  55 ; P10- P8.3 TA1.2
  56
  57 ; Launchpad Header Right J2
  58 ; -------------------------
  59 ; P1 - GND
  60 ; P2 - P1.7 TA0.1/TDO/A7
  61 ; P3 - P1.6 TA0.2/TDI/TCLK/A6
  62 ; P4 - P5.0 UCB0STE
  63 ; P5 - RST
  64 ; P6 - P5.2 UCB0SIMO/UCB0SDA
  65 ; P7 - P5.3 UCB0SOMI/UCB0SCL
  66 ; P8 - P1.3 UCA0STE/A3
  67 ; P9 - P1.4 MCLK/TCK/A4
  68 ; P10- P1.5 TA0CLK/TMS/A5
  69
  70 ; switch-keys:
  71 ; S1 - P1.2
  72 ; S2 - P2.6
  73 ; S3 - RST
  74
  75 ; LEDS:
  76 ; LED1 - P1.0/TXD
  77 ; LED2 - P4.0
  78
  79 ; XTAL LF 32768 Hz
  80 ; Y4 - P4.1 XIN
  81 ; Y4 - P4.2 XOUT
  82
  83 ; LCD
  84 ; L0  - P7.0
  85 ; L1  - P7.1
  86 ; L2  - P7.2
  87 ; L3  - P7.3
  88 ; L4  - P7.4
  89 ; L5  - P7.5
  90 ; L6  - P7.6
  91 ; L7  - P7.7
  92 ; L8  - P3.0
  93 ; L9  - P3.1
  94 ; L10 - P3.2
  95 ; L11 - P3.3
  96 ; L12 - P3.4
  97 ; L13 - P3.5
  98 ; L14 - P3.6
  99 ; L15 - P3.7
 100 ; L16 - P6.0
 101 ; L17 - P6.1
 102 ; L18 - P6.2
 103 ; L19 - P6.3
 104 ; L20 - P6.4
 105 ; L21 - P6.5
 106 ; L22 - P6.6
 107 ; L23 - P6.7
 108 ; L24 - P2.0
 109 ; L25 - P2.1
 110 ; L26 - P2.2
 111 ; L36 - P5.4
 112 ; L37 - P5.5
 113 ; L38 - P5.6
 114 ; L39 - P5.7
 115
 116
 117
 118
 119
 120
 121 ; ===================================================================================
 122 ; in case of 3.3V powered by UARTtoUSB bridge, open J13 straps {RST,TST,V+,5V} BEFORE
 123 ; then wire VCC and GND of bridge onto J13 connector
 124 ; ===================================================================================
 125
 126 ; ---------------------------------------------------
 127 ; MSP  - MSP-EXP430FR4133 LAUNCHPAD <--> OUTPUT WORLD
 128 ; ---------------------------------------------------
 129 ; P1.0 - LED1 red
 130 ; P4.0 - LED2 green
 131 ;
 132 ; P1.2 - S1
 133 ; P2.6 - S2
 134 ;                                 +-4k7-< DeepRST <-- GND
 135 ;                                 |
 136 ; P1.0 - UCA0 TXD       J101.8  --+-> RX  UARTtoUSB bridge
 137 ; P1.1 - UCA0 RXD       J101.10 <---- TX  UARTtoUSB bridge
 138 ; P2.3 - RTS            J101.14 ----> CTS UARTtoUSB bridge (if TERMINALCTSRTS option)
 139 ;  VCC -                J101.16 <---- VCC (optional supply from UARTtoUSB bridge - WARNING ! 3.3V !)
 140 ;  GND -                J101.20 <---> GND (optional supply from UARTtoUSB bridge)
 141 ;
 142 ; P2.7 -                J1.5    <---- OUT IR_Receiver (1 TSOP32236)
 143 ;
 144 ; P4.1 - LFXI 32768Hz quartz
 145 ; P4.2 - LFXO 32768Hz quartz
 146 ;
 147 ; P5.2 - UCB0 SDA/SIMO  J2.6    <---> SDA I2C Slave
 148 ; P5.3 - UCB0 SCL/SOMI  J2.7    <---- SCL I2C Slave
 149 ;
 150 ; P5.1 - UCB0 CLK       J1.7    ----> SD_CLK
 151 ; P5.2 - UCB0 SDA/SIMO  J2.6    ----> SD_SDI
 152 ; P5.3 - UCB0 SCL/SOMI  J2.7    <---- SD_SDO
 153 ; P8.0 -                J1.6    <---- SD_CD (Card Detect)
 154 ; P8.1 -                J1.2    ----> SD_CS (Card Select)
 155 ;
 156 ; P8.2 - Soft I2C_Master J1.9   ----> SDA software I2C Master
 157 ; P8.3 - Soft I2C_Master J1.10  <---> SCL software I2C Master
 158
 159
 160 ; ----------------------------------------------------------------------
 161 ; INIT order : WDT, GPIOs, FRAM, Clock, UARTs...
 162 ; ----------------------------------------------------------------------
 163
 164 ; ----------------------------------------------------------------------
 165 ; POWER ON RESET AND INITIALIZATION : LOCK PMM_LOCKLPM5
 166 ; ----------------------------------------------------------------------
 167
 168 ;              BIS     #LOCKLPM5,&PM5CTL0 ; unlocked by WARM
 169
 170 ; ----------------------------------------------------------------------
 171 ; POWER ON RESET AND INITIALIZATION : WATCHDOG TIMER A
 172 ; ----------------------------------------------------------------------
 173
 174 ; WDT code
 175         MOV #WDTPW+WDTHOLD+WDTCNTCL,&WDTCTL    ; stop WDT
 176
 177 ; ----------------------------------------------------------------------
 178 ; POWER ON RESET AND INITIALIZATION : I/O
 179 ; ----------------------------------------------------------------------
 180
 181 ; ----------------------------------------------------------------------
 182 ; POWER ON RESET AND INITIALIZATION : PORT1/2
 183 ; ----------------------------------------------------------------------
 184
 185 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 186
 187
 188 ; PORT1 usage
 189
 190 ; P1.0 - TX0 --> JP1 --> red LED1 --> GND
 191 ; P1.1 - RX0
 192
 193 Deep_RST_IN .equ P1IN  ; TERMINAL TX  pin as FORTH Deep_RST
 194 Deep_RST    .equ 1     ; TX
 195 TERM_TXRX   .equ 003h  ; TX RX
 196 TERM_SEL    .equ P1SEL0
 197 TERM_REN    .equ P1REN
 198
 199
 200 ; PORTx default wanted state : pins as input with pullup resistor
 201
 202             MOV #-1,&PAOUT  ; OUT1 for all pins
 203             BIS #-1,&PAREN  ; all pins with pullup resistors
 204
 205     .IFDEF TERMINALCTSRTS
 206 HANDSHAKOUT .set    P2OUT
 207 HANDSHAKIN  .set    P2IN
 208 RTS         .set    8       ; P2.3 bit position
 209 CTS         .set    10h     ; P2.4 bit position
 210 ;            BIS.B #RTS,&HANDSHAKOUT
 211     .ENDIF
 212
 213 ; ----------------------------------------------------------------------
 214 ; POWER ON RESET AND INITIALIZATION : PORT3/4
 215 ; ----------------------------------------------------------------------
 216
 217 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 218
 219 ; P3 configuration :
 220
 221 ; P4 configuration :
 222 ; P4.0 - LED2 green
 223 ; P4.1 - LFXI 32768Hz quartz
 224 ; P4.2 - LFXO 32768Hz quartz
 225
 226 ; PORTx default wanted state : pins as input with pullup resistor
 227
 228             MOV #00100h,&PBDIR   ; all pins as inputs else P4.0
 229             MOV #0FEFFh,&PBOUT   ; OUT1 for all pins else P4
 230             BIS #0FEFFh,&PBREN   ; pullup for all pins resistors else P4.0
 231
 232 ; ----------------------------------------------------------------------
 233 ; POWER ON RESET AND INITIALIZATION : PORT5/6
 234 ; ----------------------------------------------------------------------
 235
 236 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 237
 238 ; PORTx default wanted state : pins as input with pullup resistor
 239
 240             MOV     #-1,&PCOUT    ; all pins OUT1
 241             BIS     #-1,&PCREN    ; all pins with pull resistors
 242
 243 ; ----------------------------------------------------------------------
 244 ; POWER ON RESET AND INITIALIZATION : PORT7/8
 245 ; ----------------------------------------------------------------------
 246
 247 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 248
 249 ; PORTx default wanted state : pins as input with pullup resistor
 250
 251             MOV     #-1,&PDOUT    ; all pins OUT1
 252             BIS     #-1,&PDREN    ; all pins with pull resistors
 253
 254 ; ----------------------------------------------------------------------
 255 ; FRAM config
 256 ; ----------------------------------------------------------------------
 257
 258     .IF FREQUENCY = 16
 259             MOV.B   #0A5h, &FRCTL0_H     ; enable FRCTL0 access
 260             MOV.B   #10h, &FRCTL0         ; 1 waitstate @ 16 MHz
 261             MOV.B   #01h, &FRCTL0_H       ; disable FRCTL0 access
 262     .ENDIF
 263
 264 ; ----------------------------------------------------------------------
 265 ; POWER ON RESET SYS config
 266 ; ----------------------------------------------------------------------
 267 ; SYS code
 268 ;    BIC #1,&SYSCFG0 ; enable write program in FRAM
 269     MOV #0A500h,&SYSCFG0 ; enable write MAIN and INFO
 270
 271 ; ----------------------------------------------------------------------
 272 ; POWER ON RESET AND INITIALIZATION : CLOCK SYSTEM
 273 ; ----------------------------------------------------------------------
 274
 275 ; CS code for EXP430FR4133
 276
 277 ; to measure REFO frequency, output ACLK on P8.1:
 278 ;    BIS.B #2,&P8SEL0
 279 ;    BIS.B #2,&P8DIR
 280 ; result : REFO = ? kHz
 281
 282
 283 ; ===================================================================
 284 ; need to adjust FLLN (and DCO) for each device of MSP430fr2xxx family ?
 285 ; (no problem with MSP430FR5xxx families without FLL).
 286 ; ===================================================================
 287
 288     .IF FREQUENCY = 0.5
 289
 290             MOV #0D6h,&CSCTL0          ; preset DCO = 0xD6 (measured value @ 0x180 ; to measure, type 0x180 @ U.)
 291
 292             MOV     #0001h,&CSCTL1      ; Set 1MHZ DCORSEL,disable DCOFTRIM,Modulation
 293 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 294 ;            MOV     #100Dh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO/2),set FLLN=0Dh
 295                                         ; fCOCLKDIV = 32768 x (13+1) = 0.459 MHz ; measured :  MHz
 296 ;            MOV     #100Eh,&CSCTL2      ; Set FLLD=1 (DCOCLKCDIV=DCO/2),set FLLN=0Eh
 297                                         ; fCOCLKDIV = 32768 x (14+1) = 0.491 MHz ; measured :  MHz
 298             MOV     #100Fh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=0Fh
 299                                         ; fCOCLKDIV = 32768 x (15+1) = 0.524 MHz ; measured :  MHz
 300 ; =====================================
 301             MOV     #2,X
 302
 303     .ELSEIF FREQUENCY = 1
 304
 305             MOV #00B4h,&CSCTL0          ; preset DCO = 0xB4 (measured value @ 0x180 ; to measure, type HEX 0x180 ?)
 306
 307             MOV     #0001h,&CSCTL1      ; Set 1MHZ DCORSEL,disable DCOFTRIM,Modulation
 308 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 309 ;            MOV     #001Dh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1Dh
 310                                         ; fCOCLKDIV = 32768 x (29+1) = 0.983 MHz ; measured : 0.989MHz
 311             MOV     #001Eh,&CSCTL2         ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1Eh
 312                                         ; fCOCLKDIV = 32768 x (30+1) = 1.015 MHz ; measured : 1.013MHz
 313 ;            MOV     #001Fh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1Fh
 314                                         ; fCOCLKDIV = 32768 x (31+1) = 1.049 MHz ; measured : 1.046MHz
 315 ; =====================================
 316             MOV     #4,X
 317
 318     .ELSEIF FREQUENCY = 2
 319
 320             MOV #00B4h,&CSCTL0          ; preset DCO = 0xB4 (measured value @ 0x180 ; to measure, type HEX 0x180 ?)
 321
 322             MOV     #0003h,&CSCTL1      ; Set 2MHZ DCORSEL,disable DCOFTRIM,Modulation
 323 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 324 ;            MOV     #003Bh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=3Bh
 325                                         ; fCOCLKDIV = 32768 x (59+1) = 1.996 MHz ; measured :  MHz
 326             MOV     #003Ch,&CSCTL2         ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=3Ch
 327                                         ; fCOCLKDIV = 32768 x (60+1) = 1.998 MHz ; measured :  MHz
 328 ;            MOV     #003Dh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=3Dh
 329                                         ; fCOCLKDIV = 32768 x (61+1) = 2.031 MHz ; measured :  MHz
 330 ; =====================================
 331             MOV     #8,X
 332
 333     .ELSEIF FREQUENCY = 4
 334
 335             MOV #00D2h,&CSCTL0          ; preset DCO = 0xD2 (measured value @ 0x180)
 336
 337             MOV     #0005h,&CSCTL1      ; Set 4MHZ DCORSEL,disable DCOFTRIM,Modulation
 338 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 339 ;            MOV     #0078h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=78h
 340                                         ; fCOCLKDIV = 32768 x (120+1) = 3.965 MHz ; measured : 3.96MHz
 341
 342             MOV     #0079h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=79h
 343                                         ; fCOCLKDIV = 32768 x (121+1) = 3.997 MHz ; measured : 3.99MHz
 344
 345 ;            MOV     #007Ah,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=7Ah
 346                                         ; fCOCLKDIV = 32768 x (122+1) = 4.030 MHz ; measured : 4.020MHz
 347 ; =====================================
 348             MOV     #16,X
 349
 350     .ELSEIF FREQUENCY = 8
 351
 352             MOV #00F2h,&CSCTL0          ; preset DCO = 0xF2 (measured value @ 0x180)
 353
 354             MOV     #0007h,&CSCTL1      ; Set 8MHZ DCORSEL,disable DCOFTRIM,Modulation
 355 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 356 ;            MOV     #00F2h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F2h
 357                                         ; fCOCLKDIV = 32768 x (242+1) = 7.963 MHz ; measured : 7.943MHz
 358 ;            MOV     #00F3h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F3h
 359                                         ; fCOCLKDIV = 32768 x (243+1) = 7.995 MHz ; measured : 7.976MHz
 360             MOV     #00F4h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F4h
 361                                         ; fCOCLKDIV = 32768 x (244+1) = 8.028 MHz ; measured : 8.009MHz
 362
 363 ;            MOV     #00F5h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F5h
 364                                         ; fCOCLKDIV = 32768 x (245+1) = 8.061 MHz ; measured : 8.042MHz
 365                                         ; works with cp2102 and pl2303TA
 366 ; =====================================
 367             MOV     #32,X
 368
 369     .ELSEIF FREQUENCY = 16
 370
 371             MOV #0129h,&CSCTL0          ; preset DCO = 0x129 (measured value @ 0x180)
 372
 373             MOV     #000Bh,&CSCTL1      ; Set 16MHZ DCORSEL,disable DCOFTRIM,Modulation
 374 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 375 ;            MOV     #01E6h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E6h
 376                                         ; fCOCLKDIV = 32768 x 486+1) = 15.958 MHz ; measured : 15.92MHz
 377 ;            MOV     #01E7h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E7h
 378                                         ; fCOCLKDIV = 32768 x 487+1) = 15.991 MHz ; measured : 15.95MHz
 379 ;            MOV     #01E8h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E8h
 380                                         ; fCOCLKDIV = 32768 x 488+1) = 16.023 MHz ; measured : 15.99MHz
 381             MOV     #01E9h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E9h
 382                                         ; fCOCLKDIV = 32768 x 489+1) = 16.056 MHz ; measured : 16.02MHz
 383 ; =====================================
 384             MOV     #64,X
 385
 386     .ELSEIF
 387     .error "bad frequency setting, only 0.5,1,2,4,8,16 MHz"
 388     .ENDIF
 389
 390     .IFDEF LF_XTAL
 391 ;            MOV     #0000h,&CSCTL3      ; FLL select XT1, FLLREFDIV=0 (default value)
 392             MOV     #0000h,&CSCTL4      ; ACLOCK select XT1, MCLK & SMCLK select DCOCLKDIV
 393     .ELSE
 394             MOV     #0010h,&CSCTL3      ; FLL select REFCLOCK, FLLREFDIV=0
 395 ;           MOV     #0100h,&CSCTL4      ; ACLOCK select REFO, MCLK & SMCLK select DCOCLKDIV (default value)
 396     .ENDIF
 397
 398
 399             BIS &SYSRSTIV,&SAVE_SYSRSTIV; store volatile SYSRSTIV with preserving a pending request for DEEP_RST
 400             CMP #2,&SAVE_SYSRSTIV   ; POWER ON ?
 401             JZ      ClockWaitX      ; yes : wait 600ms to stabilize power source
 402             .word   0359h           ; no  : RRUM #1,X --> wait still 300 ms...
 403                                     ;       ...because FLL lock time = 280 ms
 404
 405 ClockWaitX  MOV     #50000,Y        ;
 406 ClockWaitY  SUB     #1,Y            ; 3 cycles loop
 407             JNZ     ClockWaitY      ; 50000x3 = 150000 cycles delay = 150ms @ 1MHz
 408             SUB     #1,X            ;
 409             JNZ     ClockWaitX      ;
 410
 411
 412 ; ----------------------------------------------------------------------
 413 ; POWER ON RESET AND INITIALIZATION : RTC REGISTERS
 414 ; ----------------------------------------------------------------------
 415
 416     .IFDEF LF_XTAL
 417 ; LFXIN : P4.1, LFXOUT : P4.2
 418     MOV  #0600h,&PBSEL0   ; SEL0 for only P4.1,P4.2
 419     .ENDIF
 420
 421
 422
 423