configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.55
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -D_XOPEN_SOURCE=700 -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     CFLAGS="$CFLAGS -Wall -std=c99"
 169
 170     # Enable -Werror=implicit-function-declaration and
 171     # -Werror=missing-prototypes, if available, or otherwise, just
 172     # -Wmissing-prototypes.  This is particularly useful to avoid
 173     # generating a loadable driver module that has undefined symbols.
 174     save_CFLAGS="$CFLAGS"
 175     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 176     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 177     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 178     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 179                    AC_MSG_RESULT([yes]),
 180                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 181                     AC_MSG_RESULT([no])]);
 182
 183     # Enable -fvisibility=hidden if using a gcc that supports it
 184     save_CFLAGS="$CFLAGS"
 185     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 186     VISIBILITY_CFLAGS="-fvisibility=hidden"
 187     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 189                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 190
 191     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 192     CFLAGS=$save_CFLAGS
 193
 194     # Work around aliasing bugs - developers should comment this out
 195     CFLAGS="$CFLAGS -fno-strict-aliasing"
 196
 197     # gcc's builtin memcmp is slower than glibc's
 198     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 199     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 200 fi
 201 if test "x$GXX" = xyes; then
 202     CXXFLAGS="$CXXFLAGS -Wall"
 203
 204     # Enable -fvisibility=hidden if using a gcc that supports it
 205     save_CXXFLAGS="$CXXFLAGS"
 206     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 207     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 208     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 209     AC_LANG_PUSH([C++])
 210     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 211                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 212     AC_LANG_POP([C++])
 213
 214     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 215     CXXFLAGS=$save_CXXFLAGS
 216
 217     # Work around aliasing bugs - developers should comment this out
 218     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 219
 220     # gcc's builtin memcmp is slower than glibc's
 221     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 222     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 223 fi
 224
 225 dnl even if the compiler appears to support it, using visibility attributes isn't
 226 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 227 case "$host_os" in
 228 cygwin*)
 229     VISIBILITY_CFLAGS=""
 230     VISIBILITY_CXXFLAGS=""
 231     ;;
 232 esac
 233
 234 AC_SUBST([VISIBILITY_CFLAGS])
 235 AC_SUBST([VISIBILITY_CXXFLAGS])
 236
 237 dnl
 238 dnl Optional flags, check for compiler support
 239 dnl
 240 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 241 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 242
 243 dnl
 244 dnl Hacks to enable 32 or 64 bit build
 245 dnl
 246 AC_ARG_ENABLE([32-bit],
 247     [AS_HELP_STRING([--enable-32-bit],
 248         [build 32-bit libraries @<:@default=auto@:>@])],
 249     [enable_32bit="$enableval"],
 250     [enable_32bit=auto]
 251 )
 252 if test "x$enable_32bit" = xyes; then
 253     if test "x$GCC" = xyes; then
 254         CFLAGS="$CFLAGS -m32"
 255         CCASFLAGS="$CCASFLAGS -m32"
 256     fi
 257     if test "x$GXX" = xyes; then
 258         CXXFLAGS="$CXXFLAGS -m32"
 259     fi
 260 fi
 261 AC_ARG_ENABLE([64-bit],
 262     [AS_HELP_STRING([--enable-64-bit],
 263         [build 64-bit libraries @<:@default=auto@:>@])],
 264     [enable_64bit="$enableval"],
 265     [enable_64bit=auto]
 266 )
 267 if test "x$enable_64bit" = xyes; then
 268     if test "x$GCC" = xyes; then
 269         CFLAGS="$CFLAGS -m64"
 270     fi
 271     if test "x$GXX" = xyes; then
 272         CXXFLAGS="$CXXFLAGS -m64"
 273     fi
 274 fi
 275
 276 dnl Can't have static and shared libraries, default to static if user
 277 dnl explicitly requested. If both disabled, set to static since shared
 278 dnl was explicitly requested.
 279 case "x$enable_static$enable_shared" in
 280 xyesyes)
 281     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 282     enable_shared=no
 283     ;;
 284 xnono)
 285     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 286     enable_shared=yes
 287     ;;
 288 esac
 289
 290 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 291
 292 dnl
 293 dnl other compiler options
 294 dnl
 295 AC_ARG_ENABLE([debug],
 296     [AS_HELP_STRING([--enable-debug],
 297         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 298     [enable_debug="$enableval"],
 299     [enable_debug=no]
 300 )
 301 if test "x$enable_debug" = xyes; then
 302     DEFINES="$DEFINES -DDEBUG"
 303     if test "x$GCC" = xyes; then
 304         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 305             CFLAGS="$CFLAGS -g"
 306         fi
 307         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 308             CFLAGS="$CFLAGS -O0"
 309         fi
 310     fi
 311     if test "x$GXX" = xyes; then
 312         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 313             CXXFLAGS="$CXXFLAGS -g"
 314         fi
 315         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 316             CXXFLAGS="$CXXFLAGS -O0"
 317         fi
 318     fi
 319 fi
 320
 321 dnl
 322 dnl Check if linker supports -Bsymbolic
 323 dnl
 324 save_LDFLAGS=$LDFLAGS
 325 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 326 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 327 AC_LINK_IFELSE(
 328     [AC_LANG_SOURCE([int main() { return 0;}])],
 329     [AC_MSG_RESULT([yes])
 330         BSYMBOLIC="-Wl,-Bsymbolic";],
 331     [AC_MSG_RESULT([no])
 332         BSYMBOLIC="";])
 333 LDFLAGS=$save_LDFLAGS
 334
 335 AC_SUBST([BSYMBOLIC])
 336
 337 dnl
 338 dnl Check if linker supports garbage collection
 339 dnl
 340 save_LDFLAGS=$LDFLAGS
 341 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 342 AC_MSG_CHECKING([whether ld supports --gc-sections])
 343 AC_LINK_IFELSE(
 344     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 345     [AC_MSG_RESULT([yes])
 346         GC_SECTIONS="-Wl,--gc-sections";],
 347     [AC_MSG_RESULT([no])
 348         GC_SECTIONS="";])
 349 LDFLAGS=$save_LDFLAGS
 350
 351 AC_SUBST([GC_SECTIONS])
 352
 353 dnl
 354 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 355 dnl so when these flags are passed to ld via libtool the checks will fail
 356 dnl
 357 case "$host_os" in
 358 openbsd* | darwin* )
 359     LD_NO_UNDEFINED="" ;;
 360 *)
 361     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 362 esac
 363
 364 AC_SUBST([LD_NO_UNDEFINED])
 365
 366 dnl
 367 dnl Check if linker supports version scripts
 368 dnl
 369 AC_MSG_CHECKING([if the linker supports version-scripts])
 370 save_LDFLAGS=$LDFLAGS
 371 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 372 cat > conftest.map <<EOF
 373 VERSION_1 {
 374      global:
 375          main;
 376
 377      local:
 378          *;
 379 };
 380 EOF
 381 AC_LINK_IFELSE(
 382     [AC_LANG_SOURCE([int main() { return 0;}])],
 383     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 384     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 385 LDFLAGS=$save_LDFLAGS
 386 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 387
 388 dnl
 389 dnl compatibility symlinks
 390 dnl
 391 case "$host_os" in
 392 linux* )
 393     HAVE_COMPAT_SYMLINKS=yes ;;
 394 * )
 395     HAVE_COMPAT_SYMLINKS=no ;;
 396 esac
 397
 398 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 399
 400 dnl
 401 dnl library names
 402 dnl
 403 case "$host_os" in
 404 darwin* )
 405     LIB_EXT='dylib' ;;
 406 cygwin* )
 407     LIB_EXT='dll' ;;
 408 aix* )
 409     LIB_EXT='a' ;;
 410 * )
 411     LIB_EXT='so' ;;
 412 esac
 413
 414 AC_SUBST([LIB_EXT])
 415
 416 AC_ARG_WITH([gl-lib-name],
 417   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 418     [specify GL library name @<:@default=GL@:>@])],
 419   [GL_LIB=$withval],
 420   [GL_LIB=GL])
 421 AC_ARG_WITH([osmesa-lib-name],
 422   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 423     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 424   [OSMESA_LIB=$withval],
 425   [OSMESA_LIB=OSMesa])
 426 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 427 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 428
 429 dnl
 430 dnl Mangled Mesa support
 431 dnl
 432 AC_ARG_ENABLE([mangling],
 433   [AS_HELP_STRING([--enable-mangling],
 434     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 435   [enable_mangling="${enableval}"],
 436   [enable_mangling=no]
 437 )
 438 if test "x${enable_mangling}" = "xyes" ; then
 439   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 440   GL_LIB="Mangled${GL_LIB}"
 441   OSMESA_LIB="Mangled${OSMESA_LIB}"
 442 fi
 443 AC_SUBST([GL_LIB])
 444 AC_SUBST([OSMESA_LIB])
 445
 446 dnl
 447 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 448 dnl
 449 AC_ARG_ENABLE([texture-float],
 450     [AS_HELP_STRING([--enable-texture-float],
 451         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 452     [enable_texture_float="$enableval"],
 453     [enable_texture_float=no]
 454 )
 455 if test "x$enable_texture_float" = xyes; then
 456     AC_MSG_WARN([Floating-point textures enabled.])
 457     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 458     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 459 fi
 460
 461 dnl
 462 dnl Arch/platform-specific settings
 463 dnl
 464 AC_ARG_ENABLE([asm],
 465     [AS_HELP_STRING([--disable-asm],
 466         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 467     [enable_asm="$enableval"],
 468     [enable_asm=yes]
 469 )
 470 asm_arch=""
 471 AC_MSG_CHECKING([whether to enable assembly])
 472 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 473 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 474 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 475     case "$host_cpu" in
 476     i?86 | x86_64 | amd64)
 477         enable_asm=no
 478         AC_MSG_RESULT([no, cross compiling])
 479         ;;
 480     esac
 481 fi
 482 # check for supported arches
 483 if test "x$enable_asm" = xyes; then
 484     case "$host_cpu" in
 485     i?86)
 486         case "$host_os" in
 487         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 488             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 489             ;;
 490         gnu*)
 491             asm_arch=x86
 492             ;;
 493         esac
 494         ;;
 495     x86_64|amd64)
 496         case "$host_os" in
 497         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 498             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 499             ;;
 500         esac
 501         ;;
 502     sparc*)
 503         case "$host_os" in
 504         linux*)
 505             asm_arch=sparc
 506             ;;
 507         esac
 508         ;;
 509     esac
 510
 511     case "$asm_arch" in
 512     x86)
 513         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 514         AC_MSG_RESULT([yes, x86])
 515         ;;
 516     x86_64|amd64)
 517         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 518         AC_MSG_RESULT([yes, x86_64])
 519         ;;
 520     sparc)
 521         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 522         AC_MSG_RESULT([yes, sparc])
 523         ;;
 524     *)
 525         AC_MSG_RESULT([no, platform not supported])
 526         ;;
 527     esac
 528 fi
 529
 530 dnl Check to see if dlopen is in default libraries (like Solaris, which
 531 dnl has it in libc), or if libdl is needed to get it.
 532 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 533     [AC_CHECK_LIB([dl], [dlopen],
 534        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 535 AC_SUBST([DLOPEN_LIBS])
 536
 537 dnl Check if that library also has dladdr
 538 AC_CHECK_FUNC([dladdr], [DEFINES="$DEFINES -DHAVE_DLADDR"],
 539     [AC_CHECK_LIB([dl], [dladdr],
 540        [DEFINES="$DEFINES -DHAVE_DLADDR"])])
 541
 542 case "$host_os" in
 543 darwin*|mingw*)
 544     ;;
 545 *)
 546     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 547                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 548                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 549     AC_SUBST([CLOCK_LIB])
 550     ;;
 551 esac
 552
 553 dnl See if posix_memalign is available
 554 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 555
 556 dnl Check for pthreads
 557 case "$host_os" in
 558 mingw*)
 559     ;;
 560 *)
 561     AX_PTHREAD
 562     ;;
 563 esac
 564 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 565 dnl to -pthread, which causes problems if we need -lpthread to appear in
 566 dnl pkgconfig files.
 567 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 568
 569 dnl SELinux awareness.
 570 AC_ARG_ENABLE([selinux],
 571     [AS_HELP_STRING([--enable-selinux],
 572         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 573     [MESA_SELINUX="$enableval"],
 574     [MESA_SELINUX=no])
 575 if test "x$enable_selinux" = "xyes"; then
 576     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 577         [AC_CHECK_HEADER([selinux/selinux.h],[],
 578                          [AC_MSG_ERROR([SELinux headers not found])])
 579          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 580                       [AC_MSG_ERROR([SELinux library not found])])
 581          SELINUX_LIBS="-lselinux"])
 582     DEFINES="$DEFINES -DMESA_SELINUX"
 583 fi
 584 AC_SUBST([SELINUX_CFLAGS])
 585 AC_SUBST([SELINUX_LIBS])
 586
 587 dnl Options for APIs
 588 AC_ARG_ENABLE([opengl],
 589     [AS_HELP_STRING([--disable-opengl],
 590         [disable support for standard OpenGL API @<:@default=no@:>@])],
 591     [enable_opengl="$enableval"],
 592     [enable_opengl=yes])
 593 AC_ARG_ENABLE([gles1],
 594     [AS_HELP_STRING([--enable-gles1],
 595         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 596     [enable_gles1="$enableval"],
 597     [enable_gles1=no])
 598 AC_ARG_ENABLE([gles2],
 599     [AS_HELP_STRING([--enable-gles2],
 600         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 601     [enable_gles2="$enableval"],
 602     [enable_gles2=no])
 603 AC_ARG_ENABLE([openvg],
 604     [AS_HELP_STRING([--enable-openvg],
 605         [enable support for OpenVG API @<:@default=no@:>@])],
 606     [enable_openvg="$enableval"],
 607     [enable_openvg=no])
 608
 609 AC_ARG_ENABLE([dri],
 610     [AS_HELP_STRING([--enable-dri],
 611         [enable DRI modules @<:@default=enabled@:>@])],
 612     [enable_dri="$enableval"],
 613     [enable_dri=yes])
 614
 615 case "$host_os" in
 616 linux*)
 617     dri3_default=yes
 618     ;;
 619 *)
 620     dri3_default=no
 621     ;;
 622 esac
 623 AC_ARG_ENABLE([dri3],
 624     [AS_HELP_STRING([--enable-dri3],
 625         [enable DRI3 @<:@default=auto@:>@])],
 626     [enable_dri3="$enableval"],
 627     [enable_dri3="$dri3_default"])
 628 AC_ARG_ENABLE([glx],
 629     [AS_HELP_STRING([--enable-glx],
 630         [enable GLX library @<:@default=enabled@:>@])],
 631     [enable_glx="$enableval"],
 632     [enable_glx=yes])
 633 AC_ARG_ENABLE([osmesa],
 634     [AS_HELP_STRING([--enable-osmesa],
 635         [enable OSMesa library @<:@default=disabled@:>@])],
 636     [enable_osmesa="$enableval"],
 637     [enable_osmesa=no])
 638 AC_ARG_ENABLE([gallium-osmesa],
 639     [AS_HELP_STRING([--enable-gallium-osmesa],
 640         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 641     [enable_gallium_osmesa="$enableval"],
 642     [enable_gallium_osmesa=no])
 643 AC_ARG_ENABLE([egl],
 644     [AS_HELP_STRING([--disable-egl],
 645         [disable EGL library @<:@default=enabled@:>@])],
 646     [enable_egl="$enableval"],
 647     [enable_egl=yes])
 648
 649 AC_ARG_ENABLE([xa],
 650     [AS_HELP_STRING([--enable-xa],
 651         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 652     [enable_xa="$enableval"],
 653     [enable_xa=no])
 654 AC_ARG_ENABLE([gbm],
 655    [AS_HELP_STRING([--enable-gbm],
 656          [enable gbm library @<:@default=auto@:>@])],
 657    [enable_gbm="$enableval"],
 658    [enable_gbm=auto])
 659
 660 AC_ARG_ENABLE([xvmc],
 661    [AS_HELP_STRING([--enable-xvmc],
 662          [enable xvmc library @<:@default=auto@:>@])],
 663    [enable_xvmc="$enableval"],
 664    [enable_xvmc=no])
 665 AC_ARG_ENABLE([vdpau],
 666    [AS_HELP_STRING([--enable-vdpau],
 667          [enable vdpau library @<:@default=auto@:>@])],
 668    [enable_vdpau="$enableval"],
 669    [enable_vdpau=auto])
 670 AC_ARG_ENABLE([omx],
 671    [AS_HELP_STRING([--enable-omx],
 672          [enable OpenMAX library @<:@default=no@:>@])],
 673    [enable_omx="$enableval"],
 674    [enable_omx=no])
 675 AC_ARG_ENABLE([opencl],
 676    [AS_HELP_STRING([--enable-opencl],
 677          [enable OpenCL library @<:@default=no@:>@])],
 678    [enable_opencl="$enableval"],
 679    [enable_opencl=no])
 680 AC_ARG_ENABLE([opencl_icd],
 681    [AS_HELP_STRING([--enable-opencl-icd],
 682           [Build an OpenCL ICD library to be loaded by an ICD implementation
 683            @<:@default=no@:>@])],
 684     [enable_opencl_icd="$enableval"],
 685     [enable_opencl_icd=no])
 686 AC_ARG_ENABLE([xlib-glx],
 687     [AS_HELP_STRING([--enable-xlib-glx],
 688         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 689     [enable_xlib_glx="$enableval"],
 690     [enable_xlib_glx=no])
 691 AC_ARG_ENABLE([gallium-egl],
 692     [AS_HELP_STRING([--enable-gallium-egl],
 693         [enable optional EGL state tracker (not required
 694          for EGL support in Gallium with OpenGL and OpenGL ES)
 695          @<:@default=disable@:>@])],
 696     [enable_gallium_egl="$enableval"],
 697     [enable_gallium_egl=no])
 698 AC_ARG_ENABLE([gallium-gbm],
 699     [AS_HELP_STRING([--enable-gallium-gbm],
 700         [enable optional gbm state tracker (not required for
 701          gbm support in Gallium)
 702          @<:@default=auto@:>@])],
 703     [enable_gallium_gbm="$enableval"],
 704     [enable_gallium_gbm=auto])
 705
 706 AC_ARG_ENABLE([r600-llvm-compiler],
 707     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 708         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 709     [enable_r600_llvm="$enableval"],
 710     [enable_r600_llvm=no])
 711
 712 AC_ARG_ENABLE([gallium-tests],
 713     [AS_HELP_STRING([--enable-gallium-tests],
 714         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 715     [enable_gallium_tests="$enableval"],
 716     [enable_gallium_tests=no])
 717
 718 # Option for Gallium drivers
 719
 720 # Keep this in sync with the --with-gallium-drivers help string default value
 721 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 722
 723 AC_ARG_WITH([gallium-drivers],
 724     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 725         [comma delimited Gallium drivers list, e.g.
 726         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 727         @<:@default=r300,r600,svga,swrast@:>@])],
 728     [with_gallium_drivers="$withval"],
 729     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 730
 731 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 732 # here so that the script doesn't choke on an unknown driver name later.
 733 case "$with_gallium_drivers" in
 734     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 735     no) with_gallium_drivers='' ;;
 736 esac
 737
 738 if test "x$enable_opengl" = xno -a \
 739         "x$enable_gles1" = xno -a \
 740         "x$enable_gles2" = xno -a \
 741         "x$enable_openvg" = xno -a \
 742         "x$enable_xa" = xno -a \
 743         "x$enable_xvmc" = xno -a \
 744         "x$enable_vdpau" = xno -a \
 745         "x$enable_omx" = xno -a \
 746         "x$enable_opencl" = xno; then
 747     AC_MSG_ERROR([at least one API should be enabled])
 748 fi
 749
 750 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 751 if test "x$enable_opengl" = xno -a \
 752         "x$enable_gles1" = xyes; then
 753     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 754 fi
 755
 756 if test "x$enable_opengl" = xno -a \
 757         "x$enable_gles2" = xyes; then
 758     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 759 fi
 760
 761 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 762 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 763 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 764 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 765                                         "x$enable_gles1" = xyes -o \
 766                                         "x$enable_gles2" = xyes)
 767
 768 if test "x$enable_glx" = xno; then
 769     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 770     enable_xlib_glx=no
 771 fi
 772
 773 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 774     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 775 fi
 776
 777 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 778     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 779 fi
 780
 781 # Disable GLX if OpenGL is not enabled
 782 if test "x$enable_glx$enable_opengl" = xyesno; then
 783     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 784     enable_glx=no
 785 fi
 786
 787 # Disable GLX if DRI and Xlib-GLX are not enabled
 788 if test "x$enable_glx" = xyes -a \
 789         "x$enable_dri" = xno -a \
 790         "x$enable_xlib_glx" = xno; then
 791     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 792     enable_glx=no
 793 fi
 794
 795 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 796                                   "x$enable_dri" = xyes)
 797
 798 # Select which platform-dependent DRI code gets built
 799 case "$host_os" in
 800 darwin*)
 801     dri_platform='apple' ;;
 802 gnu*|mingw*|cygwin*)
 803     dri_platform='none' ;;
 804 *)
 805     dri_platform='drm' ;;
 806 esac
 807
 808 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 809 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 810 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 811 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 812 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 813
 814 AC_ARG_ENABLE([shared-glapi],
 815     [AS_HELP_STRING([--enable-shared-glapi],
 816         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 817     [enable_shared_glapi="$enableval"],
 818     [enable_shared_glapi=yes])
 819
 820 case "x$enable_opengl$enable_gles1$enable_gles2" in
 821 x*yes*yes*)
 822     if test "x$enable_shared_glapi" = xno; then
 823         AC_MSG_ERROR([shared GLAPI required when building two or more of
 824                       the following APIs - opengl, gles1 gles2])
 825     fi
 826     ;;
 827 esac
 828
 829 # Building Xlib-GLX requires shared glapi to be disabled.
 830 if test "x$enable_xlib_glx" = xyes; then
 831     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 832     enable_shared_glapi=no
 833 fi
 834
 835 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 836
 837 dnl
 838 dnl Driver specific build directories
 839 dnl
 840 GALLIUM_TARGET_DIRS=""
 841 GALLIUM_WINSYS_DIRS="sw"
 842 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 843 GALLIUM_STATE_TRACKERS_DIRS=""
 844
 845 case "x$enable_glx$enable_xlib_glx" in
 846 xyesyes)
 847     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 848     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 849     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 850     NEED_WINSYS_XLIB="yes"
 851     ;;
 852 esac
 853
 854 if test "x$enable_dri" = xyes; then
 855     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 856     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 857     enable_gallium_loader=yes
 858 fi
 859
 860 if test "x$enable_gallium_osmesa" = xyes; then
 861     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 862         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 863     fi
 864     if test "x$enable_osmesa" = xyes; then
 865         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 866     fi
 867     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 868     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 869 fi
 870
 871 AC_SUBST([MESA_LLVM])
 872
 873 # Check for libdrm
 874 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 875                   [have_libdrm=yes], [have_libdrm=no])
 876 if test "x$have_libdrm" = xyes; then
 877         DEFINES="$DEFINES -DHAVE_LIBDRM"
 878 fi
 879
 880 case "$host_os" in
 881 linux*)
 882     need_pci_id=yes ;;
 883 *)
 884     need_pci_id=no ;;
 885 esac
 886
 887 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 888                   have_libudev=yes, have_libudev=no)
 889
 890 AC_ARG_ENABLE([sysfs],
 891     [AS_HELP_STRING([--enable-sysfs],
 892         [enable /sys PCI identification @<:@default=disabled@:>@])],
 893     [have_sysfs="$enableval"],
 894     [have_sysfs=no]
 895 )
 896
 897 if test "x$enable_dri" = xyes; then
 898     if test "$enable_static" = yes; then
 899         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 900     fi
 901
 902     # not a hard requirement as swrast does not depend on it
 903     if test "x$have_libdrm" = xyes; then
 904         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 905     fi
 906 fi
 907
 908 AC_ARG_ENABLE([driglx-direct],
 909     [AS_HELP_STRING([--disable-driglx-direct],
 910         [disable direct rendering in GLX and EGL for DRI \
 911             @<:@default=auto@:>@])],
 912     [driglx_direct="$enableval"],
 913     [driglx_direct="yes"])
 914
 915 dnl
 916 dnl libGL configuration per driver
 917 dnl
 918 case "x$enable_glx$enable_xlib_glx" in
 919 xyesyes)
 920     # Xlib-based GLX
 921     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 922     GL_PC_REQ_PRIV="x11 xext"
 923     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 924     GL_LIB_DEPS="$XLIBGL_LIBS"
 925     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 926     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 927     ;;
 928 xyesno)
 929     # DRI-based GLX
 930     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 931
 932     # find the DRI deps for libGL
 933     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 934
 935     if test x"$driglx_direct" = xyes; then
 936         if test x"$dri_platform" = xdrm ; then
 937             DEFINES="$DEFINES -DGLX_USE_DRM"
 938             if test "x$have_libdrm" != xyes; then
 939                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 940             fi
 941
 942             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 943             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 944             if test x"$enable_dri3" = xyes; then
 945                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 946                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 947             fi
 948
 949             if test x"$enable_dri" = xyes; then
 950                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 951             fi
 952
 953             if test x"$enable_dri3" = xyes; then
 954                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 955             fi
 956         fi
 957         if test x"$dri_platform" = xapple ; then
 958             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 959         fi
 960     fi
 961
 962     # add xf86vidmode if available
 963     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 964     if test "$HAVE_XF86VIDMODE" = yes ; then
 965         dri_modules="$dri_modules xxf86vm"
 966     fi
 967
 968     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 969     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 970     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 971     GL_LIB_DEPS="$DRIGL_LIBS"
 972
 973     # need DRM libs, $PTHREAD_LIBS, etc.
 974     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 975     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 976     ;;
 977 esac
 978
 979 have_pci_id=no
 980 if test "$have_libudev" = yes; then
 981     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 982     have_pci_id=yes
 983 fi
 984
 985 if test "$have_sysfs" = yes; then
 986     DEFINES="$DEFINES -DHAVE_SYSFS"
 987     have_pci_id=yes
 988 fi
 989
 990 # This is outside the case (above) so that it is invoked even for non-GLX
 991 # builds.
 992 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 993
 994 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 995 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 996 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 997 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 998
 999 AC_SUBST([X11_INCLUDES])
1000 AC_SUBST([GL_LIB_DEPS])
1001 AC_SUBST([GL_PC_REQ_PRIV])
1002 AC_SUBST([GL_PC_LIB_PRIV])
1003 AC_SUBST([GL_PC_CFLAGS])
1004 AC_SUBST([DRI_PC_REQ_PRIV])
1005 AC_SUBST([GLESv1_CM_LIB_DEPS])
1006 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1007 AC_SUBST([GLESv2_LIB_DEPS])
1008 AC_SUBST([GLESv2_PC_LIB_PRIV])
1009
1010 AC_SUBST([HAVE_XF86VIDMODE])
1011
1012 dnl
1013 dnl More GLX setup
1014 dnl
1015 case "x$enable_glx$enable_xlib_glx" in
1016 xyesyes)
1017     DEFINES="$DEFINES -DUSE_XSHM"
1018     ;;
1019 xyesno)
1020     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1021     if test "x$driglx_direct" = xyes; then
1022         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1023     fi
1024     ;;
1025 esac
1026
1027 dnl
1028 dnl TLS detection
1029 dnl
1030
1031 AC_ARG_ENABLE([glx-tls],
1032     [AS_HELP_STRING([--enable-glx-tls],
1033         [enable TLS support in GLX @<:@default=disabled@:>@])],
1034     [GLX_USE_TLS="$enableval"],
1035     [GLX_USE_TLS=no])
1036 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1037
1038 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1039       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1040
1041 dnl
1042 dnl More DRI setup
1043 dnl
1044 dnl Directory for DRI drivers
1045 AC_ARG_WITH([dri-driverdir],
1046     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1047         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1048     [DRI_DRIVER_INSTALL_DIR="$withval"],
1049     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1050 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1051 dnl Extra search path for DRI drivers
1052 AC_ARG_WITH([dri-searchpath],
1053     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1054         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1055     [DRI_DRIVER_SEARCH_DIR="$withval"],
1056     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1057 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1058 dnl Which drivers to build - default is chosen by platform
1059 AC_ARG_WITH([dri-drivers],
1060     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1061         [comma delimited classic DRI drivers list, e.g.
1062         "swrast,i965,radeon" @<:@default=auto@:>@])],
1063     [with_dri_drivers="$withval"],
1064     [with_dri_drivers=auto])
1065
1066 if test "x$with_dri_drivers" = xauto; then
1067     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1068         with_dri_drivers="yes"
1069     else
1070         with_dri_drivers="no"
1071     fi
1072 fi
1073 if test "x$with_dri_drivers" = xno; then
1074     with_dri_drivers=''
1075 fi
1076
1077 dnl If $with_dri_drivers is yes, drivers will be added through
1078 dnl platform checks. Set DEFINES and LIB_DEPS
1079 if test "x$enable_dri" = xyes; then
1080     # Platform specific settings and drivers to build
1081     case "$host_os" in
1082     linux*)
1083         DEFINES="$DEFINES -DHAVE_ALIAS"
1084         if test "x$enable_dri3" = xyes; then
1085             DEFINES="$DEFINES -DHAVE_DRI3"
1086         fi
1087
1088         if test "x$have_pci_id" != xyes; then
1089             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1090         fi
1091
1092         case "$host_cpu" in
1093         powerpc* | sparc*)
1094             # Build only the drivers for cards that exist on PowerPC/sparc
1095             if test "x$with_dri_drivers" = "xyes"; then
1096                 with_dri_drivers="r200 radeon swrast"
1097             fi
1098             ;;
1099         esac
1100         ;;
1101     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1102         DEFINES="$DEFINES -DHAVE_PTHREAD"
1103         DEFINES="$DEFINES -DHAVE_ALIAS"
1104         ;;
1105     gnu*)
1106         DEFINES="$DEFINES -DHAVE_ALIAS"
1107         ;;
1108     cygwin*)
1109         if test "x$with_dri_drivers" = "xyes"; then
1110             with_dri_drivers="swrast"
1111         fi
1112         ;;
1113     darwin*)
1114         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1115         if test "x$with_dri_drivers" = "xyes"; then
1116             with_dri_drivers="swrast"
1117         fi
1118         ;;
1119     esac
1120
1121     # default drivers
1122     if test "x$with_dri_drivers" = "xyes"; then
1123         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1124     fi
1125
1126     # Check for expat
1127     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1128     if test "x$have_expat" = "xyes"; then
1129        PKG_CHECK_MODULES([EXPAT], [expat], [],
1130                          AC_MSG_ERROR([Expat required for DRI.]))
1131     else
1132        # expat version 2.0 and earlier do not provide expat.pc
1133        EXPAT_LIBS=-lexpat
1134     fi
1135
1136     DRICOMMON_NEED_LIBDRM=no
1137     # If we are building any DRI driver other than swrast.
1138     if test -n "$with_dri_drivers"; then
1139         if test "x$with_dri_drivers" != xswrast; then
1140             # ... libdrm is required
1141             if test "x$have_libdrm" != xyes; then
1142                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1143             fi
1144             DRICOMMON_NEED_LIBDRM=yes
1145         fi
1146     fi
1147
1148     # If we're building any gallium DRI driver other than swrast
1149     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1150         if test "x$with_gallium_drivers" != xswrast; then
1151             # ... build a libdrm aware dricommon
1152             DRICOMMON_NEED_LIBDRM=yes
1153         fi
1154     fi
1155
1156     # put all the necessary libs together
1157     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1158 fi
1159
1160 AC_SUBST([DRI_LIB_DEPS])
1161
1162 DRI_DIRS=''
1163 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1164 if test -n "$with_dri_drivers"; then
1165     if test "x$enable_opengl" != xyes; then
1166         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1167     fi
1168
1169     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1170     for driver in $dri_drivers; do
1171         DRI_DIRS="$DRI_DIRS $driver"
1172         case "x$driver" in
1173         xi915)
1174             HAVE_I915_DRI=yes;
1175             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1176             ;;
1177         xi965)
1178             HAVE_I965_DRI=yes;
1179             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1180             ;;
1181         xnouveau)
1182             HAVE_NOUVEAU_DRI=yes;
1183             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1184             ;;
1185         xradeon)
1186             HAVE_RADEON_DRI=yes;
1187             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1188             ;;
1189         xr200)
1190             HAVE_R200_DRI=yes;
1191             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1192             ;;
1193         xswrast)
1194             HAVE_SWRAST_DRI=yes;
1195             ;;
1196         *)
1197             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1198             ;;
1199         esac
1200     done
1201     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1202 fi
1203
1204 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1205 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1206                                   "x$enable_osmesa" = xyes -o \
1207                                   -n "$DRI_DIRS")
1208
1209 dnl
1210 dnl OSMesa configuration
1211 dnl
1212
1213 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1214 AC_ARG_WITH([osmesa-bits],
1215     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1216         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1217     [osmesa_bits="$withval"],
1218     [osmesa_bits=8])
1219 if test "x$osmesa_bits" != x8; then
1220     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1221         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1222         osmesa_bits=8
1223     fi
1224 fi
1225 case "x$osmesa_bits" in
1226 x8)
1227     OSMESA_LIB="${OSMESA_LIB}"
1228     ;;
1229 x16|x32)
1230     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1231     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1232     ;;
1233 *)
1234     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1235     ;;
1236 esac
1237
1238 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1239     # only link libraries with osmesa if shared
1240     if test "$enable_static" = no; then
1241         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1242     else
1243         OSMESA_LIB_DEPS=""
1244     fi
1245     OSMESA_MESA_DEPS=""
1246     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1247 fi
1248
1249 AC_SUBST([OSMESA_LIB_DEPS])
1250 AC_SUBST([OSMESA_MESA_DEPS])
1251 AC_SUBST([OSMESA_PC_REQ])
1252 AC_SUBST([OSMESA_PC_LIB_PRIV])
1253
1254 dnl
1255 dnl gbm configuration
1256 dnl
1257 if test "x$enable_gbm" = xauto; then
1258     case "$with_egl_platforms" in
1259         *drm*)
1260             enable_gbm=yes ;;
1261          *)
1262             enable_gbm=no ;;
1263     esac
1264 fi
1265 if test "x$enable_gbm" = xyes; then
1266     if test "x$need_pci_id$have_pci_id" = xyesno; then
1267         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1268     fi
1269
1270     if test "x$enable_dri" = xyes; then
1271         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1272         if test "x$enable_shared_glapi" = xno; then
1273             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1274         fi
1275     else
1276         # Strictly speaking libgbm does not require --enable-dri, although
1277         # both of its backends do. Thus one can build libgbm without any
1278         # backends if --disable-dri is set.
1279         # To avoid unnecessary complexity of checking if at least one backend
1280         # is available when building, just mandate --enable-dri.
1281         AC_MSG_ERROR([gbm requires --enable-dri])
1282     fi
1283 fi
1284 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1285 if test "x$need_pci_id$have_libudev" = xyesyes; then
1286     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1287 else
1288     GBM_PC_REQ_PRIV=""
1289 fi
1290 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1291 AC_SUBST([GBM_PC_REQ_PRIV])
1292 AC_SUBST([GBM_PC_LIB_PRIV])
1293
1294 dnl
1295 dnl EGL configuration
1296 dnl
1297 EGL_CLIENT_APIS=""
1298
1299 if test "x$enable_egl" = xyes; then
1300     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1301
1302     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1303
1304     if test "$enable_static" != yes; then
1305         if test "x$enable_dri" = xyes; then
1306             HAVE_EGL_DRIVER_DRI2=1
1307         fi
1308
1309     fi
1310 fi
1311 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1312 AC_SUBST([EGL_LIB_DEPS])
1313
1314 dnl
1315 dnl EGL Gallium configuration
1316 dnl
1317 if test "x$enable_gallium_egl" = xyes; then
1318     if test -z "$with_gallium_drivers"; then
1319         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1320     fi
1321     if test "x$enable_egl" = xno; then
1322         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1323     fi
1324     if test "x$have_libdrm" != xyes; then
1325         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1326     fi
1327
1328     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1329     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1330 #    enable_gallium_loader=yes
1331 fi
1332 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1333
1334 dnl
1335 dnl gbm Gallium configuration
1336 dnl
1337 if test "x$enable_gallium_gbm" = xauto; then
1338     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1339         yesyesyes*drm*)
1340             enable_gallium_gbm=yes ;;
1341          *)
1342             enable_gallium_gbm=no ;;
1343     esac
1344 fi
1345 if test "x$enable_gallium_gbm" = xyes; then
1346     if test -z "$with_gallium_drivers"; then
1347         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1348     fi
1349     if test "x$enable_gbm" = xno; then
1350         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1351     fi
1352     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1353     if test "x$enable_dri" = xno; then
1354         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1355     fi
1356
1357     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1358     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1359     enable_gallium_loader=yes
1360 fi
1361 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1362
1363 dnl
1364 dnl XA configuration
1365 dnl
1366 if test "x$enable_xa" = xyes; then
1367     if test "x$with_gallium_drivers" = xswrast; then
1368        AC_MSG_ERROR([
1369           Building xa requires at least one non swrast gallium driver.
1370           If you are looking to use libxatracker.so with the VMware driver,
1371           make sure to include svga in the gallium drivers list, apart from
1372           enabling XA.
1373           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1374     fi
1375     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1376     enable_gallium_loader=yes
1377 fi
1378 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1379
1380 dnl
1381 dnl OpenVG configuration
1382 dnl
1383 VG_LIB_DEPS=""
1384
1385 if test "x$enable_openvg" = xyes; then
1386     if test "x$enable_egl" = xno; then
1387         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1388     fi
1389     if test -z "$with_gallium_drivers"; then
1390         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1391     fi
1392     if test "x$enable_gallium_egl" = xno; then
1393         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1394     fi
1395
1396     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1397     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1398     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1399     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1400     AC_SUBST([VG_PC_LIB_PRIV])
1401 fi
1402 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1403
1404 dnl
1405 dnl Gallium G3DVL configuration
1406 dnl
1407 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1408     if test "x$enable_xvmc" = xauto; then
1409         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1410     fi
1411
1412     if test "x$enable_vdpau" = xauto; then
1413         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1414     fi
1415
1416     if test "x$enable_omx" = xauto; then
1417         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1418     fi
1419 fi
1420
1421 if test "x$enable_xvmc" = xyes; then
1422     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1423     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1424     enable_gallium_loader=yes
1425 fi
1426 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1427
1428 if test "x$enable_vdpau" = xyes; then
1429     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1430                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1431     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1432     enable_gallium_loader=yes
1433 fi
1434 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1435
1436 if test "x$enable_omx" = xyes; then
1437     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1438     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1439     enable_gallium_loader=yes
1440 fi
1441 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1442
1443 dnl
1444 dnl OpenCL configuration
1445 dnl
1446
1447 AC_ARG_WITH([libclc-path],
1448    [AS_HELP_STRING([--with-libclc-path],
1449          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1450    [LIBCLC_PATH="$withval"],
1451    [LIBCLC_PATH=''])
1452
1453 if test -n "$LIBCLC_PATH"; then
1454    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1455                   Please review the updated build instructions for clover:
1456                   http://dri.freedesktop.org/wiki/GalliumCompute])
1457 fi
1458
1459
1460 AC_ARG_WITH([clang-libdir],
1461    [AS_HELP_STRING([--with-clang-libdir],
1462          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1463    [CLANG_LIBDIR="$withval"],
1464    [CLANG_LIBDIR=''])
1465
1466 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1467
1468 if test "x$enable_opencl" = xyes; then
1469     if test -z "$with_gallium_drivers"; then
1470         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1471     fi
1472
1473     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1474         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1475     fi
1476
1477     if test "x$have_libclc" = xno; then
1478         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1479                     Make sure the directory containing libclc.pc is specified in your
1480                     PKG_CONFIG_PATH environment variable.
1481                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1482     else
1483         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1484         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1485         AC_SUBST([LIBCLC_INCLUDEDIR])
1486         AC_SUBST([LIBCLC_LIBEXECDIR])
1487     fi
1488
1489     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1490     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1491     enable_gallium_loader=yes
1492
1493     if test "x$enable_opencl_icd" = xyes; then
1494         OPENCL_LIBNAME="MesaOpenCL"
1495     else
1496         OPENCL_LIBNAME="OpenCL"
1497     fi
1498 fi
1499 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1500 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1501 AC_SUBST([OPENCL_LIBNAME])
1502
1503 dnl
1504 dnl Gallium configuration
1505 dnl
1506 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1507
1508 AC_SUBST([LLVM_BINDIR])
1509 AC_SUBST([LLVM_CFLAGS])
1510 AC_SUBST([LLVM_CPPFLAGS])
1511 AC_SUBST([LLVM_CXXFLAGS])
1512 AC_SUBST([LLVM_LIBDIR])
1513 AC_SUBST([LLVM_LIBS])
1514 AC_SUBST([LLVM_LDFLAGS])
1515 AC_SUBST([LLVM_INCLUDEDIR])
1516 AC_SUBST([LLVM_VERSION])
1517 AC_SUBST([CLANG_RESOURCE_DIR])
1518
1519 case "x$enable_opengl$enable_gles1$enable_gles2" in
1520 x*yes*)
1521     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1522     ;;
1523 esac
1524
1525 AC_SUBST([VG_LIB_DEPS])
1526 AC_SUBST([EGL_CLIENT_APIS])
1527
1528 dnl
1529 dnl EGL Platforms configuration
1530 dnl
1531 AC_ARG_WITH([egl-platforms],
1532     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1533         [comma delimited native platforms libEGL supports, e.g.
1534         "x11,drm" @<:@default=auto@:>@])],
1535     [with_egl_platforms="$withval"],
1536     [if test "x$enable_egl" = xyes; then
1537         with_egl_platforms="x11"
1538     else
1539         with_egl_platforms=""
1540     fi])
1541
1542 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1543     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1544 fi
1545
1546 # Do per-EGL platform setups and checks
1547 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1548 for plat in $egl_platforms; do
1549         case "$plat" in
1550         wayland)
1551                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1552                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1553
1554                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1555                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1556                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1557                 ;;
1558
1559         x11)
1560                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1561                 ;;
1562
1563         drm)
1564                 test "x$enable_gbm" = "xno" &&
1565                         AC_MSG_ERROR([EGL platform drm needs gbm])
1566                 test "x$have_libdrm" != xyes &&
1567                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1568                 ;;
1569
1570         android|fbdev|gdi|null)
1571                 ;;
1572
1573         *)
1574                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1575                 ;;
1576         esac
1577
1578         case "$plat$need_pci_id$have_pci_id" in
1579                 waylandyesno|drmyesno)
1580                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1581         esac
1582 done
1583
1584 # libEGL wants to default to the first platform specified in
1585 # ./configure.  parse that here.
1586 if test "x$egl_platforms" != "x"; then
1587     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1588     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1589 else
1590     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1591 fi
1592
1593 if echo "$egl_platforms" | grep -q 'x11'; then
1594     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1595     NEED_WINSYS_XLIB=yes
1596 fi
1597 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1598 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1599 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1600 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1601 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1602
1603 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1604
1605 AC_SUBST([EGL_NATIVE_PLATFORM])
1606 AC_SUBST([EGL_CFLAGS])
1607
1608 # If we don't have the X11 platform, set this define so we don't try to include
1609 # the X11 headers.
1610 if ! echo "$egl_platforms" | grep -q 'x11'; then
1611     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1612     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1613 fi
1614
1615 AC_ARG_WITH([egl-driver-dir],
1616     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1617                     [directory for EGL drivers @<:@default=${libdir}/egl@:>@])],
1618     [EGL_DRIVER_INSTALL_DIR="$withval"],
1619     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1620 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1621
1622 AC_ARG_WITH([max-width],
1623     [AS_HELP_STRING([--with-max-width=N],
1624                     [Maximum framebuffer width (4096)])],
1625     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1626      AS_IF([test "${withval}" -gt "4096"],
1627            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1628 )
1629 AC_ARG_WITH([max-height],
1630     [AS_HELP_STRING([--with-max-height=N],
1631                     [Maximum framebuffer height (4096)])],
1632     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1633      AS_IF([test "${withval}" -gt "4096"],
1634            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1635 )
1636
1637 dnl
1638 dnl Gallium LLVM
1639 dnl
1640 AC_ARG_ENABLE([gallium-llvm],
1641     [AS_HELP_STRING([--enable-gallium-llvm],
1642         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1643     [enable_gallium_llvm="$enableval"],
1644     [enable_gallium_llvm=auto])
1645
1646 AC_ARG_ENABLE([llvm-shared-libs],
1647     [AS_HELP_STRING([--enable-llvm-shared-libs],
1648         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1649     [enable_llvm_shared_libs="$enableval"],
1650     [enable_llvm_shared_libs=yes])
1651
1652 AC_ARG_WITH([llvm-prefix],
1653     [AS_HELP_STRING([--with-llvm-prefix],
1654         [Prefix for LLVM installations in non-standard locations])],
1655     [llvm_prefix="$withval"],
1656     [llvm_prefix=''])
1657
1658
1659 # Call this inside ` ` to get the return value.
1660 # $1 is the llvm-config command with arguments.
1661 strip_unwanted_llvm_flags() {
1662     # Use \> (marks the end of the word)
1663     echo `$1` | sed \
1664         -e 's/-DNDEBUG\>//g' \
1665         -e 's/-pedantic\>//g' \
1666         -e 's/-Wcovered-switch-default\>//g' \
1667         -e 's/-O.\>//g' \
1668         -e 's/-g\>//g' \
1669         -e 's/-Wall\>//g' \
1670         -e 's/-Wcast-qual\>//g' \
1671         -e 's/-Woverloaded-virtual\>//g' \
1672         -e 's/-fcolor-diagnostics\>//g' \
1673         -e 's/-fdata-sections\>//g' \
1674         -e 's/-ffunction-sections\>//g' \
1675         -e 's/-fno-exceptions\>//g' \
1676         -e 's/-fomit-frame-pointer\>//g' \
1677         -e 's/-fvisibility-inlines-hidden\>//g' \
1678         -e 's/-fPIC\>//g' \
1679         -e 's/-fstack-protector-strong\>//g'
1680 }
1681
1682
1683 if test -z "$with_gallium_drivers"; then
1684     enable_gallium_llvm=no
1685 fi
1686 if test "x$enable_gallium_llvm" = xauto; then
1687     case "$host_cpu" in
1688     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1689     esac
1690 fi
1691 if test "x$enable_gallium_llvm" = xyes; then
1692     if test -n "$llvm_prefix"; then
1693         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1694     else
1695         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1696     fi
1697
1698     if test "x$LLVM_CONFIG" != xno; then
1699         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1700         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1701         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1702         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1703         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1704         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1705         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1706         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1707
1708         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1709             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1710         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1711             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1712
1713         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1714         dnl llvm-config.h
1715         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1716             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1717             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1718
1719         if test -n "${LLVM_VERSION_MAJOR}"; then
1720             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1721         else
1722             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1723         fi
1724
1725         LLVM_REQUIRED_VERSION_MAJOR="3"
1726         LLVM_REQUIRED_VERSION_MINOR="1"
1727         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1728             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1729         fi
1730
1731         LLVM_COMPONENTS="engine bitwriter"
1732         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1733             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1734         fi
1735
1736         if test "x$enable_opencl" = xyes; then
1737             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1738             # LLVM 3.3 >= 177971 requires IRReader
1739             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1740                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1741             fi
1742             # LLVM 3.4 requires Option
1743             if $LLVM_CONFIG --components | grep -qw 'option'; then
1744                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1745             fi
1746             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1747             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1748                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1749             fi
1750             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1751                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1752             fi
1753         fi
1754         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1755         MESA_LLVM=1
1756
1757         dnl Check for Clang internal headers
1758         if test "x$enable_opencl" = xyes; then
1759             if test -z "$CLANG_LIBDIR"; then
1760                 CLANG_LIBDIR=${LLVM_LIBDIR}
1761             fi
1762             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1763             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1764                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1765         fi
1766     else
1767         MESA_LLVM=0
1768         LLVM_VERSION_INT=0
1769     fi
1770 else
1771     MESA_LLVM=0
1772     LLVM_VERSION_INT=0
1773
1774     if test "x$enable_opencl" = xyes; then
1775         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1776     fi
1777 fi
1778
1779 dnl Directory for XVMC libs
1780 AC_ARG_WITH([xvmc-libdir],
1781     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1782         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1783     [XVMC_LIB_INSTALL_DIR="$withval"],
1784     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1785 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1786
1787 dnl
1788 dnl Gallium Tests
1789 dnl
1790 if test "x$enable_gallium_tests" = xyes; then
1791     enable_gallium_loader=yes
1792 fi
1793 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1794
1795 if test "x$enable_gallium_loader" = xyes; then
1796     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1797 fi
1798 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1799
1800 dnl Directory for VDPAU libs
1801 AC_ARG_WITH([vdpau-libdir],
1802     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1803         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1804     [VDPAU_LIB_INSTALL_DIR="$withval"],
1805     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1806 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1807
1808 OMX_LIB_INSTALL_DIR_DEFAULT=''
1809 if test "x$enable_omx" = xyes; then
1810     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1811 fi
1812
1813 AC_ARG_WITH([omx-libdir],
1814     [AS_HELP_STRING([--with-omx-libdir=DIR],
1815         [directory for the OMX libraries])],
1816     [OMX_LIB_INSTALL_DIR="$withval"],
1817     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1818 AC_SUBST([OMX_LIB_INSTALL_DIR])
1819
1820 dnl Directory for OpenCL libs
1821 AC_ARG_WITH([opencl-libdir],
1822     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1823         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1824     [OPENCL_LIB_INSTALL_DIR="$withval"],
1825     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1826 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1827
1828 dnl
1829 dnl Gallium helper functions
1830 dnl
1831 gallium_check_st() {
1832     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1833          if test "x$have_libdrm" != xyes; then
1834             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1835          fi
1836          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1837     fi
1838     if test "x$enable_dri" = xyes && test -n "$2"; then
1839          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1840     fi
1841     if test "x$enable_xa" = xyes && test -n "$3"; then
1842          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1843     fi
1844     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1845          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1846     fi
1847     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1848          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1849     fi
1850     if test "x$enable_omx" = xyes && test "x$6" != x; then
1851          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1852     fi
1853 }
1854
1855 gallium_require_llvm() {
1856     if test "x$MESA_LLVM" = x0; then
1857         case "$host_cpu" in
1858         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1859         esac
1860     fi
1861 }
1862
1863 gallium_require_drm_loader() {
1864     if test "x$enable_gallium_loader" = xyes; then
1865         if test "x$need_pci_id$have_pci_id" = xyesno; then
1866             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1867         fi
1868         if test "x$have_libdrm" != xyes; then
1869             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1870         fi
1871         enable_gallium_drm_loader=yes
1872     fi
1873 }
1874
1875 require_egl_drm() {
1876     case "$with_egl_platforms" in
1877         *drm*)
1878             ;;
1879          *)
1880             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1881             ;;
1882     esac
1883     if test "x$enable_gbm" != xyes; then
1884             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1885     fi
1886 }
1887
1888 radeon_llvm_check() {
1889     if test "x$enable_gallium_llvm" != "xyes"; then
1890         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1891     fi
1892     LLVM_REQUIRED_VERSION_MAJOR="3"
1893     LLVM_REQUIRED_VERSION_MINOR="4"
1894     LLVM_REQUIRED_VERSION_PATCH="2"
1895     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1896         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1897     fi
1898     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1899         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1900                       sources with the --enable-experimental-targets=R600
1901                       configure flag])
1902     fi
1903     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1904     NEED_RADEON_LLVM=yes
1905     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1906                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1907 }
1908
1909 dnl Gallium drivers
1910 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1911         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1912     NEED_NONNULL_WINSYS=yes
1913 fi
1914 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1915
1916 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1917 if test -n "$with_gallium_drivers"; then
1918     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1919     for driver in $gallium_drivers; do
1920         case "x$driver" in
1921         xsvga)
1922             HAVE_GALLIUM_SVGA=yes
1923             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1924             gallium_require_drm_loader
1925             gallium_check_st "svga/drm" "dri/vmwgfx" "xa/vmwgfx"
1926             ;;
1927         xi915)
1928             HAVE_GALLIUM_I915=yes
1929             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1930             gallium_require_drm_loader
1931             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1932             gallium_check_st "i915/drm" "dri/i915" "xa/i915"
1933             ;;
1934         xilo)
1935             HAVE_GALLIUM_ILO=yes
1936             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1937             gallium_require_drm_loader
1938             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1939             gallium_check_st "intel/drm" "dri/ilo" "xa/ilo"
1940             ;;
1941         xr300)
1942             HAVE_GALLIUM_R300=yes
1943             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1944             gallium_require_drm_loader
1945             gallium_require_llvm "Gallium R300"
1946             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1947             gallium_check_st "radeon/drm" "dri/r300"
1948             ;;
1949         xr600)
1950             HAVE_GALLIUM_R600=yes
1951             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1952             gallium_require_drm_loader
1953             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1954             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1955                 radeon_llvm_check "r600g"
1956                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1957             fi
1958             if test "x$enable_r600_llvm" = xyes; then
1959                 USE_R600_LLVM_COMPILER=yes;
1960             fi
1961             if test "x$enable_opencl" = xyes; then
1962                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1963             fi
1964             gallium_check_st "radeon/drm" "dri/r600" "" "xvmc/r600" "vdpau/r600" "omx/r600"
1965             ;;
1966         xradeonsi)
1967             HAVE_GALLIUM_RADEONSI=yes
1968             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1969             gallium_require_drm_loader
1970             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1971             radeon_llvm_check "radeonsi"
1972             require_egl_drm "radeonsi"
1973             gallium_check_st "radeon/drm" "dri/radeonsi" "" "" "vdpau/radeonsi" "omx/radeonsi"
1974             ;;
1975         xnouveau)
1976             HAVE_GALLIUM_NOUVEAU=yes
1977             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1978             gallium_require_drm_loader
1979             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1980             gallium_check_st "nouveau/drm" "dri/nouveau" "xa/nouveau" "xvmc/nouveau" "vdpau/nouveau" "omx/nouveau"
1981             ;;
1982         xfreedreno)
1983             HAVE_GALLIUM_FREEDRENO=yes
1984             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1985             gallium_require_drm_loader
1986             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1987             gallium_check_st "freedreno/drm" "dri/freedreno" "xa/freedreno" "" ""
1988             ;;
1989         xswrast)
1990             HAVE_GALLIUM_SOFTPIPE=yes
1991             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1992             if test "x$MESA_LLVM" = x1; then
1993                 HAVE_GALLIUM_LLVMPIPE=yes
1994                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1995             fi
1996
1997             if test "x$enable_dri" = xyes; then
1998                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/swrast"
1999             fi
2000
2001             if test "x$have_libdrm" = xyes; then
2002                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/kms-swrast"
2003             fi
2004             ;;
2005         *)
2006             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2007             ;;
2008         esac
2009     done
2010 fi
2011
2012 dnl Set LLVM_LIBS - This is done after the driver configuration so
2013 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2014 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2015 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2016 dnl this was causing the same libraries to be appear multiple times
2017 dnl in LLVM_LIBS.
2018
2019 if test "x$MESA_LLVM" != x0; then
2020
2021     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2022
2023     if test "x$enable_llvm_shared_libs" = xyes; then
2024         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2025         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2026         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2027
2028         if test "x$llvm_have_one_so" = xyes; then
2029             dnl LLVM was built using auto*, so there is only one shared object.
2030             LLVM_LIBS="-l$LLVM_SO_NAME"
2031         else
2032             dnl If LLVM was built with CMake, there will be one shared object per
2033             dnl component.
2034             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2035                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2036         Please make sure you have built llvm with the --enable-shared option
2037         and that your llvm libraries are installed in $LLVM_LIBDIR
2038         If you have installed your llvm libraries to a different directory you
2039         can use the --with-llvm-prefix= configure flag to specify this directory.
2040         NOTE: Mesa is attempting to use llvm shared libraries by default.
2041         If you do not want to build with llvm shared libraries and instead want to
2042         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2043         invocation and rebuild.])])
2044
2045            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2046            dnl install uses a shared object for each compoenent and we have
2047            dnl already added all of these objects to LLVM_LIBS.
2048         fi
2049     else
2050         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2051     fi
2052 fi
2053
2054 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2055 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2056 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2057 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2058 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2059 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2060 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2061                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2062 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2063 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2064 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2065 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2066
2067 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2068                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2069 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2070                                                   && test "x$MESA_LLVM" = x1)
2071
2072 # Enable static gallium targets for now.
2073 # Do not touch this unless you know what you are doing.
2074 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "xyes" = xyes)
2075
2076 # NOTE: anything using xcb or other client side libs ends up in separate
2077 #       _CLIENT variables.  The pipe loader is built in two variants,
2078 #       one that is standalone and does not link any x client libs (for
2079 #       use by XA tracker in particular, but could be used in any case
2080 #       where communication with xserver is not desired).
2081 if test "x$enable_gallium_loader" = xyes; then
2082     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2083
2084     if test "x$NEED_WINSYS_XLIB" = xyes; then
2085         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2086     fi
2087
2088     if test "x$enable_dri" = xyes; then
2089         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2090     fi
2091
2092     if test "x$enable_gallium_drm_loader" = xyes; then
2093         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2094         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2095                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2096         if test "x$pipe_loader_have_xcb" = xyes; then
2097             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2098             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2099         fi
2100     fi
2101
2102     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2103     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2104
2105     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2106     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2107     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2108     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2109 fi
2110
2111 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2112 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2113 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2114 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2115 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2116 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2117
2118 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2119                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2120                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2121                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2122 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2123                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2124 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2125 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2126 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2127 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2128 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2129 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2130 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2131
2132 AC_SUBST([ELF_LIB])
2133
2134 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2135 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2136 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2137 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2138 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2139
2140 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2141 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2142 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2143
2144 AC_SUBST([VDPAU_MAJOR], 1)
2145 AC_SUBST([VDPAU_MINOR], 0)
2146
2147 AC_SUBST([XVMC_MAJOR], 1)
2148 AC_SUBST([XVMC_MINOR], 0)
2149
2150 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2151 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2152 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2153 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2154
2155 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2156 AC_SUBST([XA_MINOR], $XA_MINOR)
2157 AC_SUBST([XA_TINY], $XA_TINY)
2158 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2159
2160 dnl Restore LDFLAGS and CPPFLAGS
2161 LDFLAGS="$_SAVE_LDFLAGS"
2162 CPPFLAGS="$_SAVE_CPPFLAGS"
2163
2164 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2165 if test "x$acv_mesa_CLANG" = xyes; then
2166     CFLAGS="$CFLAGS -Qunused-arguments"
2167     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2168 fi
2169
2170 dnl Add user CFLAGS and CXXFLAGS
2171 CFLAGS="$CFLAGS $USER_CFLAGS"
2172 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2173
2174 dnl Substitute the config
2175 AC_CONFIG_FILES([Makefile
2176                 src/Makefile
2177                 src/egl/drivers/dri2/Makefile
2178                 src/egl/main/Makefile
2179                 src/egl/main/egl.pc
2180                 src/egl/wayland/Makefile
2181                 src/egl/wayland/wayland-drm/Makefile
2182                 src/egl/wayland/wayland-egl/Makefile
2183                 src/egl/wayland/wayland-egl/wayland-egl.pc
2184                 src/gallium/auxiliary/Makefile
2185                 src/gallium/auxiliary/pipe-loader/Makefile
2186                 src/gallium/drivers/Makefile
2187                 src/gallium/drivers/freedreno/Makefile
2188                 src/gallium/drivers/galahad/Makefile
2189                 src/gallium/drivers/i915/Makefile
2190                 src/gallium/drivers/identity/Makefile
2191                 src/gallium/drivers/ilo/Makefile
2192                 src/gallium/drivers/llvmpipe/Makefile
2193                 src/gallium/drivers/noop/Makefile
2194                 src/gallium/drivers/nouveau/Makefile
2195                 src/gallium/drivers/r300/Makefile
2196                 src/gallium/drivers/r600/Makefile
2197                 src/gallium/drivers/radeon/Makefile
2198                 src/gallium/drivers/radeonsi/Makefile
2199                 src/gallium/drivers/rbug/Makefile
2200                 src/gallium/drivers/softpipe/Makefile
2201                 src/gallium/drivers/svga/Makefile
2202                 src/gallium/drivers/trace/Makefile
2203                 src/gallium/state_trackers/Makefile
2204                 src/gallium/state_trackers/clover/Makefile
2205                 src/gallium/state_trackers/dri/Makefile
2206                 src/gallium/state_trackers/egl/Makefile
2207                 src/gallium/state_trackers/gbm/Makefile
2208                 src/gallium/state_trackers/glx/xlib/Makefile
2209                 src/gallium/state_trackers/omx/Makefile
2210                 src/gallium/state_trackers/osmesa/Makefile
2211                 src/gallium/state_trackers/vdpau/Makefile
2212                 src/gallium/state_trackers/vega/Makefile
2213                 src/gallium/state_trackers/xa/Makefile
2214                 src/gallium/state_trackers/xvmc/Makefile
2215                 src/gallium/targets/Makefile
2216                 src/gallium/targets/dri/Makefile
2217                 src/gallium/targets/egl-static/Makefile
2218                 src/gallium/targets/gbm/Makefile
2219                 src/gallium/targets/libgl-xlib/Makefile
2220                 src/gallium/targets/omx/Makefile
2221                 src/gallium/targets/opencl/Makefile
2222                 src/gallium/targets/osmesa/Makefile
2223                 src/gallium/targets/osmesa/osmesa.pc
2224                 src/gallium/targets/pipe-loader/Makefile
2225                 src/gallium/targets/vdpau/Makefile
2226                 src/gallium/targets/xa/Makefile
2227                 src/gallium/targets/xa/xatracker.pc
2228                 src/gallium/targets/xvmc/Makefile
2229                 src/gallium/tests/trivial/Makefile
2230                 src/gallium/tests/unit/Makefile
2231                 src/gallium/winsys/Makefile
2232                 src/gallium/winsys/freedreno/drm/Makefile
2233                 src/gallium/winsys/i915/drm/Makefile
2234                 src/gallium/winsys/intel/drm/Makefile
2235                 src/gallium/winsys/nouveau/drm/Makefile
2236                 src/gallium/winsys/radeon/drm/Makefile
2237                 src/gallium/winsys/svga/drm/Makefile
2238                 src/gallium/winsys/sw/dri/Makefile
2239                 src/gallium/winsys/sw/fbdev/Makefile
2240                 src/gallium/winsys/sw/kms-dri/Makefile
2241                 src/gallium/winsys/sw/null/Makefile
2242                 src/gallium/winsys/sw/wayland/Makefile
2243                 src/gallium/winsys/sw/wrapper/Makefile
2244                 src/gallium/winsys/sw/xlib/Makefile
2245                 src/gbm/Makefile
2246                 src/gbm/main/gbm.pc
2247                 src/glsl/Makefile
2248                 src/glx/Makefile
2249                 src/glx/apple/Makefile
2250                 src/glx/tests/Makefile
2251                 src/gtest/Makefile
2252                 src/loader/Makefile
2253                 src/mapi/Makefile
2254                 src/mapi/es1api/Makefile
2255                 src/mapi/es1api/glesv1_cm.pc
2256                 src/mapi/es2api/Makefile
2257                 src/mapi/es2api/glesv2.pc
2258                 src/mapi/glapi/Makefile
2259                 src/mapi/glapi/gen/Makefile
2260                 src/mapi/glapi/tests/Makefile
2261                 src/mapi/shared-glapi/Makefile
2262                 src/mapi/shared-glapi/tests/Makefile
2263                 src/mapi/vgapi/Makefile
2264                 src/mapi/vgapi/vg.pc
2265                 src/mesa/Makefile
2266                 src/mesa/gl.pc
2267                 src/mesa/drivers/dri/dri.pc
2268                 src/mesa/drivers/dri/common/Makefile
2269                 src/mesa/drivers/dri/common/xmlpool/Makefile
2270                 src/mesa/drivers/dri/i915/Makefile
2271                 src/mesa/drivers/dri/i965/Makefile
2272                 src/mesa/drivers/dri/Makefile
2273                 src/mesa/drivers/dri/nouveau/Makefile
2274                 src/mesa/drivers/dri/r200/Makefile
2275                 src/mesa/drivers/dri/radeon/Makefile
2276                 src/mesa/drivers/dri/swrast/Makefile
2277                 src/mesa/drivers/osmesa/Makefile
2278                 src/mesa/drivers/osmesa/osmesa.pc
2279                 src/mesa/drivers/x11/Makefile
2280                 src/mesa/main/tests/Makefile
2281                 src/util/Makefile
2282                 src/util/tests/hash_table/Makefile])
2283
2284 dnl Sort the dirs alphabetically
2285 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2286 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2287 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2288 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2289
2290 AC_OUTPUT
2291
2292 dnl
2293 dnl Output some configuration info for the user
2294 dnl
2295 echo ""
2296 echo "        prefix:          $prefix"
2297 echo "        exec_prefix:     $exec_prefix"
2298 echo "        libdir:          $libdir"
2299 echo "        includedir:      $includedir"
2300
2301 dnl API info
2302 echo ""
2303 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2304 echo "        OpenVG:          $enable_openvg"
2305
2306 dnl Driver info
2307 echo ""
2308 case "x$enable_osmesa$enable_gallium_osmesa" in
2309 xnoyes)
2310         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2311         ;;
2312 xyesno)
2313         echo "        OSMesa:          lib$OSMESA_LIB"
2314         ;;
2315 xnono)
2316         echo "        OSMesa:          no"
2317         ;;
2318 esac
2319
2320 echo ""
2321 if test "x$enable_dri" != xno; then
2322         echo "        DRI platform:    $dri_platform"
2323         if test -z "$DRI_DIRS"; then
2324             echo "        DRI drivers:     no"
2325         else
2326             echo "        DRI drivers:     $DRI_DIRS"
2327         fi
2328         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2329 fi
2330
2331 case "x$enable_glx$enable_xlib_glx" in
2332 xyesyes)
2333     echo "        GLX:             Xlib-based"
2334     ;;
2335 xyesno)
2336     echo "        GLX:             DRI-based"
2337     ;;
2338 *)
2339     echo "        GLX:             $enable_glx"
2340     ;;
2341 esac
2342
2343 dnl EGL
2344 echo ""
2345 echo "        EGL:             $enable_egl"
2346 if test "$enable_egl" = yes; then
2347     echo "        EGL platforms:   $egl_platforms"
2348
2349     egl_drivers=""
2350     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2351         egl_drivers="$egl_drivers builtin:egl_dri2"
2352     fi
2353
2354     if test "x$enable_gallium_egl" = xyes; then
2355         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2356         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2357     else
2358         echo "        EGL drivers:    $egl_drivers"
2359     fi
2360 fi
2361
2362 echo ""
2363 if test "x$MESA_LLVM" = x1; then
2364     echo "        llvm:            yes"
2365     echo "        llvm-config:     $LLVM_CONFIG"
2366     echo "        llvm-version:    $LLVM_VERSION"
2367 else
2368     echo "        llvm:            no"
2369 fi
2370
2371 echo ""
2372 if test -n "$with_gallium_drivers"; then
2373     echo "        Gallium:         yes"
2374     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2375     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2376     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2377     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2378 else
2379     echo "        Gallium:         no"
2380 fi
2381
2382
2383 dnl Libraries
2384 echo ""
2385 echo "        Shared libs:     $enable_shared"
2386 echo "        Static libs:     $enable_static"
2387 echo "        Shared-glapi:    $enable_shared_glapi"
2388
2389 dnl Compiler options
2390 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2391 cflags=`echo $CFLAGS | \
2392     $SED 's/^ *//;s/  */ /;s/ *$//'`
2393 cxxflags=`echo $CXXFLAGS | \
2394     $SED 's/^ *//;s/  */ /;s/ *$//'`
2395 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2396 echo ""
2397 echo "        CFLAGS:          $cflags"
2398 echo "        CXXFLAGS:        $cxxflags"
2399 echo "        Macros:          $defines"
2400 echo ""
2401 if test "x$MESA_LLVM" = x1; then
2402     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2403     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2404     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2405     echo ""
2406 fi
2407 echo "        PYTHON2:         $PYTHON2"
2408
2409 echo ""
2410 echo "        Run '${MAKE-make}' to build Mesa"
2411 echo ""