arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/arm-smccc.h>
  22 #include <linux/init.h>
  23 #include <linux/linkage.h>
  24
  25 #include <asm/alternative.h>
  26 #include <asm/assembler.h>
  27 #include <asm/asm-offsets.h>
  28 #include <asm/cpufeature.h>
  29 #include <asm/errno.h>
  30 #include <asm/esr.h>
  31 #include <asm/irq.h>
  32 #include <asm/memory.h>
  33 #include <asm/mmu.h>
  34 #include <asm/processor.h>
  35 #include <asm/ptrace.h>
  36 #include <asm/thread_info.h>
  37 #include <asm/asm-uaccess.h>
  38 #include <asm/unistd.h>
  39
  40 /*
  41  * Context tracking subsystem.  Used to instrument transitions
  42  * between user and kernel mode.
  43  */
  44         .macro ct_user_exit
  45 #ifdef CONFIG_CONTEXT_TRACKING
  46         bl      context_tracking_user_exit
  47 #endif
  48         .endm
  49
  50         .macro ct_user_enter
  51 #ifdef CONFIG_CONTEXT_TRACKING
  52         bl      context_tracking_user_enter
  53 #endif
  54         .endm
  55
  56 /*
  57  * Bad Abort numbers
  58  *-----------------
  59  */
  60 #define BAD_SYNC        0
  61 #define BAD_IRQ         1
  62 #define BAD_FIQ         2
  63 #define BAD_ERROR       3
  64
  65         .macro kernel_ventry, el, label, regsize = 64
  66         .align 7
  67 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
  68 alternative_if ARM64_UNMAP_KERNEL_AT_EL0
  69         .if     \el == 0
  70         .if     \regsize == 64
  71         mrs     x30, tpidrro_el0
  72         msr     tpidrro_el0, xzr
  73         .else
  74         mov     x30, xzr
  75         .endif
  76         .endif
  77 alternative_else_nop_endif
  78 #endif
  79
  80         sub     sp, sp, #S_FRAME_SIZE
  81 #ifdef CONFIG_VMAP_STACK
  82         /*
  83          * Test whether the SP has overflowed, without corrupting a GPR.
  84          * Task and IRQ stacks are aligned to (1 << THREAD_SHIFT).
  85          */
  86         add     sp, sp, x0                      // sp' = sp + x0
  87         sub     x0, sp, x0                      // x0' = sp' - x0 = (sp + x0) - x0 = sp
  88         tbnz    x0, #THREAD_SHIFT, 0f
  89         sub     x0, sp, x0                      // x0'' = sp' - x0' = (sp + x0) - sp = x0
  90         sub     sp, sp, x0                      // sp'' = sp' - x0 = (sp + x0) - x0 = sp
  91         b       el\()\el\()_\label
  92
  93 0:
  94         /*
  95          * Either we've just detected an overflow, or we've taken an exception
  96          * while on the overflow stack. Either way, we won't return to
  97          * userspace, and can clobber EL0 registers to free up GPRs.
  98          */
  99
 100         /* Stash the original SP (minus S_FRAME_SIZE) in tpidr_el0. */
 101         msr     tpidr_el0, x0
 102
 103         /* Recover the original x0 value and stash it in tpidrro_el0 */
 104         sub     x0, sp, x0
 105         msr     tpidrro_el0, x0
 106
 107         /* Switch to the overflow stack */
 108         adr_this_cpu sp, overflow_stack + OVERFLOW_STACK_SIZE, x0
 109
 110         /*
 111          * Check whether we were already on the overflow stack. This may happen
 112          * after panic() re-enables interrupts.
 113          */
 114         mrs     x0, tpidr_el0                   // sp of interrupted context
 115         sub     x0, sp, x0                      // delta with top of overflow stack
 116         tst     x0, #~(OVERFLOW_STACK_SIZE - 1) // within range?
 117         b.ne    __bad_stack                     // no? -> bad stack pointer
 118
 119         /* We were already on the overflow stack. Restore sp/x0 and carry on. */
 120         sub     sp, sp, x0
 121         mrs     x0, tpidrro_el0
 122 #endif
 123         b       el\()\el\()_\label
 124         .endm
 125
 126         .macro tramp_alias, dst, sym
 127         mov_q   \dst, TRAMP_VALIAS
 128         add     \dst, \dst, #(\sym - .entry.tramp.text)
 129         .endm
 130
 131         // This macro corrupts x0-x3. It is the caller's duty
 132         // to save/restore them if required.
 133         .macro  apply_ssbd, state, tmp1, tmp2
 134 #ifdef CONFIG_ARM64_SSBD
 135 alternative_cb  arm64_enable_wa2_handling
 136         b       .L__asm_ssbd_skip\@
 137 alternative_cb_end
 138         ldr_this_cpu    \tmp2, arm64_ssbd_callback_required, \tmp1
 139         cbz     \tmp2,  .L__asm_ssbd_skip\@
 140         ldr     \tmp2, [tsk, #TSK_TI_FLAGS]
 141         tbnz    \tmp2, #TIF_SSBD, .L__asm_ssbd_skip\@
 142         mov     w0, #ARM_SMCCC_ARCH_WORKAROUND_2
 143         mov     w1, #\state
 144 alternative_cb  arm64_update_smccc_conduit
 145         nop                                     // Patched to SMC/HVC #0
 146 alternative_cb_end
 147 .L__asm_ssbd_skip\@:
 148 #endif
 149         .endm
 150
 151         .macro  kernel_entry, el, regsize = 64
 152         .if     \regsize == 32
 153         mov     w0, w0                          // zero upper 32 bits of x0
 154         .endif
 155         stp     x0, x1, [sp, #16 * 0]
 156         stp     x2, x3, [sp, #16 * 1]
 157         stp     x4, x5, [sp, #16 * 2]
 158         stp     x6, x7, [sp, #16 * 3]
 159         stp     x8, x9, [sp, #16 * 4]
 160         stp     x10, x11, [sp, #16 * 5]
 161         stp     x12, x13, [sp, #16 * 6]
 162         stp     x14, x15, [sp, #16 * 7]
 163         stp     x16, x17, [sp, #16 * 8]
 164         stp     x18, x19, [sp, #16 * 9]
 165         stp     x20, x21, [sp, #16 * 10]
 166         stp     x22, x23, [sp, #16 * 11]
 167         stp     x24, x25, [sp, #16 * 12]
 168         stp     x26, x27, [sp, #16 * 13]
 169         stp     x28, x29, [sp, #16 * 14]
 170
 171         .if     \el == 0
 172         mrs     x21, sp_el0
 173         ldr_this_cpu    tsk, __entry_task, x20  // Ensure MDSCR_EL1.SS is clear,
 174         ldr     x19, [tsk, #TSK_TI_FLAGS]       // since we can unmask debug
 175         disable_step_tsk x19, x20               // exceptions when scheduling.
 176
 177         apply_ssbd 1, x22, x23
 178
 179         mov     x29, xzr                        // fp pointed to user-space
 180         .else
 181         add     x21, sp, #S_FRAME_SIZE
 182         get_thread_info tsk
 183         /* Save the task's original addr_limit and set USER_DS */
 184         ldr     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 185         str     x20, [sp, #S_ORIG_ADDR_LIMIT]
 186         mov     x20, #USER_DS
 187         str     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 188         /* No need to reset PSTATE.UAO, hardware's already set it to 0 for us */
 189         .endif /* \el == 0 */
 190         mrs     x22, elr_el1
 191         mrs     x23, spsr_el1
 192         stp     lr, x21, [sp, #S_LR]
 193
 194         /*
 195          * In order to be able to dump the contents of struct pt_regs at the
 196          * time the exception was taken (in case we attempt to walk the call
 197          * stack later), chain it together with the stack frames.
 198          */
 199         .if \el == 0
 200         stp     xzr, xzr, [sp, #S_STACKFRAME]
 201         .else
 202         stp     x29, x22, [sp, #S_STACKFRAME]
 203         .endif
 204         add     x29, sp, #S_STACKFRAME
 205
 206 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 207         /*
 208          * Set the TTBR0 PAN bit in SPSR. When the exception is taken from
 209          * EL0, there is no need to check the state of TTBR0_EL1 since
 210          * accesses are always enabled.
 211          * Note that the meaning of this bit differs from the ARMv8.1 PAN
 212          * feature as all TTBR0_EL1 accesses are disabled, not just those to
 213          * user mappings.
 214          */
 215 alternative_if ARM64_HAS_PAN
 216         b       1f                              // skip TTBR0 PAN
 217 alternative_else_nop_endif
 218
 219         .if     \el != 0
 220         mrs     x21, ttbr0_el1
 221         tst     x21, #TTBR_ASID_MASK            // Check for the reserved ASID
 222         orr     x23, x23, #PSR_PAN_BIT          // Set the emulated PAN in the saved SPSR
 223         b.eq    1f                              // TTBR0 access already disabled
 224         and     x23, x23, #~PSR_PAN_BIT         // Clear the emulated PAN in the saved SPSR
 225         .endif
 226
 227         __uaccess_ttbr0_disable x21
 228 1:
 229 #endif
 230
 231         stp     x22, x23, [sp, #S_PC]
 232
 233         /* Not in a syscall by default (el0_svc overwrites for real syscall) */
 234         .if     \el == 0
 235         mov     w21, #NO_SYSCALL
 236         str     w21, [sp, #S_SYSCALLNO]
 237         .endif
 238
 239         /*
 240          * Set sp_el0 to current thread_info.
 241          */
 242         .if     \el == 0
 243         msr     sp_el0, tsk
 244         .endif
 245
 246         /*
 247          * Registers that may be useful after this macro is invoked:
 248          *
 249          * x21 - aborted SP
 250          * x22 - aborted PC
 251          * x23 - aborted PSTATE
 252         */
 253         .endm
 254
 255         .macro  kernel_exit, el
 256         .if     \el != 0
 257         disable_daif
 258
 259         /* Restore the task's original addr_limit. */
 260         ldr     x20, [sp, #S_ORIG_ADDR_LIMIT]
 261         str     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 262
 263         /* No need to restore UAO, it will be restored from SPSR_EL1 */
 264         .endif
 265
 266         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 267         .if     \el == 0
 268         ct_user_enter
 269         .endif
 270
 271 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 272         /*
 273          * Restore access to TTBR0_EL1. If returning to EL0, no need for SPSR
 274          * PAN bit checking.
 275          */
 276 alternative_if ARM64_HAS_PAN
 277         b       2f                              // skip TTBR0 PAN
 278 alternative_else_nop_endif
 279
 280         .if     \el != 0
 281         tbnz    x22, #22, 1f                    // Skip re-enabling TTBR0 access if the PSR_PAN_BIT is set
 282         .endif
 283
 284         __uaccess_ttbr0_enable x0, x1
 285
 286         .if     \el == 0
 287         /*
 288          * Enable errata workarounds only if returning to user. The only
 289          * workaround currently required for TTBR0_EL1 changes are for the
 290          * Cavium erratum 27456 (broadcast TLBI instructions may cause I-cache
 291          * corruption).
 292          */
 293         bl      post_ttbr_update_workaround
 294         .endif
 295 1:
 296         .if     \el != 0
 297         and     x22, x22, #~PSR_PAN_BIT         // ARMv8.0 CPUs do not understand this bit
 298         .endif
 299 2:
 300 #endif
 301
 302         .if     \el == 0
 303         ldr     x23, [sp, #S_SP]                // load return stack pointer
 304         msr     sp_el0, x23
 305         tst     x22, #PSR_MODE32_BIT            // native task?
 306         b.eq    3f
 307
 308 #ifdef CONFIG_ARM64_ERRATUM_845719
 309 alternative_if ARM64_WORKAROUND_845719
 310 #ifdef CONFIG_PID_IN_CONTEXTIDR
 311         mrs     x29, contextidr_el1
 312         msr     contextidr_el1, x29
 313 #else
 314         msr contextidr_el1, xzr
 315 #endif
 316 alternative_else_nop_endif
 317 #endif
 318 3:
 319         apply_ssbd 0, x0, x1
 320         .endif
 321
 322         msr     elr_el1, x21                    // set up the return data
 323         msr     spsr_el1, x22
 324         ldp     x0, x1, [sp, #16 * 0]
 325         ldp     x2, x3, [sp, #16 * 1]
 326         ldp     x4, x5, [sp, #16 * 2]
 327         ldp     x6, x7, [sp, #16 * 3]
 328         ldp     x8, x9, [sp, #16 * 4]
 329         ldp     x10, x11, [sp, #16 * 5]
 330         ldp     x12, x13, [sp, #16 * 6]
 331         ldp     x14, x15, [sp, #16 * 7]
 332         ldp     x16, x17, [sp, #16 * 8]
 333         ldp     x18, x19, [sp, #16 * 9]
 334         ldp     x20, x21, [sp, #16 * 10]
 335         ldp     x22, x23, [sp, #16 * 11]
 336         ldp     x24, x25, [sp, #16 * 12]
 337         ldp     x26, x27, [sp, #16 * 13]
 338         ldp     x28, x29, [sp, #16 * 14]
 339         ldr     lr, [sp, #S_LR]
 340         add     sp, sp, #S_FRAME_SIZE           // restore sp
 341         /*
 342          * ARCH_HAS_MEMBARRIER_SYNC_CORE rely on eret context synchronization
 343          * when returning from IPI handler, and when returning to user-space.
 344          */
 345
 346         .if     \el == 0
 347 alternative_insn eret, nop, ARM64_UNMAP_KERNEL_AT_EL0
 348 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 349         bne     4f
 350         msr     far_el1, x30
 351         tramp_alias     x30, tramp_exit_native
 352         br      x30
 353 4:
 354         tramp_alias     x30, tramp_exit_compat
 355         br      x30
 356 #endif
 357         .else
 358         eret
 359         .endif
 360         .endm
 361
 362         .macro  irq_stack_entry
 363         mov     x19, sp                 // preserve the original sp
 364
 365         /*
 366          * Compare sp with the base of the task stack.
 367          * If the top ~(THREAD_SIZE - 1) bits match, we are on a task stack,
 368          * and should switch to the irq stack.
 369          */
 370         ldr     x25, [tsk, TSK_STACK]
 371         eor     x25, x25, x19
 372         and     x25, x25, #~(THREAD_SIZE - 1)
 373         cbnz    x25, 9998f
 374
 375         ldr_this_cpu x25, irq_stack_ptr, x26
 376         mov     x26, #IRQ_STACK_SIZE
 377         add     x26, x25, x26
 378
 379         /* switch to the irq stack */
 380         mov     sp, x26
 381 9998:
 382         .endm
 383
 384         /*
 385          * x19 should be preserved between irq_stack_entry and
 386          * irq_stack_exit.
 387          */
 388         .macro  irq_stack_exit
 389         mov     sp, x19
 390         .endm
 391
 392 /*
 393  * These are the registers used in the syscall handler, and allow us to
 394  * have in theory up to 7 arguments to a function - x0 to x6.
 395  *
 396  * x7 is reserved for the system call number in 32-bit mode.
 397  */
 398 wsc_nr  .req    w25             // number of system calls
 399 xsc_nr  .req    x25             // number of system calls (zero-extended)
 400 wscno   .req    w26             // syscall number
 401 xscno   .req    x26             // syscall number (zero-extended)
 402 stbl    .req    x27             // syscall table pointer
 403 tsk     .req    x28             // current thread_info
 404
 405 /*
 406  * Interrupt handling.
 407  */
 408         .macro  irq_handler
 409         ldr_l   x1, handle_arch_irq
 410         mov     x0, sp
 411         irq_stack_entry
 412         blr     x1
 413         irq_stack_exit
 414         .endm
 415
 416         .text
 417
 418 /*
 419  * Exception vectors.
 420  */
 421         .pushsection ".entry.text", "ax"
 422
 423         .align  11
 424 ENTRY(vectors)
 425         kernel_ventry   1, sync_invalid                 // Synchronous EL1t
 426         kernel_ventry   1, irq_invalid                  // IRQ EL1t
 427         kernel_ventry   1, fiq_invalid                  // FIQ EL1t
 428         kernel_ventry   1, error_invalid                // Error EL1t
 429
 430         kernel_ventry   1, sync                         // Synchronous EL1h
 431         kernel_ventry   1, irq                          // IRQ EL1h
 432         kernel_ventry   1, fiq_invalid                  // FIQ EL1h
 433         kernel_ventry   1, error                        // Error EL1h
 434
 435         kernel_ventry   0, sync                         // Synchronous 64-bit EL0
 436         kernel_ventry   0, irq                          // IRQ 64-bit EL0
 437         kernel_ventry   0, fiq_invalid                  // FIQ 64-bit EL0
 438         kernel_ventry   0, error                        // Error 64-bit EL0
 439
 440 #ifdef CONFIG_COMPAT
 441         kernel_ventry   0, sync_compat, 32              // Synchronous 32-bit EL0
 442         kernel_ventry   0, irq_compat, 32               // IRQ 32-bit EL0
 443         kernel_ventry   0, fiq_invalid_compat, 32       // FIQ 32-bit EL0
 444         kernel_ventry   0, error_compat, 32             // Error 32-bit EL0
 445 #else
 446         kernel_ventry   0, sync_invalid, 32             // Synchronous 32-bit EL0
 447         kernel_ventry   0, irq_invalid, 32              // IRQ 32-bit EL0
 448         kernel_ventry   0, fiq_invalid, 32              // FIQ 32-bit EL0
 449         kernel_ventry   0, error_invalid, 32            // Error 32-bit EL0
 450 #endif
 451 END(vectors)
 452
 453 #ifdef CONFIG_VMAP_STACK
 454         /*
 455          * We detected an overflow in kernel_ventry, which switched to the
 456          * overflow stack. Stash the exception regs, and head to our overflow
 457          * handler.
 458          */
 459 __bad_stack:
 460         /* Restore the original x0 value */
 461         mrs     x0, tpidrro_el0
 462
 463         /*
 464          * Store the original GPRs to the new stack. The orginal SP (minus
 465          * S_FRAME_SIZE) was stashed in tpidr_el0 by kernel_ventry.
 466          */
 467         sub     sp, sp, #S_FRAME_SIZE
 468         kernel_entry 1
 469         mrs     x0, tpidr_el0
 470         add     x0, x0, #S_FRAME_SIZE
 471         str     x0, [sp, #S_SP]
 472
 473         /* Stash the regs for handle_bad_stack */
 474         mov     x0, sp
 475
 476         /* Time to die */
 477         bl      handle_bad_stack
 478         ASM_BUG()
 479 #endif /* CONFIG_VMAP_STACK */
 480
 481 /*
 482  * Invalid mode handlers
 483  */
 484         .macro  inv_entry, el, reason, regsize = 64
 485         kernel_entry \el, \regsize
 486         mov     x0, sp
 487         mov     x1, #\reason
 488         mrs     x2, esr_el1
 489         bl      bad_mode
 490         ASM_BUG()
 491         .endm
 492
 493 el0_sync_invalid:
 494         inv_entry 0, BAD_SYNC
 495 ENDPROC(el0_sync_invalid)
 496
 497 el0_irq_invalid:
 498         inv_entry 0, BAD_IRQ
 499 ENDPROC(el0_irq_invalid)
 500
 501 el0_fiq_invalid:
 502         inv_entry 0, BAD_FIQ
 503 ENDPROC(el0_fiq_invalid)
 504
 505 el0_error_invalid:
 506         inv_entry 0, BAD_ERROR
 507 ENDPROC(el0_error_invalid)
 508
 509 #ifdef CONFIG_COMPAT
 510 el0_fiq_invalid_compat:
 511         inv_entry 0, BAD_FIQ, 32
 512 ENDPROC(el0_fiq_invalid_compat)
 513 #endif
 514
 515 el1_sync_invalid:
 516         inv_entry 1, BAD_SYNC
 517 ENDPROC(el1_sync_invalid)
 518
 519 el1_irq_invalid:
 520         inv_entry 1, BAD_IRQ
 521 ENDPROC(el1_irq_invalid)
 522
 523 el1_fiq_invalid:
 524         inv_entry 1, BAD_FIQ
 525 ENDPROC(el1_fiq_invalid)
 526
 527 el1_error_invalid:
 528         inv_entry 1, BAD_ERROR
 529 ENDPROC(el1_error_invalid)
 530
 531 /*
 532  * EL1 mode handlers.
 533  */
 534         .align  6
 535 el1_sync:
 536         kernel_entry 1
 537         mrs     x1, esr_el1                     // read the syndrome register
 538         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 539         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 540         b.eq    el1_da
 541         cmp     x24, #ESR_ELx_EC_IABT_CUR       // instruction abort in EL1
 542         b.eq    el1_ia
 543         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 544         b.eq    el1_undef
 545         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 546         b.eq    el1_sp_pc
 547         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 548         b.eq    el1_sp_pc
 549         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 550         b.eq    el1_undef
 551         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 552         b.ge    el1_dbg
 553         b       el1_inv
 554
 555 el1_ia:
 556         /*
 557          * Fall through to the Data abort case
 558          */
 559 el1_da:
 560         /*
 561          * Data abort handling
 562          */
 563         mrs     x3, far_el1
 564         inherit_daif    pstate=x23, tmp=x2
 565         clear_address_tag x0, x3
 566         mov     x2, sp                          // struct pt_regs
 567         bl      do_mem_abort
 568
 569         kernel_exit 1
 570 el1_sp_pc:
 571         /*
 572          * Stack or PC alignment exception handling
 573          */
 574         mrs     x0, far_el1
 575         inherit_daif    pstate=x23, tmp=x2
 576         mov     x2, sp
 577         bl      do_sp_pc_abort
 578         ASM_BUG()
 579 el1_undef:
 580         /*
 581          * Undefined instruction
 582          */
 583         inherit_daif    pstate=x23, tmp=x2
 584         mov     x0, sp
 585         bl      do_undefinstr
 586         ASM_BUG()
 587 el1_dbg:
 588         /*
 589          * Debug exception handling
 590          */
 591         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 592         cinc    x24, x24, eq                    // set bit '0'
 593         tbz     x24, #0, el1_inv                // EL1 only
 594         mrs     x0, far_el1
 595         mov     x2, sp                          // struct pt_regs
 596         bl      do_debug_exception
 597         kernel_exit 1
 598 el1_inv:
 599         // TODO: add support for undefined instructions in kernel mode
 600         inherit_daif    pstate=x23, tmp=x2
 601         mov     x0, sp
 602         mov     x2, x1
 603         mov     x1, #BAD_SYNC
 604         bl      bad_mode
 605         ASM_BUG()
 606 ENDPROC(el1_sync)
 607
 608         .align  6
 609 el1_irq:
 610         kernel_entry 1
 611         enable_da_f
 612 #ifdef CONFIG_TRACE_IRQFLAGS
 613         bl      trace_hardirqs_off
 614 #endif
 615
 616         irq_handler
 617
 618 #ifdef CONFIG_PREEMPT
 619         ldr     w24, [tsk, #TSK_TI_PREEMPT]     // get preempt count
 620         cbnz    w24, 1f                         // preempt count != 0
 621         ldr     x0, [tsk, #TSK_TI_FLAGS]        // get flags
 622         tbz     x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 623         bl      el1_preempt
 624 1:
 625 #endif
 626 #ifdef CONFIG_TRACE_IRQFLAGS
 627         bl      trace_hardirqs_on
 628 #endif
 629         kernel_exit 1
 630 ENDPROC(el1_irq)
 631
 632 #ifdef CONFIG_PREEMPT
 633 el1_preempt:
 634         mov     x24, lr
 635 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 636         ldr     x0, [tsk, #TSK_TI_FLAGS]        // get new tasks TI_FLAGS
 637         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 638         ret     x24
 639 #endif
 640
 641 /*
 642  * EL0 mode handlers.
 643  */
 644         .align  6
 645 el0_sync:
 646         kernel_entry 0
 647         mrs     x25, esr_el1                    // read the syndrome register
 648         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 649         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 650         b.eq    el0_svc
 651         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 652         b.eq    el0_da
 653         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 654         b.eq    el0_ia
 655         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 656         b.eq    el0_fpsimd_acc
 657         cmp     x24, #ESR_ELx_EC_SVE            // SVE access
 658         b.eq    el0_sve_acc
 659         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 660         b.eq    el0_fpsimd_exc
 661         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 662         b.eq    el0_sys
 663         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 664         b.eq    el0_sp_pc
 665         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 666         b.eq    el0_sp_pc
 667         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 668         b.eq    el0_undef
 669         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 670         b.ge    el0_dbg
 671         b       el0_inv
 672
 673 #ifdef CONFIG_COMPAT
 674         .align  6
 675 el0_sync_compat:
 676         kernel_entry 0, 32
 677         mrs     x25, esr_el1                    // read the syndrome register
 678         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 679         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 680         b.eq    el0_svc_compat
 681         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 682         b.eq    el0_da
 683         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 684         b.eq    el0_ia
 685         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 686         b.eq    el0_fpsimd_acc
 687         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 688         b.eq    el0_fpsimd_exc
 689         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 690         b.eq    el0_sp_pc
 691         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 692         b.eq    el0_undef
 693         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 694         b.eq    el0_undef
 695         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 696         b.eq    el0_undef
 697         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 698         b.eq    el0_undef
 699         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 700         b.eq    el0_undef
 701         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 702         b.eq    el0_undef
 703         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 704         b.ge    el0_dbg
 705         b       el0_inv
 706 el0_svc_compat:
 707         mov     x0, sp
 708         bl      el0_svc_compat_handler
 709         b       ret_to_user
 710
 711         .align  6
 712 el0_irq_compat:
 713         kernel_entry 0, 32
 714         b       el0_irq_naked
 715
 716 el0_error_compat:
 717         kernel_entry 0, 32
 718         b       el0_error_naked
 719 #endif
 720
 721 el0_da:
 722         /*
 723          * Data abort handling
 724          */
 725         mrs     x26, far_el1
 726         enable_daif
 727         ct_user_exit
 728         clear_address_tag x0, x26
 729         mov     x1, x25
 730         mov     x2, sp
 731         bl      do_mem_abort
 732         b       ret_to_user
 733 el0_ia:
 734         /*
 735          * Instruction abort handling
 736          */
 737         mrs     x26, far_el1
 738         enable_da_f
 739 #ifdef CONFIG_TRACE_IRQFLAGS
 740         bl      trace_hardirqs_off
 741 #endif
 742         ct_user_exit
 743         mov     x0, x26
 744         mov     x1, x25
 745         mov     x2, sp
 746         bl      do_el0_ia_bp_hardening
 747         b       ret_to_user
 748 el0_fpsimd_acc:
 749         /*
 750          * Floating Point or Advanced SIMD access
 751          */
 752         enable_daif
 753         ct_user_exit
 754         mov     x0, x25
 755         mov     x1, sp
 756         bl      do_fpsimd_acc
 757         b       ret_to_user
 758 el0_sve_acc:
 759         /*
 760          * Scalable Vector Extension access
 761          */
 762         enable_daif
 763         ct_user_exit
 764         mov     x0, x25
 765         mov     x1, sp
 766         bl      do_sve_acc
 767         b       ret_to_user
 768 el0_fpsimd_exc:
 769         /*
 770          * Floating Point, Advanced SIMD or SVE exception
 771          */
 772         enable_daif
 773         ct_user_exit
 774         mov     x0, x25
 775         mov     x1, sp
 776         bl      do_fpsimd_exc
 777         b       ret_to_user
 778 el0_sp_pc:
 779         /*
 780          * Stack or PC alignment exception handling
 781          */
 782         mrs     x26, far_el1
 783         enable_da_f
 784 #ifdef CONFIG_TRACE_IRQFLAGS
 785         bl      trace_hardirqs_off
 786 #endif
 787         ct_user_exit
 788         mov     x0, x26
 789         mov     x1, x25
 790         mov     x2, sp
 791         bl      do_sp_pc_abort
 792         b       ret_to_user
 793 el0_undef:
 794         /*
 795          * Undefined instruction
 796          */
 797         enable_daif
 798         ct_user_exit
 799         mov     x0, sp
 800         bl      do_undefinstr
 801         b       ret_to_user
 802 el0_sys:
 803         /*
 804          * System instructions, for trapped cache maintenance instructions
 805          */
 806         enable_daif
 807         ct_user_exit
 808         mov     x0, x25
 809         mov     x1, sp
 810         bl      do_sysinstr
 811         b       ret_to_user
 812 el0_dbg:
 813         /*
 814          * Debug exception handling
 815          */
 816         tbnz    x24, #0, el0_inv                // EL0 only
 817         mrs     x0, far_el1
 818         mov     x1, x25
 819         mov     x2, sp
 820         bl      do_debug_exception
 821         enable_daif
 822         ct_user_exit
 823         b       ret_to_user
 824 el0_inv:
 825         enable_daif
 826         ct_user_exit
 827         mov     x0, sp
 828         mov     x1, #BAD_SYNC
 829         mov     x2, x25
 830         bl      bad_el0_sync
 831         b       ret_to_user
 832 ENDPROC(el0_sync)
 833
 834         .align  6
 835 el0_irq:
 836         kernel_entry 0
 837 el0_irq_naked:
 838         enable_da_f
 839 #ifdef CONFIG_TRACE_IRQFLAGS
 840         bl      trace_hardirqs_off
 841 #endif
 842
 843         ct_user_exit
 844 #ifdef CONFIG_HARDEN_BRANCH_PREDICTOR
 845         tbz     x22, #55, 1f
 846         bl      do_el0_irq_bp_hardening
 847 1:
 848 #endif
 849         irq_handler
 850
 851 #ifdef CONFIG_TRACE_IRQFLAGS
 852         bl      trace_hardirqs_on
 853 #endif
 854         b       ret_to_user
 855 ENDPROC(el0_irq)
 856
 857 el1_error:
 858         kernel_entry 1
 859         mrs     x1, esr_el1
 860         enable_dbg
 861         mov     x0, sp
 862         bl      do_serror
 863         kernel_exit 1
 864 ENDPROC(el1_error)
 865
 866 el0_error:
 867         kernel_entry 0
 868 el0_error_naked:
 869         mrs     x1, esr_el1
 870         enable_dbg
 871         mov     x0, sp
 872         bl      do_serror
 873         enable_daif
 874         ct_user_exit
 875         b       ret_to_user
 876 ENDPROC(el0_error)
 877
 878 /*
 879  * Ok, we need to do extra processing, enter the slow path.
 880  */
 881 work_pending:
 882         mov     x0, sp                          // 'regs'
 883         bl      do_notify_resume
 884 #ifdef CONFIG_TRACE_IRQFLAGS
 885         bl      trace_hardirqs_on               // enabled while in userspace
 886 #endif
 887         ldr     x1, [tsk, #TSK_TI_FLAGS]        // re-check for single-step
 888         b       finish_ret_to_user
 889 /*
 890  * "slow" syscall return path.
 891  */
 892 ret_to_user:
 893         disable_daif
 894         ldr     x1, [tsk, #TSK_TI_FLAGS]
 895         and     x2, x1, #_TIF_WORK_MASK
 896         cbnz    x2, work_pending
 897 finish_ret_to_user:
 898         enable_step_tsk x1, x2
 899         kernel_exit 0
 900 ENDPROC(ret_to_user)
 901
 902 /*
 903  * SVC handler.
 904  */
 905         .align  6
 906 el0_svc:
 907         mov     x0, sp
 908         bl      el0_svc_handler
 909         b       ret_to_user
 910 ENDPROC(el0_svc)
 911
 912         .popsection                             // .entry.text
 913
 914 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 915 /*
 916  * Exception vectors trampoline.
 917  */
 918         .pushsection ".entry.tramp.text", "ax"
 919
 920         .macro tramp_map_kernel, tmp
 921         mrs     \tmp, ttbr1_el1
 922         add     \tmp, \tmp, #(PAGE_SIZE + RESERVED_TTBR0_SIZE)
 923         bic     \tmp, \tmp, #USER_ASID_FLAG
 924         msr     ttbr1_el1, \tmp
 925 #ifdef CONFIG_QCOM_FALKOR_ERRATUM_1003
 926 alternative_if ARM64_WORKAROUND_QCOM_FALKOR_E1003
 927         /* ASID already in \tmp[63:48] */
 928         movk    \tmp, #:abs_g2_nc:(TRAMP_VALIAS >> 12)
 929         movk    \tmp, #:abs_g1_nc:(TRAMP_VALIAS >> 12)
 930         /* 2MB boundary containing the vectors, so we nobble the walk cache */
 931         movk    \tmp, #:abs_g0_nc:((TRAMP_VALIAS & ~(SZ_2M - 1)) >> 12)
 932         isb
 933         tlbi    vae1, \tmp
 934         dsb     nsh
 935 alternative_else_nop_endif
 936 #endif /* CONFIG_QCOM_FALKOR_ERRATUM_1003 */
 937         .endm
 938
 939         .macro tramp_unmap_kernel, tmp
 940         mrs     \tmp, ttbr1_el1
 941         sub     \tmp, \tmp, #(PAGE_SIZE + RESERVED_TTBR0_SIZE)
 942         orr     \tmp, \tmp, #USER_ASID_FLAG
 943         msr     ttbr1_el1, \tmp
 944         /*
 945          * We avoid running the post_ttbr_update_workaround here because
 946          * it's only needed by Cavium ThunderX, which requires KPTI to be
 947          * disabled.
 948          */
 949         .endm
 950
 951         .macro tramp_ventry, regsize = 64
 952         .align  7
 953 1:
 954         .if     \regsize == 64
 955         msr     tpidrro_el0, x30        // Restored in kernel_ventry
 956         .endif
 957         /*
 958          * Defend against branch aliasing attacks by pushing a dummy
 959          * entry onto the return stack and using a RET instruction to
 960          * enter the full-fat kernel vectors.
 961          */
 962         bl      2f
 963         b       .
 964 2:
 965         tramp_map_kernel        x30
 966 #ifdef CONFIG_RANDOMIZE_BASE
 967         adr     x30, tramp_vectors + PAGE_SIZE
 968 alternative_insn isb, nop, ARM64_WORKAROUND_QCOM_FALKOR_E1003
 969         ldr     x30, [x30]
 970 #else
 971         ldr     x30, =vectors
 972 #endif
 973         prfm    plil1strm, [x30, #(1b - tramp_vectors)]
 974         msr     vbar_el1, x30
 975         add     x30, x30, #(1b - tramp_vectors)
 976         isb
 977         ret
 978         .endm
 979
 980         .macro tramp_exit, regsize = 64
 981         adr     x30, tramp_vectors
 982         msr     vbar_el1, x30
 983         tramp_unmap_kernel      x30
 984         .if     \regsize == 64
 985         mrs     x30, far_el1
 986         .endif
 987         eret
 988         .endm
 989
 990         .align  11
 991 ENTRY(tramp_vectors)
 992         .space  0x400
 993
 994         tramp_ventry
 995         tramp_ventry
 996         tramp_ventry
 997         tramp_ventry
 998
 999         tramp_ventry    32
1000         tramp_ventry    32
1001         tramp_ventry    32
1002         tramp_ventry    32
1003 END(tramp_vectors)
1004
1005 ENTRY(tramp_exit_native)
1006         tramp_exit
1007 END(tramp_exit_native)
1008
1009 ENTRY(tramp_exit_compat)
1010         tramp_exit      32
1011 END(tramp_exit_compat)
1012
1013         .ltorg
1014         .popsection                             // .entry.tramp.text
1015 #ifdef CONFIG_RANDOMIZE_BASE
1016         .pushsection ".rodata", "a"
1017         .align PAGE_SHIFT
1018         .globl  __entry_tramp_data_start
1019 __entry_tramp_data_start:
1020         .quad   vectors
1021         .popsection                             // .rodata
1022 #endif /* CONFIG_RANDOMIZE_BASE */
1023 #endif /* CONFIG_UNMAP_KERNEL_AT_EL0 */
1024
1025 /*
1026  * Register switch for AArch64. The callee-saved registers need to be saved
1027  * and restored. On entry:
1028  *   x0 = previous task_struct (must be preserved across the switch)
1029  *   x1 = next task_struct
1030  * Previous and next are guaranteed not to be the same.
1031  *
1032  */
1033 ENTRY(cpu_switch_to)
1034         mov     x10, #THREAD_CPU_CONTEXT
1035         add     x8, x0, x10
1036         mov     x9, sp
1037         stp     x19, x20, [x8], #16             // store callee-saved registers
1038         stp     x21, x22, [x8], #16
1039         stp     x23, x24, [x8], #16
1040         stp     x25, x26, [x8], #16
1041         stp     x27, x28, [x8], #16
1042         stp     x29, x9, [x8], #16
1043         str     lr, [x8]
1044         add     x8, x1, x10
1045         ldp     x19, x20, [x8], #16             // restore callee-saved registers
1046         ldp     x21, x22, [x8], #16
1047         ldp     x23, x24, [x8], #16
1048         ldp     x25, x26, [x8], #16
1049         ldp     x27, x28, [x8], #16
1050         ldp     x29, x9, [x8], #16
1051         ldr     lr, [x8]
1052         mov     sp, x9
1053         msr     sp_el0, x1
1054         ret
1055 ENDPROC(cpu_switch_to)
1056 NOKPROBE(cpu_switch_to)
1057
1058 /*
1059  * This is how we return from a fork.
1060  */
1061 ENTRY(ret_from_fork)
1062         bl      schedule_tail
1063         cbz     x19, 1f                         // not a kernel thread
1064         mov     x0, x20
1065         blr     x19
1066 1:      get_thread_info tsk
1067         b       ret_to_user
1068 ENDPROC(ret_from_fork)
1069 NOKPROBE(ret_from_fork)
1070
1071 #ifdef CONFIG_ARM_SDE_INTERFACE
1072
1073 #include <asm/sdei.h>
1074 #include <uapi/linux/arm_sdei.h>
1075
1076 .macro sdei_handler_exit exit_mode
1077         /* On success, this call never returns... */
1078         cmp     \exit_mode, #SDEI_EXIT_SMC
1079         b.ne    99f
1080         smc     #0
1081         b       .
1082 99:     hvc     #0
1083         b       .
1084 .endm
1085
1086 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
1087 /*
1088  * The regular SDEI entry point may have been unmapped along with the rest of
1089  * the kernel. This trampoline restores the kernel mapping to make the x1 memory
1090  * argument accessible.
1091  *
1092  * This clobbers x4, __sdei_handler() will restore this from firmware's
1093  * copy.
1094  */
1095 .ltorg
1096 .pushsection ".entry.tramp.text", "ax"
1097 ENTRY(__sdei_asm_entry_trampoline)
1098         mrs     x4, ttbr1_el1
1099         tbz     x4, #USER_ASID_BIT, 1f
1100
1101         tramp_map_kernel tmp=x4
1102         isb
1103         mov     x4, xzr
1104
1105         /*
1106          * Use reg->interrupted_regs.addr_limit to remember whether to unmap
1107          * the kernel on exit.
1108          */
1109 1:      str     x4, [x1, #(SDEI_EVENT_INTREGS + S_ORIG_ADDR_LIMIT)]
1110
1111 #ifdef CONFIG_RANDOMIZE_BASE
1112         adr     x4, tramp_vectors + PAGE_SIZE
1113         add     x4, x4, #:lo12:__sdei_asm_trampoline_next_handler
1114         ldr     x4, [x4]
1115 #else
1116         ldr     x4, =__sdei_asm_handler
1117 #endif
1118         br      x4
1119 ENDPROC(__sdei_asm_entry_trampoline)
1120 NOKPROBE(__sdei_asm_entry_trampoline)
1121
1122 /*
1123  * Make the exit call and restore the original ttbr1_el1
1124  *
1125  * x0 & x1: setup for the exit API call
1126  * x2: exit_mode
1127  * x4: struct sdei_registered_event argument from registration time.
1128  */
1129 ENTRY(__sdei_asm_exit_trampoline)
1130         ldr     x4, [x4, #(SDEI_EVENT_INTREGS + S_ORIG_ADDR_LIMIT)]
1131         cbnz    x4, 1f
1132
1133         tramp_unmap_kernel      tmp=x4
1134
1135 1:      sdei_handler_exit exit_mode=x2
1136 ENDPROC(__sdei_asm_exit_trampoline)
1137 NOKPROBE(__sdei_asm_exit_trampoline)
1138         .ltorg
1139 .popsection             // .entry.tramp.text
1140 #ifdef CONFIG_RANDOMIZE_BASE
1141 .pushsection ".rodata", "a"
1142 __sdei_asm_trampoline_next_handler:
1143         .quad   __sdei_asm_handler
1144 .popsection             // .rodata
1145 #endif /* CONFIG_RANDOMIZE_BASE */
1146 #endif /* CONFIG_UNMAP_KERNEL_AT_EL0 */
1147
1148 /*
1149  * Software Delegated Exception entry point.
1150  *
1151  * x0: Event number
1152  * x1: struct sdei_registered_event argument from registration time.
1153  * x2: interrupted PC
1154  * x3: interrupted PSTATE
1155  * x4: maybe clobbered by the trampoline
1156  *
1157  * Firmware has preserved x0->x17 for us, we must save/restore the rest to
1158  * follow SMC-CC. We save (or retrieve) all the registers as the handler may
1159  * want them.
1160  */
1161 ENTRY(__sdei_asm_handler)
1162         stp     x2, x3, [x1, #SDEI_EVENT_INTREGS + S_PC]
1163         stp     x4, x5, [x1, #SDEI_EVENT_INTREGS + 16 * 2]
1164         stp     x6, x7, [x1, #SDEI_EVENT_INTREGS + 16 * 3]
1165         stp     x8, x9, [x1, #SDEI_EVENT_INTREGS + 16 * 4]
1166         stp     x10, x11, [x1, #SDEI_EVENT_INTREGS + 16 * 5]
1167         stp     x12, x13, [x1, #SDEI_EVENT_INTREGS + 16 * 6]
1168         stp     x14, x15, [x1, #SDEI_EVENT_INTREGS + 16 * 7]
1169         stp     x16, x17, [x1, #SDEI_EVENT_INTREGS + 16 * 8]
1170         stp     x18, x19, [x1, #SDEI_EVENT_INTREGS + 16 * 9]
1171         stp     x20, x21, [x1, #SDEI_EVENT_INTREGS + 16 * 10]
1172         stp     x22, x23, [x1, #SDEI_EVENT_INTREGS + 16 * 11]
1173         stp     x24, x25, [x1, #SDEI_EVENT_INTREGS + 16 * 12]
1174         stp     x26, x27, [x1, #SDEI_EVENT_INTREGS + 16 * 13]
1175         stp     x28, x29, [x1, #SDEI_EVENT_INTREGS + 16 * 14]
1176         mov     x4, sp
1177         stp     lr, x4, [x1, #SDEI_EVENT_INTREGS + S_LR]
1178
1179         mov     x19, x1
1180
1181 #ifdef CONFIG_VMAP_STACK
1182         /*
1183          * entry.S may have been using sp as a scratch register, find whether
1184          * this is a normal or critical event and switch to the appropriate
1185          * stack for this CPU.
1186          */
1187         ldrb    w4, [x19, #SDEI_EVENT_PRIORITY]
1188         cbnz    w4, 1f
1189         ldr_this_cpu dst=x5, sym=sdei_stack_normal_ptr, tmp=x6
1190         b       2f
1191 1:      ldr_this_cpu dst=x5, sym=sdei_stack_critical_ptr, tmp=x6
1192 2:      mov     x6, #SDEI_STACK_SIZE
1193         add     x5, x5, x6
1194         mov     sp, x5
1195 #endif
1196
1197         /*
1198          * We may have interrupted userspace, or a guest, or exit-from or
1199          * return-to either of these. We can't trust sp_el0, restore it.
1200          */
1201         mrs     x28, sp_el0
1202         ldr_this_cpu    dst=x0, sym=__entry_task, tmp=x1
1203         msr     sp_el0, x0
1204
1205         /* If we interrupted the kernel point to the previous stack/frame. */
1206         and     x0, x3, #0xc
1207         mrs     x1, CurrentEL
1208         cmp     x0, x1
1209         csel    x29, x29, xzr, eq       // fp, or zero
1210         csel    x4, x2, xzr, eq         // elr, or zero
1211
1212         stp     x29, x4, [sp, #-16]!
1213         mov     x29, sp
1214
1215         add     x0, x19, #SDEI_EVENT_INTREGS
1216         mov     x1, x19
1217         bl      __sdei_handler
1218
1219         msr     sp_el0, x28
1220         /* restore regs >x17 that we clobbered */
1221         mov     x4, x19         // keep x4 for __sdei_asm_exit_trampoline
1222         ldp     x28, x29, [x4, #SDEI_EVENT_INTREGS + 16 * 14]
1223         ldp     x18, x19, [x4, #SDEI_EVENT_INTREGS + 16 * 9]
1224         ldp     lr, x1, [x4, #SDEI_EVENT_INTREGS + S_LR]
1225         mov     sp, x1
1226
1227         mov     x1, x0                  // address to complete_and_resume
1228         /* x0 = (x0 <= 1) ? EVENT_COMPLETE:EVENT_COMPLETE_AND_RESUME */
1229         cmp     x0, #1
1230         mov_q   x2, SDEI_1_0_FN_SDEI_EVENT_COMPLETE
1231         mov_q   x3, SDEI_1_0_FN_SDEI_EVENT_COMPLETE_AND_RESUME
1232         csel    x0, x2, x3, ls
1233
1234         ldr_l   x2, sdei_exit_mode
1235
1236 alternative_if_not ARM64_UNMAP_KERNEL_AT_EL0
1237         sdei_handler_exit exit_mode=x2
1238 alternative_else_nop_endif
1239
1240 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
1241         tramp_alias     dst=x5, sym=__sdei_asm_exit_trampoline
1242         br      x5
1243 #endif
1244 ENDPROC(__sdei_asm_handler)
1245 NOKPROBE(__sdei_asm_handler)
1246 #endif /* CONFIG_ARM_SDE_INTERFACE */