2 * linux/arch/x86_64/entry.S
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 * Copyright (C) 2000, 2001, 2002 Andi Kleen SuSE Labs
6 * Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
8 * entry.S contains the system-call and fault low-level handling routines.
10 * Some of this is documented in Documentation/x86/entry_64.txt
12 * A note on terminology:
13 * - iret frame: Architecture defined interrupt frame from SS to RIP
14 * at the top of the kernel process stack.
17 * - ENTRY/END: Define functions in the symbol table.
18 * - TRACE_IRQ_*: Trace hardirq state for lock debugging.
19 * - idtentry: Define exception entry points.
21 #include <linux/linkage.h>
22 #include <asm/segment.h>
23 #include <asm/cache.h>
24 #include <asm/errno.h>
26 #include <asm/asm-offsets.h>
28 #include <asm/unistd.h>
29 #include <asm/thread_info.h>
30 #include <asm/hw_irq.h>
31 #include <asm/page_types.h>
32 #include <asm/irqflags.h>
33 #include <asm/paravirt.h>
34 #include <asm/percpu.h>
37 #include <asm/pgtable_types.h>
38 #include <asm/kaiser.h>
39 #include <asm/nospec-branch.h>
40 #include <linux/err.h>
42 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
43 #include <linux/elf-em.h>
44 #define AUDIT_ARCH_X86_64 (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
45 #define __AUDIT_ARCH_64BIT 0x80000000
46 #define __AUDIT_ARCH_LE 0x40000000
49 .section .entry.text, "ax"
51 #ifdef CONFIG_PARAVIRT
52 ENTRY(native_usergs_sysret64)
55 ENDPROC(native_usergs_sysret64)
56 #endif /* CONFIG_PARAVIRT */
58 .macro TRACE_IRQS_IRETQ
59 #ifdef CONFIG_TRACE_IRQFLAGS
60 bt $9, EFLAGS(%rsp) /* interrupts off? */
68 * When dynamic function tracer is enabled it will add a breakpoint
69 * to all locations that it is about to modify, sync CPUs, update
70 * all the code, sync CPUs, then remove the breakpoints. In this time
71 * if lockdep is enabled, it might jump back into the debug handler
72 * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
74 * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
75 * make sure the stack pointer does not get reset back to the top
76 * of the debug stack, and instead just reuses the current stack.
78 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
80 .macro TRACE_IRQS_OFF_DEBUG
81 call debug_stack_set_zero
83 call debug_stack_reset
86 .macro TRACE_IRQS_ON_DEBUG
87 call debug_stack_set_zero
89 call debug_stack_reset
92 .macro TRACE_IRQS_IRETQ_DEBUG
93 btl $9, EFLAGS(%rsp) /* interrupts off? */
100 # define TRACE_IRQS_OFF_DEBUG TRACE_IRQS_OFF
101 # define TRACE_IRQS_ON_DEBUG TRACE_IRQS_ON
102 # define TRACE_IRQS_IRETQ_DEBUG TRACE_IRQS_IRETQ
106 * 64-bit SYSCALL instruction entry. Up to 6 arguments in registers.
108 * 64-bit SYSCALL saves rip to rcx, clears rflags.RF, then saves rflags to r11,
109 * then loads new ss, cs, and rip from previously programmed MSRs.
110 * rflags gets masked by a value from another MSR (so CLD and CLAC
111 * are not needed). SYSCALL does not save anything on the stack
112 * and does not change rsp.
114 * Registers on entry:
115 * rax system call number
117 * r11 saved rflags (note: r11 is callee-clobbered register in C ABI)
121 * r10 arg3 (needs to be moved to rcx to conform to C ABI)
124 * (note: r12-r15, rbp, rbx are callee-preserved in C ABI)
126 * Only called from user space.
128 * When user can change pt_regs->foo always force IRET. That is because
129 * it deals with uncanonical addresses better. SYSRET has trouble
130 * with them due to bugs in both AMD and Intel CPUs.
133 ENTRY(entry_SYSCALL_64)
135 * Interrupts are off on entry.
136 * We do not frame this tiny irq-off block with TRACE_IRQS_OFF/ON,
137 * it is too small to ever cause noticeable irq latency.
140 SWITCH_KERNEL_CR3_NO_STACK
142 * A hypervisor implementation might want to use a label
143 * after the swapgs, so that it can do the swapgs
144 * for the guest and jump here on syscall.
146 GLOBAL(entry_SYSCALL_64_after_swapgs)
148 movq %rsp, PER_CPU_VAR(rsp_scratch)
149 movq PER_CPU_VAR(cpu_current_top_of_stack), %rsp
151 /* Construct struct pt_regs on stack */
152 pushq $__USER_DS /* pt_regs->ss */
153 pushq PER_CPU_VAR(rsp_scratch) /* pt_regs->sp */
155 * Re-enable interrupts.
156 * We use 'rsp_scratch' as a scratch space, hence irq-off block above
157 * must execute atomically in the face of possible interrupt-driven
158 * task preemption. We must enable interrupts only after we're done
159 * with using rsp_scratch:
161 ENABLE_INTERRUPTS(CLBR_NONE)
162 pushq %r11 /* pt_regs->flags */
163 pushq $__USER_CS /* pt_regs->cs */
164 pushq %rcx /* pt_regs->ip */
165 pushq %rax /* pt_regs->orig_ax */
166 pushq %rdi /* pt_regs->di */
167 pushq %rsi /* pt_regs->si */
168 pushq %rdx /* pt_regs->dx */
169 pushq %rcx /* pt_regs->cx */
170 pushq $-ENOSYS /* pt_regs->ax */
171 pushq %r8 /* pt_regs->r8 */
172 pushq %r9 /* pt_regs->r9 */
173 pushq %r10 /* pt_regs->r10 */
174 pushq %r11 /* pt_regs->r11 */
175 sub $(6*8), %rsp /* pt_regs->bp, bx, r12-15 not saved */
177 testl $_TIF_WORK_SYSCALL_ENTRY, ASM_THREAD_INFO(TI_flags, %rsp, SIZEOF_PTREGS)
179 entry_SYSCALL_64_fastpath:
180 #if __SYSCALL_MASK == ~0
181 cmpq $NR_syscalls, %rax
183 andl $__SYSCALL_MASK, %eax
184 cmpl $NR_syscalls, %eax
186 jae 1f /* return -ENOSYS (already in pt_regs->ax) */
187 sbb %rcx, %rcx /* array_index_mask_nospec() */
192 * This call instruction is handled specially in stub_ptregs_64.
193 * It might end up jumping to the slow path. If it jumps, RAX is
196 #ifdef CONFIG_RETPOLINE
197 movq sys_call_table(, %rax, 8), %rax
198 call __x86_indirect_thunk_rax
200 call *sys_call_table(, %rax, 8)
202 .Lentry_SYSCALL_64_after_fastpath_call:
207 * Syscall return path ending with SYSRET (fast path).
208 * Has incompletely filled pt_regs.
212 * We do not frame this tiny irq-off block with TRACE_IRQS_OFF/ON,
213 * it is too small to ever cause noticeable irq latency.
215 DISABLE_INTERRUPTS(CLBR_NONE)
218 * We must check ti flags with interrupts (or at least preemption)
219 * off because we must *never* return to userspace without
220 * processing exit work that is enqueued if we're preempted here.
221 * In particular, returning to userspace with any of the one-shot
222 * flags (TIF_NOTIFY_RESUME, TIF_USER_RETURN_NOTIFY, etc) set is
225 testl $_TIF_ALLWORK_MASK, ASM_THREAD_INFO(TI_flags, %rsp, SIZEOF_PTREGS)
226 jnz int_ret_from_sys_call_irqs_off /* Go to the slow path */
229 movq EFLAGS(%rsp), %r11
230 RESTORE_C_REGS_EXCEPT_RCX_R11
232 * This opens a window where we have a user CR3, but are
233 * running in the kernel. This makes using the CS
234 * register useless for telling whether or not we need to
235 * switch CR3 in NMIs. Normal interrupts are OK because
241 * 64-bit SYSRET restores rip from rcx,
242 * rflags from r11 (but RF and VM bits are forced to 0),
243 * cs and ss are loaded from MSRs.
244 * Restoration of rflags re-enables interrupts.
246 * NB: On AMD CPUs with the X86_BUG_SYSRET_SS_ATTRS bug, the ss
247 * descriptor is not reinitialized. This means that we should
248 * avoid SYSRET with SS == NULL, which could happen if we schedule,
249 * exit the kernel, and re-enter using an interrupt vector. (All
250 * interrupt entries on x86_64 set SS to NULL.) We prevent that
251 * from happening by reloading SS in __switch_to. (Actually
252 * detecting the failure in 64-bit userspace is tricky but can be
257 GLOBAL(int_ret_from_sys_call_irqs_off)
259 ENABLE_INTERRUPTS(CLBR_NONE)
260 jmp int_ret_from_sys_call
262 /* Do syscall entry tracing */
266 call syscall_trace_enter
269 * Reload registers from stack in case ptrace changed them.
270 * We don't reload %rax because syscall_trace_enter() returned
271 * the value it wants us to use in the table lookup.
273 RESTORE_C_REGS_EXCEPT_RAX
275 #if __SYSCALL_MASK == ~0
276 cmpq $NR_syscalls, %rax
278 andl $__SYSCALL_MASK, %eax
279 cmpl $NR_syscalls, %eax
281 jae 1f /* return -ENOSYS (already in pt_regs->ax) */
282 sbb %rcx, %rcx /* array_index_mask_nospec() */
284 movq %r10, %rcx /* fixup for C */
285 #ifdef CONFIG_RETPOLINE
286 movq sys_call_table(, %rax, 8), %rax
287 call __x86_indirect_thunk_rax
289 call *sys_call_table(, %rax, 8)
293 /* Use IRET because user could have changed pt_regs->foo */
296 * Syscall return path ending with IRET.
297 * Has correct iret frame.
299 GLOBAL(int_ret_from_sys_call)
302 call syscall_return_slowpath /* returns with IRQs disabled */
304 TRACE_IRQS_IRETQ /* we're about to change IF */
307 * Try to use SYSRET instead of IRET if we're returning to
308 * a completely clean 64-bit userspace context.
312 cmpq %rcx, %r11 /* RCX == RIP */
313 jne opportunistic_sysret_failed
316 * On Intel CPUs, SYSRET with non-canonical RCX/RIP will #GP
317 * in kernel space. This essentially lets the user take over
318 * the kernel, since userspace controls RSP.
320 * If width of "canonical tail" ever becomes variable, this will need
321 * to be updated to remain correct on both old and new CPUs.
323 .ifne __VIRTUAL_MASK_SHIFT - 47
324 .error "virtual address width changed -- SYSRET checks need update"
327 /* Change top 16 bits to be the sign-extension of 47th bit */
328 shl $(64 - (__VIRTUAL_MASK_SHIFT+1)), %rcx
329 sar $(64 - (__VIRTUAL_MASK_SHIFT+1)), %rcx
331 /* If this changed %rcx, it was not canonical */
333 jne opportunistic_sysret_failed
335 cmpq $__USER_CS, CS(%rsp) /* CS must match SYSRET */
336 jne opportunistic_sysret_failed
339 cmpq %r11, EFLAGS(%rsp) /* R11 == RFLAGS */
340 jne opportunistic_sysret_failed
343 * SYSRET can't restore RF. SYSRET can restore TF, but unlike IRET,
344 * restoring TF results in a trap from userspace immediately after
345 * SYSRET. This would cause an infinite loop whenever #DB happens
346 * with register state that satisfies the opportunistic SYSRET
347 * conditions. For example, single-stepping this user code:
349 * movq $stuck_here, %rcx
354 * would never get past 'stuck_here'.
356 testq $(X86_EFLAGS_RF|X86_EFLAGS_TF), %r11
357 jnz opportunistic_sysret_failed
359 /* nothing to check for RSP */
361 cmpq $__USER_DS, SS(%rsp) /* SS must match SYSRET */
362 jne opportunistic_sysret_failed
365 * We win! This label is here just for ease of understanding
366 * perf profiles. Nothing jumps here.
368 syscall_return_via_sysret:
369 /* rcx and r11 are already restored (see code above) */
370 RESTORE_C_REGS_EXCEPT_RCX_R11
372 * This opens a window where we have a user CR3, but are
373 * running in the kernel. This makes using the CS
374 * register useless for telling whether or not we need to
375 * switch CR3 in NMIs. Normal interrupts are OK because
382 opportunistic_sysret_failed:
384 * This opens a window where we have a user CR3, but are
385 * running in the kernel. This makes using the CS
386 * register useless for telling whether or not we need to
387 * switch CR3 in NMIs. Normal interrupts are OK because
392 jmp restore_c_regs_and_iret
393 END(entry_SYSCALL_64)
395 ENTRY(stub_ptregs_64)
397 * Syscalls marked as needing ptregs land here.
398 * If we are on the fast path, we need to save the extra regs.
399 * If we are on the slow path, the extra regs are already saved.
401 * RAX stores a pointer to the C function implementing the syscall.
403 cmpq $.Lentry_SYSCALL_64_after_fastpath_call, (%rsp)
406 /* Called from fast path -- pop return address and jump to slow path */
408 jmp tracesys /* called from fast path */
412 jmp *%rax /* called from C */
415 .macro ptregs_stub func
417 leaq \func(%rip), %rax
422 /* Instantiate ptregs_stub for each ptregs-using syscall */
423 #define __SYSCALL_64_QUAL_(sym)
424 #define __SYSCALL_64_QUAL_ptregs(sym) ptregs_stub sym
425 #define __SYSCALL_64(nr, sym, qual) __SYSCALL_64_QUAL_##qual(sym)
426 #include <asm/syscalls_64.h>
428 .macro FORK_LIKE func
444 /* exec failed, can use fast SYSRET code path in this case */
447 /* must use IRET code path (pt_regs->cs may have changed) */
451 jmp int_ret_from_sys_call
454 * Remaining execve stubs are only 7 bytes long.
455 * ENTRY() often aligns to 16 bytes, which in this case has no benefits.
458 GLOBAL(stub_execveat)
460 jmp return_from_execve
463 #if defined(CONFIG_X86_X32_ABI)
465 GLOBAL(stub_x32_execve)
466 call compat_sys_execve
467 jmp return_from_execve
470 GLOBAL(stub_x32_execveat)
471 call compat_sys_execveat
472 jmp return_from_execve
473 END(stub_x32_execveat)
477 * sigreturn is special because it needs to restore all registers on return.
478 * This cannot be done with SYSRET, so use the IRET return path instead.
480 ENTRY(stub_rt_sigreturn)
482 * SAVE_EXTRA_REGS result is not normally needed:
483 * sigreturn overwrites all pt_regs->GPREGS.
484 * But sigreturn can fail (!), and there is no easy way to detect that.
485 * To make sure RESTORE_EXTRA_REGS doesn't restore garbage on error,
486 * we SAVE_EXTRA_REGS here.
489 call sys_rt_sigreturn
494 jmp int_ret_from_sys_call
495 END(stub_rt_sigreturn)
497 #ifdef CONFIG_X86_X32_ABI
498 ENTRY(stub_x32_rt_sigreturn)
500 call sys32_x32_rt_sigreturn
502 END(stub_x32_rt_sigreturn)
506 * A newly forked process directly context switches into this address.
508 * rdi: prev task we switched from
512 LOCK ; btr $TIF_FORK, TI_flags(%r8)
515 popfq /* reset kernel eflags */
517 call schedule_tail /* rdi: 'prev' task parameter */
521 testb $3, CS(%rsp) /* from kernel_thread? */
524 * By the time we get here, we have no idea whether our pt_regs,
525 * ti flags, and ti status came from the 64-bit SYSCALL fast path,
526 * the slow path, or one of the 32-bit compat paths.
527 * Use IRET code path to return, since it can safely handle
530 jnz int_ret_from_sys_call
533 * We came from kernel_thread
534 * nb: we depend on RESTORE_EXTRA_REGS above
540 jmp int_ret_from_sys_call
544 * Build the entry stubs with some assembler magic.
545 * We pack 1 stub into every 8-byte block.
548 ENTRY(irq_entries_start)
549 vector=FIRST_EXTERNAL_VECTOR
550 .rept (FIRST_SYSTEM_VECTOR - FIRST_EXTERNAL_VECTOR)
551 pushq $(~vector+0x80) /* Note: always in signed byte range */
556 END(irq_entries_start)
559 * Interrupt entry/exit.
561 * Interrupt entry points save only callee clobbered registers in fast path.
563 * Entry runs with interrupts off.
566 /* 0(%rsp): ~(interrupt number) */
567 .macro interrupt func
569 ALLOC_PT_GPREGS_ON_STACK
577 * IRQ from user mode. Switch to kernel gsbase and inform context
578 * tracking that we're in kernel mode.
584 * We need to tell lockdep that IRQs are off. We can't do this until
585 * we fix gsbase, and we should do it before enter_from_user_mode
586 * (which can take locks). Since TRACE_IRQS_OFF idempotent,
587 * the simplest way to handle it is to just call it twice if
588 * we enter from user mode. There's no reason to optimize this since
589 * TRACE_IRQS_OFF is a no-op if lockdep is off.
593 #ifdef CONFIG_CONTEXT_TRACKING
594 call enter_from_user_mode
599 * Save previous stack pointer, optionally switch to interrupt stack.
600 * irq_count is used to check if a CPU is already on an interrupt stack
601 * or not. While this is essentially redundant with preempt_count it is
602 * a little cheaper to use a separate counter in the PDA (short of
603 * moving irq_enter into assembly, which would be too much work)
606 incl PER_CPU_VAR(irq_count)
607 cmovzq PER_CPU_VAR(irq_stack_ptr), %rsp
609 /* We entered an interrupt context - irqs are off: */
612 call \func /* rdi points to pt_regs */
616 * The interrupt stubs push (~vector+0x80) onto the stack and
617 * then jump to common_interrupt.
619 .p2align CONFIG_X86_L1_CACHE_SHIFT
622 addq $-0x80, (%rsp) /* Adjust vector to [-256, -1] range */
624 /* 0(%rsp): old RSP */
626 DISABLE_INTERRUPTS(CLBR_NONE)
628 decl PER_CPU_VAR(irq_count)
630 /* Restore saved previous stack */
636 /* Interrupt came from user space */
639 call prepare_exit_to_usermode
643 jmp restore_regs_and_iret
645 /* Returning to kernel space */
647 #ifdef CONFIG_PREEMPT
648 /* Interrupts are off */
649 /* Check if we need preemption */
650 btl $9, EFLAGS(%rsp) /* were interrupts off? */
652 0: cmpl $0, PER_CPU_VAR(__preempt_count)
654 call preempt_schedule_irq
659 * The iretq could re-enable interrupts:
664 * At this label, code paths which return to kernel and to user,
665 * which come from interrupts/exception and from syscalls, merge.
667 GLOBAL(restore_regs_and_iret)
669 restore_c_regs_and_iret:
671 REMOVE_PT_GPREGS_FROM_STACK 8
676 * Are we returning to a stack segment from the LDT? Note: in
677 * 64-bit mode SS:RSP on the exception stack is always valid.
679 #ifdef CONFIG_X86_ESPFIX64
680 testb $4, (SS-RIP)(%rsp)
681 jnz native_irq_return_ldt
684 .global native_irq_return_iret
685 native_irq_return_iret:
687 * This may fault. Non-paranoid faults on return to userspace are
688 * handled by fixup_bad_iret. These include #SS, #GP, and #NP.
689 * Double-faults due to espfix64 are handled in do_double_fault.
690 * Other faults here are fatal.
694 #ifdef CONFIG_X86_ESPFIX64
695 native_irq_return_ldt:
700 movq PER_CPU_VAR(espfix_waddr), %rdi
701 movq %rax, (0*8)(%rdi) /* RAX */
702 movq (2*8)(%rsp), %rax /* RIP */
703 movq %rax, (1*8)(%rdi)
704 movq (3*8)(%rsp), %rax /* CS */
705 movq %rax, (2*8)(%rdi)
706 movq (4*8)(%rsp), %rax /* RFLAGS */
707 movq %rax, (3*8)(%rdi)
708 movq (6*8)(%rsp), %rax /* SS */
709 movq %rax, (5*8)(%rdi)
710 movq (5*8)(%rsp), %rax /* RSP */
711 movq %rax, (4*8)(%rdi)
712 andl $0xffff0000, %eax
714 orq PER_CPU_VAR(espfix_stack), %rax
719 jmp native_irq_return_iret
721 END(common_interrupt)
726 .macro apicinterrupt3 num sym do_sym
736 #ifdef CONFIG_TRACING
737 #define trace(sym) trace_##sym
738 #define smp_trace(sym) smp_trace_##sym
740 .macro trace_apicinterrupt num sym
741 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
744 .macro trace_apicinterrupt num sym do_sym
748 /* Make sure APIC interrupt handlers end up in the irqentry section: */
749 #define PUSH_SECTION_IRQENTRY .pushsection .irqentry.text, "ax"
750 #define POP_SECTION_IRQENTRY .popsection
752 .macro apicinterrupt num sym do_sym
753 PUSH_SECTION_IRQENTRY
754 apicinterrupt3 \num \sym \do_sym
755 trace_apicinterrupt \num \sym
760 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
761 apicinterrupt3 REBOOT_VECTOR reboot_interrupt smp_reboot_interrupt
765 apicinterrupt3 UV_BAU_MESSAGE uv_bau_message_intr1 uv_bau_message_interrupt
768 apicinterrupt LOCAL_TIMER_VECTOR apic_timer_interrupt smp_apic_timer_interrupt
769 apicinterrupt X86_PLATFORM_IPI_VECTOR x86_platform_ipi smp_x86_platform_ipi
771 #ifdef CONFIG_HAVE_KVM
772 apicinterrupt3 POSTED_INTR_VECTOR kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
773 apicinterrupt3 POSTED_INTR_WAKEUP_VECTOR kvm_posted_intr_wakeup_ipi smp_kvm_posted_intr_wakeup_ipi
776 #ifdef CONFIG_X86_MCE_THRESHOLD
777 apicinterrupt THRESHOLD_APIC_VECTOR threshold_interrupt smp_threshold_interrupt
780 #ifdef CONFIG_X86_MCE_AMD
781 apicinterrupt DEFERRED_ERROR_VECTOR deferred_error_interrupt smp_deferred_error_interrupt
784 #ifdef CONFIG_X86_THERMAL_VECTOR
785 apicinterrupt THERMAL_APIC_VECTOR thermal_interrupt smp_thermal_interrupt
789 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR call_function_single_interrupt smp_call_function_single_interrupt
790 apicinterrupt CALL_FUNCTION_VECTOR call_function_interrupt smp_call_function_interrupt
791 apicinterrupt RESCHEDULE_VECTOR reschedule_interrupt smp_reschedule_interrupt
794 apicinterrupt ERROR_APIC_VECTOR error_interrupt smp_error_interrupt
795 apicinterrupt SPURIOUS_APIC_VECTOR spurious_interrupt smp_spurious_interrupt
797 #ifdef CONFIG_IRQ_WORK
798 apicinterrupt IRQ_WORK_VECTOR irq_work_interrupt smp_irq_work_interrupt
802 * Exception entry points.
804 #define CPU_TSS_IST(x) PER_CPU_VAR(cpu_tss) + (TSS_ist + ((x) - 1) * 8)
806 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
809 .if \shift_ist != -1 && \paranoid == 0
810 .error "using shift_ist requires paranoid=1"
814 PARAVIRT_ADJUST_EXCEPTION_FRAME
816 .ifeq \has_error_code
817 pushq $-1 /* ORIG_RAX: no syscall to restart */
820 ALLOC_PT_GPREGS_ON_STACK
824 testb $3, CS(%rsp) /* If coming from userspace, switch stacks */
831 /* returned flag: ebx=0: need swapgs on exit, ebx=1: don't need it */
835 TRACE_IRQS_OFF_DEBUG /* reload IDT in case of recursion */
841 movq %rsp, %rdi /* pt_regs pointer */
844 movq ORIG_RAX(%rsp), %rsi /* get error code */
845 movq $-1, ORIG_RAX(%rsp) /* no syscall to restart */
847 xorl %esi, %esi /* no error code */
851 subq $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
857 addq $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
860 /* these procedures expect "no swapgs" flag in ebx */
869 * Paranoid entry from userspace. Switch stacks and treat it
870 * as a normal entry. This means that paranoid handlers
871 * run in real process context if user_mode(regs).
877 movq %rsp, %rdi /* pt_regs pointer */
879 movq %rax, %rsp /* switch stack */
881 movq %rsp, %rdi /* pt_regs pointer */
884 movq ORIG_RAX(%rsp), %rsi /* get error code */
885 movq $-1, ORIG_RAX(%rsp) /* no syscall to restart */
887 xorl %esi, %esi /* no error code */
897 #ifdef CONFIG_TRACING
898 .macro trace_idtentry sym do_sym has_error_code:req
899 idtentry trace(\sym) trace(\do_sym) has_error_code=\has_error_code
900 idtentry \sym \do_sym has_error_code=\has_error_code
903 .macro trace_idtentry sym do_sym has_error_code:req
904 idtentry \sym \do_sym has_error_code=\has_error_code
908 idtentry divide_error do_divide_error has_error_code=0
909 idtentry overflow do_overflow has_error_code=0
910 idtentry bounds do_bounds has_error_code=0
911 idtentry invalid_op do_invalid_op has_error_code=0
912 idtentry device_not_available do_device_not_available has_error_code=0
913 idtentry double_fault do_double_fault has_error_code=1 paranoid=2
914 idtentry coprocessor_segment_overrun do_coprocessor_segment_overrun has_error_code=0
915 idtentry invalid_TSS do_invalid_TSS has_error_code=1
916 idtentry segment_not_present do_segment_not_present has_error_code=1
917 idtentry spurious_interrupt_bug do_spurious_interrupt_bug has_error_code=0
918 idtentry coprocessor_error do_coprocessor_error has_error_code=0
919 idtentry alignment_check do_alignment_check has_error_code=1
920 idtentry simd_coprocessor_error do_simd_coprocessor_error has_error_code=0
924 * Reload gs selector with exception handling
927 ENTRY(native_load_gs_index)
929 DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
933 2: mfence /* workaround */
937 END(native_load_gs_index)
939 _ASM_EXTABLE(gs_change, bad_gs)
940 .section .fixup, "ax"
941 /* running with kernelgs */
943 SWAPGS /* switch back to user gs */
949 /* Call softirq on interrupt stack. Interrupts are off. */
950 ENTRY(do_softirq_own_stack)
953 incl PER_CPU_VAR(irq_count)
954 cmove PER_CPU_VAR(irq_stack_ptr), %rsp
955 push %rbp /* frame pointer backlink */
958 decl PER_CPU_VAR(irq_count)
960 END(do_softirq_own_stack)
963 idtentry xen_hypervisor_callback xen_do_hypervisor_callback has_error_code=0
966 * A note on the "critical region" in our callback handler.
967 * We want to avoid stacking callback handlers due to events occurring
968 * during handling of the last event. To do this, we keep events disabled
969 * until we've done all processing. HOWEVER, we must enable events before
970 * popping the stack frame (can't be done atomically) and so it would still
971 * be possible to get enough handler activations to overflow the stack.
972 * Although unlikely, bugs of that kind are hard to track down, so we'd
973 * like to avoid the possibility.
974 * So, on entry to the handler we detect whether we interrupted an
975 * existing activation in its critical region -- if so, we pop the current
976 * activation and restart the handler using the previous one.
978 ENTRY(xen_do_hypervisor_callback) /* do_hypervisor_callback(struct *pt_regs) */
981 * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
982 * see the correct pointer to the pt_regs
984 movq %rdi, %rsp /* we don't return, adjust the stack frame */
985 11: incl PER_CPU_VAR(irq_count)
987 cmovzq PER_CPU_VAR(irq_stack_ptr), %rsp
988 pushq %rbp /* frame pointer backlink */
989 call xen_evtchn_do_upcall
991 decl PER_CPU_VAR(irq_count)
992 #ifndef CONFIG_PREEMPT
993 call xen_maybe_preempt_hcall
996 END(xen_do_hypervisor_callback)
999 * Hypervisor uses this for application faults while it executes.
1000 * We get here for two reasons:
1001 * 1. Fault while reloading DS, ES, FS or GS
1002 * 2. Fault while executing IRET
1003 * Category 1 we do not need to fix up as Xen has already reloaded all segment
1004 * registers that could be reloaded and zeroed the others.
1005 * Category 2 we fix up by killing the current process. We cannot use the
1006 * normal Linux return path in this case because if we use the IRET hypercall
1007 * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1008 * We distinguish between categories by comparing each saved segment register
1009 * with its current contents: any discrepancy means we in category 1.
1011 ENTRY(xen_failsafe_callback)
1013 cmpw %cx, 0x10(%rsp)
1016 cmpw %cx, 0x18(%rsp)
1019 cmpw %cx, 0x20(%rsp)
1022 cmpw %cx, 0x28(%rsp)
1024 /* All segments match their saved values => Category 2 (Bad IRET). */
1031 jmp general_protection
1032 1: /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1036 pushq $-1 /* orig_ax = -1 => not a system call */
1037 ALLOC_PT_GPREGS_ON_STACK
1041 END(xen_failsafe_callback)
1043 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1044 xen_hvm_callback_vector xen_evtchn_do_upcall
1046 #endif /* CONFIG_XEN */
1048 #if IS_ENABLED(CONFIG_HYPERV)
1049 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1050 hyperv_callback_vector hyperv_vector_handler
1051 #endif /* CONFIG_HYPERV */
1053 idtentry debug do_debug has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1054 idtentry int3 do_int3 has_error_code=0
1055 idtentry stack_segment do_stack_segment has_error_code=1
1058 idtentry xen_debug do_debug has_error_code=0
1059 idtentry xen_int3 do_int3 has_error_code=0
1060 idtentry xen_stack_segment do_stack_segment has_error_code=1
1063 idtentry general_protection do_general_protection has_error_code=1
1064 trace_idtentry page_fault do_page_fault has_error_code=1
1066 #ifdef CONFIG_KVM_GUEST
1067 idtentry async_page_fault do_async_page_fault has_error_code=1
1070 #ifdef CONFIG_X86_MCE
1071 idtentry machine_check do_mce has_error_code=0 paranoid=1
1075 * Save all registers in pt_regs, and switch gs if needed.
1076 * Use slow, but surefire "are we in kernel?" check.
1078 * Return: ebx=0: needs swapgs but not SWITCH_USER_CR3 in paranoid_exit
1079 * ebx=1: needs neither swapgs nor SWITCH_USER_CR3 in paranoid_exit
1080 * ebx=2: needs both swapgs and SWITCH_USER_CR3 in paranoid_exit
1081 * ebx=3: needs SWITCH_USER_CR3 but not swapgs in paranoid_exit
1083 ENTRY(paranoid_entry)
1088 movl $MSR_GS_BASE, %ecx
1091 js 1f /* negative -> in kernel */
1095 #ifdef CONFIG_PAGE_TABLE_ISOLATION
1097 * We might have come in between a swapgs and a SWITCH_KERNEL_CR3
1098 * on entry, or between a SWITCH_USER_CR3 and a swapgs on exit.
1099 * Do a conditional SWITCH_KERNEL_CR3: this could safely be done
1100 * unconditionally, but we need to find out whether the reverse
1101 * should be done on return (conveyed to paranoid_exit in %ebx).
1103 ALTERNATIVE "jmp 2f", "movq %cr3, %rax", X86_FEATURE_KAISER
1104 testl $KAISER_SHADOW_PGD_OFFSET, %eax
1107 andq $(~(X86_CR3_PCID_ASID_MASK | KAISER_SHADOW_PGD_OFFSET)), %rax
1108 /* If PCID enabled, set X86_CR3_PCID_NOFLUSH_BIT */
1109 ALTERNATIVE "", "bts $63, %rax", X86_FEATURE_PCID
1117 * "Paranoid" exit path from exception stack. This is invoked
1118 * only on return from non-NMI IST interrupts that came
1119 * from kernel space.
1121 * We may be returning to very strange contexts (e.g. very early
1122 * in syscall entry), so checking for preemption here would
1123 * be complicated. Fortunately, we there's no good reason
1124 * to try to handle preemption here.
1126 * On entry: ebx=0: needs swapgs but not SWITCH_USER_CR3
1127 * ebx=1: needs neither swapgs nor SWITCH_USER_CR3
1128 * ebx=2: needs both swapgs and SWITCH_USER_CR3
1129 * ebx=3: needs SWITCH_USER_CR3 but not swapgs
1131 ENTRY(paranoid_exit)
1132 DISABLE_INTERRUPTS(CLBR_NONE)
1133 TRACE_IRQS_OFF_DEBUG
1134 TRACE_IRQS_IRETQ_DEBUG
1135 #ifdef CONFIG_PAGE_TABLE_ISOLATION
1136 /* No ALTERNATIVE for X86_FEATURE_KAISER: paranoid_entry sets %ebx */
1137 testl $2, %ebx /* SWITCH_USER_CR3 needed? */
1138 jz paranoid_exit_no_switch
1140 paranoid_exit_no_switch:
1142 testl $1, %ebx /* swapgs needed? */
1143 jnz paranoid_exit_no_swapgs
1145 paranoid_exit_no_swapgs:
1148 REMOVE_PT_GPREGS_FROM_STACK 8
1153 * Save all registers in pt_regs, and switch gs if needed.
1160 * error_entry() always returns with a kernel gsbase and
1161 * CR3. We must also have a kernel CR3/gsbase before
1162 * calling TRACE_IRQS_*. Just unconditionally switch to
1163 * the kernel CR3 here.
1166 testb $3, CS+8(%rsp)
1167 jz .Lerror_kernelspace
1169 .Lerror_entry_from_usermode_swapgs:
1171 * We entered from user mode or we're pretending to have entered
1172 * from user mode due to an IRET fault.
1176 .Lerror_entry_from_usermode_after_swapgs:
1178 * We need to tell lockdep that IRQs are off. We can't do this until
1179 * we fix gsbase, and we should do it before enter_from_user_mode
1180 * (which can take locks).
1183 #ifdef CONFIG_CONTEXT_TRACKING
1184 call enter_from_user_mode
1193 * There are two places in the kernel that can potentially fault with
1194 * usergs. Handle them here. B stepping K8s sometimes report a
1195 * truncated RIP for IRET exceptions returning to compat mode. Check
1196 * for these here too.
1198 .Lerror_kernelspace:
1199 leaq native_irq_return_iret(%rip), %rcx
1200 cmpq %rcx, RIP+8(%rsp)
1202 movl %ecx, %eax /* zero extend */
1203 cmpq %rax, RIP+8(%rsp)
1205 cmpq $gs_change, RIP+8(%rsp)
1206 jne .Lerror_entry_done
1209 * hack: gs_change can fail with user gsbase. If this happens, fix up
1210 * gsbase and proceed. We'll fix up the exception and land in
1211 * gs_change's error handler with kernel gsbase.
1213 jmp .Lerror_entry_from_usermode_swapgs
1216 /* Fix truncated RIP */
1217 movq %rcx, RIP+8(%rsp)
1222 * We came from an IRET to user mode, so we have user gsbase.
1223 * Switch to kernel gsbase:
1228 * Pretend that the exception came from user mode: set up pt_regs
1229 * as if we faulted immediately after IRET.
1234 jmp .Lerror_entry_from_usermode_after_swapgs
1238 DISABLE_INTERRUPTS(CLBR_NONE)
1245 /* Runs on exception stack */
1248 * Fix up the exception frame if we're on Xen.
1249 * PARAVIRT_ADJUST_EXCEPTION_FRAME is guaranteed to push at most
1250 * one value to the stack on native, so it may clobber the rdx
1251 * scratch slot, but it won't clobber any of the important
1254 * Xen is a different story, because the Xen frame itself overlaps
1255 * the "NMI executing" variable.
1257 PARAVIRT_ADJUST_EXCEPTION_FRAME
1260 * We allow breakpoints in NMIs. If a breakpoint occurs, then
1261 * the iretq it performs will take us out of NMI context.
1262 * This means that we can have nested NMIs where the next
1263 * NMI is using the top of the stack of the previous NMI. We
1264 * can't let it execute because the nested NMI will corrupt the
1265 * stack of the previous NMI. NMI handlers are not re-entrant
1268 * To handle this case we do the following:
1269 * Check the a special location on the stack that contains
1270 * a variable that is set when NMIs are executing.
1271 * The interrupted task's stack is also checked to see if it
1273 * If the variable is not set and the stack is not the NMI
1275 * o Set the special variable on the stack
1276 * o Copy the interrupt frame into an "outermost" location on the
1278 * o Copy the interrupt frame into an "iret" location on the stack
1279 * o Continue processing the NMI
1280 * If the variable is set or the previous stack is the NMI stack:
1281 * o Modify the "iret" location to jump to the repeat_nmi
1282 * o return back to the first NMI
1284 * Now on exit of the first NMI, we first clear the stack variable
1285 * The NMI stack will tell any nested NMIs at that point that it is
1286 * nested. Then we pop the stack normally with iret, and if there was
1287 * a nested NMI that updated the copy interrupt stack frame, a
1288 * jump will be made to the repeat_nmi code that will handle the second
1291 * However, espfix prevents us from directly returning to userspace
1292 * with a single IRET instruction. Similarly, IRET to user mode
1293 * can fault. We therefore handle NMIs from user space like
1294 * other IST entries.
1299 /* Use %rdx as our temp variable throughout */
1302 testb $3, CS-RIP+8(%rsp)
1303 jz .Lnmi_from_kernel
1306 * NMI from user mode. We need to run on the thread stack, but we
1307 * can't go through the normal entry paths: NMIs are masked, and
1308 * we don't want to enable interrupts, because then we'll end
1309 * up in an awkward situation in which IRQs are on but NMIs
1312 * We also must not push anything to the stack before switching
1313 * stacks lest we corrupt the "NMI executing" variable.
1318 * percpu variables are mapped with user CR3, so no need
1319 * to switch CR3 here.
1323 movq PER_CPU_VAR(cpu_current_top_of_stack), %rsp
1324 pushq 5*8(%rdx) /* pt_regs->ss */
1325 pushq 4*8(%rdx) /* pt_regs->rsp */
1326 pushq 3*8(%rdx) /* pt_regs->flags */
1327 pushq 2*8(%rdx) /* pt_regs->cs */
1328 pushq 1*8(%rdx) /* pt_regs->rip */
1329 pushq $-1 /* pt_regs->orig_ax */
1330 pushq %rdi /* pt_regs->di */
1331 pushq %rsi /* pt_regs->si */
1332 pushq (%rdx) /* pt_regs->dx */
1333 pushq %rcx /* pt_regs->cx */
1334 pushq %rax /* pt_regs->ax */
1335 pushq %r8 /* pt_regs->r8 */
1336 pushq %r9 /* pt_regs->r9 */
1337 pushq %r10 /* pt_regs->r10 */
1338 pushq %r11 /* pt_regs->r11 */
1339 pushq %rbx /* pt_regs->rbx */
1340 pushq %rbp /* pt_regs->rbp */
1341 pushq %r12 /* pt_regs->r12 */
1342 pushq %r13 /* pt_regs->r13 */
1343 pushq %r14 /* pt_regs->r14 */
1344 pushq %r15 /* pt_regs->r15 */
1347 * At this point we no longer need to worry about stack damage
1348 * due to nesting -- we're on the normal thread stack and we're
1349 * done with the NMI stack.
1354 #ifdef CONFIG_PAGE_TABLE_ISOLATION
1355 /* Unconditionally use kernel CR3 for do_nmi() */
1356 /* %rax is saved above, so OK to clobber here */
1357 ALTERNATIVE "jmp 2f", "movq %cr3, %rax", X86_FEATURE_KAISER
1358 /* If PCID enabled, NOFLUSH now and NOFLUSH on return */
1359 ALTERNATIVE "", "bts $63, %rax", X86_FEATURE_PCID
1361 /* mask off "user" bit of pgd address and 12 PCID bits: */
1362 andq $(~(X86_CR3_PCID_ASID_MASK | KAISER_SHADOW_PGD_OFFSET)), %rax
1368 #ifdef CONFIG_PAGE_TABLE_ISOLATION
1370 * Unconditionally restore CR3. I know we return to
1371 * kernel code that needs user CR3, but do we ever return
1372 * to "user mode" where we need the kernel CR3?
1374 ALTERNATIVE "", "popq %rax; movq %rax, %cr3", X86_FEATURE_KAISER
1378 * Return back to user mode. We must *not* do the normal exit
1379 * work, because we don't want to enable interrupts. Do not
1380 * switch to user CR3: we might be going back to kernel code
1381 * that had a user CR3 set.
1384 jmp restore_c_regs_and_iret
1388 * Here's what our stack frame will look like:
1389 * +---------------------------------------------------------+
1391 * | original Return RSP |
1392 * | original RFLAGS |
1395 * +---------------------------------------------------------+
1396 * | temp storage for rdx |
1397 * +---------------------------------------------------------+
1398 * | "NMI executing" variable |
1399 * +---------------------------------------------------------+
1400 * | iret SS } Copied from "outermost" frame |
1401 * | iret Return RSP } on each loop iteration; overwritten |
1402 * | iret RFLAGS } by a nested NMI to force another |
1403 * | iret CS } iteration if needed. |
1405 * +---------------------------------------------------------+
1406 * | outermost SS } initialized in first_nmi; |
1407 * | outermost Return RSP } will not be changed before |
1408 * | outermost RFLAGS } NMI processing is done. |
1409 * | outermost CS } Copied to "iret" frame on each |
1410 * | outermost RIP } iteration. |
1411 * +---------------------------------------------------------+
1413 * +---------------------------------------------------------+
1415 * The "original" frame is used by hardware. Before re-enabling
1416 * NMIs, we need to be done with it, and we need to leave enough
1417 * space for the asm code here.
1419 * We return by executing IRET while RSP points to the "iret" frame.
1420 * That will either return for real or it will loop back into NMI
1423 * The "outermost" frame is copied to the "iret" frame on each
1424 * iteration of the loop, so each iteration starts with the "iret"
1425 * frame pointing to the final return target.
1429 * Determine whether we're a nested NMI.
1431 * If we interrupted kernel code between repeat_nmi and
1432 * end_repeat_nmi, then we are a nested NMI. We must not
1433 * modify the "iret" frame because it's being written by
1434 * the outer NMI. That's okay; the outer NMI handler is
1435 * about to about to call do_nmi anyway, so we can just
1436 * resume the outer NMI.
1439 movq $repeat_nmi, %rdx
1442 movq $end_repeat_nmi, %rdx
1448 * Now check "NMI executing". If it's set, then we're nested.
1449 * This will not detect if we interrupted an outer NMI just
1456 * Now test if the previous stack was an NMI stack. This covers
1457 * the case where we interrupt an outer NMI after it clears
1458 * "NMI executing" but before IRET. We need to be careful, though:
1459 * there is one case in which RSP could point to the NMI stack
1460 * despite there being no NMI active: naughty userspace controls
1461 * RSP at the very beginning of the SYSCALL targets. We can
1462 * pull a fast one on naughty userspace, though: we program
1463 * SYSCALL to mask DF, so userspace cannot cause DF to be set
1464 * if it controls the kernel's RSP. We set DF before we clear
1468 /* Compare the NMI stack (rdx) with the stack we came from (4*8(%rsp)) */
1469 cmpq %rdx, 4*8(%rsp)
1470 /* If the stack pointer is above the NMI stack, this is a normal NMI */
1473 subq $EXCEPTION_STKSZ, %rdx
1474 cmpq %rdx, 4*8(%rsp)
1475 /* If it is below the NMI stack, it is a normal NMI */
1478 /* Ah, it is within the NMI stack. */
1480 testb $(X86_EFLAGS_DF >> 8), (3*8 + 1)(%rsp)
1481 jz first_nmi /* RSP was user controlled. */
1483 /* This is a nested NMI. */
1487 * Modify the "iret" frame to point to repeat_nmi, forcing another
1488 * iteration of NMI handling.
1491 leaq -10*8(%rsp), %rdx
1498 /* Put stack back */
1504 /* We are returning to kernel mode, so this cannot result in a fault. */
1511 /* Make room for "NMI executing". */
1514 /* Leave room for the "iret" frame */
1517 /* Copy the "original" frame to the "outermost" frame */
1522 /* Everything up to here is safe from nested NMIs */
1524 #ifdef CONFIG_DEBUG_ENTRY
1526 * For ease of testing, unmask NMIs right away. Disabled by
1527 * default because IRET is very expensive.
1530 pushq %rsp /* RSP (minus 8 because of the previous push) */
1531 addq $8, (%rsp) /* Fix up RSP */
1533 pushq $__KERNEL_CS /* CS */
1535 INTERRUPT_RETURN /* continues at repeat_nmi below */
1541 * If there was a nested NMI, the first NMI's iret will return
1542 * here. But NMIs are still enabled and we can take another
1543 * nested NMI. The nested NMI checks the interrupted RIP to see
1544 * if it is between repeat_nmi and end_repeat_nmi, and if so
1545 * it will just return, as we are about to repeat an NMI anyway.
1546 * This makes it safe to copy to the stack frame that a nested
1549 * RSP is pointing to "outermost RIP". gsbase is unknown, but, if
1550 * we're repeating an NMI, gsbase has the same value that it had on
1551 * the first iteration. paranoid_entry will load the kernel
1552 * gsbase if needed before we call do_nmi. "NMI executing"
1555 movq $1, 10*8(%rsp) /* Set "NMI executing". */
1558 * Copy the "outermost" frame to the "iret" frame. NMIs that nest
1559 * here must not modify the "iret" frame while we're writing to
1560 * it or it will end up containing garbage.
1570 * Everything below this point can be preempted by a nested NMI.
1571 * If this happens, then the inner NMI will change the "iret"
1572 * frame to point back to repeat_nmi.
1574 pushq $-1 /* ORIG_RAX: no syscall to restart */
1575 ALLOC_PT_GPREGS_ON_STACK
1578 * Use the same approach as paranoid_entry to handle SWAPGS, but
1579 * without CR3 handling since we do that differently in NMIs. No
1580 * need to use paranoid_exit as we should not be calling schedule
1581 * in NMI context. Even with normal interrupts enabled. An NMI
1582 * should not be setting NEED_RESCHED or anything that normal
1583 * interrupts and exceptions might do.
1589 movl $MSR_GS_BASE, %ecx
1592 js 1f /* negative -> in kernel */
1598 #ifdef CONFIG_PAGE_TABLE_ISOLATION
1599 /* Unconditionally use kernel CR3 for do_nmi() */
1600 /* %rax is saved above, so OK to clobber here */
1601 ALTERNATIVE "jmp 2f", "movq %cr3, %rax", X86_FEATURE_KAISER
1602 /* If PCID enabled, NOFLUSH now and NOFLUSH on return */
1603 ALTERNATIVE "", "bts $63, %rax", X86_FEATURE_PCID
1605 /* mask off "user" bit of pgd address and 12 PCID bits: */
1606 andq $(~(X86_CR3_PCID_ASID_MASK | KAISER_SHADOW_PGD_OFFSET)), %rax
1611 /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1614 #ifdef CONFIG_PAGE_TABLE_ISOLATION
1616 * Unconditionally restore CR3. We might be returning to
1617 * kernel code that needs user CR3, like just just before
1620 ALTERNATIVE "", "popq %rax; movq %rax, %cr3", X86_FEATURE_KAISER
1623 testl %ebx, %ebx /* swapgs needed? */
1626 /* We fixed up CR3 above, so no need to switch it here */
1632 /* Point RSP at the "iret" frame. */
1633 REMOVE_PT_GPREGS_FROM_STACK 6*8
1636 * Clear "NMI executing". Set DF first so that we can easily
1637 * distinguish the remaining code between here and IRET from
1638 * the SYSCALL entry and exit paths. On a native kernel, we
1639 * could just inspect RIP, but, on paravirt kernels,
1640 * INTERRUPT_RETURN can translate into a jump into a
1644 movq $0, 5*8(%rsp) /* clear "NMI executing" */
1647 * INTERRUPT_RETURN reads the "iret" frame and exits the NMI
1648 * stack in a single instruction. We are returning to kernel
1649 * mode, so this cannot result in a fault.
1654 ENTRY(ignore_sysret)