arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/unistd.h>
  12 #include <asm/ftrace.h>
  13 #include <mach/entry-macro.S>
  14 #include <asm/unwind.h>
  15
  16 #include "entry-header.S"
  17
  18
  19         .align  5
  20 /*
  21  * This is the fast syscall return path.  We do as little as
  22  * possible here, and this includes saving r0 back into the SVC
  23  * stack.
  24  */
  25 ret_fast_syscall:
  26  UNWIND(.fnstart        )
  27  UNWIND(.cantunwind     )
  28         disable_irq                             @ disable interrupts
  29         ldr     r1, [tsk, #TI_FLAGS]
  30         tst     r1, #_TIF_WORK_MASK
  31         bne     fast_work_pending
  32
  33         /* perform architecture specific actions before user return */
  34         arch_ret_to_user r1, lr
  35
  36         restore_user_regs fast = 1, offset = S_OFF
  37  UNWIND(.fnend          )
  38
  39 /*
  40  * Ok, we need to do extra processing, enter the slow path.
  41  */
  42 fast_work_pending:
  43         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  44 work_pending:
  45         tst     r1, #_TIF_NEED_RESCHED
  46         bne     work_resched
  47         tst     r1, #_TIF_SIGPENDING|_TIF_NOTIFY_RESUME
  48         beq     no_work_pending
  49         mov     r0, sp                          @ 'regs'
  50         mov     r2, why                         @ 'syscall'
  51         tst     r1, #_TIF_SIGPENDING            @ delivering a signal?
  52         movne   why, #0                         @ prevent further restarts
  53         bl      do_notify_resume
  54         b       ret_slow_syscall                @ Check work again
  55
  56 work_resched:
  57         bl      schedule
  58 /*
  59  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  60  */
  61 ENTRY(ret_to_user)
  62 ret_slow_syscall:
  63         disable_irq                             @ disable interrupts
  64         ldr     r1, [tsk, #TI_FLAGS]
  65         tst     r1, #_TIF_WORK_MASK
  66         bne     work_pending
  67 no_work_pending:
  68         /* perform architecture specific actions before user return */
  69         arch_ret_to_user r1, lr
  70
  71         restore_user_regs fast = 0, offset = 0
  72 ENDPROC(ret_to_user)
  73
  74 /*
  75  * This is how we return from a fork.
  76  */
  77 ENTRY(ret_from_fork)
  78         bl      schedule_tail
  79         get_thread_info tsk
  80         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  81         mov     why, #1
  82         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  83         beq     ret_slow_syscall
  84         mov     r1, sp
  85         mov     r0, #1                          @ trace exit [IP = 1]
  86         bl      syscall_trace
  87         b       ret_slow_syscall
  88 ENDPROC(ret_from_fork)
  89
  90         .equ NR_syscalls,0
  91 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
  92 #include "calls.S"
  93 #undef CALL
  94 #define CALL(x) .long x
  95
  96 #ifdef CONFIG_FUNCTION_TRACER
  97 /*
  98  * When compiling with -pg, gcc inserts a call to the mcount routine at the
  99  * start of every function.  In mcount, apart from the function's address (in
 100  * lr), we need to get hold of the function's caller's address.
 101  *
 102  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
 103  *
 104  *      bl      mcount
 105  *
 106  * These versions have the limitation that in order for the mcount routine to
 107  * be able to determine the function's caller's address, an APCS-style frame
 108  * pointer (which is set up with something like the code below) is required.
 109  *
 110  *      mov     ip, sp
 111  *      push    {fp, ip, lr, pc}
 112  *      sub     fp, ip, #4
 113  *
 114  * With EABI, these frame pointers are not available unless -mapcs-frame is
 115  * specified, and if building as Thumb-2, not even then.
 116  *
 117  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
 118  * with call sites like:
 119  *
 120  *      push    {lr}
 121  *      bl      __gnu_mcount_nc
 122  *
 123  * With these compilers, frame pointers are not necessary.
 124  *
 125  * mcount can be thought of as a function called in the middle of a subroutine
 126  * call.  As such, it needs to be transparent for both the caller and the
 127  * callee: the original lr needs to be restored when leaving mcount, and no
 128  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
 129  * clobber the ip register.  This is OK because the ARM calling convention
 130  * allows it to be clobbered in subroutines and doesn't use it to hold
 131  * parameters.)
 132  *
 133  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
 134  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
 135  * arch/arm/kernel/ftrace.c).
 136  */
 137
 138 #ifndef CONFIG_OLD_MCOUNT
 139 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
 140 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
 141 #endif
 142 #endif
 143
 144 .macro __mcount suffix
 145         mcount_enter
 146         ldr     r0, =ftrace_trace_function
 147         ldr     r2, [r0]
 148         adr     r0, .Lftrace_stub
 149         cmp     r0, r2
 150         bne     1f
 151
 152 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 153         ldr     r1, =ftrace_graph_return
 154         ldr     r2, [r1]
 155         cmp     r0, r2
 156         bne     ftrace_graph_caller\suffix
 157
 158         ldr     r1, =ftrace_graph_entry
 159         ldr     r2, [r1]
 160         ldr     r0, =ftrace_graph_entry_stub
 161         cmp     r0, r2
 162         bne     ftrace_graph_caller\suffix
 163 #endif
 164
 165         mcount_exit
 166
 167 1:      mcount_get_lr   r1                      @ lr of instrumented func
 168         mov     r0, lr                          @ instrumented function
 169         sub     r0, r0, #MCOUNT_INSN_SIZE
 170         adr     lr, BSYM(2f)
 171         mov     pc, r2
 172 2:      mcount_exit
 173 .endm
 174
 175 .macro __ftrace_caller suffix
 176         mcount_enter
 177
 178         mcount_get_lr   r1                      @ lr of instrumented func
 179         mov     r0, lr                          @ instrumented function
 180         sub     r0, r0, #MCOUNT_INSN_SIZE
 181
 182         .globl ftrace_call\suffix
 183 ftrace_call\suffix:
 184         bl      ftrace_stub
 185
 186 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 187         .globl ftrace_graph_call\suffix
 188 ftrace_graph_call\suffix:
 189         mov     r0, r0
 190 #endif
 191
 192         mcount_exit
 193 .endm
 194
 195 .macro __ftrace_graph_caller
 196         sub     r0, fp, #4              @ &lr of instrumented routine (&parent)
 197 #ifdef CONFIG_DYNAMIC_FTRACE
 198         @ called from __ftrace_caller, saved in mcount_enter
 199         ldr     r1, [sp, #16]           @ instrumented routine (func)
 200 #else
 201         @ called from __mcount, untouched in lr
 202         mov     r1, lr                  @ instrumented routine (func)
 203 #endif
 204         sub     r1, r1, #MCOUNT_INSN_SIZE
 205         mov     r2, fp                  @ frame pointer
 206         bl      prepare_ftrace_return
 207         mcount_exit
 208 .endm
 209
 210 #ifdef CONFIG_OLD_MCOUNT
 211 /*
 212  * mcount
 213  */
 214
 215 .macro mcount_enter
 216         stmdb   sp!, {r0-r3, lr}
 217 .endm
 218
 219 .macro mcount_get_lr reg
 220         ldr     \reg, [fp, #-4]
 221 .endm
 222
 223 .macro mcount_exit
 224         ldr     lr, [fp, #-4]
 225         ldmia   sp!, {r0-r3, pc}
 226 .endm
 227
 228 ENTRY(mcount)
 229 #ifdef CONFIG_DYNAMIC_FTRACE
 230         stmdb   sp!, {lr}
 231         ldr     lr, [fp, #-4]
 232         ldmia   sp!, {pc}
 233 #else
 234         __mcount _old
 235 #endif
 236 ENDPROC(mcount)
 237
 238 #ifdef CONFIG_DYNAMIC_FTRACE
 239 ENTRY(ftrace_caller_old)
 240         __ftrace_caller _old
 241 ENDPROC(ftrace_caller_old)
 242 #endif
 243
 244 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 245 ENTRY(ftrace_graph_caller_old)
 246         __ftrace_graph_caller
 247 ENDPROC(ftrace_graph_caller_old)
 248 #endif
 249
 250 .purgem mcount_enter
 251 .purgem mcount_get_lr
 252 .purgem mcount_exit
 253 #endif
 254
 255 /*
 256  * __gnu_mcount_nc
 257  */
 258
 259 .macro mcount_enter
 260         stmdb   sp!, {r0-r3, lr}
 261 .endm
 262
 263 .macro mcount_get_lr reg
 264         ldr     \reg, [sp, #20]
 265 .endm
 266
 267 .macro mcount_exit
 268         ldmia   sp!, {r0-r3, ip, lr}
 269         mov     pc, ip
 270 .endm
 271
 272 ENTRY(__gnu_mcount_nc)
 273 #ifdef CONFIG_DYNAMIC_FTRACE
 274         mov     ip, lr
 275         ldmia   sp!, {lr}
 276         mov     pc, ip
 277 #else
 278         __mcount
 279 #endif
 280 ENDPROC(__gnu_mcount_nc)
 281
 282 #ifdef CONFIG_DYNAMIC_FTRACE
 283 ENTRY(ftrace_caller)
 284         __ftrace_caller
 285 ENDPROC(ftrace_caller)
 286 #endif
 287
 288 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 289 ENTRY(ftrace_graph_caller)
 290         __ftrace_graph_caller
 291 ENDPROC(ftrace_graph_caller)
 292 #endif
 293
 294 .purgem mcount_enter
 295 .purgem mcount_get_lr
 296 .purgem mcount_exit
 297
 298 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 299         .globl return_to_handler
 300 return_to_handler:
 301         stmdb   sp!, {r0-r3}
 302         mov     r0, fp                  @ frame pointer
 303         bl      ftrace_return_to_handler
 304         mov     lr, r0                  @ r0 has real ret addr
 305         ldmia   sp!, {r0-r3}
 306         mov     pc, lr
 307 #endif
 308
 309 ENTRY(ftrace_stub)
 310 .Lftrace_stub:
 311         mov     pc, lr
 312 ENDPROC(ftrace_stub)
 313
 314 #endif /* CONFIG_FUNCTION_TRACER */
 315
 316 /*=============================================================================
 317  * SWI handler
 318  *-----------------------------------------------------------------------------
 319  */
 320
 321         /* If we're optimising for StrongARM the resulting code won't
 322            run on an ARM7 and we can save a couple of instructions.
 323                                                                 --pb */
 324 #ifdef CONFIG_CPU_ARM710
 325 #define A710(code...) code
 326 .Larm710bug:
 327         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 328         mov     r0, r0
 329         add     sp, sp, #S_FRAME_SIZE
 330         subs    pc, lr, #4
 331 #else
 332 #define A710(code...)
 333 #endif
 334
 335         .align  5
 336 ENTRY(vector_swi)
 337         sub     sp, sp, #S_FRAME_SIZE
 338         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 339  ARM(   add     r8, sp, #S_PC           )
 340  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 341  THUMB( mov     r8, sp                  )
 342  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 343         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 344         str     lr, [sp, #S_PC]                 @ Save calling PC
 345         str     r8, [sp, #S_PSR]                @ Save CPSR
 346         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 347         zero_fp
 348
 349         /*
 350          * Get the system call number.
 351          */
 352
 353 #if defined(CONFIG_OABI_COMPAT)
 354
 355         /*
 356          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 357          * value to determine if it is an EABI or an old ABI call.
 358          */
 359 #ifdef CONFIG_ARM_THUMB
 360         tst     r8, #PSR_T_BIT
 361         movne   r10, #0                         @ no thumb OABI emulation
 362         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 363 #else
 364         ldr     r10, [lr, #-4]                  @ get SWI instruction
 365   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
 366   A710( teq     ip, #0x0f000000                                         )
 367   A710( bne     .Larm710bug                                             )
 368 #endif
 369 #ifdef CONFIG_CPU_ENDIAN_BE8
 370         rev     r10, r10                        @ little endian instruction
 371 #endif
 372
 373 #elif defined(CONFIG_AEABI)
 374
 375         /*
 376          * Pure EABI user space always put syscall number into scno (r7).
 377          */
 378   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
 379   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
 380   A710( teq     ip, #0x0f000000                                         )
 381   A710( bne     .Larm710bug                                             )
 382
 383 #elif defined(CONFIG_ARM_THUMB)
 384
 385         /* Legacy ABI only, possibly thumb mode. */
 386         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 387         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 388         ldreq   scno, [lr, #-4]
 389
 390 #else
 391
 392         /* Legacy ABI only. */
 393         ldr     scno, [lr, #-4]                 @ get SWI instruction
 394   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
 395   A710( teq     ip, #0x0f000000                                         )
 396   A710( bne     .Larm710bug                                             )
 397
 398 #endif
 399
 400 #ifdef CONFIG_ALIGNMENT_TRAP
 401         ldr     ip, __cr_alignment
 402         ldr     ip, [ip]
 403         mcr     p15, 0, ip, c1, c0              @ update control register
 404 #endif
 405         enable_irq
 406
 407         get_thread_info tsk
 408         adr     tbl, sys_call_table             @ load syscall table pointer
 409
 410 #if defined(CONFIG_OABI_COMPAT)
 411         /*
 412          * If the swi argument is zero, this is an EABI call and we do nothing.
 413          *
 414          * If this is an old ABI call, get the syscall number into scno and
 415          * get the old ABI syscall table address.
 416          */
 417         bics    r10, r10, #0xff000000
 418         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 419         ldrne   tbl, =sys_oabi_call_table
 420 #elif !defined(CONFIG_AEABI)
 421         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 422         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 423 #endif
 424
 425         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 426         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 427
 428 #ifdef CONFIG_SECCOMP
 429         tst     r10, #_TIF_SECCOMP
 430         beq     1f
 431         mov     r0, scno
 432         bl      __secure_computing
 433         add     r0, sp, #S_R0 + S_OFF           @ pointer to regs
 434         ldmia   r0, {r0 - r3}                   @ have to reload r0 - r3
 435 1:
 436 #endif
 437
 438         tst     r10, #_TIF_SYSCALL_TRACE                @ are we tracing syscalls?
 439         bne     __sys_trace
 440
 441         cmp     scno, #NR_syscalls              @ check upper syscall limit
 442         adr     lr, BSYM(ret_fast_syscall)      @ return address
 443         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 444
 445         add     r1, sp, #S_OFF
 446 2:      mov     why, #0                         @ no longer a real syscall
 447         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 448         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 449         bcs     arm_syscall
 450         b       sys_ni_syscall                  @ not private func
 451 ENDPROC(vector_swi)
 452
 453         /*
 454          * This is the really slow path.  We're going to be doing
 455          * context switches, and waiting for our parent to respond.
 456          */
 457 __sys_trace:
 458         mov     r2, scno
 459         add     r1, sp, #S_OFF
 460         mov     r0, #0                          @ trace entry [IP = 0]
 461         bl      syscall_trace
 462
 463         adr     lr, BSYM(__sys_trace_return)    @ return address
 464         mov     scno, r0                        @ syscall number (possibly new)
 465         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 466         cmp     scno, #NR_syscalls              @ check upper syscall limit
 467         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 468         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 469         b       2b
 470
 471 __sys_trace_return:
 472         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 473         mov     r2, scno
 474         mov     r1, sp
 475         mov     r0, #1                          @ trace exit [IP = 1]
 476         bl      syscall_trace
 477         b       ret_slow_syscall
 478
 479         .align  5
 480 #ifdef CONFIG_ALIGNMENT_TRAP
 481         .type   __cr_alignment, #object
 482 __cr_alignment:
 483         .word   cr_alignment
 484 #endif
 485         .ltorg
 486
 487 /*
 488  * This is the syscall table declaration for native ABI syscalls.
 489  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 490  */
 491 #define ABI(native, compat) native
 492 #ifdef CONFIG_AEABI
 493 #define OBSOLETE(syscall) sys_ni_syscall
 494 #else
 495 #define OBSOLETE(syscall) syscall
 496 #endif
 497
 498         .type   sys_call_table, #object
 499 ENTRY(sys_call_table)
 500 #include "calls.S"
 501 #undef ABI
 502 #undef OBSOLETE
 503
 504 /*============================================================================
 505  * Special system call wrappers
 506  */
 507 @ r0 = syscall number
 508 @ r8 = syscall table
 509 sys_syscall:
 510                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 511                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 512                 cmpne   scno, #NR_syscalls      @ check range
 513                 stmloia sp, {r5, r6}            @ shuffle args
 514                 movlo   r0, r1
 515                 movlo   r1, r2
 516                 movlo   r2, r3
 517                 movlo   r3, r4
 518                 ldrlo   pc, [tbl, scno, lsl #2]
 519                 b       sys_ni_syscall
 520 ENDPROC(sys_syscall)
 521
 522 sys_fork_wrapper:
 523                 add     r0, sp, #S_OFF
 524                 b       sys_fork
 525 ENDPROC(sys_fork_wrapper)
 526
 527 sys_vfork_wrapper:
 528                 add     r0, sp, #S_OFF
 529                 b       sys_vfork
 530 ENDPROC(sys_vfork_wrapper)
 531
 532 sys_execve_wrapper:
 533                 add     r3, sp, #S_OFF
 534                 b       sys_execve
 535 ENDPROC(sys_execve_wrapper)
 536
 537 sys_clone_wrapper:
 538                 add     ip, sp, #S_OFF
 539                 str     ip, [sp, #4]
 540                 b       sys_clone
 541 ENDPROC(sys_clone_wrapper)
 542
 543 sys_sigreturn_wrapper:
 544                 add     r0, sp, #S_OFF
 545                 mov     why, #0         @ prevent syscall restart handling
 546                 b       sys_sigreturn
 547 ENDPROC(sys_sigreturn_wrapper)
 548
 549 sys_rt_sigreturn_wrapper:
 550                 add     r0, sp, #S_OFF
 551                 mov     why, #0         @ prevent syscall restart handling
 552                 b       sys_rt_sigreturn
 553 ENDPROC(sys_rt_sigreturn_wrapper)
 554
 555 sys_sigaltstack_wrapper:
 556                 ldr     r2, [sp, #S_OFF + S_SP]
 557                 b       do_sigaltstack
 558 ENDPROC(sys_sigaltstack_wrapper)
 559
 560 sys_statfs64_wrapper:
 561                 teq     r1, #88
 562                 moveq   r1, #84
 563                 b       sys_statfs64
 564 ENDPROC(sys_statfs64_wrapper)
 565
 566 sys_fstatfs64_wrapper:
 567                 teq     r1, #88
 568                 moveq   r1, #84
 569                 b       sys_fstatfs64
 570 ENDPROC(sys_fstatfs64_wrapper)
 571
 572 /*
 573  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 574  * offset, we return EINVAL.
 575  */
 576 sys_mmap2:
 577 #if PAGE_SHIFT > 12
 578                 tst     r5, #PGOFF_MASK
 579                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 580                 streq   r5, [sp, #4]
 581                 beq     sys_mmap_pgoff
 582                 mov     r0, #-EINVAL
 583                 mov     pc, lr
 584 #else
 585                 str     r5, [sp, #4]
 586                 b       sys_mmap_pgoff
 587 #endif
 588 ENDPROC(sys_mmap2)
 589
 590 #ifdef CONFIG_OABI_COMPAT
 591
 592 /*
 593  * These are syscalls with argument register differences
 594  */
 595
 596 sys_oabi_pread64:
 597                 stmia   sp, {r3, r4}
 598                 b       sys_pread64
 599 ENDPROC(sys_oabi_pread64)
 600
 601 sys_oabi_pwrite64:
 602                 stmia   sp, {r3, r4}
 603                 b       sys_pwrite64
 604 ENDPROC(sys_oabi_pwrite64)
 605
 606 sys_oabi_truncate64:
 607                 mov     r3, r2
 608                 mov     r2, r1
 609                 b       sys_truncate64
 610 ENDPROC(sys_oabi_truncate64)
 611
 612 sys_oabi_ftruncate64:
 613                 mov     r3, r2
 614                 mov     r2, r1
 615                 b       sys_ftruncate64
 616 ENDPROC(sys_oabi_ftruncate64)
 617
 618 sys_oabi_readahead:
 619                 str     r3, [sp]
 620                 mov     r3, r2
 621                 mov     r2, r1
 622                 b       sys_readahead
 623 ENDPROC(sys_oabi_readahead)
 624
 625 /*
 626  * Let's declare a second syscall table for old ABI binaries
 627  * using the compatibility syscall entries.
 628  */
 629 #define ABI(native, compat) compat
 630 #define OBSOLETE(syscall) syscall
 631
 632         .type   sys_oabi_call_table, #object
 633 ENTRY(sys_oabi_call_table)
 634 #include "calls.S"
 635 #undef ABI
 636 #undef OBSOLETE
 637
 638 #endif
 639