cmake/modules/TableGen.cmake

   1 # LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
   2 # Extra parameters for `tblgen' may come after `ofn' parameter.
   3 # Adds the name of the generated file to TABLEGEN_OUTPUT.
   4
   5 include(LLVMExternalProjectUtils)
   6
   7 if(LLVM_MAIN_INCLUDE_DIR)
   8   set(LLVM_TABLEGEN_FLAGS -I ${LLVM_MAIN_INCLUDE_DIR})
   9 endif()
  10
  11 function(tablegen project ofn)
  12   # Validate calling context.
  13   if(NOT ${project}_TABLEGEN_EXE)
  14     message(FATAL_ERROR "${project}_TABLEGEN_EXE not set")
  15   endif()
  16
  17   # Use depfile instead of globbing arbitrary *.td(s)
  18   # DEPFILE is available for Ninja Generator with CMake>=3.7.
  19   if(CMAKE_GENERATOR STREQUAL "Ninja" AND NOT CMAKE_VERSION VERSION_LESS 3.7)
  20     # Make output path relative to build.ninja, assuming located on
  21     # ${CMAKE_BINARY_DIR}.
  22     # CMake emits build targets as relative paths but Ninja doesn't identify
  23     # absolute path (in *.d) as relative path (in build.ninja)
  24     # Note that tblgen is executed on ${CMAKE_BINARY_DIR} as working directory.
  25     file(RELATIVE_PATH ofn_rel
  26       ${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${ofn})
  27     set(additional_cmdline
  28       -o ${ofn_rel}.tmp
  29       -d ${ofn_rel}.d
  30       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  31       DEPFILE ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.d
  32       )
  33     set(local_tds)
  34     set(global_tds)
  35   else()
  36     file(GLOB local_tds "*.td")
  37     file(GLOB_RECURSE global_tds "${LLVM_MAIN_INCLUDE_DIR}/llvm/*.td")
  38     set(additional_cmdline
  39       -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  40       )
  41   endif()
  42
  43   if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  44     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  45   else()
  46     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
  47       ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
  48   endif()
  49   if (LLVM_ENABLE_DAGISEL_COV)
  50     list(FIND ARGN "-gen-dag-isel" idx)
  51     if( NOT idx EQUAL -1 )
  52       list(APPEND LLVM_TABLEGEN_FLAGS "-instrument-coverage")
  53     endif()
  54   endif()
  55
  56   # We need both _TABLEGEN_TARGET and _TABLEGEN_EXE in the  DEPENDS list
  57   # (both the target and the file) to have .inc files rebuilt on
  58   # a tablegen change, as cmake does not propagate file-level dependencies
  59   # of custom targets. See the following ticket for more information:
  60   # https://cmake.org/Bug/view.php?id=15858
  61   # The dependency on both, the target and the file, produces the same
  62   # dependency twice in the result file when
  63   # ("${${project}_TABLEGEN_TARGET}" STREQUAL "${${project}_TABLEGEN_EXE}")
  64   # but lets us having smaller and cleaner code here.
  65   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  66     # Generate tablegen output in a temporary file.
  67     COMMAND ${${project}_TABLEGEN_EXE} ${ARGN} -I ${CMAKE_CURRENT_SOURCE_DIR}
  68     ${LLVM_TABLEGEN_FLAGS}
  69     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  70     ${additional_cmdline}
  71     # The file in LLVM_TARGET_DEFINITIONS may be not in the current
  72     # directory and local_tds may not contain it, so we must
  73     # explicitly list it here:
  74     DEPENDS ${${project}_TABLEGEN_TARGET} ${${project}_TABLEGEN_EXE}
  75       ${local_tds} ${global_tds}
  76     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  77     COMMENT "Building ${ofn}..."
  78     )
  79   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  80     # Only update the real output file if there are any differences.
  81     # This prevents recompilation of all the files depending on it if there
  82     # aren't any.
  83     COMMAND ${CMAKE_COMMAND} -E copy_if_different
  84         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  85         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  86     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  87     COMMENT "Updating ${ofn}..."
  88     )
  89
  90   # `make clean' must remove all those generated files:
  91   set_property(DIRECTORY APPEND
  92     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${ofn}.tmp ${ofn})
  93
  94   set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn} PARENT_SCOPE)
  95   set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn} PROPERTIES
  96     GENERATED 1)
  97 endfunction()
  98
  99 # Creates a target for publicly exporting tablegen dependencies.
 100 function(add_public_tablegen_target target)
 101   if(NOT TABLEGEN_OUTPUT)
 102     message(FATAL_ERROR "Requires tablegen() definitions as TABLEGEN_OUTPUT.")
 103   endif()
 104   add_custom_target(${target}
 105     DEPENDS ${TABLEGEN_OUTPUT})
 106   if(LLVM_COMMON_DEPENDS)
 107     add_dependencies(${target} ${LLVM_COMMON_DEPENDS})
 108   endif()
 109   set_target_properties(${target} PROPERTIES FOLDER "Tablegenning")
 110   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${target} PARENT_SCOPE)
 111 endfunction()
 112
 113 if(LLVM_USE_HOST_TOOLS AND NOT TARGET NATIVE_LIB_LLVMTABLEGEN)
 114   llvm_ExternalProject_BuildCmd(tblgen_build_cmd LLVMSupport
 115     ${LLVM_NATIVE_BUILD}
 116     CONFIGURATION Release)
 117   add_custom_command(OUTPUT LIB_LLVMTABLEGEN
 118       COMMAND ${tblgen_build_cmd}
 119       DEPENDS CONFIGURE_LLVM_NATIVE
 120       WORKING_DIRECTORY ${LLVM_NATIVE_BUILD}
 121       COMMENT "Building libLLVMTableGen for native TableGen..."
 122       USES_TERMINAL)
 123   add_custom_target(NATIVE_LIB_LLVMTABLEGEN DEPENDS LIB_LLVMTABLEGEN)
 124 endif()
 125
 126 macro(add_tablegen target project)
 127   set(${target}_OLD_LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS})
 128   set(LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS} TableGen)
 129
 130   # CMake-3.9 doesn't let compilation units depend on their dependent libraries.
 131   if(NOT (CMAKE_GENERATOR STREQUAL "Ninja" AND NOT CMAKE_VERSION VERSION_LESS 3.9) AND NOT XCODE)
 132     # FIXME: It leaks to user, callee of add_tablegen.
 133     set(LLVM_ENABLE_OBJLIB ON)
 134   endif()
 135
 136   add_llvm_executable(${target} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 137   set(LLVM_LINK_COMPONENTS ${${target}_OLD_LLVM_LINK_COMPONENTS})
 138
 139   set(${project}_TABLEGEN "${target}" CACHE
 140       STRING "Native TableGen executable. Saves building one when cross-compiling.")
 141
 142   # Upgrade existing LLVM_TABLEGEN setting.
 143   if(${project} STREQUAL LLVM)
 144     if(${LLVM_TABLEGEN} STREQUAL tblgen)
 145       set(LLVM_TABLEGEN "${target}" CACHE
 146           STRING "Native TableGen executable. Saves building one when cross-compiling."
 147           FORCE)
 148     endif()
 149   endif()
 150
 151   # Effective tblgen executable to be used:
 152   set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN} PARENT_SCOPE)
 153   set(${project}_TABLEGEN_TARGET ${${project}_TABLEGEN} PARENT_SCOPE)
 154
 155   if(LLVM_USE_HOST_TOOLS)
 156     if( ${${project}_TABLEGEN} STREQUAL "${target}" )
 157       if (NOT CMAKE_CONFIGURATION_TYPES)
 158         set(${project}_TABLEGEN_EXE "${LLVM_NATIVE_BUILD}/bin/${target}")
 159       else()
 160         set(${project}_TABLEGEN_EXE "${LLVM_NATIVE_BUILD}/Release/bin/${target}")
 161       endif()
 162       set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN_EXE} PARENT_SCOPE)
 163
 164       llvm_ExternalProject_BuildCmd(tblgen_build_cmd ${target}
 165                                     ${LLVM_NATIVE_BUILD}
 166                                     CONFIGURATION Release)
 167       add_custom_command(OUTPUT ${${project}_TABLEGEN_EXE}
 168         COMMAND ${tblgen_build_cmd}
 169         DEPENDS ${target} NATIVE_LIB_LLVMTABLEGEN
 170         WORKING_DIRECTORY ${LLVM_NATIVE_BUILD}
 171         COMMENT "Building native TableGen..."
 172         USES_TERMINAL)
 173       add_custom_target(${project}-tablegen-host DEPENDS ${${project}_TABLEGEN_EXE})
 174       set(${project}_TABLEGEN_TARGET ${project}-tablegen-host PARENT_SCOPE)
 175     endif()
 176   endif()
 177
 178   if (${project} STREQUAL LLVM AND NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 179     if(${target} IN_LIST LLVM_DISTRIBUTION_COMPONENTS OR
 180         NOT LLVM_DISTRIBUTION_COMPONENTS)
 181       set(export_to_llvmexports EXPORT LLVMExports)
 182     endif()
 183
 184     install(TARGETS ${target}
 185             ${export_to_llvmexports}
 186             RUNTIME DESTINATION ${LLVM_TOOLS_INSTALL_DIR})
 187   endif()
 188   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${target})
 189 endmacro()