SConstruct

   1 #######################################################################
   2 # Top-level SConstruct
   3 #
   4 # For example, invoke scons as
   5 #
   6 #   scons debug=1 dri=0 machine=x86
   7 #
   8 # to set configuration variables. Or you can write those options to a file
   9 # named config.py:
  10 #
  11 #   # config.py
  12 #   debug=1
  13 #   dri=0
  14 #   machine='x86'
  15 #
  16 # Invoke
  17 #
  18 #   scons -h
  19 #
  20 # to get the full list of options. See scons manpage for more info.
  21 #
  22
  23 import os
  24 import os.path
  25 import sys
  26 import SCons.Util
  27
  28 import common
  29
  30 #######################################################################
  31 # Configuration options
  32
  33 default_statetrackers = 'mesa'
  34
  35 if common.default_platform in ('linux', 'freebsd', 'darwin'):
  36         default_drivers = 'softpipe,failover,svga,i915,i965,trace,identity,llvmpipe'
  37         default_winsys = 'xlib'
  38 elif common.default_platform in ('winddk',):
  39         default_drivers = 'softpipe,svga,i915,i965,trace,identity'
  40         default_winsys = 'all'
  41 elif common.default_platform in ('embedded',):
  42         default_drivers = 'softpipe,llvmpipe'
  43         default_winsys = 'xlib'
  44 else:
  45         default_drivers = 'all'
  46         default_winsys = 'all'
  47
  48 opts = Variables('config.py')
  49 common.AddOptions(opts)
  50 opts.Add(ListVariable('statetrackers', 'state trackers to build', default_statetrackers,
  51                      ['mesa', 'python', 'xorg']))
  52 opts.Add(ListVariable('drivers', 'pipe drivers to build', default_drivers,
  53                      ['softpipe', 'failover', 'svga', 'i915', 'i965', 'trace', 'r300', 'identity', 'llvmpipe']))
  54 opts.Add(ListVariable('winsys', 'winsys drivers to build', default_winsys,
  55                      ['xlib', 'vmware', 'intel', 'i965', 'gdi', 'radeon']))
  56
  57 opts.Add(EnumVariable('MSVS_VERSION', 'MS Visual C++ version', None, allowed_values=('7.1', '8.0', '9.0')))
  58
  59 env = Environment(
  60         options = opts,
  61         tools = ['gallium'],
  62         toolpath = ['#scons'],
  63         ENV = os.environ,
  64 )
  65
  66 if os.environ.has_key('CC'):
  67         env['CC'] = os.environ['CC']
  68 if os.environ.has_key('CFLAGS'):
  69         env['CCFLAGS'] += SCons.Util.CLVar(os.environ['CFLAGS'])
  70 if os.environ.has_key('CXX'):
  71         env['CXX'] = os.environ['CXX']
  72 if os.environ.has_key('CXXFLAGS'):
  73         env['CXXFLAGS'] += SCons.Util.CLVar(os.environ['CXXFLAGS'])
  74 if os.environ.has_key('LDFLAGS'):
  75         env['LINKFLAGS'] += SCons.Util.CLVar(os.environ['LDFLAGS'])
  76
  77 Help(opts.GenerateHelpText(env))
  78
  79 # replicate options values in local variables
  80 debug = env['debug']
  81 dri = env['dri']
  82 llvm = env['llvm']
  83 machine = env['machine']
  84 platform = env['platform']
  85
  86 # derived options
  87 x86 = machine == 'x86'
  88 ppc = machine == 'ppc'
  89 gcc = platform in ('linux', 'freebsd', 'darwin', 'embedded')
  90 msvc = platform in ('windows', 'winddk')
  91
  92 Export([
  93         'debug',
  94         'x86',
  95         'ppc',
  96         'dri',
  97         'llvm',
  98         'platform',
  99         'gcc',
 100         'msvc',
 101 ])
 102
 103
 104 #######################################################################
 105 # Environment setup
 106
 107 # Includes
 108 env.Append(CPPPATH = [
 109         '#/include',
 110         '#/src/gallium/include',
 111         '#/src/gallium/auxiliary',
 112         '#/src/gallium/drivers',
 113 ])
 114
 115 if env['msvc']:
 116     env.Append(CPPPATH = ['#include/c99'])
 117
 118
 119 # Posix
 120 if platform in ('posix', 'linux', 'freebsd', 'darwin', 'embedded'):
 121         env.Append(CPPDEFINES = [
 122                 '_POSIX_SOURCE',
 123                 ('_POSIX_C_SOURCE', '199309L'),
 124                 '_SVID_SOURCE',
 125                 '_BSD_SOURCE',
 126                 '_GNU_SOURCE',
 127
 128                 'PTHREADS',
 129         ])
 130         if platform != 'embedded':
 131                 env.Append(CPPDEFINES = ['HAVE_POSIX_MEMALIGN'])
 132         if platform == 'darwin':
 133                 env.Append(CPPDEFINES = ['_DARWIN_C_SOURCE'])
 134         env.Append(CPPPATH = ['/usr/X11R6/include'])
 135         env.Append(LIBPATH = ['/usr/X11R6/lib'])
 136         env.Append(LIBS = [
 137                 'm',
 138                 'pthread',
 139                 'dl',
 140         ])
 141         if platform != 'embedded':
 142                 env.Append(LIBS = [
 143                         'expat',
 144                 ])
 145
 146
 147
 148 # DRI
 149 if dri:
 150         env.ParseConfig('pkg-config --cflags --libs libdrm')
 151         env.Append(CPPDEFINES = [
 152                 ('USE_EXTERNAL_DXTN_LIB', '1'),
 153                 'IN_DRI_DRIVER',
 154                 'GLX_DIRECT_RENDERING',
 155                 'GLX_INDIRECT_RENDERING',
 156         ])
 157
 158 # LLVM
 159 if llvm:
 160         # See also http://www.scons.org/wiki/UsingPkgConfig
 161         env.ParseConfig('llvm-config --cflags --ldflags --libs backend bitreader engine instrumentation interpreter ipo')
 162         env.Append(CPPDEFINES = ['MESA_LLVM'])
 163         # Force C++ linkage
 164         env['LINK'] = env['CXX']
 165
 166 # libGL
 167 if platform in ('linux', 'freebsd', 'darwin'):
 168         env.Append(LIBS = [
 169                 'X11',
 170                 'Xext',
 171                 'Xxf86vm',
 172                 'Xdamage',
 173                 'Xfixes',
 174         ])
 175
 176 # for debugging
 177 #print env.Dump()
 178
 179 Export('env')
 180
 181
 182 #######################################################################
 183 # Invoke SConscripts
 184
 185 # TODO: Build several variants at the same time?
 186 # http://www.scons.org/wiki/SimultaneousVariantBuilds
 187
 188 if env['platform'] != common.default_platform:
 189     # GLSL code has to be built twice -- one for the host OS, another for the target OS...
 190
 191     host_env = Environment(
 192         # options are ignored
 193         # default tool is used
 194         tools = ['default', 'custom'],
 195         toolpath = ['#scons'],
 196         ENV = os.environ,
 197     )
 198
 199     host_env['platform'] = common.default_platform
 200     host_env['machine'] = common.default_machine
 201     host_env['debug'] = env['debug']
 202
 203     SConscript(
 204         'src/glsl/SConscript',
 205         variant_dir = os.path.join(env['build'], 'host'),
 206         duplicate = 0, # http://www.scons.org/doc/0.97/HTML/scons-user/x2261.html
 207         exports={'env':host_env},
 208     )
 209
 210 SConscript(
 211         'src/SConscript',
 212         variant_dir = env['build'],
 213         duplicate = 0 # http://www.scons.org/doc/0.97/HTML/scons-user/x2261.html
 214 )
 215
 216 SConscript(
 217         'progs/SConscript',
 218         variant_dir = os.path.join('progs', env['build']),
 219         duplicate = 0 # http://www.scons.org/doc/0.97/HTML/scons-user/x2261.html
 220 )