Source/WebKit.pro

   1 TEMPLATE = subdirs
   2 CONFIG += ordered
   3
   4 include(WebKit.pri)
   5
   6 !v8 {
   7     exists($$PWD/JavaScriptCore/JavaScriptCore.pro): SUBDIRS += JavaScriptCore/JavaScriptCore.pro
   8     exists($$PWD/JavaScriptCore/jsc.pro): SUBDIRS += JavaScriptCore/jsc.pro
   9 }
  10
  11 webkit2:exists($$PWD/WebKit2/WebKit2.pro): SUBDIRS += WebKit2/WebKit2.pro
  12
  13 SUBDIRS += WebCore
  14 SUBDIRS += WebKit/qt/QtWebKit.pro
  15
  16 webkit2 {
  17     exists($$PWD/WebKit2/WebProcess.pro): SUBDIRS += WebKit2/WebProcess.pro
  18     exists($$PWD/WebKit2/UIProcess/API/qt/tests): SUBDIRS += WebKit2/UIProcess/API/qt/tests
  19 }
  20
  21 contains(QT_CONFIG, declarative) {
  22     exists($$PWD/WebKit/qt/declarative): SUBDIRS += WebKit/qt/declarative
  23 }
  24
  25 exists($$PWD/WebKit/qt/tests): SUBDIRS += WebKit/qt/tests
  26
  27 build-qtscript {
  28     SUBDIRS += \
  29         JavaScriptCore/qt/api/QtScript.pro \
  30         JavaScriptCore/qt/tests \
  31         JavaScriptCore/qt/benchmarks
  32 }
  33
  34 symbian {
  35     # Forward the install target to WebCore. A workaround since INSTALLS is not implemented for symbian
  36     install.commands = $(MAKE) -C WebCore install
  37     QMAKE_EXTRA_TARGETS += install
  38 }
  39
  40 include(WebKit/qt/docs/docs.pri)