configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.59],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  33 AM_MAINTAINER_MODE([enable])
  34
  35 # Enable quiet compiles on automake 1.11.
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 # Check for programs
  39 AC_PROG_CC
  40
  41 AC_USE_SYSTEM_EXTENSIONS
  42 AC_SYS_LARGEFILE
  43 AC_FUNC_ALLOCA
  44
  45 AC_CHECK_HEADERS([sys/mkdev.h])
  46
  47 # Initialize libtool
  48 LT_PREREQ([2.2])
  49 LT_INIT([disable-static])
  50
  51
  52 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  53 AC_SUBST(PTHREADSTUBS_CFLAGS)
  54 AC_SUBST(PTHREADSTUBS_LIBS)
  55
  56 pkgconfigdir=${libdir}/pkgconfig
  57 AC_SUBST(pkgconfigdir)
  58 AC_ARG_ENABLE([udev],
  59               [AS_HELP_STRING([--enable-udev],
  60                               [Enable support for using udev instead of mknod (default: disabled)])],
  61               [UDEV=$enableval], [UDEV=no])
  62
  63 AC_ARG_ENABLE(libkms,
  64               AS_HELP_STRING([--disable-libkms],
  65               [Disable KMS mm abstraction library (default: auto, enabled on x86]),
  66               [LIBKMS=$enableval], [LIBKMS=auto])
  67
  68 AC_ARG_ENABLE(intel,
  69               AS_HELP_STRING([--disable-intel],
  70               [Enable support for intel's KMS API (default: auto)]),
  71               [INTEL=$enableval], [INTEL=auto])
  72
  73 AC_ARG_ENABLE(radeon,
  74               AS_HELP_STRING([--disable-radeon],
  75               [Enable support for radeon's KMS API (default: auto)]),
  76               [RADEON=$enableval], [RADEON=auto])
  77
  78 AC_ARG_ENABLE(nouveau,
  79               AS_HELP_STRING([--disable-nouveau],
  80               [Enable support for nouveau's KMS API (default: auto)]),
  81               [NOUVEAU=$enableval], [NOUVEAU=auto])
  82
  83 AC_ARG_ENABLE(vmwgfx,
  84               AS_HELP_STRING([--disable-vmwgfx],
  85               [Enable support for vmwgfx's KMS API (default: yes)]),
  86               [VMWGFX=$enableval], [VMWGFX=yes])
  87
  88 AC_ARG_ENABLE(omap-experimental-api,
  89               AS_HELP_STRING([--enable-omap-experimental-api],
  90               [Enable support for OMAP's experimental API (default: disabled)]),
  91               [OMAP=$enableval], [OMAP=no])
  92
  93 AC_ARG_ENABLE(exynos-experimental-api,
  94               AS_HELP_STRING([--enable-exynos-experimental-api],
  95               [Enable support for EXYNOS's experimental API (default: disabled)]),
  96               [EXYNOS=$enableval], [EXYNOS=no])
  97
  98 AC_ARG_ENABLE(freedreno,
  99               AS_HELP_STRING([--disable-freedreno],
 100               [Enable support for freedreno's KMS API (default: auto, enabled on arm)]),
 101               [FREEDRENO=$enableval], [FREEDRENO=auto])
 102
 103 AC_ARG_ENABLE(freedreno-kgsl,
 104               AS_HELP_STRING([--enable-freedreno-kgsl],
 105               [Enable support for freedreno's to use downstream android kernel API (default: disabled)]),
 106               [FREEDRENO_KGSL=$enableval], [FREEDRENO_KGSL=no])
 107
 108 AC_ARG_ENABLE(tegra-experimental-api,
 109               AS_HELP_STRING([--enable-tegra-experimental-api],
 110               [Enable support for Tegra's experimental API (default: disabled)]),
 111               [TEGRA=$enableval], [TEGRA=no])
 112
 113 AC_ARG_ENABLE(install-test-programs,
 114                   AS_HELP_STRING([--enable-install-test-programs],
 115                   [Install test programs (default: no)]),
 116                   [INSTALL_TESTS=$enableval], [INSTALL_TESTS=no])
 117
 118 dnl ===========================================================================
 119 dnl check compiler flags
 120 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 121   AC_MSG_CHECKING([whether $CC supports $1])
 122
 123   libdrm_save_CFLAGS="$CFLAGS"
 124   CFLAGS="$CFLAGS $1"
 125
 126   AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 127   CFLAGS="$libdrm_save_CFLAGS"
 128
 129   if test "x$libdrm_cc_flag" = "xyes"; then
 130     ifelse([$2], , :, [$2])
 131   else
 132     ifelse([$3], , :, [$3])
 133   fi
 134   AC_MSG_RESULT([$libdrm_cc_flag])
 135 ])
 136
 137 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 138
 139 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 140                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 141                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 142 AC_SUBST([CLOCK_LIB])
 143
 144 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 145
 146 dnl Use lots of warning flags with with gcc and compatible compilers
 147
 148 dnl Note: if you change the following variable, the cache is automatically
 149 dnl skipped and all flags rechecked.  So there's no need to do anything
 150 dnl else.  If for any reason you need to force a recheck, just change
 151 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 152
 153 MAYBE_WARN="-Wall -Wextra \
 154 -Wsign-compare -Werror-implicit-function-declaration \
 155 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 156 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 157 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 158 -Wstrict-aliasing=2 -Winit-self \
 159 -Wdeclaration-after-statement -Wold-style-definition \
 160 -Wno-missing-field-initializers -Wno-unused-parameter \
 161 -Wno-attributes -Wno-long-long -Winline"
 162
 163 # invalidate cached value if MAYBE_WARN has changed
 164 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 165         unset libdrm_cv_warn_cflags
 166 fi
 167 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 168         echo
 169         WARN_CFLAGS=""
 170
 171         # Some warning options are not supported by all versions of
 172         # gcc, so test all desired options against the current
 173         # compiler.
 174         #
 175         # Note that there are some order dependencies
 176         # here. Specifically, an option that disables a warning will
 177         # have no net effect if a later option then enables that
 178         # warnings, (perhaps implicitly). So we put some grouped
 179         # options (-Wall and -Wextra) up front and the -Wno options
 180         # last.
 181
 182         for W in $MAYBE_WARN; do
 183                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 184         done
 185
 186         libdrm_cv_warn_cflags=$WARN_CFLAGS
 187         libdrm_cv_warn_maybe=$MAYBE_WARN
 188
 189         AC_MSG_CHECKING([which warning flags were supported])])
 190 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 191
 192 # Check for atomic intrinsics
 193 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives, [
 194         drm_cv_atomic_primitives="none"
 195
 196         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 197         int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 198         int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 199                                           ]],[[]])], [drm_cv_atomic_primitives="Intel"],[])
 200
 201         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 202                 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 203         fi
 204
 205         # atomic functions defined in <atomic.h> & libc on Solaris
 206         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 207                 AC_CHECK_FUNC([atomic_cas_uint], drm_cv_atomic_primitives="Solaris")
 208         fi
 209 ])
 210
 211 if test "x$drm_cv_atomic_primitives" = xIntel; then
 212         AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 213                 [Enable if your compiler supports the Intel __sync_* atomic primitives])
 214 fi
 215 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 216         AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 217 fi
 218
 219 if test "x$INTEL" != "xno" -o \
 220         "x$RADEON" != "xno" -o \
 221         "x$NOUVEAU" != "xno" -o \
 222         "x$OMAP" != "xno" -o \
 223         "x$FREEDRENO" != "xno" -o \
 224         "x$TEGRA" != "xno"; then
 225         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 226                 if test "x$INTEL" != "xauto"; then
 227                         if test "x$INTEL" != "xno"; then
 228                                 AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
 229                         fi
 230                 else
 231                         AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 232                         INTEL=no
 233                 fi
 234                 if test "x$RADEON" != "xauto"; then
 235                         if test "x$RADEON" != "xno"; then
 236                                 AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon GPUs by passing --disable-radeon to ./configure])
 237                         fi
 238                 else
 239                         AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 240                         RADEON=no
 241                 fi
 242                 if test "x$NOUVEAU" != "xauto"; then
 243                         if test "x$NOUVEAU" != "xno"; then
 244                                 AC_MSG_ERROR([libdrm_nouveau depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA GPUs by passing --disable-nouveau to ./configure])
 245                         fi
 246                 else
 247                         AC_MSG_WARN([Disabling libdrm_nouveau. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 248                         NOUVEAU=no
 249                 fi
 250                 if test "x$OMAP" != "xauto"; then
 251                         AC_MSG_ERROR([libdrm_omap depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for OMAP GPUs by passing --disable-omap-experimental-api to ./configure])
 252                 fi
 253                 if test "x$FREEDRENO" != "xauto"; then
 254                         AC_MSG_ERROR([libdrm_freedreno depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for QCOM's Adreno GPUs by passing --disable-freedreno to ./configure])
 255                 fi
 256                 if test "x$TEGRA" != "xauto"; then
 257                         AC_MSG_ERROR([libdrm_tegra depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA's Tegra GPUs by passing --disable-tegra-experimental-api to ./configure])
 258                 fi
 259         else
 260                 if test "x$INTEL" != "xno"; then
 261                         case $host_cpu in
 262                                 i?86|x86_64) INTEL=yes ;;
 263                                 *) INTEL=no ;;
 264                         esac
 265                 fi
 266                 if test "x$RADEON" != "xno"; then
 267                         RADEON=yes
 268                 fi
 269                 if test "x$NOUVEAU" != "xno"; then
 270                         NOUVEAU=yes
 271                 fi
 272                 if test "x$FREEDRENO" != "xno"; then
 273                         case $host_cpu in
 274                                 arm*|aarch64)   FREEDRENO=yes ;;
 275                                 *)              FREEDRENO=no ;;
 276                         esac
 277                 fi
 278         fi
 279 fi
 280
 281 if test "x$INTEL" != "xno"; then
 282         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 283 fi
 284 AC_SUBST(PCIACCESS_CFLAGS)
 285 AC_SUBST(PCIACCESS_LIBS)
 286
 287 if test "x$UDEV" = xyes; then
 288         AC_DEFINE(UDEV, 1, [Have UDEV support])
 289 fi
 290
 291 AC_CANONICAL_HOST
 292 if test "x$LIBKMS" = xauto ; then
 293         case $host_os in
 294                 linux*)         LIBKMS="yes" ;;
 295                 freebsd* | kfreebsd*-gnu)
 296                                 LIBKMS="yes" ;;
 297                 dragonfly*)     LIBKMS="yes" ;;
 298                 *)              LIBKMS="no" ;;
 299         esac
 300 fi
 301
 302 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 303
 304 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" = xyes])
 305 if test "x$INTEL" = xyes; then
 306         AC_DEFINE(HAVE_INTEL, 1, [Have intel support])
 307 fi
 308
 309 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 310 if test "x$VMWGFX" = xyes; then
 311         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 312 fi
 313
 314 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 315 if test "x$NOUVEAU" = xyes; then
 316         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 317 fi
 318
 319 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 320 if test "x$OMAP" = xyes; then
 321         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 322 fi
 323
 324 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 325 if test "x$EXYNOS" = xyes; then
 326         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 327 fi
 328
 329 AM_CONDITIONAL(HAVE_FREEDRENO, [test "x$FREEDRENO" = xyes])
 330 if test "x$FREEDRENO" = xyes; then
 331         AC_DEFINE(HAVE_FREEDRENO, 1, [Have freedreno support])
 332 fi
 333
 334 AM_CONDITIONAL(HAVE_FREEDRENO_KGSL, [test "x$FREEDRENO_KGSL" = xyes])
 335 if test "x$FREEDRENO_KGSL" = xyes; then
 336         AC_DEFINE(HAVE_FREEDRENO_KGSL, 1, [Have freedreno support for KGSL kernel interface])
 337 fi
 338
 339 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 340 if test "x$RADEON" = xyes; then
 341         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 342 fi
 343
 344 AM_CONDITIONAL(HAVE_TEGRA, [test "x$TEGRA" = xyes])
 345 if test "x$TEGRA" = xyes; then
 346         AC_DEFINE(HAVE_TEGRA, 1, [Have Tegra support])
 347 fi
 348
 349 AM_CONDITIONAL(HAVE_INSTALL_TESTS, [test "x$INSTALL_TESTS" = xyes])
 350 if test "x$INSTALL_TESTS" = xyes; then
 351         AC_DEFINE(HAVE_INSTALL_TESTS, 1, [Install test programs])
 352 fi
 353
 354 AC_ARG_ENABLE([cairo-tests],
 355               [AS_HELP_STRING([--enable-cairo-tests],
 356                               [Enable support for Cairo rendering in tests (default: auto)])],
 357               [CAIRO=$enableval], [CAIRO=auto])
 358 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 359 AC_MSG_CHECKING([whether to enable Cairo tests])
 360 if test "x$CAIRO" = xauto; then
 361         CAIRO="$HAVE_CAIRO"
 362 fi
 363 if test "x$CAIRO" = xyes; then
 364         if ! test "x$HAVE_CAIRO" = xyes; then
 365                 AC_MSG_ERROR([Cairo support required but not present])
 366         fi
 367         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 368 fi
 369 AC_MSG_RESULT([$CAIRO])
 370 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 371
 372 # For enumerating devices in test case
 373 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 374 if test "x$HAVE_LIBUDEV" = xyes; then
 375         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 376 fi
 377 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 378
 379 # xsltproc for docbook manpages
 380 AC_ARG_ENABLE([manpages],
 381               AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
 382               [MANS=$enableval], [MANS=auto])
 383 AC_PATH_PROG(XSLTPROC, xsltproc)
 384 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 385
 386 # check for offline man-pages stylesheet
 387 AC_MSG_CHECKING([for docbook manpages stylesheet])
 388 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 389 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 390                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 391                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 392 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 393         AC_SUBST(MANPAGES_STYLESHEET)
 394         AC_MSG_RESULT([yes])
 395 else
 396         AC_MSG_RESULT([no])
 397 fi
 398 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 399
 400 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 401 if test "x$have_valgrind" = "xyes"; then
 402         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 403 fi
 404
 405 AC_ARG_WITH([kernel-source],
 406             [AS_HELP_STRING([--with-kernel-source],
 407               [specify path to linux kernel source])],
 408             [kernel_source="$with_kernel_source"])
 409 AC_SUBST(kernel_source)
 410
 411 dnl Add flags for gcc and g++
 412 if test "x$GCC" = xyes; then
 413     # Enable -fvisibility=hidden if using a gcc that supports it
 414     save_CFLAGS="$CFLAGS"
 415     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 416     VISIBILITY_CFLAGS="-fvisibility=hidden"
 417     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 418     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 419                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 420
 421     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 422     CFLAGS=$save_CFLAGS
 423
 424     if test "x$VISIBILITY_CFLAGS" != x; then
 425         AC_DEFINE(HAVE_VISIBILITY, 1, [Compiler has -fvisibility support])
 426     fi
 427
 428     AC_SUBST([VISIBILITY_CFLAGS])
 429 fi
 430
 431 AC_SUBST(WARN_CFLAGS)
 432 AC_CONFIG_FILES([
 433         Makefile
 434         libkms/Makefile
 435         libkms/libkms.pc
 436         intel/Makefile
 437         intel/libdrm_intel.pc
 438         radeon/Makefile
 439         radeon/libdrm_radeon.pc
 440         nouveau/Makefile
 441         nouveau/libdrm_nouveau.pc
 442         omap/Makefile
 443         omap/libdrm_omap.pc
 444         exynos/Makefile
 445         exynos/libdrm_exynos.pc
 446         freedreno/Makefile
 447         freedreno/libdrm_freedreno.pc
 448         tegra/Makefile
 449         tegra/libdrm_tegra.pc
 450         tests/Makefile
 451         tests/modeprint/Makefile
 452         tests/modetest/Makefile
 453         tests/kmstest/Makefile
 454         tests/proptest/Makefile
 455         tests/radeon/Makefile
 456         tests/vbltest/Makefile
 457         tests/exynos/Makefile
 458         tests/tegra/Makefile
 459         tests/nouveau/Makefile
 460         man/Makefile
 461         libdrm.pc])
 462 AC_OUTPUT
 463
 464 echo ""
 465 echo "$PACKAGE_STRING will be compiled with:"
 466 echo ""
 467 echo "  libkms         $LIBKMS"
 468 echo "  Intel API      $INTEL"
 469 echo "  vmwgfx API     $VMWGFX"
 470 echo "  Radeon API     $RADEON"
 471 echo "  Nouveau API    $NOUVEAU"
 472 echo "  OMAP API       $OMAP"
 473 echo "  EXYNOS API     $EXYNOS"
 474 echo "  Freedreno API  $FREEDRENO (kgsl: $FREEDRENO_KGSL)"
 475 echo "  Tegra API      $TEGRA"
 476 echo ""