arch/powerpc/kernel/tm.S

   1 /*
   2  * Transactional memory support routines to reclaim and recheckpoint
   3  * transactional process state.
   4  *
   5  * Copyright 2012 Matt Evans & Michael Neuling, IBM Corporation.
   6  */
   7
   8 #include <asm/asm-offsets.h>
   9 #include <asm/ppc_asm.h>
  10 #include <asm/ppc-opcode.h>
  11 #include <asm/ptrace.h>
  12 #include <asm/reg.h>
  13
  14 #ifdef CONFIG_VSX
  15 /* See fpu.S, this is very similar but to save/restore checkpointed FPRs/VSRs */
  16 #define __SAVE_32FPRS_VSRS_TRANSACT(n,c,base)   \
  17 BEGIN_FTR_SECTION                               \
  18         b       2f;                             \
  19 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  20         SAVE_32FPRS_TRANSACT(n,base);           \
  21         b       3f;                             \
  22 2:      SAVE_32VSRS_TRANSACT(n,c,base);         \
  23 3:
  24 /* ...and this is just plain borrowed from there. */
  25 #define __REST_32FPRS_VSRS(n,c,base)            \
  26 BEGIN_FTR_SECTION                               \
  27         b       2f;                             \
  28 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  29         REST_32FPRS(n,base);                    \
  30         b       3f;                             \
  31 2:      REST_32VSRS(n,c,base);                  \
  32 3:
  33 #else
  34 #define __SAVE_32FPRS_VSRS_TRANSACT(n,c,base) SAVE_32FPRS_TRANSACT(n, base)
  35 #define __REST_32FPRS_VSRS(n,c,base)          REST_32FPRS(n, base)
  36 #endif
  37 #define SAVE_32FPRS_VSRS_TRANSACT(n,c,base) \
  38         __SAVE_32FPRS_VSRS_TRANSACT(n,__REG_##c,__REG_##base)
  39 #define REST_32FPRS_VSRS(n,c,base) \
  40         __REST_32FPRS_VSRS(n,__REG_##c,__REG_##base)
  41
  42 /* Stack frame offsets for local variables. */
  43 #define TM_FRAME_L0     TM_FRAME_SIZE-16
  44 #define TM_FRAME_L1     TM_FRAME_SIZE-8
  45 #define STACK_PARAM(x)  (48+((x)*8))
  46
  47
  48 /* In order to access the TM SPRs, TM must be enabled.  So, do so: */
  49 _GLOBAL(tm_enable)
  50         mfmsr   r4
  51         li      r3, MSR_TM >> 32
  52         sldi    r3, r3, 32
  53         and.    r0, r4, r3
  54         bne     1f
  55         or      r4, r4, r3
  56         mtmsrd  r4
  57 1:      blr
  58
  59 _GLOBAL(tm_save_sprs)
  60         mfspr   r0, SPRN_TFHAR
  61         std     r0, THREAD_TM_TFHAR(r3)
  62         mfspr   r0, SPRN_TEXASR
  63         std     r0, THREAD_TM_TEXASR(r3)
  64         mfspr   r0, SPRN_TFIAR
  65         std     r0, THREAD_TM_TFIAR(r3)
  66         blr
  67
  68 _GLOBAL(tm_restore_sprs)
  69         ld      r0, THREAD_TM_TFHAR(r3)
  70         mtspr   SPRN_TFHAR, r0
  71         ld      r0, THREAD_TM_TEXASR(r3)
  72         mtspr   SPRN_TEXASR, r0
  73         ld      r0, THREAD_TM_TFIAR(r3)
  74         mtspr   SPRN_TFIAR, r0
  75         blr
  76
  77         /* Passed an 8-bit failure cause as first argument. */
  78 _GLOBAL(tm_abort)
  79         TABORT(R3)
  80         blr
  81
  82
  83 /* void tm_reclaim(struct thread_struct *thread,
  84  *                 unsigned long orig_msr,
  85  *                 uint8_t cause)
  86  *
  87  *      - Performs a full reclaim.  This destroys outstanding
  88  *        transactions and updates thread->regs.tm_ckpt_* with the
  89  *        original checkpointed state.  Note that thread->regs is
  90  *        unchanged.
  91  *      - FP regs are written back to thread->transact_fpr before
  92  *        reclaiming.  These are the transactional (current) versions.
  93  *
  94  * Purpose is to both abort transactions of, and preserve the state of,
  95  * a transactions at a context switch. We preserve/restore both sets of process
  96  * state to restore them when the thread's scheduled again.  We continue in
  97  * userland as though nothing happened, but when the transaction is resumed
  98  * they will abort back to the checkpointed state we save out here.
  99  *
 100  * Call with IRQs off, stacks get all out of sync for some periods in here!
 101  */
 102 _GLOBAL(tm_reclaim)
 103         mfcr    r6
 104         mflr    r0
 105         std     r6, 8(r1)
 106         std     r0, 16(r1)
 107         std     r2, 40(r1)
 108         stdu    r1, -TM_FRAME_SIZE(r1)
 109
 110         /* We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD]. */
 111
 112         std     r3, STACK_PARAM(0)(r1)
 113         SAVE_NVGPRS(r1)
 114
 115         /* We need to setup MSR for VSX register save instructions.  Here we
 116          * also clear the MSR RI since when we do the treclaim, we won't have a
 117          * valid kernel pointer for a while.  We clear RI here as it avoids
 118          * adding another mtmsr closer to the treclaim.  This makes the region
 119          * maked as non-recoverable wider than it needs to be but it saves on
 120          * inserting another mtmsrd later.
 121          */
 122         mfmsr   r14
 123         mr      r15, r14
 124         ori     r15, r15, MSR_FP
 125         li      r16, MSR_RI
 126         ori     r16, r16, MSR_EE /* IRQs hard off */
 127         andc    r15, r15, r16
 128         oris    r15, r15, MSR_VEC@h
 129 #ifdef CONFIG_VSX
 130         BEGIN_FTR_SECTION
 131         oris    r15,r15, MSR_VSX@h
 132         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 133 #endif
 134         mtmsrd  r15
 135         std     r14, TM_FRAME_L0(r1)
 136
 137         /* Stash the stack pointer away for use after reclaim */
 138         std     r1, PACAR1(r13)
 139
 140         /* ******************** FPR/VR/VSRs ************
 141          * Before reclaiming, capture the current/transactional FPR/VR
 142         * versions /if used/.
 143          *
 144          * (If VSX used, FP and VMX are implied.  Or, we don't need to look
 145          * at MSR.VSX as copying FP regs if .FP, vector regs if .VMX covers it.)
 146          *
 147          * We're passed the thread's MSR as parameter 2.
 148          *
 149          * We enabled VEC/FP/VSX in the msr above, so we can execute these
 150          * instructions!
 151          */
 152         andis.          r0, r4, MSR_VEC@h
 153         beq     dont_backup_vec
 154
 155         SAVE_32VRS_TRANSACT(0, r6, r3)  /* r6 scratch, r3 thread */
 156         mfvscr  vr0
 157         li      r6, THREAD_TRANSACT_VSCR
 158         stvx    vr0, r3, r6
 159 dont_backup_vec:
 160         mfspr   r0, SPRN_VRSAVE
 161         std     r0, THREAD_TRANSACT_VRSAVE(r3)
 162
 163         andi.   r0, r4, MSR_FP
 164         beq     dont_backup_fp
 165
 166         SAVE_32FPRS_VSRS_TRANSACT(0, R6, R3)    /* r6 scratch, r3 thread */
 167
 168         mffs    fr0
 169         stfd    fr0,THREAD_TRANSACT_FPSCR(r3)
 170
 171 dont_backup_fp:
 172         /* The moment we treclaim, ALL of our GPRs will switch
 173          * to user register state.  (FPRs, CCR etc. also!)
 174          * Use an sprg and a tm_scratch in the PACA to shuffle.
 175          */
 176         TRECLAIM(R5)                            /* Cause in r5 */
 177
 178         /* ******************** GPRs ******************** */
 179         /* Stash the checkpointed r13 away in the scratch SPR and get the real
 180          *  paca
 181          */
 182         SET_SCRATCH0(r13)
 183         GET_PACA(r13)
 184
 185         /* Stash the checkpointed r1 away in paca tm_scratch and get the real
 186          * stack pointer back
 187          */
 188         std     r1, PACATMSCRATCH(r13)
 189         ld      r1, PACAR1(r13)
 190
 191         /* Now get some more GPRS free */
 192         std     r7, GPR7(r1)                    /* Temporary stash */
 193         std     r12, GPR12(r1)                  /* ''   ''    ''   */
 194         ld      r12, STACK_PARAM(0)(r1)         /* Param 0, thread_struct * */
 195
 196         addi    r7, r12, PT_CKPT_REGS           /* Thread's ckpt_regs */
 197
 198         /* Make r7 look like an exception frame so that we
 199          * can use the neat GPRx(n) macros.  r7 is NOT a pt_regs ptr!
 200          */
 201         subi    r7, r7, STACK_FRAME_OVERHEAD
 202
 203         /* Sync the userland GPRs 2-12, 14-31 to thread->regs: */
 204         SAVE_GPR(0, r7)                         /* user r0 */
 205         SAVE_GPR(2, r7)                 /* user r2 */
 206         SAVE_4GPRS(3, r7)                       /* user r3-r6 */
 207         SAVE_4GPRS(8, r7)                       /* user r8-r11 */
 208         ld      r3, PACATMSCRATCH(r13)          /* user r1 */
 209         ld      r4, GPR7(r1)                    /* user r7 */
 210         ld      r5, GPR12(r1)                   /* user r12 */
 211         GET_SCRATCH0(6)                         /* user r13 */
 212         std     r3, GPR1(r7)
 213         std     r4, GPR7(r7)
 214         std     r5, GPR12(r7)
 215         std     r6, GPR13(r7)
 216
 217         SAVE_NVGPRS(r7)                         /* user r14-r31 */
 218
 219         /* ******************** NIP ******************** */
 220         mfspr   r3, SPRN_TFHAR
 221         std     r3, _NIP(r7)                    /* Returns to failhandler */
 222         /* The checkpointed NIP is ignored when rescheduling/rechkpting,
 223          * but is used in signal return to 'wind back' to the abort handler.
 224          */
 225
 226         /* ******************** CR,LR,CCR,MSR ********** */
 227         mfctr   r3
 228         mflr    r4
 229         mfcr    r5
 230         mfxer   r6
 231
 232         std     r3, _CTR(r7)
 233         std     r4, _LINK(r7)
 234         std     r5, _CCR(r7)
 235         std     r6, _XER(r7)
 236
 237
 238         /* ******************** TAR, PPR, DSCR ********** */
 239         mfspr   r3, SPRN_TAR
 240         mfspr   r4, SPRN_PPR
 241         mfspr   r5, SPRN_DSCR
 242
 243         std     r3, THREAD_TM_TAR(r12)
 244         std     r4, THREAD_TM_PPR(r12)
 245         std     r5, THREAD_TM_DSCR(r12)
 246
 247         /* MSR and flags:  We don't change CRs, and we don't need to alter
 248          * MSR.
 249          */
 250
 251         /* TM regs, incl TEXASR -- these live in thread_struct.  Note they've
 252          * been updated by the treclaim, to explain to userland the failure
 253          * cause (aborted).
 254          */
 255         mfspr   r0, SPRN_TEXASR
 256         mfspr   r3, SPRN_TFHAR
 257         mfspr   r4, SPRN_TFIAR
 258         std     r0, THREAD_TM_TEXASR(r12)
 259         std     r3, THREAD_TM_TFHAR(r12)
 260         std     r4, THREAD_TM_TFIAR(r12)
 261
 262         /* AMR and PPR are checkpointed too, but are unsupported by Linux. */
 263
 264         /* Restore original MSR/IRQ state & clear TM mode */
 265         ld      r14, TM_FRAME_L0(r1)            /* Orig MSR */
 266         li      r15, 0
 267         rldimi  r14, r15, MSR_TS_LG, (63-MSR_TS_LG)-1
 268         mtmsrd  r14
 269
 270         REST_NVGPRS(r1)
 271
 272         addi    r1, r1, TM_FRAME_SIZE
 273         ld      r4, 8(r1)
 274         ld      r0, 16(r1)
 275         mtcr    r4
 276         mtlr    r0
 277         ld      r2, 40(r1)
 278         blr
 279
 280
 281         /* void tm_recheckpoint(struct thread_struct *thread,
 282          *                      unsigned long orig_msr)
 283          *      - Restore the checkpointed register state saved by tm_reclaim
 284          *        when we switch_to a process.
 285          *
 286          *      Call with IRQs off, stacks get all out of sync for
 287          *      some periods in here!
 288          */
 289 _GLOBAL(tm_recheckpoint)
 290         mfcr    r5
 291         mflr    r0
 292         std     r5, 8(r1)
 293         std     r0, 16(r1)
 294         std     r2, 40(r1)
 295         stdu    r1, -TM_FRAME_SIZE(r1)
 296
 297         /* We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD].
 298          * This is used for backing up the NVGPRs:
 299          */
 300         SAVE_NVGPRS(r1)
 301
 302         std     r1, PACAR1(r13)
 303
 304         /* Load complete register state from ts_ckpt* registers */
 305
 306         addi    r7, r3, PT_CKPT_REGS            /* Thread's ckpt_regs */
 307
 308         /* Make r7 look like an exception frame so that we
 309          * can use the neat GPRx(n) macros.  r7 is now NOT a pt_regs ptr!
 310          */
 311         subi    r7, r7, STACK_FRAME_OVERHEAD
 312
 313         SET_SCRATCH0(r1)
 314
 315         mfmsr   r6
 316         /* R4 = original MSR to indicate whether thread used FP/Vector etc. */
 317
 318         /* Enable FP/vec in MSR if necessary! */
 319         lis     r5, MSR_VEC@h
 320         ori     r5, r5, MSR_FP
 321         and.    r5, r4, r5
 322         beq     restore_gprs                    /* if neither, skip both */
 323
 324 #ifdef CONFIG_VSX
 325         BEGIN_FTR_SECTION
 326         oris    r5, r5, MSR_VSX@h
 327         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 328 #endif
 329         or      r5, r6, r5                      /* Set MSR.FP+.VSX/.VEC */
 330         mtmsr   r5
 331
 332 #ifdef CONFIG_ALTIVEC
 333         /* FP and VEC registers:  These are recheckpointed from thread.fpr[]
 334          * and thread.vr[] respectively.  The thread.transact_fpr[] version
 335          * is more modern, and will be loaded subsequently by any FPUnavailable
 336          * trap.
 337          */
 338         andis.  r0, r4, MSR_VEC@h
 339         beq     dont_restore_vec
 340
 341         li      r5, THREAD_VSCR
 342         lvx     vr0, r3, r5
 343         mtvscr  vr0
 344         REST_32VRS(0, r5, r3)                   /* r5 scratch, r3 THREAD ptr */
 345 dont_restore_vec:
 346         ld      r5, THREAD_VRSAVE(r3)
 347         mtspr   SPRN_VRSAVE, r5
 348 #endif
 349
 350         andi.   r0, r4, MSR_FP
 351         beq     dont_restore_fp
 352
 353         lfd     fr0, THREAD_FPSCR(r3)
 354         MTFSF_L(fr0)
 355         REST_32FPRS_VSRS(0, R4, R3)
 356
 357 dont_restore_fp:
 358         mtmsr   r6                              /* FP/Vec off again! */
 359
 360 restore_gprs:
 361
 362         /* ******************** TAR, PPR, DSCR ********** */
 363         ld      r4, THREAD_TM_TAR(r3)
 364         ld      r5, THREAD_TM_PPR(r3)
 365         ld      r6, THREAD_TM_DSCR(r3)
 366
 367         mtspr   SPRN_TAR,       r4
 368         mtspr   SPRN_PPR,       r5
 369         mtspr   SPRN_DSCR,      r6
 370
 371         /* ******************** CR,LR,CCR,MSR ********** */
 372         ld      r3, _CTR(r7)
 373         ld      r4, _LINK(r7)
 374         ld      r5, _CCR(r7)
 375         ld      r6, _XER(r7)
 376
 377         mtctr   r3
 378         mtlr    r4
 379         mtcr    r5
 380         mtxer   r6
 381
 382         /* Clear the MSR RI since we are about to change R1.  EE is already off
 383          */
 384         li      r4, 0
 385         mtmsrd  r4, 1
 386
 387         REST_4GPRS(0, r7)                       /* GPR0-3 */
 388         REST_GPR(4, r7)                         /* GPR4-6 */
 389         REST_GPR(5, r7)
 390         REST_GPR(6, r7)
 391         REST_4GPRS(8, r7)                       /* GPR8-11 */
 392         REST_2GPRS(12, r7)                      /* GPR12-13 */
 393
 394         REST_NVGPRS(r7)                         /* GPR14-31 */
 395
 396         ld      r7, GPR7(r7)                    /* GPR7 */
 397
 398         /* Commit register state as checkpointed state: */
 399         TRECHKPT
 400
 401         /* Our transactional state has now changed.
 402          *
 403          * Now just get out of here.  Transactional (current) state will be
 404          * updated once restore is called on the return path in the _switch-ed
 405          * -to process.
 406          */
 407
 408         GET_PACA(r13)
 409         GET_SCRATCH0(r1)
 410
 411         /* R1 is restored, so we are recoverable again.  EE is still off */
 412         li      r4, MSR_RI
 413         mtmsrd  r4, 1
 414
 415         REST_NVGPRS(r1)
 416
 417         addi    r1, r1, TM_FRAME_SIZE
 418         ld      r4, 8(r1)
 419         ld      r0, 16(r1)
 420         mtcr    r4
 421         mtlr    r0
 422         ld      r2, 40(r1)
 423         blr
 424
 425         /* ****************************************************************** */