configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(hengband, 3.0.0.0)
   3
   4 AC_CONFIG_MACRO_DIRS([m4])
   5 AC_CONFIG_HEADERS(src/autoconf.h)
   6 AC_CONFIG_SRCDIR(src/main.cpp)
   7 AM_INIT_AUTOMAKE
   8
   9 AC_ARG_WITH(setgid,
  10 [  --with-setgid=NAME      install hengband as group NAME],
  11 [case "${withval}" in
  12   no) GAMEGROUP="";;
  13   yes) AC_MSG_ERROR(missing argument for --with-setgid);;
  14   *) GAMEGROUP="$withval";;
  15 esac])
  16 AC_SUBST(GAMEGROUP)
  17 AM_CONDITIONAL(SET_GID, test "$GAMEGROUP" != "")
  18
  19 dnl generate the installation path for the ./lib/ folder
  20 if test "$GAMEGROUP" != ""; then
  21   MY_EXPAND_DIR(game_libpath, "$datarootdir/games/$PACKAGE/lib/")
  22 else
  23   MY_EXPAND_DIR(game_libpath, "./lib/")
  24   bindir="`pwd`"
  25 fi
  26
  27 dnl overwrite the path with an user-specified value
  28 AC_ARG_WITH(libpath,
  29 [  --with-libpath=path     specify the path to the Hengband lib folder],
  30 [game_libpath="$withval"])
  31
  32 AC_ARG_WITH(varpath,
  33 [  --with-varpath=path     specify the path to the Hengband var folder],
  34 [game_varpath="$withval"],
  35 [game_varpath="$game_libpath"])
  36
  37 AC_DEFINE_UNQUOTED(DEFAULT_LIB_PATH, "$game_libpath", [Path to the Hengband lib folder])
  38 DEFAULT_LIB_PATH="$game_libpath"
  39 AC_SUBST(DEFAULT_LIB_PATH)
  40
  41 AC_DEFINE_UNQUOTED(DEFAULT_VAR_PATH, "$game_varpath", [Path to the Hengband var folder])
  42 DEFAULT_VAR_PATH="$game_varpath"
  43 AC_SUBST(DEFAULT_VAR_PATH)
  44
  45 dnl Checks for programs.
  46 AC_LANG(C++)
  47 AC_PROG_CXX
  48 dnl Note that the -std= option for Objective-C++ is hardwired in
  49 dnl src/Makefile.am so that should be changed if this is.
  50 AX_CXX_COMPILE_STDCXX(20, [ext], [mandatory])
  51 PKG_PROG_PKG_CONFIG
  52
  53 AC_ARG_ENABLE(japanese,
  54 [  --disable-japanese      build english version], use_japanese=no, [AC_DEFINE(JP, 1, [Enable Japanese]) AC_DEFINE(EUC, 1, [Use Extended Unix Code])])
  55
  56 AC_ARG_ENABLE(xim,
  57 [  --disable-xim           disable xim support], use_xim=no, use_xim=yes)
  58 AC_ARG_ENABLE(fontset,
  59 [  --disable-fontset       disable fontset support], use_fontset=no, use_fontset=yes)
  60 AC_ARG_ENABLE([xft],
  61         AS_HELP_STRING([--enable-xft], [Enable xft support]))
  62 AC_ARG_ENABLE(worldscore,
  63 [  --disable-worldscore    disable worldscore support], worldscore=no)
  64 AC_ARG_ENABLE([pch],
  65 [  --disable-pch           disable use of precompiled headers],
  66 enable_pch=no, enable_pch=yes)
  67 AM_CONDITIONAL([PCH], [test x$enable_pch = xyes])
  68 AC_ARG_ENABLE([cocoa],
  69 [  --enable-cocoa          enable a Cocoa user interface (OS X only)],
  70 [AC_DEFINE([MACH_O_COCOA], [1], [Use a Cocoa interface (OS X only)])], [])
  71 AM_CONDITIONAL([COCOA], [test x$enable_cocoa = xyes])
  72 dnl Since AC_PROG_OBJCXX has the side effect of setting this conditional,
  73 dnl guarantee that is is always set, regardless of what happens in the if
  74 dnl statement.
  75 AM_CONDITIONAL([am__fastdepOBJCXX], false)
  76 if test x"$enable_cocoa" = xyes ; then
  77   dnl Use AC_LANG_PUSH and AC_LANG_POP to try to get back to the state that
  78   dnl AC_LANG_C set in case there are side effects.
  79   AC_LANG_PUSH([Objective C++])
  80   AC_PROG_OBJCXX
  81   AC_LANG_POP([Objective C++])
  82   AC_DEFINE(SAFE_DIRECTORY, 1, [Mark var directory with version string])
  83   AC_DEFINE(VERSION_STRING, "3.0.0", [Version string to use for var directory])
  84 fi
  85
  86 dnl Checks for libraries.
  87 dnl Replace `main' with a function in -lncurses:
  88 if test x"$enable_cocoa" != xyes ; then
  89   AC_CHECK_LIB(ncursesw, initscr, [AC_DEFINE(USE_GCU, 1, [Allow -mGCU environment]) AC_DEFINE(USE_NCURSES, 1, [Use ncurses]) LIBS="$LIBS -lncursesw"])
  90   if test "$ac_cv_lib_ncursesw_initscr" != yes; then
  91     AC_CHECK_LIB(ncurses, initscr, [AC_DEFINE(USE_GCU, 1, [Allow -mGCU environment]) AC_DEFINE(USE_NCURSES, 1, [Use ncurses]) LIBS="$LIBS -lncurses"])
  92     if test "$ac_cv_lib_ncurses_initscr" != yes; then
  93       AC_CHECK_LIB(curses, initscr, [AC_DEFINE(USE_GCU, 1, [Allow -mGCU environment]) LIBS="$LIBS -lcurses"])
  94       if test "$ac_cv_lib_curses_initscr" != yes; then
  95         AC_CHECK_LIB(termcap, tgetent, [AC_DEFINE(USE_CAP, 1, [Allow -mCAP environment]) LIBS="$LIBS -ltermcap"])
  96       fi
  97     fi
  98   fi
  99 fi
 100
 101 AC_CHECK_LIB(iconv, iconv_open)
 102
 103 dnl The world score server is currently only available in Japanese.
 104 if test "$use_japanese" = no; then
 105   worldscore=no
 106 fi
 107 if test "$worldscore" != no; then
 108   PKG_CHECK_MODULES(libcurl, [libcurl])
 109   AC_DEFINE(WORLD_SCORE, 1, [Allow the game to send scores to the score server])
 110 fi
 111
 112 dnl Checks for header files.
 113 dnl AC_PATH_XTRA has side effects on CPP which are beneficial on Mac OS X.
 114 dnl Removing it or conditionally executing it will likely lead to warnings
 115 dnl on that platform about the preprocessor disagreeing with the compiler on
 116 dnl the tests in AC_CHECK_HEADERS.
 117 AC_PATH_XTRA
 118 AS_IF([test "$have_x" = yes && test x"$enable_cocoa" != xyes], [
 119   LIBS="$LIBS -lX11"
 120   AC_DEFINE(USE_X11, 1, [Allow -mX11 environment])
 121   CXXFLAGS="$X_CFLAGS $CXXFLAGS"
 122   LDFLAGS="$X_LIBS $LDFLAGS"
 123
 124   if test "$use_fontset" = yes; then
 125     AC_DEFINE(USE_FONTSET, 1, [Use FontSet])
 126   else
 127     if test "$use_japanese" != no; then
 128       AC_DEFINE(USE_JP_FONTSTRUCT, 1, [Use Kanji without FontSet])
 129     fi
 130   fi
 131
 132   if test "$use_xim" = yes; then
 133     AC_DEFINE(USE_XIM, 1, [Use X Imput Method])
 134   fi
 135
 136   if test "$use_fontset" = yes || test "$use_xim" = yes; then
 137     AC_DEFINE(USE_LOCALE, 1, [Support Locale])
 138     if test "$use_japanese" != no; then
 139       AC_DEFINE(DEFAULT_LOCALE, "ja_JP.eucJP", Default Japanese Locale)
 140     fi
 141     AC_CHECK_LIB(X11, _Xsetlocale, AC_DEFINE(X_LOCALE, 1, [Use XLocale]))
 142     AC_CHECK_LIB(xpg4, setlocale, LIBS="$LIBS -lxpg4")
 143   fi
 144
 145   AS_IF([test "x$enable_xft" = "xyes"], [
 146     PKG_CHECK_MODULES(XFT, [xft],
 147       [AC_DEFINE([USE_XFT], [1], [Use XFT])])
 148   ])
 149 ])
 150
 151 if test "$use_japanese" != no; then
 152   AC_CHECK_PROG(NKF, nkf, yes)
 153   if test x"$NKF" != x"yes"; then
 154     AC_MSG_ERROR([nkf is not found. Please install nkf.])
 155   fi
 156 fi
 157
 158 if test "$enable_pch" != no; then
 159   dnl md5sum, sha224sum, sha256sum, sha384sum, sha512sum and b2sum are
 160   dnl frequently available on Linux.  md5 is available on macOS and OpenBSD.
 161   dnl sha1, sha256, and sha512 are available on OpenBSD.
 162   AC_PATH_PROGS(PCH_CHECKSUMMER, [md5sum md5 sha1sum sha1 sha224sum sha256sum sha256 sha384sum sha512sum sha512 b2sum], [none])
 163   AC_ARG_VAR([PCH_CHECKSUMMER], [full path to a utility to compute the checksum for the precompiled header; checksum is for ccache's pch_external_checksum])
 164 fi
 165
 166 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/ioctl.h sys/time.h termio.h unistd.h stdint.h)
 167
 168 dnl Checks for typedefs, structures, and compiler characteristics.
 169 AC_C_CONST
 170 AC_TYPE_PID_T
 171 AC_TYPE_SIZE_T
 172 AC_STRUCT_TM
 173
 174 dnl Checks for library functions.
 175 AC_PROG_GCC_TRADITIONAL
 176 AC_FUNC_MEMCMP
 177 AC_FUNC_STRFTIME
 178 AC_FUNC_VPRINTF
 179 AC_CHECK_FUNCS(gethostname mkdir select socket strtol mkstemp usleep)
 180
 181 AC_CONFIG_FILES(Makefile src/Makefile lib/Makefile lib/apex/Makefile \
 182         lib/bone/Makefile lib/data/Makefile \
 183         lib/edit/Makefile lib/edit/quests/Makefile lib/edit/towns/Makefile \
 184         lib/file/Makefile lib/file/books/Makefile lib/help/Makefile \
 185         lib/info/Makefile lib/pref/Makefile lib/save/Makefile \
 186         lib/script/Makefile lib/user/Makefile lib/xtra/Makefile \
 187         lib/xtra/graf/Makefile lib/xtra/music/Makefile lib/xtra/sound/Makefile)
 188 AC_OUTPUT()