cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(CheckCompilerVersion)
  10 include(HandleLLVMStdlib)
  11 include(CheckCCompilerFlag)
  12 include(CheckCXXCompilerFlag)
  13
  14 if(CMAKE_LINKER MATCHES "lld-link\.exe" OR (WIN32 AND LLVM_USE_LINKER STREQUAL "lld") OR LLVM_ENABLE_LLD)
  15   set(LINKER_IS_LLD_LINK TRUE)
  16 else()
  17   set(LINKER_IS_LLD_LINK FALSE)
  18 endif()
  19
  20 set(LLVM_ENABLE_LTO OFF CACHE STRING "Build LLVM with LTO. May be specified as Thin or Full to use a particular kind of LTO")
  21 string(TOUPPER "${LLVM_ENABLE_LTO}" uppercase_LLVM_ENABLE_LTO)
  22
  23 # Ninja Job Pool support
  24 # The following only works with the Ninja generator in CMake >= 3.0.
  25 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  26   "Define the maximum number of concurrent compilation jobs (Ninja only).")
  27 if(LLVM_PARALLEL_COMPILE_JOBS)
  28   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
  29     message(WARNING "Job pooling is only available with Ninja generators.")
  30   else()
  31     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  32     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  33   endif()
  34 endif()
  35
  36 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  37   "Define the maximum number of concurrent link jobs (Ninja only).")
  38 if(CMAKE_MAKE_PROGRAM MATCHES "ninja")
  39   if(NOT LLVM_PARALLEL_LINK_JOBS AND uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
  40     message(STATUS "ThinLTO provides its own parallel linking - limiting parallel link jobs to 2.")
  41     set(LLVM_PARALLEL_LINK_JOBS "2")
  42   endif()
  43   if(LLVM_PARALLEL_LINK_JOBS)
  44     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  45     set(CMAKE_JOB_POOL_LINK link_job_pool)
  46   endif()
  47 elseif(LLVM_PARALLEL_LINK_JOBS)
  48   message(WARNING "Job pooling is only available with Ninja generators.")
  49 endif()
  50
  51 if( LLVM_ENABLE_ASSERTIONS )
  52   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  53   if( NOT MSVC )
  54     add_definitions( -D_DEBUG )
  55   endif()
  56   # On non-Debug builds cmake automatically defines NDEBUG, so we
  57   # explicitly undefine it:
  58   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  59     add_definitions( -UNDEBUG )
  60     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  61     foreach (flags_var_to_scrub
  62         CMAKE_CXX_FLAGS_RELEASE
  63         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  64         CMAKE_CXX_FLAGS_MINSIZEREL
  65         CMAKE_C_FLAGS_RELEASE
  66         CMAKE_C_FLAGS_RELWITHDEBINFO
  67         CMAKE_C_FLAGS_MINSIZEREL)
  68       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  69         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  70     endforeach()
  71   endif()
  72 endif()
  73
  74 if(LLVM_ENABLE_EXPENSIVE_CHECKS)
  75   add_definitions(-DEXPENSIVE_CHECKS)
  76   add_definitions(-D_GLIBCXX_DEBUG)
  77 endif()
  78
  79 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
  80
  81 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
  82   if( LLVM_ENABLE_ASSERTIONS )
  83     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  84   endif()
  85 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
  86   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  87 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
  88   # We don't need to do anything special to turn off ABI breaking checks.
  89 elseif( NOT DEFINED LLVM_ABI_BREAKING_CHECKS )
  90   # Treat LLVM_ABI_BREAKING_CHECKS like "FORCE_OFF" when it has not been
  91   # defined.
  92 else()
  93   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
  94 endif()
  95
  96 if( LLVM_REVERSE_ITERATION )
  97   set( LLVM_ENABLE_REVERSE_ITERATION 1 )
  98 endif()
  99
 100 if(WIN32)
 101   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 102   if(CYGWIN)
 103     set(LLVM_ON_WIN32 0)
 104     set(LLVM_ON_UNIX 1)
 105   else(CYGWIN)
 106     set(LLVM_ON_WIN32 1)
 107     set(LLVM_ON_UNIX 0)
 108   endif(CYGWIN)
 109 else(WIN32)
 110   if(FUCHSIA OR UNIX)
 111     set(LLVM_ON_WIN32 0)
 112     set(LLVM_ON_UNIX 1)
 113     if(APPLE OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 114       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 115     else()
 116       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
 117     endif()
 118   else(FUCHSIA OR UNIX)
 119     MESSAGE(SEND_ERROR "Unable to determine platform")
 120   endif(FUCHSIA OR UNIX)
 121 endif(WIN32)
 122
 123 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 124 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 125
 126 # We use *.dylib rather than *.so on darwin.
 127 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 128
 129 if(APPLE)
 130   if(LLVM_ENABLE_LLD AND LLVM_ENABLE_LTO)
 131     message(FATAL_ERROR "lld does not support LTO on Darwin")
 132   endif()
 133   # Darwin-specific linker flags for loadable modules.
 134   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 135 endif()
 136
 137 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 138 # build might work on ELF but fail on MachO/COFF.
 139 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32 OR CYGWIN OR
 140         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD" OR
 141         ${CMAKE_SYSTEM_NAME} MATCHES "OpenBSD" OR
 142         ${CMAKE_SYSTEM_NAME} MATCHES "DragonFly") AND
 143    NOT LLVM_USE_SANITIZER)
 144   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 145 endif()
 146
 147 # Pass -Wl,-z,nodelete. This makes sure our shared libraries are not unloaded
 148 # by dlclose(). We need that since the CLI API relies on cross-references
 149 # between global objects which became horribly broken when one of the libraries
 150 # is unloaded.
 151 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 152   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,nodelete")
 153   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-z,nodelete")
 154 endif()
 155
 156
 157 function(append value)
 158   foreach(variable ${ARGN})
 159     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 160   endforeach(variable)
 161 endfunction()
 162
 163 function(append_if condition value)
 164   if (${condition})
 165     foreach(variable ${ARGN})
 166       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 167     endforeach(variable)
 168   endif()
 169 endfunction()
 170
 171 macro(add_flag_if_supported flag name)
 172   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 173   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 174   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 175   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 176 endmacro()
 177
 178 function(add_flag_or_print_warning flag name)
 179   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 180   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 181   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 182     message(STATUS "Building with ${flag}")
 183     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 184     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 185     set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} ${flag}" PARENT_SCOPE)
 186   else()
 187     message(WARNING "${flag} is not supported.")
 188   endif()
 189 endfunction()
 190
 191 if( LLVM_ENABLE_LLD )
 192         if ( LLVM_USE_LINKER )
 193                 message(FATAL_ERROR "LLVM_ENABLE_LLD and LLVM_USE_LINKER can't be set at the same time")
 194         endif()
 195         set(LLVM_USE_LINKER "lld")
 196 endif()
 197
 198 if( LLVM_USE_LINKER )
 199   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 200   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fuse-ld=${LLVM_USE_LINKER}")
 201   check_cxx_source_compiles("int main() { return 0; }" CXX_SUPPORTS_CUSTOM_LINKER)
 202   if ( NOT CXX_SUPPORTS_CUSTOM_LINKER )
 203           message(FATAL_ERROR "Host compiler does not support '-fuse-ld=${LLVM_USE_LINKER}'")
 204   endif()
 205   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 206   append("-fuse-ld=${LLVM_USE_LINKER}"
 207     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 208 endif()
 209
 210 if( LLVM_ENABLE_PIC )
 211   if( XCODE )
 212     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 213     # know how to disable this, so just force ENABLE_PIC off for now.
 214     message(WARNING "-fPIC not supported with Xcode.")
 215   elseif( WIN32 OR CYGWIN)
 216     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 217   else()
 218     add_flag_or_print_warning("-fPIC" FPIC)
 219   endif()
 220 endif()
 221
 222 if(NOT WIN32 AND NOT CYGWIN)
 223   # MinGW warns if -fvisibility-inlines-hidden is used.
 224   check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 225   append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 226 endif()
 227
 228 if(CMAKE_SIZEOF_VOID_P EQUAL 8 AND MINGW)
 229   add_definitions( -D_FILE_OFFSET_BITS=64 )
 230 endif()
 231
 232 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 233   # TODO: support other platforms and toolchains.
 234   if( LLVM_BUILD_32_BITS )
 235     message(STATUS "Building 32 bits executables and libraries.")
 236     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 237     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -m32")
 238     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 239     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 240     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 241
 242     # FIXME: CMAKE_SIZEOF_VOID_P is still 8
 243     add_definitions(-D_LARGEFILE_SOURCE)
 244     add_definitions(-D_FILE_OFFSET_BITS=64)
 245   endif( LLVM_BUILD_32_BITS )
 246 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 247
 248 # If building on a GNU specific 32-bit system, make sure off_t is 64 bits
 249 # so that off_t can stored offset > 2GB.
 250 # Android until version N (API 24) doesn't support it.
 251 if (ANDROID AND (ANDROID_NATIVE_API_LEVEL LESS 24))
 252   set(LLVM_FORCE_SMALLFILE_FOR_ANDROID TRUE)
 253 endif()
 254 if( CMAKE_SIZEOF_VOID_P EQUAL 4 AND NOT LLVM_FORCE_SMALLFILE_FOR_ANDROID)
 255   # FIXME: It isn't handled in LLVM_BUILD_32_BITS.
 256   add_definitions( -D_LARGEFILE_SOURCE )
 257   add_definitions( -D_FILE_OFFSET_BITS=64 )
 258 endif()
 259
 260 if( XCODE )
 261   # For Xcode enable several build settings that correspond to
 262   # many warnings that are on by default in Clang but are
 263   # not enabled for historical reasons.  For versions of Xcode
 264   # that do not support these options they will simply
 265   # be ignored.
 266   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 267   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 268   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 269   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 270   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 271   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 272   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 273   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 274   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 275   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 276   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 277   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 278   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 279   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 280   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 281 endif()
 282
 283 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 284 # to use.
 285 if( MSVC_IDE )
 286   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 287     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 288   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 289     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 290       add_definitions( /MP )
 291     else()
 292       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 293       add_definitions( /MP${LLVM_COMPILER_JOBS} )
 294     endif()
 295   else()
 296     message(STATUS "Parallel compilation disabled")
 297   endif()
 298 endif()
 299
 300 # set stack reserved size to ~10MB
 301 if(MSVC)
 302   # CMake previously automatically set this value for MSVC builds, but the
 303   # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 304   # value (1 MB) which is not enough for us in tasks such as parsing recursive
 305   # C++ templates in Clang.
 306   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 307 elseif(MINGW) # FIXME: Also cygwin?
 308   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,16777216")
 309
 310   # Pass -mbig-obj to mingw gas on Win64. COFF has a 2**16 section limit, and
 311   # on Win64, every COMDAT function creates at least 3 sections: .text, .pdata,
 312   # and .xdata.
 313   if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 314     append("-Wa,-mbig-obj" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 315   endif()
 316 endif()
 317
 318 if( MSVC )
 319   if( CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.0 )
 320     # For MSVC 2013, disable iterator null pointer checking in debug mode,
 321     # especially so std::equal(nullptr, nullptr, nullptr) will not assert.
 322     add_definitions("-D_DEBUG_POINTER_IMPL=")
 323   endif()
 324
 325   include(ChooseMSVCCRT)
 326
 327   if( MSVC11 )
 328     add_definitions(-D_VARIADIC_MAX=10)
 329   endif()
 330
 331   # Add definitions that make MSVC much less annoying.
 332   add_definitions(
 333     # For some reason MS wants to deprecate a bunch of standard functions...
 334     -D_CRT_SECURE_NO_DEPRECATE
 335     -D_CRT_SECURE_NO_WARNINGS
 336     -D_CRT_NONSTDC_NO_DEPRECATE
 337     -D_CRT_NONSTDC_NO_WARNINGS
 338     -D_SCL_SECURE_NO_DEPRECATE
 339     -D_SCL_SECURE_NO_WARNINGS
 340     )
 341
 342   # Tell MSVC to use the Unicode version of the Win32 APIs instead of ANSI.
 343   add_definitions(
 344     -DUNICODE
 345     -D_UNICODE
 346   )
 347
 348   if (LLVM_ENABLE_WERROR)
 349     append("/WX" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 350   endif (LLVM_ENABLE_WERROR)
 351
 352   append("/Zc:inline" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 353
 354   # Allow users to request PDBs in release mode. CMake offeres the
 355   # RelWithDebInfo configuration, but it uses different optimization settings
 356   # (/Ob1 vs /Ob2 or -O2 vs -O3). LLVM provides this flag so that users can get
 357   # PDBs without changing codegen.
 358   option(LLVM_ENABLE_PDB OFF)
 359   if (LLVM_ENABLE_PDB AND uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
 360     append("/Zi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 361     # /DEBUG disables linker GC and ICF, but we want those in Release mode.
 362     append("/DEBUG /OPT:REF /OPT:ICF"
 363           CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS
 364           CMAKE_SHARED_LINKER_FLAGS)
 365   endif()
 366
 367   # /Zc:strictStrings is incompatible with VS12's (Visual Studio 2013's)
 368   # debug mode headers. Instead of only enabling them in VS2013's debug mode,
 369   # we'll just enable them for Visual Studio 2015 (VS 14, MSVC_VERSION 1900)
 370   # and up.
 371   if (NOT (MSVC_VERSION LESS 1900))
 372     # Disable string literal const->non-const type conversion.
 373     # "When specified, the compiler requires strict const-qualification
 374     # conformance for pointers initialized by using string literals."
 375     append("/Zc:strictStrings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 376   endif(NOT (MSVC_VERSION LESS 1900))
 377
 378   # "Generate Intrinsic Functions".
 379   append("/Oi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 380
 381   # "Enforce type conversion rules".
 382   append("/Zc:rvalueCast" CMAKE_CXX_FLAGS)
 383
 384   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND NOT LLVM_ENABLE_LTO)
 385     # clang-cl and cl by default produce non-deterministic binaries because
 386     # link.exe /incremental requires a timestamp in the .obj file.  clang-cl
 387     # has the flag /Brepro to force deterministic binaries. We want to pass that
 388     # whenever you're building with clang unless you're passing /incremental
 389     # or using LTO (/Brepro with LTO would result in a warning about the flag
 390     # being unused, because we're not generating object files).
 391     # This checks CMAKE_CXX_COMPILER_ID in addition to check_cxx_compiler_flag()
 392     # because cl.exe does not emit an error on flags it doesn't understand,
 393     # letting check_cxx_compiler_flag() claim it understands all flags.
 394     check_cxx_compiler_flag("/Brepro" SUPPORTS_BREPRO)
 395     if (SUPPORTS_BREPRO)
 396       # Check if /INCREMENTAL is passed to the linker and complain that it
 397       # won't work with /Brepro.
 398       string(TOUPPER "${CMAKE_EXE_LINKER_FLAGS}" upper_exe_flags)
 399       string(TOUPPER "${CMAKE_MODULE_LINKER_FLAGS}" upper_module_flags)
 400       string(TOUPPER "${CMAKE_SHARED_LINKER_FLAGS}" upper_shared_flags)
 401
 402       string(FIND "${upper_exe_flags} ${upper_module_flags} ${upper_shared_flags}"
 403         "/INCREMENTAL" linker_flag_idx)
 404
 405       if (${linker_flag_idx} GREATER -1)
 406         message(WARNING "/Brepro not compatible with /INCREMENTAL linking - builds will be non-deterministic")
 407       else()
 408         append("/Brepro" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 409       endif()
 410     endif()
 411   endif()
 412
 413 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 414   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 415   append_if(LLVM_ENABLE_WERROR "-Wno-error" CMAKE_REQUIRED_FLAGS)
 416   add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 417   add_flag_if_supported("-Werror=unguarded-availability-new" WERROR_UNGUARDED_AVAILABILITY_NEW)
 418   if (LLVM_ENABLE_CXX1Y)
 419     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 420     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 421   elseif(LLVM_ENABLE_CXX1Z)
 422     check_cxx_compiler_flag("-std=c++1z" CXX_SUPPORTS_CXX1Z)
 423     append_if(CXX_SUPPORTS_CXX1Z "-std=c++1z" CMAKE_CXX_FLAGS)
 424   else()
 425     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 426     if (CXX_SUPPORTS_CXX11)
 427       if (CYGWIN OR MINGW)
 428         # MinGW and Cygwin are a bit stricter and lack things like
 429         # 'strdup', 'stricmp', etc in c++11 mode.
 430         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 431       else()
 432         append("-std=c++11" CMAKE_CXX_FLAGS)
 433       endif()
 434     else()
 435       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 436     endif()
 437   endif()
 438   if (LLVM_ENABLE_MODULES)
 439     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 440     set(module_flags "-fmodules -fmodules-cache-path=${PROJECT_BINARY_DIR}/module.cache")
 441     if (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 442       # On Darwin -fmodules does not imply -fcxx-modules.
 443       set(module_flags "${module_flags} -fcxx-modules")
 444     endif()
 445     if (LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY)
 446       set(module_flags "${module_flags} -Xclang -fmodules-local-submodule-visibility")
 447     endif()
 448     if (LLVM_ENABLE_MODULE_DEBUGGING AND
 449         ((uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG") OR
 450          (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")))
 451       set(module_flags "${module_flags} -gmodules")
 452     endif()
 453     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${module_flags}")
 454
 455     # Check that we can build code with modules enabled, and that repeatedly
 456     # including <cassert> still manages to respect NDEBUG properly.
 457     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 458                                #include <cassert>
 459                                #define NDEBUG
 460                                #include <cassert>
 461                                int main() { assert(this code is not compiled); }"
 462                                CXX_SUPPORTS_MODULES)
 463     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 464     if (CXX_SUPPORTS_MODULES)
 465       append("${module_flags}" CMAKE_CXX_FLAGS)
 466     else()
 467       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 468     endif()
 469   endif(LLVM_ENABLE_MODULES)
 470 endif( MSVC )
 471
 472 if (MSVC)
 473   if (NOT CLANG_CL)
 474     set(msvc_warning_flags
 475       # Disabled warnings.
 476       -wd4141 # Suppress ''modifier' : used more than once' (because of __forceinline combined with inline)
 477       -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 478       -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 479       -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 480       -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 481       -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 482       -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 483       -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 484       -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 485       -wd4355 # Suppress ''this' : used in base member initializer list'
 486       -wd4456 # Suppress 'declaration of 'var' hides local variable'
 487       -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 488       -wd4458 # Suppress 'declaration of 'var' hides class member'
 489       -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 490       -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 491       -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 492       -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 493       -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 494       -wd4100 # Suppress 'unreferenced formal parameter'
 495       -wd4127 # Suppress 'conditional expression is constant'
 496       -wd4512 # Suppress 'assignment operator could not be generated'
 497       -wd4505 # Suppress 'unreferenced local function has been removed'
 498       -wd4610 # Suppress '<class> can never be instantiated'
 499       -wd4510 # Suppress 'default constructor could not be generated'
 500       -wd4702 # Suppress 'unreachable code'
 501       -wd4245 # Suppress 'signed/unsigned mismatch'
 502       -wd4706 # Suppress 'assignment within conditional expression'
 503       -wd4310 # Suppress 'cast truncates constant value'
 504       -wd4701 # Suppress 'potentially uninitialized local variable'
 505       -wd4703 # Suppress 'potentially uninitialized local pointer variable'
 506       -wd4389 # Suppress 'signed/unsigned mismatch'
 507       -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
 508       -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
 509       -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
 510       -wd4577 # Suppress 'noexcept used with no exception handling mode specified; termination on exception is not guaranteed'
 511       -wd4091 # Suppress 'typedef: ignored on left of '' when no variable is declared'
 512           # C4592 is disabled because of false positives in Visual Studio 2015
 513           # Update 1. Re-evaluate the usefulness of this diagnostic with Update 2.
 514       -wd4592 # Suppress ''var': symbol will be dynamically initialized (implementation limitation)
 515       -wd4319 # Suppress ''operator' : zero extending 'type' to 'type' of greater size'
 516           # C4709 is disabled because of a bug with Visual Studio 2017 as of
 517           # v15.8.8. Re-evaluate the usefulness of this diagnostic when the bug
 518           # is fixed.
 519       -wd4709 # Suppress comma operator within array index expression
 520
 521       # Ideally, we'd like this warning to be enabled, but MSVC 2013 doesn't
 522       # support the 'aligned' attribute in the way that clang sources requires (for
 523       # any code that uses the LLVM_ALIGNAS macro), so this is must be disabled to
 524       # avoid unwanted alignment warnings.
 525       # When we switch to requiring a version of MSVC that supports the 'alignas'
 526       # specifier (MSVC 2015?) this warning can be re-enabled.
 527       -wd4324 # Suppress 'structure was padded due to __declspec(align())'
 528
 529       # Promoted warnings.
 530       -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 531
 532       # Promoted warnings to errors.
 533       -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 534       )
 535   endif(NOT CLANG_CL)
 536
 537   # Enable warnings
 538   if (LLVM_ENABLE_WARNINGS)
 539     # Put /W4 in front of all the -we flags. cl.exe doesn't care, but for
 540     # clang-cl having /W4 after the -we flags will re-enable the warnings
 541     # disabled by -we.
 542     set(msvc_warning_flags "/W4 ${msvc_warning_flags}")
 543     # CMake appends /W3 by default, and having /W3 followed by /W4 will result in
 544     # cl : Command line warning D9025 : overriding '/W3' with '/W4'.  Since this is
 545     # a command line warning and not a compiler warning, it cannot be suppressed except
 546     # by fixing the command line.
 547     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 548     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 549
 550     if (LLVM_ENABLE_PEDANTIC)
 551       # No MSVC equivalent available
 552     endif (LLVM_ENABLE_PEDANTIC)
 553   endif (LLVM_ENABLE_WARNINGS)
 554
 555   foreach(flag ${msvc_warning_flags})
 556     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 557   endforeach(flag)
 558 endif (MSVC)
 559
 560 if (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 561
 562   # Don't add -Wall for clang-cl, because it maps -Wall to -Weverything for
 563   # MSVC compatibility.  /W4 is added above instead.
 564   if (NOT CLANG_CL)
 565     append("-Wall" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 566   endif()
 567
 568   append("-Wextra -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 569   append("-Wcast-qual" CMAKE_CXX_FLAGS)
 570
 571   # Turn off missing field initializer warnings for gcc to avoid noise from
 572   # false positives with empty {}. Turn them on otherwise (they're off by
 573   # default for clang).
 574   check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 575   if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 576     if (CMAKE_COMPILER_IS_GNUCXX)
 577       append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 578     else()
 579       append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 580     endif()
 581   endif()
 582
 583   if (LLVM_ENABLE_PEDANTIC AND LLVM_COMPILER_IS_GCC_COMPATIBLE)
 584     append("-pedantic" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 585     append("-Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 586   endif()
 587
 588   add_flag_if_supported("-Wimplicit-fallthrough" IMPLICIT_FALLTHROUGH_FLAG)
 589   add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 590   append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 591   append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 592
 593   # Disable -Wclass-memaccess, a C++-only warning from GCC 8 that fires on
 594   # LLVM's ADT classes.
 595   check_cxx_compiler_flag("-Wclass-memaccess" CXX_SUPPORTS_CLASS_MEMACCESS_FLAG)
 596   append_if(CXX_SUPPORTS_CLASS_MEMACCESS_FLAG "-Wno-class-memaccess" CMAKE_CXX_FLAGS)
 597
 598   # The LLVM libraries have no stable C++ API, so -Wnoexcept-type is not useful.
 599   check_cxx_compiler_flag("-Wnoexcept-type" CXX_SUPPORTS_NOEXCEPT_TYPE_FLAG)
 600   append_if(CXX_SUPPORTS_NOEXCEPT_TYPE_FLAG "-Wno-noexcept-type" CMAKE_CXX_FLAGS)
 601
 602   # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 603   # If it does, don't add it. So it won't be added on clang 3.4 and older.
 604   # This also catches cases when -Wnon-virtual-dtor isn't supported by
 605   # the compiler at all.  This flag is not activated for gcc since it will
 606   # incorrectly identify a protected non-virtual base when there is a friend
 607   # declaration. Don't activate this in general on Windows as this warning has
 608   # too many false positives on COM-style classes, which are destroyed with
 609   # Release() (PR32286).
 610   if (NOT CMAKE_COMPILER_IS_GNUCXX AND NOT WIN32)
 611     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 612     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 613     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 614                                class derived final : public base { public: ~derived();};
 615                                int main() { return 0; }"
 616                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 617     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 618     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 619               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 620   endif()
 621
 622   # Enable -Wdelete-non-virtual-dtor if available.
 623   add_flag_if_supported("-Wdelete-non-virtual-dtor" DELETE_NON_VIRTUAL_DTOR_FLAG)
 624
 625   # Check if -Wcomment is OK with an // comment ending with '\' if the next
 626   # line is also a // comment.
 627   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 628   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 629   CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 630                           C_WCOMMENT_ALLOWS_LINE_WRAP)
 631   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 632   if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 633     append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 634   endif()
 635
 636   # Enable -Wstring-conversion to catch misuse of string literals.
 637   add_flag_if_supported("-Wstring-conversion" STRING_CONVERSION_FLAG)
 638 endif (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 639
 640 if (LLVM_COMPILER_IS_GCC_COMPATIBLE AND NOT LLVM_ENABLE_WARNINGS)
 641   append("-w" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 642 endif()
 643
 644 macro(append_common_sanitizer_flags)
 645   if (NOT MSVC)
 646     # Append -fno-omit-frame-pointer and turn on debug info to get better
 647     # stack traces.
 648     add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 649     if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 650         NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 651       add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 652     endif()
 653     # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 654     if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND LLVM_OPTIMIZE_SANITIZED_BUILDS)
 655       add_flag_if_supported("-O1" O1)
 656     endif()
 657   elseif (CLANG_CL)
 658     # Keep frame pointers around.
 659     append("/Oy-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 660     if (LINKER_IS_LLD_LINK)
 661       # Use DWARF debug info with LLD.
 662       append("-gdwarf" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 663     else()
 664       # Enable codeview otherwise.
 665       append("/Z7" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 666     endif()
 667     # Always ask the linker to produce symbols with asan.
 668     append("-debug" CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 669   endif()
 670 endmacro()
 671
 672 # Turn on sanitizers if necessary.
 673 if(LLVM_USE_SANITIZER)
 674   if (LLVM_ON_UNIX)
 675     if (LLVM_USE_SANITIZER STREQUAL "Address")
 676       append_common_sanitizer_flags()
 677       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 678     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 679       append_common_sanitizer_flags()
 680       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 681       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 682         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 683       endif()
 684     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 685       append_common_sanitizer_flags()
 686       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 687               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 688     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 689       append_common_sanitizer_flags()
 690       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 691     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
 692             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
 693       append_common_sanitizer_flags()
 694       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 695               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 696     elseif (LLVM_USE_SANITIZER STREQUAL "Leaks")
 697       append_common_sanitizer_flags()
 698       append("-fsanitize=leak" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 699     else()
 700       message(FATAL_ERROR "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 701     endif()
 702   elseif(MSVC)
 703     if (LLVM_USE_SANITIZER STREQUAL "Address")
 704       append_common_sanitizer_flags()
 705       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 706     else()
 707       message(FATAL_ERROR "This sanitizer not yet supported in the MSVC environment: ${LLVM_USE_SANITIZER}")
 708     endif()
 709   else()
 710     message(FATAL_ERROR "LLVM_USE_SANITIZER is not supported on this platform.")
 711   endif()
 712   if (LLVM_USE_SANITIZER MATCHES "(Undefined;)?Address(;Undefined)?")
 713     add_flag_if_supported("-fsanitize-address-use-after-scope"
 714                           FSANITIZE_USE_AFTER_SCOPE_FLAG)
 715   endif()
 716   if (LLVM_USE_SANITIZE_COVERAGE)
 717     append("-fsanitize=fuzzer-no-link" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 718   endif()
 719   if (LLVM_USE_SANITIZER MATCHES ".*Undefined.*")
 720     set(BLACKLIST_FILE "${CMAKE_SOURCE_DIR}/utils/sanitizers/ubsan_blacklist.txt")
 721     if (EXISTS "${BLACKLIST_FILE}")
 722       append("-fsanitize-blacklist=${BLACKLIST_FILE}"
 723              CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 724     endif()
 725   endif()
 726 endif()
 727
 728 # Turn on -gsplit-dwarf if requested
 729 if(LLVM_USE_SPLIT_DWARF)
 730   add_definitions("-gsplit-dwarf")
 731 endif()
 732
 733 add_definitions( -D__STDC_CONSTANT_MACROS )
 734 add_definitions( -D__STDC_FORMAT_MACROS )
 735 add_definitions( -D__STDC_LIMIT_MACROS )
 736
 737 # clang and gcc don't default-print colored diagnostics when invoked from Ninja.
 738 if (UNIX AND
 739     CMAKE_GENERATOR STREQUAL "Ninja" AND
 740     (CMAKE_CXX_COMPILER_ID MATCHES "Clang" OR
 741      (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND
 742       NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.9))))
 743   append("-fdiagnostics-color" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 744 endif()
 745
 746 # lld doesn't print colored diagnostics when invoked from Ninja
 747 if (UNIX AND CMAKE_GENERATOR STREQUAL "Ninja")
 748   include(CheckLinkerFlag)
 749   check_linker_flag("-Wl,--color-diagnostics" LINKER_SUPPORTS_COLOR_DIAGNOSTICS)
 750   append_if(LINKER_SUPPORTS_COLOR_DIAGNOSTICS "-Wl,--color-diagnostics"
 751     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 752 endif()
 753
 754 # Add flags for add_dead_strip().
 755 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 756 # But MinSizeRel seems to add that automatically, so maybe disable these
 757 # flags instead if LLVM_NO_DEAD_STRIP is set.
 758 if(NOT CYGWIN AND NOT WIN32)
 759   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND
 760      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 761     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 762     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 763       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 764       # Doing so will break sanitizers.
 765       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 766     endif()
 767     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 768   endif()
 769 endif()
 770
 771 if(MSVC)
 772   # Remove flags here, for exceptions and RTTI.
 773   # Each target property or source property should be responsible to control
 774   # them.
 775   # CL.EXE complains to override flags like "/GR /GR-".
 776   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 777   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 778 endif()
 779
 780 # Provide public options to globally control RTTI and EH
 781 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 782 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 783 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 784   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 785 endif()
 786
 787 option(LLVM_USE_NEWPM "Build LLVM using the experimental new pass manager" Off)
 788 mark_as_advanced(LLVM_USE_NEWPM)
 789 if (LLVM_USE_NEWPM)
 790   append("-fexperimental-new-pass-manager"
 791     CMAKE_CXX_FLAGS
 792     CMAKE_C_FLAGS
 793     CMAKE_EXE_LINKER_FLAGS
 794     CMAKE_SHARED_LINKER_FLAGS)
 795 endif()
 796
 797 option(LLVM_ENABLE_IR_PGO "Build LLVM and tools with IR PGO instrumentation (deprecated)" Off)
 798 mark_as_advanced(LLVM_ENABLE_IR_PGO)
 799
 800 set(LLVM_BUILD_INSTRUMENTED OFF CACHE STRING "Build LLVM and tools with PGO instrumentation. May be specified as IR or Frontend")
 801 mark_as_advanced(LLVM_BUILD_INSTRUMENTED)
 802 string(TOUPPER "${LLVM_BUILD_INSTRUMENTED}" uppercase_LLVM_BUILD_INSTRUMENTED)
 803
 804 if (LLVM_BUILD_INSTRUMENTED)
 805   if (LLVM_ENABLE_IR_PGO OR uppercase_LLVM_BUILD_INSTRUMENTED STREQUAL "IR")
 806     append("-fprofile-generate='${LLVM_PROFILE_DATA_DIR}'"
 807       CMAKE_CXX_FLAGS
 808       CMAKE_C_FLAGS
 809       CMAKE_EXE_LINKER_FLAGS
 810       CMAKE_SHARED_LINKER_FLAGS)
 811   else()
 812     append("-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}'"
 813       CMAKE_CXX_FLAGS
 814       CMAKE_C_FLAGS
 815       CMAKE_EXE_LINKER_FLAGS
 816       CMAKE_SHARED_LINKER_FLAGS)
 817   endif()
 818 endif()
 819
 820 option(LLVM_BUILD_INSTRUMENTED_COVERAGE "Build LLVM and tools with Code Coverage instrumentation" Off)
 821 mark_as_advanced(LLVM_BUILD_INSTRUMENTED_COVERAGE)
 822 append_if(LLVM_BUILD_INSTRUMENTED_COVERAGE "-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}' -fcoverage-mapping"
 823   CMAKE_CXX_FLAGS
 824   CMAKE_C_FLAGS
 825   CMAKE_EXE_LINKER_FLAGS
 826   CMAKE_SHARED_LINKER_FLAGS)
 827
 828 if (LLVM_BUILD_INSTRUMENTED AND LLVM_BUILD_INSTRUMENTED_COVERAGE)
 829   message(FATAL_ERROR "LLVM_BUILD_INSTRUMENTED and LLVM_BUILD_INSTRUMENTED_COVERAGE cannot both be specified")
 830 endif()
 831
 832 if(LLVM_ENABLE_LTO AND LLVM_ON_WIN32 AND NOT LINKER_IS_LLD_LINK)
 833   message(FATAL_ERROR "When compiling for Windows, LLVM_ENABLE_LTO requires using lld as the linker (point CMAKE_LINKER at lld-link.exe)")
 834 endif()
 835 if(uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
 836   append("-flto=thin" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 837   if(NOT LINKER_IS_LLD_LINK)
 838     append("-flto=thin" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 839   endif()
 840   # If the linker supports it, enable the lto cache. This improves initial build
 841   # time a little since we re-link a lot of the same objects, and significantly
 842   # improves incremental build time.
 843   # FIXME: We should move all this logic into the clang driver.
 844   if(APPLE)
 845     append("-Wl,-cache_path_lto,${PROJECT_BINARY_DIR}/lto.cache"
 846            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 847   elseif(UNIX AND LLVM_USE_LINKER STREQUAL "lld")
 848     append("-Wl,--thinlto-cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 849            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 850   elseif(LLVM_USE_LINKER STREQUAL "gold")
 851     append("-Wl,--plugin-opt,cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 852            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 853   endif()
 854 elseif(uppercase_LLVM_ENABLE_LTO STREQUAL "FULL")
 855   append("-flto=full" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 856   if(NOT LINKER_IS_LLD_LINK)
 857     append("-flto=full" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 858   endif()
 859 elseif(LLVM_ENABLE_LTO)
 860   append("-flto" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 861   if(NOT LINKER_IS_LLD_LINK)
 862     append("-flto" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 863   endif()
 864 endif()
 865
 866 # This option makes utils/extract_symbols.py be used to determine the list of
 867 # symbols to export from LLVM tools. This is necessary when using MSVC if you
 868 # want to allow plugins, though note that the plugin has to explicitly link
 869 # against (exactly one) tool so we can't unilaterally turn on
 870 # LLVM_ENABLE_PLUGINS when it's enabled.
 871 option(LLVM_EXPORT_SYMBOLS_FOR_PLUGINS "Export symbols from LLVM tools so that plugins can import them" OFF)
 872 if(BUILD_SHARED_LIBS AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 873   message(FATAL_ERROR "BUILD_SHARED_LIBS not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 874 endif()
 875 if(LLVM_LINK_LLVM_DYLIB AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 876   message(FATAL_ERROR "LLVM_LINK_LLVM_DYLIB not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 877 endif()
 878
 879 # Plugin support
 880 # FIXME: Make this configurable.
 881 if(WIN32 OR CYGWIN)
 882   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 883     set(LLVM_ENABLE_PLUGINS ON)
 884   else()
 885     set(LLVM_ENABLE_PLUGINS OFF)
 886   endif()
 887 else()
 888   set(LLVM_ENABLE_PLUGINS ON)
 889 endif()
 890
 891 # By default we should enable LLVM_ENABLE_IDE only for multi-configuration
 892 # generators. This option disables optional build system features that make IDEs
 893 # less usable.
 894 set(LLVM_ENABLE_IDE_default OFF)
 895 if (CMAKE_CONFIGURATION_TYPES)
 896   set(LLVM_ENABLE_IDE_default ON)
 897 endif()
 898 option(LLVM_ENABLE_IDE
 899        "Disable optional build system features that cause problems for IDE generators"
 900        ${LLVM_ENABLE_IDE_default})
 901 if (CMAKE_CONFIGURATION_TYPES AND NOT LLVM_ENABLE_IDE)
 902   message(WARNING "Disabling LLVM_ENABLE_IDE on multi-configuration generators is not recommended.")
 903 endif()
 904
 905 function(get_compile_definitions)
 906   get_directory_property(top_dir_definitions DIRECTORY ${CMAKE_SOURCE_DIR} COMPILE_DEFINITIONS)
 907   foreach(definition ${top_dir_definitions})
 908     if(DEFINED result)
 909       string(APPEND result " -D${definition}")
 910     else()
 911       set(result "-D${definition}")
 912     endif()
 913   endforeach()
 914   set(LLVM_DEFINITIONS "${result}" PARENT_SCOPE)
 915 endfunction()
 916 get_compile_definitions()
 917
 918 option(LLVM_FORCE_ENABLE_STATS "Enable statistics collection for builds that wouldn't normally enable it" OFF)
 919
 920 check_symbol_exists(os_signpost_interval_begin "os/signpost.h" macos_signposts_available)
 921 if(macos_signposts_available)
 922   check_cxx_source_compiles(
 923     "#include <os/signpost.h>
 924     int main() { os_signpost_interval_begin(nullptr, 0, \"\", \"\"); return 0; }"
 925     macos_signposts_usable)
 926   if(macos_signposts_usable)
 927     set(LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS "WITH_ASSERTS" CACHE STRING
 928         "Enable support for Xcode signposts. Can be WITH_ASSERTS, FORCE_ON, FORCE_OFF")
 929     string(TOUPPER "${LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS}"
 930                    uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS)
 931     if( uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS STREQUAL "WITH_ASSERTS" )
 932       if( LLVM_ENABLE_ASSERTIONS )
 933         set( LLVM_SUPPORT_XCODE_SIGNPOSTS 1 )
 934       endif()
 935     elseif( uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS STREQUAL "FORCE_ON" )
 936       set( LLVM_SUPPORT_XCODE_SIGNPOSTS 1 )
 937     elseif( uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS STREQUAL "FORCE_OFF" )
 938       # We don't need to do anything special to turn off signposts.
 939     elseif( NOT DEFINED LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS )
 940       # Treat LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS like "FORCE_OFF" when it has not been
 941       # defined.
 942     else()
 943       message(FATAL_ERROR "Unknown value for LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS:"
 944                           " \"${LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS}\"!")
 945     endif()
 946   endif()
 947 endif()