cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3 include(DetermineGCCCompatible)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual targets can use to
  12   # force EH
  13   if(LLVM_REQUIRES_EH OR LLVM_ENABLE_EH)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18     if(MSVC)
  19       list(APPEND LLVM_COMPILE_FLAGS "/EHsc")
  20     endif()
  21   else()
  22     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  23       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  24     elseif(MSVC)
  25       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  26       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  27     endif()
  28   endif()
  29
  30   # LLVM_REQUIRES_RTTI is an internal flag that individual
  31   # targets can use to force RTTI
  32   set(LLVM_CONFIG_HAS_RTTI YES CACHE INTERNAL "")
  33   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  34     set(LLVM_CONFIG_HAS_RTTI NO CACHE INTERNAL "")
  35     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  36     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  37       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  38     elseif (MSVC)
  39       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  40     endif ()
  41   elseif(MSVC)
  42     list(APPEND LLVM_COMPILE_FLAGS "/GR")
  43   endif()
  44
  45   # Assume that;
  46   #   - LLVM_COMPILE_FLAGS is list.
  47   #   - PROPERTY COMPILE_FLAGS is string.
  48   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  49
  50   if(update_src_props)
  51     foreach(fn ${sources})
  52       get_filename_component(suf ${fn} EXT)
  53       if("${suf}" STREQUAL ".cpp")
  54         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  55           COMPILE_FLAGS "${target_compile_flags}")
  56       endif()
  57     endforeach()
  58   else()
  59     # Update target props, since all sources are C++.
  60     set_property(TARGET ${name} APPEND_STRING PROPERTY
  61       COMPILE_FLAGS "${target_compile_flags}")
  62   endif()
  63
  64   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  65 endfunction()
  66
  67 function(add_llvm_symbol_exports target_name export_file)
  68   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  69     set(native_export_file "${target_name}.exports")
  70     add_custom_command(OUTPUT ${native_export_file}
  71       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  72       DEPENDS ${export_file}
  73       VERBATIM
  74       COMMENT "Creating export file for ${target_name}")
  75     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  76                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  77   elseif(${CMAKE_SYSTEM_NAME} MATCHES "AIX")
  78     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  79                  LINK_FLAGS " -Wl,-bE:${export_file}")
  80   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  81     # Gold and BFD ld require a version script rather than a plain list.
  82     set(native_export_file "${target_name}.exports")
  83     # FIXME: Don't write the "local:" line on OpenBSD.
  84     add_custom_command(OUTPUT ${native_export_file}
  85       COMMAND echo "{" > ${native_export_file}
  86       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  87       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  88       COMMAND echo "  local: *;" >> ${native_export_file}
  89       COMMAND echo "};" >> ${native_export_file}
  90       DEPENDS ${export_file}
  91       VERBATIM
  92       COMMENT "Creating export file for ${target_name}")
  93     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  94       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  95                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  96     else()
  97       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  98                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  99     endif()
 100   else()
 101     set(native_export_file "${target_name}.def")
 102
 103     add_custom_command(OUTPUT ${native_export_file}
 104       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
 105         < ${export_file} > ${native_export_file}
 106       DEPENDS ${export_file}
 107       VERBATIM
 108       COMMENT "Creating export file for ${target_name}")
 109     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 110     if(MSVC)
 111       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 112     endif()
 113     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 114                  LINK_FLAGS " ${export_file_linker_flag}")
 115   endif()
 116
 117   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 118   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 119
 120   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 121   foreach(src ${srcs})
 122     get_filename_component(extension ${src} EXT)
 123     if(extension STREQUAL ".cpp")
 124       set(first_source_file ${src})
 125       break()
 126     endif()
 127   endforeach()
 128
 129   # Force re-linking when the exports file changes. Actually, it
 130   # forces recompilation of the source file. The LINK_DEPENDS target
 131   # property only works for makefile-based generators.
 132   # FIXME: This is not safe because this will create the same target
 133   # ${native_export_file} in several different file:
 134   # - One where we emitted ${target_name}_exports
 135   # - One where we emitted the build command for the following object.
 136   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 137   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 138
 139   set_property(DIRECTORY APPEND
 140     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 141
 142   add_dependencies(${target_name} ${target_name}_exports)
 143
 144   # Add dependency to *_exports later -- CMake issue 14747
 145   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 146   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 147 endfunction(add_llvm_symbol_exports)
 148
 149 if(NOT WIN32 AND NOT APPLE)
 150   execute_process(
 151     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 152     OUTPUT_VARIABLE stdout
 153     ERROR_QUIET
 154     )
 155   if("${stdout}" MATCHES "GNU gold")
 156     set(LLVM_LINKER_IS_GOLD ON)
 157   endif()
 158 endif()
 159
 160 function(add_link_opts target_name)
 161   # Don't use linker optimizations in debug builds since it slows down the
 162   # linker in a context where the optimizations are not important.
 163   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 164
 165     # Pass -O3 to the linker. This enabled different optimizations on different
 166     # linkers.
 167     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS|AIX" OR WIN32))
 168       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 169                    LINK_FLAGS " -Wl,-O3")
 170     endif()
 171
 172     if(LLVM_LINKER_IS_GOLD)
 173       # With gold gc-sections is always safe.
 174       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 175                    LINK_FLAGS " -Wl,--gc-sections")
 176       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 177       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 178     endif()
 179
 180     if(NOT LLVM_NO_DEAD_STRIP)
 181       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 182         # ld64's implementation of -dead_strip breaks tools that use plugins.
 183         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 184                      LINK_FLAGS " -Wl,-dead_strip")
 185       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 186         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 187                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 188       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 189         # Object files are compiled with -ffunction-data-sections.
 190         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 191         # tools that use plugins. Always pass --gc-sections once we require
 192         # a newer linker.
 193         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 194                      LINK_FLAGS " -Wl,--gc-sections")
 195       endif()
 196     endif()
 197   endif()
 198 endfunction(add_link_opts)
 199
 200 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 201 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 202 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 203 function(set_output_directory target)
 204   cmake_parse_arguments(ARG "" "BINARY_DIR;LIBRARY_DIR" "" ${ARGN})
 205
 206   # module_dir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 207   # It affects output of add_library(MODULE).
 208   if(WIN32 OR CYGWIN)
 209     # DLL platform
 210     set(module_dir ${ARG_BINARY_DIR})
 211   else()
 212     set(module_dir ${ARG_LIBRARY_DIR})
 213   endif()
 214   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 215     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 216       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 217       if(ARG_BINARY_DIR)
 218         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${ARG_BINARY_DIR})
 219         set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 220       endif()
 221       if(ARG_LIBRARY_DIR)
 222         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${ARG_LIBRARY_DIR})
 223         set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 224       endif()
 225       if(module_dir)
 226         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${module_dir})
 227         set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 228       endif()
 229     endforeach()
 230   else()
 231     if(ARG_BINARY_DIR)
 232       set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${ARG_BINARY_DIR})
 233     endif()
 234     if(ARG_LIBRARY_DIR)
 235       set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${ARG_LIBRARY_DIR})
 236     endif()
 237     if(module_dir)
 238       set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${module_dir})
 239     endif()
 240   endif()
 241 endfunction()
 242
 243 # If on Windows and building with MSVC, add the resource script containing the
 244 # VERSIONINFO data to the project.  This embeds version resource information
 245 # into the output .exe or .dll.
 246 # TODO: Enable for MinGW Windows builds too.
 247 #
 248 function(add_windows_version_resource_file OUT_VAR)
 249   set(sources ${ARGN})
 250   if (MSVC)
 251     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 252     if(EXISTS ${resource_file})
 253       set(sources ${sources} ${resource_file})
 254       source_group("Resource Files" ${resource_file})
 255       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 256     endif()
 257   endif(MSVC)
 258
 259   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 260 endfunction(add_windows_version_resource_file)
 261
 262 # set_windows_version_resource_properties(name resource_file...
 263 #   VERSION_MAJOR int
 264 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 265 #   VERSION_MINOR int
 266 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 267 #   VERSION_PATCHLEVEL int
 268 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 269 #   VERSION_STRING
 270 #     Optional version string (defaults to PACKAGE_VERSION)
 271 #   PRODUCT_NAME
 272 #     Optional product name string (defaults to "LLVM")
 273 #   )
 274 function(set_windows_version_resource_properties name resource_file)
 275   cmake_parse_arguments(ARG
 276     ""
 277     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 278     ""
 279     ${ARGN})
 280
 281   if (NOT DEFINED ARG_VERSION_MAJOR)
 282     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 283   endif()
 284
 285   if (NOT DEFINED ARG_VERSION_MINOR)
 286     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 287   endif()
 288
 289   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 290     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 291   endif()
 292
 293   if (NOT DEFINED ARG_VERSION_STRING)
 294     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 295   endif()
 296
 297   if (NOT DEFINED ARG_PRODUCT_NAME)
 298     set(ARG_PRODUCT_NAME "LLVM")
 299   endif()
 300
 301   set_property(SOURCE ${resource_file}
 302                PROPERTY COMPILE_FLAGS /nologo)
 303   set_property(SOURCE ${resource_file}
 304                PROPERTY COMPILE_DEFINITIONS
 305                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 306                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 307                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 308                "RC_VERSION_FIELD_4=0"
 309                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 310                "RC_INTERNAL_NAME=\"${name}\""
 311                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 312                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 313 endfunction(set_windows_version_resource_properties)
 314
 315 # llvm_add_library(name sources...
 316 #   SHARED;STATIC
 317 #     STATIC by default w/o BUILD_SHARED_LIBS.
 318 #     SHARED by default w/  BUILD_SHARED_LIBS.
 319 #   OBJECT
 320 #     Also create an OBJECT library target. Default if STATIC && SHARED.
 321 #   MODULE
 322 #     Target ${name} might not be created on unsupported platforms.
 323 #     Check with "if(TARGET ${name})".
 324 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 325 #     Do not link this library to libLLVM, even if
 326 #     LLVM_LINK_LLVM_DYLIB is enabled.
 327 #   OUTPUT_NAME name
 328 #     Corresponds to OUTPUT_NAME in target properties.
 329 #   DEPENDS targets...
 330 #     Same semantics as add_dependencies().
 331 #   LINK_COMPONENTS components...
 332 #     Same as the variable LLVM_LINK_COMPONENTS.
 333 #   LINK_LIBS lib_targets...
 334 #     Same semantics as target_link_libraries().
 335 #   ADDITIONAL_HEADERS
 336 #     May specify header files for IDE generators.
 337 #   SONAME
 338 #     Should set SONAME link flags and create symlinks
 339 #   PLUGIN_TOOL
 340 #     The tool (i.e. cmake target) that this plugin will link against
 341 #   )
 342 function(llvm_add_library name)
 343   cmake_parse_arguments(ARG
 344     "MODULE;SHARED;STATIC;OBJECT;DISABLE_LLVM_LINK_LLVM_DYLIB;SONAME"
 345     "OUTPUT_NAME;PLUGIN_TOOL"
 346     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 347     ${ARGN})
 348   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 349   if(ARG_ADDITIONAL_HEADERS)
 350     # Pass through ADDITIONAL_HEADERS.
 351     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 352   endif()
 353   if(ARG_OBJLIBS)
 354     set(ALL_FILES ${ARG_OBJLIBS})
 355   else()
 356     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 357   endif()
 358
 359   if(ARG_MODULE)
 360     if(ARG_SHARED OR ARG_STATIC)
 361       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 362     endif()
 363     # Plugins that link against a tool are allowed even when plugins in general are not
 364     if(NOT LLVM_ENABLE_PLUGINS AND NOT (ARG_PLUGIN_TOOL AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS))
 365       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 366       return()
 367     endif()
 368   else()
 369     if(ARG_PLUGIN_TOOL)
 370       message(WARNING "PLUGIN_TOOL without MODULE doesn't make sense.")
 371     endif()
 372     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 373       set(ARG_SHARED TRUE)
 374     endif()
 375     if(NOT ARG_SHARED)
 376       set(ARG_STATIC TRUE)
 377     endif()
 378   endif()
 379
 380   setup_dependency_debugging(${name} ${LLVM_COMMON_DEPENDS})
 381
 382   # Generate objlib
 383   if((ARG_SHARED AND ARG_STATIC) OR ARG_OBJECT)
 384     # Generate an obj library for both targets.
 385     set(obj_name "obj.${name}")
 386     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 387       ${ALL_FILES}
 388       )
 389     llvm_update_compile_flags(${obj_name})
 390     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 391
 392     # Do add_dependencies(obj) later due to CMake issue 14747.
 393     list(APPEND objlibs ${obj_name})
 394
 395     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 396   endif()
 397
 398   if(ARG_SHARED AND ARG_STATIC)
 399     # static
 400     set(name_static "${name}_static")
 401     if(ARG_OUTPUT_NAME)
 402       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 403     endif()
 404     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 405     llvm_add_library(${name_static} STATIC
 406       ${output_name}
 407       OBJLIBS ${ALL_FILES} # objlib
 408       LINK_LIBS ${ARG_LINK_LIBS}
 409       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 410       )
 411     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 412     set(ARG_STATIC)
 413   endif()
 414
 415   if(ARG_MODULE)
 416     add_library(${name} MODULE ${ALL_FILES})
 417   elseif(ARG_SHARED)
 418     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 419     add_library(${name} SHARED ${ALL_FILES})
 420
 421     llvm_setup_rpath(${name})
 422
 423   else()
 424     add_library(${name} STATIC ${ALL_FILES})
 425   endif()
 426
 427   if(DEFINED windows_resource_file)
 428     set_windows_version_resource_properties(${name} ${windows_resource_file})
 429     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 430   endif()
 431
 432   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 433   # $<TARGET_OBJECTS> doesn't require compile flags.
 434   if(NOT obj_name)
 435     llvm_update_compile_flags(${name})
 436   endif()
 437   add_link_opts( ${name} )
 438   if(ARG_OUTPUT_NAME)
 439     set_target_properties(${name}
 440       PROPERTIES
 441       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 442       )
 443   endif()
 444
 445   if(ARG_MODULE)
 446     set_target_properties(${name} PROPERTIES
 447       PREFIX ""
 448       SUFFIX ${LLVM_PLUGIN_EXT}
 449       )
 450   endif()
 451
 452   if(ARG_SHARED)
 453     if(WIN32)
 454       set_target_properties(${name} PROPERTIES
 455         PREFIX ""
 456         )
 457     endif()
 458
 459     # Set SOVERSION on shared libraries that lack explicit SONAME
 460     # specifier, on *nix systems that are not Darwin.
 461     if(UNIX AND NOT APPLE AND NOT ARG_SONAME)
 462       set_target_properties(${name}
 463         PROPERTIES
 464                 # Concatenate the version numbers since ldconfig expects exactly
 465                 # one component indicating the ABI version, while LLVM uses
 466                 # major+minor for that.
 467         SOVERSION ${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}
 468         VERSION ${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 469     endif()
 470   endif()
 471
 472   if(ARG_MODULE OR ARG_SHARED)
 473     # Do not add -Dname_EXPORTS to the command-line when building files in this
 474     # target. Doing so is actively harmful for the modules build because it
 475     # creates extra module variants, and not useful because we don't use these
 476     # macros.
 477     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 478
 479     if (LLVM_EXPORTED_SYMBOL_FILE)
 480       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 481     endif()
 482   endif()
 483
 484   if(ARG_SHARED AND UNIX)
 485     if(NOT APPLE AND ARG_SONAME)
 486       get_target_property(output_name ${name} OUTPUT_NAME)
 487       if(${output_name} STREQUAL "output_name-NOTFOUND")
 488         set(output_name ${name})
 489       endif()
 490       set(library_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}${LLVM_VERSION_SUFFIX})
 491       set(api_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 492       set_target_properties(${name} PROPERTIES OUTPUT_NAME ${library_name})
 493       llvm_install_library_symlink(${api_name} ${library_name} SHARED
 494         COMPONENT ${name}
 495         ALWAYS_GENERATE)
 496       llvm_install_library_symlink(${output_name} ${library_name} SHARED
 497         COMPONENT ${name}
 498         ALWAYS_GENERATE)
 499     endif()
 500   endif()
 501
 502   if(ARG_MODULE AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS AND ARG_PLUGIN_TOOL AND (WIN32 OR CYGWIN))
 503     # On DLL platforms symbols are imported from the tool by linking against it.
 504     set(llvm_libs ${ARG_PLUGIN_TOOL})
 505   elseif (DEFINED LLVM_LINK_COMPONENTS OR DEFINED ARG_LINK_COMPONENTS)
 506     if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 507       set(llvm_libs LLVM)
 508     else()
 509       llvm_map_components_to_libnames(llvm_libs
 510        ${ARG_LINK_COMPONENTS}
 511        ${LLVM_LINK_COMPONENTS}
 512        )
 513     endif()
 514   else()
 515     # Components have not been defined explicitly in CMake, so add the
 516     # dependency information for this library as defined by LLVMBuild.
 517     #
 518     # It would be nice to verify that we have the dependencies for this library
 519     # name, but using get_property(... SET) doesn't suffice to determine if a
 520     # property has been set to an empty value.
 521     get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 522   endif()
 523
 524   if(ARG_STATIC)
 525     set(libtype INTERFACE)
 526   else()
 527     # We can use PRIVATE since SO knows its dependent libs.
 528     set(libtype PRIVATE)
 529   endif()
 530
 531   target_link_libraries(${name} ${libtype}
 532       ${ARG_LINK_LIBS}
 533       ${lib_deps}
 534       ${llvm_libs}
 535       )
 536
 537   if(LLVM_COMMON_DEPENDS)
 538     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 539     # Add dependencies also to objlibs.
 540     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 541     foreach(objlib ${objlibs})
 542       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 543     endforeach()
 544   endif()
 545
 546   if(ARG_SHARED OR ARG_MODULE)
 547     llvm_externalize_debuginfo(${name})
 548   endif()
 549 endfunction()
 550
 551 macro(add_llvm_library name)
 552   cmake_parse_arguments(ARG
 553     "SHARED;BUILDTREE_ONLY"
 554     ""
 555     ""
 556     ${ARGN})
 557   if( BUILD_SHARED_LIBS OR ARG_SHARED )
 558     llvm_add_library(${name} SHARED ${ARG_UNPARSED_ARGUMENTS})
 559   else()
 560     llvm_add_library(${name} ${ARG_UNPARSED_ARGUMENTS})
 561   endif()
 562
 563   # Libraries that are meant to only be exposed via the build tree only are
 564   # never installed and are only exported as a target in the special build tree
 565   # config file.
 566   if (NOT ARG_BUILDTREE_ONLY)
 567     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 568   endif()
 569
 570   if( EXCLUDE_FROM_ALL )
 571     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 572   elseif(ARG_BUILDTREE_ONLY)
 573     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS_BUILDTREE_ONLY ${name})
 574   else()
 575     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO" OR
 576         (LLVM_LINK_LLVM_DYLIB AND ${name} STREQUAL "LLVM"))
 577       set(install_dir lib${LLVM_LIBDIR_SUFFIX})
 578       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 579         if(WIN32 OR CYGWIN OR MINGW)
 580           set(install_type RUNTIME)
 581           set(install_dir bin)
 582         else()
 583           set(install_type LIBRARY)
 584         endif()
 585       else()
 586         set(install_type ARCHIVE)
 587       endif()
 588
 589       if(${name} IN_LIST LLVM_DISTRIBUTION_COMPONENTS OR
 590           NOT LLVM_DISTRIBUTION_COMPONENTS)
 591         set(export_to_llvmexports EXPORT LLVMExports)
 592         set_property(GLOBAL PROPERTY LLVM_HAS_EXPORTS True)
 593       endif()
 594
 595       install(TARGETS ${name}
 596               ${export_to_llvmexports}
 597               ${install_type} DESTINATION ${install_dir}
 598               COMPONENT ${name})
 599
 600       if (NOT CMAKE_CONFIGURATION_TYPES)
 601         add_custom_target(install-${name}
 602                           DEPENDS ${name}
 603                           COMMAND "${CMAKE_COMMAND}"
 604                                   -DCMAKE_INSTALL_COMPONENT=${name}
 605                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 606       endif()
 607     endif()
 608     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 609   endif()
 610   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 611 endmacro(add_llvm_library name)
 612
 613 macro(add_llvm_loadable_module name)
 614   llvm_add_library(${name} MODULE ${ARGN})
 615   if(NOT TARGET ${name})
 616     # Add empty "phony" target
 617     add_custom_target(${name})
 618   else()
 619     if( EXCLUDE_FROM_ALL )
 620       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 621     else()
 622       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 623         if(WIN32 OR CYGWIN)
 624           # DLL platform
 625           set(dlldir "bin")
 626         else()
 627           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 628         endif()
 629
 630         if(${name} IN_LIST LLVM_DISTRIBUTION_COMPONENTS OR
 631             NOT LLVM_DISTRIBUTION_COMPONENTS)
 632           set(export_to_llvmexports EXPORT LLVMExports)
 633           set_property(GLOBAL PROPERTY LLVM_HAS_EXPORTS True)
 634         endif()
 635
 636         install(TARGETS ${name}
 637                 ${export_to_llvmexports}
 638                 LIBRARY DESTINATION ${dlldir}
 639                 ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 640       endif()
 641       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 642     endif()
 643   endif()
 644
 645   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 646 endmacro(add_llvm_loadable_module name)
 647
 648
 649 macro(add_llvm_executable name)
 650   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB;IGNORE_EXTERNALIZE_DEBUGINFO;NO_INSTALL_RPATH" "" "DEPENDS" ${ARGN})
 651   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 652
 653   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 654
 655   # Generate objlib
 656   if(LLVM_ENABLE_OBJLIB)
 657     # Generate an obj library for both targets.
 658     set(obj_name "obj.${name}")
 659     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 660       ${ALL_FILES}
 661       )
 662     llvm_update_compile_flags(${obj_name})
 663     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 664
 665     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 666   endif()
 667
 668   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 669
 670   if(XCODE)
 671     # Note: the dummy.cpp source file provides no definitions. However,
 672     # it forces Xcode to properly link the static library.
 673     list(APPEND ALL_FILES "${LLVM_MAIN_SRC_DIR}/cmake/dummy.cpp")
 674   endif()
 675
 676   setup_dependency_debugging(${name} ${LLVM_COMMON_DEPENDS})
 677
 678   if( EXCLUDE_FROM_ALL )
 679     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 680   else()
 681     add_executable(${name} ${ALL_FILES})
 682   endif()
 683
 684   if(NOT ARG_NO_INSTALL_RPATH)
 685     llvm_setup_rpath(${name})
 686   endif()
 687
 688   if(DEFINED windows_resource_file)
 689     set_windows_version_resource_properties(${name} ${windows_resource_file})
 690   endif()
 691
 692   # $<TARGET_OBJECTS> doesn't require compile flags.
 693   if(NOT LLVM_ENABLE_OBJLIB)
 694     llvm_update_compile_flags(${name})
 695   endif()
 696   add_link_opts( ${name} )
 697
 698   # Do not add -Dname_EXPORTS to the command-line when building files in this
 699   # target. Doing so is actively harmful for the modules build because it
 700   # creates extra module variants, and not useful because we don't use these
 701   # macros.
 702   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 703
 704   if (LLVM_EXPORTED_SYMBOL_FILE)
 705     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 706   endif(LLVM_EXPORTED_SYMBOL_FILE)
 707
 708   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 709     set(USE_SHARED USE_SHARED)
 710   endif()
 711
 712   set(EXCLUDE_FROM_ALL OFF)
 713   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 714   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 715   if( LLVM_COMMON_DEPENDS )
 716     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 717   endif( LLVM_COMMON_DEPENDS )
 718
 719   if(NOT ARG_IGNORE_EXTERNALIZE_DEBUGINFO)
 720     llvm_externalize_debuginfo(${name})
 721   endif()
 722   if (PTHREAD_LIB)
 723     # libpthreads overrides some standard library symbols, so main
 724     # executable must be linked with it in order to provide consistent
 725     # API for all shared libaries loaded by this executable.
 726     target_link_libraries(${name} ${PTHREAD_LIB})
 727   endif()
 728 endmacro(add_llvm_executable name)
 729
 730 function(export_executable_symbols target)
 731   if (LLVM_EXPORTED_SYMBOL_FILE)
 732     # The symbol file should contain the symbols we want the executable to
 733     # export
 734     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 735   elseif (LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 736     # Extract the symbols to export from the static libraries that the
 737     # executable links against.
 738     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 739     set(exported_symbol_file ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${target}.symbols)
 740     # We need to consider not just the direct link dependencies, but also the
 741     # transitive link dependencies. Do this by starting with the set of direct
 742     # dependencies, then the dependencies of those dependencies, and so on.
 743     get_target_property(new_libs ${target} LINK_LIBRARIES)
 744     set(link_libs ${new_libs})
 745     while(NOT "${new_libs}" STREQUAL "")
 746       foreach(lib ${new_libs})
 747         if(TARGET ${lib})
 748           get_target_property(lib_type ${lib} TYPE)
 749           if("${lib_type}" STREQUAL "STATIC_LIBRARY")
 750             list(APPEND static_libs ${lib})
 751           else()
 752             list(APPEND other_libs ${lib})
 753           endif()
 754           get_target_property(transitive_libs ${lib} INTERFACE_LINK_LIBRARIES)
 755           foreach(transitive_lib ${transitive_libs})
 756             list(FIND link_libs ${transitive_lib} idx)
 757             if(TARGET ${transitive_lib} AND idx EQUAL -1)
 758               list(APPEND newer_libs ${transitive_lib})
 759               list(APPEND link_libs ${transitive_lib})
 760             endif()
 761           endforeach(transitive_lib)
 762         endif()
 763       endforeach(lib)
 764       set(new_libs ${newer_libs})
 765       set(newer_libs "")
 766     endwhile()
 767     if (MSVC)
 768       set(mangling microsoft)
 769     else()
 770       set(mangling itanium)
 771     endif()
 772     add_custom_command(OUTPUT ${exported_symbol_file}
 773                        COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/extract_symbols.py --mangling=${mangling} ${static_libs} -o ${exported_symbol_file}
 774                        WORKING_DIRECTORY ${LLVM_LIBRARY_OUTPUT_INTDIR}
 775                        DEPENDS ${LLVM_MAIN_SRC_DIR}/utils/extract_symbols.py ${static_libs}
 776                        VERBATIM
 777                        COMMENT "Generating export list for ${target}")
 778     add_llvm_symbol_exports( ${target} ${exported_symbol_file} )
 779     # If something links against this executable then we want a
 780     # transitive link against only the libraries whose symbols
 781     # we aren't exporting.
 782     set_target_properties(${target} PROPERTIES INTERFACE_LINK_LIBRARIES "${other_libs}")
 783     # The default import library suffix that cmake uses for cygwin/mingw is
 784     # ".dll.a", but for clang.exe that causes a collision with libclang.dll,
 785     # where the import libraries of both get named libclang.dll.a. Use a suffix
 786     # of ".exe.a" to avoid this.
 787     if(CYGWIN OR MINGW)
 788       set_target_properties(${target} PROPERTIES IMPORT_SUFFIX ".exe.a")
 789     endif()
 790   elseif(NOT (WIN32 OR CYGWIN))
 791     # On Windows auto-exporting everything doesn't work because of the limit on
 792     # the size of the exported symbol table, but on other platforms we can do
 793     # it without any trouble.
 794     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 795     if (APPLE)
 796       set_property(TARGET ${target} APPEND_STRING PROPERTY
 797         LINK_FLAGS " -rdynamic")
 798     endif()
 799   endif()
 800 endfunction()
 801
 802 if(NOT LLVM_TOOLCHAIN_TOOLS)
 803   set (LLVM_TOOLCHAIN_TOOLS
 804     llvm-ar
 805     llvm-ranlib
 806     llvm-lib
 807     llvm-objdump
 808     )
 809 endif()
 810
 811 macro(add_llvm_tool name)
 812   if( NOT LLVM_BUILD_TOOLS )
 813     set(EXCLUDE_FROM_ALL ON)
 814   endif()
 815   add_llvm_executable(${name} ${ARGN})
 816
 817   if ( ${name} IN_LIST LLVM_TOOLCHAIN_TOOLS OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 818     if( LLVM_BUILD_TOOLS )
 819       if(${name} IN_LIST LLVM_DISTRIBUTION_COMPONENTS OR
 820           NOT LLVM_DISTRIBUTION_COMPONENTS)
 821         set(export_to_llvmexports EXPORT LLVMExports)
 822         set_property(GLOBAL PROPERTY LLVM_HAS_EXPORTS True)
 823       endif()
 824
 825       install(TARGETS ${name}
 826               ${export_to_llvmexports}
 827               RUNTIME DESTINATION ${LLVM_TOOLS_INSTALL_DIR}
 828               COMPONENT ${name})
 829
 830       if (NOT CMAKE_CONFIGURATION_TYPES)
 831         add_custom_target(install-${name}
 832                           DEPENDS ${name}
 833                           COMMAND "${CMAKE_COMMAND}"
 834                                   -DCMAKE_INSTALL_COMPONENT=${name}
 835                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 836       endif()
 837     endif()
 838   endif()
 839   if( LLVM_BUILD_TOOLS )
 840     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 841   endif()
 842   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 843 endmacro(add_llvm_tool name)
 844
 845
 846 macro(add_llvm_example name)
 847   if( NOT LLVM_BUILD_EXAMPLES )
 848     set(EXCLUDE_FROM_ALL ON)
 849   endif()
 850   add_llvm_executable(${name} ${ARGN})
 851   if( LLVM_BUILD_EXAMPLES )
 852     install(TARGETS ${name} RUNTIME DESTINATION examples)
 853   endif()
 854   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 855 endmacro(add_llvm_example name)
 856
 857 # This is a macro that is used to create targets for executables that are needed
 858 # for development, but that are not intended to be installed by default.
 859 macro(add_llvm_utility name)
 860   if ( NOT LLVM_BUILD_UTILS )
 861     set(EXCLUDE_FROM_ALL ON)
 862   endif()
 863
 864   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 865   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 866   if( LLVM_INSTALL_UTILS AND LLVM_BUILD_UTILS )
 867     install (TARGETS ${name}
 868       RUNTIME DESTINATION bin
 869       COMPONENT ${name})
 870     if (NOT CMAKE_CONFIGURATION_TYPES)
 871       add_custom_target(install-${name}
 872                         DEPENDS ${name}
 873                         COMMAND "${CMAKE_COMMAND}"
 874                                 -DCMAKE_INSTALL_COMPONENT=${name}
 875                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 876     endif()
 877   endif()
 878 endmacro(add_llvm_utility name)
 879
 880
 881 macro(add_llvm_target target_name)
 882   include_directories(BEFORE
 883     ${CMAKE_CURRENT_BINARY_DIR}
 884     ${CMAKE_CURRENT_SOURCE_DIR})
 885   add_llvm_library(LLVM${target_name} ${ARGN})
 886   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 887 endmacro(add_llvm_target)
 888
 889 function(canonicalize_tool_name name output)
 890   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 891   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 892   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 893   set(${output} "${nameUPPER}" PARENT_SCOPE)
 894 endfunction(canonicalize_tool_name)
 895
 896 # Custom add_subdirectory wrapper
 897 # Takes in a project name (i.e. LLVM), the subdirectory name, and an optional
 898 # path if it differs from the name.
 899 macro(add_llvm_subdirectory project type name)
 900   set(add_llvm_external_dir "${ARGN}")
 901   if("${add_llvm_external_dir}" STREQUAL "")
 902     set(add_llvm_external_dir ${name})
 903   endif()
 904   canonicalize_tool_name(${name} nameUPPER)
 905   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 906     # Treat it as in-tree subproject.
 907     option(${project}_${type}_${nameUPPER}_BUILD
 908            "Whether to build ${name} as part of ${project}" On)
 909     mark_as_advanced(${project}_${type}_${name}_BUILD)
 910     if(${project}_${type}_${nameUPPER}_BUILD)
 911       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 912       # Don't process it in add_llvm_implicit_projects().
 913       set(${project}_${type}_${nameUPPER}_BUILD OFF)
 914     endif()
 915   else()
 916     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 917       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 918       CACHE PATH "Path to ${name} source directory")
 919     set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT ON)
 920     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 921       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 922     endif()
 923     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 924       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 925     endif()
 926     option(${project}_${type}_${nameUPPER}_BUILD
 927       "Whether to build ${name} as part of LLVM"
 928       ${${project}_${type}_${nameUPPER}_BUILD_DEFAULT})
 929     if (${project}_${type}_${nameUPPER}_BUILD)
 930       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 931         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 932       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 933         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 934       endif()
 935       # FIXME: It'd be redundant.
 936       set(${project}_${type}_${nameUPPER}_BUILD Off)
 937     endif()
 938   endif()
 939 endmacro()
 940
 941 # Add external project that may want to be built as part of llvm such as Clang,
 942 # lld, and Polly. This adds two options. One for the source directory of the
 943 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 944 # enable or disable building it with everything else.
 945 # Additional parameter can be specified as the name of directory.
 946 macro(add_llvm_external_project name)
 947   add_llvm_subdirectory(LLVM TOOL ${name} ${ARGN})
 948 endmacro()
 949
 950 macro(add_llvm_tool_subdirectory name)
 951   add_llvm_external_project(${name})
 952 endmacro(add_llvm_tool_subdirectory)
 953
 954 function(get_project_name_from_src_var var output)
 955   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 956          MACHED_TOOL "${var}")
 957   if(MACHED_TOOL)
 958     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 959   else()
 960     set(${output} PARENT_SCOPE)
 961   endif()
 962 endfunction()
 963
 964 function(create_subdirectory_options project type)
 965   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 966   foreach(dir ${sub-dirs})
 967     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 968       canonicalize_tool_name(${dir} name)
 969       option(${project}_${type}_${name}_BUILD
 970            "Whether to build ${name} as part of ${project}" On)
 971       mark_as_advanced(${project}_${type}_${name}_BUILD)
 972     endif()
 973   endforeach()
 974 endfunction(create_subdirectory_options)
 975
 976 function(create_llvm_tool_options)
 977   create_subdirectory_options(LLVM TOOL)
 978 endfunction(create_llvm_tool_options)
 979
 980 function(llvm_add_implicit_projects project)
 981   set(list_of_implicit_subdirs "")
 982   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 983   foreach(dir ${sub-dirs})
 984     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 985       canonicalize_tool_name(${dir} name)
 986       if (${project}_TOOL_${name}_BUILD)
 987         get_filename_component(fn "${dir}" NAME)
 988         list(APPEND list_of_implicit_subdirs "${fn}")
 989       endif()
 990     endif()
 991   endforeach()
 992
 993   foreach(external_proj ${list_of_implicit_subdirs})
 994     add_llvm_subdirectory(${project} TOOL "${external_proj}" ${ARGN})
 995   endforeach()
 996 endfunction(llvm_add_implicit_projects)
 997
 998 function(add_llvm_implicit_projects)
 999   llvm_add_implicit_projects(LLVM)
1000 endfunction(add_llvm_implicit_projects)
1001
1002 # Generic support for adding a unittest.
1003 function(add_unittest test_suite test_name)
1004   if( NOT LLVM_BUILD_TESTS )
1005     set(EXCLUDE_FROM_ALL ON)
1006   endif()
1007
1008   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
1009   if (NOT LLVM_ENABLE_THREADS)
1010     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
1011   endif ()
1012
1013   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
1014     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
1015   endif ()
1016
1017   set(LLVM_REQUIRES_RTTI OFF)
1018
1019   list(APPEND LLVM_LINK_COMPONENTS Support) # gtest needs it for raw_ostream
1020   add_llvm_executable(${test_name} IGNORE_EXTERNALIZE_DEBUGINFO NO_INSTALL_RPATH ${ARGN})
1021   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
1022   set_output_directory(${test_name} BINARY_DIR ${outdir} LIBRARY_DIR ${outdir})
1023   # libpthreads overrides some standard library symbols, so main
1024   # executable must be linked with it in order to provide consistent
1025   # API for all shared libaries loaded by this executable.
1026   target_link_libraries(${test_name} gtest_main gtest ${PTHREAD_LIB})
1027
1028   add_dependencies(${test_suite} ${test_name})
1029   get_target_property(test_suite_folder ${test_suite} FOLDER)
1030   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
1031     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
1032   endif ()
1033 endfunction()
1034
1035 function(llvm_add_go_executable binary pkgpath)
1036   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
1037
1038   if(LLVM_BINDINGS MATCHES "go")
1039     # FIXME: This should depend only on the libraries Go needs.
1040     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
1041     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
1042     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
1043     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1044     set(cppflags "")
1045     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
1046     foreach(d ${include_dirs})
1047       set(cppflags "${cppflags} -I${d}")
1048     endforeach(d)
1049     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
1050     add_custom_command(OUTPUT ${binpath}
1051       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "packages=${LLVM_GO_PACKAGES}"
1052               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
1053       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
1054               ${llvmlibs} ${ARG_DEPENDS}
1055       COMMENT "Building Go executable ${binary}"
1056       VERBATIM)
1057     if (ARG_ALL)
1058       add_custom_target(${binary} ALL DEPENDS ${binpath})
1059     else()
1060       add_custom_target(${binary} DEPENDS ${binpath})
1061     endif()
1062   endif()
1063 endfunction()
1064
1065 # This function provides an automatic way to 'configure'-like generate a file
1066 # based on a set of common and custom variables, specifically targeting the
1067 # variables needed for the 'lit.site.cfg' files. This function bundles the
1068 # common variables that any Lit instance is likely to need, and custom
1069 # variables can be passed in.
1070 function(configure_lit_site_cfg input output)
1071   foreach(c ${LLVM_TARGETS_TO_BUILD})
1072     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
1073   endforeach(c)
1074   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
1075
1076   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
1077
1078   # Configuration-time: See Unit/lit.site.cfg.in
1079   if (CMAKE_CFG_INTDIR STREQUAL ".")
1080     set(LLVM_BUILD_MODE ".")
1081   else ()
1082     set(LLVM_BUILD_MODE "%(build_mode)s")
1083   endif ()
1084
1085   # They below might not be the build tree but provided binary tree.
1086   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
1087   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
1088   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
1089   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
1090
1091   # SHLIBDIR points the build tree.
1092   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
1093
1094   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
1095   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
1096   # plugins. We may rename it.
1097   if(LLVM_ENABLE_PLUGINS)
1098     set(ENABLE_SHARED "1")
1099   else()
1100     set(ENABLE_SHARED "0")
1101   endif()
1102
1103   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
1104     set(ENABLE_ASSERTIONS "1")
1105   else()
1106     set(ENABLE_ASSERTIONS "0")
1107   endif()
1108
1109   set(HOST_OS ${CMAKE_SYSTEM_NAME})
1110   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
1111
1112   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
1113   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1114   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
1115
1116   set(LIT_SITE_CFG_IN_HEADER  "## Autogenerated from ${input}\n## Do not edit!")
1117
1118   configure_file(${input} ${output} @ONLY)
1119 endfunction()
1120
1121 # A raw function to create a lit target. This is used to implement the testuite
1122 # management functions.
1123 function(add_lit_target target comment)
1124   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1125   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
1126   separate_arguments(LIT_ARGS)
1127   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
1128     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
1129   endif ()
1130   if (EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
1131     # reset cache after erraneous r283029
1132     # TODO: remove this once all buildbots run
1133     if (LIT_COMMAND STREQUAL "${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py")
1134       unset(LIT_COMMAND CACHE)
1135     endif()
1136     set (LIT_COMMAND "${PYTHON_EXECUTABLE};${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py"
1137          CACHE STRING "Command used to spawn llvm-lit")
1138   else()
1139     find_program(LIT_COMMAND NAMES llvm-lit lit.py lit)
1140   endif ()
1141   list(APPEND LIT_COMMAND ${LIT_ARGS})
1142   foreach(param ${ARG_PARAMS})
1143     list(APPEND LIT_COMMAND --param ${param})
1144   endforeach()
1145   if (ARG_UNPARSED_ARGUMENTS)
1146     add_custom_target(${target}
1147       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
1148       COMMENT "${comment}"
1149       USES_TERMINAL
1150       )
1151   else()
1152     add_custom_target(${target}
1153       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
1154     message(STATUS "${target} does nothing.")
1155   endif()
1156   if (ARG_DEPENDS)
1157     add_dependencies(${target} ${ARG_DEPENDS})
1158   endif()
1159
1160   # Tests should be excluded from "Build Solution".
1161   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
1162 endfunction()
1163
1164 # A function to add a set of lit test suites to be driven through 'check-*' targets.
1165 function(add_lit_testsuite target comment)
1166   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1167
1168   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
1169   if(NOT EXCLUDE_FROM_ALL)
1170     # Register the testsuites, params and depends for the global check rule.
1171     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
1172     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
1173     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
1174     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
1175   endif()
1176
1177   # Produce a specific suffixed check rule.
1178   add_lit_target(${target} ${comment}
1179     ${ARG_UNPARSED_ARGUMENTS}
1180     PARAMS ${ARG_PARAMS}
1181     DEPENDS ${ARG_DEPENDS}
1182     ARGS ${ARG_ARGS}
1183     )
1184 endfunction()
1185
1186 function(add_lit_testsuites project directory)
1187   if (NOT CMAKE_CONFIGURATION_TYPES)
1188     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1189
1190     # Search recursively for test directories by assuming anything not
1191     # in a directory called Inputs contains tests.
1192     file(GLOB_RECURSE to_process LIST_DIRECTORIES true ${directory}/*)
1193     foreach(lit_suite ${to_process})
1194       if(NOT IS_DIRECTORY ${lit_suite})
1195         continue()
1196       endif()
1197       string(FIND ${lit_suite} Inputs is_inputs)
1198       string(FIND ${lit_suite} Output is_output)
1199       if (NOT (is_inputs EQUAL -1 AND is_output EQUAL -1))
1200         continue()
1201       endif()
1202
1203       # Create a check- target for the directory.
1204       string(REPLACE ${directory} "" name_slash ${lit_suite})
1205       if (name_slash)
1206         string(REPLACE "/" "-" name_slash ${name_slash})
1207         string(REPLACE "\\" "-" name_dashes ${name_slash})
1208         string(TOLOWER "${project}${name_dashes}" name_var)
1209         add_lit_target("check-${name_var}" "Running lit suite ${lit_suite}"
1210           ${lit_suite}
1211           PARAMS ${ARG_PARAMS}
1212           DEPENDS ${ARG_DEPENDS}
1213           ARGS ${ARG_ARGS}
1214         )
1215       endif()
1216     endforeach()
1217   endif()
1218 endfunction()
1219
1220 function(llvm_install_library_symlink name dest type)
1221   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "COMPONENT" "" ${ARGN})
1222   foreach(path ${CMAKE_MODULE_PATH})
1223     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1224       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1225       break()
1226     endif()
1227   endforeach()
1228
1229   set(component ${ARG_COMPONENT})
1230   if(NOT component)
1231     set(component ${name})
1232   endif()
1233
1234   set(full_name ${CMAKE_${type}_LIBRARY_PREFIX}${name}${CMAKE_${type}_LIBRARY_SUFFIX})
1235   set(full_dest ${CMAKE_${type}_LIBRARY_PREFIX}${dest}${CMAKE_${type}_LIBRARY_SUFFIX})
1236
1237   set(output_dir lib${LLVM_LIBDIR_SUFFIX})
1238   if(WIN32 AND "${type}" STREQUAL "SHARED")
1239     set(output_dir bin)
1240   endif()
1241
1242   install(SCRIPT ${INSTALL_SYMLINK}
1243           CODE "install_symlink(${full_name} ${full_dest} ${output_dir})"
1244           COMPONENT ${component})
1245
1246   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1247     add_custom_target(install-${name}
1248                       DEPENDS ${name} ${dest} install-${dest}
1249                       COMMAND "${CMAKE_COMMAND}"
1250                               -DCMAKE_INSTALL_COMPONENT=${name}
1251                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1252   endif()
1253 endfunction()
1254
1255 function(llvm_install_symlink name dest)
1256   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1257   foreach(path ${CMAKE_MODULE_PATH})
1258     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1259       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1260       break()
1261     endif()
1262   endforeach()
1263
1264   if(ARG_ALWAYS_GENERATE)
1265     set(component ${dest})
1266   else()
1267     set(component ${name})
1268   endif()
1269
1270   set(full_name ${name}${CMAKE_EXECUTABLE_SUFFIX})
1271   set(full_dest ${dest}${CMAKE_EXECUTABLE_SUFFIX})
1272
1273   install(SCRIPT ${INSTALL_SYMLINK}
1274           CODE "install_symlink(${full_name} ${full_dest} ${LLVM_TOOLS_INSTALL_DIR})"
1275           COMPONENT ${component})
1276
1277   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1278     add_custom_target(install-${name}
1279                       DEPENDS ${name} ${dest} install-${dest}
1280                       COMMAND "${CMAKE_COMMAND}"
1281                               -DCMAKE_INSTALL_COMPONENT=${name}
1282                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1283   endif()
1284 endfunction()
1285
1286 function(add_llvm_tool_symlink name dest)
1287   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1288   if(UNIX)
1289     set(LLVM_LINK_OR_COPY create_symlink)
1290     set(dest_binary "${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1291   else()
1292     set(LLVM_LINK_OR_COPY copy)
1293     set(dest_binary "${LLVM_RUNTIME_OUTPUT_INTDIR}/${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1294   endif()
1295
1296   set(output_path "${LLVM_RUNTIME_OUTPUT_INTDIR}/${name}${CMAKE_EXECUTABLE_SUFFIX}")
1297
1298   set(target_name ${name})
1299   if(TARGET ${name})
1300     set(target_name ${name}-link)
1301   endif()
1302
1303
1304   if(ARG_ALWAYS_GENERATE)
1305     set_property(DIRECTORY APPEND PROPERTY
1306       ADDITIONAL_MAKE_CLEAN_FILES ${dest_binary})
1307     add_custom_command(TARGET ${dest} POST_BUILD
1308       COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}")
1309   else()
1310     add_custom_command(OUTPUT ${output_path}
1311                      COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}"
1312                      DEPENDS ${dest})
1313     add_custom_target(${target_name} ALL DEPENDS ${output_path})
1314     set_target_properties(${target_name} PROPERTIES FOLDER Tools)
1315
1316     # Make sure both the link and target are toolchain tools
1317     if (${name} IN_LIST LLVM_TOOLCHAIN_TOOLS AND ${dest} IN_LIST LLVM_TOOLCHAIN_TOOLS)
1318       set(TOOL_IS_TOOLCHAIN ON)
1319     endif()
1320
1321     if ((TOOL_IS_TOOLCHAIN OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY) AND LLVM_BUILD_TOOLS)
1322       llvm_install_symlink(${name} ${dest})
1323     endif()
1324   endif()
1325 endfunction()
1326
1327 function(llvm_externalize_debuginfo name)
1328   if(NOT LLVM_EXTERNALIZE_DEBUGINFO)
1329     return()
1330   endif()
1331
1332   if(NOT LLVM_EXTERNALIZE_DEBUGINFO_SKIP_STRIP)
1333     set(strip_command COMMAND xcrun strip -Sxl $<TARGET_FILE:${name}>)
1334   endif()
1335
1336   if(APPLE)
1337     if(CMAKE_CXX_FLAGS MATCHES "-flto"
1338       OR CMAKE_CXX_FLAGS_${uppercase_CMAKE_BUILD_TYPE} MATCHES "-flto")
1339
1340       set(lto_object ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${name}-lto.o)
1341       set_property(TARGET ${name} APPEND_STRING PROPERTY
1342         LINK_FLAGS " -Wl,-object_path_lto,${lto_object}")
1343     endif()
1344     add_custom_command(TARGET ${name} POST_BUILD
1345       COMMAND xcrun dsymutil $<TARGET_FILE:${name}>
1346       ${strip_command}
1347       )
1348   else()
1349     message(FATAL_ERROR "LLVM_EXTERNALIZE_DEBUGINFO isn't implemented for non-darwin platforms!")
1350   endif()
1351 endfunction()
1352
1353 function(llvm_setup_rpath name)
1354   if(CMAKE_INSTALL_RPATH)
1355     return()
1356   endif()
1357
1358   if(LLVM_INSTALL_PREFIX AND NOT (LLVM_INSTALL_PREFIX STREQUAL CMAKE_INSTALL_PREFIX))
1359     set(extra_libdir ${LLVM_LIBRARY_DIR})
1360   elseif(LLVM_BUILD_LIBRARY_DIR)
1361     set(extra_libdir ${LLVM_LIBRARY_DIR})
1362   endif()
1363
1364   if (APPLE)
1365     set(_install_name_dir INSTALL_NAME_DIR "@rpath")
1366     set(_install_rpath "@loader_path/../lib" ${extra_libdir})
1367   elseif(UNIX)
1368     set(_install_rpath "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}" ${extra_libdir})
1369     if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
1370       set_property(TARGET ${name} APPEND_STRING PROPERTY
1371                    LINK_FLAGS " -Wl,-z,origin ")
1372     elseif(${CMAKE_SYSTEM_NAME} STREQUAL "Linux" AND NOT LLVM_LINKER_IS_GOLD)
1373       # $ORIGIN is not interpreted at link time by ld.bfd
1374       set_property(TARGET ${name} APPEND_STRING PROPERTY
1375                    LINK_FLAGS " -Wl,-rpath-link,${LLVM_LIBRARY_OUTPUT_INTDIR} ")
1376     endif()
1377   else()
1378     return()
1379   endif()
1380
1381   set_target_properties(${name} PROPERTIES
1382                         BUILD_WITH_INSTALL_RPATH On
1383                         INSTALL_RPATH "${_install_rpath}"
1384                         ${_install_name_dir})
1385 endfunction()
1386
1387 function(setup_dependency_debugging name)
1388   if(NOT LLVM_DEPENDENCY_DEBUGGING)
1389     return()
1390   endif()
1391
1392   if("intrinsics_gen" IN_LIST ARGN)
1393     return()
1394   endif()
1395
1396   set(deny_attributes_gen "(deny file* (literal \"${LLVM_BINARY_DIR}/include/llvm/IR/Attributes.gen\"))")
1397   set(deny_intrinsics_gen "(deny file* (literal \"${LLVM_BINARY_DIR}/include/llvm/IR/Intrinsics.gen\"))")
1398
1399   set(sandbox_command "sandbox-exec -p '(version 1) (allow default) ${deny_attributes_gen} ${deny_intrinsics_gen}'")
1400   set_property(DIRECTORY PROPERTY RULE_LAUNCH_COMPILE ${sandbox_command})
1401 endfunction()