Source/WebKit.pri

   1 # Include file to make it easy to include WebKit into Qt projects
   2
   3 # Detect that we are building as a standalone package by the presence of
   4 # either the generated files directory or as part of the Qt package through
   5 # QTDIR_build
   6 CONFIG(QTDIR_build): CONFIG += standalone_package
   7 else:exists($$PWD/WebCore/generated): CONFIG += standalone_package
   8
   9 CONFIG += depend_includepath
  10 DEPENDPATH += $$OUT_PWD
  11
  12 DEFINES += BUILDING_QT__=1
  13 building-libs {
  14     win32-msvc*|win32-icc: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
  15 } else {
  16     CONFIG(QTDIR_build) {
  17         QT += webkit
  18     } else {
  19         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
  20         QTWEBKITLIBNAME = QtWebKit
  21         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
  22             LIBS += -framework $$QTWEBKITLIBNAME
  23             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
  24         } else {
  25             build_pass: win32-*|wince* {
  26                 !CONFIG(release, debug|release): QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}d
  27                 QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}$${QT_MAJOR_VERSION}
  28                 win32-g++*: LIBS += -l$$QTWEBKITLIBNAME
  29                 else: LIBS += $${QTWEBKITLIBNAME}.lib
  30             } else {
  31                 LIBS += -lQtWebKit
  32                 symbian {
  33                     TARGET.EPOCSTACKSIZE = 0x14000 // 80 kB
  34                     # For EXEs only: set heap to usable value
  35                     TARGET.EPOCHEAPSIZE =
  36                     heapSizeRule = \
  37                     "$${LITERAL_HASH}ifdef WINSCW" \
  38                         "EPOCHEAPSIZE  0x40000 0x2000000 // Min 256kB, Max 32MB" \
  39                     "$${LITERAL_HASH}else" \
  40                         "EPOCHEAPSIZE  0x40000 0x10000000 // Min 256kB, Max 256MB" \
  41                     "$${LITERAL_HASH}endif"
  42                     MMP_RULES += heapSizeRule
  43                 }
  44             }
  45         }
  46     }
  47     DEPENDPATH += $$PWD/WebKit/qt/Api
  48 }
  49
  50 CONFIG(release, debug|release) {
  51     DEFINES += NDEBUG
  52 }
  53
  54 INCLUDEPATH += $$OUTPUT_DIR/include/QtWebKit
  55 INCLUDEPATH += $$QT.script.includes
  56
  57 CONFIG -= warn_on
  58 *-g++*:QMAKE_CXXFLAGS += -Wall -Wextra -Wreturn-type -fno-strict-aliasing -Wcast-align -Wchar-subscripts -Wformat-security -Wreturn-type -Wno-unused-parameter -Wno-sign-compare -Wno-switch -Wno-switch-enum -Wundef -Wmissing-noreturn -Winit-self
  59
  60 # Treat warnings as errors on x86/Linux/GCC
  61 linux-g++* {
  62     isEqual(QT_ARCH,x86_64)|isEqual(QT_ARCH,i386): QMAKE_CXXFLAGS += -Werror
  63 }
  64
  65 symbian|*-armcc {
  66     # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
  67     RVCT_COMMON_CFLAGS = --gnu --diag_suppress 68,111,177,368,830,1293
  68     RVCT_COMMON_CXXFLAGS = $$RVCT_COMMON_CFLAGS --no_parse_templates
  69     # Make debug symbols leaner in RVCT4.x. Ignored by compiler for release builds
  70     QMAKE_CXXFLAGS.ARMCC_4_0 += --remove_unneeded_entities
  71 }
  72
  73 *-armcc {
  74     QMAKE_CFLAGS += $$RVCT_COMMON_CFLAGS
  75     QMAKE_CXXFLAGS += $$RVCT_COMMON_CXXFLAGS
  76 }
  77
  78 symbian {
  79     QMAKE_CXXFLAGS.ARMCC += $$RVCT_COMMON_CXXFLAGS
  80 }
  81
  82 valgrind {
  83     contains(JAVASCRIPTCORE_JIT,yes): error("'JAVASCRIPTCORE_JIT=yes' not supported with valgrind")
  84     QMAKE_CXXFLAGS += -g
  85     QMAKE_LFLAGS += -g
  86     DEFINES += USE_SYSTEM_MALLOC=1
  87     DEFINES += ENABLE_JIT=0
  88     JAVASCRIPTCORE_JIT = no
  89 }
  90
  91 ##### Defaults for some mobile platforms
  92 symbian|maemo5|maemo6 {
  93     CONFIG += disable_uitools
  94     CONFIG += enable_fast_mobile_scrolling
  95     CONFIG += use_qt_mobile_theme
  96     maemo6: CONFIG += include_webinspector
  97 } else {
  98     CONFIG += include_webinspector
  99 }
 100
 101 ####
 102
 103 disable_uitools: DEFINES *= QT_NO_UITOOLS
 104
 105 # Disable a few warnings on Windows. The warnings are also
 106 # disabled in WebKitLibraries/win/tools/vsprops/common.vsprops
 107 win32-msvc*|wince*: QMAKE_CXXFLAGS += -wd4291 -wd4344 -wd4396 -wd4503 -wd4800 -wd4819 -wd4996
 108
 109 CONFIG(qt_minimal) {
 110     DEFINES *= QT_NO_ANIMATION
 111     DEFINES *= QT_NO_BEARERMANAGEMENT
 112     DEFINES *= QT_NO_CLIPBOARD
 113     DEFINES *= QT_NO_COMBOBOX
 114     DEFINES *= QT_NO_CONCURRENT
 115     DEFINES *= QT_NO_CRASHHANDLER
 116     DEFINES *= QT_NO_CURSOR
 117     DEFINES *= QT_NO_DESKTOPSERVICES
 118     DEFINES *= QT_NO_FILEDIALOG
 119     DEFINES *= QT_NO_GRAPHICSEFFECT
 120     DEFINES *= QT_NO_IM
 121     DEFINES *= QT_NO_INPUTDIALOG
 122     DEFINES *= QT_NO_LINEEDIT
 123     DEFINES *= QT_NO_MESSAGEBOX
 124     DEFINES *= QT_NO_OPENSSL
 125     DEFINES *= QT_NO_PRINTER
 126     DEFINES *= QT_NO_QUUID_STRING
 127     DEFINES *= QT_NO_SHORTCUT
 128     DEFINES *= QT_NO_STYLE_STYLESHEET
 129     DEFINES *= QT_NO_SYSTEMTRAYICON
 130     DEFINES *= QT_NO_TEMPORARYFILE
 131     DEFINES *= QT_NO_TOOLTIP
 132     DEFINES *= QT_NO_UITOOLS
 133     DEFINES *= QT_NO_UNDOCOMMAND
 134     DEFINES *= QT_NO_UNDOSTACK
 135     DEFINES *= QT_NO_XRENDER
 136 }
 137
 138 contains(DEFINES, QT_NO_UITOOLS): CONFIG -= uitools