configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 dnl Set internal versions
  28 OSMESA_VERSION=8
  29 AC_SUBST([OSMESA_VERSION])
  30
  31 dnl Versions for external dependencies
  32 LIBDRM_REQUIRED=2.4.24
  33 LIBDRM_RADEON_REQUIRED=2.4.40
  34 LIBDRM_INTEL_REQUIRED=2.4.38
  35 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  36 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  37 DRI2PROTO_REQUIRED=2.6
  38 GLPROTO_REQUIRED=1.4.14
  39 LIBDRM_XORG_REQUIRED=2.4.24
  40 LIBKMS_XORG_REQUIRED=1.0.0
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AX_PROG_CC_FOR_BUILD
  46 AC_PROG_CXX
  47 AX_PROG_CXX_FOR_BUILD
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AC_PROG_SED
  53 AC_PROG_MKDIR_P
  54 AC_PATH_PROG([MKDEP], [makedepend])
  55
  56 LT_PREREQ([2.2])
  57 LT_INIT([disable-static])
  58
  59 if test "x$MKDEP" = "x"; then
  60     AC_MSG_ERROR([makedepend is required to build Mesa])
  61 fi
  62
  63 AC_PROG_YACC
  64 AC_PATH_PROG([YACC_INST], $YACC)
  65 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
  66     if test -z "$YACC_INST"; then
  67         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  68     fi
  69 fi
  70 AC_PROG_LEX
  71
  72 AC_PATH_PROG([PERL], [perl])
  73
  74 AC_CHECK_PROG(INDENT, indent, indent, cat)
  75 if test "x$INDENT" != "xcat"; then
  76     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  77 fi
  78
  79 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  80 dnl configuration in that case.
  81 AC_PROG_INSTALL
  82 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  83
  84 dnl We need a POSIX shell for parts of the build. Assume we have one
  85 dnl in most cases.
  86 case "$host_os" in
  87 solaris*)
  88     # Solaris /bin/sh is too old/non-POSIX compliant
  89     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  90     SHELL="$POSIX_SHELL"
  91     ;;
  92 esac
  93
  94 dnl clang is mostly GCC-compatible, but its version is much lower,
  95 dnl so we have to check for it.
  96 AC_MSG_CHECKING([if compiling with clang])
  97
  98 AC_COMPILE_IFELSE(
  99 [AC_LANG_PROGRAM([], [[
 100 #ifndef __clang__
 101        not clang
 102 #endif
 103 ]])],
 104 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 105
 106 AC_MSG_RESULT([$acv_mesa_CLANG])
 107
 108 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 109 dnl versions are explictly not supported.
 110 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 111     AC_MSG_CHECKING([whether gcc version is sufficient])
 112     major=0
 113     minor=0
 114
 115     GCC_VERSION=`$CC -dumpversion`
 116     if test $? -eq 0; then
 117         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 118         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 119     fi
 120
 121     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 122         AC_MSG_RESULT([no])
 123         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 124     else
 125         AC_MSG_RESULT([yes])
 126     fi
 127 fi
 128
 129
 130 MKDEP_OPTIONS=-fdepend
 131 dnl Ask gcc where it's keeping its secret headers
 132 if test "x$GCC" = xyes; then
 133     for dir in include include-fixed; do
 134         GCC_INCLUDES=`$CC -print-file-name=$dir`
 135         if test "x$GCC_INCLUDES" != x && \
 136            test "$GCC_INCLUDES" != "$dir" && \
 137            test -d "$GCC_INCLUDES"; then
 138             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 139         fi
 140     done
 141 fi
 142 AC_SUBST([MKDEP_OPTIONS])
 143
 144 dnl Make sure the pkg-config macros are defined
 145 m4_ifndef([PKG_PROG_PKG_CONFIG],
 146     [m4_fatal([Could not locate the pkg-config autoconf macros.
 147   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 148   are in a different location, try setting the environment variable
 149   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 150 PKG_PROG_PKG_CONFIG()
 151
 152 dnl LIB_DIR - library basename
 153 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 154 AC_SUBST([LIB_DIR])
 155
 156 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 157 _SAVE_LDFLAGS="$LDFLAGS"
 158 _SAVE_CPPFLAGS="$CPPFLAGS"
 159
 160 dnl build host compiler macros
 161 DEFINES_FOR_BUILD=""
 162 AC_SUBST([DEFINES_FOR_BUILD])
 163 case "$build_os" in
 164 linux*|*-gnu*|gnu*)
 165     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 166     ;;
 167 solaris*)
 168     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 169     ;;
 170 cygwin*)
 171     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 172     ;;
 173 esac
 174
 175 dnl Compiler macros
 176 DEFINES=""
 177 AC_SUBST([DEFINES])
 178 case "$host_os" in
 179 linux*|*-gnu*|gnu*)
 180     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 181     ;;
 182 solaris*)
 183     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 184     ;;
 185 cygwin*)
 186     DEFINES="$DEFINES -DHAVE_PTHREAD"
 187     ;;
 188 esac
 189
 190 dnl Add flags for gcc and g++
 191 if test "x$GCC" = xyes; then
 192     case "$host_os" in
 193     cygwin*)
 194         CFLAGS="$CFLAGS -Wall -std=gnu99"
 195         ;;
 196     *)
 197         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 198         CFLAGS="$CFLAGS -Wall -std=c99"
 199         ;;
 200     esac
 201
 202     # Enable -Werror=implicit-function-declaration and
 203     # -Werror=missing-prototypes, if available, or otherwise, just
 204     # -Wmissing-prototypes.  This is particularly useful to avoid
 205     # generating a loadable driver module that has undefined symbols.
 206     save_CFLAGS="$CFLAGS"
 207     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 208     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 209     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 210     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 211                    AC_MSG_RESULT([yes]),
 212                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 213                     AC_MSG_RESULT([no])]);
 214
 215     # Enable -fvisibility=hidden if using a gcc that supports it
 216     save_CFLAGS="$CFLAGS"
 217     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 218     VISIBILITY_CFLAGS="-fvisibility=hidden"
 219     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 220     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 221                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 222
 223     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 224     CFLAGS=$save_CFLAGS
 225
 226     # Work around aliasing bugs - developers should comment this out
 227     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 228     CFLAGS="$CFLAGS -fno-strict-aliasing"
 229
 230     # gcc's builtin memcmp is slower than glibc's
 231     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 232     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 233     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 234 fi
 235 if test "x$GXX" = xyes; then
 236     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 237     CXXFLAGS="$CXXFLAGS -Wall"
 238
 239     # Enable -fvisibility=hidden if using a gcc that supports it
 240     save_CXXFLAGS="$CXXFLAGS"
 241     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 242     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 243     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 244     AC_LANG_PUSH([C++])
 245     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 246                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 247     AC_LANG_POP([C++])
 248
 249     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 250     CXXFLAGS=$save_CXXFLAGS
 251
 252     # Work around aliasing bugs - developers should comment this out
 253     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 254     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 255
 256     # gcc's builtin memcmp is slower than glibc's
 257     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 258     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 259     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 260 fi
 261
 262 dnl even if the compiler appears to support it, using visibility attributes isn't
 263 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 264 case "$host_os" in
 265 cygwin*)
 266     VISIBILITY_CFLAGS=""
 267     VISIBILITY_CXXFLAGS=""
 268     ;;
 269 esac
 270
 271 AC_SUBST([VISIBILITY_CFLAGS])
 272 AC_SUBST([VISIBILITY_CXXFLAGS])
 273
 274 dnl
 275 dnl Hacks to enable 32 or 64 bit build
 276 dnl
 277 AC_ARG_ENABLE([32-bit],
 278     [AS_HELP_STRING([--enable-32-bit],
 279         [build 32-bit libraries @<:@default=auto@:>@])],
 280     [enable_32bit="$enableval"],
 281     [enable_32bit=auto]
 282 )
 283 if test "x$enable_32bit" = xyes; then
 284     if test "x$GCC" = xyes; then
 285         CFLAGS="$CFLAGS -m32"
 286         CCASFLAGS="$CCASFLAGS -m32"
 287     fi
 288     if test "x$GXX" = xyes; then
 289         CXXFLAGS="$CXXFLAGS -m32"
 290     fi
 291 fi
 292 AC_ARG_ENABLE([64-bit],
 293     [AS_HELP_STRING([--enable-64-bit],
 294         [build 64-bit libraries @<:@default=auto@:>@])],
 295     [enable_64bit="$enableval"],
 296     [enable_64bit=auto]
 297 )
 298 if test "x$enable_64bit" = xyes; then
 299     if test "x$GCC" = xyes; then
 300         CFLAGS="$CFLAGS -m64"
 301     fi
 302     if test "x$GXX" = xyes; then
 303         CXXFLAGS="$CXXFLAGS -m64"
 304     fi
 305 fi
 306
 307 dnl Can't have static and shared libraries, default to static if user
 308 dnl explicitly requested. If both disabled, set to static since shared
 309 dnl was explicitly requested.
 310 case "x$enable_static$enable_shared" in
 311 xyesyes )
 312     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 313     enable_shared=no
 314     ;;
 315 xnono )
 316     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 317     enable_static=yes
 318     ;;
 319 esac
 320
 321 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 322
 323 dnl
 324 dnl mklib options
 325 dnl
 326 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 327 if test "$enable_static" = yes; then
 328     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 329 fi
 330 AC_SUBST([MKLIB_OPTIONS])
 331
 332 dnl
 333 dnl other compiler options
 334 dnl
 335 AC_ARG_ENABLE([debug],
 336     [AS_HELP_STRING([--enable-debug],
 337         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 338     [enable_debug="$enableval"],
 339     [enable_debug=no]
 340 )
 341 if test "x$enable_debug" = xyes; then
 342     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 343     if test "x$GCC_FOR_BUILD" = xyes; then
 344         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g"
 345     fi
 346     if test "x$GXX_FOR_BUILD" = xyes; then
 347         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g"
 348     fi
 349
 350     DEFINES="$DEFINES -DDEBUG"
 351     if test "x$GCC" = xyes; then
 352         CFLAGS="$CFLAGS -g"
 353     fi
 354     if test "x$GXX" = xyes; then
 355         CXXFLAGS="$CXXFLAGS -g"
 356     fi
 357 fi
 358
 359 dnl
 360 dnl library names
 361 dnl
 362 LIB_PREFIX_GLOB='lib'
 363 LIB_VERSION_SEPARATOR='.'
 364 if test "$enable_static" = yes; then
 365     LIB_EXTENSION='a'
 366 else
 367     case "$host_os" in
 368     darwin* )
 369         LIB_EXTENSION='dylib' ;;
 370     cygwin* )
 371         dnl prefix can be 'cyg' or 'lib'
 372         LIB_PREFIX_GLOB='???'
 373         LIB_VERSION_SEPARATOR='-'
 374         LIB_EXTENSION='dll' ;;
 375     aix* )
 376         LIB_EXTENSION='a' ;;
 377     * )
 378         LIB_EXTENSION='so' ;;
 379     esac
 380 fi
 381 AC_ARG_WITH([gl-lib-name],
 382   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 383     [specify GL library name @<:@default=GL@:>@])],
 384   [GL_LIB=$withval],
 385   [GL_LIB=GL])
 386 AC_ARG_WITH([osmesa-lib-name],
 387   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 388     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 389   [OSMESA_LIB=$withval],
 390   [OSMESA_LIB=OSMesa])
 391 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 392 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 393
 394 dnl
 395 dnl Mangled Mesa support
 396 dnl
 397 AC_ARG_ENABLE([mangling],
 398   [AS_HELP_STRING([--enable-mangling],
 399     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 400   [enable_mangling="${enableval}"],
 401   [enable_mangling=no]
 402 )
 403 if test "x${enable_mangling}" = "xyes" ; then
 404   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 405   GL_LIB="Mangled${GL_LIB}"
 406   OSMESA_LIB="Mangled${OSMESA_LIB}"
 407 fi
 408 AC_SUBST([GL_LIB])
 409 AC_SUBST([OSMESA_LIB])
 410
 411 dnl
 412 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 413 dnl
 414 AC_ARG_ENABLE([texture-float],
 415     [AS_HELP_STRING([--enable-texture-float],
 416         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 417     [enable_texture_float="$enableval"],
 418     [enable_texture_float=no]
 419 )
 420 if test "x$enable_texture_float" = xyes; then
 421     AC_MSG_WARN([Floating-point textures enabled.])
 422     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 423     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 424 fi
 425
 426 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 427 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 428 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 429 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 430 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 431 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 432 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 433
 434 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 435 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 436 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 437 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 438 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 439 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 440 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 441
 442 AC_SUBST([GL_LIB_NAME])
 443 AC_SUBST([OSMESA_LIB_NAME])
 444 AC_SUBST([EGL_LIB_NAME])
 445 AC_SUBST([GLESv1_CM_LIB_NAME])
 446 AC_SUBST([GLESv2_LIB_NAME])
 447 AC_SUBST([VG_LIB_NAME])
 448 AC_SUBST([GLAPI_LIB_NAME])
 449
 450 AC_SUBST([GL_LIB_GLOB])
 451 AC_SUBST([EGL_LIB_GLOB])
 452 AC_SUBST([GLESv1_CM_LIB_GLOB])
 453 AC_SUBST([GLESv2_LIB_GLOB])
 454 AC_SUBST([VG_LIB_GLOB])
 455 AC_SUBST([GLAPI_LIB_GLOB])
 456
 457 dnl
 458 dnl Arch/platform-specific settings
 459 dnl
 460 AC_ARG_ENABLE([asm],
 461     [AS_HELP_STRING([--disable-asm],
 462         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 463     [enable_asm="$enableval"],
 464     [enable_asm=yes]
 465 )
 466 asm_arch=""
 467 MESA_ASM_FILES=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         esac
 488         ;;
 489     x86_64)
 490         case "$host_os" in
 491         linux* | *freebsd* | dragonfly* | *netbsd*)
 492             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 493             ;;
 494         esac
 495         ;;
 496     sparc*)
 497         case "$host_os" in
 498         linux*)
 499             asm_arch=sparc
 500             ;;
 501         esac
 502         ;;
 503     esac
 504
 505     case "$asm_arch" in
 506     x86)
 507         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 508         MESA_ASM_FILES='$(X86_FILES)'
 509         AC_MSG_RESULT([yes, x86])
 510         ;;
 511     x86_64)
 512         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 513         MESA_ASM_FILES='$(X86_64_FILES)'
 514         AC_MSG_RESULT([yes, x86_64])
 515         ;;
 516     sparc)
 517         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 518         MESA_ASM_FILES='$(SPARC_FILES)'
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526 AC_SUBST([MESA_ASM_FILES])
 527
 528 dnl PIC code macro
 529 MESA_PIC_FLAGS
 530
 531 dnl Check to see if dlopen is in default libraries (like Solaris, which
 532 dnl has it in libc), or if libdl is needed to get it.
 533 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 534     [AC_CHECK_LIB([dl], [dlopen],
 535        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 536 AC_SUBST([DLOPEN_LIBS])
 537
 538 dnl See if posix_memalign is available
 539 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 540
 541 dnl Check for pthreads
 542 AX_PTHREAD
 543 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 544 dnl to -pthread, which causes problems if we need -lpthread to appear in
 545 dnl pkgconfig files.
 546 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 547
 548 dnl SELinux awareness.
 549 AC_ARG_ENABLE([selinux],
 550     [AS_HELP_STRING([--enable-selinux],
 551         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 552     [MESA_SELINUX="$enableval"],
 553     [MESA_SELINUX=no])
 554 if test "x$enable_selinux" = "xyes"; then
 555     AC_CHECK_HEADER([selinux/selinux.h],[],
 556                     [AC_MSG_ERROR([SELinux headers not found])])
 557     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 558                  [AC_MSG_ERROR([SELinux library not found])])
 559     SELINUX_LIBS="-lselinux"
 560     DEFINES="$DEFINES -DMESA_SELINUX"
 561 fi
 562 AC_SUBST([SELINUX_LIBS])
 563
 564 dnl Options for APIs
 565 AC_ARG_ENABLE([opengl],
 566     [AS_HELP_STRING([--disable-opengl],
 567         [disable support for standard OpenGL API @<:@default=no@:>@])],
 568     [enable_opengl="$enableval"],
 569     [enable_opengl=yes])
 570 AC_ARG_ENABLE([gles1],
 571     [AS_HELP_STRING([--enable-gles1],
 572         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 573     [enable_gles1="$enableval"],
 574     [enable_gles1=no])
 575 AC_ARG_ENABLE([gles2],
 576     [AS_HELP_STRING([--enable-gles2],
 577         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 578     [enable_gles2="$enableval"],
 579     [enable_gles2=no])
 580 AC_ARG_ENABLE([openvg],
 581     [AS_HELP_STRING([--enable-openvg],
 582         [enable support for OpenVG API @<:@default=no@:>@])],
 583     [enable_openvg="$enableval"],
 584     [enable_openvg=no])
 585
 586 AC_ARG_ENABLE([dri],
 587     [AS_HELP_STRING([--enable-dri],
 588         [enable DRI modules @<:@default=enabled@:>@])],
 589     [enable_dri="$enableval"],
 590     [enable_dri=yes])
 591 AC_ARG_ENABLE([glx],
 592     [AS_HELP_STRING([--enable-glx],
 593         [enable GLX library @<:@default=enabled@:>@])],
 594     [enable_glx="$enableval"],
 595     [enable_glx=yes])
 596 AC_ARG_ENABLE([osmesa],
 597     [AS_HELP_STRING([--enable-osmesa],
 598         [enable OSMesa library @<:@default=disabled@:>@])],
 599     [enable_osmesa="$enableval"],
 600     [enable_osmesa=no])
 601 AC_ARG_ENABLE([egl],
 602     [AS_HELP_STRING([--disable-egl],
 603         [disable EGL library @<:@default=enabled@:>@])],
 604     [enable_egl="$enableval"],
 605     [enable_egl=yes])
 606
 607 AC_ARG_ENABLE([xorg],
 608     [AS_HELP_STRING([--enable-xorg],
 609         [enable support for X.Org DDX API @<:@default=no@:>@])],
 610     [enable_xorg="$enableval"],
 611     [enable_xorg=no])
 612 AC_ARG_ENABLE([xa],
 613     [AS_HELP_STRING([--enable-xa],
 614         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 615     [enable_xa="$enableval"],
 616     [enable_xa=no])
 617 dnl Broken, unmaintained. Don't want to see bug reports about it without patches.
 618 enable_d3d1x=no
 619 dnl AC_ARG_ENABLE([d3d1x],
 620 dnl     [AS_HELP_STRING([--enable-d3d1x],
 621 dnl         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 622 dnl     [enable_d3d1x="$enableval"],
 623 dnl     [enable_d3d1x=no])
 624 AC_ARG_ENABLE([gbm],
 625    [AS_HELP_STRING([--enable-gbm],
 626          [enable gbm library @<:@default=auto@:>@])],
 627    [enable_gbm="$enableval"],
 628    [enable_gbm=auto])
 629
 630 AC_ARG_ENABLE([xvmc],
 631    [AS_HELP_STRING([--enable-xvmc],
 632          [enable xvmc library @<:@default=auto@:>@])],
 633    [enable_xvmc="$enableval"],
 634    [enable_xvmc=auto])
 635 AC_ARG_ENABLE([vdpau],
 636    [AS_HELP_STRING([--enable-vdpau],
 637          [enable vdpau library @<:@default=auto@:>@])],
 638    [enable_vdpau="$enableval"],
 639    [enable_vdpau=auto])
 640 AC_ARG_ENABLE([opencl],
 641    [AS_HELP_STRING([--enable-opencl],
 642          [enable OpenCL library @<:@default=no@:>@])],
 643    [enable_opencl="$enableval"],
 644    [enable_opencl=no])
 645 AC_ARG_ENABLE([xlib_glx],
 646     [AS_HELP_STRING([--enable-xlib-glx],
 647         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 648     [enable_xlib_glx="$enableval"],
 649     [enable_xlib_glx=no])
 650 AC_ARG_ENABLE([gallium_egl],
 651     [AS_HELP_STRING([--enable-gallium-egl],
 652         [enable optional EGL state tracker (not required
 653          for EGL support in Gallium with OpenGL and OpenGL ES)
 654          @<:@default=disable@:>@])],
 655     [enable_gallium_egl="$enableval"],
 656     [enable_gallium_egl=no])
 657 AC_ARG_ENABLE([gallium_gbm],
 658     [AS_HELP_STRING([--enable-gallium-gbm],
 659         [enable optional gbm state tracker (not required for
 660          gbm support in Gallium)
 661          @<:@default=auto@:>@])],
 662     [enable_gallium_gbm="$enableval"],
 663     [enable_gallium_gbm=auto])
 664
 665 AC_ARG_ENABLE([r600-llvm-compiler],
 666     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 667         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 668     [enable_r600_llvm="$enableval"],
 669     [enable_r600_llvm=no])
 670
 671 AC_ARG_ENABLE([gallium_tests],
 672     [AS_HELP_STRING([--enable-gallium-tests],
 673         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 674     [enable_gallium_tests="$enableval"],
 675     [enable_gallium_tests=no])
 676
 677 # Option for Gallium drivers
 678 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 679
 680 AC_ARG_WITH([gallium-drivers],
 681     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 682         [comma delimited Gallium drivers list, e.g.
 683         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 684         @<:@default=r300,r600,swrast@:>@])],
 685     [with_gallium_drivers="$withval"],
 686     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 687
 688 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 689 # here so that the script doesn't choke on an unknown driver name later.
 690 case "$with_gallium_drivers" in
 691     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 692     no) with_gallium_drivers='' ;;
 693 esac
 694
 695 if test "x$enable_opengl" = xno -a \
 696         "x$enable_gles1" = xno -a \
 697         "x$enable_gles2" = xno -a \
 698         "x$enable_openvg" = xno -a \
 699         "x$enable_xorg" = xno -a \
 700         "x$enable_xa" = xno -a \
 701         "x$enable_d3d1x" = xno -a \
 702         "x$enable_xvmc" = xno -a \
 703         "x$enable_vdpau" = xno -a \
 704         "x$enable_opencl" = xno; then
 705     AC_MSG_ERROR([at least one API should be enabled])
 706 fi
 707
 708 API_DEFINES=""
 709 if test "x$enable_opengl" = xno; then
 710     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 711 else
 712     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 713 fi
 714 if test "x$enable_gles1" = xyes; then
 715     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 716 fi
 717 if test "x$enable_gles2" = xyes; then
 718     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 719 fi
 720 AC_SUBST([API_DEFINES])
 721
 722 if test "x$enable_glx" = xno; then
 723     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 724     enable_xlib_glx=no
 725 fi
 726
 727 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 728     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 729 fi
 730
 731 # Disable GLX if DRI and Xlib-GLX are not enabled
 732 if test "x$enable_glx" = xyes -a \
 733         "x$enable_dri" = xno -a \
 734         "x$enable_xlib_glx" = xno; then
 735     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 736     enable_glx=no
 737 fi
 738
 739 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 740 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 741                                   "x$enable_osmesa" = xyes)
 742
 743 AC_ARG_ENABLE([shared-glapi],
 744     [AS_HELP_STRING([--enable-shared-glapi],
 745         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 746     [enable_shared_glapi="$enableval"],
 747     [enable_shared_glapi="$enable_dri"])
 748
 749 # Shared GLAPI is only useful for DRI
 750 if test "x$enable_dri" = xno; then
 751     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 752     enable_shared_glapi=no
 753 fi
 754
 755 # TODO: Get rid of SHARED_GLAPI variable
 756 SHARED_GLAPI="0"
 757 if test "x$enable_shared_glapi" = xyes; then
 758     SHARED_GLAPI="1"
 759     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 760     # the remap table)
 761     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 762     CORE_DIRS="mapi/shared-glapi"
 763 fi
 764 AC_SUBST([SHARED_GLAPI])
 765 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 766
 767 dnl
 768 dnl Driver specific build directories
 769 dnl
 770 SRC_DIRS="gtest"
 771 GALLIUM_DIRS="auxiliary drivers state_trackers"
 772 GALLIUM_TARGET_DIRS=""
 773 GALLIUM_WINSYS_DIRS="sw"
 774 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 775 GALLIUM_STATE_TRACKERS_DIRS=""
 776
 777 # build glapi if OpenGL is enabled
 778 if test "x$enable_opengl" = xyes; then
 779     CORE_DIRS="$CORE_DIRS mapi/glapi"
 780 fi
 781
 782 # build es1api if OpenGL ES 1.x is enabled
 783 if test "x$enable_gles1" = xyes; then
 784     CORE_DIRS="$CORE_DIRS mapi/es1api"
 785 fi
 786
 787 # build es2api if OpenGL ES 2.x is enabled
 788 if test "x$enable_gles2" = xyes; then
 789     CORE_DIRS="$CORE_DIRS mapi/es2api"
 790 fi
 791
 792 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 793 case "x$enable_opengl$enable_gles1$enable_gles2" in
 794 x*yes*)
 795     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 796     ;;
 797 esac
 798
 799 case "x$enable_glx$enable_xlib_glx" in
 800 xyesyes)
 801     DRIVER_DIRS="$DRIVER_DIRS x11"
 802     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 803     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 804     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 805     HAVE_WINSYS_XLIB="yes"
 806     ;;
 807 xyesno)
 808     # DRI-based GLX
 809     SRC_DIRS="$SRC_DIRS glx"
 810     ;;
 811 esac
 812
 813 if test "x$enable_dri" = xyes; then
 814     DRIVER_DIRS="$DRIVER_DIRS dri"
 815
 816     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 817     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 818     HAVE_ST_DRI="yes"
 819 fi
 820
 821 if test "x$enable_osmesa" = xyes; then
 822     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 823 fi
 824
 825 AC_SUBST([SRC_DIRS])
 826 AC_SUBST([DRIVER_DIRS])
 827 AC_SUBST([GALLIUM_DIRS])
 828 AC_SUBST([GALLIUM_TARGET_DIRS])
 829 AC_SUBST([GALLIUM_WINSYS_DIRS])
 830 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 831 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 832 AC_SUBST([MESA_LLVM])
 833
 834 # Check for libdrm
 835 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 836                   [have_libdrm=yes], [have_libdrm=no])
 837
 838 if test "x$enable_dri" = xyes; then
 839     # DRI must be shared, I think
 840     if test "$enable_static" = yes; then
 841         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 842     fi
 843
 844     # not a hard requirement as swrast does not depend on it
 845     if test "x$have_libdrm" = xyes; then
 846         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 847     fi
 848 fi
 849
 850 dnl Find out if X is available.
 851 PKG_CHECK_MODULES([X11], [x11], [no_x=no], [no_x=yes])
 852
 853 dnl Try to tell the user that the --x-* options are only used when
 854 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 855 m4_divert_once([HELP_BEGIN],
 856 [These options are only used when the X libraries cannot be found by the
 857 pkg-config utility.])
 858
 859 dnl We need X for xlib and dri, so bomb now if it's not found
 860 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 861     AC_MSG_ERROR([X11 development libraries needed for GLX])
 862 fi
 863
 864 dnl Direct rendering or just indirect rendering
 865 case "$host_os" in
 866 gnu*)
 867     dnl Disable by default on GNU/Hurd
 868     driglx_direct_default="no"
 869     ;;
 870 cygwin*)
 871     dnl Disable by default on cygwin
 872     driglx_direct_default="no"
 873     ;;
 874 *)
 875     driglx_direct_default="yes"
 876     ;;
 877 esac
 878 AC_ARG_ENABLE([driglx-direct],
 879     [AS_HELP_STRING([--disable-driglx-direct],
 880         [disable direct rendering in GLX and EGL for DRI \
 881             @<:@default=auto@:>@])],
 882     [driglx_direct="$enableval"],
 883     [driglx_direct="$driglx_direct_default"])
 884
 885 dnl
 886 dnl libGL configuration per driver
 887 dnl
 888 case "x$enable_glx$enable_xlib_glx" in
 889 xyesyes)
 890     # Xlib-based GLX
 891     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 892     GL_PC_REQ_PRIV="x11 xext"
 893     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 894     GL_LIB_DEPS="$XLIBGL_LIBS"
 895     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 896     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 897     ;;
 898 xyesno)
 899     # DRI-based GLX
 900     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 901     if test x"$driglx_direct" = xyes; then
 902         if test "x$have_libdrm" != xyes; then
 903             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 904         fi
 905         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 906         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 907     fi
 908
 909     # find the DRI deps for libGL
 910     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 911
 912     # add xf86vidmode if available
 913     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 914     if test "$HAVE_XF86VIDMODE" = yes ; then
 915         dri_modules="$dri_modules xxf86vm"
 916     fi
 917
 918     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 919     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 920     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 921     GL_LIB_DEPS="$DRIGL_LIBS"
 922
 923     # need DRM libs, $PTHREAD_LIBS, etc.
 924     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 925     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 926     ;;
 927 esac
 928
 929 # This is outside the case (above) so that it is invoked even for non-GLX
 930 # builds.
 931 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 932
 933 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 934 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 935 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 936 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 937
 938 AC_SUBST([X11_INCLUDES])
 939 AC_SUBST([GL_LIB_DEPS])
 940 AC_SUBST([GL_PC_REQ_PRIV])
 941 AC_SUBST([GL_PC_LIB_PRIV])
 942 AC_SUBST([GL_PC_CFLAGS])
 943 AC_SUBST([DRI_PC_REQ_PRIV])
 944 AC_SUBST([GLESv1_CM_LIB_DEPS])
 945 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 946 AC_SUBST([GLESv2_LIB_DEPS])
 947 AC_SUBST([GLESv2_PC_LIB_PRIV])
 948
 949 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 950
 951 AC_SUBST([HAVE_XF86VIDMODE])
 952
 953 dnl
 954 dnl More GLX setup
 955 dnl
 956 case "x$enable_glx$enable_xlib_glx" in
 957 xyesyes)
 958     DEFINES="$DEFINES -DUSE_XSHM"
 959     ;;
 960 xyesno)
 961     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 962     if test "x$driglx_direct" = xyes; then
 963         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 964     fi
 965     ;;
 966 esac
 967
 968 dnl
 969 dnl TLS detection
 970 dnl
 971
 972 AC_ARG_ENABLE([glx-tls],
 973     [AS_HELP_STRING([--enable-glx-tls],
 974         [enable TLS support in GLX @<:@default=disabled@:>@])],
 975     [GLX_USE_TLS="$enableval"],
 976     [GLX_USE_TLS=no])
 977 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 978
 979 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 980       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 981
 982 dnl
 983 dnl More DRI setup
 984 dnl
 985 dnl Directory for DRI drivers
 986 AC_ARG_WITH([dri-driverdir],
 987     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 988         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 989     [DRI_DRIVER_INSTALL_DIR="$withval"],
 990     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 991 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 992 dnl Extra search path for DRI drivers
 993 AC_ARG_WITH([dri-searchpath],
 994     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 995         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 996     [DRI_DRIVER_SEARCH_DIR="$withval"],
 997     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 998 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 999 dnl Which drivers to build - default is chosen by platform
1000 AC_ARG_WITH([dri-drivers],
1001     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1002         [comma delimited DRI drivers list, e.g.
1003         "swrast,i965,radeon" @<:@default=auto@:>@])],
1004     [with_dri_drivers="$withval"],
1005     [with_dri_drivers=yes])
1006 if test "x$with_dri_drivers" = x; then
1007     with_dri_drivers=no
1008 fi
1009
1010 dnl If $with_dri_drivers is yes, directories will be added through
1011 dnl platform checks
1012 DRI_DIRS=""
1013 case "$with_dri_drivers" in
1014 no) ;;
1015 yes)
1016     # classic DRI drivers require FEATURE_GL to build
1017     if test "x$enable_opengl" = xyes; then
1018         DRI_DIRS="yes"
1019     fi
1020     ;;
1021 *)
1022     # verify the requested driver directories exist
1023     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1024     for driver in $dri_drivers; do
1025         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1026             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1027     done
1028     DRI_DIRS="$dri_drivers"
1029     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1030         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1031     fi
1032     ;;
1033 esac
1034
1035 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1036 if test "x$enable_dri" = xyes; then
1037     # Platform specific settings and drivers to build
1038     case "$host_os" in
1039     linux*)
1040         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1041         DEFINES="$DEFINES -DHAVE_ALIAS"
1042
1043         case "$host_cpu" in
1044         x86_64)
1045             if test "x$DRI_DIRS" = "xyes"; then
1046                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1047             fi
1048             ;;
1049         powerpc*)
1050             # Build only the drivers for cards that exist on PowerPC.
1051             if test "x$DRI_DIRS" = "xyes"; then
1052                 DRI_DIRS="r200 radeon swrast"
1053             fi
1054             ;;
1055         sparc*)
1056             # Build only the drivers for cards that exist on sparc
1057             if test "x$DRI_DIRS" = "xyes"; then
1058                 DRI_DIRS="r200 radeon swrast"
1059             fi
1060             ;;
1061         esac
1062         ;;
1063     freebsd* | dragonfly* | *netbsd*)
1064         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1065         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1066
1067         if test "x$DRI_DIRS" = "xyes"; then
1068             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1069         fi
1070         ;;
1071     gnu*)
1072         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1073         DEFINES="$DEFINES -DHAVE_ALIAS"
1074         ;;
1075     solaris*)
1076         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1077         ;;
1078     cygwin*)
1079         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1080         if test "x$DRI_DIRS" = "xyes"; then
1081             DRI_DIRS="swrast"
1082         fi
1083         ;;
1084     esac
1085
1086     # default drivers
1087     if test "x$DRI_DIRS" = "xyes"; then
1088         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1089     fi
1090
1091     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1092
1093     # Check for expat
1094     if test "x$enable_dri" = xyes; then
1095         EXPAT_INCLUDES=""
1096         EXPAT_LIB=-lexpat
1097         AC_ARG_WITH([expat],
1098             [AS_HELP_STRING([--with-expat=DIR],
1099                 [expat install directory])],[
1100             EXPAT_INCLUDES="-I$withval/include"
1101             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1102             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1103             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1104             ])
1105         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1106         save_LIBS="$LIBS"
1107         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1108             [AC_MSG_ERROR([Expat required for DRI.])])
1109         LIBS="$save_LIBS"
1110     fi
1111
1112     # if we are building any dri driver other than swrast ...
1113     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1114         # ... libdrm is required
1115         if test "x$have_libdrm" != xyes; then
1116             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1117         fi
1118         # ... and build dricommon
1119         HAVE_COMMON_DRI=yes
1120     fi
1121
1122     # put all the necessary libs together
1123     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1124     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1125 fi
1126 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1127 AC_SUBST([DRI_DIRS])
1128 AC_SUBST([EXPAT_INCLUDES])
1129 AC_SUBST([DRI_LIB_DEPS])
1130 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1131
1132 case $DRI_DIRS in
1133 *i915*|*i965*)
1134     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1135
1136     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1137         case $d in
1138         i915)
1139             HAVE_I915_DRI=yes;
1140             ;;
1141         i965)
1142             HAVE_I965_DRI=yes;
1143             ;;
1144         esac
1145     done
1146
1147     ;;
1148 esac
1149
1150 case $DRI_DIRS in
1151 *nouveau*)
1152     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1153     HAVE_NOUVEAU_DRI=yes;
1154     ;;
1155 esac
1156
1157 case $DRI_DIRS in
1158 *radeon*|*r200*)
1159     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1160
1161     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1162         case $d in
1163         radeon)
1164             HAVE_RADEON_DRI=yes;
1165             ;;
1166         r200)
1167             HAVE_R200_DRI=yes;
1168             ;;
1169         esac
1170     done
1171
1172     ;;
1173 esac
1174
1175 case $DRI_DIRS in
1176 *swrast*)
1177     HAVE_SWRAST_DRI=yes;
1178     ;;
1179 esac
1180
1181 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1182 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1183 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1184 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1185 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1186 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1187 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1188
1189 dnl
1190 dnl OSMesa configuration
1191 dnl
1192
1193 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1194 AC_ARG_WITH([osmesa-bits],
1195     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1196         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1197     [osmesa_bits="$withval"],
1198     [osmesa_bits=8])
1199 if test "x$osmesa_bits" != x8; then
1200     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1201         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1202         osmesa_bits=8
1203     fi
1204 fi
1205 case "x$osmesa_bits" in
1206 x8)
1207     OSMESA_LIB="${OSMESA_LIB}"
1208     ;;
1209 x16|x32)
1210     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1211     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1212     ;;
1213 *)
1214     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1215     ;;
1216 esac
1217
1218 if test "x$enable_osmesa" = xyes; then
1219     # only link libraries with osmesa if shared
1220     if test "$enable_static" = no; then
1221         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1222     else
1223         OSMESA_LIB_DEPS=""
1224     fi
1225     OSMESA_MESA_DEPS=""
1226     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1227 fi
1228
1229 AC_SUBST([OSMESA_LIB_DEPS])
1230 AC_SUBST([OSMESA_MESA_DEPS])
1231 AC_SUBST([OSMESA_PC_REQ])
1232 AC_SUBST([OSMESA_PC_LIB_PRIV])
1233
1234 dnl
1235 dnl gbm configuration
1236 dnl
1237 if test "x$enable_gbm" = xauto; then
1238     case "$with_egl_platforms" in
1239         *drm*)
1240             enable_gbm=yes ;;
1241          *)
1242             enable_gbm=no ;;
1243     esac
1244 fi
1245 if test "x$enable_gbm" = xyes; then
1246     SRC_DIRS="$SRC_DIRS gbm"
1247
1248     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1249                       AC_MSG_ERROR([gbm needs udev]))
1250
1251     if test "x$enable_dri" = xyes; then
1252         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1253         if test "x$enable_shared_glapi" = xno; then
1254             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1255         fi
1256     fi
1257 fi
1258 GBM_PC_REQ_PRIV="libudev"
1259 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1260 AC_SUBST([GBM_PC_REQ_PRIV])
1261 AC_SUBST([GBM_PC_LIB_PRIV])
1262
1263 dnl
1264 dnl EGL configuration
1265 dnl
1266 EGL_CLIENT_APIS=""
1267
1268 if test "x$enable_egl" = xyes; then
1269     SRC_DIRS="$SRC_DIRS egl"
1270     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1271
1272     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1273
1274     if test "$enable_static" != yes; then
1275         # build egl_glx when libGL is built
1276         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1277                           [have_libudev=yes],[have_libudev=no])
1278         if test "$have_libudev" = yes; then
1279             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1280         fi
1281
1282         if test "x$enable_dri" = xyes; then
1283             HAVE_EGL_DRIVER_DRI2=1
1284         fi
1285
1286     fi
1287 fi
1288 AC_SUBST([EGL_LIB_DEPS])
1289
1290 dnl
1291 dnl EGL Gallium configuration
1292 dnl
1293 if test "x$enable_gallium_egl" = xyes; then
1294     if test "x$with_gallium_drivers" = x; then
1295         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1296     fi
1297     if test "x$enable_egl" = xno; then
1298         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1299     fi
1300     if test "x$have_libdrm" != xyes; then
1301         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1302     fi
1303
1304     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1305     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1306     HAVE_ST_EGL="yes"
1307 fi
1308
1309 dnl
1310 dnl gbm Gallium configuration
1311 dnl
1312 if test "x$enable_gallium_gbm" = xauto; then
1313     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1314         yesyesyes*drm*)
1315             enable_gallium_gbm=yes ;;
1316          *)
1317             enable_gallium_gbm=no ;;
1318     esac
1319 fi
1320 if test "x$enable_gallium_gbm" = xyes; then
1321     if test "x$with_gallium_drivers" = x; then
1322         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1323     fi
1324     if test "x$enable_gbm" = xno; then
1325         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1326     fi
1327     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1328     if test "x$enable_dri" = xno; then
1329         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1330     fi
1331
1332     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1333     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1334     HAVE_ST_GBM="yes"
1335     enable_gallium_loader=yes
1336 fi
1337
1338 dnl
1339 dnl X.Org DDX configuration
1340 dnl
1341 if test "x$enable_xorg" = xyes; then
1342     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1343     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1344     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1345     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1346         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1347         HAVE_XEXTPROTO_71="no")
1348     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1349     HAVE_ST_XORG=yes
1350 fi
1351
1352 dnl
1353 dnl XA configuration
1354 dnl
1355 if test "x$enable_xa" = xyes; then
1356 AC_PROG_AWK
1357 AC_PROG_GREP
1358 AC_CHECK_PROG(NM, nm, "nm")
1359 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1360 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1361 enable_xa=no
1362 fi
1363 fi
1364 if test "x$enable_xa" = xyes; then
1365     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1366     HAVE_ST_XA=yes
1367     AC_SUBST(AWK)
1368     AC_SUBST(GREP)
1369     AC_SUBST(NM)
1370 fi
1371
1372 dnl
1373 dnl OpenVG configuration
1374 dnl
1375 VG_LIB_DEPS=""
1376
1377 if test "x$enable_openvg" = xyes; then
1378     if test "x$enable_egl" = xno; then
1379         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1380     fi
1381     if test "x$with_gallium_drivers" = x; then
1382         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1383     fi
1384     if test "x$enable_gallium_egl" = xno; then
1385         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1386     fi
1387
1388     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1389     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1390     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1391     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1392     HAVE_ST_VEGA=yes
1393     VG_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1394     AC_SUBST([VG_PC_LIB_PRIV])
1395 fi
1396
1397 dnl
1398 dnl D3D1X configuration
1399 dnl
1400
1401 if test "x$enable_d3d1x" = xyes; then
1402     if test "x$with_gallium_drivers" = x; then
1403         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1404     fi
1405
1406     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1407     HAVE_ST_D3D1X=yes
1408 fi
1409
1410 dnl
1411 dnl Gallium G3DVL configuration
1412 dnl
1413 AC_ARG_ENABLE([gallium-g3dvl],
1414     [AS_HELP_STRING([--enable-gallium-g3dvl],
1415         [build gallium g3dvl @<:@default=disabled@:>@])],
1416     [enable_gallium_g3dvl="$enableval"],
1417     [enable_gallium_g3dvl=no])
1418 if test "x$enable_gallium_g3dvl" = xyes; then
1419     if test "x$with_gallium_drivers" = x; then
1420         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1421     fi
1422
1423     if test "x$enable_xvmc" = xauto; then
1424         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1425     fi
1426
1427     if test "x$enable_vdpau" = xauto; then
1428         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1429     fi
1430 fi
1431
1432 if test "x$enable_xvmc" = xyes; then
1433     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1434     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1435     HAVE_ST_XVMC="yes"
1436 fi
1437
1438 if test "x$enable_vdpau" = xyes; then
1439     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1440     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1441     HAVE_ST_VDPAU="yes"
1442 fi
1443
1444 dnl
1445 dnl OpenCL configuration
1446 dnl
1447
1448 AC_ARG_WITH([libclc-path],
1449    [AS_HELP_STRING([--with-libclc-path],
1450          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1451    [LIBCLC_PATH="$withval"],
1452    [LIBCLC_PATH=""])
1453
1454 AC_ARG_WITH([clang-libdir],
1455    [AS_HELP_STRING([--with-clang-libdir],
1456          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1457    [CLANG_LIBDIR="$withval"],
1458    [CLANG_LIBDIR=""])
1459
1460 AC_SUBST([LIBCLC_PATH])
1461
1462 if test "x$enable_opencl" = xyes; then
1463     if test "x$with_gallium_drivers" = x; then
1464         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1465     fi
1466
1467     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1468         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1469     fi
1470
1471     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1472     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1473     enable_gallium_loader=yes
1474 fi
1475
1476 dnl
1477 dnl Gallium configuration
1478 dnl
1479 if test "x$with_gallium_drivers" != x; then
1480     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1481 fi
1482 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1483
1484 AC_SUBST([LLVM_BINDIR])
1485 AC_SUBST([LLVM_CFLAGS])
1486 AC_SUBST([LLVM_CPPFLAGS])
1487 AC_SUBST([LLVM_CXXFLAGS])
1488 AC_SUBST([LLVM_LIBDIR])
1489 AC_SUBST([LLVM_LIBS])
1490 AC_SUBST([LLVM_LDFLAGS])
1491 AC_SUBST([LLVM_INCLUDEDIR])
1492 AC_SUBST([LLVM_VERSION])
1493 AC_SUBST([CLANG_RESOURCE_DIR])
1494
1495 case "x$enable_opengl$enable_gles1$enable_gles2" in
1496 x*yes*)
1497     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1498     ;;
1499 esac
1500
1501 AC_SUBST([VG_LIB_DEPS])
1502 AC_SUBST([EGL_CLIENT_APIS])
1503
1504 dnl
1505 dnl EGL Platforms configuration
1506 dnl
1507 AC_ARG_WITH([egl-platforms],
1508     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1509         [comma delimited native platforms libEGL supports, e.g.
1510         "x11,drm" @<:@default=auto@:>@])],
1511     [with_egl_platforms="$withval"],
1512     [if test "x$enable_egl" = xyes; then
1513         with_egl_platforms="x11"
1514     else
1515         with_egl_platforms=""
1516     fi])
1517
1518 EGL_PLATFORMS=""
1519
1520 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1521     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1522 fi
1523
1524 # Do per-EGL platform setups and checks
1525 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1526 for plat in $egl_platforms; do
1527         case "$plat" in
1528         fbdev|null)
1529                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1530                 ;;
1531
1532         wayland)
1533                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1534                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1535
1536                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1537                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1538                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1539                 ;;
1540
1541         x11)
1542                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1543
1544                 if test "x$enable_glx" = xyes; then
1545                         HAVE_EGL_DRIVER_GLX=1
1546                 fi
1547                 ;;
1548
1549         drm)
1550                 test "x$enable_gbm" = "xno" &&
1551                         AC_MSG_ERROR([EGL platform drm needs gbm])
1552                 ;;
1553
1554         android|gdi)
1555                 ;;
1556
1557         *)
1558                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1559                 ;;
1560         esac
1561
1562         case "$plat$have_libudev" in
1563                 waylandno|drmno)
1564                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1565         esac
1566 done
1567
1568 # libEGL wants to default to the first platform specified in
1569 # ./configure.  parse that here.
1570 if test "x$egl_platforms" != "x"; then
1571     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1572     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1573 else
1574     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1575 fi
1576
1577 EGL_PLATFORMS="$egl_platforms"
1578
1579 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1580 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1581 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1582 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1583 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1584
1585 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1586 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1587
1588 AC_SUBST([EGL_NATIVE_PLATFORM])
1589 AC_SUBST([EGL_PLATFORMS])
1590 AC_SUBST([EGL_CFLAGS])
1591
1592 AC_ARG_WITH([egl-driver-dir],
1593     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1594                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1595     [EGL_DRIVER_INSTALL_DIR="$withval"],
1596     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1597 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1598
1599 AC_ARG_WITH([xorg-driver-dir],
1600     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1601                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1602     [XORG_DRIVER_INSTALL_DIR="$withval"],
1603     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1604 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1605
1606 AC_ARG_WITH([max-width],
1607     [AS_HELP_STRING([--with-max-width=N],
1608                     [Maximum framebuffer width (4096)])],
1609     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1610      AS_IF([test "${withval}" -gt "4096"],
1611            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1612 )
1613 AC_ARG_WITH([max-height],
1614     [AS_HELP_STRING([--with-max-height=N],
1615                     [Maximum framebuffer height (4096)])],
1616     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1617      AS_IF([test "${withval}" -gt "4096"],
1618            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1619 )
1620
1621 dnl
1622 dnl Gallium LLVM
1623 dnl
1624 AC_ARG_ENABLE([gallium-llvm],
1625     [AS_HELP_STRING([--enable-gallium-llvm],
1626         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1627     [enable_gallium_llvm="$enableval"],
1628     [enable_gallium_llvm=auto])
1629
1630 AC_ARG_WITH([llvm-shared-libs],
1631     [AS_HELP_STRING([--with-llvm-shared-libs],
1632         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1633     [with_llvm_shared_libs=yes],
1634     [with_llvm_shared_libs=no])
1635
1636 AC_ARG_WITH([llvm-prefix],
1637     [AS_HELP_STRING([--with-llvm-prefix],
1638         [Prefix for LLVM installations in non-standard locations])],
1639     [llvm_prefix="$withval"],
1640     [llvm_prefix=""])
1641
1642
1643 # Call this inside ` ` to get the return value.
1644 # $1 is the llvm-config command with arguments.
1645 strip_unwanted_llvm_flags() {
1646     # Use \> (marks the end of the word)
1647     echo `$1` | sed \
1648         -e 's/-DNDEBUG\>//g' \
1649         -e 's/-pedantic\>//g' \
1650         -e 's/-Wcovered-switch-default\>//g' \
1651         -e 's/-O.\>//g' \
1652         -e 's/-g\>//g' \
1653         -e 's/-Wall\>//g' \
1654         -e 's/-fomit-frame-pointer\>//g'
1655 }
1656
1657
1658 if test "x$with_gallium_drivers" = x; then
1659     enable_gallium_llvm=no
1660 fi
1661 if test "x$enable_gallium_llvm" = xauto; then
1662     case "$host_cpu" in
1663     i*86|x86_64) enable_gallium_llvm=yes;;
1664     esac
1665 fi
1666 if test "x$enable_gallium_llvm" = xyes; then
1667     if test "x$llvm_prefix" != x; then
1668         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1669     else
1670         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1671     fi
1672
1673     if test "x$LLVM_CONFIG" != xno; then
1674         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1675         if test "x$with_llvm_shared_libs" = xyes; then
1676             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1677             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1678         else
1679             LLVM_COMPONENTS="engine bitwriter"
1680             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1681                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1682             fi
1683
1684             if test "x$enable_opencl" = xyes; then
1685                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1686             fi
1687             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1688         fi
1689         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1690         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1691         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1692         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1693         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1694         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1695         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1696         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1697         MESA_LLVM=1
1698
1699         dnl Check for Clang interanl headers
1700         if test "x$enable_opencl" = xyes; then
1701             if test "x$CLANG_LIBDIR" = x; then
1702                 CLANG_LIBDIR=${LLVM_LIBDIR}
1703             fi
1704             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1705             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1706                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1707         fi
1708     else
1709         MESA_LLVM=0
1710     fi
1711 else
1712     MESA_LLVM=0
1713 fi
1714
1715 dnl Directory for XVMC libs
1716 AC_ARG_WITH([xvmc-libdir],
1717     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1718         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1719     [XVMC_LIB_INSTALL_DIR="$withval"],
1720     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1721 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1722
1723 dnl
1724 dnl Gallium Tests
1725 dnl
1726 if test "x$enable_gallium_tests" = xyes; then
1727     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1728     enable_gallium_loader=yes
1729 fi
1730
1731 dnl Directory for VDPAU libs
1732 AC_ARG_WITH([vdpau-libdir],
1733     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1734         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1735     [VDPAU_LIB_INSTALL_DIR="$withval"],
1736     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1737 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1738
1739 dnl Directory for OpenCL libs
1740 AC_ARG_WITH([opencl-libdir],
1741     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1742         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1743     [OPENCL_LIB_INSTALL_DIR="$withval"],
1744     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1745 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1746
1747 dnl
1748 dnl Gallium helper functions
1749 dnl
1750 gallium_check_st() {
1751     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1752          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1753          test "x$HAVE_ST_VDPAU" = xyes; then
1754          if test "x$have_libdrm" != xyes; then
1755             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1756          fi
1757          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1758     fi
1759     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1760          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1761     fi
1762     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1763          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1764     fi
1765     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1766          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1767     fi
1768     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1769          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1770     fi
1771     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1772          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1773     fi
1774 }
1775
1776 gallium_require_llvm() {
1777     if test "x$MESA_LLVM" = x0; then
1778         case "$host_cpu" in
1779         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1780         esac
1781     fi
1782 }
1783
1784 gallium_require_drm_loader() {
1785     if test "x$enable_gallium_loader" = xyes; then
1786         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1787                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1788         if test "x$have_libdrm" != xyes; then
1789             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1790         fi
1791         enable_gallium_drm_loader=yes
1792     fi
1793 }
1794
1795 radeon_llvm_check() {
1796     LLVM_REQUIRED_VERSION_MAJOR="3"
1797     LLVM_REQUIRED_VERSION_MINOR="2"
1798     LLVM_AVAILABLE_VERSION_MAJOR=`echo $LLVM_VERSION | cut -d. -f1`
1799     LLVM_AVAILABLE_VERSION_MINOR=`echo $LLVM_VERSION | cut -d. -f2`
1800     if test "$LLVM_AVAILABLE_VERSION_MAJOR" -lt "$LLVM_REQUIRED_VERSION_MAJOR" -o [ "$LLVM_AVAILABLE_VERSION_MAJOR" -eq "$LLVM_REQUIRED_VERSION_MAJOR" -a "$LLVM_AVAILABLE_VERSION_MINOR" -lt "$LLVM_REQUIRED_VERSION_MINOR" ] ; then
1801         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer with AMDGPU target enabled is required.
1802                      To use the r600/radeonsi LLVM backend, you need to fetch the LLVM source from:
1803                      git://people.freedesktop.org/~tstellar/llvm master
1804                      and build with --enable-experimental-targets=AMDGPU])
1805     fi
1806     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<AMDGPU\>' ; then
1807         AC_MSG_ERROR([LLVM AMDGPU Target not enabled.
1808                       To use the r600/radeonsi LLVM backend, you need to fetch the LLVM source from:
1809                       git://people.freedesktop.org/~tstellar/llvm master
1810                       and build with --enable-experimental-targets=AMDGPU])
1811     fi
1812     AC_MSG_WARN([Please ensure you use the latest llvm tree from git://people.freedesktop.org/~tstellar/llvm master before submitting a bug])
1813     if test "x$LLVM_VERSION" = "x3.2"; then
1814         LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --libs amdgpu`"
1815     fi
1816 }
1817
1818 dnl Gallium drivers
1819 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1820 if test "x$with_gallium_drivers" != x; then
1821     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1822     for driver in $gallium_drivers; do
1823         case "x$driver" in
1824         xsvga)
1825             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1826             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1827             ;;
1828         xi915)
1829             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1830             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1831             if test "x$MESA_LLVM" = x1; then
1832                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1833             fi
1834             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1835             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1836             ;;
1837         xr300)
1838             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1839             gallium_require_llvm "Gallium R300"
1840             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1841             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300"
1842             ;;
1843         xr600)
1844             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1845             gallium_require_drm_loader
1846             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1847             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1848                 radeon_llvm_check
1849                 NEED_RADEON_GALLIUM=yes;
1850             fi
1851             if test "x$enable_r600_llvm" = xyes; then
1852                 USE_R600_LLVM_COMPILER=yes;
1853             fi
1854             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1855                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1856             fi
1857             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1858             ;;
1859         xradeonsi)
1860             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1861             gallium_require_drm_loader
1862             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1863             radeon_llvm_check
1864             NEED_RADEON_GALLIUM=yes;
1865             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1866             ;;
1867         xnouveau)
1868             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1869             gallium_require_drm_loader
1870             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1871             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1872             ;;
1873         xswrast)
1874             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1875             if test "x$MESA_LLVM" = x1; then
1876                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1877             fi
1878
1879             if test "x$HAVE_ST_DRI" = xyes; then
1880                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1881             fi
1882             if test "x$HAVE_ST_VDPAU" = xyes; then
1883                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1884             fi
1885             if test "x$HAVE_ST_XVMC" = xyes; then
1886                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1887             fi
1888             if test "x$HAVE_ST_VDPAU" = xyes ||
1889                test "x$HAVE_ST_XVMC" = xyes; then
1890                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1891                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1892                fi
1893             fi
1894             ;;
1895         *)
1896             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1897             ;;
1898         esac
1899     done
1900 fi
1901
1902 if test "x$enable_gallium_loader" = xyes; then
1903     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1904     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1905     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1906     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1907
1908     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1909         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1910         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1911     fi
1912
1913     if test "x$enable_gallium_drm_loader" = xyes; then
1914         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1915         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1916                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1917         if test "x$pipe_loader_have_xcb" = xyes; then
1918             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1919             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1920         fi
1921     fi
1922
1923     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1924     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1925 fi
1926
1927 dnl Tell Automake which drivers to build
1928 for driver in $GALLIUM_DRIVERS_DIRS; do
1929     case "x$driver" in
1930         xgalahad)
1931             HAVE_GALAHAD_GALLIUM=yes;
1932             ;;
1933         xidentity)
1934             HAVE_IDENTITY_GALLIUM=yes;
1935             ;;
1936         xnoop)
1937             HAVE_NOOP_GALLIUM=yes;
1938             ;;
1939         *)
1940             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1941             ;;
1942     esac
1943 done
1944
1945 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1946 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1947 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1948 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1949 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1950 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1951 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1952 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1953 AC_SUBST([GALLIUM_MAKE_DIRS])
1954
1955 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1956
1957 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1958 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1959 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1960
1961 dnl prepend CORE_DIRS to SRC_DIRS
1962 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1963
1964 dnl Restore LDFLAGS and CPPFLAGS
1965 LDFLAGS="$_SAVE_LDFLAGS"
1966 CPPFLAGS="$_SAVE_CPPFLAGS"
1967
1968 dnl Add user CFLAGS and CXXFLAGS
1969 CFLAGS="$CFLAGS $USER_CFLAGS"
1970 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1971
1972 dnl Substitute the config
1973 AC_CONFIG_FILES([configs/current
1974                 Makefile
1975                 src/Makefile
1976                 src/egl/Makefile
1977                 src/egl/drivers/Makefile
1978                 src/egl/drivers/dri2/Makefile
1979                 src/egl/drivers/glx/Makefile
1980                 src/egl/main/Makefile
1981                 src/egl/main/egl.pc
1982                 src/egl/wayland/Makefile
1983                 src/egl/wayland/wayland-drm/Makefile
1984                 src/egl/wayland/wayland-egl/Makefile
1985                 src/egl/wayland/wayland-egl/wayland-egl.pc
1986                 src/gallium/Makefile
1987                 src/gallium/auxiliary/pipe-loader/Makefile
1988                 src/gallium/drivers/Makefile
1989                 src/gallium/drivers/r300/Makefile
1990                 src/gallium/drivers/r600/Makefile
1991                 src/gallium/state_trackers/clover/Makefile
1992                 src/gallium/targets/opencl/Makefile
1993                 src/gbm/Makefile
1994                 src/gbm/main/gbm.pc
1995                 src/glsl/Makefile
1996                 src/glsl/builtin_compiler/Makefile
1997                 src/glsl/glcpp/Makefile
1998                 src/glsl/tests/Makefile
1999                 src/glx/Makefile
2000                 src/glx/tests/Makefile
2001                 src/gtest/Makefile
2002                 src/mapi/es1api/Makefile
2003                 src/mapi/es1api/glesv1_cm.pc
2004                 src/mapi/es2api/Makefile
2005                 src/mapi/es2api/glesv2.pc
2006                 src/mapi/glapi/Makefile
2007                 src/mapi/glapi/gen/Makefile
2008                 src/mapi/glapi/tests/Makefile
2009                 src/mapi/shared-glapi/Makefile
2010                 src/mapi/shared-glapi/tests/Makefile
2011                 src/mapi/vgapi/Makefile
2012                 src/mapi/vgapi/vg.pc
2013                 src/mesa/Makefile
2014                 src/mesa/gl.pc
2015                 src/mesa/drivers/Makefile
2016                 src/mesa/drivers/dri/dri.pc
2017                 src/mesa/drivers/dri/common/Makefile
2018                 src/mesa/drivers/dri/i915/Makefile
2019                 src/mesa/drivers/dri/i965/Makefile
2020                 src/mesa/drivers/dri/Makefile
2021                 src/mesa/drivers/dri/nouveau/Makefile
2022                 src/mesa/drivers/dri/r200/Makefile
2023                 src/mesa/drivers/dri/radeon/Makefile
2024                 src/mesa/drivers/dri/swrast/Makefile
2025                 src/mesa/drivers/osmesa/Makefile
2026                 src/mesa/drivers/osmesa/osmesa.pc
2027                 src/mesa/drivers/x11/Makefile
2028                 src/mesa/libdricore/Makefile
2029                 src/mesa/main/tests/Makefile
2030                 src/mesa/main/tests/hash_table/Makefile
2031                 src/mesa/program/Makefile
2032                 src/mesa/x86-64/Makefile
2033                 src/mesa/x86/Makefile])
2034
2035 dnl Sort the dirs alphabetically
2036 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2037 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2038 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2039 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2040 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2041
2042 AC_OUTPUT
2043
2044 dnl
2045 dnl Output some configuration info for the user
2046 dnl
2047 echo ""
2048 echo "        prefix:          $prefix"
2049 echo "        exec_prefix:     $exec_prefix"
2050 echo "        libdir:          $libdir"
2051 echo "        includedir:      $includedir"
2052
2053 dnl API info
2054 echo ""
2055 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2056 echo "        OpenVG:          $enable_openvg"
2057
2058 dnl Driver info
2059 echo ""
2060 if test "x$enable_osmesa" != xno; then
2061         echo "        OSMesa:          lib$OSMESA_LIB"
2062 else
2063         echo "        OSMesa:          no"
2064 fi
2065
2066 if test "x$enable_dri" != xno; then
2067         # cleanup the drivers var
2068         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2069         if test "x$DRI_DIRS" = x; then
2070             echo "        DRI drivers:     no"
2071         else
2072             echo "        DRI drivers:     $dri_dirs"
2073         fi
2074         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2075 fi
2076
2077 case "x$enable_glx$enable_xlib_glx" in
2078 xyesyes)
2079     echo "        GLX:             Xlib-based"
2080     ;;
2081 xyesno)
2082     echo "        GLX:             DRI-based"
2083     ;;
2084 *)
2085     echo "        GLX:             $enable_glx"
2086     ;;
2087 esac
2088
2089 dnl EGL
2090 echo ""
2091 echo "        EGL:             $enable_egl"
2092 if test "$enable_egl" = yes; then
2093     echo "        EGL platforms:   $EGL_PLATFORMS"
2094
2095     egl_drivers=""
2096     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2097         egl_drivers="$egl_drivers builtin:egl_glx"
2098     fi
2099     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2100         egl_drivers="$egl_drivers builtin:egl_dri2"
2101     fi
2102
2103     if test "x$HAVE_ST_EGL" = xyes; then
2104         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2105         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2106     else
2107         echo "        EGL drivers:    $egl_drivers"
2108     fi
2109 fi
2110
2111 echo ""
2112 if test "x$MESA_LLVM" = x1; then
2113     echo "        llvm:            yes"
2114     echo "        llvm-config:     $LLVM_CONFIG"
2115     echo "        llvm-version:    $LLVM_VERSION"
2116 else
2117     echo "        llvm:            no"
2118 fi
2119
2120 echo ""
2121 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2122     echo "        Gallium:         yes"
2123     echo "        Gallium dirs:    $GALLIUM_DIRS"
2124     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2125     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2126     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2127     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2128 else
2129     echo "        Gallium:         no"
2130 fi
2131
2132
2133 dnl Libraries
2134 echo ""
2135 echo "        Shared libs:     $enable_shared"
2136 echo "        Static libs:     $enable_static"
2137 echo "        Shared-glapi:    $enable_shared_glapi"
2138
2139 dnl Compiler options
2140 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2141 cflags=`echo $CFLAGS $PIC_FLAGS | \
2142     $SED 's/^ *//;s/  */ /;s/ *$//'`
2143 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2144     $SED 's/^ *//;s/  */ /;s/ *$//'`
2145 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2146 echo ""
2147 echo "        CFLAGS:          $cflags"
2148 echo "        CXXFLAGS:        $cxxflags"
2149 echo "        Macros:          $defines"
2150 echo ""
2151 if test "x$MESA_LLVM" = x1; then
2152     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2153     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2154     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2155     echo ""
2156 fi
2157 echo "        PYTHON2:         $PYTHON2"
2158
2159 echo ""
2160 echo "        Run '${MAKE-make}' to build Mesa"
2161 echo ""