configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ(2.60)
  22 AC_INIT([libdrm], 2.4.14, [dri-devel@lists.sourceforge.net], libdrm)
  23 AC_USE_SYSTEM_EXTENSIONS
  24 AC_CONFIG_SRCDIR([Makefile.am])
  25 AM_INIT_AUTOMAKE([dist-bzip2])
  26
  27 AM_CONFIG_HEADER([libdrm/config.h])
  28
  29 AC_DISABLE_STATIC
  30 AC_PROG_LIBTOOL
  31 AC_PROG_CC
  32
  33 AC_HEADER_STDC
  34 AC_SYS_LARGEFILE
  35
  36 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  37 AC_SUBST(PTHREADSTUBS_CFLAGS)
  38 AC_SUBST(PTHREADSTUBS_LIBS)
  39
  40 pkgconfigdir=${libdir}/pkgconfig
  41 AC_SUBST(pkgconfigdir)
  42 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
  43                                 [Enable support for using udev instead of mknod (default: disabled)]),
  44                                 [UDEV=$enableval], [UDEV=no])
  45
  46 AC_ARG_ENABLE(nouveau-experimental-api,
  47               AS_HELP_STRING([--enable-nouveau-experimental-api],
  48               [Enable support for nouveau's experimental API (default: disabled)]),
  49               [NOUVEAU=$enableval], [NOUVEAU=no])
  50
  51 AC_ARG_ENABLE(radeon-experimental-api,
  52               AS_HELP_STRING([--enable-radeon-experimental-api],
  53               [Enable support for radeon's KMS API (default: disabled)]),
  54               [RADEON=$enableval], [RADEON=no])
  55
  56 dnl ===========================================================================
  57 dnl check compiler flags
  58 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  59   AC_MSG_CHECKING([whether $CC supports $1])
  60
  61   libdrm_save_CFLAGS="$CFLAGS"
  62   CFLAGS="$CFLAGS $1"
  63
  64   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
  65   CFLAGS="$libdrm_save_CFLAGS"
  66
  67   if test "x$libdrm_cc_flag" = "xyes"; then
  68     ifelse([$2], , :, [$2])
  69   else
  70     ifelse([$3], , :, [$3])
  71   fi
  72   AC_MSG_RESULT([$libdrm_cc_flag])
  73 ])
  74
  75 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
  76
  77 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
  78                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
  79                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
  80 AC_SUBST([CLOCK_LIB])
  81
  82 dnl Use lots of warning flags with with gcc and compatible compilers
  83
  84 dnl Note: if you change the following variable, the cache is automatically
  85 dnl skipped and all flags rechecked.  So there's no need to do anything
  86 dnl else.  If for any reason you need to force a recheck, just change
  87 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
  88
  89 MAYBE_WARN="-Wall -Wextra \
  90 -Wsign-compare -Werror-implicit-function-declaration \
  91 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
  92 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
  93 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
  94 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
  95 -Wdeclaration-after-statement -Wold-style-definition \
  96 -Wno-missing-field-initializers -Wno-unused-parameter \
  97 -Wno-attributes -Wno-long-long -Winline"
  98
  99 # invalidate cached value if MAYBE_WARN has changed
 100 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 101         unset libdrm_cv_warn_cflags
 102 fi
 103 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 104         echo
 105         WARN_CFLAGS=""
 106
 107         # Some warning options are not supported by all versions of
 108         # gcc, so test all desired options against the current
 109         # compiler.
 110         #
 111         # Note that there are some order dependencies
 112         # here. Specifically, an option that disables a warning will
 113         # have no net effect if a later option then enables that
 114         # warnings, (perhaps implicitly). So we put some grouped
 115         # options (-Wall and -Wextra) up front and the -Wno options
 116         # last.
 117
 118         for W in $MAYBE_WARN; do
 119                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 120         done
 121
 122         libdrm_cv_warn_cflags=$WARN_CFLAGS
 123         libdrm_cv_warn_maybe=$MAYBE_WARN
 124
 125         AC_MSG_CHECKING([which warning flags were supported])])
 126 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 127
 128 if test "x$UDEV" = xyes; then
 129         AC_DEFINE(UDEV, 1, [Have UDEV support])
 130 fi
 131
 132 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 133
 134 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 135
 136 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 137 if test "x$HAVE_CAIRO" = xyes; then
 138         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
 139 fi
 140 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
 141
 142 # For enumerating devices in test case
 143 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 144 if test "x$HAVE_LIBUDEV" = xyes; then
 145         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 146 fi
 147 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 148
 149 # Check for atomic intrinsics
 150 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
 151 [
 152         drm_cv_atomic_primitives="none"
 153
 154         AC_TRY_LINK([
 155 int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 156 int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 157 ], [],
 158           drm_cv_atomic_primitives="Intel"
 159           )
 160 ])
 161 if test "x$drm_cv_atomic_primitives" = xIntel; then
 162         AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1,
 163                   [Enable if your compiler supports the Intel __sync_* atomic primitives])
 164 fi
 165
 166 AC_SUBST(WARN_CFLAGS)
 167 AC_OUTPUT([
 168         Makefile
 169         libdrm/Makefile
 170         libdrm/intel/Makefile
 171         libdrm/radeon/Makefile
 172         libdrm/radeon/libdrm_radeon.pc
 173         libdrm/nouveau/Makefile
 174         libdrm/nouveau/libdrm_nouveau.pc
 175         shared-core/Makefile
 176         tests/Makefile
 177         tests/modeprint/Makefile
 178         tests/modetest/Makefile
 179         libdrm.pc
 180         libdrm_intel.pc])