configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.59],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  33 AM_MAINTAINER_MODE([enable])
  34
  35 # Enable quiet compiles on automake 1.11.
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 # Check for programs
  39 AC_PROG_CC
  40
  41 AC_USE_SYSTEM_EXTENSIONS
  42 AC_SYS_LARGEFILE
  43 AC_FUNC_ALLOCA
  44
  45 # Initialize libtool
  46 LT_PREREQ([2.2])
  47 LT_INIT([disable-static])
  48
  49
  50 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  51 AC_SUBST(PTHREADSTUBS_CFLAGS)
  52 AC_SUBST(PTHREADSTUBS_LIBS)
  53
  54 pkgconfigdir=${libdir}/pkgconfig
  55 AC_SUBST(pkgconfigdir)
  56 AC_ARG_ENABLE([udev],
  57               [AS_HELP_STRING([--enable-udev],
  58                               [Enable support for using udev instead of mknod (default: disabled)])],
  59               [UDEV=$enableval], [UDEV=no])
  60
  61 AC_ARG_ENABLE(libkms,
  62               AS_HELP_STRING([--disable-libkms],
  63               [Disable KMS mm abstraction library (default: auto, enabled on x86]),
  64               [LIBKMS=$enableval], [LIBKMS=auto])
  65
  66 AC_ARG_ENABLE(intel,
  67               AS_HELP_STRING([--disable-intel],
  68               [Enable support for intel's KMS API (default: auto)]),
  69               [INTEL=$enableval], [INTEL=auto])
  70
  71 AC_ARG_ENABLE(radeon,
  72               AS_HELP_STRING([--disable-radeon],
  73               [Enable support for radeon's KMS API (default: auto)]),
  74               [RADEON=$enableval], [RADEON=auto])
  75
  76 AC_ARG_ENABLE(nouveau,
  77               AS_HELP_STRING([--disable-nouveau],
  78               [Enable support for nouveau's KMS API (default: auto)]),
  79               [NOUVEAU=$enableval], [NOUVEAU=auto])
  80
  81 AC_ARG_ENABLE(vmwgfx,
  82               AS_HELP_STRING([--disable-vmwgfx],
  83               [Enable support for vmwgfx's KMS API (default: yes)]),
  84               [VMWGFX=$enableval], [VMWGFX=yes])
  85
  86 AC_ARG_ENABLE(omap-experimental-api,
  87               AS_HELP_STRING([--enable-omap-experimental-api],
  88               [Enable support for OMAP's experimental API (default: disabled)]),
  89               [OMAP=$enableval], [OMAP=no])
  90
  91 AC_ARG_ENABLE(exynos-experimental-api,
  92               AS_HELP_STRING([--enable-exynos-experimental-api],
  93               [Enable support for EXYNOS's experimental API (default: disabled)]),
  94               [EXYNOS=$enableval], [EXYNOS=no])
  95
  96 AC_ARG_ENABLE(freedreno,
  97               AS_HELP_STRING([--disable-freedreno],
  98               [Enable support for freedreno's KMS API (default: auto, enabled on arm)]),
  99               [FREEDRENO=$enableval], [FREEDRENO=auto])
 100
 101 AC_ARG_ENABLE(freedreno-kgsl,
 102               AS_HELP_STRING([--enable-freedreno-kgsl],
 103               [Enable support for freedreno's to use downstream android kernel API (default: disabled)]),
 104               [FREEDRENO_KGSL=$enableval], [FREEDRENO_KGSL=no])
 105
 106 AC_ARG_ENABLE(tegra-experimental-api,
 107               AS_HELP_STRING([--enable-tegra-experimental-api],
 108               [Enable support for Tegra's experimental API (default: disabled)]),
 109               [TEGRA=$enableval], [TEGRA=no])
 110
 111 AC_ARG_ENABLE(install-test-programs,
 112                   AS_HELP_STRING([--enable-install-test-programs],
 113                   [Install test programs (default: no)]),
 114                   [INSTALL_TESTS=$enableval], [INSTALL_TESTS=no])
 115
 116 dnl ===========================================================================
 117 dnl check compiler flags
 118 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 119   AC_MSG_CHECKING([whether $CC supports $1])
 120
 121   libdrm_save_CFLAGS="$CFLAGS"
 122   CFLAGS="$CFLAGS $1"
 123
 124   AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 125   CFLAGS="$libdrm_save_CFLAGS"
 126
 127   if test "x$libdrm_cc_flag" = "xyes"; then
 128     ifelse([$2], , :, [$2])
 129   else
 130     ifelse([$3], , :, [$3])
 131   fi
 132   AC_MSG_RESULT([$libdrm_cc_flag])
 133 ])
 134
 135 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 136
 137 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 138                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 139                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 140 AC_SUBST([CLOCK_LIB])
 141
 142 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 143
 144 dnl Use lots of warning flags with with gcc and compatible compilers
 145
 146 dnl Note: if you change the following variable, the cache is automatically
 147 dnl skipped and all flags rechecked.  So there's no need to do anything
 148 dnl else.  If for any reason you need to force a recheck, just change
 149 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 150
 151 MAYBE_WARN="-Wall -Wextra \
 152 -Wsign-compare -Werror-implicit-function-declaration \
 153 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 154 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 155 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 156 -Wstrict-aliasing=2 -Winit-self \
 157 -Wdeclaration-after-statement -Wold-style-definition \
 158 -Wno-missing-field-initializers -Wno-unused-parameter \
 159 -Wno-attributes -Wno-long-long -Winline"
 160
 161 # invalidate cached value if MAYBE_WARN has changed
 162 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 163         unset libdrm_cv_warn_cflags
 164 fi
 165 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 166         echo
 167         WARN_CFLAGS=""
 168
 169         # Some warning options are not supported by all versions of
 170         # gcc, so test all desired options against the current
 171         # compiler.
 172         #
 173         # Note that there are some order dependencies
 174         # here. Specifically, an option that disables a warning will
 175         # have no net effect if a later option then enables that
 176         # warnings, (perhaps implicitly). So we put some grouped
 177         # options (-Wall and -Wextra) up front and the -Wno options
 178         # last.
 179
 180         for W in $MAYBE_WARN; do
 181                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 182         done
 183
 184         libdrm_cv_warn_cflags=$WARN_CFLAGS
 185         libdrm_cv_warn_maybe=$MAYBE_WARN
 186
 187         AC_MSG_CHECKING([which warning flags were supported])])
 188 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 189
 190 # Check for atomic intrinsics
 191 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives, [
 192         drm_cv_atomic_primitives="none"
 193
 194         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 195         int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 196         int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 197                                           ]],[[]])], [drm_cv_atomic_primitives="Intel"],[])
 198
 199         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 200                 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 201         fi
 202
 203         # atomic functions defined in <atomic.h> & libc on Solaris
 204         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 205                 AC_CHECK_FUNC([atomic_cas_uint], drm_cv_atomic_primitives="Solaris")
 206         fi
 207 ])
 208
 209 if test "x$drm_cv_atomic_primitives" = xIntel; then
 210         AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 211                 [Enable if your compiler supports the Intel __sync_* atomic primitives])
 212 fi
 213 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 214         AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 215 fi
 216
 217 if test "x$INTEL" != "xno" -o \
 218         "x$RADEON" != "xno" -o \
 219         "x$NOUVEAU" != "xno" -o \
 220         "x$OMAP" != "xno" -o \
 221         "x$FREEDRENO" != "xno" -o \
 222         "x$TEGRA" != "xno"; then
 223         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 224                 if test "x$INTEL" != "xauto"; then
 225                         if test "x$INTEL" != "xno"; then
 226                                 AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
 227                         fi
 228                 else
 229                         AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 230                         INTEL=no
 231                 fi
 232                 if test "x$RADEON" != "xauto"; then
 233                         if test "x$RADEON" != "xno"; then
 234                                 AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon GPUs by passing --disable-radeon to ./configure])
 235                         fi
 236                 else
 237                         AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 238                         RADEON=no
 239                 fi
 240                 if test "x$NOUVEAU" != "xauto"; then
 241                         if test "x$NOUVEAU" != "xno"; then
 242                                 AC_MSG_ERROR([libdrm_nouveau depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA GPUs by passing --disable-nouveau to ./configure])
 243                         fi
 244                 else
 245                         AC_MSG_WARN([Disabling libdrm_nouveau. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 246                         NOUVEAU=no
 247                 fi
 248                 if test "x$OMAP" != "xauto"; then
 249                         AC_MSG_ERROR([libdrm_omap depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for OMAP GPUs by passing --disable-omap-experimental-api to ./configure])
 250                 fi
 251                 if test "x$FREEDRENO" != "xauto"; then
 252                         AC_MSG_ERROR([libdrm_freedreno depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for QCOM's Adreno GPUs by passing --disable-freedreno to ./configure])
 253                 fi
 254                 if test "x$TEGRA" != "xauto"; then
 255                         AC_MSG_ERROR([libdrm_tegra depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA's Tegra GPUs by passing --disable-tegra-experimental-api to ./configure])
 256                 fi
 257         else
 258                 if test "x$INTEL" != "xno"; then
 259                         case $host_cpu in
 260                                 i?86|x86_64) INTEL=yes ;;
 261                                 *) INTEL=no ;;
 262                         esac
 263                 fi
 264                 if test "x$RADEON" != "xno"; then
 265                         RADEON=yes
 266                 fi
 267                 if test "x$NOUVEAU" != "xno"; then
 268                         NOUVEAU=yes
 269                 fi
 270                 if test "x$FREEDRENO" != "xno"; then
 271                         case $host_cpu in
 272                                 arm*|aarch64)   FREEDRENO=yes ;;
 273                                 *)              FREEDRENO=no ;;
 274                         esac
 275                 fi
 276         fi
 277 fi
 278
 279 if test "x$INTEL" != "xno"; then
 280         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 281 fi
 282 AC_SUBST(PCIACCESS_CFLAGS)
 283 AC_SUBST(PCIACCESS_LIBS)
 284
 285 if test "x$UDEV" = xyes; then
 286         AC_DEFINE(UDEV, 1, [Have UDEV support])
 287 fi
 288
 289 AC_CANONICAL_HOST
 290 if test "x$LIBKMS" = xauto ; then
 291         case $host_os in
 292                 linux*)         LIBKMS="yes" ;;
 293                 freebsd* | kfreebsd*-gnu)
 294                                 LIBKMS="yes" ;;
 295                 dragonfly*)     LIBKMS="yes" ;;
 296                 *)              LIBKMS="no" ;;
 297         esac
 298 fi
 299
 300 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 301
 302 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" = xyes])
 303 if test "x$INTEL" = xyes; then
 304         AC_DEFINE(HAVE_INTEL, 1, [Have intel support])
 305 fi
 306
 307 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 308 if test "x$VMWGFX" = xyes; then
 309         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 310 fi
 311
 312 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 313 if test "x$NOUVEAU" = xyes; then
 314         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 315 fi
 316
 317 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 318 if test "x$OMAP" = xyes; then
 319         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 320 fi
 321
 322 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 323 if test "x$EXYNOS" = xyes; then
 324         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 325 fi
 326
 327 AM_CONDITIONAL(HAVE_FREEDRENO, [test "x$FREEDRENO" = xyes])
 328 if test "x$FREEDRENO" = xyes; then
 329         AC_DEFINE(HAVE_FREEDRENO, 1, [Have freedreno support])
 330 fi
 331
 332 AM_CONDITIONAL(HAVE_FREEDRENO_KGSL, [test "x$FREEDRENO_KGSL" = xyes])
 333 if test "x$FREEDRENO_KGSL" = xyes; then
 334         AC_DEFINE(HAVE_FREEDRENO_KGSL, 1, [Have freedreno support for KGSL kernel interface])
 335 fi
 336
 337 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 338 if test "x$RADEON" = xyes; then
 339         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 340 fi
 341
 342 AM_CONDITIONAL(HAVE_TEGRA, [test "x$TEGRA" = xyes])
 343 if test "x$TEGRA" = xyes; then
 344         AC_DEFINE(HAVE_TEGRA, 1, [Have Tegra support])
 345 fi
 346
 347 AM_CONDITIONAL(HAVE_INSTALL_TESTS, [test "x$INSTALL_TESTS" = xyes])
 348 if test "x$INSTALL_TESTS" = xyes; then
 349         AC_DEFINE(HAVE_INSTALL_TESTS, 1, [Install test programs])
 350 fi
 351
 352 AC_ARG_ENABLE([cairo-tests],
 353               [AS_HELP_STRING([--enable-cairo-tests],
 354                               [Enable support for Cairo rendering in tests (default: auto)])],
 355               [CAIRO=$enableval], [CAIRO=auto])
 356 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 357 AC_MSG_CHECKING([whether to enable Cairo tests])
 358 if test "x$CAIRO" = xauto; then
 359         CAIRO="$HAVE_CAIRO"
 360 fi
 361 if test "x$CAIRO" = xyes; then
 362         if ! test "x$HAVE_CAIRO" = xyes; then
 363                 AC_MSG_ERROR([Cairo support required but not present])
 364         fi
 365         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 366 fi
 367 AC_MSG_RESULT([$CAIRO])
 368 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 369
 370 # For enumerating devices in test case
 371 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 372 if test "x$HAVE_LIBUDEV" = xyes; then
 373         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 374 fi
 375 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 376
 377 # xsltproc for docbook manpages
 378 AC_ARG_ENABLE([manpages],
 379               AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
 380               [MANS=$enableval], [MANS=auto])
 381 AC_PATH_PROG(XSLTPROC, xsltproc)
 382 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 383
 384 # check for offline man-pages stylesheet
 385 AC_MSG_CHECKING([for docbook manpages stylesheet])
 386 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 387 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 388                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 389                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 390 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 391         AC_SUBST(MANPAGES_STYLESHEET)
 392         AC_MSG_RESULT([yes])
 393 else
 394         AC_MSG_RESULT([no])
 395 fi
 396 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 397
 398 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 399 if test "x$have_valgrind" = "xyes"; then
 400         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 401 fi
 402
 403 AC_ARG_WITH([kernel-source],
 404             [AS_HELP_STRING([--with-kernel-source],
 405               [specify path to linux kernel source])],
 406             [kernel_source="$with_kernel_source"])
 407 AC_SUBST(kernel_source)
 408
 409 dnl Add flags for gcc and g++
 410 if test "x$GCC" = xyes; then
 411     # Enable -fvisibility=hidden if using a gcc that supports it
 412     save_CFLAGS="$CFLAGS"
 413     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 414     VISIBILITY_CFLAGS="-fvisibility=hidden"
 415     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 416     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 417                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 418
 419     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 420     CFLAGS=$save_CFLAGS
 421
 422     if test "x$VISIBILITY_CFLAGS" != x; then
 423         AC_DEFINE(HAVE_VISIBILITY, 1, [Compiler has -fvisibility support])
 424     fi
 425
 426     AC_SUBST([VISIBILITY_CFLAGS])
 427 fi
 428
 429 AC_SUBST(WARN_CFLAGS)
 430 AC_CONFIG_FILES([
 431         Makefile
 432         libkms/Makefile
 433         libkms/libkms.pc
 434         intel/Makefile
 435         intel/libdrm_intel.pc
 436         radeon/Makefile
 437         radeon/libdrm_radeon.pc
 438         nouveau/Makefile
 439         nouveau/libdrm_nouveau.pc
 440         omap/Makefile
 441         omap/libdrm_omap.pc
 442         exynos/Makefile
 443         exynos/libdrm_exynos.pc
 444         freedreno/Makefile
 445         freedreno/libdrm_freedreno.pc
 446         tegra/Makefile
 447         tegra/libdrm_tegra.pc
 448         tests/Makefile
 449         tests/modeprint/Makefile
 450         tests/modetest/Makefile
 451         tests/kmstest/Makefile
 452         tests/proptest/Makefile
 453         tests/radeon/Makefile
 454         tests/vbltest/Makefile
 455         tests/exynos/Makefile
 456         tests/tegra/Makefile
 457         man/Makefile
 458         libdrm.pc])
 459 AC_OUTPUT
 460
 461 echo ""
 462 echo "$PACKAGE_STRING will be compiled with:"
 463 echo ""
 464 echo "  libkms         $LIBKMS"
 465 echo "  Intel API      $INTEL"
 466 echo "  vmwgfx API     $VMWGFX"
 467 echo "  Radeon API     $RADEON"
 468 echo "  Nouveau API    $NOUVEAU"
 469 echo "  OMAP API       $OMAP"
 470 echo "  EXYNOS API     $EXYNOS"
 471 echo "  Freedreno API  $FREEDRENO (kgsl: $FREEDRENO_KGSL)"
 472 echo "  Tegra API      $TEGRA"
 473 echo ""