cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3 include(DetermineGCCCompatible)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual targets can use to
  12   # force EH
  13   if(LLVM_REQUIRES_EH OR LLVM_ENABLE_EH)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18     if(MSVC)
  19       list(APPEND LLVM_COMPILE_FLAGS "/EHsc")
  20     endif()
  21   else()
  22     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  23       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  24     elseif(MSVC)
  25       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  26       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  27     endif()
  28   endif()
  29
  30   # LLVM_REQUIRES_RTTI is an internal flag that individual
  31   # targets can use to force RTTI
  32   set(LLVM_CONFIG_HAS_RTTI YES CACHE INTERNAL "")
  33   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  34     set(LLVM_CONFIG_HAS_RTTI NO CACHE INTERNAL "")
  35     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  36     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  37       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  38     elseif (MSVC)
  39       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  40     endif ()
  41   elseif(MSVC)
  42     list(APPEND LLVM_COMPILE_FLAGS "/GR")
  43   endif()
  44
  45   # Assume that;
  46   #   - LLVM_COMPILE_FLAGS is list.
  47   #   - PROPERTY COMPILE_FLAGS is string.
  48   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  49
  50   if(update_src_props)
  51     foreach(fn ${sources})
  52       get_filename_component(suf ${fn} EXT)
  53       if("${suf}" STREQUAL ".cpp")
  54         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  55           COMPILE_FLAGS "${target_compile_flags}")
  56       endif()
  57     endforeach()
  58   else()
  59     # Update target props, since all sources are C++.
  60     set_property(TARGET ${name} APPEND_STRING PROPERTY
  61       COMPILE_FLAGS "${target_compile_flags}")
  62   endif()
  63
  64   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  65 endfunction()
  66
  67 function(add_llvm_symbol_exports target_name export_file)
  68   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  69     set(native_export_file "${target_name}.exports")
  70     add_custom_command(OUTPUT ${native_export_file}
  71       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  72       DEPENDS ${export_file}
  73       VERBATIM
  74       COMMENT "Creating export file for ${target_name}")
  75     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  76                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  77   elseif(${CMAKE_SYSTEM_NAME} MATCHES "AIX")
  78     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  79                  LINK_FLAGS " -Wl,-bE:${export_file}")
  80   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  81     # Gold and BFD ld require a version script rather than a plain list.
  82     set(native_export_file "${target_name}.exports")
  83     # FIXME: Don't write the "local:" line on OpenBSD.
  84     add_custom_command(OUTPUT ${native_export_file}
  85       COMMAND echo "{" > ${native_export_file}
  86       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  87       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  88       COMMAND echo "  local: *;" >> ${native_export_file}
  89       COMMAND echo "};" >> ${native_export_file}
  90       DEPENDS ${export_file}
  91       VERBATIM
  92       COMMENT "Creating export file for ${target_name}")
  93     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  94       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  95                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  96     else()
  97       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  98                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  99     endif()
 100   else()
 101     set(native_export_file "${target_name}.def")
 102
 103     add_custom_command(OUTPUT ${native_export_file}
 104       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
 105         < ${export_file} > ${native_export_file}
 106       DEPENDS ${export_file}
 107       VERBATIM
 108       COMMENT "Creating export file for ${target_name}")
 109     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 110     if(MSVC)
 111       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 112     endif()
 113     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 114                  LINK_FLAGS " ${export_file_linker_flag}")
 115   endif()
 116
 117   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 118   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 119
 120   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 121   foreach(src ${srcs})
 122     get_filename_component(extension ${src} EXT)
 123     if(extension STREQUAL ".cpp")
 124       set(first_source_file ${src})
 125       break()
 126     endif()
 127   endforeach()
 128
 129   # Force re-linking when the exports file changes. Actually, it
 130   # forces recompilation of the source file. The LINK_DEPENDS target
 131   # property only works for makefile-based generators.
 132   # FIXME: This is not safe because this will create the same target
 133   # ${native_export_file} in several different file:
 134   # - One where we emitted ${target_name}_exports
 135   # - One where we emitted the build command for the following object.
 136   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 137   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 138
 139   set_property(DIRECTORY APPEND
 140     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 141
 142   add_dependencies(${target_name} ${target_name}_exports)
 143
 144   # Add dependency to *_exports later -- CMake issue 14747
 145   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 146   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 147 endfunction(add_llvm_symbol_exports)
 148
 149 if(NOT WIN32 AND NOT APPLE)
 150   execute_process(
 151     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 152     OUTPUT_VARIABLE stdout
 153     ERROR_QUIET
 154     )
 155   if("${stdout}" MATCHES "GNU gold")
 156     set(LLVM_LINKER_IS_GOLD ON)
 157   endif()
 158 endif()
 159
 160 function(add_link_opts target_name)
 161   # Don't use linker optimizations in debug builds since it slows down the
 162   # linker in a context where the optimizations are not important.
 163   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 164
 165     # Pass -O3 to the linker. This enabled different optimizations on different
 166     # linkers.
 167     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS|AIX" OR WIN32))
 168       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 169                    LINK_FLAGS " -Wl,-O3")
 170     endif()
 171
 172     if(LLVM_LINKER_IS_GOLD)
 173       # With gold gc-sections is always safe.
 174       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 175                    LINK_FLAGS " -Wl,--gc-sections")
 176       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 177       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 178     endif()
 179
 180     if(NOT LLVM_NO_DEAD_STRIP)
 181       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 182         # ld64's implementation of -dead_strip breaks tools that use plugins.
 183         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 184                      LINK_FLAGS " -Wl,-dead_strip")
 185       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 186         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 187                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 188       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 189         # Object files are compiled with -ffunction-data-sections.
 190         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 191         # tools that use plugins. Always pass --gc-sections once we require
 192         # a newer linker.
 193         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 194                      LINK_FLAGS " -Wl,--gc-sections")
 195       endif()
 196     endif()
 197   endif()
 198 endfunction(add_link_opts)
 199
 200 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 201 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 202 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 203 function(set_output_directory target)
 204   cmake_parse_arguments(ARG "" "BINARY_DIR;LIBRARY_DIR" "" ${ARGN})
 205
 206   # module_dir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 207   # It affects output of add_library(MODULE).
 208   if(WIN32 OR CYGWIN)
 209     # DLL platform
 210     set(module_dir ${ARG_BINARY_DIR})
 211   else()
 212     set(module_dir ${ARG_LIBRARY_DIR})
 213   endif()
 214   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 215     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 216       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 217       if(ARG_BINARY_DIR)
 218         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${ARG_BINARY_DIR})
 219         set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 220       endif()
 221       if(ARG_LIBRARY_DIR)
 222         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${ARG_LIBRARY_DIR})
 223         set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 224       endif()
 225       if(module_dir)
 226         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${module_dir})
 227         set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 228       endif()
 229     endforeach()
 230   else()
 231     if(ARG_BINARY_DIR)
 232       set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${ARG_BINARY_DIR})
 233     endif()
 234     if(ARG_LIBRARY_DIR)
 235       set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${ARG_LIBRARY_DIR})
 236     endif()
 237     if(module_dir)
 238       set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${module_dir})
 239     endif()
 240   endif()
 241 endfunction()
 242
 243 # If on Windows and building with MSVC, add the resource script containing the
 244 # VERSIONINFO data to the project.  This embeds version resource information
 245 # into the output .exe or .dll.
 246 # TODO: Enable for MinGW Windows builds too.
 247 #
 248 function(add_windows_version_resource_file OUT_VAR)
 249   set(sources ${ARGN})
 250   if (MSVC)
 251     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 252     if(EXISTS ${resource_file})
 253       set(sources ${sources} ${resource_file})
 254       source_group("Resource Files" ${resource_file})
 255       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 256     endif()
 257   endif(MSVC)
 258
 259   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 260 endfunction(add_windows_version_resource_file)
 261
 262 # set_windows_version_resource_properties(name resource_file...
 263 #   VERSION_MAJOR int
 264 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 265 #   VERSION_MINOR int
 266 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 267 #   VERSION_PATCHLEVEL int
 268 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 269 #   VERSION_STRING
 270 #     Optional version string (defaults to PACKAGE_VERSION)
 271 #   PRODUCT_NAME
 272 #     Optional product name string (defaults to "LLVM")
 273 #   )
 274 function(set_windows_version_resource_properties name resource_file)
 275   cmake_parse_arguments(ARG
 276     ""
 277     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 278     ""
 279     ${ARGN})
 280
 281   if (NOT DEFINED ARG_VERSION_MAJOR)
 282     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 283   endif()
 284
 285   if (NOT DEFINED ARG_VERSION_MINOR)
 286     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 287   endif()
 288
 289   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 290     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 291   endif()
 292
 293   if (NOT DEFINED ARG_VERSION_STRING)
 294     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 295   endif()
 296
 297   if (NOT DEFINED ARG_PRODUCT_NAME)
 298     set(ARG_PRODUCT_NAME "LLVM")
 299   endif()
 300
 301   set_property(SOURCE ${resource_file}
 302                PROPERTY COMPILE_FLAGS /nologo)
 303   set_property(SOURCE ${resource_file}
 304                PROPERTY COMPILE_DEFINITIONS
 305                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 306                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 307                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 308                "RC_VERSION_FIELD_4=0"
 309                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 310                "RC_INTERNAL_NAME=\"${name}\""
 311                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 312                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 313 endfunction(set_windows_version_resource_properties)
 314
 315 # llvm_add_library(name sources...
 316 #   SHARED;STATIC
 317 #     STATIC by default w/o BUILD_SHARED_LIBS.
 318 #     SHARED by default w/  BUILD_SHARED_LIBS.
 319 #   OBJECT
 320 #     Also create an OBJECT library target. Default if STATIC && SHARED.
 321 #   MODULE
 322 #     Target ${name} might not be created on unsupported platforms.
 323 #     Check with "if(TARGET ${name})".
 324 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 325 #     Do not link this library to libLLVM, even if
 326 #     LLVM_LINK_LLVM_DYLIB is enabled.
 327 #   OUTPUT_NAME name
 328 #     Corresponds to OUTPUT_NAME in target properties.
 329 #   DEPENDS targets...
 330 #     Same semantics as add_dependencies().
 331 #   LINK_COMPONENTS components...
 332 #     Same as the variable LLVM_LINK_COMPONENTS.
 333 #   LINK_LIBS lib_targets...
 334 #     Same semantics as target_link_libraries().
 335 #   ADDITIONAL_HEADERS
 336 #     May specify header files for IDE generators.
 337 #   SONAME
 338 #     Should set SONAME link flags and create symlinks
 339 #   PLUGIN_TOOL
 340 #     The tool (i.e. cmake target) that this plugin will link against
 341 #   )
 342 function(llvm_add_library name)
 343   cmake_parse_arguments(ARG
 344     "MODULE;SHARED;STATIC;OBJECT;DISABLE_LLVM_LINK_LLVM_DYLIB;SONAME"
 345     "OUTPUT_NAME;PLUGIN_TOOL"
 346     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 347     ${ARGN})
 348   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 349   if(ARG_ADDITIONAL_HEADERS)
 350     # Pass through ADDITIONAL_HEADERS.
 351     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 352   endif()
 353   if(ARG_OBJLIBS)
 354     set(ALL_FILES ${ARG_OBJLIBS})
 355   else()
 356     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 357   endif()
 358
 359   if(ARG_MODULE)
 360     if(ARG_SHARED OR ARG_STATIC)
 361       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 362     endif()
 363     # Plugins that link against a tool are allowed even when plugins in general are not
 364     if(NOT LLVM_ENABLE_PLUGINS AND NOT (ARG_PLUGIN_TOOL AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS))
 365       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 366       return()
 367     endif()
 368   else()
 369     if(ARG_PLUGIN_TOOL)
 370       message(WARNING "PLUGIN_TOOL without MODULE doesn't make sense.")
 371     endif()
 372     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 373       set(ARG_SHARED TRUE)
 374     endif()
 375     if(NOT ARG_SHARED)
 376       set(ARG_STATIC TRUE)
 377     endif()
 378   endif()
 379
 380   # Generate objlib
 381   if((ARG_SHARED AND ARG_STATIC) OR ARG_OBJECT)
 382     # Generate an obj library for both targets.
 383     set(obj_name "obj.${name}")
 384     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 385       ${ALL_FILES}
 386       )
 387     llvm_update_compile_flags(${obj_name})
 388     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 389
 390     # Do add_dependencies(obj) later due to CMake issue 14747.
 391     list(APPEND objlibs ${obj_name})
 392
 393     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 394   endif()
 395
 396   if(ARG_SHARED AND ARG_STATIC)
 397     # static
 398     set(name_static "${name}_static")
 399     if(ARG_OUTPUT_NAME)
 400       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 401     endif()
 402     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 403     llvm_add_library(${name_static} STATIC
 404       ${output_name}
 405       OBJLIBS ${ALL_FILES} # objlib
 406       LINK_LIBS ${ARG_LINK_LIBS}
 407       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 408       )
 409     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 410     set(ARG_STATIC)
 411   endif()
 412
 413   if(ARG_MODULE)
 414     add_library(${name} MODULE ${ALL_FILES})
 415   elseif(ARG_SHARED)
 416     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 417     add_library(${name} SHARED ${ALL_FILES})
 418
 419     llvm_setup_rpath(${name})
 420
 421   else()
 422     add_library(${name} STATIC ${ALL_FILES})
 423   endif()
 424
 425   if(DEFINED windows_resource_file)
 426     set_windows_version_resource_properties(${name} ${windows_resource_file})
 427     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 428   endif()
 429
 430   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 431   # $<TARGET_OBJECTS> doesn't require compile flags.
 432   if(NOT obj_name)
 433     llvm_update_compile_flags(${name})
 434   endif()
 435   add_link_opts( ${name} )
 436   if(ARG_OUTPUT_NAME)
 437     set_target_properties(${name}
 438       PROPERTIES
 439       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 440       )
 441   endif()
 442
 443   if(ARG_MODULE)
 444     set_target_properties(${name} PROPERTIES
 445       PREFIX ""
 446       SUFFIX ${LLVM_PLUGIN_EXT}
 447       )
 448   endif()
 449
 450   if(ARG_SHARED)
 451     if(WIN32)
 452       set_target_properties(${name} PROPERTIES
 453         PREFIX ""
 454         )
 455     endif()
 456
 457     # Set SOVERSION on shared libraries that lack explicit SONAME
 458     # specifier, on *nix systems that are not Darwin.
 459     if(UNIX AND NOT APPLE AND NOT ARG_SONAME)
 460       set_target_properties(${name}
 461         PROPERTIES
 462                 # Concatenate the version numbers since ldconfig expects exactly
 463                 # one component indicating the ABI version, while LLVM uses
 464                 # major+minor for that.
 465         SOVERSION ${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}
 466         VERSION ${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 467     endif()
 468   endif()
 469
 470   if(ARG_MODULE OR ARG_SHARED)
 471     # Do not add -Dname_EXPORTS to the command-line when building files in this
 472     # target. Doing so is actively harmful for the modules build because it
 473     # creates extra module variants, and not useful because we don't use these
 474     # macros.
 475     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 476
 477     if (LLVM_EXPORTED_SYMBOL_FILE)
 478       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 479     endif()
 480   endif()
 481
 482   if(ARG_SHARED AND UNIX)
 483     if(NOT APPLE AND ARG_SONAME)
 484       get_target_property(output_name ${name} OUTPUT_NAME)
 485       if(${output_name} STREQUAL "output_name-NOTFOUND")
 486         set(output_name ${name})
 487       endif()
 488       set(library_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}${LLVM_VERSION_SUFFIX})
 489       set(api_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 490       set_target_properties(${name} PROPERTIES OUTPUT_NAME ${library_name})
 491       llvm_install_library_symlink(${api_name} ${library_name} SHARED
 492         COMPONENT ${name}
 493         ALWAYS_GENERATE)
 494       llvm_install_library_symlink(${output_name} ${library_name} SHARED
 495         COMPONENT ${name}
 496         ALWAYS_GENERATE)
 497     endif()
 498   endif()
 499
 500   if(ARG_MODULE AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS AND ARG_PLUGIN_TOOL AND (WIN32 OR CYGWIN))
 501     # On DLL platforms symbols are imported from the tool by linking against it.
 502     set(llvm_libs ${ARG_PLUGIN_TOOL})
 503   elseif (DEFINED LLVM_LINK_COMPONENTS OR DEFINED ARG_LINK_COMPONENTS)
 504     if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 505       set(llvm_libs LLVM)
 506     else()
 507       llvm_map_components_to_libnames(llvm_libs
 508        ${ARG_LINK_COMPONENTS}
 509        ${LLVM_LINK_COMPONENTS}
 510        )
 511     endif()
 512   else()
 513     # Components have not been defined explicitly in CMake, so add the
 514     # dependency information for this library as defined by LLVMBuild.
 515     #
 516     # It would be nice to verify that we have the dependencies for this library
 517     # name, but using get_property(... SET) doesn't suffice to determine if a
 518     # property has been set to an empty value.
 519     get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 520   endif()
 521
 522   if(ARG_STATIC)
 523     set(libtype INTERFACE)
 524   else()
 525     # We can use PRIVATE since SO knows its dependent libs.
 526     set(libtype PRIVATE)
 527   endif()
 528
 529   target_link_libraries(${name} ${libtype}
 530       ${ARG_LINK_LIBS}
 531       ${lib_deps}
 532       ${llvm_libs}
 533       )
 534
 535   if(LLVM_COMMON_DEPENDS)
 536     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 537     # Add dependencies also to objlibs.
 538     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 539     foreach(objlib ${objlibs})
 540       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 541     endforeach()
 542   endif()
 543
 544   if(ARG_SHARED OR ARG_MODULE)
 545     llvm_externalize_debuginfo(${name})
 546   endif()
 547 endfunction()
 548
 549 macro(add_llvm_library name)
 550   cmake_parse_arguments(ARG
 551     "SHARED;BUILDTREE_ONLY"
 552     ""
 553     ""
 554     ${ARGN})
 555   if( BUILD_SHARED_LIBS OR ARG_SHARED )
 556     llvm_add_library(${name} SHARED ${ARG_UNPARSED_ARGUMENTS})
 557   else()
 558     llvm_add_library(${name} ${ARG_UNPARSED_ARGUMENTS})
 559   endif()
 560
 561   # Libraries that are meant to only be exposed via the build tree only are
 562   # never installed and are only exported as a target in the special build tree
 563   # config file.
 564   if (NOT ARG_BUILDTREE_ONLY)
 565     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 566   endif()
 567
 568   if( EXCLUDE_FROM_ALL )
 569     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 570   elseif(ARG_BUILDTREE_ONLY)
 571     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS_BUILDTREE_ONLY ${name})
 572   else()
 573     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO" OR
 574         (LLVM_LINK_LLVM_DYLIB AND ${name} STREQUAL "LLVM"))
 575       set(install_dir lib${LLVM_LIBDIR_SUFFIX})
 576       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 577         if(WIN32 OR CYGWIN OR MINGW)
 578           set(install_type RUNTIME)
 579           set(install_dir bin)
 580         else()
 581           set(install_type LIBRARY)
 582         endif()
 583       else()
 584         set(install_type ARCHIVE)
 585       endif()
 586
 587       install(TARGETS ${name}
 588             EXPORT LLVMExports
 589             ${install_type} DESTINATION ${install_dir}
 590             COMPONENT ${name})
 591
 592       if (NOT CMAKE_CONFIGURATION_TYPES)
 593         add_custom_target(install-${name}
 594                           DEPENDS ${name}
 595                           COMMAND "${CMAKE_COMMAND}"
 596                                   -DCMAKE_INSTALL_COMPONENT=${name}
 597                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 598       endif()
 599     endif()
 600     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 601   endif()
 602   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 603 endmacro(add_llvm_library name)
 604
 605 macro(add_llvm_loadable_module name)
 606   llvm_add_library(${name} MODULE ${ARGN})
 607   if(NOT TARGET ${name})
 608     # Add empty "phony" target
 609     add_custom_target(${name})
 610   else()
 611     if( EXCLUDE_FROM_ALL )
 612       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 613     else()
 614       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 615         if(WIN32 OR CYGWIN)
 616           # DLL platform
 617           set(dlldir "bin")
 618         else()
 619           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 620         endif()
 621         install(TARGETS ${name}
 622           EXPORT LLVMExports
 623           LIBRARY DESTINATION ${dlldir}
 624           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 625       endif()
 626       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 627     endif()
 628   endif()
 629
 630   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 631 endmacro(add_llvm_loadable_module name)
 632
 633
 634 macro(add_llvm_executable name)
 635   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB;IGNORE_EXTERNALIZE_DEBUGINFO;NO_INSTALL_RPATH" "" "" ${ARGN})
 636   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 637
 638   # Generate objlib
 639   if(LLVM_ENABLE_OBJLIB)
 640     # Generate an obj library for both targets.
 641     set(obj_name "obj.${name}")
 642     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 643       ${ALL_FILES}
 644       )
 645     llvm_update_compile_flags(${obj_name})
 646     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 647
 648     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 649   endif()
 650
 651   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 652
 653   if(XCODE)
 654     # Note: the dummy.cpp source file provides no definitions. However,
 655     # it forces Xcode to properly link the static library.
 656     list(APPEND ALL_FILES "${LLVM_MAIN_SRC_DIR}/cmake/dummy.cpp")
 657   endif()
 658
 659   if( EXCLUDE_FROM_ALL )
 660     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 661   else()
 662     add_executable(${name} ${ALL_FILES})
 663   endif()
 664
 665   if(NOT ARG_NO_INSTALL_RPATH)
 666     llvm_setup_rpath(${name})
 667   endif()
 668
 669   if(DEFINED windows_resource_file)
 670     set_windows_version_resource_properties(${name} ${windows_resource_file})
 671   endif()
 672
 673   # $<TARGET_OBJECTS> doesn't require compile flags.
 674   if(NOT LLVM_ENABLE_OBJLIB)
 675     llvm_update_compile_flags(${name})
 676   endif()
 677   add_link_opts( ${name} )
 678
 679   # Do not add -Dname_EXPORTS to the command-line when building files in this
 680   # target. Doing so is actively harmful for the modules build because it
 681   # creates extra module variants, and not useful because we don't use these
 682   # macros.
 683   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 684
 685   if (LLVM_EXPORTED_SYMBOL_FILE)
 686     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 687   endif(LLVM_EXPORTED_SYMBOL_FILE)
 688
 689   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 690     set(USE_SHARED USE_SHARED)
 691   endif()
 692
 693   set(EXCLUDE_FROM_ALL OFF)
 694   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 695   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 696   if( LLVM_COMMON_DEPENDS )
 697     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 698   endif( LLVM_COMMON_DEPENDS )
 699
 700   if(NOT ARG_IGNORE_EXTERNALIZE_DEBUGINFO)
 701     llvm_externalize_debuginfo(${name})
 702   endif()
 703   if (PTHREAD_LIB)
 704     # libpthreads overrides some standard library symbols, so main
 705     # executable must be linked with it in order to provide consistent
 706     # API for all shared libaries loaded by this executable.
 707     target_link_libraries(${name} ${PTHREAD_LIB})
 708   endif()
 709 endmacro(add_llvm_executable name)
 710
 711 function(export_executable_symbols target)
 712   if (LLVM_EXPORTED_SYMBOL_FILE)
 713     # The symbol file should contain the symbols we want the executable to
 714     # export
 715     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 716   elseif (LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 717     # Extract the symbols to export from the static libraries that the
 718     # executable links against.
 719     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 720     set(exported_symbol_file ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${target}.symbols)
 721     # We need to consider not just the direct link dependencies, but also the
 722     # transitive link dependencies. Do this by starting with the set of direct
 723     # dependencies, then the dependencies of those dependencies, and so on.
 724     get_target_property(new_libs ${target} LINK_LIBRARIES)
 725     set(link_libs ${new_libs})
 726     while(NOT "${new_libs}" STREQUAL "")
 727       foreach(lib ${new_libs})
 728         if(TARGET ${lib})
 729           get_target_property(lib_type ${lib} TYPE)
 730           if("${lib_type}" STREQUAL "STATIC_LIBRARY")
 731             list(APPEND static_libs ${lib})
 732           else()
 733             list(APPEND other_libs ${lib})
 734           endif()
 735           get_target_property(transitive_libs ${lib} INTERFACE_LINK_LIBRARIES)
 736           foreach(transitive_lib ${transitive_libs})
 737             list(FIND link_libs ${transitive_lib} idx)
 738             if(TARGET ${transitive_lib} AND idx EQUAL -1)
 739               list(APPEND newer_libs ${transitive_lib})
 740               list(APPEND link_libs ${transitive_lib})
 741             endif()
 742           endforeach(transitive_lib)
 743         endif()
 744       endforeach(lib)
 745       set(new_libs ${newer_libs})
 746       set(newer_libs "")
 747     endwhile()
 748     if (MSVC)
 749       set(mangling microsoft)
 750     else()
 751       set(mangling itanium)
 752     endif()
 753     add_custom_command(OUTPUT ${exported_symbol_file}
 754                        COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/extract_symbols.py --mangling=${mangling} ${static_libs} -o ${exported_symbol_file}
 755                        WORKING_DIRECTORY ${LLVM_LIBRARY_OUTPUT_INTDIR}
 756                        DEPENDS ${LLVM_MAIN_SRC_DIR}/utils/extract_symbols.py ${static_libs}
 757                        VERBATIM
 758                        COMMENT "Generating export list for ${target}")
 759     add_llvm_symbol_exports( ${target} ${exported_symbol_file} )
 760     # If something links against this executable then we want a
 761     # transitive link against only the libraries whose symbols
 762     # we aren't exporting.
 763     set_target_properties(${target} PROPERTIES INTERFACE_LINK_LIBRARIES "${other_libs}")
 764     # The default import library suffix that cmake uses for cygwin/mingw is
 765     # ".dll.a", but for clang.exe that causes a collision with libclang.dll,
 766     # where the import libraries of both get named libclang.dll.a. Use a suffix
 767     # of ".exe.a" to avoid this.
 768     if(CYGWIN OR MINGW)
 769       set_target_properties(${target} PROPERTIES IMPORT_SUFFIX ".exe.a")
 770     endif()
 771   elseif(NOT (WIN32 OR CYGWIN))
 772     # On Windows auto-exporting everything doesn't work because of the limit on
 773     # the size of the exported symbol table, but on other platforms we can do
 774     # it without any trouble.
 775     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 776     if (APPLE)
 777       set_property(TARGET ${target} APPEND_STRING PROPERTY
 778         LINK_FLAGS " -rdynamic")
 779     endif()
 780   endif()
 781 endfunction()
 782
 783 if(NOT LLVM_TOOLCHAIN_TOOLS)
 784   set (LLVM_TOOLCHAIN_TOOLS
 785     llvm-ar
 786     llvm-ranlib
 787     llvm-lib
 788     llvm-objdump
 789     )
 790 endif()
 791
 792 macro(add_llvm_tool name)
 793   if( NOT LLVM_BUILD_TOOLS )
 794     set(EXCLUDE_FROM_ALL ON)
 795   endif()
 796   add_llvm_executable(${name} ${ARGN})
 797
 798   if ( ${name} IN_LIST LLVM_TOOLCHAIN_TOOLS OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 799     if( LLVM_BUILD_TOOLS )
 800       install(TARGETS ${name}
 801               EXPORT LLVMExports
 802               RUNTIME DESTINATION ${LLVM_TOOLS_INSTALL_DIR}
 803               COMPONENT ${name})
 804
 805       if (NOT CMAKE_CONFIGURATION_TYPES)
 806         add_custom_target(install-${name}
 807                           DEPENDS ${name}
 808                           COMMAND "${CMAKE_COMMAND}"
 809                                   -DCMAKE_INSTALL_COMPONENT=${name}
 810                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 811       endif()
 812     endif()
 813   endif()
 814   if( LLVM_BUILD_TOOLS )
 815     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 816   endif()
 817   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 818 endmacro(add_llvm_tool name)
 819
 820
 821 macro(add_llvm_example name)
 822   if( NOT LLVM_BUILD_EXAMPLES )
 823     set(EXCLUDE_FROM_ALL ON)
 824   endif()
 825   add_llvm_executable(${name} ${ARGN})
 826   if( LLVM_BUILD_EXAMPLES )
 827     install(TARGETS ${name} RUNTIME DESTINATION examples)
 828   endif()
 829   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 830 endmacro(add_llvm_example name)
 831
 832 # This is a macro that is used to create targets for executables that are needed
 833 # for development, but that are not intended to be installed by default.
 834 macro(add_llvm_utility name)
 835   if ( NOT LLVM_BUILD_UTILS )
 836     set(EXCLUDE_FROM_ALL ON)
 837   endif()
 838
 839   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 840   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 841   if( LLVM_INSTALL_UTILS AND LLVM_BUILD_UTILS )
 842     install (TARGETS ${name}
 843       RUNTIME DESTINATION bin
 844       COMPONENT ${name})
 845     if (NOT CMAKE_CONFIGURATION_TYPES)
 846       add_custom_target(install-${name}
 847                         DEPENDS ${name}
 848                         COMMAND "${CMAKE_COMMAND}"
 849                                 -DCMAKE_INSTALL_COMPONENT=${name}
 850                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 851     endif()
 852   endif()
 853 endmacro(add_llvm_utility name)
 854
 855
 856 macro(add_llvm_target target_name)
 857   include_directories(BEFORE
 858     ${CMAKE_CURRENT_BINARY_DIR}
 859     ${CMAKE_CURRENT_SOURCE_DIR})
 860   add_llvm_library(LLVM${target_name} ${ARGN})
 861   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 862 endmacro(add_llvm_target)
 863
 864 function(canonicalize_tool_name name output)
 865   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 866   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 867   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 868   set(${output} "${nameUPPER}" PARENT_SCOPE)
 869 endfunction(canonicalize_tool_name)
 870
 871 # Custom add_subdirectory wrapper
 872 # Takes in a project name (i.e. LLVM), the subdirectory name, and an optional
 873 # path if it differs from the name.
 874 macro(add_llvm_subdirectory project type name)
 875   set(add_llvm_external_dir "${ARGN}")
 876   if("${add_llvm_external_dir}" STREQUAL "")
 877     set(add_llvm_external_dir ${name})
 878   endif()
 879   canonicalize_tool_name(${name} nameUPPER)
 880   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 881     # Treat it as in-tree subproject.
 882     option(${project}_${type}_${nameUPPER}_BUILD
 883            "Whether to build ${name} as part of ${project}" On)
 884     mark_as_advanced(${project}_${type}_${name}_BUILD)
 885     if(${project}_${type}_${nameUPPER}_BUILD)
 886       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 887       # Don't process it in add_llvm_implicit_projects().
 888       set(${project}_${type}_${nameUPPER}_BUILD OFF)
 889     endif()
 890   else()
 891     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 892       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 893       CACHE PATH "Path to ${name} source directory")
 894     set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT ON)
 895     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 896       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 897     endif()
 898     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 899       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 900     endif()
 901     option(${project}_${type}_${nameUPPER}_BUILD
 902       "Whether to build ${name} as part of LLVM"
 903       ${${project}_${type}_${nameUPPER}_BUILD_DEFAULT})
 904     if (${project}_${type}_${nameUPPER}_BUILD)
 905       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 906         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 907       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 908         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 909       endif()
 910       # FIXME: It'd be redundant.
 911       set(${project}_${type}_${nameUPPER}_BUILD Off)
 912     endif()
 913   endif()
 914 endmacro()
 915
 916 # Add external project that may want to be built as part of llvm such as Clang,
 917 # lld, and Polly. This adds two options. One for the source directory of the
 918 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 919 # enable or disable building it with everything else.
 920 # Additional parameter can be specified as the name of directory.
 921 macro(add_llvm_external_project name)
 922   add_llvm_subdirectory(LLVM TOOL ${name} ${ARGN})
 923 endmacro()
 924
 925 macro(add_llvm_tool_subdirectory name)
 926   add_llvm_external_project(${name})
 927 endmacro(add_llvm_tool_subdirectory)
 928
 929 function(get_project_name_from_src_var var output)
 930   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 931          MACHED_TOOL "${var}")
 932   if(MACHED_TOOL)
 933     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 934   else()
 935     set(${output} PARENT_SCOPE)
 936   endif()
 937 endfunction()
 938
 939 function(create_subdirectory_options project type)
 940   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 941   foreach(dir ${sub-dirs})
 942     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 943       canonicalize_tool_name(${dir} name)
 944       option(${project}_${type}_${name}_BUILD
 945            "Whether to build ${name} as part of ${project}" On)
 946       mark_as_advanced(${project}_${type}_${name}_BUILD)
 947     endif()
 948   endforeach()
 949 endfunction(create_subdirectory_options)
 950
 951 function(create_llvm_tool_options)
 952   create_subdirectory_options(LLVM TOOL)
 953 endfunction(create_llvm_tool_options)
 954
 955 function(llvm_add_implicit_projects project)
 956   set(list_of_implicit_subdirs "")
 957   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 958   foreach(dir ${sub-dirs})
 959     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 960       canonicalize_tool_name(${dir} name)
 961       if (${project}_TOOL_${name}_BUILD)
 962         get_filename_component(fn "${dir}" NAME)
 963         list(APPEND list_of_implicit_subdirs "${fn}")
 964       endif()
 965     endif()
 966   endforeach()
 967
 968   foreach(external_proj ${list_of_implicit_subdirs})
 969     add_llvm_subdirectory(${project} TOOL "${external_proj}" ${ARGN})
 970   endforeach()
 971 endfunction(llvm_add_implicit_projects)
 972
 973 function(add_llvm_implicit_projects)
 974   llvm_add_implicit_projects(LLVM)
 975 endfunction(add_llvm_implicit_projects)
 976
 977 # Generic support for adding a unittest.
 978 function(add_unittest test_suite test_name)
 979   if( NOT LLVM_BUILD_TESTS )
 980     set(EXCLUDE_FROM_ALL ON)
 981   endif()
 982
 983   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 984   if (NOT LLVM_ENABLE_THREADS)
 985     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 986   endif ()
 987
 988   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 989     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 990   endif ()
 991
 992   set(LLVM_REQUIRES_RTTI OFF)
 993
 994   list(APPEND LLVM_LINK_COMPONENTS Support) # gtest needs it for raw_ostream
 995   add_llvm_executable(${test_name} IGNORE_EXTERNALIZE_DEBUGINFO NO_INSTALL_RPATH ${ARGN})
 996   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 997   set_output_directory(${test_name} BINARY_DIR ${outdir} LIBRARY_DIR ${outdir})
 998   # libpthreads overrides some standard library symbols, so main
 999   # executable must be linked with it in order to provide consistent
1000   # API for all shared libaries loaded by this executable.
1001   target_link_libraries(${test_name} gtest_main gtest ${PTHREAD_LIB})
1002
1003   add_dependencies(${test_suite} ${test_name})
1004   get_target_property(test_suite_folder ${test_suite} FOLDER)
1005   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
1006     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
1007   endif ()
1008 endfunction()
1009
1010 function(llvm_add_go_executable binary pkgpath)
1011   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
1012
1013   if(LLVM_BINDINGS MATCHES "go")
1014     # FIXME: This should depend only on the libraries Go needs.
1015     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
1016     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
1017     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
1018     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1019     set(cppflags "")
1020     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
1021     foreach(d ${include_dirs})
1022       set(cppflags "${cppflags} -I${d}")
1023     endforeach(d)
1024     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
1025     add_custom_command(OUTPUT ${binpath}
1026       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "packages=${LLVM_GO_PACKAGES}"
1027               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
1028       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
1029               ${llvmlibs} ${ARG_DEPENDS}
1030       COMMENT "Building Go executable ${binary}"
1031       VERBATIM)
1032     if (ARG_ALL)
1033       add_custom_target(${binary} ALL DEPENDS ${binpath})
1034     else()
1035       add_custom_target(${binary} DEPENDS ${binpath})
1036     endif()
1037   endif()
1038 endfunction()
1039
1040 # This function provides an automatic way to 'configure'-like generate a file
1041 # based on a set of common and custom variables, specifically targeting the
1042 # variables needed for the 'lit.site.cfg' files. This function bundles the
1043 # common variables that any Lit instance is likely to need, and custom
1044 # variables can be passed in.
1045 function(configure_lit_site_cfg input output)
1046   foreach(c ${LLVM_TARGETS_TO_BUILD})
1047     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
1048   endforeach(c)
1049   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
1050
1051   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
1052
1053   # Configuration-time: See Unit/lit.site.cfg.in
1054   if (CMAKE_CFG_INTDIR STREQUAL ".")
1055     set(LLVM_BUILD_MODE ".")
1056   else ()
1057     set(LLVM_BUILD_MODE "%(build_mode)s")
1058   endif ()
1059
1060   # They below might not be the build tree but provided binary tree.
1061   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
1062   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
1063   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
1064   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
1065
1066   # SHLIBDIR points the build tree.
1067   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
1068
1069   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
1070   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
1071   # plugins. We may rename it.
1072   if(LLVM_ENABLE_PLUGINS)
1073     set(ENABLE_SHARED "1")
1074   else()
1075     set(ENABLE_SHARED "0")
1076   endif()
1077
1078   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
1079     set(ENABLE_ASSERTIONS "1")
1080   else()
1081     set(ENABLE_ASSERTIONS "0")
1082   endif()
1083
1084   set(HOST_OS ${CMAKE_SYSTEM_NAME})
1085   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
1086
1087   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
1088   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1089   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
1090
1091   set(LIT_SITE_CFG_IN_HEADER  "## Autogenerated from ${input}\n## Do not edit!")
1092
1093   configure_file(${input} ${output} @ONLY)
1094 endfunction()
1095
1096 # A raw function to create a lit target. This is used to implement the testuite
1097 # management functions.
1098 function(add_lit_target target comment)
1099   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1100   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
1101   separate_arguments(LIT_ARGS)
1102   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
1103     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
1104   endif ()
1105   if (EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
1106     # reset cache after erraneous r283029
1107     # TODO: remove this once all buildbots run
1108     if (LIT_COMMAND STREQUAL "${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py")
1109       unset(LIT_COMMAND CACHE)
1110     endif()
1111     set (LIT_COMMAND "${PYTHON_EXECUTABLE};${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py"
1112          CACHE STRING "Command used to spawn llvm-lit")
1113   else()
1114     find_program(LIT_COMMAND NAMES llvm-lit lit.py lit)
1115   endif ()
1116   list(APPEND LIT_COMMAND ${LIT_ARGS})
1117   foreach(param ${ARG_PARAMS})
1118     list(APPEND LIT_COMMAND --param ${param})
1119   endforeach()
1120   if (ARG_UNPARSED_ARGUMENTS)
1121     add_custom_target(${target}
1122       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
1123       COMMENT "${comment}"
1124       USES_TERMINAL
1125       )
1126   else()
1127     add_custom_target(${target}
1128       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
1129     message(STATUS "${target} does nothing.")
1130   endif()
1131   if (ARG_DEPENDS)
1132     add_dependencies(${target} ${ARG_DEPENDS})
1133   endif()
1134
1135   # Tests should be excluded from "Build Solution".
1136   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
1137 endfunction()
1138
1139 # A function to add a set of lit test suites to be driven through 'check-*' targets.
1140 function(add_lit_testsuite target comment)
1141   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1142
1143   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
1144   if(NOT EXCLUDE_FROM_ALL)
1145     # Register the testsuites, params and depends for the global check rule.
1146     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
1147     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
1148     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
1149     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
1150   endif()
1151
1152   # Produce a specific suffixed check rule.
1153   add_lit_target(${target} ${comment}
1154     ${ARG_UNPARSED_ARGUMENTS}
1155     PARAMS ${ARG_PARAMS}
1156     DEPENDS ${ARG_DEPENDS}
1157     ARGS ${ARG_ARGS}
1158     )
1159 endfunction()
1160
1161 function(add_lit_testsuites project directory)
1162   if (NOT CMAKE_CONFIGURATION_TYPES)
1163     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1164
1165     # Search recursively for test directories by assuming anything not
1166     # in a directory called Inputs contains tests.
1167     file(GLOB_RECURSE to_process LIST_DIRECTORIES true ${directory}/*)
1168     foreach(lit_suite ${to_process})
1169       if(NOT IS_DIRECTORY ${lit_suite})
1170         continue()
1171       endif()
1172       string(FIND ${lit_suite} Inputs is_inputs)
1173       string(FIND ${lit_suite} Output is_output)
1174       if (NOT (is_inputs EQUAL -1 AND is_output EQUAL -1))
1175         continue()
1176       endif()
1177
1178       # Create a check- target for the directory.
1179       string(REPLACE ${directory} "" name_slash ${lit_suite})
1180       if (name_slash)
1181         string(REPLACE "/" "-" name_slash ${name_slash})
1182         string(REPLACE "\\" "-" name_dashes ${name_slash})
1183         string(TOLOWER "${project}${name_dashes}" name_var)
1184         add_lit_target("check-${name_var}" "Running lit suite ${lit_suite}"
1185           ${lit_suite}
1186           PARAMS ${ARG_PARAMS}
1187           DEPENDS ${ARG_DEPENDS}
1188           ARGS ${ARG_ARGS}
1189         )
1190       endif()
1191     endforeach()
1192   endif()
1193 endfunction()
1194
1195 function(llvm_install_library_symlink name dest type)
1196   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "COMPONENT" "" ${ARGN})
1197   foreach(path ${CMAKE_MODULE_PATH})
1198     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1199       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1200       break()
1201     endif()
1202   endforeach()
1203
1204   set(component ${ARG_COMPONENT})
1205   if(NOT component)
1206     set(component ${name})
1207   endif()
1208
1209   set(full_name ${CMAKE_${type}_LIBRARY_PREFIX}${name}${CMAKE_${type}_LIBRARY_SUFFIX})
1210   set(full_dest ${CMAKE_${type}_LIBRARY_PREFIX}${dest}${CMAKE_${type}_LIBRARY_SUFFIX})
1211
1212   set(output_dir lib${LLVM_LIBDIR_SUFFIX})
1213   if(WIN32 AND "${type}" STREQUAL "SHARED")
1214     set(output_dir bin)
1215   endif()
1216
1217   install(SCRIPT ${INSTALL_SYMLINK}
1218           CODE "install_symlink(${full_name} ${full_dest} ${output_dir})"
1219           COMPONENT ${component})
1220
1221   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1222     add_custom_target(install-${name}
1223                       DEPENDS ${name} ${dest} install-${dest}
1224                       COMMAND "${CMAKE_COMMAND}"
1225                               -DCMAKE_INSTALL_COMPONENT=${name}
1226                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1227   endif()
1228 endfunction()
1229
1230 function(llvm_install_symlink name dest)
1231   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1232   foreach(path ${CMAKE_MODULE_PATH})
1233     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1234       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1235       break()
1236     endif()
1237   endforeach()
1238
1239   if(ARG_ALWAYS_GENERATE)
1240     set(component ${dest})
1241   else()
1242     set(component ${name})
1243   endif()
1244
1245   set(full_name ${name}${CMAKE_EXECUTABLE_SUFFIX})
1246   set(full_dest ${dest}${CMAKE_EXECUTABLE_SUFFIX})
1247
1248   install(SCRIPT ${INSTALL_SYMLINK}
1249           CODE "install_symlink(${full_name} ${full_dest} ${LLVM_TOOLS_INSTALL_DIR})"
1250           COMPONENT ${component})
1251
1252   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1253     add_custom_target(install-${name}
1254                       DEPENDS ${name} ${dest} install-${dest}
1255                       COMMAND "${CMAKE_COMMAND}"
1256                               -DCMAKE_INSTALL_COMPONENT=${name}
1257                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1258   endif()
1259 endfunction()
1260
1261 function(add_llvm_tool_symlink name dest)
1262   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1263   if(UNIX)
1264     set(LLVM_LINK_OR_COPY create_symlink)
1265     set(dest_binary "${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1266   else()
1267     set(LLVM_LINK_OR_COPY copy)
1268     set(dest_binary "${LLVM_RUNTIME_OUTPUT_INTDIR}/${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1269   endif()
1270
1271   set(output_path "${LLVM_RUNTIME_OUTPUT_INTDIR}/${name}${CMAKE_EXECUTABLE_SUFFIX}")
1272
1273   set(target_name ${name})
1274   if(TARGET ${name})
1275     set(target_name ${name}-link)
1276   endif()
1277
1278
1279   if(ARG_ALWAYS_GENERATE)
1280     set_property(DIRECTORY APPEND PROPERTY
1281       ADDITIONAL_MAKE_CLEAN_FILES ${dest_binary})
1282     add_custom_command(TARGET ${dest} POST_BUILD
1283       COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}")
1284   else()
1285     add_custom_command(OUTPUT ${output_path}
1286                      COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}"
1287                      DEPENDS ${dest})
1288     add_custom_target(${target_name} ALL DEPENDS ${output_path})
1289     set_target_properties(${target_name} PROPERTIES FOLDER Tools)
1290
1291     # Make sure both the link and target are toolchain tools
1292     if (${name} IN_LIST LLVM_TOOLCHAIN_TOOLS AND ${dest} IN_LIST LLVM_TOOLCHAIN_TOOLS)
1293       set(TOOL_IS_TOOLCHAIN ON)
1294     endif()
1295
1296     if ((TOOL_IS_TOOLCHAIN OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY) AND LLVM_BUILD_TOOLS)
1297       llvm_install_symlink(${name} ${dest})
1298     endif()
1299   endif()
1300 endfunction()
1301
1302 function(llvm_externalize_debuginfo name)
1303   if(NOT LLVM_EXTERNALIZE_DEBUGINFO)
1304     return()
1305   endif()
1306
1307   if(NOT LLVM_EXTERNALIZE_DEBUGINFO_SKIP_STRIP)
1308     set(strip_command COMMAND xcrun strip -Sxl $<TARGET_FILE:${name}>)
1309   endif()
1310
1311   if(APPLE)
1312     if(CMAKE_CXX_FLAGS MATCHES "-flto"
1313       OR CMAKE_CXX_FLAGS_${uppercase_CMAKE_BUILD_TYPE} MATCHES "-flto")
1314
1315       set(lto_object ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${name}-lto.o)
1316       set_property(TARGET ${name} APPEND_STRING PROPERTY
1317         LINK_FLAGS " -Wl,-object_path_lto,${lto_object}")
1318     endif()
1319     add_custom_command(TARGET ${name} POST_BUILD
1320       COMMAND xcrun dsymutil $<TARGET_FILE:${name}>
1321       ${strip_command}
1322       )
1323   else()
1324     message(FATAL_ERROR "LLVM_EXTERNALIZE_DEBUGINFO isn't implemented for non-darwin platforms!")
1325   endif()
1326 endfunction()
1327
1328 function(llvm_setup_rpath name)
1329   if(LLVM_INSTALL_PREFIX AND NOT (LLVM_INSTALL_PREFIX STREQUAL CMAKE_INSTALL_PREFIX))
1330     set(extra_libdir ${LLVM_LIBRARY_DIR})
1331   elseif(LLVM_BUILD_LIBRARY_DIR)
1332     set(extra_libdir ${LLVM_LIBRARY_DIR})
1333   endif()
1334
1335   if (APPLE)
1336     set(_install_name_dir INSTALL_NAME_DIR "@rpath")
1337     set(_install_rpath "@loader_path/../lib" ${extra_libdir})
1338   elseif(UNIX)
1339     if(NOT DEFINED CMAKE_INSTALL_RPATH)
1340       set(_install_rpath "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}" ${extra_libdir})
1341       if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
1342         set_property(TARGET ${name} APPEND_STRING PROPERTY
1343                      LINK_FLAGS " -Wl,-z,origin ")
1344       elseif(${CMAKE_SYSTEM_NAME} STREQUAL "Linux" AND NOT LLVM_LINKER_IS_GOLD)
1345         # $ORIGIN is not interpreted at link time by ld.bfd
1346         set_property(TARGET ${name} APPEND_STRING PROPERTY
1347                      LINK_FLAGS " -Wl,-rpath-link,${LLVM_LIBRARY_OUTPUT_INTDIR} ")
1348       endif()
1349     endif()
1350   else()
1351     return()
1352   endif()
1353
1354   set_target_properties(${name} PROPERTIES
1355                         BUILD_WITH_INSTALL_RPATH On
1356                         INSTALL_RPATH "${_install_rpath}"
1357                         ${_install_name_dir})
1358 endfunction()