alter-stable/any/kpmcore-git/PKGBUILD

   1 # Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
   2
   3 pkgname=kpmcore-git
   4 pkgver=4.1.0.r1067.0ffec31
   5 pkgrel=1
   6 pkgdesc="Library for managing partitions. Common code for KDE Partition Manager and other projects. (GIT version)"
   7 arch=('x86_64' 'i686')
   8 url='http://kde.org/applications/system/kdepartitionmanager'
   9 license=('GPL2')
  10 depends=('parted'
  11          'libatasmart'
  12          'kwidgetsaddons'
  13          'ki18n'
  14          'kauth'
  15          'qca'
  16          )
  17 conflicts=('kpmcore')
  18 provides=('kpmcore')
  19 makedepends=('extra-cmake-modules'
  20              'git'
  21              'python'
  22              )
  23 optdepends=('e2fsprogs: ext2/3/4 support'
  24             'xfsprogs: XFS support'
  25             'jfsutils: JFS support'
  26             'reiserfsprogs: Reiser support'
  27             'ntfs-3g: NTFS support'
  28             'dosfstools: FAT32 support'
  29             'f2fs-tools: F2FS support'
  30             'exfat-utils: exFAT support'
  31             'nilfs-utils: nilfs support'
  32             'udftools: UDF support'
  33             )
  34 source=('git+https://invent.kde.org/system/kpmcore.git')
  35 sha256sums=('SKIP')
  36
  37 pkgver() {
  38   cd kpmcore
  39   _ver="$(cat CMakeLists.txt | grep -m3 -e MAJOR -e MINOR -e RELEASE | grep -o "[[:digit:]]*" | paste -sd'.')"
  40   echo "${_ver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
  41 }
  42
  43 prepare() {
  44   mkdir -p build
  45
  46   cd build
  47   cmake ../kpmcore \
  48     -DCMAKE_BUILD_TYPE=None \
  49     -DCMAKE_INSTALL_PREFIX=/usr \
  50     -DKDE_INSTALL_LIBDIR=lib \
  51     -DBUILD_TESTING=OFF
  52
  53 }
  54
  55 build() {
  56   make -C build
  57 }
  58
  59 package() {
  60   make -C build DESTDIR="${pkgdir}" install
  61 }