arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/irq.h>
  31 #include <asm/memory.h>
  32 #include <asm/thread_info.h>
  33 #include <asm/asm-uaccess.h>
  34 #include <asm/unistd.h>
  35
  36 /*
  37  * Context tracking subsystem.  Used to instrument transitions
  38  * between user and kernel mode.
  39  */
  40         .macro ct_user_exit, syscall = 0
  41 #ifdef CONFIG_CONTEXT_TRACKING
  42         bl      context_tracking_user_exit
  43         .if \syscall == 1
  44         /*
  45          * Save/restore needed during syscalls.  Restore syscall arguments from
  46          * the values already saved on stack during kernel_entry.
  47          */
  48         ldp     x0, x1, [sp]
  49         ldp     x2, x3, [sp, #S_X2]
  50         ldp     x4, x5, [sp, #S_X4]
  51         ldp     x6, x7, [sp, #S_X6]
  52         .endif
  53 #endif
  54         .endm
  55
  56         .macro ct_user_enter
  57 #ifdef CONFIG_CONTEXT_TRACKING
  58         bl      context_tracking_user_enter
  59 #endif
  60         .endm
  61
  62 /*
  63  * Bad Abort numbers
  64  *-----------------
  65  */
  66 #define BAD_SYNC        0
  67 #define BAD_IRQ         1
  68 #define BAD_FIQ         2
  69 #define BAD_ERROR       3
  70
  71         .macro kernel_ventry    label
  72         .align 7
  73         sub     sp, sp, #S_FRAME_SIZE
  74         b       \label
  75         .endm
  76
  77         .macro  kernel_entry, el, regsize = 64
  78         .if     \regsize == 32
  79         mov     w0, w0                          // zero upper 32 bits of x0
  80         .endif
  81         stp     x0, x1, [sp, #16 * 0]
  82         stp     x2, x3, [sp, #16 * 1]
  83         stp     x4, x5, [sp, #16 * 2]
  84         stp     x6, x7, [sp, #16 * 3]
  85         stp     x8, x9, [sp, #16 * 4]
  86         stp     x10, x11, [sp, #16 * 5]
  87         stp     x12, x13, [sp, #16 * 6]
  88         stp     x14, x15, [sp, #16 * 7]
  89         stp     x16, x17, [sp, #16 * 8]
  90         stp     x18, x19, [sp, #16 * 9]
  91         stp     x20, x21, [sp, #16 * 10]
  92         stp     x22, x23, [sp, #16 * 11]
  93         stp     x24, x25, [sp, #16 * 12]
  94         stp     x26, x27, [sp, #16 * 13]
  95         stp     x28, x29, [sp, #16 * 14]
  96
  97         .if     \el == 0
  98         mrs     x21, sp_el0
  99         mov     tsk, sp
 100         and     tsk, tsk, #~(THREAD_SIZE - 1)   // Ensure MDSCR_EL1.SS is clear,
 101         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
 102         disable_step_tsk x19, x20               // exceptions when scheduling.
 103
 104         mov     x29, xzr                        // fp pointed to user-space
 105         .else
 106         add     x21, sp, #S_FRAME_SIZE
 107         get_thread_info tsk
 108         /* Save the task's original addr_limit and set USER_DS (TASK_SIZE_64) */
 109         ldr     x20, [tsk, #TI_ADDR_LIMIT]
 110         str     x20, [sp, #S_ORIG_ADDR_LIMIT]
 111         mov     x20, #TASK_SIZE_64
 112         str     x20, [tsk, #TI_ADDR_LIMIT]
 113         /* No need to reset PSTATE.UAO, hardware's already set it to 0 for us */
 114         .endif /* \el == 0 */
 115         mrs     x22, elr_el1
 116         mrs     x23, spsr_el1
 117         stp     lr, x21, [sp, #S_LR]
 118         stp     x22, x23, [sp, #S_PC]
 119
 120         /*
 121          * Set syscallno to -1 by default (overridden later if real syscall).
 122          */
 123         .if     \el == 0
 124         mvn     x21, xzr
 125         str     x21, [sp, #S_SYSCALLNO]
 126         .endif
 127
 128         /*
 129          * Set sp_el0 to current thread_info.
 130          */
 131         .if     \el == 0
 132         msr     sp_el0, tsk
 133         .endif
 134
 135         /*
 136          * Registers that may be useful after this macro is invoked:
 137          *
 138          * x21 - aborted SP
 139          * x22 - aborted PC
 140          * x23 - aborted PSTATE
 141         */
 142         .endm
 143
 144         .macro  kernel_exit, el
 145         .if     \el != 0
 146         /* Restore the task's original addr_limit. */
 147         ldr     x20, [sp, #S_ORIG_ADDR_LIMIT]
 148         str     x20, [tsk, #TI_ADDR_LIMIT]
 149
 150         /* No need to restore UAO, it will be restored from SPSR_EL1 */
 151         .endif
 152
 153         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 154         .if     \el == 0
 155         ct_user_enter
 156         ldr     x23, [sp, #S_SP]                // load return stack pointer
 157         msr     sp_el0, x23
 158 #ifdef CONFIG_ARM64_ERRATUM_845719
 159 alternative_if ARM64_WORKAROUND_845719
 160         tbz     x22, #4, 1f
 161 #ifdef CONFIG_PID_IN_CONTEXTIDR
 162         mrs     x29, contextidr_el1
 163         msr     contextidr_el1, x29
 164 #else
 165         msr contextidr_el1, xzr
 166 #endif
 167 1:
 168 alternative_else_nop_endif
 169 #endif
 170         .endif
 171         msr     elr_el1, x21                    // set up the return data
 172         msr     spsr_el1, x22
 173         ldp     x0, x1, [sp, #16 * 0]
 174         ldp     x2, x3, [sp, #16 * 1]
 175         ldp     x4, x5, [sp, #16 * 2]
 176         ldp     x6, x7, [sp, #16 * 3]
 177         ldp     x8, x9, [sp, #16 * 4]
 178         ldp     x10, x11, [sp, #16 * 5]
 179         ldp     x12, x13, [sp, #16 * 6]
 180         ldp     x14, x15, [sp, #16 * 7]
 181         ldp     x16, x17, [sp, #16 * 8]
 182         ldp     x18, x19, [sp, #16 * 9]
 183         ldp     x20, x21, [sp, #16 * 10]
 184         ldp     x22, x23, [sp, #16 * 11]
 185         ldp     x24, x25, [sp, #16 * 12]
 186         ldp     x26, x27, [sp, #16 * 13]
 187         ldp     x28, x29, [sp, #16 * 14]
 188         ldr     lr, [sp, #S_LR]
 189         add     sp, sp, #S_FRAME_SIZE           // restore sp
 190         eret                                    // return to kernel
 191         .endm
 192
 193         .macro  get_thread_info, rd
 194         mrs     \rd, sp_el0
 195         .endm
 196
 197         .macro  irq_stack_entry
 198         mov     x19, sp                 // preserve the original sp
 199
 200         /*
 201          * Compare sp with the current thread_info, if the top
 202          * ~(THREAD_SIZE - 1) bits match, we are on a task stack, and
 203          * should switch to the irq stack.
 204          */
 205         and     x25, x19, #~(THREAD_SIZE - 1)
 206         cmp     x25, tsk
 207         b.ne    9998f
 208
 209         this_cpu_ptr irq_stack, x25, x26
 210         mov     x26, #IRQ_STACK_START_SP
 211         add     x26, x25, x26
 212
 213         /* switch to the irq stack */
 214         mov     sp, x26
 215
 216         /*
 217          * Add a dummy stack frame, this non-standard format is fixed up
 218          * by unwind_frame()
 219          */
 220         stp     x29, x19, [sp, #-16]!
 221         mov     x29, sp
 222
 223 9998:
 224         .endm
 225
 226         /*
 227          * x19 should be preserved between irq_stack_entry and
 228          * irq_stack_exit.
 229          */
 230         .macro  irq_stack_exit
 231         mov     sp, x19
 232         .endm
 233
 234 /*
 235  * These are the registers used in the syscall handler, and allow us to
 236  * have in theory up to 7 arguments to a function - x0 to x6.
 237  *
 238  * x7 is reserved for the system call number in 32-bit mode.
 239  */
 240 sc_nr   .req    x25             // number of system calls
 241 scno    .req    x26             // syscall number
 242 stbl    .req    x27             // syscall table pointer
 243 tsk     .req    x28             // current thread_info
 244
 245 /*
 246  * Interrupt handling.
 247  */
 248         .macro  irq_handler
 249         ldr_l   x1, handle_arch_irq
 250         mov     x0, sp
 251         irq_stack_entry
 252         blr     x1
 253         irq_stack_exit
 254         .endm
 255
 256         .text
 257
 258 /*
 259  * Exception vectors.
 260  */
 261         .pushsection ".entry.text", "ax"
 262
 263         .align  11
 264 ENTRY(vectors)
 265         kernel_ventry   el1_sync_invalid                // Synchronous EL1t
 266         kernel_ventry   el1_irq_invalid                 // IRQ EL1t
 267         kernel_ventry   el1_fiq_invalid                 // FIQ EL1t
 268         kernel_ventry   el1_error_invalid               // Error EL1t
 269
 270         kernel_ventry   el1_sync                        // Synchronous EL1h
 271         kernel_ventry   el1_irq                         // IRQ EL1h
 272         kernel_ventry   el1_fiq_invalid                 // FIQ EL1h
 273         kernel_ventry   el1_error_invalid               // Error EL1h
 274
 275         kernel_ventry   el0_sync                        // Synchronous 64-bit EL0
 276         kernel_ventry   el0_irq                         // IRQ 64-bit EL0
 277         kernel_ventry   el0_fiq_invalid                 // FIQ 64-bit EL0
 278         kernel_ventry   el0_error_invalid               // Error 64-bit EL0
 279
 280 #ifdef CONFIG_COMPAT
 281         kernel_ventry   el0_sync_compat                 // Synchronous 32-bit EL0
 282         kernel_ventry   el0_irq_compat                  // IRQ 32-bit EL0
 283         kernel_ventry   el0_fiq_invalid_compat          // FIQ 32-bit EL0
 284         kernel_ventry   el0_error_invalid_compat        // Error 32-bit EL0
 285 #else
 286         kernel_ventry   el0_sync_invalid                // Synchronous 32-bit EL0
 287         kernel_ventry   el0_irq_invalid                 // IRQ 32-bit EL0
 288         kernel_ventry   el0_fiq_invalid                 // FIQ 32-bit EL0
 289         kernel_ventry   el0_error_invalid               // Error 32-bit EL0
 290 #endif
 291 END(vectors)
 292
 293 /*
 294  * Invalid mode handlers
 295  */
 296         .macro  inv_entry, el, reason, regsize = 64
 297         kernel_entry \el, \regsize
 298         mov     x0, sp
 299         mov     x1, #\reason
 300         mrs     x2, esr_el1
 301         b       bad_mode
 302         .endm
 303
 304 el0_sync_invalid:
 305         inv_entry 0, BAD_SYNC
 306 ENDPROC(el0_sync_invalid)
 307
 308 el0_irq_invalid:
 309         inv_entry 0, BAD_IRQ
 310 ENDPROC(el0_irq_invalid)
 311
 312 el0_fiq_invalid:
 313         inv_entry 0, BAD_FIQ
 314 ENDPROC(el0_fiq_invalid)
 315
 316 el0_error_invalid:
 317         inv_entry 0, BAD_ERROR
 318 ENDPROC(el0_error_invalid)
 319
 320 #ifdef CONFIG_COMPAT
 321 el0_fiq_invalid_compat:
 322         inv_entry 0, BAD_FIQ, 32
 323 ENDPROC(el0_fiq_invalid_compat)
 324
 325 el0_error_invalid_compat:
 326         inv_entry 0, BAD_ERROR, 32
 327 ENDPROC(el0_error_invalid_compat)
 328 #endif
 329
 330 el1_sync_invalid:
 331         inv_entry 1, BAD_SYNC
 332 ENDPROC(el1_sync_invalid)
 333
 334 el1_irq_invalid:
 335         inv_entry 1, BAD_IRQ
 336 ENDPROC(el1_irq_invalid)
 337
 338 el1_fiq_invalid:
 339         inv_entry 1, BAD_FIQ
 340 ENDPROC(el1_fiq_invalid)
 341
 342 el1_error_invalid:
 343         inv_entry 1, BAD_ERROR
 344 ENDPROC(el1_error_invalid)
 345
 346 /*
 347  * EL1 mode handlers.
 348  */
 349         .align  6
 350 el1_sync:
 351         kernel_entry 1
 352         mrs     x1, esr_el1                     // read the syndrome register
 353         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 354         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 355         b.eq    el1_da
 356         cmp     x24, #ESR_ELx_EC_IABT_CUR       // instruction abort in EL1
 357         b.eq    el1_ia
 358         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 359         b.eq    el1_undef
 360         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 361         b.eq    el1_sp_pc
 362         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 363         b.eq    el1_sp_pc
 364         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 365         b.eq    el1_undef
 366         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 367         b.ge    el1_dbg
 368         b       el1_inv
 369
 370 el1_ia:
 371         /*
 372          * Fall through to the Data abort case
 373          */
 374 el1_da:
 375         /*
 376          * Data abort handling
 377          */
 378         mrs     x3, far_el1
 379         enable_dbg
 380         // re-enable interrupts if they were enabled in the aborted context
 381         tbnz    x23, #7, 1f                     // PSR_I_BIT
 382         enable_irq
 383 1:
 384         clear_address_tag x0, x3
 385         mov     x2, sp                          // struct pt_regs
 386         bl      do_mem_abort
 387
 388         // disable interrupts before pulling preserved data off the stack
 389         disable_irq
 390         kernel_exit 1
 391 el1_sp_pc:
 392         /*
 393          * Stack or PC alignment exception handling
 394          */
 395         mrs     x0, far_el1
 396         enable_dbg
 397         mov     x2, sp
 398         b       do_sp_pc_abort
 399 el1_undef:
 400         /*
 401          * Undefined instruction
 402          */
 403         enable_dbg
 404         mov     x0, sp
 405         b       do_undefinstr
 406 el1_dbg:
 407         /*
 408          * Debug exception handling
 409          */
 410         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 411         cinc    x24, x24, eq                    // set bit '0'
 412         tbz     x24, #0, el1_inv                // EL1 only
 413         mrs     x0, far_el1
 414         mov     x2, sp                          // struct pt_regs
 415         bl      do_debug_exception
 416         kernel_exit 1
 417 el1_inv:
 418         // TODO: add support for undefined instructions in kernel mode
 419         enable_dbg
 420         mov     x0, sp
 421         mov     x2, x1
 422         mov     x1, #BAD_SYNC
 423         b       bad_mode
 424 ENDPROC(el1_sync)
 425
 426         .align  6
 427 el1_irq:
 428         kernel_entry 1
 429         enable_dbg
 430 #ifdef CONFIG_TRACE_IRQFLAGS
 431         bl      trace_hardirqs_off
 432 #endif
 433
 434         irq_handler
 435
 436 #ifdef CONFIG_PREEMPT
 437         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 438         cbnz    w24, 1f                         // preempt count != 0
 439         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 440         tbz     x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 441         bl      el1_preempt
 442 1:
 443 #endif
 444 #ifdef CONFIG_TRACE_IRQFLAGS
 445         bl      trace_hardirqs_on
 446 #endif
 447         kernel_exit 1
 448 ENDPROC(el1_irq)
 449
 450 #ifdef CONFIG_PREEMPT
 451 el1_preempt:
 452         mov     x24, lr
 453 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 454         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 455         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 456         ret     x24
 457 #endif
 458
 459 /*
 460  * EL0 mode handlers.
 461  */
 462         .align  6
 463 el0_sync:
 464         kernel_entry 0
 465         mrs     x25, esr_el1                    // read the syndrome register
 466         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 467         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 468         b.eq    el0_svc
 469         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 470         b.eq    el0_da
 471         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 472         b.eq    el0_ia
 473         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 474         b.eq    el0_fpsimd_acc
 475         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 476         b.eq    el0_fpsimd_exc
 477         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 478         b.eq    el0_sys
 479         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 480         b.eq    el0_sp_pc
 481         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 482         b.eq    el0_sp_pc
 483         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 484         b.eq    el0_undef
 485         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 486         b.ge    el0_dbg
 487         b       el0_inv
 488
 489 #ifdef CONFIG_COMPAT
 490         .align  6
 491 el0_sync_compat:
 492         kernel_entry 0, 32
 493         mrs     x25, esr_el1                    // read the syndrome register
 494         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 495         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 496         b.eq    el0_svc_compat
 497         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 498         b.eq    el0_da
 499         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 500         b.eq    el0_ia
 501         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 502         b.eq    el0_fpsimd_acc
 503         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 504         b.eq    el0_fpsimd_exc
 505         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 506         b.eq    el0_sp_pc
 507         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 508         b.eq    el0_undef
 509         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 510         b.eq    el0_undef
 511         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 512         b.eq    el0_undef
 513         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 514         b.eq    el0_undef
 515         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 516         b.eq    el0_undef
 517         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 518         b.eq    el0_undef
 519         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 520         b.ge    el0_dbg
 521         b       el0_inv
 522 el0_svc_compat:
 523         /*
 524          * AArch32 syscall handling
 525          */
 526         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 527         uxtw    scno, w7                        // syscall number in w7 (r7)
 528         mov     sc_nr, #__NR_compat_syscalls
 529         b       el0_svc_naked
 530
 531         .align  6
 532 el0_irq_compat:
 533         kernel_entry 0, 32
 534         b       el0_irq_naked
 535 #endif
 536
 537 el0_da:
 538         /*
 539          * Data abort handling
 540          */
 541         mrs     x26, far_el1
 542         // enable interrupts before calling the main handler
 543         enable_dbg_and_irq
 544         ct_user_exit
 545         clear_address_tag x0, x26
 546         mov     x1, x25
 547         mov     x2, sp
 548         bl      do_mem_abort
 549         b       ret_to_user
 550 el0_ia:
 551         /*
 552          * Instruction abort handling
 553          */
 554         mrs     x26, far_el1
 555         // enable interrupts before calling the main handler
 556         enable_dbg_and_irq
 557         ct_user_exit
 558         mov     x0, x26
 559         mov     x1, x25
 560         mov     x2, sp
 561         bl      do_mem_abort
 562         b       ret_to_user
 563 el0_fpsimd_acc:
 564         /*
 565          * Floating Point or Advanced SIMD access
 566          */
 567         enable_dbg
 568         ct_user_exit
 569         mov     x0, x25
 570         mov     x1, sp
 571         bl      do_fpsimd_acc
 572         b       ret_to_user
 573 el0_fpsimd_exc:
 574         /*
 575          * Floating Point or Advanced SIMD exception
 576          */
 577         enable_dbg
 578         ct_user_exit
 579         mov     x0, x25
 580         mov     x1, sp
 581         bl      do_fpsimd_exc
 582         b       ret_to_user
 583 el0_sp_pc:
 584         /*
 585          * Stack or PC alignment exception handling
 586          */
 587         mrs     x26, far_el1
 588         // enable interrupts before calling the main handler
 589         enable_dbg_and_irq
 590         ct_user_exit
 591         mov     x0, x26
 592         mov     x1, x25
 593         mov     x2, sp
 594         bl      do_sp_pc_abort
 595         b       ret_to_user
 596 el0_undef:
 597         /*
 598          * Undefined instruction
 599          */
 600         // enable interrupts before calling the main handler
 601         enable_dbg_and_irq
 602         ct_user_exit
 603         mov     x0, sp
 604         bl      do_undefinstr
 605         b       ret_to_user
 606 el0_sys:
 607         /*
 608          * System instructions, for trapped cache maintenance instructions
 609          */
 610         enable_dbg_and_irq
 611         ct_user_exit
 612         mov     x0, x25
 613         mov     x1, sp
 614         bl      do_sysinstr
 615         b       ret_to_user
 616 el0_dbg:
 617         /*
 618          * Debug exception handling
 619          */
 620         tbnz    x24, #0, el0_inv                // EL0 only
 621         mrs     x0, far_el1
 622         mov     x1, x25
 623         mov     x2, sp
 624         bl      do_debug_exception
 625         enable_dbg
 626         ct_user_exit
 627         b       ret_to_user
 628 el0_inv:
 629         enable_dbg
 630         ct_user_exit
 631         mov     x0, sp
 632         mov     x1, #BAD_SYNC
 633         mov     x2, x25
 634         bl      bad_el0_sync
 635         b       ret_to_user
 636 ENDPROC(el0_sync)
 637
 638         .align  6
 639 el0_irq:
 640         kernel_entry 0
 641 el0_irq_naked:
 642         enable_dbg
 643 #ifdef CONFIG_TRACE_IRQFLAGS
 644         bl      trace_hardirqs_off
 645 #endif
 646
 647         ct_user_exit
 648         irq_handler
 649
 650 #ifdef CONFIG_TRACE_IRQFLAGS
 651         bl      trace_hardirqs_on
 652 #endif
 653         b       ret_to_user
 654 ENDPROC(el0_irq)
 655
 656 /*
 657  * Register switch for AArch64. The callee-saved registers need to be saved
 658  * and restored. On entry:
 659  *   x0 = previous task_struct (must be preserved across the switch)
 660  *   x1 = next task_struct
 661  * Previous and next are guaranteed not to be the same.
 662  *
 663  */
 664 ENTRY(cpu_switch_to)
 665         mov     x10, #THREAD_CPU_CONTEXT
 666         add     x8, x0, x10
 667         mov     x9, sp
 668         stp     x19, x20, [x8], #16             // store callee-saved registers
 669         stp     x21, x22, [x8], #16
 670         stp     x23, x24, [x8], #16
 671         stp     x25, x26, [x8], #16
 672         stp     x27, x28, [x8], #16
 673         stp     x29, x9, [x8], #16
 674         str     lr, [x8]
 675         add     x8, x1, x10
 676         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 677         ldp     x21, x22, [x8], #16
 678         ldp     x23, x24, [x8], #16
 679         ldp     x25, x26, [x8], #16
 680         ldp     x27, x28, [x8], #16
 681         ldp     x29, x9, [x8], #16
 682         ldr     lr, [x8]
 683         mov     sp, x9
 684         and     x9, x9, #~(THREAD_SIZE - 1)
 685         msr     sp_el0, x9
 686         ret
 687 ENDPROC(cpu_switch_to)
 688
 689 /*
 690  * This is the fast syscall return path.  We do as little as possible here,
 691  * and this includes saving x0 back into the kernel stack.
 692  */
 693 ret_fast_syscall:
 694         disable_irq                             // disable interrupts
 695         str     x0, [sp, #S_X0]                 // returned x0
 696         ldr     x1, [tsk, #TI_FLAGS]            // re-check for syscall tracing
 697         and     x2, x1, #_TIF_SYSCALL_WORK
 698         cbnz    x2, ret_fast_syscall_trace
 699         and     x2, x1, #_TIF_WORK_MASK
 700         cbnz    x2, work_pending
 701         enable_step_tsk x1, x2
 702         kernel_exit 0
 703 ret_fast_syscall_trace:
 704         enable_irq                              // enable interrupts
 705         b       __sys_trace_return_skipped      // we already saved x0
 706
 707 /*
 708  * Ok, we need to do extra processing, enter the slow path.
 709  */
 710 work_pending:
 711         mov     x0, sp                          // 'regs'
 712         bl      do_notify_resume
 713 #ifdef CONFIG_TRACE_IRQFLAGS
 714         bl      trace_hardirqs_on               // enabled while in userspace
 715 #endif
 716         ldr     x1, [tsk, #TI_FLAGS]            // re-check for single-step
 717         b       finish_ret_to_user
 718 /*
 719  * "slow" syscall return path.
 720  */
 721 ret_to_user:
 722         disable_irq                             // disable interrupts
 723         ldr     x1, [tsk, #TI_FLAGS]
 724         and     x2, x1, #_TIF_WORK_MASK
 725         cbnz    x2, work_pending
 726 finish_ret_to_user:
 727         enable_step_tsk x1, x2
 728         kernel_exit 0
 729 ENDPROC(ret_to_user)
 730
 731 /*
 732  * This is how we return from a fork.
 733  */
 734 ENTRY(ret_from_fork)
 735         bl      schedule_tail
 736         cbz     x19, 1f                         // not a kernel thread
 737         mov     x0, x20
 738         blr     x19
 739 1:      get_thread_info tsk
 740         b       ret_to_user
 741 ENDPROC(ret_from_fork)
 742
 743 /*
 744  * SVC handler.
 745  */
 746         .align  6
 747 el0_svc:
 748         adrp    stbl, sys_call_table            // load syscall table pointer
 749         uxtw    scno, w8                        // syscall number in w8
 750         mov     sc_nr, #__NR_syscalls
 751 el0_svc_naked:                                  // compat entry point
 752         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 753         enable_dbg_and_irq
 754         ct_user_exit 1
 755
 756         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 757         tst     x16, #_TIF_SYSCALL_WORK
 758         b.ne    __sys_trace
 759         cmp     scno, sc_nr                     // check upper syscall limit
 760         b.hs    ni_sys
 761         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 762         blr     x16                             // call sys_* routine
 763         b       ret_fast_syscall
 764 ni_sys:
 765         mov     x0, sp
 766         bl      do_ni_syscall
 767         b       ret_fast_syscall
 768 ENDPROC(el0_svc)
 769
 770         /*
 771          * This is the really slow path.  We're going to be doing context
 772          * switches, and waiting for our parent to respond.
 773          */
 774 __sys_trace:
 775         mov     w0, #-1                         // set default errno for
 776         cmp     scno, x0                        // user-issued syscall(-1)
 777         b.ne    1f
 778         mov     x0, #-ENOSYS
 779         str     x0, [sp, #S_X0]
 780 1:      mov     x0, sp
 781         bl      syscall_trace_enter
 782         cmp     w0, #-1                         // skip the syscall?
 783         b.eq    __sys_trace_return_skipped
 784         uxtw    scno, w0                        // syscall number (possibly new)
 785         mov     x1, sp                          // pointer to regs
 786         cmp     scno, sc_nr                     // check upper syscall limit
 787         b.hs    __ni_sys_trace
 788         ldp     x0, x1, [sp]                    // restore the syscall args
 789         ldp     x2, x3, [sp, #S_X2]
 790         ldp     x4, x5, [sp, #S_X4]
 791         ldp     x6, x7, [sp, #S_X6]
 792         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 793         blr     x16                             // call sys_* routine
 794
 795 __sys_trace_return:
 796         str     x0, [sp, #S_X0]                 // save returned x0
 797 __sys_trace_return_skipped:
 798         mov     x0, sp
 799         bl      syscall_trace_exit
 800         b       ret_to_user
 801
 802 __ni_sys_trace:
 803         mov     x0, sp
 804         bl      do_ni_syscall
 805         b       __sys_trace_return
 806
 807         .popsection                             // .entry.text
 808
 809 /*
 810  * Special system call wrappers.
 811  */
 812 ENTRY(sys_rt_sigreturn_wrapper)
 813         mov     x0, sp
 814         b       sys_rt_sigreturn
 815 ENDPROC(sys_rt_sigreturn_wrapper)