arch/h8300/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2 #include <asm/page.h>
   3
   4 /* target memory map */
   5 #ifdef CONFIG_H8300H_GENERIC
   6 #define ROMTOP  0x000000
   7 #define ROMSIZE 0x400000
   8 #define RAMTOP  0x400000
   9 #define RAMSIZE 0x400000
  10 #endif
  11
  12 #ifdef CONFIG_H8300H_AKI3068NET
  13 #define ROMTOP  0x000000
  14 #define ROMSIZE 0x080000
  15 #define RAMTOP  0x400000
  16 #define RAMSIZE 0x200000
  17 #endif
  18
  19 #ifdef CONFIG_H8300H_H8MAX
  20 #define ROMTOP  0x000000
  21 #define ROMSIZE 0x080000
  22 #define RAMTOP  0x400000
  23 #define RAMSIZE 0x200000
  24 #endif
  25
  26 #ifdef CONFIG_H8300H_SIM
  27 #define ROMTOP  0x000000
  28 #define ROMSIZE 0x100000
  29 #define RAMTOP  0x100000
  30 #define RAMSIZE 0x200000
  31 #endif
  32
  33 #ifdef CONFIG_H8S_SIM
  34 #define ROMTOP  0x000000
  35 #define ROMSIZE 0x400000
  36 #define RAMTOP  0x400000
  37 #define RAMSIZE 0x800000
  38 #endif
  39
  40 #ifdef CONFIG_H8S_EDOSK2674
  41 #define ROMTOP  0x000000
  42 #define ROMSIZE 0x400000
  43 #define RAMTOP  0x400000
  44 #define RAMSIZE 0x800000
  45 #endif
  46
  47 #if defined(CONFIG_H8300H_SIM) || defined(CONFIG_H8S_SIM)
  48 /*INPUT(romfs.o)*/
  49 #endif
  50
  51 jiffies = jiffies_64 + 4;
  52
  53 ENTRY(_start)
  54
  55 SECTIONS
  56 {
  57 #if defined(CONFIG_ROMKERNEL)
  58         . = ROMTOP;
  59         .vectors :
  60         {
  61         _vector = . ;
  62                 *(.vector*)
  63         }
  64 #else
  65         . = RAMTOP;
  66         .bootvec :
  67         {
  68                 *(.bootvec)
  69         }
  70 #endif
  71         .text :
  72         {
  73         _text = .;
  74 #if defined(CONFIG_ROMKERNEL)
  75         *(.int_redirect)
  76 #endif
  77         _stext = . ;
  78         TEXT_TEXT
  79         SCHED_TEXT
  80         LOCK_TEXT
  81         _etext = . ;
  82         }
  83         EXCEPTION_TABLE(16)
  84         NOTES
  85         RODATA
  86 #if defined(CONFIG_ROMKERNEL)
  87         SECURITY_INIT
  88 #endif
  89         ROEND = .;
  90 #if defined(CONFIG_ROMKERNEL)
  91         . = RAMTOP;
  92         .data : AT(ROEND)
  93 #else
  94         .data :
  95 #endif
  96         {
  97         _sdata = . ;
  98         __data_start = . ;
  99
 100         INIT_TASK_DATA(0x2000)
 101         . = ALIGN(0x4) ;
 102                 DATA_DATA
 103         . = ALIGN(0x4) ;
 104                 *(.data.*)
 105
 106         . = ALIGN(0x4) ;
 107         __init_begin = .;
 108         _sinittext = .;
 109                 INIT_TEXT
 110         _einittext = .;
 111                 INIT_DATA
 112         INIT_SETUP(0x4)
 113         INIT_CALLS
 114         CON_INITCALL
 115                 EXIT_TEXT
 116                 EXIT_DATA
 117         INIT_RAM_FS
 118         . = ALIGN(0x4) ;
 119         __init_end = .;
 120         _edata = . ;
 121         }
 122 #if defined(CONFIG_RAMKERNEL)
 123         SECURITY_INIT
 124 #endif
 125         _begin_data = LOADADDR(.data);
 126         .bss :
 127         {
 128         . = ALIGN(0x4) ;
 129         __sbss = . ;
 130         __bss_start = . ;
 131                 *(.bss*)
 132         . = ALIGN(0x4) ;
 133                 *(COMMON)
 134         . = ALIGN(0x4) ;
 135         __bss_stop = . ;
 136         _ebss = . ;
 137         _end = . ;
 138         _ramstart = .;
 139         }
 140         .romfs :
 141         {
 142                 *(.romfs*)
 143         }
 144         . = RAMTOP+RAMSIZE;
 145         .dummy :
 146         {
 147         command_start = . - 0x200 ;
 148         _ramend = . ;
 149         }
 150
 151         DISCARDS
 152 }