configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.67
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 102 AC_CHECK_PROGS([PYTHON3], [python3.5 python3.4 python3])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112
 113 AX_PROG_BISON([],
 114               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 115                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 116 AX_PROG_FLEX([],
 117              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 118                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 119
 120 AC_CHECK_PROG(INDENT, indent, indent, cat)
 121 if test "x$INDENT" != "xcat"; then
 122     # Only GNU indent is supported
 123     INDENT_VERSION=`indent --version | grep GNU`
 124     if test $? -eq 0; then
 125        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 126     else
 127        INDENT="cat"
 128     fi
 129 fi
 130
 131 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 132
 133 if test -z "$PYTHON2"; then
 134     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 135         AC_MSG_ERROR([Python not found - unable to generate sources])
 136     fi
 137 else
 138     if test "x$acv_mako_found" = xno; then
 139         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 140             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 141         fi
 142     fi
 143 fi
 144
 145 AC_PROG_INSTALL
 146
 147 dnl We need a POSIX shell for parts of the build. Assume we have one
 148 dnl in most cases.
 149 case "$host_os" in
 150 solaris*)
 151     # Solaris /bin/sh is too old/non-POSIX compliant
 152     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 153     SHELL="$POSIX_SHELL"
 154     ;;
 155 esac
 156
 157 dnl clang is mostly GCC-compatible, but its version is much lower,
 158 dnl so we have to check for it.
 159 AC_MSG_CHECKING([if compiling with clang])
 160
 161 AC_COMPILE_IFELSE(
 162 [AC_LANG_PROGRAM([], [[
 163 #ifndef __clang__
 164        not clang
 165 #endif
 166 ]])],
 167 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 168
 169 AC_MSG_RESULT([$acv_mesa_CLANG])
 170
 171 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 172 dnl versions are explictly not supported.
 173 GEN_ASM_OFFSETS=no
 174 USE_GNU99=no
 175 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 176     AC_MSG_CHECKING([whether gcc version is sufficient])
 177     major=0
 178     minor=0
 179
 180     GCC_VERSION=`$CC -dumpversion`
 181     if test $? -eq 0; then
 182         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 183         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 184     fi
 185
 186     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 187         AC_MSG_RESULT([no])
 188         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 189     else
 190         AC_MSG_RESULT([yes])
 191     fi
 192
 193     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 194         USE_GNU99=yes
 195     fi
 196     if test "x$cross_compiling" = xyes; then
 197         GEN_ASM_OFFSETS=yes
 198     fi
 199 fi
 200
 201 dnl We don't support building Mesa with Sun C compiler
 202 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 203 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 204 if test "x$SUNCC" = xyes; then
 205     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 206 fi
 207
 208 dnl Check for compiler builtins
 209 AX_GCC_BUILTIN([__builtin_bswap32])
 210 AX_GCC_BUILTIN([__builtin_bswap64])
 211 AX_GCC_BUILTIN([__builtin_clz])
 212 AX_GCC_BUILTIN([__builtin_clzll])
 213 AX_GCC_BUILTIN([__builtin_ctz])
 214 AX_GCC_BUILTIN([__builtin_expect])
 215 AX_GCC_BUILTIN([__builtin_ffs])
 216 AX_GCC_BUILTIN([__builtin_ffsll])
 217 AX_GCC_BUILTIN([__builtin_popcount])
 218 AX_GCC_BUILTIN([__builtin_popcountll])
 219 AX_GCC_BUILTIN([__builtin_unreachable])
 220
 221 AX_GCC_FUNC_ATTRIBUTE([const])
 222 AX_GCC_FUNC_ATTRIBUTE([flatten])
 223 AX_GCC_FUNC_ATTRIBUTE([format])
 224 AX_GCC_FUNC_ATTRIBUTE([malloc])
 225 AX_GCC_FUNC_ATTRIBUTE([packed])
 226 AX_GCC_FUNC_ATTRIBUTE([pure])
 227 AX_GCC_FUNC_ATTRIBUTE([unused])
 228 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 229
 230 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 231
 232 dnl Make sure the pkg-config macros are defined
 233 m4_ifndef([PKG_PROG_PKG_CONFIG],
 234     [m4_fatal([Could not locate the pkg-config autoconf macros.
 235   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 236   are in a different location, try setting the environment variable
 237   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 238 PKG_PROG_PKG_CONFIG()
 239
 240 dnl LIB_DIR - library basename
 241 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 242 AC_SUBST([LIB_DIR])
 243
 244 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 245 _SAVE_LDFLAGS="$LDFLAGS"
 246 _SAVE_CPPFLAGS="$CPPFLAGS"
 247
 248 dnl Compiler macros
 249 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 250 AC_SUBST([DEFINES])
 251 case "$host_os" in
 252 linux*|*-gnu*|gnu*)
 253     DEFINES="$DEFINES -D_GNU_SOURCE"
 254     ;;
 255 solaris*)
 256     DEFINES="$DEFINES -DSVR4"
 257     ;;
 258 cygwin*)
 259     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 260     ;;
 261 esac
 262
 263 dnl Add flags for gcc and g++
 264 if test "x$GCC" = xyes; then
 265     CFLAGS="$CFLAGS -Wall"
 266
 267     if test "x$USE_GNU99" = xyes; then
 268         CFLAGS="$CFLAGS -std=gnu99"
 269     else
 270         CFLAGS="$CFLAGS -std=c99"
 271     fi
 272
 273     # Enable -Werror=implicit-function-declaration and
 274     # -Werror=missing-prototypes, if available, or otherwise, just
 275     # -Wmissing-prototypes.  This is particularly useful to avoid
 276     # generating a loadable driver module that has undefined symbols.
 277     save_CFLAGS="$CFLAGS"
 278     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 279     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 280     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 281     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 282                    AC_MSG_RESULT([yes]),
 283                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 284                     AC_MSG_RESULT([no])]);
 285
 286     # Enable -fvisibility=hidden if using a gcc that supports it
 287     save_CFLAGS="$CFLAGS"
 288     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 289     VISIBILITY_CFLAGS="-fvisibility=hidden"
 290     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 291     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 292                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 293
 294     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 295     CFLAGS=$save_CFLAGS
 296
 297     # Work around aliasing bugs - developers should comment this out
 298     CFLAGS="$CFLAGS -fno-strict-aliasing"
 299
 300     # We don't want floating-point math functions to set errno or trap
 301     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 302
 303     # gcc's builtin memcmp is slower than glibc's
 304     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 305     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 306
 307     # Flags to help ensure that certain portions of the code -- and only those
 308     # portions -- can be built with MSVC:
 309     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326 fi
 327 if test "x$GXX" = xyes; then
 328     CXXFLAGS="$CXXFLAGS -Wall"
 329
 330     # Enable -fvisibility=hidden if using a gcc that supports it
 331     save_CXXFLAGS="$CXXFLAGS"
 332     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 333     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 334     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 335     AC_LANG_PUSH([C++])
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 337                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 338     AC_LANG_POP([C++])
 339
 340     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 341     CXXFLAGS=$save_CXXFLAGS
 342
 343     # Work around aliasing bugs - developers should comment this out
 344     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 345
 346     # gcc's builtin memcmp is slower than glibc's
 347     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 348     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 349 fi
 350
 351 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 352 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 353
 354 dnl even if the compiler appears to support it, using visibility attributes isn't
 355 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 356 case "$host_os" in
 357 cygwin*)
 358     VISIBILITY_CFLAGS=""
 359     VISIBILITY_CXXFLAGS=""
 360     ;;
 361 esac
 362
 363 AC_SUBST([VISIBILITY_CFLAGS])
 364 AC_SUBST([VISIBILITY_CXXFLAGS])
 365
 366 dnl
 367 dnl Optional flags, check for compiler support
 368 dnl
 369 SSE41_CFLAGS="-msse4.1"
 370 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 371 dnl stack, but on x86-32 such alignment is not guaranteed.
 372 case "$target_cpu" in
 373 i?86)
 374     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 375     ;;
 376 esac
 377 save_CFLAGS="$CFLAGS"
 378 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 379 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 380 #include <smmintrin.h>
 381 int param;
 382 int main () {
 383     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 384     c = _mm_max_epu32(a, b);
 385     return _mm_cvtsi128_si32(c);
 386 }]])], SSE41_SUPPORTED=1)
 387 CFLAGS="$save_CFLAGS"
 388 if test "x$SSE41_SUPPORTED" = x1; then
 389     DEFINES="$DEFINES -DUSE_SSE41"
 390 fi
 391 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 392 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 393
 394 dnl Check for Endianness
 395 AC_C_BIGENDIAN(
 396    little_endian=no,
 397    little_endian=yes,
 398    little_endian=no,
 399    little_endian=no
 400 )
 401
 402 dnl Check for POWER8 Architecture
 403 PWR8_CFLAGS="-mpower8-vector"
 404 have_pwr8_intrinsics=no
 405 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 406 save_CFLAGS=$CFLAGS
 407 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 408 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 409 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 410 #error "Need GCC >= 4.8 for sane POWER8 support"
 411 #endif
 412 #include <altivec.h>
 413 int main () {
 414     vector unsigned char r;
 415     vector unsigned int v = vec_splat_u32 (1);
 416     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 417     return 0;
 418 }]])], have_pwr8_intrinsics=yes)
 419 CFLAGS=$save_CFLAGS
 420
 421 AC_ARG_ENABLE(pwr8,
 422    [AC_HELP_STRING([--disable-pwr8-inst],
 423                    [disable POWER8-specific instructions])],
 424    [enable_pwr8=$enableval], [enable_pwr8=auto])
 425
 426 if test "x$enable_pwr8" = xno ; then
 427    have_pwr8_intrinsics=disabled
 428 fi
 429
 430 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 431    DEFINES="$DEFINES -D_ARCH_PWR8"
 432    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 433    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 434 else
 435    PWR8_CFLAGS=
 436 fi
 437
 438 AC_MSG_RESULT($have_pwr8_intrinsics)
 439 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 440    AC_MSG_ERROR([POWER8 compiler support not detected])
 441 fi
 442
 443 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 444    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 445 fi
 446
 447 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 448
 449 dnl Can't have static and shared libraries, default to static if user
 450 dnl explicitly requested. If both disabled, set to static since shared
 451 dnl was explicitly requested.
 452 case "x$enable_static$enable_shared" in
 453 xyesyes)
 454     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 455     enable_shared=no
 456     ;;
 457 xnono)
 458     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 459     enable_shared=yes
 460     ;;
 461 esac
 462
 463 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 464
 465 dnl
 466 dnl other compiler options
 467 dnl
 468 AC_ARG_ENABLE([debug],
 469     [AS_HELP_STRING([--enable-debug],
 470         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 471     [enable_debug="$enableval"],
 472     [enable_debug=no]
 473 )
 474
 475 AC_ARG_ENABLE([profile],
 476     [AS_HELP_STRING([--enable-profile],
 477         [enable profiling of code @<:@default=disabled@:>@])],
 478     [enable_profile="$enableval"],
 479     [enable_profile=no]
 480 )
 481
 482 if test "x$enable_profile" = xyes; then
 483     DEFINES="$DEFINES -DPROFILE"
 484     if test "x$GCC" = xyes; then
 485         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 486     fi
 487     if test "x$GXX" = xyes; then
 488         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 489     fi
 490 fi
 491
 492 if test "x$enable_debug" = xyes; then
 493     DEFINES="$DEFINES -DDEBUG"
 494     if test "x$enable_profile" = xyes; then
 495         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 496     fi
 497     if test "x$GCC" = xyes; then
 498         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 499             CFLAGS="$CFLAGS -g"
 500         fi
 501         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 502             CFLAGS="$CFLAGS -O0"
 503         fi
 504     fi
 505     if test "x$GXX" = xyes; then
 506         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 507             CXXFLAGS="$CXXFLAGS -g"
 508         fi
 509         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 510             CXXFLAGS="$CXXFLAGS -O0"
 511         fi
 512     fi
 513 else
 514    DEFINES="$DEFINES -DNDEBUG"
 515 fi
 516
 517 dnl
 518 dnl Check if linker supports -Bsymbolic
 519 dnl
 520 save_LDFLAGS=$LDFLAGS
 521 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 522 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 523 AC_LINK_IFELSE(
 524     [AC_LANG_SOURCE([int main() { return 0;}])],
 525     [AC_MSG_RESULT([yes])
 526         BSYMBOLIC="-Wl,-Bsymbolic";],
 527     [AC_MSG_RESULT([no])
 528         BSYMBOLIC="";])
 529 LDFLAGS=$save_LDFLAGS
 530
 531 AC_SUBST([BSYMBOLIC])
 532
 533 dnl
 534 dnl Check if linker supports garbage collection
 535 dnl
 536 save_LDFLAGS=$LDFLAGS
 537 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 538 AC_MSG_CHECKING([whether ld supports --gc-sections])
 539 AC_LINK_IFELSE(
 540     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 541     [AC_MSG_RESULT([yes])
 542         GC_SECTIONS="-Wl,--gc-sections";],
 543     [AC_MSG_RESULT([no])
 544         GC_SECTIONS="";])
 545 LDFLAGS=$save_LDFLAGS
 546
 547 AC_SUBST([GC_SECTIONS])
 548
 549 dnl
 550 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 551 dnl so when these flags are passed to ld via libtool the checks will fail
 552 dnl
 553 case "$host_os" in
 554 openbsd* | darwin* )
 555     LD_NO_UNDEFINED="" ;;
 556 *)
 557     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 558 esac
 559
 560 AC_SUBST([LD_NO_UNDEFINED])
 561
 562 dnl
 563 dnl Check if linker supports version scripts
 564 dnl
 565 AC_MSG_CHECKING([if the linker supports version-scripts])
 566 save_LDFLAGS=$LDFLAGS
 567 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 568 cat > conftest.map <<EOF
 569 VERSION_1 {
 570      global:
 571          main;
 572
 573      local:
 574          *;
 575 };
 576 EOF
 577 AC_LINK_IFELSE(
 578     [AC_LANG_SOURCE([int main() { return 0;}])],
 579     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 580     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 581 LDFLAGS=$save_LDFLAGS
 582 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 583
 584 dnl
 585 dnl Check if linker supports dynamic list files
 586 dnl
 587 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 588 save_LDFLAGS=$LDFLAGS
 589 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 590 cat > conftest.dyn <<EOF
 591 {
 592         radeon_drm_winsys_create;
 593 };
 594 EOF
 595 AC_LINK_IFELSE(
 596     [AC_LANG_SOURCE([int main() { return 0;}])],
 597     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 598     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 599 LDFLAGS=$save_LDFLAGS
 600 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 601
 602 dnl
 603 dnl compatibility symlinks
 604 dnl
 605 case "$host_os" in
 606 linux* )
 607     HAVE_COMPAT_SYMLINKS=yes ;;
 608 * )
 609     HAVE_COMPAT_SYMLINKS=no ;;
 610 esac
 611
 612 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 613
 614 dnl
 615 dnl library names
 616 dnl
 617 dnl Unfortunately we need to do a few things that libtool can't help us with,
 618 dnl so we need some knowledge of shared library filenames:
 619 dnl
 620 dnl LIB_EXT is the extension used when creating symlinks for alternate
 621 dnl filenames for a shared library which will be dynamically loaded
 622 dnl
 623 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 624 dnl the file for a shared library we wish to link with
 625 dnl
 626 case "$host_os" in
 627 darwin* )
 628     LIB_EXT='dylib'
 629     IMP_LIB_EXT=$LIB_EXT
 630     ;;
 631 cygwin* )
 632     LIB_EXT='dll'
 633     IMP_LIB_EXT='dll.a'
 634     ;;
 635 aix* )
 636     LIB_EXT='a'
 637     IMP_LIB_EXT=$LIB_EXT
 638     ;;
 639 * )
 640     LIB_EXT='so'
 641     IMP_LIB_EXT=$LIB_EXT
 642     ;;
 643 esac
 644
 645 AC_SUBST([LIB_EXT])
 646
 647 AC_ARG_WITH([gl-lib-name],
 648   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 649     [specify GL library name @<:@default=GL@:>@])],
 650   [GL_LIB=$withval],
 651   [GL_LIB=GL])
 652 AC_ARG_WITH([osmesa-lib-name],
 653   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 654     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 655   [OSMESA_LIB=$withval],
 656   [OSMESA_LIB=OSMesa])
 657 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 658 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 659
 660 dnl
 661 dnl Mangled Mesa support
 662 dnl
 663 AC_ARG_ENABLE([mangling],
 664   [AS_HELP_STRING([--enable-mangling],
 665     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 666   [enable_mangling="${enableval}"],
 667   [enable_mangling=no]
 668 )
 669 if test "x${enable_mangling}" = "xyes" ; then
 670   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 671   GL_LIB="Mangled${GL_LIB}"
 672   OSMESA_LIB="Mangled${OSMESA_LIB}"
 673 fi
 674 AC_SUBST([GL_LIB])
 675 AC_SUBST([OSMESA_LIB])
 676
 677 dnl
 678 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 679 dnl
 680 AC_ARG_ENABLE([texture-float],
 681     [AS_HELP_STRING([--enable-texture-float],
 682         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 683     [enable_texture_float="$enableval"],
 684     [enable_texture_float=no]
 685 )
 686 if test "x$enable_texture_float" = xyes; then
 687     AC_MSG_WARN([Floating-point textures enabled.])
 688     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 689     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 690 fi
 691
 692 dnl
 693 dnl Arch/platform-specific settings
 694 dnl
 695 AC_ARG_ENABLE([asm],
 696     [AS_HELP_STRING([--disable-asm],
 697         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 698     [enable_asm="$enableval"],
 699     [enable_asm=yes]
 700 )
 701 asm_arch=""
 702 AC_MSG_CHECKING([whether to enable assembly])
 703 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 704 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 705 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 706     case "$host_cpu" in
 707     i?86 | x86_64 | amd64)
 708         if test "x$host_cpu" != "x$target_cpu"; then
 709             enable_asm=no
 710             AC_MSG_RESULT([no, cross compiling])
 711         fi
 712         ;;
 713     esac
 714 fi
 715 # check for supported arches
 716 if test "x$enable_asm" = xyes; then
 717     case "$host_cpu" in
 718     i?86)
 719         case "$host_os" in
 720         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 721             asm_arch=x86
 722             ;;
 723         esac
 724         ;;
 725     x86_64|amd64)
 726         case "$host_os" in
 727         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 728             asm_arch=x86_64
 729             ;;
 730         esac
 731         ;;
 732     sparc*)
 733         case "$host_os" in
 734         linux*)
 735             asm_arch=sparc
 736             ;;
 737         esac
 738         ;;
 739     esac
 740
 741     case "$asm_arch" in
 742     x86)
 743         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 744         AC_MSG_RESULT([yes, x86])
 745         ;;
 746     x86_64|amd64)
 747         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 748         AC_MSG_RESULT([yes, x86_64])
 749         ;;
 750     sparc)
 751         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 752         AC_MSG_RESULT([yes, sparc])
 753         ;;
 754     *)
 755         AC_MSG_RESULT([no, platform not supported])
 756         ;;
 757     esac
 758 fi
 759
 760 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 761 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 762 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 763 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 764
 765 dnl Check to see if dlopen is in default libraries (like Solaris, which
 766 dnl has it in libc), or if libdl is needed to get it.
 767 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 768     [AC_CHECK_LIB([dl], [dlopen],
 769        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 770 AC_SUBST([DLOPEN_LIBS])
 771
 772 dnl Check if that library also has dladdr
 773 save_LIBS="$LIBS"
 774 LIBS="$LIBS $DLOPEN_LIBS"
 775 AC_CHECK_FUNCS([dladdr])
 776 LIBS="$save_LIBS"
 777
 778 case "$host_os" in
 779 darwin*)
 780     ;;
 781 *)
 782     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 783                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 784                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 785     AC_SUBST([CLOCK_LIB])
 786     ;;
 787 esac
 788
 789 dnl See if posix_memalign is available
 790 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 791
 792 dnl Check for pthreads
 793 AX_PTHREAD
 794 if test "x$ax_pthread_ok" = xno; then
 795     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 796 fi
 797 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 798 dnl to -pthread, which causes problems if we need -lpthread to appear in
 799 dnl pkgconfig files.
 800 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 801
 802 dnl SELinux awareness.
 803 AC_ARG_ENABLE([selinux],
 804     [AS_HELP_STRING([--enable-selinux],
 805         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 806     [MESA_SELINUX="$enableval"],
 807     [MESA_SELINUX=no])
 808 if test "x$enable_selinux" = "xyes"; then
 809     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 810         [AC_CHECK_HEADER([selinux/selinux.h],[],
 811                          [AC_MSG_ERROR([SELinux headers not found])])
 812          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 813                       [AC_MSG_ERROR([SELinux library not found])])
 814          SELINUX_LIBS="-lselinux"])
 815     DEFINES="$DEFINES -DMESA_SELINUX"
 816 fi
 817 AC_SUBST([SELINUX_CFLAGS])
 818 AC_SUBST([SELINUX_LIBS])
 819
 820 dnl Options for APIs
 821 AC_ARG_ENABLE([opengl],
 822     [AS_HELP_STRING([--disable-opengl],
 823         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 824     [enable_opengl="$enableval"],
 825     [enable_opengl=yes])
 826 AC_ARG_ENABLE([gles1],
 827     [AS_HELP_STRING([--disable-gles1],
 828         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 829     [enable_gles1="$enableval"],
 830     [enable_gles1=yes])
 831 AC_ARG_ENABLE([gles2],
 832     [AS_HELP_STRING([--disable-gles2],
 833         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 834     [enable_gles2="$enableval"],
 835     [enable_gles2=yes])
 836
 837 AC_ARG_ENABLE([dri],
 838     [AS_HELP_STRING([--enable-dri],
 839         [enable DRI modules @<:@default=enabled@:>@])],
 840     [enable_dri="$enableval"],
 841     [enable_dri=yes])
 842
 843 case "$host_os" in
 844 linux*)
 845     dri3_default=yes
 846     ;;
 847 *)
 848     dri3_default=no
 849     ;;
 850 esac
 851
 852 if test "x$enable_dri" = xno; then
 853     dri3_default=no
 854 fi
 855
 856 AC_ARG_ENABLE([dri3],
 857     [AS_HELP_STRING([--enable-dri3],
 858         [enable DRI3 @<:@default=auto@:>@])],
 859     [enable_dri3="$enableval"],
 860     [enable_dri3="$dri3_default"])
 861 AC_ARG_ENABLE([glx],
 862     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 863         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 864     [enable_glx="$enableval"],
 865     [enable_glx=yes])
 866 AC_ARG_ENABLE([osmesa],
 867     [AS_HELP_STRING([--enable-osmesa],
 868         [enable OSMesa library @<:@default=disabled@:>@])],
 869     [enable_osmesa="$enableval"],
 870     [enable_osmesa=no])
 871 AC_ARG_ENABLE([gallium-osmesa],
 872     [AS_HELP_STRING([--enable-gallium-osmesa],
 873         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 874     [enable_gallium_osmesa="$enableval"],
 875     [enable_gallium_osmesa=no])
 876 AC_ARG_ENABLE([egl],
 877     [AS_HELP_STRING([--disable-egl],
 878         [disable EGL library @<:@default=enabled@:>@])],
 879     [enable_egl="$enableval"],
 880     [enable_egl=yes])
 881
 882 AC_ARG_ENABLE([xa],
 883     [AS_HELP_STRING([--enable-xa],
 884         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 885     [enable_xa="$enableval"],
 886     [enable_xa=no])
 887 AC_ARG_ENABLE([gbm],
 888    [AS_HELP_STRING([--enable-gbm],
 889          [enable gbm library @<:@default=auto@:>@])],
 890    [enable_gbm="$enableval"],
 891    [enable_gbm=auto])
 892 AC_ARG_ENABLE([nine],
 893     [AS_HELP_STRING([--enable-nine],
 894         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 895     [enable_nine="$enableval"],
 896     [enable_nine=no])
 897
 898 AC_ARG_ENABLE([xvmc],
 899    [AS_HELP_STRING([--enable-xvmc],
 900          [enable xvmc library @<:@default=auto@:>@])],
 901    [enable_xvmc="$enableval"],
 902    [enable_xvmc=auto])
 903 AC_ARG_ENABLE([vdpau],
 904    [AS_HELP_STRING([--enable-vdpau],
 905          [enable vdpau library @<:@default=auto@:>@])],
 906    [enable_vdpau="$enableval"],
 907    [enable_vdpau=auto])
 908 AC_ARG_ENABLE([omx],
 909    [AS_HELP_STRING([--enable-omx],
 910          [enable OpenMAX library @<:@default=disabled@:>@])],
 911    [enable_omx="$enableval"],
 912    [enable_omx=no])
 913 AC_ARG_ENABLE([va],
 914    [AS_HELP_STRING([--enable-va],
 915          [enable va library @<:@default=auto@:>@])],
 916    [enable_va="$enableval"],
 917    [enable_va=auto])
 918 AC_ARG_ENABLE([opencl],
 919    [AS_HELP_STRING([--enable-opencl],
 920          [enable OpenCL library @<:@default=disabled@:>@])],
 921    [enable_opencl="$enableval"],
 922    [enable_opencl=no])
 923 AC_ARG_ENABLE([opencl_icd],
 924    [AS_HELP_STRING([--enable-opencl-icd],
 925           [Build an OpenCL ICD library to be loaded by an ICD implementation
 926            @<:@default=disabled@:>@])],
 927     [enable_opencl_icd="$enableval"],
 928     [enable_opencl_icd=no])
 929
 930 AC_ARG_ENABLE([gallium-tests],
 931     [AS_HELP_STRING([--enable-gallium-tests],
 932         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 933     [enable_gallium_tests="$enableval"],
 934     [enable_gallium_tests=no])
 935
 936 # Option for Gallium drivers
 937
 938 # Keep this in sync with the --with-gallium-drivers help string default value
 939 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 940
 941 AC_ARG_WITH([gallium-drivers],
 942     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 943         [comma delimited Gallium drivers list, e.g.
 944         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 945         @<:@default=r300,r600,svga,swrast@:>@])],
 946     [with_gallium_drivers="$withval"],
 947     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 948
 949 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 950 # here so that the script doesn't choke on an unknown driver name later.
 951 case "$with_gallium_drivers" in
 952     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 953     no) with_gallium_drivers='' ;;
 954 esac
 955
 956 if test "x$enable_opengl" = xno -a \
 957         "x$enable_gles1" = xno -a \
 958         "x$enable_gles2" = xno -a \
 959         "x$enable_nine" = xno -a \
 960         "x$enable_xa" = xno -a \
 961         "x$enable_xvmc" = xno -a \
 962         "x$enable_vdpau" = xno -a \
 963         "x$enable_omx" = xno -a \
 964         "x$enable_va" = xno -a \
 965         "x$enable_opencl" = xno; then
 966     AC_MSG_ERROR([at least one API should be enabled])
 967 fi
 968
 969 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 970 if test "x$enable_opengl" = xno -a \
 971         "x$enable_gles1" = xyes; then
 972     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 973 fi
 974
 975 if test "x$enable_opengl" = xno -a \
 976         "x$enable_gles2" = xyes; then
 977     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 978 fi
 979
 980 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 981 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 982 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 983 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 984                                         "x$enable_gles1" = xyes -o \
 985                                         "x$enable_gles2" = xyes)
 986
 987 # Validate GLX options
 988 if test "x$enable_glx" = xyes; then
 989     if test "x$enable_dri" = xyes; then
 990         enable_glx=dri
 991     elif test -n "$with_gallium_drivers"; then
 992         enable_glx=gallium-xlib
 993     else
 994         enable_glx=xlib
 995     fi
 996 fi
 997 case "x$enable_glx" in
 998 xdri | xxlib | xgallium-xlib)
 999     # GLX requires OpenGL
1000     if test "x$enable_opengl" = xno; then
1001         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1002     fi
1003
1004     # Check individual dependencies
1005     case "x$enable_glx" in
1006     xdri)
1007         if test "x$enable_dri" = xno; then
1008             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1009         fi
1010         ;;
1011     xxlib)
1012         if test "x$enable_dri" = xyes; then
1013             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1014         fi
1015         ;;
1016     xgallium-xlib )
1017         if test "x$enable_dri" = xyes; then
1018             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1019         fi
1020         if test -z "$with_gallium_drivers"; then
1021             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1022         fi
1023         ;;
1024     esac
1025     ;;
1026 xno)
1027     ;;
1028 *)
1029     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1030     ;;
1031 esac
1032
1033 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1034 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1035 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1036
1037 # Check for libdrm
1038 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1039                   [have_libdrm=yes], [have_libdrm=no])
1040 if test "x$have_libdrm" = xyes; then
1041         DEFINES="$DEFINES -DHAVE_LIBDRM"
1042 fi
1043
1044 # Select which platform-dependent DRI code gets built
1045 case "$host_os" in
1046 darwin*)
1047     dri_platform='apple' ;;
1048 gnu*|cygwin*)
1049     dri_platform='none' ;;
1050 *)
1051     dri_platform='drm' ;;
1052 esac
1053
1054 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1055     have_drisw_kms='yes'
1056 fi
1057
1058 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1059 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1060 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1061 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1062 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1063 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1064
1065 AC_ARG_ENABLE([shared-glapi],
1066     [AS_HELP_STRING([--enable-shared-glapi],
1067         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1068     [enable_shared_glapi="$enableval"],
1069     [enable_shared_glapi=yes])
1070
1071 case "x$enable_opengl$enable_gles1$enable_gles2" in
1072 x*yes*yes*)
1073     if test "x$enable_shared_glapi" = xno; then
1074         AC_MSG_ERROR([shared GLAPI required when building two or more of
1075                       the following APIs - opengl, gles1 gles2])
1076     fi
1077     ;;
1078 esac
1079
1080 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1081
1082 # Build the pipe-drivers as separate libraries/modules.
1083 # Do not touch this unless you know what you are doing.
1084 # XXX: Expose via configure option ?
1085 enable_shared_pipe_drivers=no
1086
1087 dnl
1088 dnl Driver specific build directories
1089 dnl
1090
1091 if test "x$enable_gallium_osmesa" = xyes; then
1092     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1093         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1094     fi
1095     if test "x$enable_osmesa" = xyes; then
1096         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1097     fi
1098 fi
1099
1100 AC_SUBST([MESA_LLVM])
1101
1102 # SHA1 hashing
1103 AC_ARG_WITH([sha1],
1104         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1105         [choose SHA1 implementation])])
1106 case "x$with_sha1" in
1107 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1108   ;;
1109 *)
1110         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1111 esac
1112
1113 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1114 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1115         with_sha1=libc
1116 fi
1117 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1118         AC_MSG_ERROR([sha1 in libc requested but not found])
1119 fi
1120 if test "x$with_sha1" = xlibc; then
1121         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1122                 [Use libc SHA1 functions])
1123         SHA1_LIBS=""
1124 fi
1125 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1126 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1127         with_sha1=CommonCrypto
1128 fi
1129 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1130         AC_MSG_ERROR([CommonCrypto requested but not found])
1131 fi
1132 if test "x$with_sha1" = xCommonCrypto; then
1133         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1134                 [Use CommonCrypto SHA1 functions])
1135         SHA1_LIBS=""
1136 fi
1137 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1138 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1139 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1140         with_sha1=CryptoAPI
1141 fi
1142 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1143         AC_MSG_ERROR([CryptoAPI requested but not found])
1144 fi
1145 if test "x$with_sha1" = xCryptoAPI; then
1146         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1147                 [Use CryptoAPI SHA1 functions])
1148         SHA1_LIBS=""
1149 fi
1150 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1151 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1152         with_sha1=libmd
1153 fi
1154 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1155         AC_MSG_ERROR([libmd requested but not found])
1156 fi
1157 if test "x$with_sha1" = xlibmd; then
1158         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1159                   [Use libmd SHA1 functions])
1160         SHA1_LIBS=-lmd
1161 fi
1162 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1163 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1164    with_sha1=libsha1
1165 fi
1166 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1167         AC_MSG_ERROR([libsha1 requested but not found])
1168 fi
1169 if test "x$with_sha1" = xlibsha1; then
1170         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1171                   [Use libsha1 for SHA1])
1172         SHA1_LIBS=-lsha1
1173 fi
1174 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1175 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1176         with_sha1=libnettle
1177 fi
1178 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1179         AC_MSG_ERROR([libnettle requested but not found])
1180 fi
1181 if test "x$with_sha1" = xlibnettle; then
1182         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1183                   [Use libnettle SHA1 functions])
1184         SHA1_LIBS=-lnettle
1185 fi
1186 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1187 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1188         with_sha1=libgcrypt
1189 fi
1190 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1191         AC_MSG_ERROR([libgcrypt requested but not found])
1192 fi
1193 if test "x$with_sha1" = xlibgcrypt; then
1194         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1195                   [Use libgcrypt SHA1 functions])
1196         SHA1_LIBS=-lgcrypt
1197 fi
1198 # We don't need all of the OpenSSL libraries, just libcrypto
1199 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1200 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1201                   [HAVE_OPENSSL_PKC=no])
1202 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1203         if test "x$with_sha1" = x; then
1204                 with_sha1=libcrypto
1205         fi
1206 else
1207         if test "x$with_sha1" = xlibcrypto; then
1208                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1209         fi
1210 fi
1211 if test "x$with_sha1" = xlibcrypto; then
1212         if test "x$HAVE_LIBCRYPTO" = xyes; then
1213                 SHA1_LIBS=-lcrypto
1214         else
1215                 SHA1_LIBS="$OPENSSL_LIBS"
1216                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1217         fi
1218 fi
1219 AC_MSG_CHECKING([for SHA1 implementation])
1220 AC_MSG_RESULT([$with_sha1])
1221 AC_SUBST(SHA1_LIBS)
1222 AC_SUBST(SHA1_CFLAGS)
1223
1224 # Enable a define for SHA1
1225 if test "x$with_sha1" != "x"; then
1226         DEFINES="$DEFINES -DHAVE_SHA1"
1227 fi
1228
1229 # Allow user to configure out the shader-cache feature
1230 AC_ARG_ENABLE([shader-cache],
1231     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1232     [enable_shader_cache="$enableval"],
1233     [if test "x$with_sha1" != "x"; then
1234         enable_shader_cache=yes
1235      else
1236         enable_shader_cache=no
1237      fi])
1238 if test "x$with_sha1" = "x"; then
1239     if test "x$enable_shader_cache" = "xyes"; then
1240         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1241     fi
1242 fi
1243 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1244
1245 case "$host_os" in
1246 linux*)
1247     need_pci_id=yes ;;
1248 *)
1249     need_pci_id=no ;;
1250 esac
1251
1252 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1253                   have_libudev=yes, have_libudev=no)
1254
1255 AC_ARG_ENABLE([sysfs],
1256     [AS_HELP_STRING([--enable-sysfs],
1257         [enable /sys PCI identification @<:@default=disabled@:>@])],
1258     [have_sysfs="$enableval"],
1259     [have_sysfs=no]
1260 )
1261
1262 if test "x$enable_dri" = xyes; then
1263     if test "$enable_static" = yes; then
1264         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1265     fi
1266
1267     # not a hard requirement as swrast does not depend on it
1268     if test "x$have_libdrm" = xyes; then
1269         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1270     fi
1271 fi
1272
1273 AC_ARG_ENABLE([driglx-direct],
1274     [AS_HELP_STRING([--disable-driglx-direct],
1275         [disable direct rendering in GLX and EGL for DRI \
1276             @<:@default=auto@:>@])],
1277     [driglx_direct="$enableval"],
1278     [driglx_direct="yes"])
1279
1280 dnl
1281 dnl libGL configuration per driver
1282 dnl
1283 case "x$enable_glx" in
1284 xxlib | xgallium-xlib)
1285     # Xlib-based GLX
1286     dri_modules="x11 xext xcb"
1287     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1288     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1289     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1290     GL_LIB_DEPS="$XLIBGL_LIBS"
1291     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1292     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1293     ;;
1294 xdri)
1295     # DRI-based GLX
1296     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1297
1298     # find the DRI deps for libGL
1299     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1300
1301     if test x"$driglx_direct" = xyes; then
1302         if test x"$dri_platform" = xdrm ; then
1303             DEFINES="$DEFINES -DGLX_USE_DRM"
1304             if test "x$have_libdrm" != xyes; then
1305                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1306             fi
1307
1308             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1309             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1310             if test x"$enable_dri3" = xyes; then
1311                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1312                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1313             fi
1314
1315             if test x"$enable_dri" = xyes; then
1316                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1317             fi
1318
1319             if test x"$enable_dri3" = xyes; then
1320                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1321                dri3_modules="xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1322                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1323             fi
1324         fi
1325         if test x"$dri_platform" = xapple ; then
1326             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1327         fi
1328     fi
1329
1330     # add xf86vidmode if available
1331     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1332     if test "$HAVE_XF86VIDMODE" = yes ; then
1333         dri_modules="$dri_modules xxf86vm"
1334     fi
1335
1336     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1337     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1338     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1339     GL_LIB_DEPS="$DRIGL_LIBS"
1340
1341     # need DRM libs, $PTHREAD_LIBS, etc.
1342     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1343     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1344     ;;
1345 esac
1346
1347 have_pci_id=no
1348 if test "$have_libudev" = yes; then
1349     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1350     have_pci_id=yes
1351 fi
1352
1353 if test "$have_sysfs" = yes; then
1354     DEFINES="$DEFINES -DHAVE_SYSFS"
1355     have_pci_id=yes
1356 fi
1357
1358 # This is outside the case (above) so that it is invoked even for non-GLX
1359 # builds.
1360 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1361
1362 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1363 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1364 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1365 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1366
1367 AC_SUBST([X11_INCLUDES])
1368 AC_SUBST([GL_LIB_DEPS])
1369 AC_SUBST([GL_PC_REQ_PRIV])
1370 AC_SUBST([GL_PC_LIB_PRIV])
1371 AC_SUBST([GL_PC_CFLAGS])
1372 AC_SUBST([DRI_PC_REQ_PRIV])
1373 AC_SUBST([GLESv1_CM_LIB_DEPS])
1374 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1375 AC_SUBST([GLESv2_LIB_DEPS])
1376 AC_SUBST([GLESv2_PC_LIB_PRIV])
1377
1378 AC_SUBST([HAVE_XF86VIDMODE])
1379
1380 dnl
1381 dnl More GLX setup
1382 dnl
1383 case "x$enable_glx" in
1384 xxlib | xgallium-xlib)
1385     DEFINES="$DEFINES -DUSE_XSHM"
1386     ;;
1387 xdri)
1388     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1389     if test "x$driglx_direct" = xyes; then
1390         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1391     fi
1392     ;;
1393 esac
1394
1395 dnl
1396 dnl TLS detection
1397 dnl
1398
1399 AC_ARG_ENABLE([glx-tls],
1400     [AS_HELP_STRING([--enable-glx-tls],
1401         [enable TLS support in GLX @<:@default=disabled@:>@])],
1402     [GLX_USE_TLS="$enableval"],
1403     [GLX_USE_TLS=no])
1404 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1405
1406 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1407       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1408
1409 dnl Read-only text section on x86 hardened platforms
1410 AC_ARG_ENABLE([glx-read-only-text],
1411     [AS_HELP_STRING([--enable-glx-read-only-text],
1412         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1413     [enable_glx_read_only_text="$enableval"],
1414     [enable_glx_read_only_text=no])
1415 if test "x$enable_glx_read_only_text" = xyes; then
1416     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1417 fi
1418
1419 dnl
1420 dnl More DRI setup
1421 dnl
1422 dnl Directory for DRI drivers
1423 AC_ARG_WITH([dri-driverdir],
1424     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1425         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1426     [DRI_DRIVER_INSTALL_DIR="$withval"],
1427     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1428 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1429 dnl Extra search path for DRI drivers
1430 AC_ARG_WITH([dri-searchpath],
1431     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1432         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1433     [DRI_DRIVER_SEARCH_DIR="$withval"],
1434     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1435 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1436 dnl Which drivers to build - default is chosen by platform
1437 AC_ARG_WITH([dri-drivers],
1438     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1439         [comma delimited classic DRI drivers list, e.g.
1440         "swrast,i965,radeon" @<:@default=auto@:>@])],
1441     [with_dri_drivers="$withval"],
1442     [with_dri_drivers=auto])
1443
1444 if test "x$with_dri_drivers" = xauto; then
1445     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1446         with_dri_drivers="yes"
1447     else
1448         with_dri_drivers="no"
1449     fi
1450 fi
1451 if test "x$with_dri_drivers" = xno; then
1452     with_dri_drivers=''
1453 fi
1454
1455 dnl If $with_dri_drivers is yes, drivers will be added through
1456 dnl platform checks. Set DEFINES and LIB_DEPS
1457 if test "x$enable_dri" = xyes; then
1458     # Platform specific settings and drivers to build
1459     case "$host_os" in
1460     linux*)
1461         DEFINES="$DEFINES -DHAVE_ALIAS"
1462         if test "x$enable_dri3" = xyes; then
1463             DEFINES="$DEFINES -DHAVE_DRI3"
1464         fi
1465
1466         if test "x$have_pci_id" != xyes; then
1467             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1468         fi
1469
1470         case "$host_cpu" in
1471         powerpc* | sparc*)
1472             # Build only the drivers for cards that exist on PowerPC/sparc
1473             if test "x$with_dri_drivers" = "xyes"; then
1474                 with_dri_drivers="r200 radeon swrast"
1475             fi
1476             ;;
1477         esac
1478         ;;
1479     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1480         DEFINES="$DEFINES -DHAVE_ALIAS"
1481         ;;
1482     gnu*)
1483         DEFINES="$DEFINES -DHAVE_ALIAS"
1484         ;;
1485     cygwin*)
1486         if test "x$with_dri_drivers" = "xyes"; then
1487             with_dri_drivers="swrast"
1488         fi
1489         ;;
1490     darwin*)
1491         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1492         if test "x$with_dri_drivers" = "xyes"; then
1493             with_dri_drivers="swrast"
1494         fi
1495         ;;
1496     esac
1497
1498     # default drivers
1499     if test "x$with_dri_drivers" = "xyes"; then
1500         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1501     fi
1502
1503     # Check for expat
1504     PKG_CHECK_MODULES([EXPAT], [expat], [],
1505         # expat version 2.0 and earlier do not provide expat.pc
1506         [AC_CHECK_HEADER([expat.h],[],
1507                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1508          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1509                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1510          EXPAT_LIBS="-lexpat"])
1511
1512     # put all the necessary libs together
1513     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1514 fi
1515
1516 AC_SUBST([DRI_LIB_DEPS])
1517
1518 DRI_DIRS=''
1519 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1520 if test -n "$with_dri_drivers"; then
1521     if test "x$enable_opengl" != xyes; then
1522         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1523     fi
1524
1525     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1526     for driver in $dri_drivers; do
1527         DRI_DIRS="$DRI_DIRS $driver"
1528         case "x$driver" in
1529         xi915)
1530             HAVE_I915_DRI=yes;
1531             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1532             ;;
1533         xi965)
1534             HAVE_I965_DRI=yes;
1535             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1536             ;;
1537         xnouveau)
1538             HAVE_NOUVEAU_DRI=yes;
1539             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1540             ;;
1541         xradeon)
1542             HAVE_RADEON_DRI=yes;
1543             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1544             ;;
1545         xr200)
1546             HAVE_R200_DRI=yes;
1547             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1548             ;;
1549         xswrast)
1550             HAVE_SWRAST_DRI=yes;
1551             ;;
1552         *)
1553             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1554             ;;
1555         esac
1556     done
1557     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1558 fi
1559
1560
1561 #
1562 # Vulkan driver configuration
1563 #
1564
1565 AC_ARG_WITH([vulkan-drivers],
1566     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1567         [comma delimited Vulkan drivers list, e.g.
1568         "intel"
1569         @<:@default=no@:>@])],
1570     [with_vulkan_drivers="$withval"],
1571     [with_vulkan_drivers="no"])
1572
1573 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1574 # here so that the script doesn't choke on an unknown driver name later.
1575 case "x$with_vulkan_drivers" in
1576     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1577     xno) with_vulkan_drivers='' ;;
1578 esac
1579
1580 AC_ARG_WITH([vulkan-icddir],
1581     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1582         [directory for the Vulkan driver icd files @<:@${sysconfdir}/vulkan/icd.d@:>@])],
1583     [VULKAN_ICD_INSTALL_DIR="$withval"],
1584     [VULKAN_ICD_INSTALL_DIR='${sysconfdir}/vulkan/icd.d'])
1585 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1586
1587 if test -n "$with_vulkan_drivers"; then
1588     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1589     for driver in $VULKAN_DRIVERS; do
1590         case "x$driver" in
1591         xintel)
1592             if test "x$HAVE_I965_DRI" != xyes; then
1593                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1594             fi
1595             if test "x$with_sha1" == "x"; then
1596                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1597             fi
1598             HAVE_INTEL_VULKAN=yes;
1599
1600             ;;
1601         *)
1602             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1603             ;;
1604         esac
1605     done
1606     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1607 fi
1608
1609
1610 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1611 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1612                                   "x$enable_osmesa" = xyes -o \
1613                                   -n "$DRI_DIRS")
1614
1615 dnl
1616 dnl OSMesa configuration
1617 dnl
1618
1619 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1620 AC_ARG_WITH([osmesa-bits],
1621     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1622         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1623     [osmesa_bits="$withval"],
1624     [osmesa_bits=8])
1625 if test "x$osmesa_bits" != x8; then
1626     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1627         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1628         osmesa_bits=8
1629     fi
1630 fi
1631 case "x$osmesa_bits" in
1632 x8)
1633     OSMESA_LIB="${OSMESA_LIB}"
1634     ;;
1635 x16|x32)
1636     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1637     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1638     ;;
1639 *)
1640     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1641     ;;
1642 esac
1643
1644 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1645     # only link libraries with osmesa if shared
1646     if test "$enable_static" = no; then
1647         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1648     else
1649         OSMESA_LIB_DEPS=""
1650     fi
1651     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1652 fi
1653
1654 AC_SUBST([OSMESA_LIB_DEPS])
1655 AC_SUBST([OSMESA_PC_REQ])
1656 AC_SUBST([OSMESA_PC_LIB_PRIV])
1657
1658 dnl
1659 dnl gbm configuration
1660 dnl
1661 if test "x$enable_gbm" = xauto; then
1662     case "$with_egl_platforms" in
1663         *drm*)
1664             enable_gbm=yes ;;
1665          *)
1666             enable_gbm=no ;;
1667     esac
1668 fi
1669 if test "x$enable_gbm" = xyes; then
1670     if test "x$need_pci_id$have_pci_id" = xyesno; then
1671         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1672     fi
1673
1674     if test "x$enable_dri" = xyes; then
1675         if test "x$enable_shared_glapi" = xno; then
1676             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1677         fi
1678     else
1679         # Strictly speaking libgbm does not require --enable-dri, although
1680         # both of its backends do. Thus one can build libgbm without any
1681         # backends if --disable-dri is set.
1682         # To avoid unnecessary complexity of checking if at least one backend
1683         # is available when building, just mandate --enable-dri.
1684         AC_MSG_ERROR([gbm requires --enable-dri])
1685     fi
1686 fi
1687 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1688 if test "x$need_pci_id$have_libudev" = xyesyes; then
1689     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1690 else
1691     GBM_PC_REQ_PRIV=""
1692 fi
1693 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1694 AC_SUBST([GBM_PC_REQ_PRIV])
1695 AC_SUBST([GBM_PC_LIB_PRIV])
1696
1697 dnl
1698 dnl EGL configuration
1699 dnl
1700 EGL_CLIENT_APIS=""
1701
1702 if test "x$enable_egl" = xyes; then
1703     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1704
1705     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1706
1707     if test "$enable_static" != yes; then
1708         if test "x$enable_dri" = xyes; then
1709             HAVE_EGL_DRIVER_DRI2=1
1710             if test "x$enable_shared_glapi" = xno; then
1711                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1712             fi
1713             if test "x$enable_dri3" = xyes; then
1714                 HAVE_EGL_DRIVER_DRI3=1
1715                 if test "x$enable_shared_glapi" = xno; then
1716                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1717                 fi
1718             fi
1719         else
1720             # Avoid building an "empty" libEGL. Drop/update this
1721             # when other backends (haiku?) come along.
1722             AC_MSG_ERROR([egl requires --enable-dri])
1723         fi
1724
1725     fi
1726 fi
1727 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1728 AC_SUBST([EGL_LIB_DEPS])
1729
1730 gallium_st="mesa"
1731
1732 dnl
1733 dnl XA configuration
1734 dnl
1735 if test "x$enable_xa" = xyes; then
1736     if test "x$with_gallium_drivers" = xswrast; then
1737        AC_MSG_ERROR([
1738           Building xa requires at least one non swrast gallium driver.
1739           If you are looking to use libxatracker.so with the VMware driver,
1740           make sure to include svga in the gallium drivers list, apart from
1741           enabling XA.
1742           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1743     fi
1744     gallium_st="$gallium_st xa"
1745 fi
1746 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1747
1748 dnl
1749 dnl Gallium G3DVL configuration
1750 dnl
1751 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1752     if test "x$enable_xvmc" = xauto; then
1753         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1754     fi
1755
1756     if test "x$enable_vdpau" = xauto; then
1757         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1758     fi
1759
1760     if test "x$enable_omx" = xauto; then
1761         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1762     fi
1763
1764     if test "x$enable_va" = xauto; then
1765         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1766     fi
1767 fi
1768
1769 if test "x$enable_dri" = xyes -o \
1770         "x$enable_xvmc" = xyes -o \
1771         "x$enable_vdpau" = xyes -o \
1772         "x$enable_omx" = xyes -o \
1773         "x$enable_va" = xyes; then
1774     need_gallium_vl=yes
1775 fi
1776 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1777
1778 if test "x$enable_xvmc" = xyes -o \
1779         "x$enable_vdpau" = xyes -o \
1780         "x$enable_omx" = xyes -o \
1781         "x$enable_va" = xyes; then
1782     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1783     need_gallium_vl_winsys=yes
1784 fi
1785 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1786
1787 if test "x$enable_xvmc" = xyes; then
1788     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1789     gallium_st="$gallium_st xvmc"
1790 fi
1791 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1792
1793 if test "x$enable_vdpau" = xyes; then
1794     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1795     gallium_st="$gallium_st vdpau"
1796     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1797 fi
1798 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1799
1800 if test "x$enable_omx" = xyes; then
1801     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1802     gallium_st="$gallium_st omx"
1803 fi
1804 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1805
1806 if test "x$enable_va" = xyes; then
1807     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1808     gallium_st="$gallium_st va"
1809 fi
1810 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1811
1812 dnl
1813 dnl Nine Direct3D9 configuration
1814 dnl
1815 if test "x$enable_nine" = xyes; then
1816     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1817         AC_MSG_ERROR([nine requires the gallium swrast driver])
1818     fi
1819     if test "x$with_gallium_drivers" = xswrast; then
1820         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1821     fi
1822     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1823         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1824     fi
1825
1826     if test "x$enable_dri3" = xno; then
1827         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1828     fi
1829
1830     gallium_st="$gallium_st nine"
1831 fi
1832 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1833
1834 dnl
1835 dnl OpenCL configuration
1836 dnl
1837
1838 AC_ARG_WITH([clang-libdir],
1839    [AS_HELP_STRING([--with-clang-libdir],
1840          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1841    [CLANG_LIBDIR="$withval"],
1842    [CLANG_LIBDIR=''])
1843
1844 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1845 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1846
1847 if test "x$have_libelf" = xno; then
1848    LIBELF_LIBS=''
1849    LIBELF_CFLAGS=''
1850    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1851    AC_SUBST([LIBELF_LIBS])
1852    AC_SUBST([LIBELF_CFLAGS])
1853 fi
1854
1855 if test "x$enable_opencl" = xyes; then
1856     if test -z "$with_gallium_drivers"; then
1857         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1858     fi
1859
1860     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1861         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1862     fi
1863
1864     if test "x$have_libclc" = xno; then
1865         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1866                     Make sure the directory containing libclc.pc is specified in your
1867                     PKG_CONFIG_PATH environment variable.
1868                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1869     else
1870         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1871         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1872         AC_SUBST([LIBCLC_INCLUDEDIR])
1873         AC_SUBST([LIBCLC_LIBEXECDIR])
1874     fi
1875
1876     gallium_st="$gallium_st clover"
1877
1878     if test "x$enable_opencl_icd" = xyes; then
1879         OPENCL_LIBNAME="MesaOpenCL"
1880     else
1881         OPENCL_LIBNAME="OpenCL"
1882     fi
1883
1884     if test "x$have_libelf" != xyes; then
1885        AC_MSG_ERROR([Clover requires libelf])
1886     fi
1887 fi
1888 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1889 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1890 AC_SUBST([OPENCL_LIBNAME])
1891
1892 dnl
1893 dnl Gallium configuration
1894 dnl
1895 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1896
1897 AC_SUBST([LLVM_BINDIR])
1898 AC_SUBST([LLVM_CFLAGS])
1899 AC_SUBST([LLVM_CPPFLAGS])
1900 AC_SUBST([LLVM_CXXFLAGS])
1901 AC_SUBST([LLVM_LIBDIR])
1902 AC_SUBST([LLVM_LIBS])
1903 AC_SUBST([LLVM_LDFLAGS])
1904 AC_SUBST([LLVM_INCLUDEDIR])
1905 AC_SUBST([LLVM_VERSION])
1906 AC_SUBST([CLANG_RESOURCE_DIR])
1907
1908 case "x$enable_opengl$enable_gles1$enable_gles2" in
1909 x*yes*)
1910     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1911     ;;
1912 esac
1913
1914 AC_SUBST([VG_LIB_DEPS])
1915 AC_SUBST([EGL_CLIENT_APIS])
1916
1917 dnl
1918 dnl EGL Platforms configuration
1919 dnl
1920 AC_ARG_WITH([egl-platforms],
1921     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1922         [comma delimited native platforms libEGL supports, e.g.
1923         "x11,drm" @<:@default=auto@:>@])],
1924     [with_egl_platforms="$withval"],
1925     [if test "x$enable_egl" = xyes; then
1926         with_egl_platforms="x11"
1927     else
1928         with_egl_platforms=""
1929     fi])
1930
1931 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1932     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1933 fi
1934
1935 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1936         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1937         WAYLAND_SCANNER='')
1938 if test "x$WAYLAND_SCANNER" = x; then
1939     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1940 fi
1941
1942 # Do per-EGL platform setups and checks
1943 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1944 for plat in $egl_platforms; do
1945         case "$plat" in
1946         wayland)
1947                 test "x$have_libdrm" != xyes &&
1948                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1949
1950                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1951
1952                 if test "x$WAYLAND_SCANNER" = x; then
1953                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1954                 fi
1955                 ;;
1956
1957         x11)
1958                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1959                 ;;
1960
1961         drm)
1962                 test "x$enable_gbm" = "xno" &&
1963                         AC_MSG_ERROR([EGL platform drm needs gbm])
1964                 test "x$have_libdrm" != xyes &&
1965                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1966                 ;;
1967
1968         surfaceless)
1969                 test "x$have_libdrm" != xyes &&
1970                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1971                 ;;
1972
1973         *)
1974                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1975                 ;;
1976         esac
1977
1978         case "$plat$need_pci_id$have_pci_id" in
1979                 waylandyesno|drmyesno)
1980                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1981         esac
1982 done
1983
1984 # libEGL wants to default to the first platform specified in
1985 # ./configure.  parse that here.
1986 if test "x$egl_platforms" != "x"; then
1987     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1988     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1989 else
1990     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1991 fi
1992
1993 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1994 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1995 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1996 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1997
1998 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1999
2000 AC_SUBST([EGL_NATIVE_PLATFORM])
2001 AC_SUBST([EGL_CFLAGS])
2002
2003 # If we don't have the X11 platform, set this define so we don't try to include
2004 # the X11 headers.
2005 if ! echo "$egl_platforms" | grep -q 'x11'; then
2006     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2007     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2008 fi
2009
2010 dnl
2011 dnl Gallium LLVM
2012 dnl
2013 AC_ARG_ENABLE([gallium-llvm],
2014     [AS_HELP_STRING([--enable-gallium-llvm],
2015         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2016     [enable_gallium_llvm="$enableval"],
2017     [enable_gallium_llvm=auto])
2018
2019 AC_ARG_ENABLE([llvm-shared-libs],
2020     [AS_HELP_STRING([--enable-llvm-shared-libs],
2021         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2022     [enable_llvm_shared_libs="$enableval"],
2023     [enable_llvm_shared_libs=yes])
2024
2025 AC_ARG_WITH([llvm-prefix],
2026     [AS_HELP_STRING([--with-llvm-prefix],
2027         [Prefix for LLVM installations in non-standard locations])],
2028     [llvm_prefix="$withval"],
2029     [llvm_prefix=''])
2030
2031
2032 # Call this inside ` ` to get the return value.
2033 # $1 is the llvm-config command with arguments.
2034 strip_unwanted_llvm_flags() {
2035     # Use \> (marks the end of the word)
2036     echo `$1` | sed \
2037         -e 's/-DNDEBUG\>//g' \
2038         -e 's/-D_GNU_SOURCE\>//g' \
2039         -e 's/-pedantic\>//g' \
2040         -e 's/-Wcovered-switch-default\>//g' \
2041         -e 's/-O.\>//g' \
2042         -e 's/-g\>//g' \
2043         -e 's/-Wall\>//g' \
2044         -e 's/-Wcast-qual\>//g' \
2045         -e 's/-Woverloaded-virtual\>//g' \
2046         -e 's/-fcolor-diagnostics\>//g' \
2047         -e 's/-fdata-sections\>//g' \
2048         -e 's/-ffunction-sections\>//g' \
2049         -e 's/-fno-exceptions\>//g' \
2050         -e 's/-fomit-frame-pointer\>//g' \
2051         -e 's/-fvisibility-inlines-hidden\>//g' \
2052         -e 's/-fPIC\>//g' \
2053         -e 's/-fstack-protector-strong\>//g'
2054 }
2055
2056 llvm_check_version_for() {
2057     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2058         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2059     fi
2060 }
2061
2062
2063
2064 if test -z "$with_gallium_drivers"; then
2065     enable_gallium_llvm=no
2066 fi
2067 if test "x$enable_gallium_llvm" = xauto; then
2068     case "$host_cpu" in
2069     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2070     esac
2071 fi
2072 if test "x$enable_gallium_llvm" = xyes; then
2073     if test -n "$llvm_prefix"; then
2074         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2075     else
2076         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2077     fi
2078
2079     if test "x$LLVM_CONFIG" != xno; then
2080         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2081         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2082         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2083         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2084         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2085         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2086         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2087         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2088
2089         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2090             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2091         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2092             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2093
2094         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2095         if test -z "$LLVM_VERSION_PATCH"; then
2096             LLVM_VERSION_PATCH=0
2097         fi
2098
2099         if test -n "${LLVM_VERSION_MAJOR}"; then
2100             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2101         else
2102             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2103         fi
2104
2105         LLVM_REQUIRED_VERSION_MAJOR="3"
2106         LLVM_REQUIRED_VERSION_MINOR="3"
2107         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2108             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2109         fi
2110
2111         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2112
2113         if test "x$enable_opencl" = xyes; then
2114             llvm_check_version_for "3" "5" "0" "opencl"
2115
2116             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2117             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2118         fi
2119         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2120         MESA_LLVM=1
2121
2122         dnl Check for Clang internal headers
2123         if test "x$enable_opencl" = xyes; then
2124             if test -z "$CLANG_LIBDIR"; then
2125                 CLANG_LIBDIR=${LLVM_LIBDIR}
2126             fi
2127             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2128             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2129                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2130         fi
2131     else
2132         MESA_LLVM=0
2133         LLVM_VERSION_INT=0
2134     fi
2135 else
2136     MESA_LLVM=0
2137     LLVM_VERSION_INT=0
2138
2139     if test "x$enable_opencl" = xyes; then
2140         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2141     fi
2142 fi
2143
2144 dnl Directory for XVMC libs
2145 AC_ARG_WITH([xvmc-libdir],
2146     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2147         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2148     [XVMC_LIB_INSTALL_DIR="$withval"],
2149     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2150 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2151
2152 dnl
2153 dnl Gallium Tests
2154 dnl
2155 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2156
2157 dnl Directory for VDPAU libs
2158 AC_ARG_WITH([vdpau-libdir],
2159     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2160         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2161     [VDPAU_LIB_INSTALL_DIR="$withval"],
2162     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2163 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2164
2165 dnl Directory for OMX libs
2166
2167 AC_ARG_WITH([omx-libdir],
2168     [AS_HELP_STRING([--with-omx-libdir=DIR],
2169         [directory for the OMX libraries])],
2170     [OMX_LIB_INSTALL_DIR="$withval"],
2171     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2172 AC_SUBST([OMX_LIB_INSTALL_DIR])
2173
2174 dnl Directory for VA libs
2175
2176 AC_ARG_WITH([va-libdir],
2177     [AS_HELP_STRING([--with-va-libdir=DIR],
2178         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2179     [VA_LIB_INSTALL_DIR="$withval"],
2180     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2181 AC_SUBST([VA_LIB_INSTALL_DIR])
2182
2183 AC_ARG_WITH([d3d-libdir],
2184     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2185         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2186     [D3D_DRIVER_INSTALL_DIR="$withval"],
2187     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2188 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2189
2190 dnl
2191 dnl Gallium helper functions
2192 dnl
2193 gallium_require_drm() {
2194     if test "x$have_libdrm" != xyes; then
2195        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2196     fi
2197 }
2198
2199 gallium_require_llvm() {
2200     if test "x$MESA_LLVM" = x0; then
2201         case "$host" in *gnux32) return;; esac
2202         case "$host_cpu" in
2203         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2204         esac
2205     fi
2206 }
2207
2208 gallium_require_drm_loader() {
2209     if test "x$need_pci_id$have_pci_id" = xyesno; then
2210         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2211     fi
2212 }
2213
2214 dnl This is for Glamor. Skip this if OpenGL is disabled.
2215 require_egl_drm() {
2216     if test "x$enable_opengl" = xno; then
2217         return 0
2218     fi
2219
2220     case "$with_egl_platforms" in
2221         *drm*)
2222             ;;
2223          *)
2224             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2225             ;;
2226     esac
2227     if test "x$enable_gbm" != xyes; then
2228             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2229     fi
2230 }
2231
2232 radeon_llvm_check() {
2233     if test ${LLVM_VERSION_INT} -lt 307; then
2234         amdgpu_llvm_target_name='r600'
2235     else
2236         amdgpu_llvm_target_name='amdgpu'
2237     fi
2238     if test "x$enable_gallium_llvm" != "xyes"; then
2239         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2240     fi
2241     llvm_check_version_for "3" "6" "0" $1
2242     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2243         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2244     fi
2245     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2246     NEED_RADEON_LLVM=yes
2247     if test "x$have_libelf" != xyes; then
2248        AC_MSG_ERROR([$1 requires libelf when using llvm])
2249     fi
2250 }
2251
2252 swr_llvm_check() {
2253     gallium_require_llvm $1
2254     if test ${LLVM_VERSION_INT} -lt 306; then
2255         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2256     fi
2257     if test "x$enable_gallium_llvm" != "xyes"; then
2258         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2259     fi
2260 }
2261
2262 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2263 if test -n "$with_gallium_drivers"; then
2264     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2265     for driver in $gallium_drivers; do
2266         case "x$driver" in
2267         xsvga)
2268             HAVE_GALLIUM_SVGA=yes
2269             gallium_require_drm "svga"
2270             gallium_require_drm_loader
2271             ;;
2272         xi915)
2273             HAVE_GALLIUM_I915=yes
2274             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2275             gallium_require_drm "Gallium i915"
2276             gallium_require_drm_loader
2277             ;;
2278         xilo)
2279             HAVE_GALLIUM_ILO=yes
2280             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2281             gallium_require_drm "Gallium i965/ilo"
2282             gallium_require_drm_loader
2283             ;;
2284         xr300)
2285             HAVE_GALLIUM_R300=yes
2286             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2287             gallium_require_drm "Gallium R300"
2288             gallium_require_drm_loader
2289             gallium_require_llvm "Gallium R300"
2290             ;;
2291         xr600)
2292             HAVE_GALLIUM_R600=yes
2293             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2294             gallium_require_drm "Gallium R600"
2295             gallium_require_drm_loader
2296             if test "x$enable_opencl" = xyes; then
2297                 radeon_llvm_check "r600g"
2298                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2299             fi
2300             ;;
2301         xradeonsi)
2302             HAVE_GALLIUM_RADEONSI=yes
2303             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2304             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2305             gallium_require_drm "radeonsi"
2306             gallium_require_drm_loader
2307             radeon_llvm_check "radeonsi"
2308             require_egl_drm "radeonsi"
2309             ;;
2310         xnouveau)
2311             HAVE_GALLIUM_NOUVEAU=yes
2312             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2313             gallium_require_drm "nouveau"
2314             gallium_require_drm_loader
2315             ;;
2316         xfreedreno)
2317             HAVE_GALLIUM_FREEDRENO=yes
2318             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2319             gallium_require_drm "freedreno"
2320             gallium_require_drm_loader
2321             ;;
2322         xswrast)
2323             HAVE_GALLIUM_SOFTPIPE=yes
2324             if test "x$MESA_LLVM" = x1; then
2325                 HAVE_GALLIUM_LLVMPIPE=yes
2326             fi
2327             ;;
2328         xswr)
2329             swr_llvm_check "swr"
2330
2331             AC_MSG_CHECKING([whether $CXX supports c++11/AVX/AVX2])
2332             AVX_CXXFLAGS="-march=core-avx-i"
2333             AVX2_CXXFLAGS="-march=core-avx2"
2334
2335             AC_LANG_PUSH([C++])
2336             save_CXXFLAGS="$CXXFLAGS"
2337             CXXFLAGS="-std=c++11 $CXXFLAGS"
2338             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2339                               [AC_MSG_ERROR([c++11 compiler support not detected])])
2340             CXXFLAGS="$save_CXXFLAGS"
2341
2342             save_CXXFLAGS="$CXXFLAGS"
2343             CXXFLAGS="$AVX_CXXFLAGS $CXXFLAGS"
2344             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2345                               [AC_MSG_ERROR([AVX compiler support not detected])])
2346             CXXFLAGS="$save_CXXFLAGS"
2347
2348             save_CFLAGS="$CXXFLAGS"
2349             CXXFLAGS="$AVX2_CXXFLAGS $CXXFLAGS"
2350             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2351                               [AC_MSG_ERROR([AVX2 compiler support not detected])])
2352             CXXFLAGS="$save_CXXFLAGS"
2353             AC_LANG_POP([C++])
2354
2355             HAVE_GALLIUM_SWR=yes
2356             ;;
2357         xvc4)
2358             HAVE_GALLIUM_VC4=yes
2359             gallium_require_drm "vc4"
2360             gallium_require_drm_loader
2361
2362             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2363                               [USE_VC4_SIMULATOR=yes;
2364                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2365                               [USE_VC4_SIMULATOR=no])
2366             ;;
2367         xvirgl)
2368             HAVE_GALLIUM_VIRGL=yes
2369             gallium_require_drm "virgl"
2370             gallium_require_drm_loader
2371             require_egl_drm "virgl"
2372             ;;
2373         *)
2374             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2375             ;;
2376         esac
2377     done
2378 fi
2379
2380 dnl Set LLVM_LIBS - This is done after the driver configuration so
2381 dnl that drivers can add additional components to LLVM_COMPONENTS.
2382 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2383 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2384 dnl this was causing the same libraries to be appear multiple times
2385 dnl in LLVM_LIBS.
2386
2387 if test "x$MESA_LLVM" != x0; then
2388
2389     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2390        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2391     fi
2392     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2393
2394     dnl llvm-config may not give the right answer when llvm is a built as a
2395     dnl single shared library, so we must work the library name out for
2396     dnl ourselves.
2397     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2398     if test "x$enable_llvm_shared_libs" = xyes; then
2399         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2400         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2401         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2402
2403         if test "x$llvm_have_one_so" = xyes; then
2404             dnl LLVM was built using auto*, so there is only one shared object.
2405             LLVM_LIBS="-l$LLVM_SO_NAME"
2406         else
2407             dnl If LLVM was built with CMake, there will be one shared object per
2408             dnl component.
2409             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2410                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2411         Please make sure you have built llvm with the --enable-shared option
2412         and that your llvm libraries are installed in $LLVM_LIBDIR
2413         If you have installed your llvm libraries to a different directory you
2414         can use the --with-llvm-prefix= configure flag to specify this directory.
2415         NOTE: Mesa is attempting to use llvm shared libraries by default.
2416         If you do not want to build with llvm shared libraries and instead want to
2417         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2418         invocation and rebuild.])])
2419
2420            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2421            dnl install uses a shared object for each component and we have
2422            dnl already added all of these objects to LLVM_LIBS.
2423         fi
2424     else
2425         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2426         dnl We need to link to llvm system libs when using static libs
2427         dnl However, only llvm 3.5+ provides --system-libs
2428         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2429             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2430         fi
2431     fi
2432 fi
2433
2434 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2435 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2436 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2437 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2438 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2439 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2440 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2441                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2442 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2443 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2444 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2445 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2446 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2447 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2448                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2449                                          "x$HAVE_GALLIUM_SWR" = xyes)
2450 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2451 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2452
2453 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2454
2455 if test "x$enable_dri" = xyes; then
2456     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2457 fi
2458
2459 if test "x$have_drisw_kms" = xyes; then
2460     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2461 fi
2462 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2463
2464 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2465 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2466 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2467 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2468 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2469 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2470
2471 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2472
2473 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2474                                         "x$HAVE_I965_DRI" = xyes)
2475
2476 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2477                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2478                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2479 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2480 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2481 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2482 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2483 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2484 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2485     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2486 fi
2487
2488 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2489 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2490 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2491
2492 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2493 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2494 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2495
2496 AC_SUBST([NINE_MAJOR], 1)
2497 AC_SUBST([NINE_MINOR], 0)
2498 AC_SUBST([NINE_TINY], 0)
2499 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2500
2501 AC_SUBST([VDPAU_MAJOR], 1)
2502 AC_SUBST([VDPAU_MINOR], 0)
2503
2504 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2505 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2506 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2507 AC_SUBST([VA_MINOR], $VA_MINOR)
2508
2509 AC_SUBST([XVMC_MAJOR], 1)
2510 AC_SUBST([XVMC_MINOR], 0)
2511
2512 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2513 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2514 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2515 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2516
2517 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2518 AC_SUBST([XA_MINOR], $XA_MINOR)
2519 AC_SUBST([XA_TINY], $XA_TINY)
2520 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2521
2522 AC_ARG_ENABLE(valgrind,
2523               [AS_HELP_STRING([--enable-valgrind],
2524                              [Build mesa with valgrind support (default: auto)])],
2525                              [VALGRIND=$enableval], [VALGRIND=auto])
2526 if test "x$VALGRIND" != xno; then
2527         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2528 fi
2529 AC_MSG_CHECKING([whether to enable Valgrind support])
2530 if test "x$VALGRIND" = xauto; then
2531         VALGRIND="$have_valgrind"
2532 fi
2533
2534 if test "x$VALGRIND" = "xyes"; then
2535         if ! test "x$have_valgrind" = xyes; then
2536                 AC_MSG_ERROR([Valgrind support required but not present])
2537         fi
2538         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2539 fi
2540
2541 AC_MSG_RESULT([$VALGRIND])
2542
2543 dnl Restore LDFLAGS and CPPFLAGS
2544 LDFLAGS="$_SAVE_LDFLAGS"
2545 CPPFLAGS="$_SAVE_CPPFLAGS"
2546
2547 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2548 if test "x$acv_mesa_CLANG" = xyes; then
2549     CFLAGS="$CFLAGS -Qunused-arguments"
2550     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2551 fi
2552
2553 dnl Add user CFLAGS and CXXFLAGS
2554 CFLAGS="$CFLAGS $USER_CFLAGS"
2555 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2556
2557 dnl Substitute the config
2558 AC_CONFIG_FILES([Makefile
2559                 src/Makefile
2560                 src/compiler/Makefile
2561                 src/egl/Makefile
2562                 src/egl/main/egl.pc
2563                 src/egl/wayland/wayland-drm/Makefile
2564                 src/egl/wayland/wayland-egl/Makefile
2565                 src/egl/wayland/wayland-egl/wayland-egl.pc
2566                 src/gallium/Makefile
2567                 src/gallium/auxiliary/Makefile
2568                 src/gallium/auxiliary/pipe-loader/Makefile
2569                 src/gallium/drivers/freedreno/Makefile
2570                 src/gallium/drivers/ddebug/Makefile
2571                 src/gallium/drivers/i915/Makefile
2572                 src/gallium/drivers/ilo/Makefile
2573                 src/gallium/drivers/llvmpipe/Makefile
2574                 src/gallium/drivers/noop/Makefile
2575                 src/gallium/drivers/nouveau/Makefile
2576                 src/gallium/drivers/r300/Makefile
2577                 src/gallium/drivers/r600/Makefile
2578                 src/gallium/drivers/radeon/Makefile
2579                 src/gallium/drivers/radeonsi/Makefile
2580                 src/gallium/drivers/rbug/Makefile
2581                 src/gallium/drivers/softpipe/Makefile
2582                 src/gallium/drivers/svga/Makefile
2583                 src/gallium/drivers/swr/Makefile
2584                 src/gallium/drivers/trace/Makefile
2585                 src/gallium/drivers/vc4/Makefile
2586                 src/gallium/drivers/virgl/Makefile
2587                 src/gallium/state_trackers/clover/Makefile
2588                 src/gallium/state_trackers/dri/Makefile
2589                 src/gallium/state_trackers/glx/xlib/Makefile
2590                 src/gallium/state_trackers/nine/Makefile
2591                 src/gallium/state_trackers/omx/Makefile
2592                 src/gallium/state_trackers/osmesa/Makefile
2593                 src/gallium/state_trackers/va/Makefile
2594                 src/gallium/state_trackers/vdpau/Makefile
2595                 src/gallium/state_trackers/xa/Makefile
2596                 src/gallium/state_trackers/xvmc/Makefile
2597                 src/gallium/targets/d3dadapter9/Makefile
2598                 src/gallium/targets/d3dadapter9/d3d.pc
2599                 src/gallium/targets/dri/Makefile
2600                 src/gallium/targets/libgl-xlib/Makefile
2601                 src/gallium/targets/omx/Makefile
2602                 src/gallium/targets/opencl/Makefile
2603                 src/gallium/targets/opencl/mesa.icd
2604                 src/gallium/targets/osmesa/Makefile
2605                 src/gallium/targets/osmesa/osmesa.pc
2606                 src/gallium/targets/pipe-loader/Makefile
2607                 src/gallium/targets/va/Makefile
2608                 src/gallium/targets/vdpau/Makefile
2609                 src/gallium/targets/xa/Makefile
2610                 src/gallium/targets/xa/xatracker.pc
2611                 src/gallium/targets/xvmc/Makefile
2612                 src/gallium/tests/trivial/Makefile
2613                 src/gallium/tests/unit/Makefile
2614                 src/gallium/winsys/freedreno/drm/Makefile
2615                 src/gallium/winsys/i915/drm/Makefile
2616                 src/gallium/winsys/intel/drm/Makefile
2617                 src/gallium/winsys/nouveau/drm/Makefile
2618                 src/gallium/winsys/radeon/drm/Makefile
2619                 src/gallium/winsys/amdgpu/drm/Makefile
2620                 src/gallium/winsys/svga/drm/Makefile
2621                 src/gallium/winsys/sw/dri/Makefile
2622                 src/gallium/winsys/sw/kms-dri/Makefile
2623                 src/gallium/winsys/sw/null/Makefile
2624                 src/gallium/winsys/sw/wrapper/Makefile
2625                 src/gallium/winsys/sw/xlib/Makefile
2626                 src/gallium/winsys/vc4/drm/Makefile
2627                 src/gallium/winsys/virgl/drm/Makefile
2628                 src/gallium/winsys/virgl/vtest/Makefile
2629                 src/gbm/Makefile
2630                 src/gbm/main/gbm.pc
2631                 src/glx/Makefile
2632                 src/glx/apple/Makefile
2633                 src/glx/tests/Makefile
2634                 src/gtest/Makefile
2635                 src/intel/Makefile
2636                 src/intel/genxml/Makefile
2637                 src/intel/isl/Makefile
2638                 src/intel/vulkan/Makefile
2639                 src/loader/Makefile
2640                 src/mapi/Makefile
2641                 src/mapi/es1api/glesv1_cm.pc
2642                 src/mapi/es2api/glesv2.pc
2643                 src/mapi/glapi/gen/Makefile
2644                 src/mesa/Makefile
2645                 src/mesa/gl.pc
2646                 src/mesa/drivers/dri/dri.pc
2647                 src/mesa/drivers/dri/common/Makefile
2648                 src/mesa/drivers/dri/common/xmlpool/Makefile
2649                 src/mesa/drivers/dri/i915/Makefile
2650                 src/mesa/drivers/dri/i965/Makefile
2651                 src/mesa/drivers/dri/Makefile
2652                 src/mesa/drivers/dri/nouveau/Makefile
2653                 src/mesa/drivers/dri/r200/Makefile
2654                 src/mesa/drivers/dri/radeon/Makefile
2655                 src/mesa/drivers/dri/swrast/Makefile
2656                 src/mesa/drivers/osmesa/Makefile
2657                 src/mesa/drivers/osmesa/osmesa.pc
2658                 src/mesa/drivers/x11/Makefile
2659                 src/mesa/main/tests/Makefile
2660                 src/util/Makefile
2661                 src/util/tests/hash_table/Makefile])
2662
2663 AC_OUTPUT
2664
2665 # Fix up dependencies in *.Plo files, where we changed the extension of a
2666 # source file
2667 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2668 $SED -i -e 's/gen6_blorp.cpp/gen6_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen6_blorp.Plo
2669 $SED -i -e 's/gen7_blorp.cpp/gen7_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen7_blorp.Plo
2670 $SED -i -e 's/gen8_blorp.cpp/gen8_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen8_blorp.Plo
2671
2672
2673 dnl
2674 dnl Output some configuration info for the user
2675 dnl
2676 echo ""
2677 echo "        prefix:          $prefix"
2678 echo "        exec_prefix:     $exec_prefix"
2679 echo "        libdir:          $libdir"
2680 echo "        includedir:      $includedir"
2681
2682 dnl API info
2683 echo ""
2684 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2685
2686 dnl Driver info
2687 echo ""
2688 case "x$enable_osmesa$enable_gallium_osmesa" in
2689 xnoyes)
2690         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2691         ;;
2692 xyesno)
2693         echo "        OSMesa:          lib$OSMESA_LIB"
2694         ;;
2695 xnono)
2696         echo "        OSMesa:          no"
2697         ;;
2698 esac
2699
2700 echo ""
2701 if test "x$enable_dri" != xno; then
2702         echo "        DRI platform:    $dri_platform"
2703         if test -z "$DRI_DIRS"; then
2704             echo "        DRI drivers:     no"
2705         else
2706             echo "        DRI drivers:     $DRI_DIRS"
2707         fi
2708         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2709 fi
2710
2711 case "x$enable_glx" in
2712 xdri)
2713     echo "        GLX:             DRI-based"
2714     ;;
2715 xxlib)
2716     echo "        GLX:             Xlib-based"
2717     ;;
2718 xgallium-xlib)
2719     echo "        GLX:             Xlib-based (Gallium)"
2720     ;;
2721 *)
2722     echo "        GLX:             $enable_glx"
2723     ;;
2724 esac
2725
2726 dnl EGL
2727 echo ""
2728 echo "        EGL:             $enable_egl"
2729 if test "$enable_egl" = yes; then
2730     echo "        EGL platforms:   $egl_platforms"
2731
2732     egl_drivers=""
2733     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2734         egl_drivers="$egl_drivers builtin:egl_dri2"
2735     fi
2736     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2737         egl_drivers="$egl_drivers builtin:egl_dri3"
2738     fi
2739
2740     echo "        EGL drivers:    $egl_drivers"
2741 fi
2742
2743 # Vulkan
2744 echo ""
2745 if test "x$VULKAN_DRIVERS" != x; then
2746     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2747     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2748 else
2749     echo "        Vulkan drivers:  no"
2750 fi
2751
2752 echo ""
2753 if test "x$MESA_LLVM" = x1; then
2754     echo "        llvm:            yes"
2755     echo "        llvm-config:     $LLVM_CONFIG"
2756     echo "        llvm-version:    $LLVM_VERSION"
2757 else
2758     echo "        llvm:            no"
2759 fi
2760
2761 echo ""
2762 if test -n "$with_gallium_drivers"; then
2763     echo "        Gallium drivers: $gallium_drivers"
2764     echo "        Gallium st:      $gallium_st"
2765 else
2766     echo "        Gallium:         no"
2767 fi
2768
2769 dnl Shader cache
2770 echo ""
2771 echo "        Shader cache:    $enable_shader_cache"
2772 if test "x$enable_shader_cache" = "xyes"; then
2773     echo "        With SHA1 from:  $with_sha1"
2774 fi
2775
2776 dnl Libraries
2777 echo ""
2778 echo "        Shared libs:     $enable_shared"
2779 echo "        Static libs:     $enable_static"
2780 echo "        Shared-glapi:    $enable_shared_glapi"
2781
2782 dnl Compiler options
2783 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2784 cflags=`echo $CFLAGS | \
2785     $SED 's/^ *//;s/  */ /;s/ *$//'`
2786 cxxflags=`echo $CXXFLAGS | \
2787     $SED 's/^ *//;s/  */ /;s/ *$//'`
2788 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2789 echo ""
2790 echo "        CFLAGS:          $cflags"
2791 echo "        CXXFLAGS:        $cxxflags"
2792 echo "        Macros:          $defines"
2793 echo ""
2794 if test "x$MESA_LLVM" = x1; then
2795     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2796     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2797     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2798     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2799     echo ""
2800 fi
2801 echo "        PYTHON2:         $PYTHON2"
2802 echo "        PYTHON3:         $PYTHON3"
2803
2804 echo ""
2805 echo "        Run '${MAKE-make}' to build Mesa"
2806 echo ""