configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.93
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.93
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.89
  83 LIBDRM_VC4_REQUIRED=2.4.89
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
  90 LIBVA_REQUIRED=0.39.0
  91 VDPAU_REQUIRED=1.1
  92 WAYLAND_REQUIRED=1.11
  93 WAYLAND_EGL_BACKEND_REQUIRED=3
  94 WAYLAND_PROTOCOLS_REQUIRED=1.8
  95 XCB_REQUIRED=1.9.3
  96 XCBDRI2_REQUIRED=1.8
  97 XCBDRI3_MODIFIERS_REQUIRED=1.13
  98 XCBGLX_REQUIRED=1.8.1
  99 XCBPRESENT_MODIFIERS_REQUIRED=1.13
 100 XDAMAGE_REQUIRED=1.1
 101 XSHMFENCE_REQUIRED=1.1
 102 XVMC_REQUIRED=1.0.6
 103 PYTHON_MAKO_REQUIRED=0.8.0
 104 LIBSENSORS_REQUIRED=4.0.0
 105 ZLIB_REQUIRED=1.2.3
 106
 107 dnl LLVM versions
 108 LLVM_REQUIRED_GALLIUM=3.3.0
 109 LLVM_REQUIRED_OPENCL=3.9.0
 110 LLVM_REQUIRED_R600=3.9.0
 111 LLVM_REQUIRED_RADEONSI=6.0.0
 112 LLVM_REQUIRED_RADV=6.0.0
 113 LLVM_REQUIRED_SWR=5.0.0
 114
 115 dnl Check for progs
 116 AC_PROG_CPP
 117 AC_PROG_CC
 118 AC_PROG_CXX
 119 dnl add this here, so the help for this environmnet variable is close to
 120 dnl other CC/CXX flags related help
 121 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 122                               enabled by default and different  from -std=c++11)])
 123 AM_PROG_CC_C_O
 124 AC_PROG_GREP
 125 AC_PROG_NM
 126 AM_PROG_AS
 127 AX_CHECK_GNU_MAKE
 128 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 129 AC_PROG_SED
 130 AC_PROG_MKDIR_P
 131
 132 AC_SYS_LARGEFILE
 133
 134
 135 LT_PREREQ([2.2])
 136 LT_INIT([disable-static])
 137
 138 AC_CHECK_PROG(RM, rm, [rm -f])
 139
 140 AX_PROG_BISON([],
 141               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 142                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 143 AX_PROG_FLEX([],
 144              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 145                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 146
 147 AC_CHECK_PROG(INDENT, indent, indent, cat)
 148 if test "x$INDENT" != "xcat"; then
 149     # Only GNU indent is supported
 150     INDENT_VERSION=`indent --version | grep GNU`
 151     if test $? -eq 0; then
 152        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 153     else
 154        INDENT="cat"
 155     fi
 156 fi
 157
 158 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 159
 160 if test -z "$PYTHON2"; then
 161     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 162         AC_MSG_ERROR([Python not found - unable to generate sources])
 163     fi
 164 else
 165     if test "x$acv_mako_found" = xno; then
 166         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 167             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 168         fi
 169     fi
 170 fi
 171
 172 AC_PROG_INSTALL
 173
 174 dnl We need a POSIX shell for parts of the build. Assume we have one
 175 dnl in most cases.
 176 case "$host_os" in
 177 solaris*)
 178     # Solaris /bin/sh is too old/non-POSIX compliant
 179     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 180     SHELL="$POSIX_SHELL"
 181     ;;
 182 esac
 183
 184 dnl clang is mostly GCC-compatible, but its version is much lower,
 185 dnl so we have to check for it.
 186 AC_MSG_CHECKING([if compiling with clang])
 187
 188 AC_COMPILE_IFELSE(
 189 [AC_LANG_PROGRAM([], [[
 190 #ifndef __clang__
 191        not clang
 192 #endif
 193 ]])],
 194 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 195
 196 AC_MSG_RESULT([$acv_mesa_CLANG])
 197
 198 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 199 dnl versions are explictly not supported.
 200 GEN_ASM_OFFSETS=no
 201 USE_GNU99=no
 202 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 203     AC_MSG_CHECKING([whether gcc version is sufficient])
 204     major=0
 205     minor=0
 206
 207     GCC_VERSION=`$CC -dumpversion`
 208     if test $? -eq 0; then
 209         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 210         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 211     fi
 212
 213     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 214         AC_MSG_RESULT([no])
 215         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 216     else
 217         AC_MSG_RESULT([yes])
 218     fi
 219
 220     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 221         USE_GNU99=yes
 222     fi
 223     if test "x$cross_compiling" = xyes; then
 224         GEN_ASM_OFFSETS=yes
 225     fi
 226 fi
 227
 228 dnl We don't support building Mesa with Sun C compiler
 229 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 230 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 231 if test "x$SUNCC" = xyes; then
 232     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 233 fi
 234
 235 dnl Check for compiler builtins
 236 AX_GCC_BUILTIN([__builtin_bswap32])
 237 AX_GCC_BUILTIN([__builtin_bswap64])
 238 AX_GCC_BUILTIN([__builtin_clz])
 239 AX_GCC_BUILTIN([__builtin_clzll])
 240 AX_GCC_BUILTIN([__builtin_ctz])
 241 AX_GCC_BUILTIN([__builtin_expect])
 242 AX_GCC_BUILTIN([__builtin_ffs])
 243 AX_GCC_BUILTIN([__builtin_ffsll])
 244 AX_GCC_BUILTIN([__builtin_popcount])
 245 AX_GCC_BUILTIN([__builtin_popcountll])
 246 AX_GCC_BUILTIN([__builtin_unreachable])
 247
 248 AX_GCC_FUNC_ATTRIBUTE([const])
 249 AX_GCC_FUNC_ATTRIBUTE([flatten])
 250 AX_GCC_FUNC_ATTRIBUTE([format])
 251 AX_GCC_FUNC_ATTRIBUTE([malloc])
 252 AX_GCC_FUNC_ATTRIBUTE([packed])
 253 AX_GCC_FUNC_ATTRIBUTE([pure])
 254 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 255 AX_GCC_FUNC_ATTRIBUTE([unused])
 256 AX_GCC_FUNC_ATTRIBUTE([visibility])
 257 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 258 AX_GCC_FUNC_ATTRIBUTE([weak])
 259 AX_GCC_FUNC_ATTRIBUTE([alias])
 260 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 261
 262 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 263
 264 dnl Make sure the pkg-config macros are defined
 265 m4_ifndef([PKG_PROG_PKG_CONFIG],
 266     [m4_fatal([Could not locate the pkg-config autoconf macros.
 267   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 268   are in a different location, try setting the environment variable
 269   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 270 PKG_PROG_PKG_CONFIG()
 271
 272 dnl LIB_DIR - library basename
 273 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 274 AC_SUBST([LIB_DIR])
 275
 276 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 277 _SAVE_LDFLAGS="$LDFLAGS"
 278 _SAVE_CPPFLAGS="$CPPFLAGS"
 279
 280 dnl Compiler macros
 281 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 282 AC_SUBST([DEFINES])
 283 android=no
 284 case "$host_os" in
 285 *-android*)
 286     android=yes
 287     ;;
 288 linux*|*-gnu*|gnu*|cygwin*)
 289     DEFINES="$DEFINES -D_GNU_SOURCE"
 290     ;;
 291 solaris*)
 292     DEFINES="$DEFINES -DSVR4"
 293     ;;
 294 esac
 295
 296 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 297
 298 dnl
 299 dnl Check compiler flags
 300 dnl
 301 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 302 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 303 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 304 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 305 dnl Dylan Baker: gcc and clang always accepr -Wno-*, hence check for the original warning, then set the no-* flag
 306 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CFLAGS="$CFLAGS -Wno-missing-field-initializers"])
 307 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 308
 309 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 310 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 311
 312 dnl
 313 dnl Check C++ compiler flags
 314 dnl
 315 AC_LANG_PUSH([C++])
 316 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 317 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 318 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 319 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 320 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CXXFLAGS="$CXXFLAGS -Wno-missing-field-initializers"])
 321 AC_LANG_POP([C++])
 322
 323 # Flags to help ensure that certain portions of the code -- and only those
 324 # portions -- can be built with MSVC:
 325 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 326 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 327 #   supports most of C99)
 328 # - the rest has no compiler compiler restrictions
 329 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 330 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 331 AC_LANG_PUSH([C++])
 332 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 333 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 334 AC_LANG_POP([C++])
 335
 336 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 337 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 338
 339 if test "x$GCC" = xyes; then
 340     if test "x$USE_GNU99" = xyes; then
 341         CFLAGS="$CFLAGS -std=gnu99"
 342     else
 343         CFLAGS="$CFLAGS -std=c99"
 344     fi
 345 fi
 346
 347 dnl
 348 dnl Check whether C++11 is supported, if the environment variable
 349 dnl CXX11_CXXFLAGS is set it takes precedence.
 350 dnl
 351
 352 AC_LANG_PUSH([C++])
 353
 354 check_cxx11_available() {
 355     output_support=$1
 356     AC_COMPILE_IFELSE(
 357         [AC_LANG_PROGRAM([
 358              #if !(__cplusplus >= 201103L)
 359              #error
 360              #endif
 361              #include <tuple>
 362         ])
 363     ], [
 364          AC_MSG_RESULT(yes)
 365          cxx11_support=yes
 366     ], AC_MSG_RESULT(no))
 367     eval "$output_support=\$cxx11_support"
 368 }
 369
 370 HAVE_CXX11=no
 371 save_CXXFLAGS="$CXXFLAGS"
 372
 373 dnl If the user provides a flag to enable c++11, then we test only this
 374 if test "x$CXX11_CXXFLAGS" != "x"; then
 375    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 376    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 377    check_cxx11_available HAVE_CXX11
 378 else
 379    dnl test whether c++11 is enabled by default
 380    AC_MSG_CHECKING(whether c++11 is enabled by default)
 381    check_cxx11_available HAVE_CXX11
 382
 383    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 384    if test "x$HAVE_CXX11" != "xyes"; then
 385        CXX11_CXXFLAGS=-std=c++11
 386        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 387        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 388        check_cxx11_available HAVE_CXX11
 389    fi
 390 fi
 391
 392 CXXFLAGS="$save_CXXFLAGS"
 393 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 394 AC_SUBST(CXX11_CXXFLAGS)
 395 AC_LANG_POP([C++])
 396
 397 dnl even if the compiler appears to support it, using visibility attributes isn't
 398 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 399 case "$host_os" in
 400 cygwin*)
 401     VISIBILITY_CFLAGS=""
 402     VISIBILITY_CXXFLAGS=""
 403     ;;
 404 esac
 405
 406 AC_SUBST([VISIBILITY_CFLAGS])
 407 AC_SUBST([VISIBILITY_CXXFLAGS])
 408
 409 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 410 dnl option is not supported. Hence, check for -Wfoo instead.
 411 AX_CHECK_COMPILE_FLAG([-Woverride-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 412 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 413 AC_SUBST([WNO_OVERRIDE_INIT])
 414
 415 dnl
 416 dnl Optional flags, check for compiler support
 417 dnl
 418 SSE41_CFLAGS="-msse4.1"
 419 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 420 dnl stack, but on x86-32 such alignment is not guaranteed.
 421 case "$target_cpu" in
 422 i?86)
 423     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 424     ;;
 425 esac
 426 save_CFLAGS="$CFLAGS"
 427 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 428 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 429 #include <smmintrin.h>
 430 int param;
 431 int main () {
 432     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 433     c = _mm_max_epu32(a, b);
 434     return _mm_cvtsi128_si32(c);
 435 }]])], SSE41_SUPPORTED=1)
 436 CFLAGS="$save_CFLAGS"
 437 if test "x$SSE41_SUPPORTED" = x1; then
 438     DEFINES="$DEFINES -DUSE_SSE41"
 439 fi
 440 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 441 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 442
 443 dnl Check for new-style atomic builtins. We first check without linking to
 444 dnl -latomic.
 445 AC_MSG_CHECKING(whether __atomic_load_n is supported)
 446 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 447 #include <stdint.h>
 448 int main() {
 449     struct {
 450         uint64_t *v;
 451     } x;
 452     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 453            (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 454 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes, GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 455
 456 dnl If that didn't work, we try linking with -latomic, which is needed on some
 457 dnl platforms.
 458 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" != xyes; then
 459    save_LDFLAGS=$LDFLAGS
 460    LDFLAGS="$LDFLAGS -latomic"
 461    AC_LINK_IFELSE([AC_LANG_SOURCE([[
 462    #include <stdint.h>
 463    int main() {
 464         struct {
 465             uint64_t *v;
 466         } x;
 467         return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 468                (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 469    }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes LIBATOMIC_LIBS="-latomic",
 470           GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 471    LDFLAGS=$save_LDFLAGS
 472 fi
 473 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_SUPPORTED)
 474
 475 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = xyes; then
 476     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 477 fi
 478 AC_SUBST([LIBATOMIC_LIBS])
 479
 480 dnl Check if host supports 64-bit atomics
 481 dnl note that lack of support usually results in link (not compile) error
 482 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 483 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 484 #include <stdint.h>
 485 uint64_t v;
 486 int main() {
 487     return __sync_add_and_fetch(&v, (uint64_t)1);
 488 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 489 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 490     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 491 fi
 492 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 493
 494 dnl Check for Endianness
 495 AC_C_BIGENDIAN(
 496    little_endian=no,
 497    little_endian=yes,
 498    little_endian=no,
 499    little_endian=no
 500 )
 501
 502 dnl Check for POWER8 Architecture
 503 PWR8_CFLAGS="-mpower8-vector"
 504 have_pwr8_intrinsics=no
 505 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 506 save_CFLAGS=$CFLAGS
 507 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 508 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 509 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 510 #error "Need GCC >= 4.8 for sane POWER8 support"
 511 #endif
 512 #include <altivec.h>
 513 int main () {
 514     vector unsigned char r;
 515     vector unsigned int v = vec_splat_u32 (1);
 516     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 517     return 0;
 518 }]])], have_pwr8_intrinsics=yes)
 519 CFLAGS=$save_CFLAGS
 520
 521 AC_ARG_ENABLE(pwr8,
 522    [AS_HELP_STRING([--disable-pwr8],
 523                    [disable POWER8-specific instructions])],
 524    [enable_pwr8=$enableval], [enable_pwr8=auto])
 525
 526 if test "x$enable_pwr8" = xno ; then
 527    have_pwr8_intrinsics=disabled
 528 fi
 529
 530 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 531    DEFINES="$DEFINES -D_ARCH_PWR8"
 532    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 533    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 534 else
 535    PWR8_CFLAGS=
 536 fi
 537
 538 AC_MSG_RESULT($have_pwr8_intrinsics)
 539 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 540    AC_MSG_ERROR([POWER8 compiler support not detected])
 541 fi
 542
 543 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 544    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 545 fi
 546
 547 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 548
 549 dnl Can't have static and shared libraries, default to static if user
 550 dnl explicitly requested. If both disabled, set to static since shared
 551 dnl was explicitly requested.
 552 case "x$enable_static$enable_shared" in
 553 xyesyes)
 554     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 555     ;;
 556 xnono)
 557     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 558     ;;
 559 esac
 560
 561 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 562
 563 dnl
 564 dnl other compiler options
 565 dnl
 566 AC_ARG_ENABLE([debug],
 567     [AS_HELP_STRING([--enable-debug],
 568         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 569     [enable_debug="$enableval"],
 570     [enable_debug=no]
 571 )
 572
 573 AC_ARG_ENABLE([profile],
 574     [AS_HELP_STRING([--enable-profile],
 575         [enable profiling of code @<:@default=disabled@:>@])],
 576     [enable_profile="$enableval"],
 577     [enable_profile=no]
 578 )
 579
 580 AC_ARG_ENABLE([sanitize],
 581     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 582         [enable code sanitizer @<:@default=disabled@:>@])],
 583     [enable_sanitize="$enableval"],
 584     [enable_sanitize=no])
 585
 586 if test "x$enable_profile" = xyes; then
 587     DEFINES="$DEFINES -DPROFILE"
 588     if test "x$GCC" = xyes; then
 589         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 590     fi
 591     if test "x$GXX" = xyes; then
 592         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 593     fi
 594 fi
 595
 596 if test "x$enable_debug" = xyes; then
 597     DEFINES="$DEFINES -DDEBUG"
 598     if test "x$enable_profile" = xyes; then
 599         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 600     fi
 601     if test "x$GCC" = xyes; then
 602         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 603             CFLAGS="$CFLAGS -g"
 604         fi
 605         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 606             CFLAGS="$CFLAGS -O0"
 607         fi
 608     fi
 609     if test "x$GXX" = xyes; then
 610         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 611             CXXFLAGS="$CXXFLAGS -g"
 612         fi
 613         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 614             CXXFLAGS="$CXXFLAGS -O0"
 615         fi
 616     fi
 617 else
 618    DEFINES="$DEFINES -DNDEBUG"
 619 fi
 620
 621 if test "x$enable_sanitize" != xno; then
 622     if test "x$enable_profile" = xyes; then
 623         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 624     fi
 625
 626     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 627     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 628     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 629
 630     AC_LINK_IFELSE(
 631         [AC_LANG_SOURCE([int main(){return 0;}])],
 632         [],
 633         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 634 fi
 635
 636 dnl
 637 dnl Check if linker supports -Bsymbolic
 638 dnl
 639 save_LDFLAGS=$LDFLAGS
 640 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 641 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 642 AC_LINK_IFELSE(
 643     [AC_LANG_SOURCE([int main() { return 0;}])],
 644     [AC_MSG_RESULT([yes])
 645         BSYMBOLIC="-Wl,-Bsymbolic";],
 646     [AC_MSG_RESULT([no])
 647         BSYMBOLIC="";])
 648 LDFLAGS=$save_LDFLAGS
 649
 650 AC_SUBST([BSYMBOLIC])
 651
 652 dnl
 653 dnl Check if linker supports garbage collection
 654 dnl
 655 save_LDFLAGS=$LDFLAGS
 656 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 657 AC_MSG_CHECKING([whether ld supports --gc-sections])
 658 AC_LINK_IFELSE(
 659     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 660     [AC_MSG_RESULT([yes])
 661         GC_SECTIONS="-Wl,--gc-sections";],
 662     [AC_MSG_RESULT([no])
 663         GC_SECTIONS="";])
 664 LDFLAGS=$save_LDFLAGS
 665
 666 AC_SUBST([GC_SECTIONS])
 667
 668 dnl
 669 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 670 dnl so when these flags are passed to ld via libtool the checks will fail
 671 dnl
 672 case "$host_os" in
 673 openbsd* | darwin* )
 674     LD_NO_UNDEFINED="" ;;
 675 *)
 676     if test "x$enable_sanitize" = xno; then
 677         LD_NO_UNDEFINED="-Wl,--no-undefined"
 678     else
 679         LD_NO_UNDEFINED=""
 680     fi
 681     ;;
 682 esac
 683
 684 AC_SUBST([LD_NO_UNDEFINED])
 685
 686 dnl
 687 dnl Check if linker supports version scripts
 688 dnl
 689 AC_MSG_CHECKING([if the linker supports version-scripts])
 690 save_LDFLAGS=$LDFLAGS
 691 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 692 AC_LINK_IFELSE(
 693     [AC_LANG_SOURCE([int main() { return 0;}])],
 694     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 695     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 696 LDFLAGS=$save_LDFLAGS
 697 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 698
 699 dnl
 700 dnl Check if linker supports dynamic list files
 701 dnl
 702 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 703 save_LDFLAGS=$LDFLAGS
 704 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 705 AC_LINK_IFELSE(
 706     [AC_LANG_SOURCE([int main() { return 0;}])],
 707     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 708     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 709 LDFLAGS=$save_LDFLAGS
 710 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 711
 712 dnl
 713 dnl OSX linker does not support build-id
 714 dnl
 715 case "$host_os" in
 716 darwin*)
 717     LD_BUILD_ID=""
 718     ;;
 719 *)
 720     LD_BUILD_ID="-Wl,--build-id=sha1"
 721     ;;
 722 esac
 723 AC_SUBST([LD_BUILD_ID])
 724
 725 dnl
 726 dnl compatibility symlinks
 727 dnl
 728 case "$host_os" in
 729 linux* )
 730     HAVE_COMPAT_SYMLINKS=yes ;;
 731 * )
 732     HAVE_COMPAT_SYMLINKS=no ;;
 733 esac
 734
 735 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 736
 737 dnl
 738 dnl library names
 739 dnl
 740 dnl Unfortunately we need to do a few things that libtool can't help us with,
 741 dnl so we need some knowledge of shared library filenames:
 742 dnl
 743 dnl LIB_EXT is the extension used when creating symlinks for alternate
 744 dnl filenames for a shared library which will be dynamically loaded
 745 dnl
 746 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 747 dnl the file for a shared library we wish to link with
 748 dnl
 749 case "$host_os" in
 750 darwin* )
 751     LIB_EXT='dylib'
 752     IMP_LIB_EXT=$LIB_EXT
 753     ;;
 754 cygwin* )
 755     LIB_EXT='dll'
 756     IMP_LIB_EXT='dll.a'
 757     ;;
 758 aix* )
 759     LIB_EXT='a'
 760     IMP_LIB_EXT=$LIB_EXT
 761     ;;
 762 * )
 763     LIB_EXT='so'
 764     IMP_LIB_EXT=$LIB_EXT
 765     ;;
 766 esac
 767
 768 AC_SUBST([LIB_EXT])
 769
 770 dnl
 771 dnl Arch/platform-specific settings
 772 dnl
 773 AC_ARG_ENABLE([asm],
 774     [AS_HELP_STRING([--disable-asm],
 775         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 776     [enable_asm="$enableval"],
 777     [enable_asm=yes]
 778 )
 779 asm_arch=""
 780 AC_MSG_CHECKING([whether to enable assembly])
 781 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 782 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 783 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 784     case "$host_cpu" in
 785     i?86 | x86_64 | amd64)
 786         if test "x$host_cpu" != "x$target_cpu"; then
 787             enable_asm=no
 788             AC_MSG_RESULT([no, cross compiling])
 789         fi
 790         ;;
 791     esac
 792 fi
 793 # check for supported arches
 794 if test "x$enable_asm" = xyes; then
 795     case "$host_cpu" in
 796     i?86)
 797         case "$host_os" in
 798         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 799             asm_arch=x86
 800             ;;
 801         esac
 802         ;;
 803     x86_64|amd64)
 804         case "$host_os" in
 805         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 806             asm_arch=x86_64
 807             ;;
 808         esac
 809         ;;
 810     sparc*)
 811         case "$host_os" in
 812         linux*)
 813             asm_arch=sparc
 814             ;;
 815         esac
 816         ;;
 817     powerpc64le)
 818         case "$host_os" in
 819         linux*)
 820             asm_arch=ppc64le
 821             ;;
 822         esac
 823         ;;
 824     aarch64)
 825         case "$host_os" in
 826         linux*)
 827             asm_arch=aarch64
 828             ;;
 829         esac
 830         ;;
 831     arm)
 832         case "$host_os" in
 833         linux*)
 834             asm_arch=arm
 835             ;;
 836         esac
 837         ;;
 838     esac
 839
 840     case "$asm_arch" in
 841     x86)
 842         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 843         AC_MSG_RESULT([yes, x86])
 844         ;;
 845     x86_64|amd64)
 846         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 847         AC_MSG_RESULT([yes, x86_64])
 848         ;;
 849     sparc)
 850         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 851         AC_MSG_RESULT([yes, sparc])
 852         ;;
 853     ppc64le)
 854         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 855         AC_MSG_RESULT([yes, ppc64le])
 856         ;;
 857     aarch64)
 858         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 859         AC_MSG_RESULT([yes, aarch64])
 860         ;;
 861     arm)
 862         DEFINES="$DEFINES -DUSE_ARM_ASM"
 863         AC_MSG_RESULT([yes, arm])
 864         ;;
 865     *)
 866         AC_MSG_RESULT([no, platform not supported])
 867         ;;
 868     esac
 869 fi
 870
 871 AC_HEADER_MAJOR
 872 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 873 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 874 AC_CHECK_HEADERS([endian.h])
 875 AC_CHECK_HEADER([dlfcn.h], [DEFINES="$DEFINES -DHAVE_DLFCN_H"])
 876 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 877 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 878 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 879 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
 880
 881 AC_MSG_CHECKING([whether strtod has locale support])
 882 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 883     #define _GNU_SOURCE
 884     #include <stdlib.h>
 885     #include <locale.h>
 886     #ifdef HAVE_XLOCALE_H
 887     #include <xlocale.h>
 888     #endif
 889     int main() {
 890        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 891        const char *s = "1.0";
 892        char *end;
 893        double d = strtod_l(s, end, loc);
 894        float f = strtof_l(s, end, loc);
 895        freelocale(loc);
 896        return 0;
 897     }]])],
 898   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 899    AC_MSG_RESULT([yes]),
 900    AC_MSG_RESULT([no]))
 901
 902 dnl Check to see if dlopen is in default libraries (like Solaris, which
 903 dnl has it in libc), or if libdl is needed to get it.
 904 AC_CHECK_FUNC([dlopen], [],
 905     [AC_CHECK_LIB([dl], [dlopen],
 906        [DLOPEN_LIBS="-ldl"])])
 907 AC_SUBST([DLOPEN_LIBS])
 908
 909 dnl Check if that library also has dladdr
 910 save_LIBS="$LIBS"
 911 LIBS="$LIBS $DLOPEN_LIBS"
 912 AC_CHECK_FUNCS([dladdr])
 913 LIBS="$save_LIBS"
 914
 915 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 916
 917 case "$host_os" in
 918 darwin*)
 919     ;;
 920 *)
 921     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 922                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 923                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 924     AC_SUBST([CLOCK_LIB])
 925     ;;
 926 esac
 927
 928 dnl See if posix_memalign is available
 929 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 930
 931 dnl Check for zlib
 932 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 933 DEFINES="$DEFINES -DHAVE_ZLIB"
 934
 935 dnl Check for pthreads
 936 AX_PTHREAD
 937 if test "x$ax_pthread_ok" = xno; then
 938     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 939 fi
 940 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 941 dnl to -pthread, which causes problems if we need -lpthread to appear in
 942 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 943 dnl is not valid for that platform.
 944 if test "x$android" = xno; then
 945     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 946 fi
 947 dnl According to the manual when using pthreads, one should add -pthread to
 948 dnl both compile and link-time arguments.
 949 dnl In practise that should be sufficient for all platforms, since any
 950 dnl platforms build with GCC and Clang support the flag.
 951 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 952
 953 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
 954 dnl project. Even then there's a notable issue as described in the project README
 955 case "$host_os" in
 956 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
 957     pthread_stubs_possible="no"
 958     ;;
 959 * )
 960     pthread_stubs_possible="yes"
 961     ;;
 962 esac
 963
 964 if test "x$pthread_stubs_possible" = xyes; then
 965     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 966 fi
 967
 968 dnl Check for futex for fast inline simple_mtx_t.
 969 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
 970
 971 dnl SELinux awareness.
 972 AC_ARG_ENABLE([selinux],
 973     [AS_HELP_STRING([--enable-selinux],
 974         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 975     [MESA_SELINUX="$enableval"],
 976     [MESA_SELINUX=no])
 977 if test "x$enable_selinux" = "xyes"; then
 978     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 979         [AC_CHECK_HEADER([selinux/selinux.h],[],
 980                          [AC_MSG_ERROR([SELinux headers not found])])
 981          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 982                       [AC_MSG_ERROR([SELinux library not found])])
 983          SELINUX_LIBS="-lselinux"])
 984     DEFINES="$DEFINES -DMESA_SELINUX"
 985 fi
 986 AC_SUBST([SELINUX_CFLAGS])
 987 AC_SUBST([SELINUX_LIBS])
 988
 989 dnl
 990 dnl LLVM
 991 dnl
 992 AC_ARG_ENABLE([llvm-shared-libs],
 993     [AS_HELP_STRING([--enable-llvm-shared-libs],
 994         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 995     [enable_llvm_shared_libs="$enableval"],
 996     [enable_llvm_shared_libs=yes])
 997
 998 AC_ARG_WITH([llvm-prefix],
 999     [AS_HELP_STRING([--with-llvm-prefix],
1000         [Prefix for LLVM installations in non-standard locations])],
1001     [llvm_prefix="$withval"],
1002     [llvm_prefix=''])
1003
1004 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1005 if test "x$have_libelf" = xno; then
1006    LIBELF_LIBS=''
1007    LIBELF_CFLAGS=''
1008    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1009    AC_SUBST([LIBELF_LIBS])
1010    AC_SUBST([LIBELF_CFLAGS])
1011 fi
1012
1013 if test -z "$LLVM_CONFIG"; then
1014     if test -n "$llvm_prefix"; then
1015         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1016     else
1017         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1018     fi
1019 fi
1020
1021 llvm_add_component() {
1022     new_llvm_component=$1
1023     driver_name=$2
1024
1025     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1026         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1027     else
1028         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1029     fi
1030 }
1031
1032 llvm_add_optional_component() {
1033     new_llvm_component=$1
1034     driver_name=$2
1035
1036     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1037         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1038     fi
1039 }
1040
1041 llvm_add_default_components() {
1042     driver_name=$1
1043
1044     # Required default components
1045     llvm_add_component "bitwriter" $driver_name
1046     llvm_add_component "engine" $driver_name
1047     llvm_add_component "mcdisassembler" $driver_name
1048     llvm_add_component "mcjit" $driver_name
1049
1050     # Optional default components
1051     llvm_add_optional_component "inteljitevents" $driver_name
1052 }
1053
1054 llvm_add_target() {
1055     new_llvm_target=$1
1056     driver_name=$2
1057
1058     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1059         llvm_add_component $new_llvm_target $driver_name
1060     else
1061         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1062     fi
1063 }
1064
1065 # Call this inside ` ` to get the return value.
1066 # $1 is the llvm-config command with arguments.
1067 strip_unwanted_llvm_flags() {
1068     echo " `$1` " | sed -E \
1069         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1070         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1071         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1072         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1073         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1074         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1075         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1076         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1077         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1078         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1079         -e 's/^[[[:space:]]]//' \
1080         -e 's/[[[:space:]]]$//'
1081 }
1082
1083 llvm_set_environment_variables() {
1084     if test "x$LLVM_CONFIG" != xno; then
1085         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1086         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1087         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1088         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1089
1090         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1091         save_CFLAGS="$CFLAGS"
1092         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1093
1094         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1095             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1096         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1097             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1098         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1099             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1100
1101         CFLAGS="$save_CFLAGS"
1102
1103         # Only needed for LLVM < 3.6.0
1104         if test -z "$LLVM_VERSION_PATCH"; then
1105             LLVM_VERSION_PATCH=0
1106         fi
1107
1108         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1109
1110         FOUND_LLVM=yes
1111     else
1112         FOUND_LLVM=no
1113         LLVM_VERSION_INT=0
1114     fi
1115 }
1116
1117 require_llvm() {
1118     if test "x$enable_llvm" != "xyes"; then
1119         AC_MSG_ERROR([--enable-llvm is required when building $1])
1120     fi
1121 }
1122
1123 llvm_require_version() {
1124     require_llvm $2
1125
1126     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1127     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1128     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1129
1130     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1131         # major > required major
1132         #  --> OK
1133         return
1134     fi
1135
1136     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1137         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1138             # major = required major and
1139             # minor > required minor
1140             #  --> OK
1141             return
1142         else
1143             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1144                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1145                     # major = required major and
1146                     # minor = required minor and
1147                     # patch >= required patch
1148                     #  --> OK
1149                     return
1150                 fi
1151             fi
1152         fi
1153     fi
1154
1155     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1156 }
1157
1158 radeon_llvm_check() {
1159     if test ${LLVM_VERSION_INT} -lt 307; then
1160         amdgpu_llvm_target_name='r600'
1161     else
1162         amdgpu_llvm_target_name='amdgpu'
1163     fi
1164
1165     llvm_require_version $*
1166
1167     llvm_add_target $amdgpu_llvm_target_name $2
1168
1169     llvm_add_default_components $2
1170     llvm_add_component "bitreader" $2
1171     llvm_add_component "ipo" $2
1172
1173     if test "x$have_libelf" != xyes; then
1174        AC_MSG_ERROR([$2 requires libelf when using llvm])
1175     fi
1176 }
1177
1178 llvm_set_environment_variables
1179
1180 AC_SUBST([LLVM_CFLAGS])
1181 AC_SUBST([LLVM_CXXFLAGS])
1182 AC_SUBST([LLVM_LIBS])
1183 AC_SUBST([LLVM_LDFLAGS])
1184 AC_SUBST([LLVM_INCLUDEDIR])
1185
1186 dnl
1187 dnl libunwind
1188 dnl
1189 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1190 AC_ARG_ENABLE([libunwind],
1191     [AS_HELP_STRING([--enable-libunwind],
1192             [Use libunwind for backtracing (default: auto)])],
1193         [LIBUNWIND="$enableval"],
1194         [LIBUNWIND="$HAVE_LIBUNWIND"])
1195
1196 if test "x$LIBUNWIND" = "xyes"; then
1197     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1198     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1199 fi
1200
1201
1202 dnl Options for APIs
1203 AC_ARG_ENABLE([opengl],
1204     [AS_HELP_STRING([--disable-opengl],
1205         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1206     [enable_opengl="$enableval"],
1207     [enable_opengl=yes])
1208 AC_ARG_ENABLE([gles1],
1209     [AS_HELP_STRING([--disable-gles1],
1210         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1211     [enable_gles1="$enableval"],
1212     [enable_gles1=yes])
1213 AC_ARG_ENABLE([gles2],
1214     [AS_HELP_STRING([--disable-gles2],
1215         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1216     [enable_gles2="$enableval"],
1217     [enable_gles2=yes])
1218
1219 AC_ARG_ENABLE([dri],
1220     [AS_HELP_STRING([--enable-dri],
1221         [enable DRI modules @<:@default=enabled@:>@])],
1222     [enable_dri="$enableval"],
1223     [enable_dri=yes])
1224
1225 AC_ARG_ENABLE([gallium-extra-hud],
1226     [AS_HELP_STRING([--enable-gallium-extra-hud],
1227         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1228     [enable_gallium_extra_hud="$enableval"],
1229     [enable_gallium_extra_hud=no])
1230 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1231 if test "x$enable_gallium_extra_hud" = xyes ; then
1232     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1233 fi
1234
1235 #TODO: no pkgconfig .pc available for libsensors.
1236 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1237 AC_ARG_ENABLE([lmsensors],
1238     [AS_HELP_STRING([--enable-lmsensors],
1239         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1240     [enable_lmsensors="$enableval"],
1241     [enable_lmsensors=no])
1242 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1243 if test "x$enable_lmsensors" = xyes ; then
1244     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1245     LIBSENSORS_LIBS="-lsensors"
1246 else
1247     LIBSENSORS_LIBS=""
1248 fi
1249 AC_SUBST(LIBSENSORS_LIBS)
1250
1251 case "$host_os" in
1252 linux*)
1253     dri3_default=yes
1254     ;;
1255 *)
1256     dri3_default=no
1257     ;;
1258 esac
1259
1260 if test "x$enable_dri" = xno; then
1261     dri3_default=no
1262 fi
1263
1264 AC_ARG_ENABLE([dri3],
1265     [AS_HELP_STRING([--enable-dri3],
1266         [enable DRI3 @<:@default=auto@:>@])],
1267     [enable_dri3="$enableval"],
1268     [enable_dri3="$dri3_default"])
1269 AC_ARG_ENABLE([glx],
1270     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1271         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1272     [enable_glx="$enableval"],
1273     [enable_glx=yes])
1274 AC_ARG_ENABLE([osmesa],
1275     [AS_HELP_STRING([--enable-osmesa],
1276         [enable OSMesa library @<:@default=disabled@:>@])],
1277     [enable_osmesa="$enableval"],
1278     [enable_osmesa=no])
1279 AC_ARG_ENABLE([gallium-osmesa],
1280     [AS_HELP_STRING([--enable-gallium-osmesa],
1281         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1282     [enable_gallium_osmesa="$enableval"],
1283     [enable_gallium_osmesa=no])
1284 AC_ARG_ENABLE([egl],
1285     [AS_HELP_STRING([--disable-egl],
1286         [disable EGL library @<:@default=enabled@:>@])],
1287     [enable_egl="$enableval"],
1288     [enable_egl=yes])
1289
1290 AC_ARG_ENABLE([xa],
1291     [AS_HELP_STRING([--enable-xa],
1292         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1293     [enable_xa="$enableval"],
1294     [enable_xa=no])
1295 AC_ARG_ENABLE([gbm],
1296    [AS_HELP_STRING([--enable-gbm],
1297          [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1298    [enable_gbm="$enableval"],
1299    [case "$host_os" in
1300        cygwin* | darwin*)
1301           enable_gbm=no
1302           ;;
1303        *)
1304           enable_gbm=yes
1305           ;;
1306     esac])
1307 AC_ARG_ENABLE([nine],
1308     [AS_HELP_STRING([--enable-nine],
1309         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1310     [enable_nine="$enableval"],
1311     [enable_nine=no])
1312
1313 AC_ARG_ENABLE([xvmc],
1314    [AS_HELP_STRING([--enable-xvmc],
1315          [enable xvmc library @<:@default=auto@:>@])],
1316    [enable_xvmc="$enableval"],
1317    [enable_xvmc=auto])
1318 AC_ARG_ENABLE([vdpau],
1319    [AS_HELP_STRING([--enable-vdpau],
1320          [enable vdpau library @<:@default=auto@:>@])],
1321    [enable_vdpau="$enableval"],
1322    [enable_vdpau=auto])
1323 AC_ARG_ENABLE([omx],
1324    [AS_HELP_STRING([--enable-omx],
1325          [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1326    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1327    [])
1328 AC_ARG_ENABLE([omx-bellagio],
1329    [AS_HELP_STRING([--enable-omx-bellagio],
1330          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1331    [enable_omx_bellagio="$enableval"],
1332    [enable_omx_bellagio=no])
1333 AC_ARG_ENABLE([omx-tizonia],
1334    [AS_HELP_STRING([--enable-omx-tizonia],
1335          [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1336    [enable_omx_tizonia="$enableval"],
1337    [enable_omx_tizonia=no])
1338 AC_ARG_ENABLE([va],
1339    [AS_HELP_STRING([--enable-va],
1340          [enable va library @<:@default=auto@:>@])],
1341    [enable_va="$enableval"],
1342    [enable_va=auto])
1343 AC_ARG_ENABLE([opencl],
1344    [AS_HELP_STRING([--enable-opencl],
1345          [enable OpenCL library @<:@default=disabled@:>@])],
1346    [enable_opencl="$enableval"],
1347    [enable_opencl=no])
1348 AC_ARG_ENABLE([opencl_icd],
1349    [AS_HELP_STRING([--enable-opencl-icd],
1350           [Build an OpenCL ICD library to be loaded by an ICD implementation
1351            @<:@default=enabled@:>@])],
1352     [enable_opencl_icd="$enableval"],
1353     [enable_opencl_icd=yes])
1354
1355 AC_ARG_ENABLE([gallium-tests],
1356     [AS_HELP_STRING([--enable-gallium-tests],
1357         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1358     [enable_gallium_tests="$enableval"],
1359     [enable_gallium_tests=no])
1360
1361 # Option for Gallium drivers
1362
1363 # Keep this in sync with the --with-gallium-drivers help string default value
1364 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1365
1366 AC_ARG_WITH([gallium-drivers],
1367     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1368         [comma delimited Gallium drivers list, e.g.
1369         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,v3d,vc4,virgl,etnaviv,imx"
1370         @<:@default=r300,r600,svga,swrast@:>@])],
1371     [with_gallium_drivers="$withval"],
1372     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1373
1374 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1375 # here so that the script doesn't choke on an unknown driver name later.
1376 case "$with_gallium_drivers" in
1377     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1378     no) with_gallium_drivers='' ;;
1379 esac
1380
1381 if test "x$enable_opengl" = xno -a \
1382         "x$enable_gles1" = xno -a \
1383         "x$enable_gles2" = xno -a \
1384         "x$enable_nine" = xno -a \
1385         "x$enable_xa" = xno -a \
1386         "x$enable_xvmc" = xno -a \
1387         "x$enable_vdpau" = xno -a \
1388         "x$enable_omx_bellagio" = xno -a \
1389         "x$enable_omx_tizonia" = xno -a \
1390         "x$enable_va" = xno -a \
1391         "x$enable_opencl" = xno; then
1392     AC_MSG_ERROR([at least one API should be enabled])
1393 fi
1394
1395 if test "x$enable_omx_bellagio" = xyes -a \
1396         "x$enable_omx_tizonia" = xyes; then
1397    AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1398 fi
1399
1400 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1401 if test "x$enable_opengl" = xno -a \
1402         "x$enable_gles1" = xyes; then
1403     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1404 fi
1405
1406 if test "x$enable_opengl" = xno -a \
1407         "x$enable_gles2" = xyes; then
1408     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1409 fi
1410
1411 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1412 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1413 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1414 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1415                                         "x$enable_gles1" = xyes -o \
1416                                         "x$enable_gles2" = xyes)
1417 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1418                                       "x$enable_opengl" = xyes -o \
1419                                       "x$enable_gles1" = xyes -o \
1420                                       "x$enable_gles2" = xyes)
1421
1422 # Validate GLX options
1423 if test "x$enable_glx" = xyes; then
1424     if test "x$enable_dri" = xyes; then
1425         enable_glx=dri
1426     elif test -n "$with_gallium_drivers"; then
1427         enable_glx=gallium-xlib
1428     else
1429         enable_glx=xlib
1430     fi
1431 fi
1432 case "x$enable_glx" in
1433 xdri | xxlib | xgallium-xlib)
1434     # GLX requires OpenGL
1435     if test "x$enable_opengl" = xno; then
1436         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1437     fi
1438
1439     # Check individual dependencies
1440     case "x$enable_glx" in
1441     xdri)
1442         if test "x$enable_dri" = xno; then
1443             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1444         fi
1445         ;;
1446     xxlib)
1447         if test "x$enable_dri" = xyes; then
1448             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1449         fi
1450         ;;
1451     xgallium-xlib )
1452         if test "x$enable_dri" = xyes; then
1453             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1454         fi
1455         if test -z "$with_gallium_drivers"; then
1456             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1457         fi
1458         ;;
1459     esac
1460     ;;
1461 xno)
1462     ;;
1463 *)
1464     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1465     ;;
1466 esac
1467
1468 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1469 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1470 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1471 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1472
1473 DEFAULT_GL_LIB_NAME=GL
1474
1475 dnl
1476 dnl Libglvnd configuration
1477 dnl
1478 AC_ARG_ENABLE([libglvnd],
1479     [AS_HELP_STRING([--enable-libglvnd],
1480         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1481     [enable_libglvnd="$enableval"],
1482     [enable_libglvnd=no])
1483 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1484
1485 if test "x$enable_libglvnd" = xyes ; then
1486     case "x$enable_glx" in
1487     xxlib | xgallium-xlib )
1488         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1489         ;;
1490     esac
1491
1492     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1493     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1494     AC_SUBST([LIBGLVND_DATADIR])
1495
1496     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1497     DEFAULT_GL_LIB_NAME=GLX_mesa
1498
1499     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1500         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1501     fi
1502 fi
1503
1504 AC_ARG_WITH([gl-lib-name],
1505   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1506     [specify GL library name @<:@default=GL@:>@])],
1507   [AC_MSG_ERROR([--with-gl-lib-name is no longer supported. Rename the library manually if needed.])],
1508   [])
1509 AC_ARG_WITH([osmesa-lib-name],
1510   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1511     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1512   [AC_MSG_ERROR([--with-osmesa-lib-name is no longer supported. Rename the library manually if needed.])],
1513   [])
1514 GL_LIB="$DEFAULT_GL_LIB_NAME"
1515 OSMESA_LIB=OSMesa
1516
1517 dnl
1518 dnl Mangled Mesa support
1519 dnl
1520 AC_ARG_ENABLE([mangling],
1521   [AS_HELP_STRING([--enable-mangling],
1522     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1523   [enable_mangling="${enableval}"],
1524   [enable_mangling=no]
1525 )
1526 if test "x${enable_mangling}" = "xyes" ; then
1527   if test "x$enable_libglvnd" = xyes; then
1528     AC_MSG_ERROR([Conflicting options --enable-mangling and --enable-libglvnd.])
1529   fi
1530   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1531   GL_LIB="Mangled${GL_LIB}"
1532   OSMESA_LIB="Mangled${OSMESA_LIB}"
1533 fi
1534 AC_SUBST([GL_LIB])
1535 AC_SUBST([OSMESA_LIB])
1536
1537 dnl HACK when building glx + glvnd we ship gl.pc, despite that glvnd should do it
1538 dnl Thus we need to use GL as a DSO name.
1539 if test "x$enable_libglvnd" = xyes -a "x$enable_glx" != xno; then
1540   GL_PKGCONF_LIB="GL"
1541 else
1542   GL_PKGCONF_LIB="$GL_LIB"
1543 fi
1544 AC_SUBST([GL_PKGCONF_LIB])
1545
1546 # Check for libdrm
1547 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1548                   [have_libdrm=yes], [have_libdrm=no])
1549 if test "x$have_libdrm" = xyes; then
1550     DEFINES="$DEFINES -DHAVE_LIBDRM"
1551 fi
1552
1553 require_libdrm() {
1554     if test "x$have_libdrm" != xyes; then
1555        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1556     fi
1557 }
1558
1559
1560 # Select which platform-dependent DRI code gets built
1561 case "$host_os" in
1562 darwin*)
1563     dri_platform='apple' ;;
1564 cygwin*)
1565     dri_platform='windows' ;;
1566 gnu*)
1567     dri_platform='none' ;;
1568 *)
1569     dri_platform='drm' ;;
1570 esac
1571
1572 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1573     have_drisw_kms='yes'
1574 fi
1575
1576 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1577 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1578 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1579 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1580 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1581 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1582 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1583 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1584 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1585 AM_CONDITIONAL(HAVE_XLEASE, test "x$have_xlease" = xyes )
1586
1587 AC_ARG_ENABLE([shared-glapi],
1588     [AS_HELP_STRING([--enable-shared-glapi],
1589         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1590     [enable_shared_glapi="$enableval"],
1591     [enable_shared_glapi=yes])
1592
1593 case "x$enable_opengl$enable_gles1$enable_gles2" in
1594 x*yes*yes*)
1595     if test "x$enable_shared_glapi" = xno; then
1596         AC_MSG_ERROR([shared GLAPI required when building two or more of
1597                       the following APIs - opengl, gles1 gles2])
1598     fi
1599     ;;
1600 esac
1601
1602 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1603
1604 # Build the pipe-drivers as separate libraries/modules.
1605 # Do not touch this unless you know what you are doing.
1606 # XXX: Expose via configure option ?
1607 enable_shared_pipe_drivers=no
1608
1609 dnl
1610 dnl Driver specific build directories
1611 dnl
1612
1613 if test "x$enable_gallium_osmesa" = xyes; then
1614     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1615         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1616     fi
1617     if test "x$enable_osmesa" = xyes; then
1618         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1619     fi
1620 fi
1621
1622 require_dri_shared_libs_and_glapi() {
1623     if test "x$enable_static" = xyes; then
1624         AC_MSG_ERROR([$1 cannot be build as static library])
1625     fi
1626
1627     if test "x$enable_dri" != xyes; then
1628         # There is only a single backend which won't be build/used otherwise.
1629         # XXX: Revisit this as the egl/haiku is a thing.
1630         AC_MSG_ERROR([$1 requires --enable-dri])
1631     fi
1632
1633     if test "x$enable_shared_glapi" != xyes; then
1634         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1635     fi
1636 }
1637
1638 if test "x$enable_dri" = xyes; then
1639     require_dri_shared_libs_and_glapi "DRI"
1640
1641     # not a hard requirement as swrast does not depend on it
1642     if test "x$have_libdrm" = xyes; then
1643         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1644     fi
1645 fi
1646
1647 AC_ARG_ENABLE([driglx-direct],
1648     [AS_HELP_STRING([--disable-driglx-direct],
1649         [disable direct rendering in GLX and EGL for DRI \
1650             @<:@default=enabled@:>@])],
1651     [driglx_direct="$enableval"],
1652     [driglx_direct="yes"])
1653
1654 dnl
1655 dnl libGL configuration per driver
1656 dnl
1657 if test "x$enable_glx" != xno; then
1658     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1659 fi
1660 case "x$enable_glx" in
1661 xxlib | xgallium-xlib)
1662     # Xlib-based GLX
1663     dri_modules="x11 xext xcb"
1664     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1665     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1666     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1667     GL_LIB_DEPS="$XLIBGL_LIBS"
1668     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1669     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1670     ;;
1671 xdri)
1672     # DRI-based GLX
1673
1674     require_dri_shared_libs_and_glapi "GLX"
1675
1676     # find the DRI deps for libGL
1677     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1678
1679     if test x"$driglx_direct" = xyes; then
1680         if test x"$dri_platform" = xdrm ; then
1681             DEFINES="$DEFINES -DGLX_USE_DRM"
1682             require_libdrm "Direct rendering"
1683
1684             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1685             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1686
1687             if test x"$enable_dri" = xyes; then
1688                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1689             fi
1690         fi
1691         if test x"$dri_platform" = xapple ; then
1692             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1693         fi
1694         if test x"$dri_platform" = xwindows ; then
1695             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1696         fi
1697     fi
1698
1699     # add xf86vidmode if available
1700     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1701     if test "$HAVE_XF86VIDMODE" = yes ; then
1702         dri_modules="$dri_modules xxf86vm"
1703     fi
1704
1705     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1706     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1707     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1708     GL_LIB_DEPS="$DRIGL_LIBS"
1709
1710     # need DRM libs, $PTHREAD_LIBS, etc.
1711     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1712     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1713     ;;
1714 esac
1715
1716 # This is outside the case (above) so that it is invoked even for non-GLX
1717 # builds.
1718 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1719
1720 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1721 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1722 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1723 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1724
1725 AC_SUBST([X11_INCLUDES])
1726 AC_SUBST([GL_LIB_DEPS])
1727 AC_SUBST([GL_PC_REQ_PRIV])
1728 AC_SUBST([GL_PC_LIB_PRIV])
1729 AC_SUBST([GL_PC_CFLAGS])
1730 AC_SUBST([DRI_PC_REQ_PRIV])
1731 AC_SUBST([GLESv1_CM_LIB_DEPS])
1732 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1733 AC_SUBST([GLESv2_LIB_DEPS])
1734 AC_SUBST([GLESv2_PC_LIB_PRIV])
1735
1736 AC_SUBST([HAVE_XF86VIDMODE])
1737
1738 dnl
1739 dnl More GLX setup
1740 dnl
1741 case "x$enable_glx" in
1742 xxlib | xgallium-xlib)
1743     DEFINES="$DEFINES -DUSE_XSHM"
1744     ;;
1745 xdri)
1746     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1747     if test "x$driglx_direct" = xyes; then
1748         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1749     fi
1750     ;;
1751 esac
1752
1753 dnl
1754 dnl TLS detection
1755 dnl
1756
1757 AC_ARG_ENABLE([glx-tls],
1758     [AS_HELP_STRING([--enable-glx-tls],
1759         [enable TLS support in GLX @<:@default=enabled@:>@])],
1760     [GLX_USE_TLS="$enableval"],
1761     [GLX_USE_TLS=yes])
1762 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1763
1764 if test "x$GLX_USE_TLS" = xyes; then
1765     DEFINES="$DEFINES -DGLX_USE_TLS"
1766 fi
1767
1768 dnl Read-only text section on x86 hardened platforms
1769 AC_ARG_ENABLE([glx-read-only-text],
1770     [AS_HELP_STRING([--enable-glx-read-only-text],
1771         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1772     [enable_glx_read_only_text="$enableval"],
1773     [enable_glx_read_only_text=no])
1774 if test "x$enable_glx_read_only_text" = xyes; then
1775     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1776 fi
1777
1778 dnl
1779 dnl DEPRECATED: EGL Platforms configuration
1780 dnl
1781 AC_ARG_WITH([egl-platforms],
1782     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1783         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1784     [with_egl_platforms="$withval"],
1785     [with_egl_platforms=auto])
1786
1787 if test "x$with_egl_platforms" = xauto; then
1788     with_egl_platforms="x11,surfaceless"
1789     if test "x$enable_gbm" = xyes; then
1790         with_egl_platforms="$with_egl_platforms,drm"
1791     fi
1792 else
1793     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1794 fi
1795
1796 dnl
1797 dnl Platforms configuration
1798 dnl
1799 AC_ARG_WITH([platforms],
1800     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1801         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1802         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1803     [with_platforms="$withval"],
1804     [with_platforms=auto])
1805
1806 # Reuse the autodetection rather than duplicating it.
1807 if test "x$with_platforms" = xauto; then
1808     with_platforms=$with_egl_platforms
1809 fi
1810
1811 # Do per platform setups and checks
1812 platforms=`IFS=', '; echo $with_platforms`
1813 for plat in $platforms; do
1814     case "$plat" in
1815     wayland)
1816
1817         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1818         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1819         PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1820         if test "x$enable_egl" = xyes; then
1821           PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl-backend >= $WAYLAND_EGL_BACKEND_REQUIRED])
1822         fi
1823         WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1824
1825         PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1826                           WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1827                           WAYLAND_SCANNER='')
1828         PKG_CHECK_EXISTS([wayland-scanner >= 1.15],
1829                           AC_SUBST(SCANNER_ARG, 'private-code'),
1830                           AC_SUBST(SCANNER_ARG, 'code'))
1831
1832         if test "x$WAYLAND_SCANNER" = x; then
1833             AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1834         fi
1835
1836         if test "x$WAYLAND_SCANNER" = "x:"; then
1837                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1838         fi
1839         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1840         ;;
1841
1842     x11)
1843         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1844         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1845         ;;
1846
1847     drm)
1848         test "x$enable_gbm" = "xno" &&
1849                 AC_MSG_ERROR([EGL platform drm needs gbm])
1850         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1851         ;;
1852
1853     surfaceless)
1854         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1855         ;;
1856
1857     android)
1858         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1859         if test -n "$with_gallium_drivers"; then
1860             PKG_CHECK_MODULES([BACKTRACE], [backtrace])
1861         fi
1862         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1863         ;;
1864
1865     *)
1866         AC_MSG_ERROR([platform '$plat' does not exist])
1867         ;;
1868     esac
1869
1870     case "$plat" in
1871     wayland|drm|surfaceless)
1872         require_libdrm "Platform $plat"
1873         ;;
1874     esac
1875 done
1876 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1877
1878 if test "x$enable_glx" != xno; then
1879     if ! echo "$platforms" | grep -q 'x11'; then
1880         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1881     fi
1882 fi
1883
1884 if test x"$enable_dri3" = xyes; then
1885     DEFINES="$DEFINES -DHAVE_DRI3"
1886
1887     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1888     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1889     dri3_modifier_modules="xcb-dri3 >= $XCBDRI3_MODIFIERS_REQUIRED xcb-present >= $XCBPRESENT_MODIFIERS_REQUIRED"
1890     PKG_CHECK_MODULES([XCB_DRI3_MODIFIERS], [$dri3_modifier_modules], [have_dri3_modifiers=yes], [have_dri3_modifiers=no])
1891
1892     if test "x$have_dri3_modifiers" == xyes; then
1893         DEFINES="$DEFINES -DHAVE_DRI3_MODIFIERS"
1894     fi
1895 fi
1896
1897
1898 if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1899     have_xlease=yes
1900 else
1901     have_xlease=no
1902 fi
1903
1904 if test x"$have_xlease" = xyes; then
1905     randr_modules="x11-xcb xcb-randr"
1906     PKG_CHECK_MODULES([XCB_RANDR], [$randr_modules])
1907     xlib_randr_modules="xrandr"
1908     PKG_CHECK_MODULES([XLIB_RANDR], [$xlib_randr_modules])
1909 fi
1910
1911 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1912 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1913 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1914 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1915 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1916
1917 AC_ARG_ENABLE(xlib-lease,
1918     [AS_HELP_STRING([--enable-xlib-lease]
1919                     [enable VK_acquire_xlib_display using X leases])],
1920     [enable_xlib_lease=$enableval], [enable_xlib_lease=auto])
1921 case "x$enable_xlib_lease" in
1922 xyes)
1923     ;;
1924 xno)
1925     ;;
1926 *)
1927     if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1928         enable_xlib_lease=yes
1929     else
1930         enable_xlib_lease=no
1931     fi
1932 esac
1933
1934 AM_CONDITIONAL(HAVE_XLIB_LEASE, test "x$enable_xlib_lease" = xyes)
1935
1936 dnl
1937 dnl More DRI setup
1938 dnl
1939 dnl Directory for DRI drivers
1940 AC_ARG_WITH([dri-driverdir],
1941     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1942         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1943     [DRI_DRIVER_INSTALL_DIR="$withval"],
1944     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1945 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1946 dnl Extra search path for DRI drivers
1947 AC_ARG_WITH([dri-searchpath],
1948     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1949         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1950     [DRI_DRIVER_SEARCH_DIR="$withval"],
1951     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1952 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1953 dnl Which drivers to build - default is chosen by platform
1954 AC_ARG_WITH([dri-drivers],
1955     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1956         [comma delimited classic DRI drivers list, e.g.
1957         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1958     [with_dri_drivers="$withval"],
1959     [with_dri_drivers=auto])
1960
1961 if test "x$with_dri_drivers" = xauto; then
1962     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1963         with_dri_drivers="yes"
1964     else
1965         with_dri_drivers="no"
1966     fi
1967 fi
1968 if test "x$with_dri_drivers" = xno; then
1969     with_dri_drivers=''
1970 fi
1971
1972 # Check for expat
1973 PKG_CHECK_MODULES([EXPAT], [expat],,
1974     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1975 )
1976
1977 dnl If $with_dri_drivers is yes, drivers will be added through
1978 dnl platform checks. Set DEFINES and LIB_DEPS
1979 if test "x$enable_dri" = xyes; then
1980     # Platform specific settings and drivers to build
1981     case "$host_os" in
1982     linux*)
1983         case "$host_cpu" in
1984         powerpc* | sparc*)
1985             # Build only the drivers for cards that exist on PowerPC/sparc
1986             if test "x$with_dri_drivers" = "xyes"; then
1987                 with_dri_drivers="r200 radeon swrast"
1988             fi
1989             ;;
1990         esac
1991         ;;
1992     cygwin*)
1993         if test "x$with_dri_drivers" = "xyes"; then
1994             with_dri_drivers="swrast"
1995         fi
1996         ;;
1997     darwin*)
1998         DEFINES="$DEFINES -DBUILDING_MESA"
1999         if test "x$with_dri_drivers" = "xyes"; then
2000             with_dri_drivers="swrast"
2001         fi
2002         ;;
2003     esac
2004
2005     # default drivers
2006     if test "x$with_dri_drivers" = "xyes"; then
2007         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
2008     fi
2009
2010     # put all the necessary libs together
2011     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
2012 fi
2013
2014 AC_SUBST([DRI_LIB_DEPS])
2015
2016 DRI_DIRS=''
2017 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
2018 if test -n "$with_dri_drivers"; then
2019     if test "x$enable_opengl" != xyes; then
2020         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
2021     fi
2022
2023     dri_drivers=`IFS=', '; echo $with_dri_drivers`
2024     for driver in $dri_drivers; do
2025         DRI_DIRS="$DRI_DIRS $driver"
2026         case "x$driver" in
2027         xi915)
2028             require_libdrm "i915"
2029             HAVE_I915_DRI=yes
2030             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2031             ;;
2032         xi965)
2033             require_libdrm "i965"
2034             HAVE_I965_DRI=yes
2035             ;;
2036         xnouveau)
2037             require_libdrm "nouveau"
2038             HAVE_NOUVEAU_DRI=yes
2039             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
2040             ;;
2041         xradeon)
2042             require_libdrm "radeon"
2043             HAVE_RADEON_DRI=yes;
2044             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2045             ;;
2046         xr200)
2047             require_libdrm "r200"
2048             HAVE_R200_DRI=yes
2049             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2050             ;;
2051         xswrast)
2052             HAVE_SWRAST_DRI=yes
2053             ;;
2054         *)
2055             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
2056             ;;
2057         esac
2058     done
2059     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2060 fi
2061
2062
2063 dnl
2064 dnl Gallium LLVM
2065 dnl Deprecated: kept for backwards compatibility
2066 dnl
2067 AC_ARG_ENABLE([gallium-llvm],
2068     [AS_HELP_STRING([--enable-gallium-llvm],
2069         [DEPRECATED: use --enable-llvm instead])],
2070     [enable_gallium_llvm="$enableval"],
2071     [enable_gallium_llvm=auto])
2072
2073 if test "x$enable_gallium_llvm" != xauto; then
2074    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2075    enable_llvm=$enable_gallium_llvm
2076 fi
2077
2078 dnl
2079 dnl LLVM
2080 dnl
2081 AC_ARG_ENABLE([llvm],
2082     [AS_HELP_STRING([--enable-llvm],
2083         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2084     [enable_llvm="$enableval"],
2085     [enable_llvm=auto])
2086
2087 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2088     if test "x$FOUND_LLVM" = xyes; then
2089         case "$host_cpu" in
2090         i*86|x86_64|amd64) enable_llvm=yes;;
2091         *) enable_llvm=no;;
2092         esac
2093     else
2094         enable_llvm=no
2095     fi
2096 fi
2097
2098 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2099     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2100 fi
2101
2102 #
2103 # Vulkan driver configuration
2104 #
2105
2106 AC_ARG_WITH([vulkan-drivers],
2107     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2108         [comma delimited Vulkan drivers list, e.g.
2109         "intel,radeon"
2110         @<:@default=no@:>@])],
2111     [with_vulkan_drivers="$withval"],
2112     [with_vulkan_drivers="no"])
2113
2114 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2115 # here so that the script doesn't choke on an unknown driver name later.
2116 case "x$with_vulkan_drivers" in
2117     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2118     xno) with_vulkan_drivers='' ;;
2119 esac
2120
2121 AC_ARG_WITH([vulkan-icddir],
2122     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2123         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2124     [VULKAN_ICD_INSTALL_DIR="$withval"],
2125     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2126 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2127
2128 require_x11_dri3() {
2129     if echo "$platforms" | grep -q 'x11'; then
2130         if test "x$enable_dri3" != xyes; then
2131             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2132         fi
2133     fi
2134 }
2135
2136 if test -n "$with_vulkan_drivers"; then
2137     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2138         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2139     fi
2140
2141     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2142     for driver in $VULKAN_DRIVERS; do
2143         case "x$driver" in
2144         xintel)
2145             require_libdrm "ANV"
2146             require_x11_dri3 "ANV"
2147             HAVE_INTEL_VULKAN=yes
2148             ;;
2149         xradeon)
2150             require_libdrm "radv"
2151             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2152             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2153             require_x11_dri3 "radv"
2154             if test "x$acv_mako_found" = xno; then
2155                 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
2156             fi
2157             HAVE_RADEON_VULKAN=yes
2158             ;;
2159         *)
2160             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2161             ;;
2162         esac
2163     done
2164     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2165 fi
2166
2167
2168 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2169 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2170 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2171                                   "x$enable_osmesa" = xyes -o \
2172                                   -n "$DRI_DIRS")
2173
2174 dnl
2175 dnl OSMesa configuration
2176 dnl
2177
2178 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2179 AC_ARG_WITH([osmesa-bits],
2180     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2181         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2182     [osmesa_bits="$withval"],
2183     [osmesa_bits=8])
2184 if test "x$osmesa_bits" != x8; then
2185     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2186         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2187         osmesa_bits=8
2188     fi
2189 fi
2190 case "x$osmesa_bits" in
2191 x8)
2192     OSMESA_LIB="${OSMESA_LIB}"
2193     ;;
2194 x16|x32)
2195     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2196     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2197     ;;
2198 *)
2199     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2200     ;;
2201 esac
2202
2203 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2204     # only link libraries with osmesa if shared
2205     if test "$enable_static" = no; then
2206         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2207     else
2208         OSMESA_LIB_DEPS=""
2209     fi
2210     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2211 fi
2212
2213 AC_SUBST([OSMESA_LIB_DEPS])
2214 AC_SUBST([OSMESA_PC_REQ])
2215 AC_SUBST([OSMESA_PC_LIB_PRIV])
2216
2217 dnl
2218 dnl gbm configuration
2219 dnl
2220 if test "x$enable_gbm" = xyes; then
2221     require_dri_shared_libs_and_glapi "gbm"
2222 fi
2223 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2224 # FINISHME: GBM has a number of dependencies which we should add below
2225 GBM_PC_REQ_PRIV=""
2226 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2227 AC_SUBST([GBM_PC_REQ_PRIV])
2228 AC_SUBST([GBM_PC_LIB_PRIV])
2229
2230 dnl
2231 dnl EGL configuration
2232 dnl
2233
2234 if test "x$enable_egl" = xyes; then
2235     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2236
2237     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2238
2239     require_dri_shared_libs_and_glapi "egl"
2240 fi
2241 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2242 AC_SUBST([EGL_LIB_DEPS])
2243
2244 gallium_st="mesa"
2245
2246 dnl
2247 dnl XA configuration
2248 dnl
2249 if test "x$enable_xa" = xyes; then
2250     if test "x$with_gallium_drivers" = xswrast; then
2251        AC_MSG_ERROR([
2252           Building xa requires at least one non swrast gallium driver.
2253           If you are looking to use libxatracker.so with the VMware driver,
2254           make sure to include svga in the gallium drivers list, apart from
2255           enabling XA.
2256           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2257     fi
2258     gallium_st="$gallium_st xa"
2259 fi
2260 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2261
2262 if echo $platforms | grep -q "x11"; then
2263     have_xvmc_platform=yes
2264 else
2265     have_xvmc_platform=no
2266 fi
2267
2268 if echo $platforms | grep -q "x11"; then
2269     have_vdpau_platform=yes
2270 else
2271     have_vdpau_platform=no
2272 fi
2273
2274 if echo $platforms | egrep -q "x11|drm"; then
2275     have_omx_platform=yes
2276 else
2277     have_omx_platform=no
2278 fi
2279
2280 if echo $platforms | egrep -q "x11|drm|wayland"; then
2281     have_va_platform=yes
2282 else
2283     have_va_platform=no
2284 fi
2285
2286 dnl
2287 dnl Gallium G3DVL configuration
2288 dnl
2289 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2290     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2291         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2292     fi
2293
2294     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2295         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2296     fi
2297
2298     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2299         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2300     fi
2301
2302     if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2303        PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2304     fi
2305
2306     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2307         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2308     fi
2309 fi
2310
2311 if test "x$enable_dri" = xyes -o \
2312         "x$enable_xvmc" = xyes -o \
2313         "x$enable_vdpau" = xyes -o \
2314         "x$enable_omx_bellagio" = xyes -o \
2315         "x$enable_omx_tizonia" = xyes -o \
2316         "x$enable_va" = xyes; then
2317     need_gallium_vl=yes
2318 fi
2319 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2320
2321 if test "x$enable_xvmc" = xyes -o \
2322         "x$enable_vdpau" = xyes -o \
2323         "x$enable_omx_bellagio" = xyes -o \
2324         "x$enable_omx_tizonia" = xyes -o \
2325         "x$enable_va" = xyes; then
2326     if echo $platforms | grep -q "x11"; then
2327         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2328     fi
2329     need_gallium_vl_winsys=yes
2330 fi
2331 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2332
2333 if test "x$enable_xvmc" = xyes; then
2334     if test "x$have_xvmc_platform" != xyes; then
2335         AC_MSG_ERROR([XVMC requires the x11 platforms])
2336     fi
2337     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2338     gallium_st="$gallium_st xvmc"
2339 fi
2340 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2341
2342 if test "x$enable_vdpau" = xyes; then
2343     if test "x$have_vdpau_platform" != xyes; then
2344         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2345     fi
2346     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2347     gallium_st="$gallium_st vdpau"
2348     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2349 fi
2350 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2351
2352 if test "x$enable_omx_bellagio" = xyes; then
2353     if test "x$have_omx_platform" != xyes; then
2354         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2355     fi
2356     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2357     gallium_st="$gallium_st omx_bellagio"
2358     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2359 else
2360     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 0)
2361 fi
2362 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2363
2364 if test "x$enable_omx_tizonia" = xyes; then
2365     if test "x$have_omx_platform" != xyes; then
2366         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2367     fi
2368     PKG_CHECK_MODULES([OMX_TIZONIA],
2369                       [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2370                        tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2371                        libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2372     gallium_st="$gallium_st omx_tizonia"
2373     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2374 else
2375     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 0)
2376 fi
2377 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2378
2379 if test "x$enable_va" = xyes; then
2380     if test "x$have_va_platform" != xyes; then
2381         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2382     fi
2383     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2384     gallium_st="$gallium_st va"
2385 fi
2386 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2387
2388 dnl
2389 dnl Nine Direct3D9 configuration
2390 dnl
2391 if test "x$enable_nine" = xyes; then
2392     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2393         AC_MSG_ERROR([nine requires the gallium swrast driver])
2394     fi
2395     if test "x$with_gallium_drivers" = xswrast; then
2396         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2397     fi
2398     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2399         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2400     fi
2401
2402     if test "x$enable_dri3" = xno; then
2403         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2404     fi
2405
2406     gallium_st="$gallium_st nine"
2407 fi
2408 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2409
2410 dnl
2411 dnl OpenCL configuration
2412 dnl
2413
2414 AC_ARG_WITH([clang-libdir],
2415    [AS_HELP_STRING([--with-clang-libdir],
2416          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2417    [CLANG_LIBDIR="$withval"],
2418    [CLANG_LIBDIR=''])
2419
2420 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2421
2422 if test "x$enable_opencl" = xyes; then
2423     if test -z "$with_gallium_drivers"; then
2424         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2425     fi
2426
2427     if test "x$HAVE_CXX11" != "xyes"; then
2428        AC_MSG_ERROR([clover requires c++11 support])
2429     fi
2430
2431     if test "x$have_libclc" = xno; then
2432         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2433                     Make sure the directory containing libclc.pc is specified in your
2434                     PKG_CONFIG_PATH environment variable.
2435                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2436     else
2437         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2438         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2439         AC_SUBST([LIBCLC_INCLUDEDIR])
2440         AC_SUBST([LIBCLC_LIBEXECDIR])
2441     fi
2442
2443     gallium_st="$gallium_st clover"
2444
2445     if test "x$enable_opencl_icd" = xyes; then
2446         OPENCL_LIBNAME="MesaOpenCL"
2447     else
2448         OPENCL_LIBNAME="OpenCL"
2449     fi
2450
2451     if test "x$have_libelf" != xyes; then
2452        AC_MSG_ERROR([Clover requires libelf])
2453     fi
2454
2455     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2456         altivec_enabled=no
2457         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2458         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2459         #error "AltiVec not enabled"
2460         #endif
2461         ])], altivec_enabled=yes)
2462
2463         if test "$altivec_enabled" = yes; then
2464             CLOVER_STD_OVERRIDE="-std=gnu++11"
2465         fi
2466         AC_SUBST([CLOVER_STD_OVERRIDE])
2467     fi
2468
2469     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2470
2471     llvm_add_default_components "opencl"
2472     llvm_add_component "all-targets" "opencl"
2473     llvm_add_component "coverage" "opencl"
2474     llvm_add_component "linker" "opencl"
2475     llvm_add_component "instrumentation" "opencl"
2476     llvm_add_component "ipo" "opencl"
2477     llvm_add_component "irreader" "opencl"
2478     llvm_add_component "lto" "opencl"
2479     llvm_add_component "option" "opencl"
2480     llvm_add_component "objcarcopts" "opencl"
2481     llvm_add_component "profiledata" "opencl"
2482     llvm_add_optional_component "coroutines" "opencl"
2483
2484     dnl Check for Clang internal headers
2485     if test -z "$CLANG_LIBDIR"; then
2486         CLANG_LIBDIR=${LLVM_LIBDIR}
2487     fi
2488     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2489     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2490         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2491 fi
2492 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2493 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2494 AC_SUBST([OPENCL_LIBNAME])
2495 AC_SUBST([CLANG_RESOURCE_DIR])
2496
2497 dnl
2498 dnl Gallium configuration
2499 dnl
2500 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2501
2502 # libEGL wants to default to the first platform specified in
2503 # ./configure.  parse that here.
2504 if test "x$platforms" != "x"; then
2505     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2506     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2507 else
2508     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2509 fi
2510
2511 AC_SUBST([EGL_NATIVE_PLATFORM])
2512 AC_SUBST([EGL_CFLAGS])
2513
2514 # If we don't have the X11 platform, set this define so we don't try to include
2515 # the X11 headers.
2516 if ! echo "$platforms" | grep -q 'x11'; then
2517     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2518     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2519 fi
2520
2521 dnl Directory for XVMC libs
2522 AC_ARG_WITH([xvmc-libdir],
2523     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2524         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2525     [XVMC_LIB_INSTALL_DIR="$withval"],
2526     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2527 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2528
2529 dnl
2530 dnl Gallium Tests
2531 dnl
2532 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2533
2534 dnl Directory for VDPAU libs
2535 AC_ARG_WITH([vdpau-libdir],
2536     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2537         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2538     [VDPAU_LIB_INSTALL_DIR="$withval"],
2539     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2540 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2541
2542 dnl Directory for OMX_BELLAGIO libs
2543
2544 AC_ARG_WITH([omx-bellagio-libdir],
2545     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2546         [directory for the OMX_BELLAGIO libraries])],
2547     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2548     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2549                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2550 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2551
2552 dnl Directory for OMX_TIZONIA libs
2553
2554 AC_ARG_WITH([omx-tizonia-libdir],
2555     [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2556         [directory for the OMX_TIZONIA libraries])],
2557     [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2558     [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2559 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2560
2561 dnl Directory for VA libs
2562
2563 AC_ARG_WITH([va-libdir],
2564     [AS_HELP_STRING([--with-va-libdir=DIR],
2565         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2566     [VA_LIB_INSTALL_DIR="$withval"],
2567     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2568 AC_SUBST([VA_LIB_INSTALL_DIR])
2569
2570 AC_ARG_WITH([d3d-libdir],
2571     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2572         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2573     [D3D_DRIVER_INSTALL_DIR="$withval"],
2574     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2575 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2576
2577 dnl Architectures to build SWR library for
2578
2579 AC_ARG_WITH([swr-archs],
2580     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2581         [comma delimited swr architectures list, e.g.
2582         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2583     [with_swr_archs="$withval"],
2584     [with_swr_archs="avx,avx2"])
2585
2586 dnl
2587 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2588 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2589 dnl architectures.
2590 dnl
2591 r300_require_llvm() {
2592     case "$host" in *gnux32) return;; esac
2593     case "$host_cpu" in
2594     i*86|x86_64|amd64) require_llvm $1
2595         ;;
2596     esac
2597 }
2598
2599 dnl
2600 dnl DRM is needed by X, Wayland, and offscreen rendering.
2601 dnl Surfaceless is an alternative for the last one.
2602 dnl
2603 require_basic_egl() {
2604     case "$with_platforms" in
2605         *drm*|*surfaceless*|*android*)
2606             ;;
2607         *)
2608             AC_MSG_ERROR([$1 requires one of these:
2609                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2610                   2) --with-platforms=surfaceless (offscreen only)
2611                   3) --with-platforms=android (Android only)
2612                   Recommended options: drm,x11])
2613             ;;
2614     esac
2615 }
2616
2617 swr_require_cxx_feature_flags() {
2618     feature_name="$1"
2619     preprocessor_test="$2"
2620     option_list="$3"
2621     output_var="$4"
2622
2623     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2624     AC_LANG_PUSH([C++])
2625     save_CXXFLAGS="$CXXFLAGS"
2626     save_IFS="$IFS"
2627     IFS=","
2628     found=0
2629     for opts in $option_list
2630     do
2631         unset IFS
2632         CXXFLAGS="$opts $save_CXXFLAGS"
2633         AC_COMPILE_IFELSE(
2634             [AC_LANG_PROGRAM(
2635                 [   #if !($preprocessor_test)
2636                     #error
2637                     #endif
2638                 ])],
2639             [found=1; break],
2640             [])
2641         IFS=","
2642     done
2643     IFS="$save_IFS"
2644     CXXFLAGS="$save_CXXFLAGS"
2645     AC_LANG_POP([C++])
2646     if test $found -eq 1; then
2647         AC_MSG_RESULT([$opts])
2648         eval "$output_var=\$opts"
2649         return 0
2650     fi
2651     AC_MSG_RESULT([no])
2652     AC_MSG_ERROR([swr requires $feature_name support])
2653     return 1
2654 }
2655
2656 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2657 if test -n "$with_gallium_drivers"; then
2658     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2659     for driver in $gallium_drivers; do
2660         case "x$driver" in
2661         xsvga)
2662             HAVE_GALLIUM_SVGA=yes
2663             require_libdrm "svga"
2664             ;;
2665         xi915)
2666             HAVE_GALLIUM_I915=yes
2667             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2668             require_libdrm "Gallium i915"
2669             ;;
2670         xr300)
2671             HAVE_GALLIUM_R300=yes
2672             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2673             require_libdrm "r300"
2674             r300_require_llvm "r300"
2675             ;;
2676         xr600)
2677             HAVE_GALLIUM_R600=yes
2678             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2679             require_libdrm "r600"
2680             if test "x$enable_llvm" = xyes; then
2681                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2682
2683                 llvm_add_component "asmparser" "r600"
2684                 llvm_add_component "bitreader" "r600"
2685             fi
2686             ;;
2687         xradeonsi)
2688             HAVE_GALLIUM_RADEONSI=yes
2689             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2690             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2691             require_libdrm "radeonsi"
2692             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2693             if test "x$enable_egl" = xyes; then
2694                 require_basic_egl "radeonsi"
2695             fi
2696             ;;
2697         xnouveau)
2698             HAVE_GALLIUM_NOUVEAU=yes
2699             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2700             require_libdrm "nouveau"
2701             ;;
2702         xfreedreno)
2703             HAVE_GALLIUM_FREEDRENO=yes
2704             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2705             require_libdrm "freedreno"
2706             ;;
2707         xetnaviv)
2708             HAVE_GALLIUM_ETNAVIV=yes
2709             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2710             require_libdrm "etnaviv"
2711             ;;
2712        ximx)
2713             HAVE_GALLIUM_IMX=yes
2714             ;;
2715         xtegra)
2716             HAVE_GALLIUM_TEGRA=yes
2717             require_libdrm "tegra"
2718             ;;
2719         xswrast)
2720             HAVE_GALLIUM_SOFTPIPE=yes
2721             if test "x$enable_llvm" = xyes; then
2722                 HAVE_GALLIUM_LLVMPIPE=yes
2723             fi
2724             ;;
2725         xswr)
2726             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2727
2728             if test "x$HAVE_CXX11" != "xyes"; then
2729                 AC_MSG_ERROR([swr requires c++11 support])
2730             fi
2731
2732             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2733                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2734                 SWR_AVX_CXXFLAGS
2735             AC_SUBST([SWR_AVX_CXXFLAGS])
2736
2737             swr_archs=`IFS=', '; echo $with_swr_archs`
2738             for arch in $swr_archs; do
2739                 case "x$arch" in
2740                 xavx)
2741                     HAVE_SWR_AVX=yes
2742                     ;;
2743                 xavx2)
2744                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2745                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2746                         SWR_AVX2_CXXFLAGS
2747                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2748                     HAVE_SWR_AVX2=yes
2749                     ;;
2750                 xknl)
2751                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2752                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2753                         SWR_KNL_CXXFLAGS
2754                     AC_SUBST([SWR_KNL_CXXFLAGS])
2755                     HAVE_SWR_KNL=yes
2756                     ;;
2757                 xskx)
2758                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2759                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2760                         SWR_SKX_CXXFLAGS
2761                     AC_SUBST([SWR_SKX_CXXFLAGS])
2762                     HAVE_SWR_SKX=yes
2763                     ;;
2764                 *)
2765                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2766                     ;;
2767                 esac
2768             done
2769
2770             if test "x$HAVE_SWR_AVX" != xyes -a \
2771                     "x$HAVE_SWR_AVX2" != xyes -a \
2772                     "x$HAVE_SWR_KNL" != xyes -a \
2773                     "x$HAVE_SWR_SKX" != xyes; then
2774                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2775             fi
2776
2777             # test if more than one swr arch configured
2778             if test `echo $swr_archs | wc -w` -eq 1; then
2779                 HAVE_SWR_BUILTIN=yes
2780             fi
2781
2782             HAVE_GALLIUM_SWR=yes
2783             ;;
2784         xvc4)
2785             HAVE_GALLIUM_VC4=yes
2786             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED])
2787
2788             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2789                               [USE_VC4_SIMULATOR=yes;
2790                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2791                               [USE_VC4_SIMULATOR=no])
2792             ;;
2793         xv3d)
2794             HAVE_GALLIUM_V3D=yes
2795
2796             PKG_CHECK_MODULES([V3D_SIMULATOR], [v3dv3],
2797                               [USE_V3D_SIMULATOR=yes;
2798                                DEFINES="$DEFINES -DUSE_V3D_SIMULATOR"],
2799                               [USE_V3D_SIMULATOR=no])
2800             ;;
2801         xpl111)
2802             HAVE_GALLIUM_PL111=yes
2803             ;;
2804         xvirgl)
2805             HAVE_GALLIUM_VIRGL=yes
2806             require_libdrm "virgl"
2807             if test "x$enable_egl" = xyes; then
2808                 require_basic_egl "virgl"
2809             fi
2810             ;;
2811         *)
2812             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2813             ;;
2814         esac
2815     done
2816 fi
2817
2818 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2819 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x5.0.0 -a \
2820                                               "x$LLVM_VERSION" != x5.0.1 -a \
2821                                               "x$LLVM_VERSION" != x5.0.2)
2822
2823 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2824     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2825     llvm_add_default_components "gallium"
2826 fi
2827
2828 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2829 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2830 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2831 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2832 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2833
2834 dnl We need to validate some needed dependencies for renderonly drivers.
2835
2836 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2837     AC_MSG_ERROR([Building with imx requires etnaviv])
2838 fi
2839
2840 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2841     AC_MSG_ERROR([Building with pl111 requires vc4])
2842 fi
2843
2844 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2845     AC_MSG_ERROR([Building with tegra requires nouveau])
2846 fi
2847
2848 detect_old_buggy_llvm() {
2849     dnl llvm-config may not give the right answer when llvm is a built as a
2850     dnl single shared library, so we must work the library name out for
2851     dnl ourselves.
2852     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2853     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2854     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2855     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2856
2857     if test "x$llvm_have_one_so" = xyes; then
2858         dnl LLVM was built using auto*, so there is only one shared object.
2859         LLVM_LIBS="-l$LLVM_SO_NAME"
2860     else
2861         dnl If LLVM was built with CMake, there will be one shared object per
2862         dnl component.
2863         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2864                [AC_MSG_ERROR([Could not find llvm shared libraries:
2865                 Please make sure you have built llvm with the --enable-shared option
2866                 and that your llvm libraries are installed in $LLVM_LIBDIR
2867                 If you have installed your llvm libraries to a different directory you
2868                 can use the --with-llvm-prefix= configure flag to specify this directory.
2869                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2870                 If you do not want to build with llvm shared libraries and instead want to
2871                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2872                 invocation and rebuild.])])
2873
2874         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2875         dnl install uses a shared object for each component and we have
2876         dnl already added all of these objects to LLVM_LIBS.
2877     fi
2878 }
2879
2880 dnl
2881 dnl Set defines and buildtime variables only when using LLVM.
2882 dnl
2883 if test "x$enable_llvm" = xyes; then
2884     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2885
2886     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2887     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2888     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2889
2890     dnl Set LLVM_LIBS - This is done after the driver configuration so
2891     dnl that drivers can add additional components to LLVM_COMPONENTS.
2892     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2893     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2894     dnl this was causing the same libraries to be appear multiple times
2895     dnl in LLVM_LIBS.
2896
2897     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2898         if test "x$enable_llvm_shared_libs" = xyes; then
2899             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2900         else
2901             dnl Invoking llvm-config with both -libs and --system-libs produces the
2902             dnl two separate lines - each for the set of libraries.
2903                 dnl Call the program twice, effectively folding them into a single line.
2904             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2905             dnl We need to link to llvm system libs when using static libs
2906             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2907         fi
2908     else
2909         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2910         if test "x$enable_llvm_shared_libs" = xyes; then
2911             detect_old_buggy_llvm
2912         else
2913             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2914             dnl We need to link to llvm system libs when using static libs
2915             dnl However, only llvm 3.5+ provides --system-libs
2916             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2917                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2918             fi
2919         fi
2920     fi
2921
2922     dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2923     dnl swr/llvmpipe driver into the final binary.  Adding LLVM_LIBS results in
2924     dnl the LLVM library propagated in the Libs.private of the respective .pc
2925     dnl file which ensures complete dependency information when statically
2926     dnl linking.
2927     if test "x$enable_glx" == xgallium-xlib; then
2928         GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2929     fi
2930     if test "x$enable_gallium_osmesa" = xyes; then
2931         OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2932     fi
2933 fi
2934
2935 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2936 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2937 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2938 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2939 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2940 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2941 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2942 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2943 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2944 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2945 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2946 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2947 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2948 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2949 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2950                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2951                                          "x$HAVE_GALLIUM_SWR" = xyes)
2952 AM_CONDITIONAL(HAVE_GALLIUM_V3D, test "x$HAVE_GALLIUM_V3D" = xyes)
2953 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2954 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2955
2956 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2957
2958 if test "x$enable_dri" = xyes; then
2959     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2960 fi
2961
2962 if test "x$have_drisw_kms" = xyes; then
2963     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2964 fi
2965 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2966
2967 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2968 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2969 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2970 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2971 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2972 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2973
2974 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2975 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2976
2977 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2978                                       "x$HAVE_RADEON_VULKAN" = xyes)
2979
2980 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2981                                       "x$HAVE_GALLIUM_V3D" = xyes)
2982
2983 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2984                                         "x$HAVE_I965_DRI" = xyes)
2985
2986 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2987                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2988                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2989 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2990 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2991 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2992 AM_CONDITIONAL(USE_V3D_SIMULATOR, test x$USE_V3D_SIMULATOR = xyes)
2993 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2994
2995 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2996 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2997 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2998 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2999                                         "x$enable_gallium_osmesa" = xyes)
3000
3001 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
3002 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
3003 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
3004 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
3005 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
3006 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
3007
3008 AC_SUBST([NINE_MAJOR], 1)
3009 AC_SUBST([NINE_MINOR], 0)
3010 AC_SUBST([NINE_PATCH], 0)
3011 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
3012
3013 AC_SUBST([VDPAU_MAJOR], 1)
3014 AC_SUBST([VDPAU_MINOR], 0)
3015
3016 if test "x$enable_va" = xyes; then
3017     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
3018     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
3019 fi
3020 AC_SUBST([VA_MAJOR], $VA_MAJOR)
3021 AC_SUBST([VA_MINOR], $VA_MINOR)
3022
3023 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
3024
3025 AC_SUBST([XVMC_MAJOR], 1)
3026 AC_SUBST([XVMC_MINOR], 0)
3027
3028 AC_SUBST([XA_MAJOR], 2)
3029 AC_SUBST([XA_MINOR], 4)
3030 AC_SUBST([XA_PATCH], 0)
3031 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
3032
3033 AC_ARG_ENABLE(valgrind,
3034               [AS_HELP_STRING([--enable-valgrind],
3035                              [Build mesa with valgrind support (default: auto)])],
3036                              [VALGRIND=$enableval], [VALGRIND=auto])
3037 if test "x$VALGRIND" != xno; then
3038     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
3039 fi
3040 AC_MSG_CHECKING([whether to enable Valgrind support])
3041 if test "x$VALGRIND" = xauto; then
3042     VALGRIND="$have_valgrind"
3043 fi
3044
3045 if test "x$VALGRIND" = "xyes"; then
3046     if ! test "x$have_valgrind" = xyes; then
3047         AC_MSG_ERROR([Valgrind support required but not present])
3048     fi
3049     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
3050 fi
3051
3052 AC_MSG_RESULT([$VALGRIND])
3053
3054 dnl Restore LDFLAGS and CPPFLAGS
3055 LDFLAGS="$_SAVE_LDFLAGS"
3056 CPPFLAGS="$_SAVE_CPPFLAGS"
3057
3058 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
3059 if test "x$acv_mesa_CLANG" = xyes; then
3060     CFLAGS="$CFLAGS -Qunused-arguments"
3061     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
3062 fi
3063
3064 dnl Add user CFLAGS and CXXFLAGS
3065 CFLAGS="$CFLAGS $USER_CFLAGS"
3066 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
3067
3068 dnl Substitute the config
3069 AC_CONFIG_FILES([Makefile
3070                  src/Makefile
3071                  src/amd/Makefile
3072                  src/amd/vulkan/Makefile
3073                  src/broadcom/Makefile
3074                  src/compiler/Makefile
3075                  src/egl/Makefile
3076                  src/egl/main/egl.pc
3077                  src/egl/wayland/wayland-drm/Makefile
3078                  src/gallium/Makefile
3079                  src/gallium/auxiliary/Makefile
3080                  src/gallium/auxiliary/pipe-loader/Makefile
3081                  src/gallium/drivers/freedreno/Makefile
3082                  src/gallium/drivers/i915/Makefile
3083                  src/gallium/drivers/llvmpipe/Makefile
3084                  src/gallium/drivers/nouveau/Makefile
3085                  src/gallium/drivers/pl111/Makefile
3086                  src/gallium/drivers/r300/Makefile
3087                  src/gallium/drivers/r600/Makefile
3088                  src/gallium/drivers/radeonsi/Makefile
3089                  src/gallium/drivers/softpipe/Makefile
3090                  src/gallium/drivers/svga/Makefile
3091                  src/gallium/drivers/swr/Makefile
3092                  src/gallium/drivers/tegra/Makefile
3093                  src/gallium/drivers/etnaviv/Makefile
3094                  src/gallium/drivers/imx/Makefile
3095                  src/gallium/drivers/v3d/Makefile
3096                  src/gallium/drivers/vc4/Makefile
3097                  src/gallium/drivers/virgl/Makefile
3098                  src/gallium/state_trackers/clover/Makefile
3099                  src/gallium/state_trackers/dri/Makefile
3100                  src/gallium/state_trackers/glx/xlib/Makefile
3101                  src/gallium/state_trackers/nine/Makefile
3102                  src/gallium/state_trackers/omx/Makefile
3103                  src/gallium/state_trackers/omx/bellagio/Makefile
3104                  src/gallium/state_trackers/omx/tizonia/Makefile
3105                  src/gallium/state_trackers/osmesa/Makefile
3106                  src/gallium/state_trackers/va/Makefile
3107                  src/gallium/state_trackers/vdpau/Makefile
3108                  src/gallium/state_trackers/xa/Makefile
3109                  src/gallium/state_trackers/xa/xa_tracker.h
3110                  src/gallium/state_trackers/xvmc/Makefile
3111                  src/gallium/targets/d3dadapter9/Makefile
3112                  src/gallium/targets/d3dadapter9/d3d.pc
3113                  src/gallium/targets/dri/Makefile
3114                  src/gallium/targets/libgl-xlib/Makefile
3115                  src/gallium/targets/omx/Makefile
3116                  src/gallium/targets/opencl/Makefile
3117                  src/gallium/targets/opencl/mesa.icd
3118                  src/gallium/targets/osmesa/Makefile
3119                  src/gallium/targets/osmesa/osmesa.pc
3120                  src/gallium/targets/pipe-loader/Makefile
3121                  src/gallium/targets/va/Makefile
3122                  src/gallium/targets/vdpau/Makefile
3123                  src/gallium/targets/xa/Makefile
3124                  src/gallium/targets/xa/xatracker.pc
3125                  src/gallium/targets/xvmc/Makefile
3126                  src/gallium/tests/trivial/Makefile
3127                  src/gallium/tests/unit/Makefile
3128                  src/gallium/winsys/etnaviv/drm/Makefile
3129                  src/gallium/winsys/imx/drm/Makefile
3130                  src/gallium/winsys/freedreno/drm/Makefile
3131                  src/gallium/winsys/i915/drm/Makefile
3132                  src/gallium/winsys/nouveau/drm/Makefile
3133                  src/gallium/winsys/pl111/drm/Makefile
3134                  src/gallium/winsys/radeon/drm/Makefile
3135                  src/gallium/winsys/amdgpu/drm/Makefile
3136                  src/gallium/winsys/svga/drm/Makefile
3137                  src/gallium/winsys/sw/dri/Makefile
3138                  src/gallium/winsys/sw/kms-dri/Makefile
3139                  src/gallium/winsys/sw/null/Makefile
3140                  src/gallium/winsys/sw/wrapper/Makefile
3141                  src/gallium/winsys/sw/xlib/Makefile
3142                  src/gallium/winsys/tegra/drm/Makefile
3143                  src/gallium/winsys/v3d/drm/Makefile
3144                  src/gallium/winsys/vc4/drm/Makefile
3145                  src/gallium/winsys/virgl/drm/Makefile
3146                  src/gallium/winsys/virgl/vtest/Makefile
3147                  src/gbm/Makefile
3148                  src/gbm/main/gbm.pc
3149                  src/glx/Makefile
3150                  src/glx/apple/Makefile
3151                  src/glx/tests/Makefile
3152                  src/glx/windows/Makefile
3153                  src/glx/windows/windowsdriproto.pc
3154                  src/gtest/Makefile
3155                  src/intel/Makefile
3156                  src/loader/Makefile
3157                  src/mapi/Makefile
3158                  src/mapi/es1api/glesv1_cm.pc
3159                  src/mapi/es2api/glesv2.pc
3160                  src/mapi/glapi/gen/Makefile
3161                  src/mesa/Makefile
3162                  src/mesa/gl.pc
3163                  src/mesa/drivers/dri/dri.pc
3164                  src/mesa/drivers/dri/common/Makefile
3165                  src/mesa/drivers/dri/i915/Makefile
3166                  src/mesa/drivers/dri/i965/Makefile
3167                  src/mesa/drivers/dri/Makefile
3168                  src/mesa/drivers/dri/nouveau/Makefile
3169                  src/mesa/drivers/dri/r200/Makefile
3170                  src/mesa/drivers/dri/radeon/Makefile
3171                  src/mesa/drivers/dri/swrast/Makefile
3172                  src/mesa/drivers/osmesa/Makefile
3173                  src/mesa/drivers/osmesa/osmesa.pc
3174                  src/mesa/drivers/x11/Makefile
3175                  src/mesa/main/tests/Makefile
3176                  src/mesa/state_tracker/tests/Makefile
3177                  src/util/Makefile
3178                  src/util/tests/hash_table/Makefile
3179                  src/util/tests/set/Makefile
3180                  src/util/tests/string_buffer/Makefile
3181                  src/util/tests/vma/Makefile
3182                  src/util/xmlpool/Makefile
3183                  src/vulkan/Makefile])
3184
3185 AC_OUTPUT
3186
3187 # Fix up dependencies in *.Plo files, where we changed the extension of a
3188 # source file
3189 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3190
3191 rm -f src/compiler/spirv/spirv_info.lo
3192 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3193
3194 rm -f src/compiler/nir/.deps/nir_intrinsics.Plo
3195 echo "# dummy" > src/compiler/nir/.deps/nir_intrinsics.Plo
3196
3197 dnl
3198 dnl Output some configuration info for the user
3199 dnl
3200 echo ""
3201 echo "        prefix:          $prefix"
3202 echo "        exec_prefix:     $exec_prefix"
3203 echo "        libdir:          $libdir"
3204 echo "        includedir:      $includedir"
3205
3206 dnl API info
3207 echo ""
3208 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3209
3210 dnl Driver info
3211 echo ""
3212 case "x$enable_osmesa$enable_gallium_osmesa" in
3213 xnoyes)
3214         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3215         ;;
3216 xyesno)
3217         echo "        OSMesa:          lib$OSMESA_LIB"
3218         ;;
3219 xnono)
3220         echo "        OSMesa:          no"
3221         ;;
3222 esac
3223
3224 echo ""
3225 if test "x$enable_dri" != xno; then
3226         echo "        DRI platform:    $dri_platform"
3227         if test -z "$DRI_DIRS"; then
3228             echo "        DRI drivers:     no"
3229         else
3230             echo "        DRI drivers:     $DRI_DIRS"
3231         fi
3232         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3233 fi
3234
3235 case "x$enable_glx" in
3236 xdri)
3237     echo "        GLX:             DRI-based"
3238     ;;
3239 xxlib)
3240     echo "        GLX:             Xlib-based"
3241     ;;
3242 xgallium-xlib)
3243     echo "        GLX:             Xlib-based (Gallium)"
3244     ;;
3245 *)
3246     echo "        GLX:             $enable_glx"
3247     ;;
3248 esac
3249
3250 dnl EGL
3251 echo ""
3252 echo "        EGL:             $enable_egl"
3253 if test "$enable_egl" = yes; then
3254
3255     egl_drivers=""
3256     if test "x$enable_dri" != "xno"; then
3257         egl_drivers="$egl_drivers builtin:egl_dri2"
3258     fi
3259     if test "x$enable_dri3" != "xno"; then
3260         egl_drivers="$egl_drivers builtin:egl_dri3"
3261     fi
3262
3263     echo "        EGL drivers:    $egl_drivers"
3264 fi
3265 if test "x$enable_gbm" = xyes; then
3266     echo "        GBM:             yes"
3267 else
3268     echo "        GBM:             no"
3269 fi
3270
3271     echo "        EGL/Vulkan/VL platforms:   $platforms"
3272
3273 # Vulkan
3274 echo ""
3275 if test "x$VULKAN_DRIVERS" != x; then
3276     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3277     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3278 else
3279     echo "        Vulkan drivers:  no"
3280 fi
3281
3282 echo ""
3283 if test "x$enable_llvm" = xyes; then
3284     echo "        llvm:            yes"
3285     echo "        llvm-config:     $LLVM_CONFIG"
3286     echo "        llvm-version:    $LLVM_VERSION"
3287 else
3288     echo "        llvm:            no"
3289 fi
3290
3291 echo ""
3292 if test -n "$with_gallium_drivers"; then
3293     echo "        Gallium drivers: $gallium_drivers"
3294     echo "        Gallium st:      $gallium_st"
3295 else
3296     echo "        Gallium:         no"
3297 fi
3298
3299 echo ""
3300 if test "x$enable_gallium_extra_hud" != xyes; then
3301     echo "        HUD extra stats: no"
3302 else
3303     echo "        HUD extra stats: yes"
3304 fi
3305
3306 if test "x$enable_lmsensors" != xyes; then
3307     echo "        HUD lmsensors:   no"
3308 else
3309     echo "        HUD lmsensors:   yes"
3310 fi
3311
3312 echo ""
3313 if test "x$HAVE_GALLIUM_SWR" != x; then
3314     if test "x$HAVE_SWR_BUILTIN" = xyes; then
3315         echo "        SWR archs:       $swr_archs (builtin)"
3316     else
3317         echo "        SWR archs:       $swr_archs"
3318     fi
3319 fi
3320
3321 dnl Libraries
3322 echo ""
3323 echo "        Shared libs:     $enable_shared"
3324 echo "        Static libs:     $enable_static"
3325 echo "        Shared-glapi:    $enable_shared_glapi"
3326
3327 dnl Compiler options
3328 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3329 cflags=`echo $CFLAGS | \
3330     $SED 's/^ *//;s/  */ /;s/ *$//'`
3331 cxxflags=`echo $CXXFLAGS | \
3332     $SED 's/^ *//;s/  */ /;s/ *$//'`
3333 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3334 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3335 echo ""
3336 echo "        CFLAGS:          $cflags"
3337 echo "        CXXFLAGS:        $cxxflags"
3338 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3339 echo "        LDFLAGS:         $ldflags"
3340 echo "        Macros:          $defines"
3341 echo ""
3342 if test "x$enable_llvm" = xyes; then
3343     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3344     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3345     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3346     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3347     echo ""
3348 fi
3349 echo "        PYTHON2:         $PYTHON2"
3350
3351 echo ""
3352 echo "        Run '${MAKE-make}' to build Mesa"
3353 echo ""