arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/irq.h>
  31 #include <asm/memory.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/thread_info.h>
  34 #include <asm/uaccess.h>
  35 #include <asm/asm-uaccess.h>
  36 #include <asm/unistd.h>
  37
  38 /*
  39  * Context tracking subsystem.  Used to instrument transitions
  40  * between user and kernel mode.
  41  */
  42         .macro ct_user_exit, syscall = 0
  43 #ifdef CONFIG_CONTEXT_TRACKING
  44         bl      context_tracking_user_exit
  45         .if \syscall == 1
  46         /*
  47          * Save/restore needed during syscalls.  Restore syscall arguments from
  48          * the values already saved on stack during kernel_entry.
  49          */
  50         ldp     x0, x1, [sp]
  51         ldp     x2, x3, [sp, #S_X2]
  52         ldp     x4, x5, [sp, #S_X4]
  53         ldp     x6, x7, [sp, #S_X6]
  54         .endif
  55 #endif
  56         .endm
  57
  58         .macro ct_user_enter
  59 #ifdef CONFIG_CONTEXT_TRACKING
  60         bl      context_tracking_user_enter
  61 #endif
  62         .endm
  63
  64 /*
  65  * Bad Abort numbers
  66  *-----------------
  67  */
  68 #define BAD_SYNC        0
  69 #define BAD_IRQ         1
  70 #define BAD_FIQ         2
  71 #define BAD_ERROR       3
  72
  73         .macro  kernel_entry, el, regsize = 64
  74         sub     sp, sp, #S_FRAME_SIZE
  75         .if     \regsize == 32
  76         mov     w0, w0                          // zero upper 32 bits of x0
  77         .endif
  78         stp     x0, x1, [sp, #16 * 0]
  79         stp     x2, x3, [sp, #16 * 1]
  80         stp     x4, x5, [sp, #16 * 2]
  81         stp     x6, x7, [sp, #16 * 3]
  82         stp     x8, x9, [sp, #16 * 4]
  83         stp     x10, x11, [sp, #16 * 5]
  84         stp     x12, x13, [sp, #16 * 6]
  85         stp     x14, x15, [sp, #16 * 7]
  86         stp     x16, x17, [sp, #16 * 8]
  87         stp     x18, x19, [sp, #16 * 9]
  88         stp     x20, x21, [sp, #16 * 10]
  89         stp     x22, x23, [sp, #16 * 11]
  90         stp     x24, x25, [sp, #16 * 12]
  91         stp     x26, x27, [sp, #16 * 13]
  92         stp     x28, x29, [sp, #16 * 14]
  93
  94         .if     \el == 0
  95         mrs     x21, sp_el0
  96         mov     tsk, sp
  97         and     tsk, tsk, #~(THREAD_SIZE - 1)   // Ensure MDSCR_EL1.SS is clear,
  98         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
  99         disable_step_tsk x19, x20               // exceptions when scheduling.
 100
 101         mov     x29, xzr                        // fp pointed to user-space
 102         .else
 103         add     x21, sp, #S_FRAME_SIZE
 104         get_thread_info tsk
 105         /* Save the task's original addr_limit and set USER_DS (TASK_SIZE_64) */
 106         ldr     x20, [tsk, #TI_ADDR_LIMIT]
 107         str     x20, [sp, #S_ORIG_ADDR_LIMIT]
 108         mov     x20, #TASK_SIZE_64
 109         str     x20, [tsk, #TI_ADDR_LIMIT]
 110         /* No need to reset PSTATE.UAO, hardware's already set it to 0 for us */
 111         .endif /* \el == 0 */
 112         mrs     x22, elr_el1
 113         mrs     x23, spsr_el1
 114         stp     lr, x21, [sp, #S_LR]
 115
 116 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 117         /*
 118          * Set the TTBR0 PAN bit in SPSR. When the exception is taken from
 119          * EL0, there is no need to check the state of TTBR0_EL1 since
 120          * accesses are always enabled.
 121          * Note that the meaning of this bit differs from the ARMv8.1 PAN
 122          * feature as all TTBR0_EL1 accesses are disabled, not just those to
 123          * user mappings.
 124          */
 125 alternative_if ARM64_HAS_PAN
 126         b       1f                              // skip TTBR0 PAN
 127 alternative_else_nop_endif
 128
 129         .if     \el != 0
 130         mrs     x21, ttbr0_el1
 131         tst     x21, #0xffff << 48              // Check for the reserved ASID
 132         orr     x23, x23, #PSR_PAN_BIT          // Set the emulated PAN in the saved SPSR
 133         b.eq    1f                              // TTBR0 access already disabled
 134         and     x23, x23, #~PSR_PAN_BIT         // Clear the emulated PAN in the saved SPSR
 135         .endif
 136
 137         __uaccess_ttbr0_disable x21
 138 1:
 139 #endif
 140
 141         stp     x22, x23, [sp, #S_PC]
 142
 143         /*
 144          * Set syscallno to -1 by default (overridden later if real syscall).
 145          */
 146         .if     \el == 0
 147         mvn     x21, xzr
 148         str     x21, [sp, #S_SYSCALLNO]
 149         .endif
 150
 151         /*
 152          * Set sp_el0 to current thread_info.
 153          */
 154         .if     \el == 0
 155         msr     sp_el0, tsk
 156         .endif
 157
 158         /*
 159          * Registers that may be useful after this macro is invoked:
 160          *
 161          * x21 - aborted SP
 162          * x22 - aborted PC
 163          * x23 - aborted PSTATE
 164         */
 165         .endm
 166
 167         .macro  kernel_exit, el
 168         .if     \el != 0
 169         /* Restore the task's original addr_limit. */
 170         ldr     x20, [sp, #S_ORIG_ADDR_LIMIT]
 171         str     x20, [tsk, #TI_ADDR_LIMIT]
 172
 173         /* No need to restore UAO, it will be restored from SPSR_EL1 */
 174         .endif
 175
 176         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 177         .if     \el == 0
 178         ct_user_enter
 179         .endif
 180
 181 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 182         /*
 183          * Restore access to TTBR0_EL1. If returning to EL0, no need for SPSR
 184          * PAN bit checking.
 185          */
 186 alternative_if ARM64_HAS_PAN
 187         b       2f                              // skip TTBR0 PAN
 188 alternative_else_nop_endif
 189
 190         .if     \el != 0
 191         tbnz    x22, #22, 1f                    // Skip re-enabling TTBR0 access if the PSR_PAN_BIT is set
 192         .endif
 193
 194         __uaccess_ttbr0_enable x0
 195
 196         .if     \el == 0
 197         /*
 198          * Enable errata workarounds only if returning to user. The only
 199          * workaround currently required for TTBR0_EL1 changes are for the
 200          * Cavium erratum 27456 (broadcast TLBI instructions may cause I-cache
 201          * corruption).
 202          */
 203         post_ttbr0_update_workaround
 204         .endif
 205 1:
 206         .if     \el != 0
 207         and     x22, x22, #~PSR_PAN_BIT         // ARMv8.0 CPUs do not understand this bit
 208         .endif
 209 2:
 210 #endif
 211
 212         .if     \el == 0
 213         ldr     x23, [sp, #S_SP]                // load return stack pointer
 214         msr     sp_el0, x23
 215 #ifdef CONFIG_ARM64_ERRATUM_845719
 216 alternative_if ARM64_WORKAROUND_845719
 217         tbz     x22, #4, 1f
 218 #ifdef CONFIG_PID_IN_CONTEXTIDR
 219         mrs     x29, contextidr_el1
 220         msr     contextidr_el1, x29
 221 #else
 222         msr contextidr_el1, xzr
 223 #endif
 224 1:
 225 alternative_else_nop_endif
 226 #endif
 227         .endif
 228
 229         msr     elr_el1, x21                    // set up the return data
 230         msr     spsr_el1, x22
 231         ldp     x0, x1, [sp, #16 * 0]
 232         ldp     x2, x3, [sp, #16 * 1]
 233         ldp     x4, x5, [sp, #16 * 2]
 234         ldp     x6, x7, [sp, #16 * 3]
 235         ldp     x8, x9, [sp, #16 * 4]
 236         ldp     x10, x11, [sp, #16 * 5]
 237         ldp     x12, x13, [sp, #16 * 6]
 238         ldp     x14, x15, [sp, #16 * 7]
 239         ldp     x16, x17, [sp, #16 * 8]
 240         ldp     x18, x19, [sp, #16 * 9]
 241         ldp     x20, x21, [sp, #16 * 10]
 242         ldp     x22, x23, [sp, #16 * 11]
 243         ldp     x24, x25, [sp, #16 * 12]
 244         ldp     x26, x27, [sp, #16 * 13]
 245         ldp     x28, x29, [sp, #16 * 14]
 246         ldr     lr, [sp, #S_LR]
 247         add     sp, sp, #S_FRAME_SIZE           // restore sp
 248         eret                                    // return to kernel
 249         .endm
 250
 251         .macro  irq_stack_entry
 252         mov     x19, sp                 // preserve the original sp
 253
 254         /*
 255          * Compare sp with the current thread_info, if the top
 256          * ~(THREAD_SIZE - 1) bits match, we are on a task stack, and
 257          * should switch to the irq stack.
 258          */
 259         and     x25, x19, #~(THREAD_SIZE - 1)
 260         cmp     x25, tsk
 261         b.ne    9998f
 262
 263         this_cpu_ptr irq_stack, x25, x26
 264         mov     x26, #IRQ_STACK_START_SP
 265         add     x26, x25, x26
 266
 267         /* switch to the irq stack */
 268         mov     sp, x26
 269
 270         /*
 271          * Add a dummy stack frame, this non-standard format is fixed up
 272          * by unwind_frame()
 273          */
 274         stp     x29, x19, [sp, #-16]!
 275         mov     x29, sp
 276
 277 9998:
 278         .endm
 279
 280         /*
 281          * x19 should be preserved between irq_stack_entry and
 282          * irq_stack_exit.
 283          */
 284         .macro  irq_stack_exit
 285         mov     sp, x19
 286         .endm
 287
 288 /*
 289  * These are the registers used in the syscall handler, and allow us to
 290  * have in theory up to 7 arguments to a function - x0 to x6.
 291  *
 292  * x7 is reserved for the system call number in 32-bit mode.
 293  */
 294 sc_nr   .req    x25             // number of system calls
 295 scno    .req    x26             // syscall number
 296 stbl    .req    x27             // syscall table pointer
 297 tsk     .req    x28             // current thread_info
 298
 299 /*
 300  * Interrupt handling.
 301  */
 302         .macro  irq_handler
 303         ldr_l   x1, handle_arch_irq
 304         mov     x0, sp
 305         irq_stack_entry
 306         blr     x1
 307         irq_stack_exit
 308         .endm
 309
 310         .text
 311
 312 /*
 313  * Exception vectors.
 314  */
 315         .pushsection ".entry.text", "ax"
 316
 317         .align  11
 318 ENTRY(vectors)
 319         ventry  el1_sync_invalid                // Synchronous EL1t
 320         ventry  el1_irq_invalid                 // IRQ EL1t
 321         ventry  el1_fiq_invalid                 // FIQ EL1t
 322         ventry  el1_error_invalid               // Error EL1t
 323
 324         ventry  el1_sync                        // Synchronous EL1h
 325         ventry  el1_irq                         // IRQ EL1h
 326         ventry  el1_fiq_invalid                 // FIQ EL1h
 327         ventry  el1_error_invalid               // Error EL1h
 328
 329         ventry  el0_sync                        // Synchronous 64-bit EL0
 330         ventry  el0_irq                         // IRQ 64-bit EL0
 331         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 332         ventry  el0_error_invalid               // Error 64-bit EL0
 333
 334 #ifdef CONFIG_COMPAT
 335         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 336         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 337         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 338         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 339 #else
 340         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 341         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 342         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 343         ventry  el0_error_invalid               // Error 32-bit EL0
 344 #endif
 345 END(vectors)
 346
 347 /*
 348  * Invalid mode handlers
 349  */
 350         .macro  inv_entry, el, reason, regsize = 64
 351         kernel_entry \el, \regsize
 352         mov     x0, sp
 353         mov     x1, #\reason
 354         mrs     x2, esr_el1
 355         b       bad_mode
 356         .endm
 357
 358 el0_sync_invalid:
 359         inv_entry 0, BAD_SYNC
 360 ENDPROC(el0_sync_invalid)
 361
 362 el0_irq_invalid:
 363         inv_entry 0, BAD_IRQ
 364 ENDPROC(el0_irq_invalid)
 365
 366 el0_fiq_invalid:
 367         inv_entry 0, BAD_FIQ
 368 ENDPROC(el0_fiq_invalid)
 369
 370 el0_error_invalid:
 371         inv_entry 0, BAD_ERROR
 372 ENDPROC(el0_error_invalid)
 373
 374 #ifdef CONFIG_COMPAT
 375 el0_fiq_invalid_compat:
 376         inv_entry 0, BAD_FIQ, 32
 377 ENDPROC(el0_fiq_invalid_compat)
 378
 379 el0_error_invalid_compat:
 380         inv_entry 0, BAD_ERROR, 32
 381 ENDPROC(el0_error_invalid_compat)
 382 #endif
 383
 384 el1_sync_invalid:
 385         inv_entry 1, BAD_SYNC
 386 ENDPROC(el1_sync_invalid)
 387
 388 el1_irq_invalid:
 389         inv_entry 1, BAD_IRQ
 390 ENDPROC(el1_irq_invalid)
 391
 392 el1_fiq_invalid:
 393         inv_entry 1, BAD_FIQ
 394 ENDPROC(el1_fiq_invalid)
 395
 396 el1_error_invalid:
 397         inv_entry 1, BAD_ERROR
 398 ENDPROC(el1_error_invalid)
 399
 400 /*
 401  * EL1 mode handlers.
 402  */
 403         .align  6
 404 el1_sync:
 405         kernel_entry 1
 406         mrs     x1, esr_el1                     // read the syndrome register
 407         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 408         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 409         b.eq    el1_da
 410         cmp     x24, #ESR_ELx_EC_IABT_CUR       // instruction abort in EL1
 411         b.eq    el1_ia
 412         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 413         b.eq    el1_undef
 414         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 415         b.eq    el1_sp_pc
 416         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 417         b.eq    el1_sp_pc
 418         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 419         b.eq    el1_undef
 420         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 421         b.ge    el1_dbg
 422         b       el1_inv
 423
 424 el1_ia:
 425         /*
 426          * Fall through to the Data abort case
 427          */
 428 el1_da:
 429         /*
 430          * Data abort handling
 431          */
 432         mrs     x3, far_el1
 433         enable_dbg
 434         // re-enable interrupts if they were enabled in the aborted context
 435         tbnz    x23, #7, 1f                     // PSR_I_BIT
 436         enable_irq
 437 1:
 438         clear_address_tag x0, x3
 439         mov     x2, sp                          // struct pt_regs
 440         bl      do_mem_abort
 441
 442         // disable interrupts before pulling preserved data off the stack
 443         disable_irq
 444         kernel_exit 1
 445 el1_sp_pc:
 446         /*
 447          * Stack or PC alignment exception handling
 448          */
 449         mrs     x0, far_el1
 450         enable_dbg
 451         mov     x2, sp
 452         b       do_sp_pc_abort
 453 el1_undef:
 454         /*
 455          * Undefined instruction
 456          */
 457         enable_dbg
 458         mov     x0, sp
 459         b       do_undefinstr
 460 el1_dbg:
 461         /*
 462          * Debug exception handling
 463          */
 464         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 465         cinc    x24, x24, eq                    // set bit '0'
 466         tbz     x24, #0, el1_inv                // EL1 only
 467         mrs     x0, far_el1
 468         mov     x2, sp                          // struct pt_regs
 469         bl      do_debug_exception
 470         kernel_exit 1
 471 el1_inv:
 472         // TODO: add support for undefined instructions in kernel mode
 473         enable_dbg
 474         mov     x0, sp
 475         mov     x2, x1
 476         mov     x1, #BAD_SYNC
 477         b       bad_mode
 478 ENDPROC(el1_sync)
 479
 480         .align  6
 481 el1_irq:
 482         kernel_entry 1
 483         enable_dbg
 484 #ifdef CONFIG_TRACE_IRQFLAGS
 485         bl      trace_hardirqs_off
 486 #endif
 487
 488         irq_handler
 489
 490 #ifdef CONFIG_PREEMPT
 491         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 492         cbnz    w24, 1f                         // preempt count != 0
 493         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 494         tbz     x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 495         bl      el1_preempt
 496 1:
 497 #endif
 498 #ifdef CONFIG_TRACE_IRQFLAGS
 499         bl      trace_hardirqs_on
 500 #endif
 501         kernel_exit 1
 502 ENDPROC(el1_irq)
 503
 504 #ifdef CONFIG_PREEMPT
 505 el1_preempt:
 506         mov     x24, lr
 507 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 508         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 509         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 510         ret     x24
 511 #endif
 512
 513 /*
 514  * EL0 mode handlers.
 515  */
 516         .align  6
 517 el0_sync:
 518         kernel_entry 0
 519         mrs     x25, esr_el1                    // read the syndrome register
 520         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 521         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 522         b.eq    el0_svc
 523         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 524         b.eq    el0_da
 525         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 526         b.eq    el0_ia
 527         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 528         b.eq    el0_fpsimd_acc
 529         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 530         b.eq    el0_fpsimd_exc
 531         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 532         b.eq    el0_sys
 533         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 534         b.eq    el0_sp_pc
 535         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 536         b.eq    el0_sp_pc
 537         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 538         b.eq    el0_undef
 539         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 540         b.ge    el0_dbg
 541         b       el0_inv
 542
 543 #ifdef CONFIG_COMPAT
 544         .align  6
 545 el0_sync_compat:
 546         kernel_entry 0, 32
 547         mrs     x25, esr_el1                    // read the syndrome register
 548         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 549         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 550         b.eq    el0_svc_compat
 551         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 552         b.eq    el0_da
 553         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 554         b.eq    el0_ia
 555         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 556         b.eq    el0_fpsimd_acc
 557         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 558         b.eq    el0_fpsimd_exc
 559         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 560         b.eq    el0_sp_pc
 561         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 562         b.eq    el0_undef
 563         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 564         b.eq    el0_undef
 565         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 566         b.eq    el0_undef
 567         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 568         b.eq    el0_undef
 569         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 570         b.eq    el0_undef
 571         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 572         b.eq    el0_undef
 573         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 574         b.ge    el0_dbg
 575         b       el0_inv
 576 el0_svc_compat:
 577         /*
 578          * AArch32 syscall handling
 579          */
 580         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 581         uxtw    scno, w7                        // syscall number in w7 (r7)
 582         mov     sc_nr, #__NR_compat_syscalls
 583         b       el0_svc_naked
 584
 585         .align  6
 586 el0_irq_compat:
 587         kernel_entry 0, 32
 588         b       el0_irq_naked
 589 #endif
 590
 591 el0_da:
 592         /*
 593          * Data abort handling
 594          */
 595         mrs     x26, far_el1
 596         // enable interrupts before calling the main handler
 597         enable_dbg_and_irq
 598         ct_user_exit
 599         clear_address_tag x0, x26
 600         mov     x1, x25
 601         mov     x2, sp
 602         bl      do_mem_abort
 603         b       ret_to_user
 604 el0_ia:
 605         /*
 606          * Instruction abort handling
 607          */
 608         mrs     x26, far_el1
 609         // enable interrupts before calling the main handler
 610         enable_dbg_and_irq
 611         ct_user_exit
 612         mov     x0, x26
 613         mov     x1, x25
 614         mov     x2, sp
 615         bl      do_mem_abort
 616         b       ret_to_user
 617 el0_fpsimd_acc:
 618         /*
 619          * Floating Point or Advanced SIMD access
 620          */
 621         enable_dbg
 622         ct_user_exit
 623         mov     x0, x25
 624         mov     x1, sp
 625         bl      do_fpsimd_acc
 626         b       ret_to_user
 627 el0_fpsimd_exc:
 628         /*
 629          * Floating Point or Advanced SIMD exception
 630          */
 631         enable_dbg
 632         ct_user_exit
 633         mov     x0, x25
 634         mov     x1, sp
 635         bl      do_fpsimd_exc
 636         b       ret_to_user
 637 el0_sp_pc:
 638         /*
 639          * Stack or PC alignment exception handling
 640          */
 641         mrs     x26, far_el1
 642         // enable interrupts before calling the main handler
 643         enable_dbg_and_irq
 644         ct_user_exit
 645         mov     x0, x26
 646         mov     x1, x25
 647         mov     x2, sp
 648         bl      do_sp_pc_abort
 649         b       ret_to_user
 650 el0_undef:
 651         /*
 652          * Undefined instruction
 653          */
 654         // enable interrupts before calling the main handler
 655         enable_dbg_and_irq
 656         ct_user_exit
 657         mov     x0, sp
 658         bl      do_undefinstr
 659         b       ret_to_user
 660 el0_sys:
 661         /*
 662          * System instructions, for trapped cache maintenance instructions
 663          */
 664         enable_dbg_and_irq
 665         ct_user_exit
 666         mov     x0, x25
 667         mov     x1, sp
 668         bl      do_sysinstr
 669         b       ret_to_user
 670 el0_dbg:
 671         /*
 672          * Debug exception handling
 673          */
 674         tbnz    x24, #0, el0_inv                // EL0 only
 675         mrs     x0, far_el1
 676         mov     x1, x25
 677         mov     x2, sp
 678         bl      do_debug_exception
 679         enable_dbg
 680         ct_user_exit
 681         b       ret_to_user
 682 el0_inv:
 683         enable_dbg
 684         ct_user_exit
 685         mov     x0, sp
 686         mov     x1, #BAD_SYNC
 687         mov     x2, x25
 688         bl      bad_el0_sync
 689         b       ret_to_user
 690 ENDPROC(el0_sync)
 691
 692         .align  6
 693 el0_irq:
 694         kernel_entry 0
 695 el0_irq_naked:
 696         enable_dbg
 697 #ifdef CONFIG_TRACE_IRQFLAGS
 698         bl      trace_hardirqs_off
 699 #endif
 700
 701         ct_user_exit
 702         irq_handler
 703
 704 #ifdef CONFIG_TRACE_IRQFLAGS
 705         bl      trace_hardirqs_on
 706 #endif
 707         b       ret_to_user
 708 ENDPROC(el0_irq)
 709
 710 /*
 711  * Register switch for AArch64. The callee-saved registers need to be saved
 712  * and restored. On entry:
 713  *   x0 = previous task_struct (must be preserved across the switch)
 714  *   x1 = next task_struct
 715  * Previous and next are guaranteed not to be the same.
 716  *
 717  */
 718 ENTRY(cpu_switch_to)
 719         mov     x10, #THREAD_CPU_CONTEXT
 720         add     x8, x0, x10
 721         mov     x9, sp
 722         stp     x19, x20, [x8], #16             // store callee-saved registers
 723         stp     x21, x22, [x8], #16
 724         stp     x23, x24, [x8], #16
 725         stp     x25, x26, [x8], #16
 726         stp     x27, x28, [x8], #16
 727         stp     x29, x9, [x8], #16
 728         str     lr, [x8]
 729         add     x8, x1, x10
 730         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 731         ldp     x21, x22, [x8], #16
 732         ldp     x23, x24, [x8], #16
 733         ldp     x25, x26, [x8], #16
 734         ldp     x27, x28, [x8], #16
 735         ldp     x29, x9, [x8], #16
 736         ldr     lr, [x8]
 737         mov     sp, x9
 738         and     x9, x9, #~(THREAD_SIZE - 1)
 739         msr     sp_el0, x9
 740         ret
 741 ENDPROC(cpu_switch_to)
 742
 743 /*
 744  * This is the fast syscall return path.  We do as little as possible here,
 745  * and this includes saving x0 back into the kernel stack.
 746  */
 747 ret_fast_syscall:
 748         disable_irq                             // disable interrupts
 749         str     x0, [sp, #S_X0]                 // returned x0
 750         ldr     x1, [tsk, #TI_FLAGS]            // re-check for syscall tracing
 751         and     x2, x1, #_TIF_SYSCALL_WORK
 752         cbnz    x2, ret_fast_syscall_trace
 753         and     x2, x1, #_TIF_WORK_MASK
 754         cbnz    x2, work_pending
 755         enable_step_tsk x1, x2
 756         kernel_exit 0
 757 ret_fast_syscall_trace:
 758         enable_irq                              // enable interrupts
 759         b       __sys_trace_return_skipped      // we already saved x0
 760
 761 /*
 762  * Ok, we need to do extra processing, enter the slow path.
 763  */
 764 work_pending:
 765         mov     x0, sp                          // 'regs'
 766         bl      do_notify_resume
 767 #ifdef CONFIG_TRACE_IRQFLAGS
 768         bl      trace_hardirqs_on               // enabled while in userspace
 769 #endif
 770         ldr     x1, [tsk, #TI_FLAGS]            // re-check for single-step
 771         b       finish_ret_to_user
 772 /*
 773  * "slow" syscall return path.
 774  */
 775 ret_to_user:
 776         disable_irq                             // disable interrupts
 777         ldr     x1, [tsk, #TI_FLAGS]
 778         and     x2, x1, #_TIF_WORK_MASK
 779         cbnz    x2, work_pending
 780 finish_ret_to_user:
 781         enable_step_tsk x1, x2
 782         kernel_exit 0
 783 ENDPROC(ret_to_user)
 784
 785 /*
 786  * This is how we return from a fork.
 787  */
 788 ENTRY(ret_from_fork)
 789         bl      schedule_tail
 790         cbz     x19, 1f                         // not a kernel thread
 791         mov     x0, x20
 792         blr     x19
 793 1:      get_thread_info tsk
 794         b       ret_to_user
 795 ENDPROC(ret_from_fork)
 796
 797 /*
 798  * SVC handler.
 799  */
 800         .align  6
 801 el0_svc:
 802         adrp    stbl, sys_call_table            // load syscall table pointer
 803         uxtw    scno, w8                        // syscall number in w8
 804         mov     sc_nr, #__NR_syscalls
 805 el0_svc_naked:                                  // compat entry point
 806         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 807         enable_dbg_and_irq
 808         ct_user_exit 1
 809
 810         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 811         tst     x16, #_TIF_SYSCALL_WORK
 812         b.ne    __sys_trace
 813         cmp     scno, sc_nr                     // check upper syscall limit
 814         b.hs    ni_sys
 815         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 816         blr     x16                             // call sys_* routine
 817         b       ret_fast_syscall
 818 ni_sys:
 819         mov     x0, sp
 820         bl      do_ni_syscall
 821         b       ret_fast_syscall
 822 ENDPROC(el0_svc)
 823
 824         /*
 825          * This is the really slow path.  We're going to be doing context
 826          * switches, and waiting for our parent to respond.
 827          */
 828 __sys_trace:
 829         mov     w0, #-1                         // set default errno for
 830         cmp     scno, x0                        // user-issued syscall(-1)
 831         b.ne    1f
 832         mov     x0, #-ENOSYS
 833         str     x0, [sp, #S_X0]
 834 1:      mov     x0, sp
 835         bl      syscall_trace_enter
 836         cmp     w0, #-1                         // skip the syscall?
 837         b.eq    __sys_trace_return_skipped
 838         uxtw    scno, w0                        // syscall number (possibly new)
 839         mov     x1, sp                          // pointer to regs
 840         cmp     scno, sc_nr                     // check upper syscall limit
 841         b.hs    __ni_sys_trace
 842         ldp     x0, x1, [sp]                    // restore the syscall args
 843         ldp     x2, x3, [sp, #S_X2]
 844         ldp     x4, x5, [sp, #S_X4]
 845         ldp     x6, x7, [sp, #S_X6]
 846         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 847         blr     x16                             // call sys_* routine
 848
 849 __sys_trace_return:
 850         str     x0, [sp, #S_X0]                 // save returned x0
 851 __sys_trace_return_skipped:
 852         mov     x0, sp
 853         bl      syscall_trace_exit
 854         b       ret_to_user
 855
 856 __ni_sys_trace:
 857         mov     x0, sp
 858         bl      do_ni_syscall
 859         b       __sys_trace_return
 860
 861         .popsection                             // .entry.text
 862
 863 /*
 864  * Special system call wrappers.
 865  */
 866 ENTRY(sys_rt_sigreturn_wrapper)
 867         mov     x0, sp
 868         b       sys_rt_sigreturn
 869 ENDPROC(sys_rt_sigreturn_wrapper)