cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckCCompilerFlag)
  11
  12 include(CheckCompilerVersion)
  13 include(HandleLLVMStdlib)
  14
  15 if( UNIX AND NOT (BEOS OR HAIKU) )
  16   # Used by check_symbol_exists:
  17   list(APPEND CMAKE_REQUIRED_LIBRARIES "m")
  18 endif()
  19 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  20 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  21     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  22   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  23 endif()
  24
  25 # include checks
  26 check_include_file(dlfcn.h HAVE_DLFCN_H)
  27 check_include_file(errno.h HAVE_ERRNO_H)
  28 check_include_file(fcntl.h HAVE_FCNTL_H)
  29 check_include_file(link.h HAVE_LINK_H)
  30 check_include_file(malloc.h HAVE_MALLOC_H)
  31 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  32 if( NOT PURE_WINDOWS )
  33   check_include_file(pthread.h HAVE_PTHREAD_H)
  34 endif()
  35 check_include_file(signal.h HAVE_SIGNAL_H)
  36 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  37 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  38 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  39 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  40 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  41 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  42 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  43 check_include_file(termios.h HAVE_TERMIOS_H)
  44 check_include_file(unistd.h HAVE_UNISTD_H)
  45 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  46 check_include_file(zlib.h HAVE_ZLIB_H)
  47 check_include_file(fenv.h HAVE_FENV_H)
  48 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  49 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  50
  51 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  52 check_include_file(histedit.h HAVE_HISTEDIT_H)
  53 check_include_file(CrashReporterClient.h HAVE_CRASHREPORTERCLIENT_H)
  54 if(APPLE)
  55   include(CheckCSourceCompiles)
  56   CHECK_C_SOURCE_COMPILES("
  57      static const char *__crashreporter_info__ = 0;
  58      asm(\".desc ___crashreporter_info__, 0x10\");
  59      int main() { return 0; }"
  60     HAVE_CRASHREPORTER_INFO)
  61 endif()
  62
  63 if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  64   check_include_file(linux/magic.h HAVE_LINUX_MAGIC_H)
  65   if(NOT HAVE_LINUX_MAGIC_H)
  66     # older kernels use split files
  67     check_include_file(linux/nfs_fs.h HAVE_LINUX_NFS_FS_H)
  68     check_include_file(linux/smb.h HAVE_LINUX_SMB_H)
  69   endif()
  70 endif()
  71
  72 # library checks
  73 if( NOT PURE_WINDOWS )
  74   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  75   if (HAVE_LIBPTHREAD)
  76     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  77     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  78     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  79   else()
  80     # this could be Android
  81     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  82     if (PTHREAD_IN_LIBC)
  83       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  84       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  85       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  86     endif()
  87   endif()
  88   check_library_exists(dl dlopen "" HAVE_LIBDL)
  89   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
  90 endif()
  91
  92 # Check for libpfm.
  93 include(FindLibpfm)
  94
  95 if(HAVE_LIBPTHREAD)
  96   # We want to find pthreads library and at the moment we do want to
  97   # have it reported as '-l<lib>' instead of '-pthread'.
  98   # TODO: switch to -pthread once the rest of the build system can deal with it.
  99   set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 100   set(THREADS_HAVE_PTHREAD_ARG Off)
 101   find_package(Threads REQUIRED)
 102   set(LLVM_PTHREAD_LIB ${CMAKE_THREAD_LIBS_INIT})
 103 endif()
 104
 105 # Don't look for these libraries if we're using MSan, since uninstrumented third
 106 # party code may call MSan interceptors like strlen, leading to false positives.
 107 if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 108   set(HAVE_LIBZ 0)
 109   if(LLVM_ENABLE_ZLIB)
 110     foreach(library z zlib_static zlib)
 111       string(TOUPPER ${library} library_suffix)
 112       check_library_exists(${library} compress2 "" HAVE_LIBZ_${library_suffix})
 113       if(HAVE_LIBZ_${library_suffix})
 114         set(HAVE_LIBZ 1)
 115         set(ZLIB_LIBRARIES "${library}")
 116         break()
 117       endif()
 118     endforeach()
 119   endif()
 120
 121   # Don't look for these libraries on Windows.
 122   if (NOT PURE_WINDOWS)
 123     # Skip libedit if using ASan as it contains memory leaks.
 124     if (LLVM_ENABLE_LIBEDIT AND HAVE_HISTEDIT_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*")
 125       check_library_exists(edit el_init "" HAVE_LIBEDIT)
 126     else()
 127       set(HAVE_LIBEDIT 0)
 128     endif()
 129     if(LLVM_ENABLE_TERMINFO)
 130       set(HAVE_TERMINFO 0)
 131       foreach(library tinfo terminfo curses ncurses ncursesw)
 132         string(TOUPPER ${library} library_suffix)
 133         check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 134         if(HAVE_TERMINFO_${library_suffix})
 135           set(HAVE_TERMINFO 1)
 136           set(TERMINFO_LIBS "${library}")
 137           break()
 138         endif()
 139       endforeach()
 140     else()
 141       set(HAVE_TERMINFO 0)
 142     endif()
 143
 144     find_library(ICONV_LIBRARY_PATH NAMES iconv libiconv libiconv-2 c)
 145     set(LLVM_LIBXML2_ENABLED 0)
 146     set(LIBXML2_FOUND 0)
 147     if((LLVM_ENABLE_LIBXML2) AND ((CMAKE_SYSTEM_NAME MATCHES "Linux") AND (ICONV_LIBRARY_PATH) OR APPLE))
 148       find_package(LibXml2)
 149       if (LIBXML2_FOUND)
 150         set(LLVM_LIBXML2_ENABLED 1)
 151         include_directories(${LIBXML2_INCLUDE_DIR})
 152         set(LIBXML2_LIBS "xml2")
 153       endif()
 154     endif()
 155   endif()
 156 endif()
 157
 158 if (LLVM_ENABLE_LIBXML2 STREQUAL "FORCE_ON" AND NOT LLVM_LIBXML2_ENABLED)
 159   message(FATAL_ERROR "Failed to congifure libxml2")
 160 endif()
 161
 162 check_library_exists(xar xar_open "" HAVE_LIBXAR)
 163 if(HAVE_LIBXAR)
 164   set(XAR_LIB xar)
 165 endif()
 166
 167 # function checks
 168 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 169 find_package(Backtrace)
 170 set(HAVE_BACKTRACE ${Backtrace_FOUND})
 171 set(BACKTRACE_HEADER ${Backtrace_HEADER})
 172
 173 # Prevent check_symbol_exists from using API that is not supported for a given
 174 # deployment target.
 175 check_c_compiler_flag("-Werror=unguarded-availability-new" "C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW")
 176 if(C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW)
 177   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror=unguarded-availability-new")
 178 endif()
 179
 180 check_symbol_exists(_Unwind_Backtrace "unwind.h" HAVE__UNWIND_BACKTRACE)
 181 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 182 check_symbol_exists(sysconf unistd.h HAVE_SYSCONF)
 183 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 184 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 185 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 186 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 187 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 188 check_symbol_exists(posix_fallocate fcntl.h HAVE_POSIX_FALLOCATE)
 189 # AddressSanitizer conflicts with lib/Support/Unix/Signals.inc
 190 # Avoid sigaltstack on Apple platforms, where backtrace() cannot handle it
 191 # (rdar://7089625) and _Unwind_Backtrace is unusable because it cannot unwind
 192 # past the signal handler after an assertion failure (rdar://29866587).
 193 if( HAVE_SIGNAL_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*" AND NOT APPLE )
 194   check_symbol_exists(sigaltstack signal.h HAVE_SIGALTSTACK)
 195 endif()
 196 set(CMAKE_REQUIRED_DEFINITIONS "-D_LARGEFILE64_SOURCE")
 197 check_symbol_exists(lseek64 "sys/types.h;unistd.h" HAVE_LSEEK64)
 198 set(CMAKE_REQUIRED_DEFINITIONS "")
 199 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
 200 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 201 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 202                     HAVE_MALLOC_ZONE_STATISTICS)
 203 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 204 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 205 check_symbol_exists(pread unistd.h HAVE_PREAD)
 206 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 207 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 208 check_symbol_exists(strerror string.h HAVE_STRERROR)
 209 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 210 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 211 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 212 if( PURE_WINDOWS )
 213   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 214
 215   check_function_exists(_alloca HAVE__ALLOCA)
 216   check_function_exists(__alloca HAVE___ALLOCA)
 217   check_function_exists(__chkstk HAVE___CHKSTK)
 218   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
 219   check_function_exists(___chkstk HAVE____CHKSTK)
 220   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
 221
 222   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 223   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 224   check_function_exists(__divdi3 HAVE___DIVDI3)
 225   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 226   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 227   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 228   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 229   check_function_exists(__moddi3 HAVE___MODDI3)
 230   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 231   check_function_exists(__umoddi3 HAVE___UMODDI3)
 232
 233   check_function_exists(__main HAVE___MAIN)
 234   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 235 endif()
 236 if( HAVE_DLFCN_H )
 237   if( HAVE_LIBDL )
 238     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 239   endif()
 240   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 241   check_symbol_exists(dladdr dlfcn.h HAVE_DLADDR)
 242   if( HAVE_LIBDL )
 243     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 244   endif()
 245 endif()
 246
 247 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 248 if( LLVM_USING_GLIBC )
 249   add_definitions( -D_GNU_SOURCE )
 250   list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
 251 endif()
 252 # This check requires _GNU_SOURCE
 253 check_symbol_exists(sched_getaffinity sched.h HAVE_SCHED_GETAFFINITY)
 254 check_symbol_exists(CPU_COUNT sched.h HAVE_CPU_COUNT)
 255 if (NOT PURE_WINDOWS)
 256   if (LLVM_PTHREAD_LIB)
 257     list(APPEND CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 258   endif()
 259   check_symbol_exists(pthread_getname_np pthread.h HAVE_PTHREAD_GETNAME_NP)
 260   check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 261   if (LLVM_PTHREAD_LIB)
 262     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 263   endif()
 264 endif()
 265
 266 # available programs checks
 267 function(llvm_find_program name)
 268   string(TOUPPER ${name} NAME)
 269   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 270
 271   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 272   mark_as_advanced(LLVM_PATH_${NAME})
 273   if(LLVM_PATH_${NAME})
 274     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 275     mark_as_advanced(HAVE_${NAME})
 276   else(LLVM_PATH_${NAME})
 277     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 278   endif(LLVM_PATH_${NAME})
 279 endfunction()
 280
 281 if (LLVM_ENABLE_DOXYGEN)
 282   llvm_find_program(dot)
 283 endif ()
 284
 285 if( LLVM_ENABLE_FFI )
 286   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 287   if( EXISTS "${FFI_INCLUDE_PATH}/ffi.h" )
 288     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 289     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 290   else()
 291     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 292     if( EXISTS "${FFI_INCLUDE_PATH}/ffi/ffi.h" )
 293       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 294       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 295     endif()
 296   endif()
 297
 298   if( NOT FFI_HEADER )
 299     message(FATAL_ERROR "libffi includes are not found.")
 300   endif()
 301
 302   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 303   if( NOT FFI_LIBRARY_PATH )
 304     message(FATAL_ERROR "libffi is not found.")
 305   endif()
 306
 307   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 308   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 309   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 310   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 311   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 312 else()
 313   unset(HAVE_FFI_FFI_H CACHE)
 314   unset(HAVE_FFI_H CACHE)
 315   unset(HAVE_FFI_CALL CACHE)
 316 endif( LLVM_ENABLE_FFI )
 317
 318 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 319 include(CheckAtomic)
 320
 321 if( LLVM_ENABLE_PIC )
 322   set(ENABLE_PIC 1)
 323 else()
 324   set(ENABLE_PIC 0)
 325   check_cxx_compiler_flag("-fno-pie" SUPPORTS_NO_PIE_FLAG)
 326   if(SUPPORTS_NO_PIE_FLAG)
 327     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fno-pie")
 328   endif()
 329 endif()
 330
 331 check_cxx_compiler_flag("-Wvariadic-macros" SUPPORTS_VARIADIC_MACROS_FLAG)
 332 check_cxx_compiler_flag("-Wgnu-zero-variadic-macro-arguments"
 333                         SUPPORTS_GNU_ZERO_VARIADIC_MACRO_ARGUMENTS_FLAG)
 334
 335 set(USE_NO_MAYBE_UNINITIALIZED 0)
 336 set(USE_NO_UNINITIALIZED 0)
 337
 338 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 339 # false positives.
 340 if (CMAKE_COMPILER_IS_GNUCXX)
 341   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 342   if (HAS_MAYBE_UNINITIALIZED)
 343     set(USE_NO_MAYBE_UNINITIALIZED 1)
 344   else()
 345     # Only recent versions of gcc make the distinction between -Wuninitialized
 346     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 347     # turn off all uninitialized use warnings.
 348     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 349     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 350   endif()
 351 endif()
 352
 353 # By default, we target the host, but this can be overridden at CMake
 354 # invocation time.
 355 include(GetHostTriple)
 356 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 357
 358 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 359     "Host on which LLVM binaries will run")
 360
 361 # Determine the native architecture.
 362 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 363 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 364   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 365 endif ()
 366
 367 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 368   set(LLVM_NATIVE_ARCH X86)
 369 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 370   set(LLVM_NATIVE_ARCH X86)
 371 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 372   set(LLVM_NATIVE_ARCH X86)
 373 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 374   set(LLVM_NATIVE_ARCH X86)
 375 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 376   set(LLVM_NATIVE_ARCH Sparc)
 377 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 378   set(LLVM_NATIVE_ARCH PowerPC)
 379 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 380   set(LLVM_NATIVE_ARCH AArch64)
 381 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 382   set(LLVM_NATIVE_ARCH AArch64)
 383 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 384   set(LLVM_NATIVE_ARCH ARM)
 385 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 386   set(LLVM_NATIVE_ARCH Mips)
 387 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 388   set(LLVM_NATIVE_ARCH XCore)
 389 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 390   set(LLVM_NATIVE_ARCH MSP430)
 391 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 392   set(LLVM_NATIVE_ARCH Hexagon)
 393 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 394   set(LLVM_NATIVE_ARCH SystemZ)
 395 elseif (LLVM_NATIVE_ARCH MATCHES "wasm32")
 396   set(LLVM_NATIVE_ARCH WebAssembly)
 397 elseif (LLVM_NATIVE_ARCH MATCHES "wasm64")
 398   set(LLVM_NATIVE_ARCH WebAssembly)
 399 elseif (LLVM_NATIVE_ARCH MATCHES "riscv32")
 400   set(LLVM_NATIVE_ARCH RISCV)
 401 elseif (LLVM_NATIVE_ARCH MATCHES "riscv64")
 402   set(LLVM_NATIVE_ARCH RISCV)
 403 else ()
 404   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 405 endif ()
 406
 407 # If build targets includes "host", then replace with native architecture.
 408 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 409 if( NOT idx LESS 0 )
 410   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 411   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 412   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 413 endif()
 414
 415 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 416 if (NATIVE_ARCH_IDX EQUAL -1)
 417   message(STATUS
 418     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 419 else ()
 420   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 421   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 422   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 423   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 424   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 425
 426   # We don't have an ASM parser for all architectures yet.
 427   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 428     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 429   endif ()
 430
 431   # We don't have an disassembler for all architectures yet.
 432   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 433     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 434   endif ()
 435 endif ()
 436
 437 if( MSVC )
 438   set(SHLIBEXT ".lib")
 439   set(stricmp "_stricmp")
 440   set(strdup "_strdup")
 441
 442   # See if the DIA SDK is available and usable.
 443   set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK")
 444
 445   # Due to a bug in MSVC 2013's installation software, it is possible
 446   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
 447   # install directory.  If this happens, the installation is corrupt
 448   # and there's nothing we can do.  It happens with enough frequency
 449   # though that we should handle it.  We do so by simply checking that
 450   # the DIA SDK folder exists.  Should this happen you will need to
 451   # uninstall VS 2012 and then re-install VS 2013.
 452   if (IS_DIRECTORY ${MSVC_DIA_SDK_DIR})
 453     set(HAVE_DIA_SDK 1)
 454   else()
 455     set(HAVE_DIA_SDK 0)
 456   endif()
 457
 458   option(LLVM_ENABLE_DIA_SDK "Use MSVC DIA SDK for debugging if available."
 459                              ${HAVE_DIA_SDK})
 460
 461   if(LLVM_ENABLE_DIA_SDK AND NOT HAVE_DIA_SDK)
 462     message(FATAL_ERROR "DIA SDK not found. If you have both VS 2012 and 2013 installed, you may need to uninstall the former and re-install the latter afterwards.")
 463   endif()
 464 else()
 465   set(LLVM_ENABLE_DIA_SDK 0)
 466 endif( MSVC )
 467
 468 # FIXME: Signal handler return type, currently hardcoded to 'void'
 469 set(RETSIGTYPE void)
 470
 471 if( LLVM_ENABLE_THREADS )
 472   # Check if threading primitives aren't supported on this platform
 473   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 474     set(LLVM_ENABLE_THREADS 0)
 475   endif()
 476 endif()
 477
 478 if( LLVM_ENABLE_THREADS )
 479   message(STATUS "Threads enabled.")
 480 else( LLVM_ENABLE_THREADS )
 481   message(STATUS "Threads disabled.")
 482 endif()
 483
 484 if (LLVM_ENABLE_ZLIB )
 485   # Check if zlib is available in the system.
 486   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 487     set(LLVM_ENABLE_ZLIB 0)
 488   endif()
 489 endif()
 490
 491 if (LLVM_ENABLE_DOXYGEN)
 492   message(STATUS "Doxygen enabled.")
 493   find_package(Doxygen REQUIRED)
 494
 495   if (DOXYGEN_FOUND)
 496     # If we find doxygen and we want to enable doxygen by default create a
 497     # global aggregate doxygen target for generating llvm and any/all
 498     # subprojects doxygen documentation.
 499     if (LLVM_BUILD_DOCS)
 500       add_custom_target(doxygen ALL)
 501     endif()
 502
 503     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 504     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 505       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external search.")
 506       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 507     endif()
 508   endif()
 509 else()
 510   message(STATUS "Doxygen disabled.")
 511 endif()
 512
 513 set(LLVM_BINDINGS "")
 514 find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 515 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 516   message(STATUS "Go bindings disabled.")
 517 else()
 518   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 519     message(STATUS "Go bindings disabled.")
 520   else()
 521     execute_process(COMMAND ${GO_EXECUTABLE} run ${PROJECT_SOURCE_DIR}/bindings/go/conftest.go
 522                     RESULT_VARIABLE GO_CONFTEST)
 523     if(GO_CONFTEST STREQUAL "0")
 524       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 525       message(STATUS "Go bindings enabled.")
 526     else()
 527       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 528     endif()
 529   endif()
 530 endif()
 531
 532 find_program(GOLD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.gold ld.gold ${LLVM_DEFAULT_TARGET_TRIPLE}-ld ld DOC "The gold linker")
 533 set(LLVM_BINUTILS_INCDIR "" CACHE PATH
 534         "PATH to binutils/include containing plugin-api.h for gold plugin.")
 535
 536 if(CMAKE_HOST_APPLE AND APPLE)
 537   if(NOT CMAKE_XCRUN)
 538     find_program(CMAKE_XCRUN NAMES xcrun)
 539   endif()
 540   if(CMAKE_XCRUN)
 541     execute_process(COMMAND ${CMAKE_XCRUN} -find ld
 542       OUTPUT_VARIABLE LD64_EXECUTABLE
 543       OUTPUT_STRIP_TRAILING_WHITESPACE)
 544   else()
 545     find_program(LD64_EXECUTABLE NAMES ld DOC "The ld64 linker")
 546   endif()
 547
 548   if(LD64_EXECUTABLE)
 549     set(LD64_EXECUTABLE ${LD64_EXECUTABLE} CACHE PATH "ld64 executable")
 550     message(STATUS "Found ld64 - ${LD64_EXECUTABLE}")
 551   endif()
 552 endif()
 553
 554 # Keep the version requirements in sync with bindings/ocaml/README.txt.
 555 include(FindOCaml)
 556 include(AddOCaml)
 557 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 558   message(STATUS "OCaml bindings disabled.")
 559 else()
 560   find_package(OCaml)
 561   if( NOT OCAML_FOUND )
 562     message(STATUS "OCaml bindings disabled.")
 563   else()
 564     if( OCAML_VERSION VERSION_LESS "4.00.0" )
 565       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
 566     else()
 567       find_ocamlfind_package(ctypes VERSION 0.4 OPTIONAL)
 568       if( HAVE_OCAML_CTYPES )
 569         message(STATUS "OCaml bindings enabled.")
 570         find_ocamlfind_package(oUnit VERSION 2 OPTIONAL)
 571         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
 572
 573         set(LLVM_OCAML_INSTALL_PATH "${OCAML_STDLIB_PATH}" CACHE STRING
 574             "Install directory for LLVM OCaml packages")
 575       else()
 576         message(STATUS "OCaml bindings disabled, need ctypes >=0.4.")
 577       endif()
 578     endif()
 579   endif()
 580 endif()
 581
 582 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")
 583
 584 function(find_python_module module)
 585   string(REPLACE "." "_" module_name ${module})
 586   string(TOUPPER ${module_name} module_upper)
 587   set(FOUND_VAR PY_${module_upper}_FOUND)
 588
 589   execute_process(COMMAND "${PYTHON_EXECUTABLE}" "-c" "import ${module}"
 590     RESULT_VARIABLE status
 591     ERROR_QUIET)
 592
 593   if(status)
 594     set(${FOUND_VAR} 0 PARENT_SCOPE)
 595     message(STATUS "Could NOT find Python module ${module}")
 596   else()
 597     set(${FOUND_VAR} 1 PARENT_SCOPE)
 598     message(STATUS "Found Python module ${module}")
 599   endif()
 600 endfunction()
 601
 602 set (PYTHON_MODULES
 603   pygments
 604   # Some systems still don't have pygments.lexers.c_cpp which was introduced in
 605   # version 2.0 in 2014...
 606   pygments.lexers.c_cpp
 607   yaml
 608   )
 609 foreach(module ${PYTHON_MODULES})
 610   find_python_module(${module})
 611 endforeach()
 612
 613 if(PY_PYGMENTS_FOUND AND PY_PYGMENTS_LEXERS_C_CPP_FOUND AND PY_YAML_FOUND)
 614   set (LLVM_HAVE_OPT_VIEWER_MODULES 1)
 615 else()
 616   set (LLVM_HAVE_OPT_VIEWER_MODULES 0)
 617 endif()