Tools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro

   1 TEMPLATE = lib
   2 TARGET = TestNetscapePlugIn
   3
   4 VPATH = ../../unix/TestNetscapePlugin ../../TestNetscapePlugIn
   5 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../../../..
   6 include(../../../../WebKit.pri)
   7
   8 DESTDIR = $$OUTPUT_DIR/lib/plugins
   9
  10 mac {
  11     CONFIG += plugin
  12     CONFIG += plugin_bundle
  13     QMAKE_INFO_PLIST = ../../TestNetscapePlugIn/mac/Info.plist
  14     QMAKE_PLUGIN_BUNDLE_NAME = $$TARGET
  15     QMAKE_BUNDLE_LOCATION += "Contents/MacOS"
  16
  17     !build_pass:CONFIG += build_all
  18     debug_and_release:TARGET = $$qtLibraryTarget($$TARGET)
  19 }
  20
  21 INCLUDEPATH += ../../../../JavaScriptCore \
  22                ../../unix/TestNetscapePlugin/ForwardingHeaders \
  23                ../../unix/TestNetscapePlugin/ForwardingHeaders/WebKit \
  24                ../../../../WebCore \
  25                ../../../../WebCore/bridge \
  26                ../../TestNetscapePlugIn
  27
  28 SOURCES = PluginObject.cpp \
  29           PluginTest.cpp \
  30           TestObject.cpp \
  31           Tests/DocumentOpenInDestroyStream.cpp \
  32           Tests/EvaluateJSAfterRemovingPluginElement.cpp \
  33           Tests/GetUserAgentWithNullNPPFromNPPNew.cpp \
  34           Tests/NPRuntimeObjectFromDestroyedPlugin.cpp \
  35           Tests/NPRuntimeRemoveProperty.cpp \
  36           Tests/NullNPPGetValuePointer.cpp \
  37           Tests/PassDifferentNPPStruct.cpp \
  38           Tests/PluginScriptableNPObjectInvokeDefault.cpp
  39
  40 mac {
  41     SOURCES += ../../TestNetscapePlugIn/main.cpp
  42     OBJECTIVE_SOURCES += PluginObjectMac.mm
  43     LIBS += -framework Carbon -framework Cocoa -framework QuartzCore
  44 } else {
  45     SOURCES += ../../unix/TestNetscapePlugin/TestNetscapePlugin.cpp
  46 }