cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(CheckCompilerVersion)
  10 include(HandleLLVMStdlib)
  11 include(AddLLVMDefinitions)
  12 include(CheckCCompilerFlag)
  13 include(CheckCXXCompilerFlag)
  14
  15 # Ninja Job Pool support
  16 # The following only works with the Ninja generator in CMake >= 3.0.
  17 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  18   "Define the maximum number of concurrent compilation jobs.")
  19 if(LLVM_PARALLEL_COMPILE_JOBS)
  20   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
  21     message(WARNING "Job pooling is only available with Ninja generators.")
  22   else()
  23     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  24     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  25   endif()
  26 endif()
  27
  28 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  29   "Define the maximum number of concurrent link jobs.")
  30 if(LLVM_PARALLEL_LINK_JOBS)
  31   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
  32     message(WARNING "Job pooling is only available with Ninja generators.")
  33   else()
  34     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  35     set(CMAKE_JOB_POOL_LINK link_job_pool)
  36   endif()
  37 endif()
  38
  39
  40 if (CMAKE_LINKER MATCHES "lld-link.exe")
  41   # Pass /MANIFEST:NO so that CMake doesn't run mt.exe on our binaries.  Adding
  42   # manifests with mt.exe breaks LLD's symbol tables and takes as much time as
  43   # the link. See PR24476.
  44   append("/MANIFEST:NO"
  45     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
  46 endif()
  47
  48 if( LLVM_ENABLE_ASSERTIONS )
  49   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  50   if( NOT MSVC )
  51     add_definitions( -D_DEBUG )
  52   endif()
  53   # On non-Debug builds cmake automatically defines NDEBUG, so we
  54   # explicitly undefine it:
  55   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  56     add_definitions( -UNDEBUG )
  57     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  58     foreach (flags_var_to_scrub
  59         CMAKE_CXX_FLAGS_RELEASE
  60         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  61         CMAKE_CXX_FLAGS_MINSIZEREL
  62         CMAKE_C_FLAGS_RELEASE
  63         CMAKE_C_FLAGS_RELWITHDEBINFO
  64         CMAKE_C_FLAGS_MINSIZEREL)
  65       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  66         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  67     endforeach()
  68   endif()
  69 endif()
  70
  71 if(LLVM_ENABLE_EXPENSIVE_CHECKS)
  72   add_definitions(-DEXPENSIVE_CHECKS)
  73   add_definitions(-D_GLIBCXX_DEBUG)
  74 endif()
  75
  76 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
  77
  78 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
  79   if( LLVM_ENABLE_ASSERTIONS )
  80     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  81   endif()
  82 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
  83   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  84 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
  85   # We don't need to do anything special to turn off ABI breaking checks.
  86 elseif( NOT DEFINED LLVM_ABI_BREAKING_CHECKS )
  87   # Treat LLVM_ABI_BREAKING_CHECKS like "FORCE_OFF" when it has not been
  88   # defined.
  89 else()
  90   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
  91 endif()
  92
  93 if(WIN32)
  94   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  95   if(CYGWIN)
  96     set(LLVM_ON_WIN32 0)
  97     set(LLVM_ON_UNIX 1)
  98   else(CYGWIN)
  99     set(LLVM_ON_WIN32 1)
 100     set(LLVM_ON_UNIX 0)
 101   endif(CYGWIN)
 102 else(WIN32)
 103   if(UNIX)
 104     set(LLVM_ON_WIN32 0)
 105     set(LLVM_ON_UNIX 1)
 106     if(APPLE OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 107       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 108     else()
 109       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
 110     endif()
 111   else(UNIX)
 112     MESSAGE(SEND_ERROR "Unable to determine platform")
 113   endif(UNIX)
 114 endif(WIN32)
 115
 116 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 117 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 118
 119 # We use *.dylib rather than *.so on darwin.
 120 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 121
 122 if(APPLE)
 123   if(LLVM_ENABLE_LLD AND LLVM_ENABLE_LTO)
 124     message(FATAL_ERROR "lld does not support LTO on Darwin")
 125   endif()
 126   # Darwin-specific linker flags for loadable modules.
 127   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 128 endif()
 129
 130 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 131 # build might work on ELF but fail on MachO/COFF.
 132 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32 OR CYGWIN OR
 133         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD" OR
 134         ${CMAKE_SYSTEM_NAME} MATCHES "OpenBSD") AND
 135    NOT LLVM_USE_SANITIZER)
 136   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 137 endif()
 138
 139
 140 function(append value)
 141   foreach(variable ${ARGN})
 142     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 143   endforeach(variable)
 144 endfunction()
 145
 146 function(append_if condition value)
 147   if (${condition})
 148     foreach(variable ${ARGN})
 149       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 150     endforeach(variable)
 151   endif()
 152 endfunction()
 153
 154 macro(add_flag_if_supported flag name)
 155   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 156   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 157   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 158   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 159 endmacro()
 160
 161 function(add_flag_or_print_warning flag name)
 162   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 163   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 164   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 165     message(STATUS "Building with ${flag}")
 166     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 167     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 168     set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} ${flag}" PARENT_SCOPE)
 169   else()
 170     message(WARNING "${flag} is not supported.")
 171   endif()
 172 endfunction()
 173
 174 if( LLVM_ENABLE_LLD )
 175         if ( LLVM_USE_LINKER )
 176                 message(FATAL_ERROR "LLVM_ENABLE_LLD and LLVM_USE_LINKER can't be set at the same time")
 177         endif()
 178         set(LLVM_USE_LINKER "lld")
 179 endif()
 180
 181 if( LLVM_USE_LINKER )
 182   check_cxx_compiler_flag("-fuse-ld=${LLVM_USE_LINKER}" CXX_SUPPORTS_CUSTOM_LINKER)
 183   if ( NOT CXX_SUPPORTS_CUSTOM_LINKER )
 184           message(FATAL_ERROR "Host compiler does not support '-fuse-ld=${LLVM_USE_LINKER}'")
 185   endif()
 186   append("-fuse-ld=${LLVM_USE_LINKER}"
 187     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 188 endif()
 189
 190 if( LLVM_ENABLE_PIC )
 191   if( XCODE )
 192     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 193     # know how to disable this, so just force ENABLE_PIC off for now.
 194     message(WARNING "-fPIC not supported with Xcode.")
 195   elseif( WIN32 OR CYGWIN)
 196     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 197   else()
 198     add_flag_or_print_warning("-fPIC" FPIC)
 199   endif()
 200 endif()
 201
 202 if(NOT WIN32 AND NOT CYGWIN)
 203   # MinGW warns if -fvisibility-inlines-hidden is used.
 204   check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 205   append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 206 endif()
 207
 208 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 209   # TODO: support other platforms and toolchains.
 210   if( LLVM_BUILD_32_BITS )
 211     message(STATUS "Building 32 bits executables and libraries.")
 212     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 213     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -m32")
 214     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 215     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 216     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 217   endif( LLVM_BUILD_32_BITS )
 218 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 219
 220 if( XCODE )
 221   # For Xcode enable several build settings that correspond to
 222   # many warnings that are on by default in Clang but are
 223   # not enabled for historical reasons.  For versions of Xcode
 224   # that do not support these options they will simply
 225   # be ignored.
 226   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 227   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 228   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 229   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 230   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 231   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 232   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 233   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 234   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 235   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 236   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 237   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 238   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 239   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 240   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 241 endif()
 242
 243 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 244 # to use.
 245 if( MSVC_IDE )
 246   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 247     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 248   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 249     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 250       add_llvm_definitions( /MP )
 251     else()
 252       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 253       add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 254     endif()
 255   else()
 256     message(STATUS "Parallel compilation disabled")
 257   endif()
 258 endif()
 259
 260 # set stack reserved size to ~10MB
 261 if(MSVC)
 262   # CMake previously automatically set this value for MSVC builds, but the
 263   # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 264   # value (1 MB) which is not enough for us in tasks such as parsing recursive
 265   # C++ templates in Clang.
 266   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 267 elseif(MINGW) # FIXME: Also cygwin?
 268   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,16777216")
 269
 270   # Pass -mbig-obj to mingw gas on Win64. COFF has a 2**16 section limit, and
 271   # on Win64, every COMDAT function creates at least 3 sections: .text, .pdata,
 272   # and .xdata.
 273   if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 274     append("-Wa,-mbig-obj" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 275   endif()
 276 endif()
 277
 278 if( MSVC )
 279   if( CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.0 )
 280     # For MSVC 2013, disable iterator null pointer checking in debug mode,
 281     # especially so std::equal(nullptr, nullptr, nullptr) will not assert.
 282     add_llvm_definitions("-D_DEBUG_POINTER_IMPL=")
 283   endif()
 284
 285   include(ChooseMSVCCRT)
 286
 287   if( MSVC11 )
 288     add_llvm_definitions(-D_VARIADIC_MAX=10)
 289   endif()
 290
 291   # Add definitions that make MSVC much less annoying.
 292   add_llvm_definitions(
 293     # For some reason MS wants to deprecate a bunch of standard functions...
 294     -D_CRT_SECURE_NO_DEPRECATE
 295     -D_CRT_SECURE_NO_WARNINGS
 296     -D_CRT_NONSTDC_NO_DEPRECATE
 297     -D_CRT_NONSTDC_NO_WARNINGS
 298     -D_SCL_SECURE_NO_DEPRECATE
 299     -D_SCL_SECURE_NO_WARNINGS
 300     )
 301
 302   # Tell MSVC to use the Unicode version of the Win32 APIs instead of ANSI.
 303   add_llvm_definitions(
 304     -DUNICODE
 305     -D_UNICODE
 306   )
 307
 308   set(msvc_warning_flags
 309     # Disabled warnings.
 310     -wd4141 # Suppress ''modifier' : used more than once' (because of __forceinline combined with inline)
 311     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 312     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 313     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 314     -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 315     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 316     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 317     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 318     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 319     -wd4355 # Suppress ''this' : used in base member initializer list'
 320     -wd4456 # Suppress 'declaration of 'var' hides local variable'
 321     -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 322     -wd4458 # Suppress 'declaration of 'var' hides class member'
 323     -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 324     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 325     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 326     -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 327     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 328     -wd4100 # Suppress 'unreferenced formal parameter'
 329     -wd4127 # Suppress 'conditional expression is constant'
 330     -wd4512 # Suppress 'assignment operator could not be generated'
 331     -wd4505 # Suppress 'unreferenced local function has been removed'
 332     -wd4610 # Suppress '<class> can never be instantiated'
 333     -wd4510 # Suppress 'default constructor could not be generated'
 334     -wd4702 # Suppress 'unreachable code'
 335     -wd4245 # Suppress 'signed/unsigned mismatch'
 336     -wd4706 # Suppress 'assignment within conditional expression'
 337     -wd4310 # Suppress 'cast truncates constant value'
 338     -wd4701 # Suppress 'potentially uninitialized local variable'
 339     -wd4703 # Suppress 'potentially uninitialized local pointer variable'
 340     -wd4389 # Suppress 'signed/unsigned mismatch'
 341     -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
 342     -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
 343     -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
 344     -wd4577 # Suppress 'noexcept used with no exception handling mode specified; termination on exception is not guaranteed'
 345     -wd4091 # Suppress 'typedef: ignored on left of '' when no variable is declared'
 346         # C4592 is disabled because of false positives in Visual Studio 2015
 347         # Update 1. Re-evaluate the usefulness of this diagnostic with Update 2.
 348     -wd4592 # Suppress ''var': symbol will be dynamically initialized (implementation limitation)
 349     -wd4319 # Suppress ''operator' : zero extending 'type' to 'type' of greater size'
 350
 351         # Ideally, we'd like this warning to be enabled, but MSVC 2013 doesn't
 352         # support the 'aligned' attribute in the way that clang sources requires (for
 353         # any code that uses the LLVM_ALIGNAS macro), so this is must be disabled to
 354         # avoid unwanted alignment warnings.
 355         # When we switch to requiring a version of MSVC that supports the 'alignas'
 356         # specifier (MSVC 2015?) this warning can be re-enabled.
 357     -wd4324 # Suppress 'structure was padded due to __declspec(align())'
 358
 359     # Promoted warnings.
 360     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 361
 362     # Promoted warnings to errors.
 363     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 364     )
 365
 366   # Enable warnings
 367   if (LLVM_ENABLE_WARNINGS)
 368     # Put /W4 in front of all the -we flags. cl.exe doesn't care, but for
 369     # clang-cl having /W4 after the -we flags will re-enable the warnings
 370     # disabled by -we.
 371     set(msvc_warning_flags "/W4 ${msvc_warning_flags}")
 372     # CMake appends /W3 by default, and having /W3 followed by /W4 will result in
 373     # cl : Command line warning D9025 : overriding '/W3' with '/W4'.  Since this is
 374     # a command line warning and not a compiler warning, it cannot be suppressed except
 375     # by fixing the command line.
 376     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 377     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 378
 379     if (LLVM_ENABLE_PEDANTIC)
 380       # No MSVC equivalent available
 381     endif (LLVM_ENABLE_PEDANTIC)
 382   endif (LLVM_ENABLE_WARNINGS)
 383   if (LLVM_ENABLE_WERROR)
 384     append("/WX" msvc_warning_flags)
 385   endif (LLVM_ENABLE_WERROR)
 386
 387   foreach(flag ${msvc_warning_flags})
 388     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 389   endforeach(flag)
 390
 391   append("/Zc:inline" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 392
 393   # /Zc:strictStrings is incompatible with VS12's (Visual Studio 2013's)
 394   # debug mode headers. Instead of only enabling them in VS2013's debug mode,
 395   # we'll just enable them for Visual Studio 2015 (VS 14, MSVC_VERSION 1900)
 396   # and up.
 397   if (NOT (MSVC_VERSION LESS 1900))
 398     # Disable string literal const->non-const type conversion.
 399     # "When specified, the compiler requires strict const-qualification
 400     # conformance for pointers initialized by using string literals."
 401     append("/Zc:strictStrings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 402   endif(NOT (MSVC_VERSION LESS 1900))
 403
 404   # "Generate Intrinsic Functions".
 405   append("/Oi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 406
 407   # "Enforce type conversion rules".
 408   append("/Zc:rvalueCast" CMAKE_CXX_FLAGS)
 409
 410   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 411     # clang-cl and cl by default produce non-deterministic binaries because
 412     # link.exe /incremental requires a timestamp in the .obj file.  clang-cl
 413     # has the flag /Brepro to force deterministic binaries. We want to pass that
 414     # whenever you're building with clang unless you're passing /incremental.
 415     # This checks CMAKE_CXX_COMPILER_ID in addition to check_cxx_compiler_flag()
 416     # because cl.exe does not emit an error on flags it doesn't understand,
 417     # letting check_cxx_compiler_flag() claim it understands all flags.
 418     check_cxx_compiler_flag("/Brepro" SUPPORTS_BREPRO)
 419     if (SUPPORTS_BREPRO)
 420       # Check if /INCREMENTAL is passed to the linker and complain that it
 421       # won't work with /Brepro.
 422       string(TOUPPER "${CMAKE_EXE_LINKER_FLAGS}" upper_exe_flags)
 423       string(TOUPPER "${CMAKE_MODULE_LINKER_FLAGS}" upper_module_flags)
 424       string(TOUPPER "${CMAKE_SHARED_LINKER_FLAGS}" upper_shared_flags)
 425
 426       string(FIND "${upper_exe_flags} ${upper_module_flags} ${upper_shared_flags}"
 427         "/INCREMENTAL" linker_flag_idx)
 428
 429       if (${linker_flag_idx} GREATER -1)
 430         message(WARNING "/Brepro not compatible with /INCREMENTAL linking - builds will be non-deterministic")
 431       else()
 432         append("/Brepro" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 433       endif()
 434     endif()
 435   endif()
 436
 437 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 438   if (LLVM_ENABLE_WARNINGS)
 439     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 440     append("-Wcast-qual" CMAKE_CXX_FLAGS)
 441
 442     # Turn off missing field initializer warnings for gcc to avoid noise from
 443     # false positives with empty {}. Turn them on otherwise (they're off by
 444     # default for clang).
 445     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 446     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 447       if (CMAKE_COMPILER_IS_GNUCXX)
 448         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 449       else()
 450         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 451       endif()
 452     endif()
 453
 454     append_if(LLVM_ENABLE_PEDANTIC "-pedantic" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 455     append_if(LLVM_ENABLE_PEDANTIC "-Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 456     add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 457     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 458     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 459
 460     # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 461     # If it does, don't add it. So it won't be added on clang 3.4 and older.
 462     # This also catches cases when -Wnon-virtual-dtor isn't supported by
 463     # the compiler at all.  This flag is not activated for gcc since it will
 464     # incorrectly identify a protected non-virtual base when there is a friend
 465     # declaration.
 466     if (NOT CMAKE_COMPILER_IS_GNUCXX)
 467       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 468       set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 469       CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 470                                  class derived final : public base { public: ~derived();};
 471                                  int main() { return 0; }"
 472                                 CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 473       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 474       append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 475                 "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 476     endif()
 477
 478     # Enable -Wdelete-non-virtual-dtor if available.
 479     add_flag_if_supported("-Wdelete-non-virtual-dtor" DELETE_NON_VIRTUAL_DTOR_FLAG)
 480
 481     # Check if -Wcomment is OK with an // comment ending with '\' if the next
 482     # line is also a // comment.
 483     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 484     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 485     CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 486                             C_WCOMMENT_ALLOWS_LINE_WRAP)
 487     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 488     if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 489       append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 490     endif()
 491
 492     # Enable -Wstring-conversion to catch misuse of string literals.
 493     add_flag_if_supported("-Wstring-conversion" STRING_CONVERSION_FLAG)
 494   endif (LLVM_ENABLE_WARNINGS)
 495   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 496   add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 497   if (LLVM_ENABLE_CXX1Y)
 498     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 499     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 500   else()
 501     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 502     if (CXX_SUPPORTS_CXX11)
 503       if (CYGWIN OR MINGW)
 504         # MinGW and Cygwin are a bit stricter and lack things like
 505         # 'strdup', 'stricmp', etc in c++11 mode.
 506         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 507       else()
 508         append("-std=c++11" CMAKE_CXX_FLAGS)
 509       endif()
 510     else()
 511       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 512     endif()
 513   endif()
 514   if (LLVM_ENABLE_MODULES)
 515     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 516     set(module_flags "-fmodules -fmodules-cache-path=${PROJECT_BINARY_DIR}/module.cache")
 517     if (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 518       # On Darwin -fmodules does not imply -fcxx-modules.
 519       set(module_flags "${module_flags} -fcxx-modules")
 520     endif()
 521     if (LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY)
 522       set(module_flags "${module_flags} -Xclang -fmodules-local-submodule-visibility")
 523     endif()
 524     if (LLVM_ENABLE_MODULE_DEBUGGING AND
 525         ((uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG") OR
 526          (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")))
 527       set(module_flags "${module_flags} -gmodules")
 528     endif()
 529     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${module_flags}")
 530
 531     # Check that we can build code with modules enabled, and that repeatedly
 532     # including <cassert> still manages to respect NDEBUG properly.
 533     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 534                                #include <cassert>
 535                                #define NDEBUG
 536                                #include <cassert>
 537                                int main() { assert(this code is not compiled); }"
 538                                CXX_SUPPORTS_MODULES)
 539     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 540     if (CXX_SUPPORTS_MODULES)
 541       append("${module_flags}" CMAKE_CXX_FLAGS)
 542     else()
 543       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 544     endif()
 545   endif(LLVM_ENABLE_MODULES)
 546 endif( MSVC )
 547
 548 macro(append_common_sanitizer_flags)
 549   if (NOT MSVC)
 550     # Append -fno-omit-frame-pointer and turn on debug info to get better
 551     # stack traces.
 552     add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 553     if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 554         NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 555       add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 556     endif()
 557     # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 558     if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 559       add_flag_if_supported("-O1" O1)
 560     endif()
 561   elseif (CLANG_CL)
 562     # Keep frame pointers around.
 563     append("/Oy-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 564     if (CMAKE_LINKER MATCHES "lld-link.exe")
 565       # Use DWARF debug info with LLD.
 566       append("-gdwarf" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 567     else()
 568       # Enable codeview otherwise.
 569       append("/Z7" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 570     endif()
 571     # Always ask the linker to produce symbols with asan.
 572     append("-debug" CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 573   endif()
 574 endmacro()
 575
 576 # Turn on sanitizers if necessary.
 577 if(LLVM_USE_SANITIZER)
 578   if (LLVM_ON_UNIX)
 579     if (LLVM_USE_SANITIZER STREQUAL "Address")
 580       append_common_sanitizer_flags()
 581       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 582     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 583       append_common_sanitizer_flags()
 584       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 585       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 586         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 587       endif()
 588     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 589       append_common_sanitizer_flags()
 590       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 591               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 592       append("-fsanitize-blacklist=${CMAKE_SOURCE_DIR}/utils/sanitizers/ubsan_blacklist.txt"
 593               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 594     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 595       append_common_sanitizer_flags()
 596       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 597     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
 598             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
 599       append_common_sanitizer_flags()
 600       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 601               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 602     else()
 603       message(FATAL_ERROR "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 604     endif()
 605   elseif(MSVC)
 606     if (LLVM_USE_SANITIZER STREQUAL "Address")
 607       append_common_sanitizer_flags()
 608       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 609     else()
 610       message(FATAL_ERROR "This sanitizer not yet supported in the MSVC environment: ${LLVM_USE_SANITIZER}")
 611     endif()
 612   else()
 613     message(FATAL_ERROR "LLVM_USE_SANITIZER is not supported on this platform.")
 614   endif()
 615   if (LLVM_USE_SANITIZER MATCHES "(Undefined;)?Address(;Undefined)?")
 616     add_flag_if_supported("-fsanitize-address-use-after-scope"
 617                           FSANITIZE_USE_AFTER_SCOPE_FLAG)
 618   endif()
 619   if (LLVM_USE_SANITIZE_COVERAGE)
 620     append("-fsanitize-coverage=trace-pc-guard,indirect-calls,trace-cmp" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 621   endif()
 622 endif()
 623
 624 # Turn on -gsplit-dwarf if requested
 625 if(LLVM_USE_SPLIT_DWARF)
 626   add_definitions("-gsplit-dwarf")
 627 endif()
 628
 629 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 630 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 631 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 632
 633 # clang doesn't print colored diagnostics when invoked from Ninja
 634 if (UNIX AND
 635     CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND
 636     CMAKE_GENERATOR STREQUAL "Ninja")
 637   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 638 endif()
 639
 640 # lld doesn't print colored diagnostics when invoked from Ninja
 641 if (UNIX AND CMAKE_GENERATOR STREQUAL "Ninja")
 642   include(CheckLinkerFlag)
 643   check_linker_flag("-Wl,-color-diagnostics" LINKER_SUPPORTS_COLOR_DIAGNOSTICS)
 644   append_if(LINKER_SUPPORTS_COLOR_DIAGNOSTICS "-Wl,-color-diagnostics"
 645     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 646 endif()
 647
 648 # Add flags for add_dead_strip().
 649 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 650 # But MinSizeRel seems to add that automatically, so maybe disable these
 651 # flags instead if LLVM_NO_DEAD_STRIP is set.
 652 if(NOT CYGWIN AND NOT WIN32)
 653   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND
 654      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 655     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 656     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 657       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 658       # Doing so will break sanitizers.
 659       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 660     endif()
 661     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 662   endif()
 663 endif()
 664
 665 if(MSVC)
 666   # Remove flags here, for exceptions and RTTI.
 667   # Each target property or source property should be responsible to control
 668   # them.
 669   # CL.EXE complains to override flags like "/GR /GR-".
 670   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 671   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 672 endif()
 673
 674 # Provide public options to globally control RTTI and EH
 675 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 676 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 677 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 678   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 679 endif()
 680
 681 option(LLVM_BUILD_INSTRUMENTED "Build LLVM and tools with PGO instrumentation (experimental)" Off)
 682 mark_as_advanced(LLVM_BUILD_INSTRUMENTED)
 683 append_if(LLVM_BUILD_INSTRUMENTED "-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}'"
 684   CMAKE_CXX_FLAGS
 685   CMAKE_C_FLAGS
 686   CMAKE_EXE_LINKER_FLAGS
 687   CMAKE_SHARED_LINKER_FLAGS)
 688
 689 option(LLVM_BUILD_INSTRUMENTED_COVERAGE "Build LLVM and tools with Code Coverage instrumentation (experimental)" Off)
 690 mark_as_advanced(LLVM_BUILD_INSTRUMENTED_COVERAGE)
 691 append_if(LLVM_BUILD_INSTRUMENTED_COVERAGE "-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}' -fcoverage-mapping"
 692   CMAKE_CXX_FLAGS
 693   CMAKE_C_FLAGS
 694   CMAKE_EXE_LINKER_FLAGS
 695   CMAKE_SHARED_LINKER_FLAGS)
 696
 697 set(LLVM_ENABLE_LTO OFF CACHE STRING "Build LLVM with LTO. May be specified as Thin or Full to use a particular kind of LTO")
 698 string(TOUPPER "${LLVM_ENABLE_LTO}" uppercase_LLVM_ENABLE_LTO)
 699 if(uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
 700   append("-flto=thin" CMAKE_CXX_FLAGS CMAKE_C_FLAGS
 701                       CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 702   # On darwin, enable the lto cache. This improves initial build time a little
 703   # since we re-link a lot of the same objects, and significantly improves
 704   # incremental build time.
 705   append_if(APPLE "-Wl,-cache_path_lto,${PROJECT_BINARY_DIR}/lto.cache"
 706             CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 707 elseif(uppercase_LLVM_ENABLE_LTO STREQUAL "FULL")
 708   append("-flto=full" CMAKE_CXX_FLAGS CMAKE_C_FLAGS
 709                  CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 710 elseif(LLVM_ENABLE_LTO)
 711   append("-flto" CMAKE_CXX_FLAGS CMAKE_C_FLAGS
 712                  CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 713 endif()
 714
 715 # This option makes utils/extract_symbols.py be used to determine the list of
 716 # symbols to export from LLVM tools. This is necessary when using MSVC if you
 717 # want to allow plugins, though note that the plugin has to explicitly link
 718 # against (exactly one) tool so we can't unilaterally turn on
 719 # LLVM_ENABLE_PLUGINS when it's enabled.
 720 option(LLVM_EXPORT_SYMBOLS_FOR_PLUGINS "Export symbols from LLVM tools so that plugins can import them" OFF)
 721 if(BUILD_SHARED_LIBS AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 722   message(FATAL_ERROR "BUILD_SHARED_LIBS not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 723 endif()
 724 if(LLVM_LINK_LLVM_DYLIB AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 725   message(FATAL_ERROR "LLVM_LINK_LLVM_DYLIB not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 726 endif()
 727
 728 # Plugin support
 729 # FIXME: Make this configurable.
 730 if(WIN32 OR CYGWIN)
 731   if(BUILD_SHARED_LIBS)
 732     set(LLVM_ENABLE_PLUGINS ON)
 733   else()
 734     set(LLVM_ENABLE_PLUGINS OFF)
 735   endif()
 736 else()
 737   set(LLVM_ENABLE_PLUGINS ON)
 738 endif()