configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.55
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCB_REQUIRED=1.9.3
  45 XCBDRI2_REQUIRED=1.8
  46 XCBGLX_REQUIRED=1.8.1
  47 XSHMFENCE_REQUIRED=1.1
  48 XVMC_REQUIRED=1.0.6
  49
  50 dnl Check for progs
  51 AC_PROG_CPP
  52 AC_PROG_CC
  53 AC_PROG_CXX
  54 AM_PROG_CC_C_O
  55 AM_PROG_AS
  56 AC_CHECK_PROGS([MAKE], [gmake make])
  57 AC_CHECK_PROGS([PYTHON2], [python2 python])
  58 AC_PROG_SED
  59 AC_PROG_MKDIR_P
  60
  61 AC_SYS_LARGEFILE
  62
  63 LT_PREREQ([2.2])
  64 LT_INIT([disable-static])
  65
  66 AX_PROG_BISON([],
  67               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  68                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  69 AX_PROG_FLEX([],
  70              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  71                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  72
  73 AC_PATH_PROG([PERL], [perl])
  74
  75 AC_CHECK_PROG(INDENT, indent, indent, cat)
  76 if test "x$INDENT" != "xcat"; then
  77     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  78 fi
  79
  80 AC_PROG_INSTALL
  81
  82 dnl We need a POSIX shell for parts of the build. Assume we have one
  83 dnl in most cases.
  84 case "$host_os" in
  85 solaris*)
  86     # Solaris /bin/sh is too old/non-POSIX compliant
  87     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  88     SHELL="$POSIX_SHELL"
  89     ;;
  90 esac
  91
  92 dnl clang is mostly GCC-compatible, but its version is much lower,
  93 dnl so we have to check for it.
  94 AC_MSG_CHECKING([if compiling with clang])
  95
  96 AC_COMPILE_IFELSE(
  97 [AC_LANG_PROGRAM([], [[
  98 #ifndef __clang__
  99        not clang
 100 #endif
 101 ]])],
 102 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 103
 104 AC_MSG_RESULT([$acv_mesa_CLANG])
 105
 106 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 107 dnl versions are explictly not supported.
 108 GEN_ASM_OFFSETS=no
 109 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 110     AC_MSG_CHECKING([whether gcc version is sufficient])
 111     major=0
 112     minor=0
 113
 114     GCC_VERSION=`$CC -dumpversion`
 115     if test $? -eq 0; then
 116         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 117         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 118     fi
 119
 120     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 121         AC_MSG_RESULT([no])
 122         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 123     else
 124         AC_MSG_RESULT([yes])
 125     fi
 126
 127     if test "x$cross_compiling" = xyes; then
 128         GEN_ASM_OFFSETS=yes
 129     fi
 130 fi
 131
 132 dnl Check for compiler builtins
 133 AX_GCC_BUILTIN([__builtin_bswap32])
 134 AX_GCC_BUILTIN([__builtin_bswap64])
 135
 136 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 137
 138 dnl Make sure the pkg-config macros are defined
 139 m4_ifndef([PKG_PROG_PKG_CONFIG],
 140     [m4_fatal([Could not locate the pkg-config autoconf macros.
 141   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 142   are in a different location, try setting the environment variable
 143   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 144 PKG_PROG_PKG_CONFIG()
 145
 146 dnl LIB_DIR - library basename
 147 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 148 AC_SUBST([LIB_DIR])
 149
 150 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 151 _SAVE_LDFLAGS="$LDFLAGS"
 152 _SAVE_CPPFLAGS="$CPPFLAGS"
 153
 154 dnl Compiler macros
 155 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 156 AC_SUBST([DEFINES])
 157 case "$host_os" in
 158 linux*|*-gnu*|gnu*)
 159     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 160     ;;
 161 solaris*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 163     ;;
 164 cygwin*)
 165     DEFINES="$DEFINES -D_XOPEN_SOURCE=700 -DHAVE_PTHREAD"
 166     ;;
 167 esac
 168
 169 dnl Add flags for gcc and g++
 170 if test "x$GCC" = xyes; then
 171     CFLAGS="$CFLAGS -Wall -std=c99"
 172
 173     # Enable -Werror=implicit-function-declaration and
 174     # -Werror=missing-prototypes, if available, or otherwise, just
 175     # -Wmissing-prototypes.  This is particularly useful to avoid
 176     # generating a loadable driver module that has undefined symbols.
 177     save_CFLAGS="$CFLAGS"
 178     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 179     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 180     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 181     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 182                    AC_MSG_RESULT([yes]),
 183                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 184                     AC_MSG_RESULT([no])]);
 185
 186     # Enable -fvisibility=hidden if using a gcc that supports it
 187     save_CFLAGS="$CFLAGS"
 188     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 189     VISIBILITY_CFLAGS="-fvisibility=hidden"
 190     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 191     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 192                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 193
 194     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 195     CFLAGS=$save_CFLAGS
 196
 197     # Work around aliasing bugs - developers should comment this out
 198     CFLAGS="$CFLAGS -fno-strict-aliasing"
 199
 200     # gcc's builtin memcmp is slower than glibc's
 201     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 202     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 203 fi
 204 if test "x$GXX" = xyes; then
 205     CXXFLAGS="$CXXFLAGS -Wall"
 206
 207     # Enable -fvisibility=hidden if using a gcc that supports it
 208     save_CXXFLAGS="$CXXFLAGS"
 209     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 210     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 211     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 212     AC_LANG_PUSH([C++])
 213     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 214                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 215     AC_LANG_POP([C++])
 216
 217     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 218     CXXFLAGS=$save_CXXFLAGS
 219
 220     # Work around aliasing bugs - developers should comment this out
 221     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 222
 223     # gcc's builtin memcmp is slower than glibc's
 224     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 225     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 226 fi
 227
 228 dnl even if the compiler appears to support it, using visibility attributes isn't
 229 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 230 case "$host_os" in
 231 cygwin*)
 232     VISIBILITY_CFLAGS=""
 233     VISIBILITY_CXXFLAGS=""
 234     ;;
 235 esac
 236
 237 AC_SUBST([VISIBILITY_CFLAGS])
 238 AC_SUBST([VISIBILITY_CXXFLAGS])
 239
 240 dnl
 241 dnl Optional flags, check for compiler support
 242 dnl
 243 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 244 if test "x$SSE41_SUPPORTED" = x1; then
 245     DEFINES="$DEFINES -DUSE_SSE41"
 246 fi
 247 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 248
 249 dnl Can't have static and shared libraries, default to static if user
 250 dnl explicitly requested. If both disabled, set to static since shared
 251 dnl was explicitly requested.
 252 case "x$enable_static$enable_shared" in
 253 xyesyes)
 254     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 255     enable_shared=no
 256     ;;
 257 xnono)
 258     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 259     enable_shared=yes
 260     ;;
 261 esac
 262
 263 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 264
 265 dnl
 266 dnl other compiler options
 267 dnl
 268 AC_ARG_ENABLE([debug],
 269     [AS_HELP_STRING([--enable-debug],
 270         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 271     [enable_debug="$enableval"],
 272     [enable_debug=no]
 273 )
 274 if test "x$enable_debug" = xyes; then
 275     DEFINES="$DEFINES -DDEBUG"
 276     if test "x$GCC" = xyes; then
 277         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 278             CFLAGS="$CFLAGS -g"
 279         fi
 280         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 281             CFLAGS="$CFLAGS -O0"
 282         fi
 283     fi
 284     if test "x$GXX" = xyes; then
 285         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 286             CXXFLAGS="$CXXFLAGS -g"
 287         fi
 288         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 289             CXXFLAGS="$CXXFLAGS -O0"
 290         fi
 291     fi
 292 fi
 293
 294 dnl
 295 dnl Check if linker supports -Bsymbolic
 296 dnl
 297 save_LDFLAGS=$LDFLAGS
 298 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 299 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 300 AC_LINK_IFELSE(
 301     [AC_LANG_SOURCE([int main() { return 0;}])],
 302     [AC_MSG_RESULT([yes])
 303         BSYMBOLIC="-Wl,-Bsymbolic";],
 304     [AC_MSG_RESULT([no])
 305         BSYMBOLIC="";])
 306 LDFLAGS=$save_LDFLAGS
 307
 308 AC_SUBST([BSYMBOLIC])
 309
 310 dnl
 311 dnl Check if linker supports garbage collection
 312 dnl
 313 save_LDFLAGS=$LDFLAGS
 314 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 315 AC_MSG_CHECKING([whether ld supports --gc-sections])
 316 AC_LINK_IFELSE(
 317     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 318     [AC_MSG_RESULT([yes])
 319         GC_SECTIONS="-Wl,--gc-sections";],
 320     [AC_MSG_RESULT([no])
 321         GC_SECTIONS="";])
 322 LDFLAGS=$save_LDFLAGS
 323
 324 AC_SUBST([GC_SECTIONS])
 325
 326 dnl
 327 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 328 dnl so when these flags are passed to ld via libtool the checks will fail
 329 dnl
 330 case "$host_os" in
 331 openbsd* | darwin* )
 332     LD_NO_UNDEFINED="" ;;
 333 *)
 334     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 335 esac
 336
 337 AC_SUBST([LD_NO_UNDEFINED])
 338
 339 dnl
 340 dnl Check if linker supports version scripts
 341 dnl
 342 AC_MSG_CHECKING([if the linker supports version-scripts])
 343 save_LDFLAGS=$LDFLAGS
 344 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 345 cat > conftest.map <<EOF
 346 VERSION_1 {
 347      global:
 348          main;
 349
 350      local:
 351          *;
 352 };
 353 EOF
 354 AC_LINK_IFELSE(
 355     [AC_LANG_SOURCE([int main() { return 0;}])],
 356     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 357     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 358 LDFLAGS=$save_LDFLAGS
 359 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 360
 361 dnl
 362 dnl Check if linker supports dynamic list files
 363 dnl
 364 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 365 save_LDFLAGS=$LDFLAGS
 366 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 367 cat > conftest.dyn <<EOF
 368 {
 369         radeon_drm_winsys_create;
 370 };
 371 EOF
 372 AC_LINK_IFELSE(
 373     [AC_LANG_SOURCE([int main() { return 0;}])],
 374     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 375     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 376 LDFLAGS=$save_LDFLAGS
 377 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 378
 379 dnl
 380 dnl compatibility symlinks
 381 dnl
 382 case "$host_os" in
 383 linux* )
 384     HAVE_COMPAT_SYMLINKS=yes ;;
 385 * )
 386     HAVE_COMPAT_SYMLINKS=no ;;
 387 esac
 388
 389 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 390
 391 dnl
 392 dnl library names
 393 dnl
 394 case "$host_os" in
 395 darwin* )
 396     LIB_EXT='dylib' ;;
 397 cygwin* )
 398     LIB_EXT='dll' ;;
 399 aix* )
 400     LIB_EXT='a' ;;
 401 * )
 402     LIB_EXT='so' ;;
 403 esac
 404
 405 AC_SUBST([LIB_EXT])
 406
 407 AC_ARG_WITH([gl-lib-name],
 408   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 409     [specify GL library name @<:@default=GL@:>@])],
 410   [GL_LIB=$withval],
 411   [GL_LIB=GL])
 412 AC_ARG_WITH([osmesa-lib-name],
 413   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 414     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 415   [OSMESA_LIB=$withval],
 416   [OSMESA_LIB=OSMesa])
 417 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 418 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 419
 420 dnl
 421 dnl Mangled Mesa support
 422 dnl
 423 AC_ARG_ENABLE([mangling],
 424   [AS_HELP_STRING([--enable-mangling],
 425     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 426   [enable_mangling="${enableval}"],
 427   [enable_mangling=no]
 428 )
 429 if test "x${enable_mangling}" = "xyes" ; then
 430   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 431   GL_LIB="Mangled${GL_LIB}"
 432   OSMESA_LIB="Mangled${OSMESA_LIB}"
 433 fi
 434 AC_SUBST([GL_LIB])
 435 AC_SUBST([OSMESA_LIB])
 436
 437 dnl
 438 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 439 dnl
 440 AC_ARG_ENABLE([texture-float],
 441     [AS_HELP_STRING([--enable-texture-float],
 442         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 443     [enable_texture_float="$enableval"],
 444     [enable_texture_float=no]
 445 )
 446 if test "x$enable_texture_float" = xyes; then
 447     AC_MSG_WARN([Floating-point textures enabled.])
 448     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 449     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 450 fi
 451
 452 dnl
 453 dnl Arch/platform-specific settings
 454 dnl
 455 AC_ARG_ENABLE([asm],
 456     [AS_HELP_STRING([--disable-asm],
 457         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 458     [enable_asm="$enableval"],
 459     [enable_asm=yes]
 460 )
 461 asm_arch=""
 462 AC_MSG_CHECKING([whether to enable assembly])
 463 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 464 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 465 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 466     case "$host_cpu" in
 467     i?86 | x86_64 | amd64)
 468         enable_asm=no
 469         AC_MSG_RESULT([no, cross compiling])
 470         ;;
 471     esac
 472 fi
 473 # check for supported arches
 474 if test "x$enable_asm" = xyes; then
 475     case "$host_cpu" in
 476     i?86)
 477         case "$host_os" in
 478         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 479             asm_arch=x86
 480             ;;
 481         esac
 482         ;;
 483     x86_64|amd64)
 484         case "$host_os" in
 485         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 486             asm_arch=x86_64
 487             ;;
 488         esac
 489         ;;
 490     sparc*)
 491         case "$host_os" in
 492         linux*)
 493             asm_arch=sparc
 494             ;;
 495         esac
 496         ;;
 497     esac
 498
 499     case "$asm_arch" in
 500     x86)
 501         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 502         AC_MSG_RESULT([yes, x86])
 503         ;;
 504     x86_64|amd64)
 505         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 506         AC_MSG_RESULT([yes, x86_64])
 507         ;;
 508     sparc)
 509         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 510         AC_MSG_RESULT([yes, sparc])
 511         ;;
 512     *)
 513         AC_MSG_RESULT([no, platform not supported])
 514         ;;
 515     esac
 516 fi
 517
 518 dnl Check to see if dlopen is in default libraries (like Solaris, which
 519 dnl has it in libc), or if libdl is needed to get it.
 520 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 521     [AC_CHECK_LIB([dl], [dlopen],
 522        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 523 AC_SUBST([DLOPEN_LIBS])
 524
 525 dnl Check if that library also has dladdr
 526 save_LIBS="$LIBS"
 527 LIBS="$LIBS $DLOPEN_LIBS"
 528 AC_CHECK_FUNCS([dladdr])
 529 LIBS="$save_LIBS"
 530
 531 case "$host_os" in
 532 darwin*|mingw*)
 533     ;;
 534 *)
 535     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 536                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 537                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 538     AC_SUBST([CLOCK_LIB])
 539     ;;
 540 esac
 541
 542 dnl See if posix_memalign is available
 543 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 544
 545 dnl Check for pthreads
 546 case "$host_os" in
 547 mingw*)
 548     ;;
 549 *)
 550     AX_PTHREAD
 551     ;;
 552 esac
 553 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 554 dnl to -pthread, which causes problems if we need -lpthread to appear in
 555 dnl pkgconfig files.
 556 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 557
 558 dnl SELinux awareness.
 559 AC_ARG_ENABLE([selinux],
 560     [AS_HELP_STRING([--enable-selinux],
 561         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 562     [MESA_SELINUX="$enableval"],
 563     [MESA_SELINUX=no])
 564 if test "x$enable_selinux" = "xyes"; then
 565     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 566         [AC_CHECK_HEADER([selinux/selinux.h],[],
 567                          [AC_MSG_ERROR([SELinux headers not found])])
 568          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 569                       [AC_MSG_ERROR([SELinux library not found])])
 570          SELINUX_LIBS="-lselinux"])
 571     DEFINES="$DEFINES -DMESA_SELINUX"
 572 fi
 573 AC_SUBST([SELINUX_CFLAGS])
 574 AC_SUBST([SELINUX_LIBS])
 575
 576 dnl Options for APIs
 577 AC_ARG_ENABLE([opengl],
 578     [AS_HELP_STRING([--disable-opengl],
 579         [disable support for standard OpenGL API @<:@default=no@:>@])],
 580     [enable_opengl="$enableval"],
 581     [enable_opengl=yes])
 582 AC_ARG_ENABLE([gles1],
 583     [AS_HELP_STRING([--enable-gles1],
 584         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 585     [enable_gles1="$enableval"],
 586     [enable_gles1=no])
 587 AC_ARG_ENABLE([gles2],
 588     [AS_HELP_STRING([--enable-gles2],
 589         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 590     [enable_gles2="$enableval"],
 591     [enable_gles2=no])
 592 AC_ARG_ENABLE([openvg],
 593     [AS_HELP_STRING([--enable-openvg],
 594         [enable support for OpenVG API @<:@default=no@:>@])],
 595     [enable_openvg="$enableval"],
 596     [enable_openvg=no])
 597
 598 AC_ARG_ENABLE([dri],
 599     [AS_HELP_STRING([--enable-dri],
 600         [enable DRI modules @<:@default=enabled@:>@])],
 601     [enable_dri="$enableval"],
 602     [enable_dri=yes])
 603
 604 case "$host_os" in
 605 linux*)
 606     dri3_default=yes
 607     ;;
 608 *)
 609     dri3_default=no
 610     ;;
 611 esac
 612 AC_ARG_ENABLE([dri3],
 613     [AS_HELP_STRING([--enable-dri3],
 614         [enable DRI3 @<:@default=auto@:>@])],
 615     [enable_dri3="$enableval"],
 616     [enable_dri3="$dri3_default"])
 617 AC_ARG_ENABLE([glx],
 618     [AS_HELP_STRING([--enable-glx],
 619         [enable GLX library @<:@default=enabled@:>@])],
 620     [enable_glx="$enableval"],
 621     [enable_glx=yes])
 622 AC_ARG_ENABLE([osmesa],
 623     [AS_HELP_STRING([--enable-osmesa],
 624         [enable OSMesa library @<:@default=disabled@:>@])],
 625     [enable_osmesa="$enableval"],
 626     [enable_osmesa=no])
 627 AC_ARG_ENABLE([gallium-osmesa],
 628     [AS_HELP_STRING([--enable-gallium-osmesa],
 629         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 630     [enable_gallium_osmesa="$enableval"],
 631     [enable_gallium_osmesa=no])
 632 AC_ARG_ENABLE([egl],
 633     [AS_HELP_STRING([--disable-egl],
 634         [disable EGL library @<:@default=enabled@:>@])],
 635     [enable_egl="$enableval"],
 636     [enable_egl=yes])
 637
 638 AC_ARG_ENABLE([xa],
 639     [AS_HELP_STRING([--enable-xa],
 640         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 641     [enable_xa="$enableval"],
 642     [enable_xa=no])
 643 AC_ARG_ENABLE([gbm],
 644    [AS_HELP_STRING([--enable-gbm],
 645          [enable gbm library @<:@default=auto@:>@])],
 646    [enable_gbm="$enableval"],
 647    [enable_gbm=auto])
 648
 649 AC_ARG_ENABLE([xvmc],
 650    [AS_HELP_STRING([--enable-xvmc],
 651          [enable xvmc library @<:@default=auto@:>@])],
 652    [enable_xvmc="$enableval"],
 653    [enable_xvmc=auto])
 654 AC_ARG_ENABLE([vdpau],
 655    [AS_HELP_STRING([--enable-vdpau],
 656          [enable vdpau library @<:@default=auto@:>@])],
 657    [enable_vdpau="$enableval"],
 658    [enable_vdpau=auto])
 659 AC_ARG_ENABLE([omx],
 660    [AS_HELP_STRING([--enable-omx],
 661          [enable OpenMAX library @<:@default=no@:>@])],
 662    [enable_omx="$enableval"],
 663    [enable_omx=no])
 664 AC_ARG_ENABLE([opencl],
 665    [AS_HELP_STRING([--enable-opencl],
 666          [enable OpenCL library @<:@default=no@:>@])],
 667    [enable_opencl="$enableval"],
 668    [enable_opencl=no])
 669 AC_ARG_ENABLE([opencl_icd],
 670    [AS_HELP_STRING([--enable-opencl-icd],
 671           [Build an OpenCL ICD library to be loaded by an ICD implementation
 672            @<:@default=no@:>@])],
 673     [enable_opencl_icd="$enableval"],
 674     [enable_opencl_icd=no])
 675 AC_ARG_ENABLE([xlib-glx],
 676     [AS_HELP_STRING([--enable-xlib-glx],
 677         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 678     [enable_xlib_glx="$enableval"],
 679     [enable_xlib_glx=no])
 680 AC_ARG_ENABLE([gallium-egl],
 681     [AS_HELP_STRING([--enable-gallium-egl],
 682         [enable optional EGL state tracker (not required
 683          for EGL support in Gallium with OpenGL and OpenGL ES)
 684          @<:@default=disable@:>@])],
 685     [enable_gallium_egl="$enableval"],
 686     [enable_gallium_egl=no])
 687 AC_ARG_ENABLE([gallium-gbm],
 688     [AS_HELP_STRING([--enable-gallium-gbm],
 689         [enable optional gbm state tracker (not required for
 690          gbm support in Gallium)
 691          @<:@default=auto@:>@])],
 692     [enable_gallium_gbm="$enableval"],
 693     [enable_gallium_gbm=auto])
 694
 695 AC_ARG_ENABLE([r600-llvm-compiler],
 696     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 697         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 698     [enable_r600_llvm="$enableval"],
 699     [enable_r600_llvm=no])
 700
 701 AC_ARG_ENABLE([gallium-tests],
 702     [AS_HELP_STRING([--enable-gallium-tests],
 703         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 704     [enable_gallium_tests="$enableval"],
 705     [enable_gallium_tests=no])
 706
 707 # Option for Gallium drivers
 708
 709 # Keep this in sync with the --with-gallium-drivers help string default value
 710 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 711
 712 AC_ARG_WITH([gallium-drivers],
 713     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 714         [comma delimited Gallium drivers list, e.g.
 715         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 716         @<:@default=r300,r600,svga,swrast@:>@])],
 717     [with_gallium_drivers="$withval"],
 718     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 719
 720 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 721 # here so that the script doesn't choke on an unknown driver name later.
 722 case "$with_gallium_drivers" in
 723     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 724     no) with_gallium_drivers='' ;;
 725 esac
 726
 727 if test "x$enable_opengl" = xno -a \
 728         "x$enable_gles1" = xno -a \
 729         "x$enable_gles2" = xno -a \
 730         "x$enable_openvg" = xno -a \
 731         "x$enable_xa" = xno -a \
 732         "x$enable_xvmc" = xno -a \
 733         "x$enable_vdpau" = xno -a \
 734         "x$enable_omx" = xno -a \
 735         "x$enable_opencl" = xno; then
 736     AC_MSG_ERROR([at least one API should be enabled])
 737 fi
 738
 739 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 740 if test "x$enable_opengl" = xno -a \
 741         "x$enable_gles1" = xyes; then
 742     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 743 fi
 744
 745 if test "x$enable_opengl" = xno -a \
 746         "x$enable_gles2" = xyes; then
 747     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 748 fi
 749
 750 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 751 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 752 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 753 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 754                                         "x$enable_gles1" = xyes -o \
 755                                         "x$enable_gles2" = xyes)
 756
 757 if test "x$enable_glx" = xno; then
 758     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 759     enable_xlib_glx=no
 760 fi
 761
 762 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 763     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 764 fi
 765
 766 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 767     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 768 fi
 769
 770 # Disable GLX if OpenGL is not enabled
 771 if test "x$enable_glx$enable_opengl" = xyesno; then
 772     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 773     enable_glx=no
 774 fi
 775
 776 # Disable GLX if DRI and Xlib-GLX are not enabled
 777 if test "x$enable_glx" = xyes -a \
 778         "x$enable_dri" = xno -a \
 779         "x$enable_xlib_glx" = xno; then
 780     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 781     enable_glx=no
 782 fi
 783
 784 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 785                                   "x$enable_dri" = xyes)
 786
 787 # Select which platform-dependent DRI code gets built
 788 case "$host_os" in
 789 darwin*)
 790     dri_platform='apple' ;;
 791 gnu*|mingw*|cygwin*)
 792     dri_platform='none' ;;
 793 *)
 794     dri_platform='drm' ;;
 795 esac
 796
 797 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 798 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 799 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 800 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 801 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 802
 803 AC_ARG_ENABLE([shared-glapi],
 804     [AS_HELP_STRING([--enable-shared-glapi],
 805         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 806     [enable_shared_glapi="$enableval"],
 807     [enable_shared_glapi=yes])
 808
 809 case "x$enable_opengl$enable_gles1$enable_gles2" in
 810 x*yes*yes*)
 811     if test "x$enable_shared_glapi" = xno; then
 812         AC_MSG_ERROR([shared GLAPI required when building two or more of
 813                       the following APIs - opengl, gles1 gles2])
 814     fi
 815     ;;
 816 esac
 817
 818 # Building Xlib-GLX requires shared glapi to be disabled.
 819 if test "x$enable_xlib_glx" = xyes; then
 820     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 821     enable_shared_glapi=no
 822 fi
 823
 824 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 825
 826 # Build the pipe-drivers as separate libraries/modules.
 827 # Do not touch this unless you know what you are doing.
 828 # XXX: Expose via configure option ?
 829 enable_shared_pipe_drivers=no
 830
 831 dnl
 832 dnl Driver specific build directories
 833 dnl
 834 GALLIUM_TARGET_DIRS=""
 835 GALLIUM_WINSYS_DIRS="sw"
 836 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 837 GALLIUM_STATE_TRACKERS_DIRS=""
 838
 839 case "x$enable_glx$enable_xlib_glx" in
 840 xyesyes)
 841     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 842     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 843     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 844     NEED_WINSYS_XLIB="yes"
 845     ;;
 846 esac
 847
 848 if test "x$enable_dri" = xyes; then
 849     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 850     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 851     enable_gallium_loader="$enable_shared_pipe_drivers"
 852 fi
 853
 854 if test "x$enable_gallium_osmesa" = xyes; then
 855     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 856         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 857     fi
 858     if test "x$enable_osmesa" = xyes; then
 859         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 860     fi
 861     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 862     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 863 fi
 864
 865 AC_SUBST([MESA_LLVM])
 866
 867 # Check for libdrm
 868 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 869                   [have_libdrm=yes], [have_libdrm=no])
 870 if test "x$have_libdrm" = xyes; then
 871         DEFINES="$DEFINES -DHAVE_LIBDRM"
 872 fi
 873
 874 case "$host_os" in
 875 linux*)
 876     need_pci_id=yes ;;
 877 *)
 878     need_pci_id=no ;;
 879 esac
 880
 881 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 882                   have_libudev=yes, have_libudev=no)
 883
 884 AC_ARG_ENABLE([sysfs],
 885     [AS_HELP_STRING([--enable-sysfs],
 886         [enable /sys PCI identification @<:@default=disabled@:>@])],
 887     [have_sysfs="$enableval"],
 888     [have_sysfs=no]
 889 )
 890
 891 if test "x$enable_dri" = xyes; then
 892     if test "$enable_static" = yes; then
 893         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 894     fi
 895
 896     # not a hard requirement as swrast does not depend on it
 897     if test "x$have_libdrm" = xyes; then
 898         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 899     fi
 900 fi
 901
 902 AC_ARG_ENABLE([driglx-direct],
 903     [AS_HELP_STRING([--disable-driglx-direct],
 904         [disable direct rendering in GLX and EGL for DRI \
 905             @<:@default=auto@:>@])],
 906     [driglx_direct="$enableval"],
 907     [driglx_direct="yes"])
 908
 909 dnl
 910 dnl libGL configuration per driver
 911 dnl
 912 case "x$enable_glx$enable_xlib_glx" in
 913 xyesyes)
 914     # Xlib-based GLX
 915     dri_modules="x11 xext xcb"
 916     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
 917     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 918     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 919     GL_LIB_DEPS="$XLIBGL_LIBS"
 920     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 921     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 922     ;;
 923 xyesno)
 924     # DRI-based GLX
 925     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 926
 927     # find the DRI deps for libGL
 928     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
 929
 930     if test x"$driglx_direct" = xyes; then
 931         if test x"$dri_platform" = xdrm ; then
 932             DEFINES="$DEFINES -DGLX_USE_DRM"
 933             if test "x$have_libdrm" != xyes; then
 934                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 935             fi
 936
 937             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 938             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 939             if test x"$enable_dri3" = xyes; then
 940                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 941                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 942             fi
 943
 944             if test x"$enable_dri" = xyes; then
 945                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 946             fi
 947
 948             if test x"$enable_dri3" = xyes; then
 949                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
 950                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 951             fi
 952         fi
 953         if test x"$dri_platform" = xapple ; then
 954             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 955         fi
 956     fi
 957
 958     # add xf86vidmode if available
 959     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 960     if test "$HAVE_XF86VIDMODE" = yes ; then
 961         dri_modules="$dri_modules xxf86vm"
 962     fi
 963
 964     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 965     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 966     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 967     GL_LIB_DEPS="$DRIGL_LIBS"
 968
 969     # need DRM libs, $PTHREAD_LIBS, etc.
 970     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 971     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 972     ;;
 973 esac
 974
 975 have_pci_id=no
 976 if test "$have_libudev" = yes; then
 977     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 978     have_pci_id=yes
 979 fi
 980
 981 if test "$have_sysfs" = yes; then
 982     DEFINES="$DEFINES -DHAVE_SYSFS"
 983     have_pci_id=yes
 984 fi
 985
 986 # This is outside the case (above) so that it is invoked even for non-GLX
 987 # builds.
 988 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 989
 990 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 991 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 992 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 993 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 994
 995 AC_SUBST([X11_INCLUDES])
 996 AC_SUBST([GL_LIB_DEPS])
 997 AC_SUBST([GL_PC_REQ_PRIV])
 998 AC_SUBST([GL_PC_LIB_PRIV])
 999 AC_SUBST([GL_PC_CFLAGS])
1000 AC_SUBST([DRI_PC_REQ_PRIV])
1001 AC_SUBST([GLESv1_CM_LIB_DEPS])
1002 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1003 AC_SUBST([GLESv2_LIB_DEPS])
1004 AC_SUBST([GLESv2_PC_LIB_PRIV])
1005
1006 AC_SUBST([HAVE_XF86VIDMODE])
1007
1008 dnl
1009 dnl More GLX setup
1010 dnl
1011 case "x$enable_glx$enable_xlib_glx" in
1012 xyesyes)
1013     DEFINES="$DEFINES -DUSE_XSHM"
1014     ;;
1015 xyesno)
1016     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1017     if test "x$driglx_direct" = xyes; then
1018         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1019     fi
1020     ;;
1021 esac
1022
1023 dnl
1024 dnl TLS detection
1025 dnl
1026
1027 AC_ARG_ENABLE([glx-tls],
1028     [AS_HELP_STRING([--enable-glx-tls],
1029         [enable TLS support in GLX @<:@default=disabled@:>@])],
1030     [GLX_USE_TLS="$enableval"],
1031     [GLX_USE_TLS=no])
1032 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1033
1034 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1035       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1036
1037 dnl
1038 dnl More DRI setup
1039 dnl
1040 dnl Directory for DRI drivers
1041 AC_ARG_WITH([dri-driverdir],
1042     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1043         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1044     [DRI_DRIVER_INSTALL_DIR="$withval"],
1045     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1046 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1047 dnl Extra search path for DRI drivers
1048 AC_ARG_WITH([dri-searchpath],
1049     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1050         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1051     [DRI_DRIVER_SEARCH_DIR="$withval"],
1052     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1053 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1054 dnl Which drivers to build - default is chosen by platform
1055 AC_ARG_WITH([dri-drivers],
1056     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1057         [comma delimited classic DRI drivers list, e.g.
1058         "swrast,i965,radeon" @<:@default=auto@:>@])],
1059     [with_dri_drivers="$withval"],
1060     [with_dri_drivers=auto])
1061
1062 if test "x$with_dri_drivers" = xauto; then
1063     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1064         with_dri_drivers="yes"
1065     else
1066         with_dri_drivers="no"
1067     fi
1068 fi
1069 if test "x$with_dri_drivers" = xno; then
1070     with_dri_drivers=''
1071 fi
1072
1073 dnl If $with_dri_drivers is yes, drivers will be added through
1074 dnl platform checks. Set DEFINES and LIB_DEPS
1075 if test "x$enable_dri" = xyes; then
1076     # Platform specific settings and drivers to build
1077     case "$host_os" in
1078     linux*)
1079         DEFINES="$DEFINES -DHAVE_ALIAS"
1080         if test "x$enable_dri3" = xyes; then
1081             DEFINES="$DEFINES -DHAVE_DRI3"
1082         fi
1083
1084         if test "x$have_pci_id" != xyes; then
1085             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1086         fi
1087
1088         case "$host_cpu" in
1089         powerpc* | sparc*)
1090             # Build only the drivers for cards that exist on PowerPC/sparc
1091             if test "x$with_dri_drivers" = "xyes"; then
1092                 with_dri_drivers="r200 radeon swrast"
1093             fi
1094             ;;
1095         esac
1096         ;;
1097     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1098         DEFINES="$DEFINES -DHAVE_PTHREAD"
1099         DEFINES="$DEFINES -DHAVE_ALIAS"
1100         ;;
1101     gnu*)
1102         DEFINES="$DEFINES -DHAVE_ALIAS"
1103         ;;
1104     cygwin*)
1105         if test "x$with_dri_drivers" = "xyes"; then
1106             with_dri_drivers="swrast"
1107         fi
1108         ;;
1109     darwin*)
1110         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1111         if test "x$with_dri_drivers" = "xyes"; then
1112             with_dri_drivers="swrast"
1113         fi
1114         ;;
1115     esac
1116
1117     # default drivers
1118     if test "x$with_dri_drivers" = "xyes"; then
1119         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1120     fi
1121
1122     # Check for expat
1123     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1124     if test "x$have_expat" = "xyes"; then
1125        PKG_CHECK_MODULES([EXPAT], [expat], [],
1126                          AC_MSG_ERROR([Expat required for DRI.]))
1127     else
1128        # expat version 2.0 and earlier do not provide expat.pc
1129        EXPAT_LIBS=-lexpat
1130     fi
1131
1132     DRICOMMON_NEED_LIBDRM=no
1133     # If we are building any DRI driver other than swrast.
1134     if test -n "$with_dri_drivers"; then
1135         if test "x$with_dri_drivers" != xswrast; then
1136             # ... libdrm is required
1137             if test "x$have_libdrm" != xyes; then
1138                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1139             fi
1140             DRICOMMON_NEED_LIBDRM=yes
1141         fi
1142     fi
1143
1144     # If we're building any gallium DRI driver other than swrast
1145     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1146         if test "x$with_gallium_drivers" != xswrast; then
1147             # ... build a libdrm aware dricommon
1148             DRICOMMON_NEED_LIBDRM=yes
1149         fi
1150     fi
1151
1152     # put all the necessary libs together
1153     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1154 fi
1155
1156 AC_SUBST([DRI_LIB_DEPS])
1157
1158 DRI_DIRS=''
1159 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1160 if test -n "$with_dri_drivers"; then
1161     if test "x$enable_opengl" != xyes; then
1162         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1163     fi
1164
1165     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1166     for driver in $dri_drivers; do
1167         DRI_DIRS="$DRI_DIRS $driver"
1168         case "x$driver" in
1169         xi915)
1170             HAVE_I915_DRI=yes;
1171             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1172             ;;
1173         xi965)
1174             HAVE_I965_DRI=yes;
1175             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1176             ;;
1177         xnouveau)
1178             HAVE_NOUVEAU_DRI=yes;
1179             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1180             ;;
1181         xradeon)
1182             HAVE_RADEON_DRI=yes;
1183             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1184             ;;
1185         xr200)
1186             HAVE_R200_DRI=yes;
1187             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1188             ;;
1189         xswrast)
1190             HAVE_SWRAST_DRI=yes;
1191             ;;
1192         *)
1193             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1194             ;;
1195         esac
1196     done
1197     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1198 fi
1199
1200 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1201 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1202                                   "x$enable_osmesa" = xyes -o \
1203                                   -n "$DRI_DIRS")
1204
1205 dnl
1206 dnl OSMesa configuration
1207 dnl
1208
1209 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1210 AC_ARG_WITH([osmesa-bits],
1211     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1212         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1213     [osmesa_bits="$withval"],
1214     [osmesa_bits=8])
1215 if test "x$osmesa_bits" != x8; then
1216     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1217         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1218         osmesa_bits=8
1219     fi
1220 fi
1221 case "x$osmesa_bits" in
1222 x8)
1223     OSMESA_LIB="${OSMESA_LIB}"
1224     ;;
1225 x16|x32)
1226     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1227     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1228     ;;
1229 *)
1230     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1231     ;;
1232 esac
1233
1234 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1235     # only link libraries with osmesa if shared
1236     if test "$enable_static" = no; then
1237         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1238     else
1239         OSMESA_LIB_DEPS=""
1240     fi
1241     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1242 fi
1243
1244 AC_SUBST([OSMESA_LIB_DEPS])
1245 AC_SUBST([OSMESA_PC_REQ])
1246 AC_SUBST([OSMESA_PC_LIB_PRIV])
1247
1248 dnl
1249 dnl gbm configuration
1250 dnl
1251 if test "x$enable_gbm" = xauto; then
1252     case "$with_egl_platforms" in
1253         *drm*)
1254             enable_gbm=yes ;;
1255          *)
1256             enable_gbm=no ;;
1257     esac
1258 fi
1259 if test "x$enable_gbm" = xyes; then
1260     if test "x$need_pci_id$have_pci_id" = xyesno; then
1261         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1262     fi
1263
1264     if test "x$enable_dri" = xyes; then
1265         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1266         if test "x$enable_shared_glapi" = xno; then
1267             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1268         fi
1269     else
1270         # Strictly speaking libgbm does not require --enable-dri, although
1271         # both of its backends do. Thus one can build libgbm without any
1272         # backends if --disable-dri is set.
1273         # To avoid unnecessary complexity of checking if at least one backend
1274         # is available when building, just mandate --enable-dri.
1275         AC_MSG_ERROR([gbm requires --enable-dri])
1276     fi
1277 fi
1278 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1279 if test "x$need_pci_id$have_libudev" = xyesyes; then
1280     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1281 else
1282     GBM_PC_REQ_PRIV=""
1283 fi
1284 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1285 AC_SUBST([GBM_PC_REQ_PRIV])
1286 AC_SUBST([GBM_PC_LIB_PRIV])
1287
1288 dnl
1289 dnl EGL configuration
1290 dnl
1291 EGL_CLIENT_APIS=""
1292
1293 if test "x$enable_egl" = xyes; then
1294     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1295
1296     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1297
1298     if test "$enable_static" != yes; then
1299         if test "x$enable_dri" = xyes; then
1300             HAVE_EGL_DRIVER_DRI2=1
1301         fi
1302
1303     fi
1304 fi
1305 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1306 AC_SUBST([EGL_LIB_DEPS])
1307
1308 dnl
1309 dnl EGL Gallium configuration
1310 dnl
1311 if test "x$enable_gallium_egl" = xyes; then
1312     if test -z "$with_gallium_drivers"; then
1313         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1314     fi
1315     if test "x$enable_egl" = xno; then
1316         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1317     fi
1318     if test "x$have_libdrm" != xyes; then
1319         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1320     fi
1321
1322     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1323     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1324 # XXX: Uncomment once converted to use static/shared pipe-drivers
1325 #    enable_gallium_loader=$enable_shared_pipe_drivers
1326 fi
1327 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1328
1329 dnl
1330 dnl gbm Gallium configuration
1331 dnl
1332 if test "x$enable_gallium_gbm" = xauto; then
1333     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1334         yesyesyes*drm*)
1335             enable_gallium_gbm=yes ;;
1336          *)
1337             enable_gallium_gbm=no ;;
1338     esac
1339 fi
1340 if test "x$enable_gallium_gbm" = xyes; then
1341     if test -z "$with_gallium_drivers"; then
1342         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1343     fi
1344     if test "x$enable_gbm" = xno; then
1345         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1346     fi
1347
1348     if test "x$enable_gallium_egl" != xyes; then
1349         AC_MSG_ERROR([gbm_gallium is only used by egl_gallium])
1350     fi
1351
1352     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1353     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1354     enable_gallium_loader=$enable_shared_pipe_drivers
1355 fi
1356 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1357
1358 dnl
1359 dnl XA configuration
1360 dnl
1361 if test "x$enable_xa" = xyes; then
1362     if test "x$with_gallium_drivers" = xswrast; then
1363        AC_MSG_ERROR([
1364           Building xa requires at least one non swrast gallium driver.
1365           If you are looking to use libxatracker.so with the VMware driver,
1366           make sure to include svga in the gallium drivers list, apart from
1367           enabling XA.
1368           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1369     fi
1370     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1371     enable_gallium_loader=$enable_shared_pipe_drivers
1372 fi
1373 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1374
1375 dnl
1376 dnl OpenVG configuration
1377 dnl
1378 VG_LIB_DEPS=""
1379
1380 if test "x$enable_openvg" = xyes; then
1381     if test "x$enable_egl" = xno; then
1382         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1383     fi
1384     if test -z "$with_gallium_drivers"; then
1385         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1386     fi
1387     if test "x$enable_gallium_egl" = xno; then
1388         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1389     fi
1390
1391     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1392     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1393     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1394     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1395     AC_SUBST([VG_PC_LIB_PRIV])
1396 fi
1397 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1398
1399 dnl
1400 dnl Gallium G3DVL configuration
1401 dnl
1402 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1403     if test "x$enable_xvmc" = xauto; then
1404         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1405     fi
1406
1407     if test "x$enable_vdpau" = xauto; then
1408         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1409     fi
1410
1411     if test "x$enable_omx" = xauto; then
1412         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1413     fi
1414 fi
1415
1416 if test "x$enable_xvmc" = xyes; then
1417     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1418     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1419     enable_gallium_loader=$enable_shared_pipe_drivers
1420 fi
1421 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1422
1423 if test "x$enable_vdpau" = xyes; then
1424     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1425                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb xcb-dri2`"])
1426     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1427     enable_gallium_loader=$enable_shared_pipe_drivers
1428 fi
1429 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1430
1431 if test "x$enable_omx" = xyes; then
1432     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1433     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1434     enable_gallium_loader=$enable_shared_pipe_drivers
1435 fi
1436 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1437
1438 dnl
1439 dnl OpenCL configuration
1440 dnl
1441
1442 AC_ARG_WITH([libclc-path],
1443    [AS_HELP_STRING([--with-libclc-path],
1444          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1445    [LIBCLC_PATH="$withval"],
1446    [LIBCLC_PATH=''])
1447
1448 if test -n "$LIBCLC_PATH"; then
1449    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1450                   Please review the updated build instructions for clover:
1451                   http://dri.freedesktop.org/wiki/GalliumCompute])
1452 fi
1453
1454
1455 AC_ARG_WITH([clang-libdir],
1456    [AS_HELP_STRING([--with-clang-libdir],
1457          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1458    [CLANG_LIBDIR="$withval"],
1459    [CLANG_LIBDIR=''])
1460
1461 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1462
1463 if test "x$enable_opencl" = xyes; then
1464     if test -z "$with_gallium_drivers"; then
1465         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1466     fi
1467
1468     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1469         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1470     fi
1471
1472     if test "x$have_libclc" = xno; then
1473         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1474                     Make sure the directory containing libclc.pc is specified in your
1475                     PKG_CONFIG_PATH environment variable.
1476                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1477     else
1478         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1479         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1480         AC_SUBST([LIBCLC_INCLUDEDIR])
1481         AC_SUBST([LIBCLC_LIBEXECDIR])
1482     fi
1483
1484     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1485     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1486     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1487     enable_gallium_loader=yes
1488
1489     if test "x$enable_opencl_icd" = xyes; then
1490         OPENCL_LIBNAME="MesaOpenCL"
1491     else
1492         OPENCL_LIBNAME="OpenCL"
1493     fi
1494 fi
1495 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1496 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1497 AC_SUBST([OPENCL_LIBNAME])
1498
1499 dnl
1500 dnl Gallium configuration
1501 dnl
1502 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1503
1504 AC_SUBST([LLVM_BINDIR])
1505 AC_SUBST([LLVM_CFLAGS])
1506 AC_SUBST([LLVM_CPPFLAGS])
1507 AC_SUBST([LLVM_CXXFLAGS])
1508 AC_SUBST([LLVM_LIBDIR])
1509 AC_SUBST([LLVM_LIBS])
1510 AC_SUBST([LLVM_LDFLAGS])
1511 AC_SUBST([LLVM_INCLUDEDIR])
1512 AC_SUBST([LLVM_VERSION])
1513 AC_SUBST([CLANG_RESOURCE_DIR])
1514
1515 case "x$enable_opengl$enable_gles1$enable_gles2" in
1516 x*yes*)
1517     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1518     ;;
1519 esac
1520
1521 AC_SUBST([VG_LIB_DEPS])
1522 AC_SUBST([EGL_CLIENT_APIS])
1523
1524 dnl
1525 dnl EGL Platforms configuration
1526 dnl
1527 AC_ARG_WITH([egl-platforms],
1528     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1529         [comma delimited native platforms libEGL supports, e.g.
1530         "x11,drm" @<:@default=auto@:>@])],
1531     [with_egl_platforms="$withval"],
1532     [if test "x$enable_egl" = xyes; then
1533         with_egl_platforms="x11"
1534     else
1535         with_egl_platforms=""
1536     fi])
1537
1538 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1539     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1540 fi
1541
1542 # Do per-EGL platform setups and checks
1543 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1544 for plat in $egl_platforms; do
1545         case "$plat" in
1546         wayland)
1547                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1548                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1549
1550                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1551                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1552                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1553                 ;;
1554
1555         x11)
1556                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1557                 ;;
1558
1559         drm)
1560                 test "x$enable_gbm" = "xno" &&
1561                         AC_MSG_ERROR([EGL platform drm needs gbm])
1562                 test "x$have_libdrm" != xyes &&
1563                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1564                 ;;
1565
1566         android|fbdev|gdi|null)
1567                 ;;
1568
1569         *)
1570                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1571                 ;;
1572         esac
1573
1574         case "$plat$need_pci_id$have_pci_id" in
1575                 waylandyesno|drmyesno)
1576                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1577         esac
1578 done
1579
1580 # libEGL wants to default to the first platform specified in
1581 # ./configure.  parse that here.
1582 if test "x$egl_platforms" != "x"; then
1583     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1584     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1585 else
1586     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1587 fi
1588
1589 if echo "$egl_platforms" | grep -q 'x11'; then
1590     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1591     NEED_WINSYS_XLIB=yes
1592 fi
1593 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1594 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1595 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1596 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1597 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1598
1599 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1600
1601 AC_SUBST([EGL_NATIVE_PLATFORM])
1602 AC_SUBST([EGL_CFLAGS])
1603
1604 # If we don't have the X11 platform, set this define so we don't try to include
1605 # the X11 headers.
1606 if ! echo "$egl_platforms" | grep -q 'x11'; then
1607     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1608     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1609 fi
1610
1611 AC_ARG_WITH([egl-driver-dir],
1612     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1613                     [directory for EGL drivers @<:@default=${libdir}/egl@:>@])],
1614     [EGL_DRIVER_INSTALL_DIR="$withval"],
1615     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1616 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1617
1618 AC_ARG_WITH([max-width],
1619     [AS_HELP_STRING([--with-max-width=N],
1620                     [Maximum framebuffer width (4096)])],
1621     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1622      AS_IF([test "${withval}" -gt "4096"],
1623            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1624 )
1625 AC_ARG_WITH([max-height],
1626     [AS_HELP_STRING([--with-max-height=N],
1627                     [Maximum framebuffer height (4096)])],
1628     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1629      AS_IF([test "${withval}" -gt "4096"],
1630            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1631 )
1632
1633 dnl
1634 dnl Gallium LLVM
1635 dnl
1636 AC_ARG_ENABLE([gallium-llvm],
1637     [AS_HELP_STRING([--enable-gallium-llvm],
1638         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1639     [enable_gallium_llvm="$enableval"],
1640     [enable_gallium_llvm=auto])
1641
1642 AC_ARG_ENABLE([llvm-shared-libs],
1643     [AS_HELP_STRING([--enable-llvm-shared-libs],
1644         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1645     [enable_llvm_shared_libs="$enableval"],
1646     [enable_llvm_shared_libs=yes])
1647
1648 AC_ARG_WITH([llvm-prefix],
1649     [AS_HELP_STRING([--with-llvm-prefix],
1650         [Prefix for LLVM installations in non-standard locations])],
1651     [llvm_prefix="$withval"],
1652     [llvm_prefix=''])
1653
1654
1655 # Call this inside ` ` to get the return value.
1656 # $1 is the llvm-config command with arguments.
1657 strip_unwanted_llvm_flags() {
1658     # Use \> (marks the end of the word)
1659     echo `$1` | sed \
1660         -e 's/-DNDEBUG\>//g' \
1661         -e 's/-D_GNU_SOURCE\>//g' \
1662         -e 's/-pedantic\>//g' \
1663         -e 's/-Wcovered-switch-default\>//g' \
1664         -e 's/-O.\>//g' \
1665         -e 's/-g\>//g' \
1666         -e 's/-Wall\>//g' \
1667         -e 's/-Wcast-qual\>//g' \
1668         -e 's/-Woverloaded-virtual\>//g' \
1669         -e 's/-fcolor-diagnostics\>//g' \
1670         -e 's/-fdata-sections\>//g' \
1671         -e 's/-ffunction-sections\>//g' \
1672         -e 's/-fno-exceptions\>//g' \
1673         -e 's/-fomit-frame-pointer\>//g' \
1674         -e 's/-fvisibility-inlines-hidden\>//g' \
1675         -e 's/-fPIC\>//g' \
1676         -e 's/-fstack-protector-strong\>//g'
1677 }
1678
1679
1680 if test -z "$with_gallium_drivers"; then
1681     enable_gallium_llvm=no
1682 fi
1683 if test "x$enable_gallium_llvm" = xauto; then
1684     case "$host_cpu" in
1685     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1686     esac
1687 fi
1688 if test "x$enable_gallium_llvm" = xyes; then
1689     if test -n "$llvm_prefix"; then
1690         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1691     else
1692         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1693     fi
1694
1695     if test "x$LLVM_CONFIG" != xno; then
1696         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1697         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1698         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1699         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1700         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1701         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1702         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1703         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1704
1705         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1706             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1707         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1708             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1709
1710         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1711         dnl llvm-config.h
1712         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1713             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1714             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1715
1716         if test -n "${LLVM_VERSION_MAJOR}"; then
1717             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1718         else
1719             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1720         fi
1721
1722         LLVM_REQUIRED_VERSION_MAJOR="3"
1723         LLVM_REQUIRED_VERSION_MINOR="1"
1724         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1725             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1726         fi
1727
1728         LLVM_COMPONENTS="engine bitwriter"
1729         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1730             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1731         fi
1732
1733         if test "x$enable_opencl" = xyes; then
1734             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1735             # LLVM 3.3 >= 177971 requires IRReader
1736             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1737                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1738             fi
1739             # LLVM 3.4 requires Option
1740             if $LLVM_CONFIG --components | grep -qw 'option'; then
1741                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1742             fi
1743             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1744             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1745                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1746             fi
1747             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1748                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1749             fi
1750         fi
1751         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1752         MESA_LLVM=1
1753
1754         dnl Check for Clang internal headers
1755         if test "x$enable_opencl" = xyes; then
1756             if test -z "$CLANG_LIBDIR"; then
1757                 CLANG_LIBDIR=${LLVM_LIBDIR}
1758             fi
1759             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1760             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1761                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1762         fi
1763     else
1764         MESA_LLVM=0
1765         LLVM_VERSION_INT=0
1766     fi
1767 else
1768     MESA_LLVM=0
1769     LLVM_VERSION_INT=0
1770
1771     if test "x$enable_opencl" = xyes; then
1772         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1773     fi
1774 fi
1775
1776 dnl Directory for XVMC libs
1777 AC_ARG_WITH([xvmc-libdir],
1778     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1779         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1780     [XVMC_LIB_INSTALL_DIR="$withval"],
1781     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1782 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1783
1784 dnl
1785 dnl Gallium Tests
1786 dnl
1787 if test "x$enable_gallium_tests" = xyes; then
1788     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1789     enable_gallium_loader=yes
1790 fi
1791 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1792
1793 if test "x$enable_gallium_loader" = xyes; then
1794     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1795 fi
1796
1797 dnl Directory for VDPAU libs
1798 AC_ARG_WITH([vdpau-libdir],
1799     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1800         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1801     [VDPAU_LIB_INSTALL_DIR="$withval"],
1802     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1803 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1804
1805 OMX_LIB_INSTALL_DIR_DEFAULT=''
1806 if test "x$enable_omx" = xyes; then
1807     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1808 fi
1809
1810 AC_ARG_WITH([omx-libdir],
1811     [AS_HELP_STRING([--with-omx-libdir=DIR],
1812         [directory for the OMX libraries])],
1813     [OMX_LIB_INSTALL_DIR="$withval"],
1814     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1815 AC_SUBST([OMX_LIB_INSTALL_DIR])
1816
1817 dnl Directory for OpenCL libs
1818 AC_ARG_WITH([opencl-libdir],
1819     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1820         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1821     [OPENCL_LIB_INSTALL_DIR="$withval"],
1822     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1823 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1824
1825 dnl
1826 dnl Gallium helper functions
1827 dnl
1828 gallium_check_st() {
1829     if test "x$have_libdrm" != xyes; then
1830        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1831     fi
1832     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $2"
1833
1834     if test "x$enable_dri" = xyes && test -n "$3"; then
1835          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1836     fi
1837     if test "x$enable_xa" = xyes && test -n "$4"; then
1838          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1839     fi
1840     if test "x$enable_xvmc" = xyes && test -n "$5"; then
1841          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1842     fi
1843     if test "x$enable_vdpau" = xyes && test -n "$6"; then
1844          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1845     fi
1846     if test "x$enable_omx" = xyes && test "x$7" != x; then
1847          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1848     fi
1849 }
1850
1851 gallium_require_llvm() {
1852     if test "x$MESA_LLVM" = x0; then
1853         case "$host" in *gnux32) return;; esac
1854         case "$host_cpu" in
1855         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1856         esac
1857     fi
1858 }
1859
1860 gallium_require_drm_loader() {
1861     if test "x$enable_gallium_loader" = xyes; then
1862         if test "x$need_pci_id$have_pci_id" = xyesno; then
1863             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1864         fi
1865         if test "x$have_libdrm" != xyes; then
1866             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1867         fi
1868         enable_gallium_drm_loader=yes
1869     fi
1870 }
1871
1872 require_egl_drm() {
1873     case "$with_egl_platforms" in
1874         *drm*)
1875             ;;
1876          *)
1877             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1878             ;;
1879     esac
1880     if test "x$enable_gbm" != xyes; then
1881             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1882     fi
1883 }
1884
1885 radeon_llvm_check() {
1886     if test "x$enable_gallium_llvm" != "xyes"; then
1887         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1888     fi
1889     LLVM_REQUIRED_VERSION_MAJOR="3"
1890     LLVM_REQUIRED_VERSION_MINOR="4"
1891     LLVM_REQUIRED_VERSION_PATCH="2"
1892     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1893         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1894     fi
1895     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1896         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1897                       sources with the --enable-experimental-targets=R600
1898                       configure flag])
1899     fi
1900     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1901     NEED_RADEON_LLVM=yes
1902     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1903                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1904 }
1905
1906 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1907 if test -n "$with_gallium_drivers"; then
1908     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1909     for driver in $gallium_drivers; do
1910         case "x$driver" in
1911         xsvga)
1912             HAVE_GALLIUM_SVGA=yes
1913             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1914             gallium_require_drm_loader
1915             gallium_check_st "svga" "svga/drm" "dri/vmwgfx" "xa/vmwgfx"
1916             ;;
1917         xi915)
1918             HAVE_GALLIUM_I915=yes
1919             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1920             gallium_require_drm_loader
1921             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1922             gallium_check_st "Gallium i915" "i915/drm" "dri/i915" "xa/i915"
1923             ;;
1924         xilo)
1925             HAVE_GALLIUM_ILO=yes
1926             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1927             gallium_require_drm_loader
1928             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1929             gallium_check_st "Gallium i965/ilo" "intel/drm" "dri/ilo" "xa/ilo"
1930             ;;
1931         xr300)
1932             HAVE_GALLIUM_R300=yes
1933             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1934             gallium_require_drm_loader
1935             gallium_require_llvm "Gallium R300"
1936             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1937             gallium_check_st "Gallium R300" "radeon/drm" "dri/r300"
1938             ;;
1939         xr600)
1940             HAVE_GALLIUM_R600=yes
1941             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1942             gallium_require_drm_loader
1943             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1944             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1945                 radeon_llvm_check "r600g"
1946                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1947             fi
1948             if test "x$enable_r600_llvm" = xyes; then
1949                 USE_R600_LLVM_COMPILER=yes;
1950             fi
1951             if test "x$enable_opencl" = xyes; then
1952                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1953             fi
1954             gallium_check_st "Gallium R600" "radeon/drm" "dri/r600" "" "xvmc/r600" "vdpau/r600" "omx/r600"
1955             ;;
1956         xradeonsi)
1957             HAVE_GALLIUM_RADEONSI=yes
1958             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1959             gallium_require_drm_loader
1960             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1961             radeon_llvm_check "radeonsi"
1962             require_egl_drm "radeonsi"
1963             gallium_check_st "radeonsi" "radeon/drm" "dri/radeonsi" "" "" "vdpau/radeonsi" "omx/radeonsi"
1964             ;;
1965         xnouveau)
1966             HAVE_GALLIUM_NOUVEAU=yes
1967             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1968             gallium_require_drm_loader
1969             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1970             gallium_check_st "nouveau" "nouveau/drm" "dri/nouveau" "xa/nouveau" "xvmc/nouveau" "vdpau/nouveau" "omx/nouveau"
1971             ;;
1972         xfreedreno)
1973             HAVE_GALLIUM_FREEDRENO=yes
1974             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1975             gallium_require_drm_loader
1976             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1977             gallium_check_st "freedreno" "freedreno/drm" "dri/freedreno" "xa/freedreno" "" ""
1978             ;;
1979         xswrast)
1980             HAVE_GALLIUM_SOFTPIPE=yes
1981             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1982             if test "x$MESA_LLVM" = x1; then
1983                 HAVE_GALLIUM_LLVMPIPE=yes
1984                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1985             fi
1986
1987             if test "x$enable_dri" = xyes; then
1988                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/swrast"
1989             fi
1990
1991             if test "x$have_libdrm" = xyes; then
1992                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/kms-dri"
1993                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/kms-swrast"
1994             fi
1995             ;;
1996         xvc4)
1997             HAVE_GALLIUM_VC4=yes
1998             gallium_require_drm_loader
1999             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS vc4"
2000             gallium_check_st "vc4" "vc4/drm" "dri-vc4" "" "" ""
2001
2002             case "$host_cpu" in
2003                 i?86 | x86_64 | amd64)
2004                 USE_VC4_SIMULATOR=yes
2005                 ;;
2006             esac
2007             ;;
2008         *)
2009             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2010             ;;
2011         esac
2012     done
2013 fi
2014
2015 dnl Set LLVM_LIBS - This is done after the driver configuration so
2016 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2017 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2018 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2019 dnl this was causing the same libraries to be appear multiple times
2020 dnl in LLVM_LIBS.
2021
2022 if test "x$MESA_LLVM" != x0; then
2023
2024     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2025
2026     if test "x$enable_llvm_shared_libs" = xyes; then
2027         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2028         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2029         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2030
2031         if test "x$llvm_have_one_so" = xyes; then
2032             dnl LLVM was built using auto*, so there is only one shared object.
2033             LLVM_LIBS="-l$LLVM_SO_NAME"
2034         else
2035             dnl If LLVM was built with CMake, there will be one shared object per
2036             dnl component.
2037             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2038                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2039         Please make sure you have built llvm with the --enable-shared option
2040         and that your llvm libraries are installed in $LLVM_LIBDIR
2041         If you have installed your llvm libraries to a different directory you
2042         can use the --with-llvm-prefix= configure flag to specify this directory.
2043         NOTE: Mesa is attempting to use llvm shared libraries by default.
2044         If you do not want to build with llvm shared libraries and instead want to
2045         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2046         invocation and rebuild.])])
2047
2048            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2049            dnl install uses a shared object for each compoenent and we have
2050            dnl already added all of these objects to LLVM_LIBS.
2051         fi
2052     else
2053         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2054     fi
2055 fi
2056
2057 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2058 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2059 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2060 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2061 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2062 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2063 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2064                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2065 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2066 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2067 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2068 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2069 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2070
2071 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2072                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2073 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2074                                                   && test "x$MESA_LLVM" = x1)
2075
2076 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2077
2078 # NOTE: anything using xcb or other client side libs ends up in separate
2079 #       _CLIENT variables.  The pipe loader is built in two variants,
2080 #       one that is standalone and does not link any x client libs (for
2081 #       use by XA tracker in particular, but could be used in any case
2082 #       where communication with xserver is not desired).
2083 if test "x$enable_gallium_loader" = xyes; then
2084     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2085
2086     if test "x$NEED_WINSYS_XLIB" = xyes; then
2087         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2088     fi
2089
2090     if test "x$enable_dri" = xyes; then
2091         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2092     fi
2093
2094     if test "x$enable_gallium_drm_loader" = xyes; then
2095         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2096         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2097                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2098         if test "x$pipe_loader_have_xcb" = xyes; then
2099             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2100             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2101         fi
2102     fi
2103
2104     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2105     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2106
2107     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2108     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2109     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2110     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2111 fi
2112
2113 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2114 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2115 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2116 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2117 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2118 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2119
2120 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2121                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2122                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2123 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2124 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2125 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2126 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2127 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2128 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2129 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2130 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2131 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2132     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2133 fi
2134
2135 AC_SUBST([ELF_LIB])
2136
2137 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2138 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2139 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2140 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2141 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2142
2143 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2144 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2145 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2146
2147 AC_SUBST([VDPAU_MAJOR], 1)
2148 AC_SUBST([VDPAU_MINOR], 0)
2149
2150 AC_SUBST([XVMC_MAJOR], 1)
2151 AC_SUBST([XVMC_MINOR], 0)
2152
2153 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2154 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2155 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2156 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2157
2158 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2159 AC_SUBST([XA_MINOR], $XA_MINOR)
2160 AC_SUBST([XA_TINY], $XA_TINY)
2161 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2162
2163 dnl Restore LDFLAGS and CPPFLAGS
2164 LDFLAGS="$_SAVE_LDFLAGS"
2165 CPPFLAGS="$_SAVE_CPPFLAGS"
2166
2167 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2168 if test "x$acv_mesa_CLANG" = xyes; then
2169     CFLAGS="$CFLAGS -Qunused-arguments"
2170     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2171 fi
2172
2173 dnl Add user CFLAGS and CXXFLAGS
2174 CFLAGS="$CFLAGS $USER_CFLAGS"
2175 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2176
2177 dnl Substitute the config
2178 AC_CONFIG_FILES([Makefile
2179                 src/Makefile
2180                 src/egl/drivers/dri2/Makefile
2181                 src/egl/main/Makefile
2182                 src/egl/main/egl.pc
2183                 src/egl/wayland/Makefile
2184                 src/egl/wayland/wayland-drm/Makefile
2185                 src/egl/wayland/wayland-egl/Makefile
2186                 src/egl/wayland/wayland-egl/wayland-egl.pc
2187                 src/gallium/Makefile
2188                 src/gallium/auxiliary/Makefile
2189                 src/gallium/auxiliary/pipe-loader/Makefile
2190                 src/gallium/drivers/freedreno/Makefile
2191                 src/gallium/drivers/galahad/Makefile
2192                 src/gallium/drivers/i915/Makefile
2193                 src/gallium/drivers/identity/Makefile
2194                 src/gallium/drivers/ilo/Makefile
2195                 src/gallium/drivers/llvmpipe/Makefile
2196                 src/gallium/drivers/noop/Makefile
2197                 src/gallium/drivers/nouveau/Makefile
2198                 src/gallium/drivers/r300/Makefile
2199                 src/gallium/drivers/r600/Makefile
2200                 src/gallium/drivers/radeon/Makefile
2201                 src/gallium/drivers/radeonsi/Makefile
2202                 src/gallium/drivers/rbug/Makefile
2203                 src/gallium/drivers/softpipe/Makefile
2204                 src/gallium/drivers/svga/Makefile
2205                 src/gallium/drivers/trace/Makefile
2206                 src/gallium/drivers/vc4/Makefile
2207                 src/gallium/state_trackers/clover/Makefile
2208                 src/gallium/state_trackers/dri/Makefile
2209                 src/gallium/state_trackers/egl/Makefile
2210                 src/gallium/state_trackers/gbm/Makefile
2211                 src/gallium/state_trackers/glx/xlib/Makefile
2212                 src/gallium/state_trackers/omx/Makefile
2213                 src/gallium/state_trackers/osmesa/Makefile
2214                 src/gallium/state_trackers/vdpau/Makefile
2215                 src/gallium/state_trackers/vega/Makefile
2216                 src/gallium/state_trackers/xa/Makefile
2217                 src/gallium/state_trackers/xvmc/Makefile
2218                 src/gallium/targets/dri/Makefile
2219                 src/gallium/targets/egl-static/Makefile
2220                 src/gallium/targets/gbm/Makefile
2221                 src/gallium/targets/libgl-xlib/Makefile
2222                 src/gallium/targets/omx/Makefile
2223                 src/gallium/targets/opencl/Makefile
2224                 src/gallium/targets/osmesa/Makefile
2225                 src/gallium/targets/osmesa/osmesa.pc
2226                 src/gallium/targets/pipe-loader/Makefile
2227                 src/gallium/targets/vdpau/Makefile
2228                 src/gallium/targets/xa/Makefile
2229                 src/gallium/targets/xa/xatracker.pc
2230                 src/gallium/targets/xvmc/Makefile
2231                 src/gallium/tests/trivial/Makefile
2232                 src/gallium/tests/unit/Makefile
2233                 src/gallium/winsys/freedreno/drm/Makefile
2234                 src/gallium/winsys/i915/drm/Makefile
2235                 src/gallium/winsys/intel/drm/Makefile
2236                 src/gallium/winsys/nouveau/drm/Makefile
2237                 src/gallium/winsys/radeon/drm/Makefile
2238                 src/gallium/winsys/svga/drm/Makefile
2239                 src/gallium/winsys/sw/dri/Makefile
2240                 src/gallium/winsys/sw/fbdev/Makefile
2241                 src/gallium/winsys/sw/kms-dri/Makefile
2242                 src/gallium/winsys/sw/null/Makefile
2243                 src/gallium/winsys/sw/wayland/Makefile
2244                 src/gallium/winsys/sw/wrapper/Makefile
2245                 src/gallium/winsys/sw/xlib/Makefile
2246                 src/gallium/winsys/vc4/drm/Makefile
2247                 src/gbm/Makefile
2248                 src/gbm/main/gbm.pc
2249                 src/glsl/Makefile
2250                 src/glx/Makefile
2251                 src/glx/apple/Makefile
2252                 src/glx/tests/Makefile
2253                 src/gtest/Makefile
2254                 src/loader/Makefile
2255                 src/mapi/Makefile
2256                 src/mapi/es1api/glesv1_cm.pc
2257                 src/mapi/es2api/glesv2.pc
2258                 src/mapi/glapi/gen/Makefile
2259                 src/mapi/vgapi/Makefile
2260                 src/mapi/vgapi/vg.pc
2261                 src/mesa/Makefile
2262                 src/mesa/gl.pc
2263                 src/mesa/drivers/dri/dri.pc
2264                 src/mesa/drivers/dri/common/Makefile
2265                 src/mesa/drivers/dri/common/xmlpool/Makefile
2266                 src/mesa/drivers/dri/i915/Makefile
2267                 src/mesa/drivers/dri/i965/Makefile
2268                 src/mesa/drivers/dri/Makefile
2269                 src/mesa/drivers/dri/nouveau/Makefile
2270                 src/mesa/drivers/dri/r200/Makefile
2271                 src/mesa/drivers/dri/radeon/Makefile
2272                 src/mesa/drivers/dri/swrast/Makefile
2273                 src/mesa/drivers/osmesa/Makefile
2274                 src/mesa/drivers/osmesa/osmesa.pc
2275                 src/mesa/drivers/x11/Makefile
2276                 src/mesa/main/tests/Makefile
2277                 src/util/Makefile
2278                 src/util/tests/hash_table/Makefile])
2279
2280 dnl Sort the dirs alphabetically
2281 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2282 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2283 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2284 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2285
2286 AC_OUTPUT
2287
2288 dnl
2289 dnl Output some configuration info for the user
2290 dnl
2291 echo ""
2292 echo "        prefix:          $prefix"
2293 echo "        exec_prefix:     $exec_prefix"
2294 echo "        libdir:          $libdir"
2295 echo "        includedir:      $includedir"
2296
2297 dnl API info
2298 echo ""
2299 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2300 echo "        OpenVG:          $enable_openvg"
2301
2302 dnl Driver info
2303 echo ""
2304 case "x$enable_osmesa$enable_gallium_osmesa" in
2305 xnoyes)
2306         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2307         ;;
2308 xyesno)
2309         echo "        OSMesa:          lib$OSMESA_LIB"
2310         ;;
2311 xnono)
2312         echo "        OSMesa:          no"
2313         ;;
2314 esac
2315
2316 echo ""
2317 if test "x$enable_dri" != xno; then
2318         echo "        DRI platform:    $dri_platform"
2319         if test -z "$DRI_DIRS"; then
2320             echo "        DRI drivers:     no"
2321         else
2322             echo "        DRI drivers:     $DRI_DIRS"
2323         fi
2324         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2325 fi
2326
2327 case "x$enable_glx$enable_xlib_glx" in
2328 xyesyes)
2329     echo "        GLX:             Xlib-based"
2330     ;;
2331 xyesno)
2332     echo "        GLX:             DRI-based"
2333     ;;
2334 *)
2335     echo "        GLX:             $enable_glx"
2336     ;;
2337 esac
2338
2339 dnl EGL
2340 echo ""
2341 echo "        EGL:             $enable_egl"
2342 if test "$enable_egl" = yes; then
2343     echo "        EGL platforms:   $egl_platforms"
2344
2345     egl_drivers=""
2346     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2347         egl_drivers="$egl_drivers builtin:egl_dri2"
2348     fi
2349
2350     if test "x$enable_gallium_egl" = xyes; then
2351         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2352         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2353     else
2354         echo "        EGL drivers:    $egl_drivers"
2355     fi
2356 fi
2357
2358 echo ""
2359 if test "x$MESA_LLVM" = x1; then
2360     echo "        llvm:            yes"
2361     echo "        llvm-config:     $LLVM_CONFIG"
2362     echo "        llvm-version:    $LLVM_VERSION"
2363 else
2364     echo "        llvm:            no"
2365 fi
2366
2367 echo ""
2368 if test -n "$with_gallium_drivers"; then
2369     echo "        Gallium:         yes"
2370     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2371     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2372     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2373     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2374 else
2375     echo "        Gallium:         no"
2376 fi
2377
2378
2379 dnl Libraries
2380 echo ""
2381 echo "        Shared libs:     $enable_shared"
2382 echo "        Static libs:     $enable_static"
2383 echo "        Shared-glapi:    $enable_shared_glapi"
2384
2385 dnl Compiler options
2386 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2387 cflags=`echo $CFLAGS | \
2388     $SED 's/^ *//;s/  */ /;s/ *$//'`
2389 cxxflags=`echo $CXXFLAGS | \
2390     $SED 's/^ *//;s/  */ /;s/ *$//'`
2391 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2392 echo ""
2393 echo "        CFLAGS:          $cflags"
2394 echo "        CXXFLAGS:        $cxxflags"
2395 echo "        Macros:          $defines"
2396 echo ""
2397 if test "x$MESA_LLVM" = x1; then
2398     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2399     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2400     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2401     echo ""
2402 fi
2403 echo "        PYTHON2:         $PYTHON2"
2404
2405 echo ""
2406 echo "        Run '${MAKE-make}' to build Mesa"
2407 echo ""