configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.2.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  24     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  25
  26 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  27
  28 dnl Set internal versions
  29 OSMESA_VERSION=8
  30 AC_SUBST([OSMESA_VERSION])
  31
  32 dnl Versions for external dependencies
  33 LIBDRM_REQUIRED=2.4.24
  34 LIBDRM_RADEON_REQUIRED=2.4.44
  35 LIBDRM_INTEL_REQUIRED=2.4.38
  36 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  37 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  38 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  39 DRI2PROTO_REQUIRED=2.6
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBDRM_XORG_REQUIRED=2.4.24
  42 LIBKMS_XORG_REQUIRED=1.0.0
  43
  44 dnl Check for progs
  45 AC_PROG_CPP
  46 AC_PROG_CC
  47 AX_PROG_CC_FOR_BUILD
  48 AC_PROG_CXX
  49 AX_PROG_CXX_FOR_BUILD
  50 AM_PROG_CC_C_O
  51 AM_PROG_AS
  52 AC_CHECK_PROGS([MAKE], [gmake make])
  53 AC_CHECK_PROGS([PYTHON2], [python2 python])
  54 AX_PYTHON_MODULE([libxml2], [needed])
  55 AC_PROG_SED
  56 AC_PROG_MKDIR_P
  57
  58 LT_PREREQ([2.2])
  59 LT_INIT([disable-static])
  60
  61 AX_PROG_BISON([],
  62               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  63                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  64 AX_PROG_FLEX([],
  65              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  66                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  67
  68 AC_PATH_PROG([PERL], [perl])
  69
  70 AC_CHECK_PROG(INDENT, indent, indent, cat)
  71 if test "x$INDENT" != "xcat"; then
  72     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  73 fi
  74
  75 AC_PROG_INSTALL
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122 dnl Make sure the pkg-config macros are defined
 123 m4_ifndef([PKG_PROG_PKG_CONFIG],
 124     [m4_fatal([Could not locate the pkg-config autoconf macros.
 125   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 126   are in a different location, try setting the environment variable
 127   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 128 PKG_PROG_PKG_CONFIG()
 129
 130 dnl LIB_DIR - library basename
 131 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 132 AC_SUBST([LIB_DIR])
 133
 134 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 135 _SAVE_LDFLAGS="$LDFLAGS"
 136 _SAVE_CPPFLAGS="$CPPFLAGS"
 137
 138 dnl build host compiler macros
 139 DEFINES_FOR_BUILD=""
 140 AC_SUBST([DEFINES_FOR_BUILD])
 141 case "$build_os" in
 142 linux*|*-gnu*|gnu*)
 143     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 144     ;;
 145 solaris*)
 146     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 147     ;;
 148 cygwin*)
 149     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 150     ;;
 151 esac
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DHAVE_PTHREAD"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     case "$host_os" in
 171     cygwin*)
 172         CFLAGS="$CFLAGS -Wall -std=gnu99"
 173         ;;
 174     *)
 175         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 176         CFLAGS="$CFLAGS -Wall -std=c99"
 177         ;;
 178     esac
 179
 180     # Enable -Werror=implicit-function-declaration and
 181     # -Werror=missing-prototypes, if available, or otherwise, just
 182     # -Wmissing-prototypes.  This is particularly useful to avoid
 183     # generating a loadable driver module that has undefined symbols.
 184     save_CFLAGS="$CFLAGS"
 185     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 186     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 187     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 189                    AC_MSG_RESULT([yes]),
 190                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 191                     AC_MSG_RESULT([no])]);
 192
 193     # Enable -fvisibility=hidden if using a gcc that supports it
 194     save_CFLAGS="$CFLAGS"
 195     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 196     VISIBILITY_CFLAGS="-fvisibility=hidden"
 197     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 199                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 200
 201     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 202     CFLAGS=$save_CFLAGS
 203
 204     # Work around aliasing bugs - developers should comment this out
 205     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 206     CFLAGS="$CFLAGS -fno-strict-aliasing"
 207
 208     # gcc's builtin memcmp is slower than glibc's
 209     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 210     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 211     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 212 fi
 213 if test "x$GXX" = xyes; then
 214     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 215     CXXFLAGS="$CXXFLAGS -Wall"
 216
 217     # Enable -fvisibility=hidden if using a gcc that supports it
 218     save_CXXFLAGS="$CXXFLAGS"
 219     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 220     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 221     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 222     AC_LANG_PUSH([C++])
 223     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 224                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 225     AC_LANG_POP([C++])
 226
 227     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 228     CXXFLAGS=$save_CXXFLAGS
 229
 230     # Work around aliasing bugs - developers should comment this out
 231     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 232     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 233
 234     # gcc's builtin memcmp is slower than glibc's
 235     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 236     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 237     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 238 fi
 239
 240 dnl even if the compiler appears to support it, using visibility attributes isn't
 241 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 242 case "$host_os" in
 243 cygwin*)
 244     VISIBILITY_CFLAGS=""
 245     VISIBILITY_CXXFLAGS=""
 246     ;;
 247 esac
 248
 249 AC_SUBST([VISIBILITY_CFLAGS])
 250 AC_SUBST([VISIBILITY_CXXFLAGS])
 251
 252 dnl
 253 dnl Hacks to enable 32 or 64 bit build
 254 dnl
 255 AC_ARG_ENABLE([32-bit],
 256     [AS_HELP_STRING([--enable-32-bit],
 257         [build 32-bit libraries @<:@default=auto@:>@])],
 258     [enable_32bit="$enableval"],
 259     [enable_32bit=auto]
 260 )
 261 if test "x$enable_32bit" = xyes; then
 262     if test "x$GCC" = xyes; then
 263         CFLAGS="$CFLAGS -m32"
 264         CCASFLAGS="$CCASFLAGS -m32"
 265     fi
 266     if test "x$GXX" = xyes; then
 267         CXXFLAGS="$CXXFLAGS -m32"
 268     fi
 269 fi
 270 AC_ARG_ENABLE([64-bit],
 271     [AS_HELP_STRING([--enable-64-bit],
 272         [build 64-bit libraries @<:@default=auto@:>@])],
 273     [enable_64bit="$enableval"],
 274     [enable_64bit=auto]
 275 )
 276 if test "x$enable_64bit" = xyes; then
 277     if test "x$GCC" = xyes; then
 278         CFLAGS="$CFLAGS -m64"
 279     fi
 280     if test "x$GXX" = xyes; then
 281         CXXFLAGS="$CXXFLAGS -m64"
 282     fi
 283 fi
 284
 285 dnl Can't have static and shared libraries, default to static if user
 286 dnl explicitly requested. If both disabled, set to static since shared
 287 dnl was explicitly requested.
 288 case "x$enable_static$enable_shared" in
 289 xyesyes )
 290     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 291     enable_shared=no
 292     ;;
 293 xnono )
 294     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 295     enable_static=yes
 296     ;;
 297 esac
 298
 299 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 300
 301 dnl
 302 dnl other compiler options
 303 dnl
 304 AC_ARG_ENABLE([debug],
 305     [AS_HELP_STRING([--enable-debug],
 306         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 307     [enable_debug="$enableval"],
 308     [enable_debug=no]
 309 )
 310 if test "x$enable_debug" = xyes; then
 311     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 312     if test "x$GCC_FOR_BUILD" = xyes; then
 313         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 314     fi
 315     if test "x$GXX_FOR_BUILD" = xyes; then
 316         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 317     fi
 318
 319     DEFINES="$DEFINES -DDEBUG"
 320     if test "x$GCC" = xyes; then
 321         CFLAGS="$CFLAGS -g -O0"
 322     fi
 323     if test "x$GXX" = xyes; then
 324         CXXFLAGS="$CXXFLAGS -g -O0"
 325     fi
 326 fi
 327
 328 dnl
 329 dnl library names
 330 dnl
 331 LIB_PREFIX_GLOB='lib'
 332 LIB_VERSION_SEPARATOR='.'
 333 if test "$enable_static" = yes; then
 334     LIB_EXTENSION='a'
 335 else
 336     case "$host_os" in
 337     darwin* )
 338         LIB_EXTENSION='dylib' ;;
 339     cygwin* )
 340         dnl prefix can be 'cyg' or 'lib'
 341         LIB_PREFIX_GLOB='???'
 342         LIB_VERSION_SEPARATOR='-'
 343         LIB_EXTENSION='dll' ;;
 344     aix* )
 345         LIB_EXTENSION='a' ;;
 346     * )
 347         LIB_EXTENSION='so' ;;
 348     esac
 349 fi
 350 AC_ARG_WITH([gl-lib-name],
 351   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 352     [specify GL library name @<:@default=GL@:>@])],
 353   [GL_LIB=$withval],
 354   [GL_LIB=GL])
 355 AC_ARG_WITH([osmesa-lib-name],
 356   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 357     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 358   [OSMESA_LIB=$withval],
 359   [OSMESA_LIB=OSMesa])
 360 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 361 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 362
 363 dnl
 364 dnl Mangled Mesa support
 365 dnl
 366 AC_ARG_ENABLE([mangling],
 367   [AS_HELP_STRING([--enable-mangling],
 368     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 369   [enable_mangling="${enableval}"],
 370   [enable_mangling=no]
 371 )
 372 if test "x${enable_mangling}" = "xyes" ; then
 373   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 374   GL_LIB="Mangled${GL_LIB}"
 375   OSMESA_LIB="Mangled${OSMESA_LIB}"
 376 fi
 377 AC_SUBST([GL_LIB])
 378 AC_SUBST([OSMESA_LIB])
 379
 380 dnl
 381 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 382 dnl
 383 AC_ARG_ENABLE([texture-float],
 384     [AS_HELP_STRING([--enable-texture-float],
 385         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 386     [enable_texture_float="$enableval"],
 387     [enable_texture_float=no]
 388 )
 389 if test "x$enable_texture_float" = xyes; then
 390     AC_MSG_WARN([Floating-point textures enabled.])
 391     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 392     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 393 fi
 394
 395 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 396 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 397 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 398 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 399 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 400 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 401 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 402
 403 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410
 411 AC_SUBST([GL_LIB_NAME])
 412 AC_SUBST([OSMESA_LIB_NAME])
 413 AC_SUBST([EGL_LIB_NAME])
 414 AC_SUBST([GLESv1_CM_LIB_NAME])
 415 AC_SUBST([GLESv2_LIB_NAME])
 416 AC_SUBST([VG_LIB_NAME])
 417 AC_SUBST([GLAPI_LIB_NAME])
 418
 419 AC_SUBST([GL_LIB_GLOB])
 420 AC_SUBST([EGL_LIB_GLOB])
 421 AC_SUBST([GLESv1_CM_LIB_GLOB])
 422 AC_SUBST([GLESv2_LIB_GLOB])
 423 AC_SUBST([VG_LIB_GLOB])
 424 AC_SUBST([GLAPI_LIB_GLOB])
 425
 426 dnl
 427 dnl Arch/platform-specific settings
 428 dnl
 429 AC_ARG_ENABLE([asm],
 430     [AS_HELP_STRING([--disable-asm],
 431         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 432     [enable_asm="$enableval"],
 433     [enable_asm=yes]
 434 )
 435 asm_arch=""
 436 AC_MSG_CHECKING([whether to enable assembly])
 437 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 438 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 439 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 440     case "$host_cpu" in
 441     i?86 | x86_64)
 442         enable_asm=no
 443         AC_MSG_RESULT([no, cross compiling])
 444         ;;
 445     esac
 446 fi
 447 # check for supported arches
 448 if test "x$enable_asm" = xyes; then
 449     case "$host_cpu" in
 450     i?86)
 451         case "$host_os" in
 452         linux* | *freebsd* | dragonfly* | *netbsd*)
 453             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 454             ;;
 455         gnu*)
 456             asm_arch=x86
 457             ;;
 458         esac
 459         ;;
 460     x86_64)
 461         case "$host_os" in
 462         linux* | *freebsd* | dragonfly* | *netbsd*)
 463             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 464             ;;
 465         esac
 466         ;;
 467     sparc*)
 468         case "$host_os" in
 469         linux*)
 470             asm_arch=sparc
 471             ;;
 472         esac
 473         ;;
 474     esac
 475
 476     case "$asm_arch" in
 477     x86)
 478         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 479         AC_MSG_RESULT([yes, x86])
 480         ;;
 481     x86_64)
 482         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 483         AC_MSG_RESULT([yes, x86_64])
 484         ;;
 485     sparc)
 486         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 487         AC_MSG_RESULT([yes, sparc])
 488         ;;
 489     *)
 490         AC_MSG_RESULT([no, platform not supported])
 491         ;;
 492     esac
 493 fi
 494
 495 dnl Check to see if dlopen is in default libraries (like Solaris, which
 496 dnl has it in libc), or if libdl is needed to get it.
 497 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 498     [AC_CHECK_LIB([dl], [dlopen],
 499        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 500 AC_SUBST([DLOPEN_LIBS])
 501
 502 case "$host_os" in
 503 darwin*|mingw*)
 504     ;;
 505 *)
 506     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 507                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 508                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 509     AC_SUBST([CLOCK_LIB])
 510     ;;
 511 esac
 512
 513 dnl See if posix_memalign is available
 514 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 515
 516 dnl Check for pthreads
 517 AX_PTHREAD
 518 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 519 dnl to -pthread, which causes problems if we need -lpthread to appear in
 520 dnl pkgconfig files.
 521 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 522
 523 dnl SELinux awareness.
 524 AC_ARG_ENABLE([selinux],
 525     [AS_HELP_STRING([--enable-selinux],
 526         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 527     [MESA_SELINUX="$enableval"],
 528     [MESA_SELINUX=no])
 529 if test "x$enable_selinux" = "xyes"; then
 530     AC_CHECK_HEADER([selinux/selinux.h],[],
 531                     [AC_MSG_ERROR([SELinux headers not found])])
 532     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 533                  [AC_MSG_ERROR([SELinux library not found])])
 534     SELINUX_LIBS="-lselinux"
 535     DEFINES="$DEFINES -DMESA_SELINUX"
 536 fi
 537 AC_SUBST([SELINUX_LIBS])
 538
 539 dnl Options for APIs
 540 AC_ARG_ENABLE([opengl],
 541     [AS_HELP_STRING([--disable-opengl],
 542         [disable support for standard OpenGL API @<:@default=no@:>@])],
 543     [enable_opengl="$enableval"],
 544     [enable_opengl=yes])
 545 AC_ARG_ENABLE([gles1],
 546     [AS_HELP_STRING([--enable-gles1],
 547         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 548     [enable_gles1="$enableval"],
 549     [enable_gles1=no])
 550 AC_ARG_ENABLE([gles2],
 551     [AS_HELP_STRING([--enable-gles2],
 552         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 553     [enable_gles2="$enableval"],
 554     [enable_gles2=no])
 555 AC_ARG_ENABLE([openvg],
 556     [AS_HELP_STRING([--enable-openvg],
 557         [enable support for OpenVG API @<:@default=no@:>@])],
 558     [enable_openvg="$enableval"],
 559     [enable_openvg=no])
 560
 561 AC_ARG_ENABLE([dri],
 562     [AS_HELP_STRING([--enable-dri],
 563         [enable DRI modules @<:@default=enabled@:>@])],
 564     [enable_dri="$enableval"],
 565     [enable_dri=yes])
 566 AC_ARG_ENABLE([glx],
 567     [AS_HELP_STRING([--enable-glx],
 568         [enable GLX library @<:@default=enabled@:>@])],
 569     [enable_glx="$enableval"],
 570     [enable_glx=yes])
 571 AC_ARG_ENABLE([osmesa],
 572     [AS_HELP_STRING([--enable-osmesa],
 573         [enable OSMesa library @<:@default=disabled@:>@])],
 574     [enable_osmesa="$enableval"],
 575     [enable_osmesa=no])
 576 AC_ARG_ENABLE([egl],
 577     [AS_HELP_STRING([--disable-egl],
 578         [disable EGL library @<:@default=enabled@:>@])],
 579     [enable_egl="$enableval"],
 580     [enable_egl=yes])
 581
 582 AC_ARG_ENABLE([xorg],
 583     [AS_HELP_STRING([--enable-xorg],
 584         [enable support for X.Org DDX API @<:@default=no@:>@])],
 585     [enable_xorg="$enableval"],
 586     [enable_xorg=no])
 587 AC_ARG_ENABLE([xa],
 588     [AS_HELP_STRING([--enable-xa],
 589         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 590     [enable_xa="$enableval"],
 591     [enable_xa=no])
 592 AC_ARG_ENABLE([gbm],
 593    [AS_HELP_STRING([--enable-gbm],
 594          [enable gbm library @<:@default=auto@:>@])],
 595    [enable_gbm="$enableval"],
 596    [enable_gbm=auto])
 597
 598 AC_ARG_ENABLE([xvmc],
 599    [AS_HELP_STRING([--enable-xvmc],
 600          [enable xvmc library @<:@default=auto@:>@])],
 601    [enable_xvmc="$enableval"],
 602    [enable_xvmc=auto])
 603 AC_ARG_ENABLE([vdpau],
 604    [AS_HELP_STRING([--enable-vdpau],
 605          [enable vdpau library @<:@default=auto@:>@])],
 606    [enable_vdpau="$enableval"],
 607    [enable_vdpau=auto])
 608 AC_ARG_ENABLE([opencl],
 609    [AS_HELP_STRING([--enable-opencl],
 610          [enable OpenCL library NOTE: Enabling this option will also enable
 611           --with-llvm-shared-libs
 612           @<:@default=no@:>@])],
 613    [],
 614    [enable_opencl=no])
 615 AC_ARG_ENABLE([xlib_glx],
 616     [AS_HELP_STRING([--enable-xlib-glx],
 617         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 618     [enable_xlib_glx="$enableval"],
 619     [enable_xlib_glx=no])
 620 AC_ARG_ENABLE([gallium_egl],
 621     [AS_HELP_STRING([--enable-gallium-egl],
 622         [enable optional EGL state tracker (not required
 623          for EGL support in Gallium with OpenGL and OpenGL ES)
 624          @<:@default=disable@:>@])],
 625     [enable_gallium_egl="$enableval"],
 626     [enable_gallium_egl=no])
 627 AC_ARG_ENABLE([gallium_gbm],
 628     [AS_HELP_STRING([--enable-gallium-gbm],
 629         [enable optional gbm state tracker (not required for
 630          gbm support in Gallium)
 631          @<:@default=auto@:>@])],
 632     [enable_gallium_gbm="$enableval"],
 633     [enable_gallium_gbm=auto])
 634
 635 AC_ARG_ENABLE([r600-llvm-compiler],
 636     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 637         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 638     [enable_r600_llvm="$enableval"],
 639     [enable_r600_llvm=no])
 640
 641 AC_ARG_ENABLE([gallium_tests],
 642     [AS_HELP_STRING([--enable-gallium-tests],
 643         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 644     [enable_gallium_tests="$enableval"],
 645     [enable_gallium_tests=no])
 646
 647 # Option for Gallium drivers
 648
 649 # Keep this in sync with the --with-gallium-drivers help string default value
 650 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 651
 652 AC_ARG_WITH([gallium-drivers],
 653     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 654         [comma delimited Gallium drivers list, e.g.
 655         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 656         @<:@default=r300,r600,svga,swrast@:>@])],
 657     [with_gallium_drivers="$withval"],
 658     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 659
 660 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 661 # here so that the script doesn't choke on an unknown driver name later.
 662 case "$with_gallium_drivers" in
 663     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 664     no) with_gallium_drivers='' ;;
 665 esac
 666
 667 if test "x$enable_opengl" = xno -a \
 668         "x$enable_gles1" = xno -a \
 669         "x$enable_gles2" = xno -a \
 670         "x$enable_openvg" = xno -a \
 671         "x$enable_xorg" = xno -a \
 672         "x$enable_xa" = xno -a \
 673         "x$enable_xvmc" = xno -a \
 674         "x$enable_vdpau" = xno -a \
 675         "x$enable_opencl" = xno; then
 676     AC_MSG_ERROR([at least one API should be enabled])
 677 fi
 678
 679 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 680 if test "x$enable_opengl" = xno -a \
 681         "x$enable_gles1" = xyes; then
 682     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 683 fi
 684
 685 if test "x$enable_opengl" = xno -a \
 686         "x$enable_gles2" = xyes; then
 687     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 688 fi
 689
 690 API_DEFINES=""
 691 if test "x$enable_opengl" = xno; then
 692     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 693 else
 694     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 695 fi
 696 if test "x$enable_gles1" = xyes; then
 697     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 698 fi
 699 if test "x$enable_gles2" = xyes; then
 700     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 701 fi
 702 AC_SUBST([API_DEFINES])
 703
 704 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 705 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 706 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 707 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 708                                         "x$enable_gles1" = xyes -o \
 709                                         "x$enable_gles2" = xyes)
 710
 711 if test "x$enable_glx" = xno; then
 712     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 713     enable_xlib_glx=no
 714 fi
 715
 716 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 717     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 718 fi
 719
 720 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 721     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 722 fi
 723
 724 # Disable GLX if OpenGL is not enabled
 725 if test "x$enable_glx$enable_opengl" = xyesno; then
 726     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 727     enable_glx=no
 728 fi
 729
 730 # Disable GLX if DRI and Xlib-GLX are not enabled
 731 if test "x$enable_glx" = xyes -a \
 732         "x$enable_dri" = xno -a \
 733         "x$enable_xlib_glx" = xno; then
 734     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 735     enable_glx=no
 736 fi
 737
 738 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 739                                   "x$enable_dri" = xyes)
 740 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 741 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 742                                   "x$enable_osmesa" = xyes)
 743
 744 AC_ARG_ENABLE([shared-glapi],
 745     [AS_HELP_STRING([--enable-shared-glapi],
 746         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 747     [enable_shared_glapi="$enableval"],
 748     [enable_shared_glapi="$enable_dri"])
 749
 750 # Shared GLAPI is only useful for DRI
 751 if test "x$enable_dri" = xno; then
 752     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 753     enable_shared_glapi=no
 754 fi
 755
 756 if test "x$enable_shared_glapi" = xyes; then
 757     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 758     # the remap table)
 759     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 760 fi
 761 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 762
 763 dnl
 764 dnl Driver specific build directories
 765 dnl
 766 GALLIUM_TARGET_DIRS=""
 767 GALLIUM_WINSYS_DIRS="sw"
 768 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 769 GALLIUM_STATE_TRACKERS_DIRS=""
 770
 771 case "x$enable_glx$enable_xlib_glx" in
 772 xyesyes)
 773     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 774     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 775     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 776     NEED_WINSYS_XLIB="yes"
 777     ;;
 778 esac
 779
 780 if test "x$enable_dri" = xyes; then
 781     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 782     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 783 fi
 784
 785 if test "x$enable_osmesa" = xyes; then
 786     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 787     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 788 fi
 789
 790 AC_SUBST([MESA_LLVM])
 791
 792 # Check for libdrm
 793 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 794                   [have_libdrm=yes], [have_libdrm=no])
 795
 796 if test "x$enable_dri" = xyes; then
 797     # DRI must be shared, I think
 798     if test "$enable_static" = yes; then
 799         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 800     fi
 801
 802     # not a hard requirement as swrast does not depend on it
 803     if test "x$have_libdrm" = xyes; then
 804         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 805     fi
 806 fi
 807
 808 dnl Direct rendering or just indirect rendering
 809 case "$host_os" in
 810 gnu*)
 811     dnl Disable by default on GNU/Hurd
 812     driglx_direct_default="no"
 813     ;;
 814 cygwin*)
 815     dnl Disable by default on cygwin
 816     driglx_direct_default="no"
 817     ;;
 818 *)
 819     driglx_direct_default="yes"
 820     ;;
 821 esac
 822 AC_ARG_ENABLE([driglx-direct],
 823     [AS_HELP_STRING([--disable-driglx-direct],
 824         [disable direct rendering in GLX and EGL for DRI \
 825             @<:@default=auto@:>@])],
 826     [driglx_direct="$enableval"],
 827     [driglx_direct="$driglx_direct_default"])
 828
 829 dnl
 830 dnl libGL configuration per driver
 831 dnl
 832 case "x$enable_glx$enable_xlib_glx" in
 833 xyesyes)
 834     # Xlib-based GLX
 835     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 836     GL_PC_REQ_PRIV="x11 xext"
 837     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 838     GL_LIB_DEPS="$XLIBGL_LIBS"
 839     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 840     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 841     ;;
 842 xyesno)
 843     # DRI-based GLX
 844     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 845     if test x"$driglx_direct" = xyes; then
 846         if test "x$have_libdrm" != xyes; then
 847             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 848         fi
 849         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 850         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 851     fi
 852
 853     # find the DRI deps for libGL
 854     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 855
 856     # add xf86vidmode if available
 857     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 858     if test "$HAVE_XF86VIDMODE" = yes ; then
 859         dri_modules="$dri_modules xxf86vm"
 860     fi
 861
 862     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 863     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 864     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 865     GL_LIB_DEPS="$DRIGL_LIBS"
 866
 867     # need DRM libs, $PTHREAD_LIBS, etc.
 868     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 869     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 870     ;;
 871 esac
 872
 873 # This is outside the case (above) so that it is invoked even for non-GLX
 874 # builds.
 875 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 876
 877 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 878 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 879 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 880 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 881
 882 AC_SUBST([X11_INCLUDES])
 883 AC_SUBST([GL_LIB_DEPS])
 884 AC_SUBST([GL_PC_REQ_PRIV])
 885 AC_SUBST([GL_PC_LIB_PRIV])
 886 AC_SUBST([GL_PC_CFLAGS])
 887 AC_SUBST([DRI_PC_REQ_PRIV])
 888 AC_SUBST([GLESv1_CM_LIB_DEPS])
 889 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 890 AC_SUBST([GLESv2_LIB_DEPS])
 891 AC_SUBST([GLESv2_PC_LIB_PRIV])
 892
 893 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 894
 895 AC_SUBST([HAVE_XF86VIDMODE])
 896
 897 dnl
 898 dnl More GLX setup
 899 dnl
 900 case "x$enable_glx$enable_xlib_glx" in
 901 xyesyes)
 902     DEFINES="$DEFINES -DUSE_XSHM"
 903     ;;
 904 xyesno)
 905     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 906     if test "x$driglx_direct" = xyes; then
 907         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 908     fi
 909     ;;
 910 esac
 911
 912 dnl
 913 dnl TLS detection
 914 dnl
 915
 916 AC_ARG_ENABLE([glx-tls],
 917     [AS_HELP_STRING([--enable-glx-tls],
 918         [enable TLS support in GLX @<:@default=disabled@:>@])],
 919     [GLX_USE_TLS="$enableval"],
 920     [GLX_USE_TLS=no])
 921 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 922
 923 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 924       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 925
 926 dnl
 927 dnl More DRI setup
 928 dnl
 929 dnl Directory for DRI drivers
 930 AC_ARG_WITH([dri-driverdir],
 931     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 932         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 933     [DRI_DRIVER_INSTALL_DIR="$withval"],
 934     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 935 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 936 dnl Extra search path for DRI drivers
 937 AC_ARG_WITH([dri-searchpath],
 938     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 939         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 940     [DRI_DRIVER_SEARCH_DIR="$withval"],
 941     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 942 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 943 dnl Which drivers to build - default is chosen by platform
 944 AC_ARG_WITH([dri-drivers],
 945     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 946         [comma delimited DRI drivers list, e.g.
 947         "swrast,i965,radeon" @<:@default=auto@:>@])],
 948     [with_dri_drivers="$withval"],
 949     [with_dri_drivers=yes])
 950 if test "x$with_dri_drivers" = x; then
 951     with_dri_drivers=no
 952 fi
 953
 954 dnl If $with_dri_drivers is yes, directories will be added through
 955 dnl platform checks
 956 DRI_DIRS=""
 957 case "$with_dri_drivers" in
 958 no) ;;
 959 yes)
 960     # classic DRI drivers require FEATURE_GL to build
 961     if test "x$enable_opengl" = xyes; then
 962         DRI_DIRS="yes"
 963     fi
 964     ;;
 965 *)
 966     # verify the requested driver directories exist
 967     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 968     for driver in $dri_drivers; do
 969         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 970             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 971     done
 972     DRI_DIRS="$dri_drivers"
 973     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 974         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 975     fi
 976     ;;
 977 esac
 978
 979 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 980 if test "x$enable_dri" = xyes; then
 981     # Platform specific settings and drivers to build
 982     case "$host_os" in
 983     linux*)
 984         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 985         DEFINES="$DEFINES -DHAVE_ALIAS"
 986
 987         case "$host_cpu" in
 988         x86_64)
 989             if test "x$DRI_DIRS" = "xyes"; then
 990                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 991             fi
 992             ;;
 993         powerpc*)
 994             # Build only the drivers for cards that exist on PowerPC.
 995             if test "x$DRI_DIRS" = "xyes"; then
 996                 DRI_DIRS="r200 radeon swrast"
 997             fi
 998             ;;
 999         sparc*)
1000             # Build only the drivers for cards that exist on sparc
1001             if test "x$DRI_DIRS" = "xyes"; then
1002                 DRI_DIRS="r200 radeon swrast"
1003             fi
1004             ;;
1005         esac
1006         ;;
1007     freebsd* | dragonfly* | *netbsd*)
1008         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1009         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1010
1011         if test "x$DRI_DIRS" = "xyes"; then
1012             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1013         fi
1014         ;;
1015     gnu*)
1016         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1017         DEFINES="$DEFINES -DHAVE_ALIAS"
1018         ;;
1019     solaris*)
1020         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1021         ;;
1022     cygwin*)
1023         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1024         if test "x$DRI_DIRS" = "xyes"; then
1025             DRI_DIRS="swrast"
1026         fi
1027         ;;
1028     esac
1029
1030     # default drivers
1031     if test "x$DRI_DIRS" = "xyes"; then
1032         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1033     fi
1034
1035     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1036
1037     # Check for expat
1038     EXPAT_INCLUDES=""
1039     EXPAT_LIB=-lexpat
1040     AC_ARG_WITH([expat],
1041         [AS_HELP_STRING([--with-expat=DIR],
1042             [expat install directory])],[
1043         EXPAT_INCLUDES="-I$withval/include"
1044         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1045         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1046         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1047         ])
1048     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1049     save_LIBS="$LIBS"
1050     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1051         [AC_MSG_ERROR([Expat required for DRI.])])
1052     LIBS="$save_LIBS"
1053
1054     # If we are building any DRI driver other than swrast.
1055     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1056         # ... libdrm is required
1057         if test "x$have_libdrm" != xyes; then
1058             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1059         fi
1060         # ... and build dricommon
1061         HAVE_COMMON_DRI=yes
1062     fi
1063
1064     # put all the necessary libs together
1065     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1066     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1067 fi
1068 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1069 AC_SUBST([EXPAT_INCLUDES])
1070 AC_SUBST([DRI_LIB_DEPS])
1071 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1072
1073 case $DRI_DIRS in
1074 *i915*|*i965*)
1075     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1076
1077     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1078         case $d in
1079         i915)
1080             HAVE_I915_DRI=yes;
1081             ;;
1082         i965)
1083             HAVE_I965_DRI=yes;
1084             ;;
1085         esac
1086     done
1087
1088     ;;
1089 esac
1090
1091 case $DRI_DIRS in
1092 *nouveau*)
1093     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1094     HAVE_NOUVEAU_DRI=yes;
1095     ;;
1096 esac
1097
1098 case $DRI_DIRS in
1099 *radeon*|*r200*)
1100     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1101
1102     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1103         case $d in
1104         radeon)
1105             HAVE_RADEON_DRI=yes;
1106             ;;
1107         r200)
1108             HAVE_R200_DRI=yes;
1109             ;;
1110         esac
1111     done
1112
1113     ;;
1114 esac
1115
1116 case $DRI_DIRS in
1117 *swrast*)
1118     HAVE_SWRAST_DRI=yes;
1119     ;;
1120 esac
1121
1122 dnl
1123 dnl OSMesa configuration
1124 dnl
1125
1126 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1127 AC_ARG_WITH([osmesa-bits],
1128     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1129         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1130     [osmesa_bits="$withval"],
1131     [osmesa_bits=8])
1132 if test "x$osmesa_bits" != x8; then
1133     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1134         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1135         osmesa_bits=8
1136     fi
1137 fi
1138 case "x$osmesa_bits" in
1139 x8)
1140     OSMESA_LIB="${OSMESA_LIB}"
1141     ;;
1142 x16|x32)
1143     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1144     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1145     ;;
1146 *)
1147     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1148     ;;
1149 esac
1150
1151 if test "x$enable_osmesa" = xyes; then
1152     # only link libraries with osmesa if shared
1153     if test "$enable_static" = no; then
1154         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1155     else
1156         OSMESA_LIB_DEPS=""
1157     fi
1158     OSMESA_MESA_DEPS=""
1159     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1160 fi
1161
1162 AC_SUBST([OSMESA_LIB_DEPS])
1163 AC_SUBST([OSMESA_MESA_DEPS])
1164 AC_SUBST([OSMESA_PC_REQ])
1165 AC_SUBST([OSMESA_PC_LIB_PRIV])
1166
1167 dnl
1168 dnl gbm configuration
1169 dnl
1170 if test "x$enable_gbm" = xauto; then
1171     case "$with_egl_platforms" in
1172         *drm*)
1173             enable_gbm=yes ;;
1174          *)
1175             enable_gbm=no ;;
1176     esac
1177 fi
1178 if test "x$enable_gbm" = xyes; then
1179     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1180                       AC_MSG_ERROR([gbm needs udev]))
1181
1182     if test "x$enable_dri" = xyes; then
1183         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1184         if test "x$enable_shared_glapi" = xno; then
1185             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1186         fi
1187     fi
1188 fi
1189 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1190 GBM_PC_REQ_PRIV="libudev"
1191 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1192 AC_SUBST([GBM_PC_REQ_PRIV])
1193 AC_SUBST([GBM_PC_LIB_PRIV])
1194
1195 dnl
1196 dnl EGL configuration
1197 dnl
1198 EGL_CLIENT_APIS=""
1199
1200 if test "x$enable_egl" = xyes; then
1201     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1202
1203     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1204
1205     if test "$enable_static" != yes; then
1206         # build egl_glx when libGL is built
1207         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1208                           [have_libudev=yes],[have_libudev=no])
1209         if test "$have_libudev" = yes; then
1210             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1211         fi
1212
1213         if test "x$enable_dri" = xyes; then
1214             HAVE_EGL_DRIVER_DRI2=1
1215         fi
1216
1217     fi
1218 fi
1219 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1220 AC_SUBST([EGL_LIB_DEPS])
1221
1222 dnl
1223 dnl EGL Gallium configuration
1224 dnl
1225 if test "x$enable_gallium_egl" = xyes; then
1226     if test "x$with_gallium_drivers" = x; then
1227         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1228     fi
1229     if test "x$enable_egl" = xno; then
1230         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1231     fi
1232     if test "x$have_libdrm" != xyes; then
1233         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1234     fi
1235
1236     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1237     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1238 fi
1239 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1240
1241 dnl
1242 dnl gbm Gallium configuration
1243 dnl
1244 if test "x$enable_gallium_gbm" = xauto; then
1245     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1246         yesyesyes*drm*)
1247             enable_gallium_gbm=yes ;;
1248          *)
1249             enable_gallium_gbm=no ;;
1250     esac
1251 fi
1252 if test "x$enable_gallium_gbm" = xyes; then
1253     if test "x$with_gallium_drivers" = x; then
1254         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1255     fi
1256     if test "x$enable_gbm" = xno; then
1257         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1258     fi
1259     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1260     if test "x$enable_dri" = xno; then
1261         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1262     fi
1263
1264     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1265     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1266     enable_gallium_loader=yes
1267 fi
1268 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1269
1270 dnl
1271 dnl X.Org DDX configuration
1272 dnl
1273 if test "x$enable_xorg" = xyes; then
1274     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1275     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1276     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1277     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1278         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1279         HAVE_XEXTPROTO_71="no")
1280     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1281 fi
1282 AM_CONDITIONAL(HAVE_ST_XORG, test "x$enable_xorg" = xyes)
1283
1284 dnl
1285 dnl XA configuration
1286 dnl
1287 if test "x$enable_xa" = xyes; then
1288 AC_PROG_AWK
1289 AC_PROG_GREP
1290 AC_CHECK_PROG(NM, nm, "nm")
1291 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1292 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1293 enable_xa=no
1294 fi
1295 fi
1296 if test "x$enable_xa" = xyes; then
1297     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1298     AC_SUBST(AWK)
1299     AC_SUBST(GREP)
1300     AC_SUBST(NM)
1301 fi
1302 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1303
1304 dnl
1305 dnl OpenVG configuration
1306 dnl
1307 VG_LIB_DEPS=""
1308
1309 if test "x$enable_openvg" = xyes; then
1310     if test "x$enable_egl" = xno; then
1311         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1312     fi
1313     if test "x$with_gallium_drivers" = x; then
1314         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1315     fi
1316     if test "x$enable_gallium_egl" = xno; then
1317         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1318     fi
1319
1320     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1321     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1322     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1323     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1324     AC_SUBST([VG_PC_LIB_PRIV])
1325 fi
1326 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1327
1328 dnl
1329 dnl Gallium G3DVL configuration
1330 dnl
1331 if test -n "$with_gallium_drivers"; then
1332     if test "x$enable_xvmc" = xauto; then
1333         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1334     fi
1335
1336     if test "x$enable_vdpau" = xauto; then
1337         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1338     fi
1339 fi
1340
1341 if test "x$enable_xvmc" = xyes; then
1342     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1343     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1344 fi
1345 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1346
1347 if test "x$enable_vdpau" = xyes; then
1348     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1349     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1350 fi
1351 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1352
1353 dnl
1354 dnl OpenCL configuration
1355 dnl
1356
1357 AC_ARG_WITH([libclc-path],
1358    [AS_HELP_STRING([--with-libclc-path],
1359          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1360    [LIBCLC_PATH="$withval"],
1361    [LIBCLC_PATH=""])
1362
1363 if test "x$LIBCLC_PATH" != x; then
1364    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1365                   Please review the updated build instructions for clover:
1366                   http://dri.freedesktop.org/wiki/GalliumCompute])
1367 fi
1368
1369
1370 AC_ARG_WITH([clang-libdir],
1371    [AS_HELP_STRING([--with-clang-libdir],
1372          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1373    [CLANG_LIBDIR="$withval"],
1374    [CLANG_LIBDIR=""])
1375
1376 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1377 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1378 AC_SUBST([LIBCLC_INCLUDEDIR])
1379 AC_SUBST([LIBCLC_LIBEXECDIR])
1380
1381 if test "x$enable_opencl" = xyes; then
1382     if test "x$with_gallium_drivers" = x; then
1383         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1384     fi
1385
1386     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1387         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1388     fi
1389
1390     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1391         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1392     fi
1393
1394     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1395     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1396     enable_gallium_loader=yes
1397 fi
1398 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1399
1400 dnl
1401 dnl Gallium configuration
1402 dnl
1403 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1404
1405 AC_SUBST([LLVM_BINDIR])
1406 AC_SUBST([LLVM_CFLAGS])
1407 AC_SUBST([LLVM_CPPFLAGS])
1408 AC_SUBST([LLVM_CXXFLAGS])
1409 AC_SUBST([LLVM_LIBDIR])
1410 AC_SUBST([LLVM_LIBS])
1411 AC_SUBST([LLVM_LDFLAGS])
1412 AC_SUBST([LLVM_INCLUDEDIR])
1413 AC_SUBST([LLVM_VERSION])
1414 AC_SUBST([CLANG_RESOURCE_DIR])
1415
1416 case "x$enable_opengl$enable_gles1$enable_gles2" in
1417 x*yes*)
1418     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1419     ;;
1420 esac
1421
1422 AC_SUBST([VG_LIB_DEPS])
1423 AC_SUBST([EGL_CLIENT_APIS])
1424
1425 dnl
1426 dnl EGL Platforms configuration
1427 dnl
1428 AC_ARG_WITH([egl-platforms],
1429     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1430         [comma delimited native platforms libEGL supports, e.g.
1431         "x11,drm" @<:@default=auto@:>@])],
1432     [with_egl_platforms="$withval"],
1433     [if test "x$enable_egl" = xyes; then
1434         with_egl_platforms="x11"
1435     else
1436         with_egl_platforms=""
1437     fi])
1438
1439 EGL_PLATFORMS=""
1440
1441 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1442     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1443 fi
1444
1445 # Do per-EGL platform setups and checks
1446 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1447 for plat in $egl_platforms; do
1448         case "$plat" in
1449         wayland)
1450                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1451                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1452
1453                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1454                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1455                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1456                 ;;
1457
1458         x11)
1459                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1460
1461                 if test "x$enable_glx" = xyes; then
1462                         HAVE_EGL_DRIVER_GLX=1
1463                 fi
1464                 ;;
1465
1466         drm)
1467                 test "x$enable_gbm" = "xno" &&
1468                         AC_MSG_ERROR([EGL platform drm needs gbm])
1469                 ;;
1470
1471         android|fbdev|gdi|null)
1472                 ;;
1473
1474         *)
1475                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1476                 ;;
1477         esac
1478
1479         case "$plat$have_libudev" in
1480                 waylandno|drmno)
1481                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1482         esac
1483 done
1484
1485 # libEGL wants to default to the first platform specified in
1486 # ./configure.  parse that here.
1487 if test "x$egl_platforms" != "x"; then
1488     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1489     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1490 else
1491     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1492 fi
1493
1494 EGL_PLATFORMS="$egl_platforms"
1495
1496 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1497     NEED_WINSYS_XLIB=yes
1498 fi
1499 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1500 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1501 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1502 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1503 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1504
1505 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1506 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1507
1508 AC_SUBST([EGL_NATIVE_PLATFORM])
1509 AC_SUBST([EGL_PLATFORMS])
1510 AC_SUBST([EGL_CFLAGS])
1511
1512 AC_ARG_WITH([egl-driver-dir],
1513     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1514                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1515     [EGL_DRIVER_INSTALL_DIR="$withval"],
1516     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1517 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1518
1519 AC_ARG_WITH([xorg-driver-dir],
1520     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1521                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1522     [XORG_DRIVER_INSTALL_DIR="$withval"],
1523     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1524 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1525
1526 AC_ARG_WITH([max-width],
1527     [AS_HELP_STRING([--with-max-width=N],
1528                     [Maximum framebuffer width (4096)])],
1529     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1530      AS_IF([test "${withval}" -gt "4096"],
1531            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1532 )
1533 AC_ARG_WITH([max-height],
1534     [AS_HELP_STRING([--with-max-height=N],
1535                     [Maximum framebuffer height (4096)])],
1536     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1537      AS_IF([test "${withval}" -gt "4096"],
1538            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1539 )
1540
1541 dnl
1542 dnl Gallium LLVM
1543 dnl
1544 AC_ARG_ENABLE([gallium-llvm],
1545     [AS_HELP_STRING([--enable-gallium-llvm],
1546         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1547     [enable_gallium_llvm="$enableval"],
1548     [enable_gallium_llvm=auto])
1549
1550 AC_ARG_WITH([llvm-shared-libs],
1551     [AS_HELP_STRING([--with-llvm-shared-libs],
1552         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1553     [],
1554     [with_llvm_shared_libs=no])
1555 AS_IF([test x$enable_opencl = xyes],
1556     [
1557         AC_MSG_WARN([OpenCL required, forcing LLVM shared libraries])
1558         with_llvm_shared_libs=yes
1559     ])
1560
1561 AC_ARG_WITH([llvm-prefix],
1562     [AS_HELP_STRING([--with-llvm-prefix],
1563         [Prefix for LLVM installations in non-standard locations])],
1564     [llvm_prefix="$withval"],
1565     [llvm_prefix=""])
1566
1567
1568 # Call this inside ` ` to get the return value.
1569 # $1 is the llvm-config command with arguments.
1570 strip_unwanted_llvm_flags() {
1571     # Use \> (marks the end of the word)
1572     echo `$1` | sed \
1573         -e 's/-DNDEBUG\>//g' \
1574         -e 's/-pedantic\>//g' \
1575         -e 's/-Wcovered-switch-default\>//g' \
1576         -e 's/-O.\>//g' \
1577         -e 's/-g\>//g' \
1578         -e 's/-Wall\>//g' \
1579         -e 's/-fomit-frame-pointer\>//g'
1580 }
1581
1582
1583 if test "x$with_gallium_drivers" = x; then
1584     enable_gallium_llvm=no
1585 fi
1586 if test "x$enable_gallium_llvm" = xauto; then
1587     case "$host_cpu" in
1588     i*86|x86_64) enable_gallium_llvm=yes;;
1589     esac
1590 fi
1591 if test "x$enable_gallium_llvm" = xyes; then
1592     if test "x$llvm_prefix" != x; then
1593         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1594     else
1595         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1596     fi
1597
1598     if test "x$LLVM_CONFIG" != xno; then
1599         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1600         LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1601         LLVM_COMPONENTS="engine bitwriter"
1602         if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1603             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1604         fi
1605
1606         if test "x$enable_opencl" = xyes; then
1607             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1608             # LLVM 3.3 >= 177971 requires IRReader
1609             if $LLVM_CONFIG --components | grep -q '\<irreader\>'; then
1610                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1611             fi
1612         fi
1613         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1614         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1615         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1616         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1617         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1618         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1619         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1620         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1621         MESA_LLVM=1
1622
1623         dnl Check for Clang interanl headers
1624         if test "x$enable_opencl" = xyes; then
1625             if test "x$CLANG_LIBDIR" = x; then
1626                 CLANG_LIBDIR=${LLVM_LIBDIR}
1627             fi
1628             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1629             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1630                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1631         fi
1632     else
1633         MESA_LLVM=0
1634         LLVM_VERSION_INT=0
1635     fi
1636 else
1637     MESA_LLVM=0
1638     LLVM_VERSION_INT=0
1639 fi
1640
1641 dnl Directory for XVMC libs
1642 AC_ARG_WITH([xvmc-libdir],
1643     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1644         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1645     [XVMC_LIB_INSTALL_DIR="$withval"],
1646     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1647 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1648
1649 dnl
1650 dnl Gallium Tests
1651 dnl
1652 if test "x$enable_gallium_tests" = xyes; then
1653     enable_gallium_loader=yes
1654 fi
1655 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1656
1657 if test "x$enable_gallium_loader" = xyes; then
1658     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1659 fi
1660 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1661
1662 dnl Directory for VDPAU libs
1663 AC_ARG_WITH([vdpau-libdir],
1664     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1665         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1666     [VDPAU_LIB_INSTALL_DIR="$withval"],
1667     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1668 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1669
1670 dnl Directory for OpenCL libs
1671 AC_ARG_WITH([opencl-libdir],
1672     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1673         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1674     [OPENCL_LIB_INSTALL_DIR="$withval"],
1675     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1676 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1677
1678 dnl
1679 dnl Gallium helper functions
1680 dnl
1681 gallium_check_st() {
1682     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1683          if test "x$have_libdrm" != xyes; then
1684             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1685          fi
1686          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1687     fi
1688     if test "x$enable_dri" = xyes && test "x$2" != x; then
1689          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1690          HAVE_COMMON_DRI=yes
1691     fi
1692     if test "x$enable_xorg" = xyes && test "x$3" != x; then
1693          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1694     fi
1695     if test "x$enable_xa" = xyes && test "x$4" != x; then
1696          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1697     fi
1698     if test "x$enable_xvmc" = xyes && test "x$5" != x; then
1699          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1700     fi
1701     if test "x$enable_vdpau" = xyes && test "x$6" != x; then
1702          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1703     fi
1704 }
1705
1706 gallium_require_llvm() {
1707     if test "x$MESA_LLVM" = x0; then
1708         case "$host_cpu" in
1709         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1710         esac
1711     fi
1712 }
1713
1714 gallium_require_drm_loader() {
1715     if test "x$enable_gallium_loader" = xyes; then
1716         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1717                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1718         if test "x$have_libdrm" != xyes; then
1719             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1720         fi
1721         enable_gallium_drm_loader=yes
1722     fi
1723 }
1724
1725 radeon_llvm_check() {
1726     LLVM_REQUIRED_VERSION_MAJOR="3"
1727     LLVM_REQUIRED_VERSION_MINOR="3"
1728     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1729         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1730     fi
1731     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<R600\>' ; then
1732         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1733                       sources with the --enable-experimental-targets=R600
1734                       configure flag])
1735     fi
1736     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader"
1737     NEED_RADEON_LLVM=yes
1738     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1739                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1740 }
1741
1742 dnl Gallium drivers
1743 if test "x$enable_dri" = xyes -o "x$enable_xorg" = xyes -o \
1744         "x$enable_xa" = xyes -o "x$enable_xvmc" = xyes -o \
1745         "x$enable_vdpau" = xyes; then
1746     NEED_NONNULL_WINSYS=yes
1747 fi
1748 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1749
1750 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1751 if test "x$with_gallium_drivers" != x; then
1752     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1753     for driver in $gallium_drivers; do
1754         case "x$driver" in
1755         xsvga)
1756             HAVE_GALLIUM_SVGA=yes
1757             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1758             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1759             ;;
1760         xi915)
1761             HAVE_GALLIUM_I915=yes
1762             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1763             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1764             if test "x$MESA_LLVM" = x1; then
1765                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1766             fi
1767             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1768             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1769             ;;
1770         xr300)
1771             HAVE_GALLIUM_R300=yes
1772             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1773             gallium_require_llvm "Gallium R300"
1774             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1775             gallium_check_st "radeon/drm" "dri-r300" "" "" "xvmc-r300" "vdpau-r300"
1776             ;;
1777         xr600)
1778             HAVE_GALLIUM_R600=yes
1779             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1780             gallium_require_drm_loader
1781             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1782             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1783                 radeon_llvm_check
1784                 R600_NEED_RADEON_GALLIUM=yes;
1785                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo bitreader asmparser"
1786             fi
1787             if test "x$enable_r600_llvm" = xyes; then
1788                 USE_R600_LLVM_COMPILER=yes;
1789             fi
1790             if test "x$enable_opencl" = xyes; then
1791                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1792             fi
1793             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1794             ;;
1795         xradeonsi)
1796             HAVE_GALLIUM_RADEONSI=yes
1797             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1798             gallium_require_drm_loader
1799             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1800             radeon_llvm_check
1801             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1802             ;;
1803         xnouveau)
1804             HAVE_GALLIUM_NOUVEAU=yes
1805             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1806             gallium_require_drm_loader
1807             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1808             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1809             ;;
1810         xfreedreno)
1811             HAVE_GALLIUM_FREEDRENO=yes
1812             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1813             gallium_require_drm_loader
1814             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1815             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" "" ""
1816             ;;
1817         xswrast)
1818             HAVE_GALLIUM_SOFTPIPE=yes
1819             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1820             if test "x$MESA_LLVM" = x1; then
1821                 HAVE_GALLIUM_LLVMPIPE=yes
1822                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1823             fi
1824
1825             if test "x$enable_dri" = xyes; then
1826                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1827             fi
1828             if test "x$enable_vdpau" = xyes; then
1829                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1830             fi
1831             if test "x$enable_xvmc" = xyes; then
1832                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1833             fi
1834             if test "x$enable_vdpau" = xyes -o "x$enable_xvmc" = xyes; then
1835                 NEED_WINSYS_XLIB=yes
1836                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1837             fi
1838             ;;
1839         *)
1840             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1841             ;;
1842         esac
1843     done
1844 fi
1845
1846 dnl Set LLVM_LIBS - This is done after the driver configuration so
1847 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1848 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1849 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1850 dnl this was causing the same libraries to be appear multiple times
1851 dnl in LLVM_LIBS.
1852
1853 if test "x$MESA_LLVM" != x0; then
1854
1855     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1856
1857     if test "x$with_llvm_shared_libs" = xyes; then
1858         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1859         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1860         AC_CHECK_FILE("$LLVM_LIBDIR/lib$LLVM_SO_NAME.so", llvm_have_one_so=yes,)
1861
1862         if test "x$llvm_have_one_so" = xyes; then
1863             dnl LLVM was built using auto*, so there is only one shared object.
1864             LLVM_LIBS="-l$LLVM_SO_NAME"
1865         else
1866             dnl If LLVM was built with CMake, there will be one shared object per
1867             dnl component.
1868             AC_CHECK_FILE("$LLVM_LIBDIR/libLLVMTarget.so",,
1869                     AC_MSG_ERROR([Could not find llvm shared libraries:
1870         Please make sure you have built llvm with the --enable-shared option
1871         and that your llvm libraries are installed in $LLVM_LIBDIR
1872         If you have installed your llvm libraries to a different directory you
1873         can use the --with-llvm-prefix= configure flag to specify this directory.
1874         NOTE: Mesa is attempting to use llvm shared libraries because you have
1875         passed one of the following options to configure:
1876                 --with-llvm-shared-libs
1877                 --enable-opencl
1878         If you do not want to build with llvm shared libraries and instead want to
1879         use llvm static libraries then remove these options from your configure
1880         invocation and reconfigure.]))
1881
1882            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1883            dnl install uses a shared object for each compoenent and we have
1884            dnl already added all of these objects to LLVM_LIBS.
1885         fi
1886     fi
1887 fi
1888
1889 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1890 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1891 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1892 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1893 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1894 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1895 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1896 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1897 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1898
1899 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1900                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1901                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1902 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1903                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes -a \
1904                                                   "x$MESA_LLVM" = x1)
1905
1906 if test "x$enable_gallium_loader" = xyes; then
1907     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1908     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1909     GALLIUM_PIPE_LOADER_LIBS="\$(top_builddir)/src/gallium/auxiliary/pipe-loader/libpipe_loader.la"
1910     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/null/libws_null.la"
1911
1912     if test "x$NEED_WINSYS_XLIB" = xyes; then
1913         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1914         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/xlib/libws_xlib.la"
1915     fi
1916
1917     if test "x$enable_gallium_drm_loader" = xyes; then
1918         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1919         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1920                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1921         if test "x$pipe_loader_have_xcb" = xyes; then
1922             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1923             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1924         fi
1925     fi
1926
1927     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1928     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1929 fi
1930
1931 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1932 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1933 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1934 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1935 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1936 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1937 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1938
1939 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1940                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1941                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1942                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1943 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1944                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1945 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1946 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1947 AM_CONDITIONAL(R600_NEED_RADEON_GALLIUM, test x$R600_NEED_RADEON_GALLIUM = xyes)
1948 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1949 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1950 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1951 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1952 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1953 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
1954
1955 AC_SUBST([ELF_LIB])
1956
1957 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
1958                                      "x$enable_xlib_glx" = xyes -o \
1959                                      "x$enable_osmesa" = xyes)
1960 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1961 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1962
1963 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1964 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1965 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1966
1967 AM_CONDITIONAL(CROSS_COMPILING, test "x$cross_compiling" = xyes)
1968
1969 AC_SUBST([VDPAU_MAJOR], 1)
1970 AC_SUBST([VDPAU_MINOR], 0)
1971
1972 AC_SUBST([XVMC_MAJOR], 1)
1973 AC_SUBST([XVMC_MINOR], 0)
1974
1975 AC_SUBST([XA_MAJOR], 1)
1976 AC_SUBST([XA_MINOR], 0)
1977 AC_SUBST([XA_TINY], 0)
1978 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1979
1980 dnl Restore LDFLAGS and CPPFLAGS
1981 LDFLAGS="$_SAVE_LDFLAGS"
1982 CPPFLAGS="$_SAVE_CPPFLAGS"
1983
1984 dnl Add user CFLAGS and CXXFLAGS
1985 CFLAGS="$CFLAGS $USER_CFLAGS"
1986 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1987
1988 dnl Substitute the config
1989 AC_CONFIG_FILES([Makefile
1990                 src/Makefile
1991                 src/egl/Makefile
1992                 src/egl/drivers/Makefile
1993                 src/egl/drivers/dri2/Makefile
1994                 src/egl/drivers/glx/Makefile
1995                 src/egl/main/Makefile
1996                 src/egl/main/egl.pc
1997                 src/egl/wayland/Makefile
1998                 src/egl/wayland/wayland-drm/Makefile
1999                 src/egl/wayland/wayland-egl/Makefile
2000                 src/egl/wayland/wayland-egl/wayland-egl.pc
2001                 src/gallium/auxiliary/Makefile
2002                 src/gallium/auxiliary/pipe-loader/Makefile
2003                 src/gallium/drivers/Makefile
2004                 src/gallium/drivers/freedreno/Makefile
2005                 src/gallium/drivers/i915/Makefile
2006                 src/gallium/drivers/llvmpipe/Makefile
2007                 src/gallium/drivers/nouveau/Makefile
2008                 src/gallium/drivers/nv30/Makefile
2009                 src/gallium/drivers/nv50/Makefile
2010                 src/gallium/drivers/nvc0/Makefile
2011                 src/gallium/drivers/r300/Makefile
2012                 src/gallium/drivers/r600/Makefile
2013                 src/gallium/drivers/radeon/Makefile
2014                 src/gallium/drivers/radeonsi/Makefile
2015                 src/gallium/drivers/rbug/Makefile
2016                 src/gallium/drivers/softpipe/Makefile
2017                 src/gallium/drivers/svga/Makefile
2018                 src/gallium/drivers/trace/Makefile
2019                 src/gallium/state_trackers/Makefile
2020                 src/gallium/state_trackers/clover/Makefile
2021                 src/gallium/state_trackers/dri/Makefile
2022                 src/gallium/state_trackers/dri/drm/Makefile
2023                 src/gallium/state_trackers/dri/sw/Makefile
2024                 src/gallium/state_trackers/egl/Makefile
2025                 src/gallium/state_trackers/gbm/Makefile
2026                 src/gallium/state_trackers/glx/Makefile
2027                 src/gallium/state_trackers/osmesa/Makefile
2028                 src/gallium/state_trackers/vdpau/Makefile
2029                 src/gallium/state_trackers/vega/Makefile
2030                 src/gallium/state_trackers/xa/Makefile
2031                 src/gallium/state_trackers/xorg/Makefile
2032                 src/gallium/state_trackers/xvmc/Makefile
2033                 src/gallium/targets/Makefile
2034                 src/gallium/targets/dri-freedreno/Makefile
2035                 src/gallium/targets/dri-i915/Makefile
2036                 src/gallium/targets/dri-nouveau/Makefile
2037                 src/gallium/targets/dri-r300/Makefile
2038                 src/gallium/targets/dri-r600/Makefile
2039                 src/gallium/targets/dri-radeonsi/Makefile
2040                 src/gallium/targets/dri-swrast/Makefile
2041                 src/gallium/targets/dri-vmwgfx/Makefile
2042                 src/gallium/targets/egl-static/Makefile
2043                 src/gallium/targets/gbm/Makefile
2044                 src/gallium/targets/opencl/Makefile
2045                 src/gallium/targets/osmesa/Makefile
2046                 src/gallium/targets/pipe-loader/Makefile
2047                 src/gallium/targets/libgl-xlib/Makefile
2048                 src/gallium/targets/vdpau-nouveau/Makefile
2049                 src/gallium/targets/vdpau-r300/Makefile
2050                 src/gallium/targets/vdpau-r600/Makefile
2051                 src/gallium/targets/vdpau-radeonsi/Makefile
2052                 src/gallium/targets/vdpau-softpipe/Makefile
2053                 src/gallium/targets/xa-vmwgfx/Makefile
2054                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2055                 src/gallium/targets/xorg-i915/Makefile
2056                 src/gallium/targets/xorg-nouveau/Makefile
2057                 src/gallium/targets/xorg-r600/Makefile
2058                 src/gallium/targets/xorg-radeonsi/Makefile
2059                 src/gallium/targets/xvmc-nouveau/Makefile
2060                 src/gallium/targets/xvmc-r300/Makefile
2061                 src/gallium/targets/xvmc-r600/Makefile
2062                 src/gallium/targets/xvmc-softpipe/Makefile
2063                 src/gallium/tests/trivial/Makefile
2064                 src/gallium/tests/unit/Makefile
2065                 src/gallium/winsys/Makefile
2066                 src/gallium/winsys/freedreno/drm/Makefile
2067                 src/gallium/winsys/i915/drm/Makefile
2068                 src/gallium/winsys/i915/sw/Makefile
2069                 src/gallium/winsys/nouveau/drm/Makefile
2070                 src/gallium/winsys/radeon/drm/Makefile
2071                 src/gallium/winsys/svga/drm/Makefile
2072                 src/gallium/winsys/sw/dri/Makefile
2073                 src/gallium/winsys/sw/fbdev/Makefile
2074                 src/gallium/winsys/sw/null/Makefile
2075                 src/gallium/winsys/sw/wayland/Makefile
2076                 src/gallium/winsys/sw/wrapper/Makefile
2077                 src/gallium/winsys/sw/xlib/Makefile
2078                 src/gbm/Makefile
2079                 src/gbm/main/gbm.pc
2080                 src/glsl/Makefile
2081                 src/glsl/builtin_compiler/Makefile
2082                 src/glx/Makefile
2083                 src/glx/tests/Makefile
2084                 src/gtest/Makefile
2085                 src/mapi/Makefile
2086                 src/mapi/es1api/Makefile
2087                 src/mapi/es1api/glesv1_cm.pc
2088                 src/mapi/es2api/Makefile
2089                 src/mapi/es2api/glesv2.pc
2090                 src/mapi/glapi/Makefile
2091                 src/mapi/glapi/gen/Makefile
2092                 src/mapi/glapi/tests/Makefile
2093                 src/mapi/shared-glapi/Makefile
2094                 src/mapi/shared-glapi/tests/Makefile
2095                 src/mapi/vgapi/Makefile
2096                 src/mapi/vgapi/vg.pc
2097                 src/mesa/Makefile
2098                 src/mesa/gl.pc
2099                 src/mesa/drivers/dri/dri.pc
2100                 src/mesa/drivers/dri/common/Makefile
2101                 src/mesa/drivers/dri/common/xmlpool/Makefile
2102                 src/mesa/drivers/dri/i915/Makefile
2103                 src/mesa/drivers/dri/i965/Makefile
2104                 src/mesa/drivers/dri/Makefile
2105                 src/mesa/drivers/dri/nouveau/Makefile
2106                 src/mesa/drivers/dri/r200/Makefile
2107                 src/mesa/drivers/dri/radeon/Makefile
2108                 src/mesa/drivers/dri/swrast/Makefile
2109                 src/mesa/drivers/osmesa/Makefile
2110                 src/mesa/drivers/osmesa/osmesa.pc
2111                 src/mesa/drivers/x11/Makefile
2112                 src/mesa/libdricore/Makefile
2113                 src/mesa/main/tests/Makefile
2114                 src/mesa/main/tests/hash_table/Makefile
2115                 src/mesa/program/Makefile
2116                 src/mesa/x86-64/Makefile
2117                 src/mesa/x86/Makefile])
2118
2119 dnl Sort the dirs alphabetically
2120 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2121 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2122 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2123 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2124
2125 AC_OUTPUT
2126
2127 dnl
2128 dnl Output some configuration info for the user
2129 dnl
2130 echo ""
2131 echo "        prefix:          $prefix"
2132 echo "        exec_prefix:     $exec_prefix"
2133 echo "        libdir:          $libdir"
2134 echo "        includedir:      $includedir"
2135
2136 dnl API info
2137 echo ""
2138 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2139 echo "        OpenVG:          $enable_openvg"
2140
2141 dnl Driver info
2142 echo ""
2143 if test "x$enable_osmesa" != xno; then
2144         echo "        OSMesa:          lib$OSMESA_LIB"
2145 else
2146         echo "        OSMesa:          no"
2147 fi
2148
2149 if test "x$enable_dri" != xno; then
2150         # cleanup the drivers var
2151         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2152         if test "x$DRI_DIRS" = x; then
2153             echo "        DRI drivers:     no"
2154         else
2155             echo "        DRI drivers:     $dri_dirs"
2156         fi
2157         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2158 fi
2159
2160 case "x$enable_glx$enable_xlib_glx" in
2161 xyesyes)
2162     echo "        GLX:             Xlib-based"
2163     ;;
2164 xyesno)
2165     echo "        GLX:             DRI-based"
2166     ;;
2167 *)
2168     echo "        GLX:             $enable_glx"
2169     ;;
2170 esac
2171
2172 dnl EGL
2173 echo ""
2174 echo "        EGL:             $enable_egl"
2175 if test "$enable_egl" = yes; then
2176     echo "        EGL platforms:   $EGL_PLATFORMS"
2177
2178     egl_drivers=""
2179     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2180         egl_drivers="$egl_drivers builtin:egl_glx"
2181     fi
2182     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2183         egl_drivers="$egl_drivers builtin:egl_dri2"
2184     fi
2185
2186     if test "x$enable_gallium_egl" = xyes; then
2187         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2188         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2189     else
2190         echo "        EGL drivers:    $egl_drivers"
2191     fi
2192 fi
2193
2194 echo ""
2195 if test "x$MESA_LLVM" = x1; then
2196     echo "        llvm:            yes"
2197     echo "        llvm-config:     $LLVM_CONFIG"
2198     echo "        llvm-version:    $LLVM_VERSION"
2199 else
2200     echo "        llvm:            no"
2201 fi
2202
2203 echo ""
2204 if test -n "$with_gallium_drivers"; then
2205     echo "        Gallium:         yes"
2206     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2207     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2208     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2209     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2210 else
2211     echo "        Gallium:         no"
2212 fi
2213
2214
2215 dnl Libraries
2216 echo ""
2217 echo "        Shared libs:     $enable_shared"
2218 echo "        Static libs:     $enable_static"
2219 echo "        Shared-glapi:    $enable_shared_glapi"
2220
2221 dnl Compiler options
2222 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2223 cflags=`echo $CFLAGS | \
2224     $SED 's/^ *//;s/  */ /;s/ *$//'`
2225 cxxflags=`echo $CXXFLAGS | \
2226     $SED 's/^ *//;s/  */ /;s/ *$//'`
2227 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2228 echo ""
2229 echo "        CFLAGS:          $cflags"
2230 echo "        CXXFLAGS:        $cxxflags"
2231 echo "        Macros:          $defines"
2232 echo ""
2233 if test "x$MESA_LLVM" = x1; then
2234     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2235     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2236     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2237     echo ""
2238 fi
2239 echo "        PYTHON2:         $PYTHON2"
2240
2241 echo ""
2242 echo "        Run '${MAKE-make}' to build Mesa"
2243 echo ""