configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.59],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  33 AM_MAINTAINER_MODE([enable])
  34
  35 # Enable quiet compiles on automake 1.11.
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 # Check for programs
  39 AC_PROG_CC
  40
  41 AC_USE_SYSTEM_EXTENSIONS
  42 AC_SYS_LARGEFILE
  43 AC_FUNC_ALLOCA
  44
  45 # Initialize libtool
  46 LT_PREREQ([2.2])
  47 LT_INIT([disable-static])
  48
  49
  50 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  51 AC_SUBST(PTHREADSTUBS_CFLAGS)
  52 AC_SUBST(PTHREADSTUBS_LIBS)
  53
  54 pkgconfigdir=${libdir}/pkgconfig
  55 AC_SUBST(pkgconfigdir)
  56 AC_ARG_ENABLE([udev],
  57               [AS_HELP_STRING([--enable-udev],
  58                               [Enable support for using udev instead of mknod (default: disabled)])],
  59               [UDEV=$enableval], [UDEV=no])
  60
  61 AC_ARG_ENABLE(libkms,
  62               AS_HELP_STRING([--disable-libkms],
  63               [Disable KMS mm abstraction library (default: auto)]),
  64               [LIBKMS=$enableval], [LIBKMS=auto])
  65
  66 AC_ARG_ENABLE(intel,
  67               AS_HELP_STRING([--disable-intel],
  68               [Enable support for intel's KMS API (default: auto)]),
  69               [INTEL=$enableval], [INTEL=auto])
  70
  71 AC_ARG_ENABLE(radeon,
  72               AS_HELP_STRING([--disable-radeon],
  73               [Enable support for radeon's KMS API (default: auto)]),
  74               [RADEON=$enableval], [RADEON=auto])
  75
  76 AC_ARG_ENABLE(nouveau,
  77               AS_HELP_STRING([--disable-nouveau],
  78               [Enable support for nouveau's KMS API (default: auto)]),
  79               [NOUVEAU=$enableval], [NOUVEAU=auto])
  80
  81 AC_ARG_ENABLE(vmwgfx,
  82               AS_HELP_STRING([--disable-vmwgfx],
  83               [Enable support for vmwgfx's KMS API (default: yes)]),
  84               [VMWGFX=$enableval], [VMWGFX=yes])
  85
  86 AC_ARG_ENABLE(omap-experimental-api,
  87               AS_HELP_STRING([--enable-omap-experimental-api],
  88               [Enable support for OMAP's experimental API (default: disabled)]),
  89               [OMAP=$enableval], [OMAP=no])
  90
  91 AC_ARG_ENABLE(exynos-experimental-api,
  92               AS_HELP_STRING([--enable-exynos-experimental-api],
  93               [Enable support for EXYNOS's experimental API (default: disabled)]),
  94               [EXYNOS=$enableval], [EXYNOS=no])
  95
  96 AC_ARG_ENABLE(freedreno,
  97               AS_HELP_STRING([--disable-freedreno],
  98               [Enable support for freedreno's KMS API (default: enabled on arm)]),
  99               [FREEDRENO=$enableval], [FREEDRENO=auto])
 100
 101 AC_ARG_ENABLE(freedreno-kgsl,
 102               AS_HELP_STRING([--enable-freedreno-kgsl],
 103               [Enable support for freedreno's to use downstream android kernel API (default: disabled)]),
 104               [FREEDRENO_KGSL=$enableval], [FREEDRENO_KGSL=no])
 105
 106 AC_ARG_ENABLE(tegra-experimental-api,
 107               AS_HELP_STRING([--enable-tegra-experimental-api],
 108               [Enable support for Tegra's experimental API (default: disabled)]),
 109               [TEGRA=$enableval], [TEGRA=no])
 110
 111 AC_ARG_ENABLE(install-test-programs,
 112                   AS_HELP_STRING([--enable-install-test-programs],
 113                   [Install test programs (default: no)]),
 114                   [INSTALL_TESTS=$enableval], [INSTALL_TESTS=no])
 115
 116 dnl ===========================================================================
 117 dnl check compiler flags
 118 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 119   AC_MSG_CHECKING([whether $CC supports $1])
 120
 121   libdrm_save_CFLAGS="$CFLAGS"
 122   CFLAGS="$CFLAGS $1"
 123
 124   AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 125   CFLAGS="$libdrm_save_CFLAGS"
 126
 127   if test "x$libdrm_cc_flag" = "xyes"; then
 128     ifelse([$2], , :, [$2])
 129   else
 130     ifelse([$3], , :, [$3])
 131   fi
 132   AC_MSG_RESULT([$libdrm_cc_flag])
 133 ])
 134
 135 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 136
 137 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 138                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 139                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 140 AC_SUBST([CLOCK_LIB])
 141
 142 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 143
 144 dnl Use lots of warning flags with with gcc and compatible compilers
 145
 146 dnl Note: if you change the following variable, the cache is automatically
 147 dnl skipped and all flags rechecked.  So there's no need to do anything
 148 dnl else.  If for any reason you need to force a recheck, just change
 149 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 150
 151 MAYBE_WARN="-Wall -Wextra \
 152 -Wsign-compare -Werror-implicit-function-declaration \
 153 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 154 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 155 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 156 -Wstrict-aliasing=2 -Winit-self \
 157 -Wdeclaration-after-statement -Wold-style-definition \
 158 -Wno-missing-field-initializers -Wno-unused-parameter \
 159 -Wno-attributes -Wno-long-long -Winline"
 160
 161 # invalidate cached value if MAYBE_WARN has changed
 162 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 163         unset libdrm_cv_warn_cflags
 164 fi
 165 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 166         echo
 167         WARN_CFLAGS=""
 168
 169         # Some warning options are not supported by all versions of
 170         # gcc, so test all desired options against the current
 171         # compiler.
 172         #
 173         # Note that there are some order dependencies
 174         # here. Specifically, an option that disables a warning will
 175         # have no net effect if a later option then enables that
 176         # warnings, (perhaps implicitly). So we put some grouped
 177         # options (-Wall and -Wextra) up front and the -Wno options
 178         # last.
 179
 180         for W in $MAYBE_WARN; do
 181                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 182         done
 183
 184         libdrm_cv_warn_cflags=$WARN_CFLAGS
 185         libdrm_cv_warn_maybe=$MAYBE_WARN
 186
 187         AC_MSG_CHECKING([which warning flags were supported])])
 188 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 189
 190 # Check for atomic intrinsics
 191 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives, [
 192         drm_cv_atomic_primitives="none"
 193
 194         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 195         int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 196         int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 197                                           ]],[[]])], [drm_cv_atomic_primitives="Intel"],[])
 198
 199         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 200                 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 201         fi
 202
 203         # atomic functions defined in <atomic.h> & libc on Solaris
 204         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 205                 AC_CHECK_FUNC([atomic_cas_uint], drm_cv_atomic_primitives="Solaris")
 206         fi
 207 ])
 208
 209 if test "x$drm_cv_atomic_primitives" = xIntel; then
 210         AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 211                 [Enable if your compiler supports the Intel __sync_* atomic primitives])
 212 fi
 213 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 214         AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 215 fi
 216
 217 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno" -o "x$NOUVEAU" != "xno"; then
 218         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 219                 if test "x$INTEL" != "xauto"; then
 220                         if test "x$INTEL" != "xno"; then
 221                                 AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
 222                         fi
 223                 else
 224                         AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 225                         INTEL=no
 226                 fi
 227                 if test "x$RADEON" != "xauto"; then
 228                         if test "x$RADEON" != "xno"; then
 229                                 AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon GPUs by passing --disable-radeon to ./configure])
 230                         fi
 231                 else
 232                         AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 233                         RADEON=no
 234                 fi
 235                 if test "x$NOUVEAU" != "xauto"; then
 236                         if test "x$NOUVEAU" != "xno"; then
 237                                 AC_MSG_ERROR([libdrm_nouveau depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA GPUs by passing --disable-nouveau to ./configure])
 238                         fi
 239                 else
 240                         AC_MSG_WARN([Disabling libdrm_nouveau. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 241                         NOUVEAU=no
 242                 fi
 243         else
 244                 if test "x$INTEL" != "xno"; then
 245                         case $host_cpu in
 246                                 i?86|x86_64) INTEL=yes ;;
 247                                 *) INTEL=no ;;
 248                         esac
 249                 fi
 250                 if test "x$RADEON" != "xno"; then
 251                         RADEON=yes
 252                 fi
 253                 if test "x$NOUVEAU" != "xno"; then
 254                         NOUVEAU=yes
 255                 fi
 256         fi
 257 fi
 258
 259 if test "x$INTEL" != "xno"; then
 260         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 261 fi
 262 AC_SUBST(PCIACCESS_CFLAGS)
 263 AC_SUBST(PCIACCESS_LIBS)
 264
 265 if test "x$UDEV" = xyes; then
 266         AC_DEFINE(UDEV, 1, [Have UDEV support])
 267 fi
 268
 269 AC_CANONICAL_HOST
 270 if test "x$LIBKMS" = xauto ; then
 271         case $host_os in
 272                 linux*)         LIBKMS="yes" ;;
 273                 freebsd* | kfreebsd*-gnu)
 274                                 LIBKMS="yes" ;;
 275                 dragonfly*)     LIBKMS="yes" ;;
 276                 *)              LIBKMS="no" ;;
 277         esac
 278 fi
 279
 280 if test "x$FREEDRENO" = xauto ; then
 281         case $host_cpu in
 282                 arm*|aarch64)   FREEDRENO="yes" ;;
 283                 *)              FREEDRENO="no" ;;
 284         esac
 285 fi
 286
 287 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 288
 289 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" = xyes])
 290 if test "x$INTEL" = xyes; then
 291         AC_DEFINE(HAVE_INTEL, 1, [Have intel support])
 292 fi
 293
 294 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 295 if test "x$VMWGFX" = xyes; then
 296         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 297 fi
 298
 299 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 300 if test "x$NOUVEAU" = xyes; then
 301         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 302 fi
 303
 304 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 305 if test "x$OMAP" = xyes; then
 306         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 307 fi
 308
 309 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 310 if test "x$EXYNOS" = xyes; then
 311         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 312 fi
 313
 314 AM_CONDITIONAL(HAVE_FREEDRENO, [test "x$FREEDRENO" = xyes])
 315 if test "x$FREEDRENO" = xyes; then
 316         AC_DEFINE(HAVE_FREEDRENO, 1, [Have freedreno support])
 317 fi
 318
 319 AM_CONDITIONAL(HAVE_FREEDRENO_KGSL, [test "x$FREEDRENO_KGSL" = xyes])
 320 if test "x$FREEDRENO_KGSL" = xyes; then
 321         AC_DEFINE(HAVE_FREEDRENO_KGSL, 1, [Have freedreno support for KGSL kernel interface])
 322 fi
 323
 324 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 325 if test "x$RADEON" = xyes; then
 326         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 327 fi
 328
 329 AM_CONDITIONAL(HAVE_TEGRA, [test "x$TEGRA" = xyes])
 330 if test "x$TEGRA" = xyes; then
 331         AC_DEFINE(HAVE_TEGRA, 1, [Have Tegra support])
 332 fi
 333
 334 AM_CONDITIONAL(HAVE_INSTALL_TESTS, [test "x$INSTALL_TESTS" = xyes])
 335 if test "x$INSTALL_TESTS" = xyes; then
 336         AC_DEFINE(HAVE_INSTALL_TESTS, 1, [Install test programs])
 337 fi
 338
 339 AC_ARG_ENABLE([cairo-tests],
 340               [AS_HELP_STRING([--enable-cairo-tests],
 341                               [Enable support for Cairo rendering in tests (default: auto)])],
 342               [CAIRO=$enableval], [CAIRO=auto])
 343 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 344 AC_MSG_CHECKING([whether to enable Cairo tests])
 345 if test "x$CAIRO" = xauto; then
 346         CAIRO="$HAVE_CAIRO"
 347 fi
 348 if test "x$CAIRO" = xyes; then
 349         if ! test "x$HAVE_CAIRO" = xyes; then
 350                 AC_MSG_ERROR([Cairo support required but not present])
 351         fi
 352         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 353 fi
 354 AC_MSG_RESULT([$CAIRO])
 355 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 356
 357 # For enumerating devices in test case
 358 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 359 if test "x$HAVE_LIBUDEV" = xyes; then
 360         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 361 fi
 362 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 363
 364 # xsltproc for docbook manpages
 365 AC_ARG_ENABLE([manpages],
 366               AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
 367               [MANS=$enableval], [MANS=auto])
 368 AC_PATH_PROG(XSLTPROC, xsltproc)
 369 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 370
 371 # check for offline man-pages stylesheet
 372 AC_MSG_CHECKING([for docbook manpages stylesheet])
 373 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 374 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 375                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 376                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 377 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 378         AC_SUBST(MANPAGES_STYLESHEET)
 379         AC_MSG_RESULT([yes])
 380 else
 381         AC_MSG_RESULT([no])
 382 fi
 383 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 384
 385 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 386 if test "x$have_valgrind" = "xyes"; then
 387         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 388 fi
 389
 390 AC_ARG_WITH([kernel-source],
 391             [AS_HELP_STRING([--with-kernel-source],
 392               [specify path to linux kernel source])],
 393             [kernel_source="$with_kernel_source"])
 394 AC_SUBST(kernel_source)
 395
 396 dnl Add flags for gcc and g++
 397 if test "x$GCC" = xyes; then
 398     # Enable -fvisibility=hidden if using a gcc that supports it
 399     save_CFLAGS="$CFLAGS"
 400     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 401     VISIBILITY_CFLAGS="-fvisibility=hidden"
 402     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 403     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 404                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 405
 406     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 407     CFLAGS=$save_CFLAGS
 408
 409     if test "x$VISIBILITY_CFLAGS" != x; then
 410         AC_DEFINE(HAVE_VISIBILITY, 1, [Compiler has -fvisibility support])
 411     fi
 412
 413     AC_SUBST([VISIBILITY_CFLAGS])
 414 fi
 415
 416 AC_SUBST(WARN_CFLAGS)
 417 AC_CONFIG_FILES([
 418         Makefile
 419         libkms/Makefile
 420         libkms/libkms.pc
 421         intel/Makefile
 422         intel/libdrm_intel.pc
 423         radeon/Makefile
 424         radeon/libdrm_radeon.pc
 425         nouveau/Makefile
 426         nouveau/libdrm_nouveau.pc
 427         omap/Makefile
 428         omap/libdrm_omap.pc
 429         exynos/Makefile
 430         exynos/libdrm_exynos.pc
 431         freedreno/Makefile
 432         freedreno/libdrm_freedreno.pc
 433         tegra/Makefile
 434         tegra/libdrm_tegra.pc
 435         tests/Makefile
 436         tests/modeprint/Makefile
 437         tests/modetest/Makefile
 438         tests/kmstest/Makefile
 439         tests/proptest/Makefile
 440         tests/radeon/Makefile
 441         tests/vbltest/Makefile
 442         tests/exynos/Makefile
 443         tests/tegra/Makefile
 444         man/Makefile
 445         libdrm.pc])
 446 AC_OUTPUT
 447
 448 echo ""
 449 echo "$PACKAGE_STRING will be compiled with:"
 450 echo ""
 451 echo "  libkms         $LIBKMS"
 452 echo "  Intel API      $INTEL"
 453 echo "  vmwgfx API     $VMWGFX"
 454 echo "  Radeon API     $RADEON"
 455 echo "  Nouveau API    $NOUVEAU"
 456 echo "  OMAP API       $OMAP"
 457 echo "  EXYNOS API     $EXYNOS"
 458 echo "  Freedreno API  $FREEDRENO (kgsl: $FREEDRENO_KGSL)"
 459 echo "  Tegra API      $TEGRA"
 460 echo ""