arch/h8300/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2 #include <asm/page.h>
   3
   4 #define ROMTOP 0x000000
   5 #define RAMTOP CONFIG_RAMBASE
   6
   7 jiffies = jiffies_64 + 4;
   8
   9 ENTRY(_start)
  10
  11 SECTIONS
  12 {
  13 #if defined(CONFIG_ROMKERNEL)
  14         . = ROMTOP;
  15         .vectors :
  16         {
  17         _vector = . ;
  18                 *(.vector*)
  19         }
  20 #else
  21         . = RAMTOP;
  22         _ramstart = .;
  23 #endif
  24         HEAD_TEXT_SECTION
  25         .text : {
  26         _stext = . ;
  27                 TEXT_TEXT
  28                 SCHED_TEXT
  29                 LOCK_TEXT
  30 #if defined(CONFIG_ROMKERNEL)
  31                 *(.int_redirect)
  32 #endif
  33         _etext = . ;
  34         }
  35         EXCEPTION_TABLE(16)
  36         NOTES
  37         RO_DATA(4)
  38 #if defined(CONFIG_ROMKERNEL)
  39         .init.text : {
  40                 _sinittext = .;
  41                 INIT_TEXT
  42                 _einittext = .;
  43         }
  44         SECURITY_INIT
  45 #endif
  46         ROMEND = .;
  47 #if defined(CONFIG_ROMKERNEL)
  48         . = RAMTOP;
  49         _ramstart = .;
  50         .data : AT(ROMEND)
  51 #else
  52         .data :
  53 #endif
  54         {
  55         _sdata = . ;
  56         __data_start = . ;
  57                 INIT_TASK_DATA(0x2000)
  58                 NOSAVE_DATA
  59                 PAGE_ALIGNED_DATA(0x1000)
  60                 CACHELINE_ALIGNED_DATA(0x0002)
  61                 READ_MOSTLY_DATA(0x0002)
  62                 DATA_DATA
  63                 CONSTRUCTORS
  64         }
  65         . = ALIGN(0x4) ;
  66         __init_begin = .;
  67         _sinittext = .;
  68         INIT_TEXT_SECTION(4)
  69         _einittext = .;
  70         INIT_DATA_SECTION(4)
  71 #if defined(CONFIG_RAMKERNEL)
  72         SECURITY_INIT
  73 #endif
  74         __init_end = .;
  75         _edata = . ;
  76         _begin_data = LOADADDR(.data);
  77         _sbss =.;
  78         BSS_SECTION(4,4,4)
  79         _ebss =.;
  80         _ramend = .;
  81         DISCARDS
  82 }