SConstruct

   1 #
   2 #       SConstruct (10.09.09)
   3 #       SConscript for all components.
   4 #
   5 #       Copyright (C) 2010-2012  Andrew Nayenko
   6 #
   7 #       This program is free software: you can redistribute it and/or modify
   8 #       it under the terms of the GNU General Public License as published by
   9 #       the Free Software Foundation, either version 3 of the License, or
  10 #       (at your option) any later version.
  11 #
  12 #       This program is distributed in the hope that it will be useful,
  13 #       but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #       MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #       GNU General Public License for more details.
  16 #
  17 #       You should have received a copy of the GNU General Public License
  18 #       along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 import os
  22 import platform
  23 import SCons
  24
  25 env = Environment(**ARGUMENTS)
  26 env['ENV']['PATH'] = os.environ['PATH']
  27
  28 destdir = env.get('DESTDIR', '/sbin');
  29 targets = []
  30 libs = ['exfat']
  31 libfuse = 'fuse'
  32
  33 if not env.GetOption('clean'):
  34         conf = Configure(env)
  35
  36         if 'CC' in os.environ:
  37                 conf.env.Replace(CC = os.environ['CC'])
  38         if 'CCFLAGS' in os.environ:
  39                 conf.env.Replace(CCFLAGS = os.environ['CCFLAGS'])
  40         # Set default CCFLAGS for known compilers
  41         if not conf.env['CCFLAGS']:
  42                 if conf.env['CC'] == 'gcc':
  43                         conf.env.Replace(CCFLAGS = '-Wall -O2 -ggdb -std=c99')
  44                 elif conf.env['CC'] == 'clang':
  45                         conf.env.Replace(CCFLAGS = '-Wall -O2 -g -std=c99')
  46         if 'CPPFLAGS' in os.environ:
  47                 conf.env.Replace(CPPFLAGS = os.environ['CPPFLAGS'])
  48         conf.env.Append(CPPDEFINES = {'_FILE_OFFSET_BITS' : 64})
  49         conf.env.Append(CPPPATH = ['libexfat'])
  50         if 'LDFLAGS' in os.environ:
  51                 conf.env.Append(LINKFLAGS = os.environ['LDFLAGS'])
  52         conf.env.Append(LIBPATH = ['libexfat'])
  53
  54         # GNU/Linux requires _BSD_SOURCE define for vsyslog(), _XOPEN_SOURCE >= 500
  55         # for pread(), pwrite(), snprintf(), strdup(), etc. Everything needed is
  56         # enabled by _GNU_SOURCE.
  57         if platform.system() == 'Linux':
  58                 conf.env.Append(CPPDEFINES = '_GNU_SOURCE');
  59
  60         # Use 64-bit inode numbers (introduced in Mac OS X 10.5 Leopard). Require
  61         # OSXFUSE (http://osxfuse.github.com).
  62         if platform.system() == 'Darwin':
  63                 conf.env.Append(CPPDEFINES = '_DARWIN_USE_64_BIT_INODE')
  64                 conf.env.Append(CPPDEFINES = {'__DARWIN_UNIX03' : 1})
  65                 conf.env.Append(CPPPATH = ['/usr/local/include/osxfuse'])
  66                 conf.env.Append(CFLAGS    = '-mmacosx-version-min=10.5')
  67                 conf.env.Append(LINKFLAGS = '-mmacosx-version-min=10.5')
  68                 libfuse = 'osxfuse_i64'
  69
  70         # FreeBSD does not support block devices, only raw devices. Ublio is
  71         # required for unaligned I/O and caching.
  72         if platform.system() == 'FreeBSD':
  73                 conf.env.Append(CPPDEFINES = 'USE_UBLIO')
  74                 libs.append('ublio')
  75                 conf.env.Append(CPPPATH = ['/usr/local/include'])
  76                 conf.env.Append(LIBPATH = ['/usr/local/lib'])
  77
  78         if not conf.CheckCC():
  79                 print '''
  80         A working C compiler is needed very much.
  81 '''
  82                 Exit(1)
  83
  84         if not conf.CheckTypeSize('off_t', '#include <sys/types.h>', 'C', 8):
  85                 print '''
  86         The size of off_t type must be 64 bits. File systems larger than
  87         2 GB will be corrupted with 32-bit off_t.
  88 '''
  89                 Exit(1)
  90
  91         env = conf.Finish()
  92
  93
  94
  95 def make_symlink(dir, target, link_name):
  96         workdir = os.getcwd()
  97         os.chdir(dir)
  98         try:
  99                 os.remove(link_name)
 100         except OSError:
 101                 pass
 102         os.symlink(target, link_name)
 103         os.chdir(workdir)
 104
 105 symlink = SCons.Action.ActionFactory(make_symlink,
 106                 lambda dir, target, link_name:
 107                                 'make_symlink("%s", "%s", "%s")' % (dir, target, link_name))
 108
 109 def program(pattern, output, alias, libs):
 110         sources = Glob(pattern)
 111         if not sources:
 112                 return
 113         target = env.Program(output, sources, LIBS = libs)
 114         if alias:
 115                 Clean(Alias('install', Install(destdir, target),
 116                                 symlink(destdir, os.path.basename(output), alias)),
 117                                 destdir + '/' + alias)
 118         else:
 119                 Alias('install', Install(destdir, target))
 120         targets.append(target)
 121
 122 env.Library('libexfat/exfat', Glob('libexfat/*.c'))
 123
 124 program('fuse/*.c', 'fuse/mount.exfat-fuse', 'mount.exfat', [libs + [libfuse]])
 125 program('dump/*.c', 'dump/dumpexfat', None, libs)
 126 program('fsck/*.c', 'fsck/exfatfsck', 'fsck.exfat', libs)
 127 program('mkfs/*.c', 'mkfs/mkexfatfs', 'mkfs.exfat', libs)
 128 program('label/*.c', 'label/exfatlabel', None, libs)
 129
 130 Default(targets)