configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports -Bsymbolic
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 323 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         BSYMBOLIC="-Wl,-Bsymbolic";],
 328     [AC_MSG_RESULT([no])
 329         BSYMBOLIC="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([BSYMBOLIC])
 333
 334 dnl
 335 dnl Check if linker supports garbage collection
 336 dnl
 337 save_LDFLAGS=$LDFLAGS
 338 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 339 AC_MSG_CHECKING([whether ld supports --gc-sections])
 340 AC_LINK_IFELSE(
 341     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 342     [AC_MSG_RESULT([yes])
 343         GC_SECTIONS="-Wl,--gc-sections";],
 344     [AC_MSG_RESULT([no])
 345         GC_SECTIONS="";])
 346 LDFLAGS=$save_LDFLAGS
 347
 348 AC_SUBST([GC_SECTIONS])
 349
 350 dnl
 351 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 352 dnl so when these flags are passed to ld via libtool the checks will fail
 353 dnl
 354 case "$host_os" in
 355 openbsd* | darwin* )
 356     LD_NO_UNDEFINED="" ;;
 357 *)
 358     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 359 esac
 360
 361 AC_SUBST([LD_NO_UNDEFINED])
 362
 363 dnl
 364 dnl Check if linker supports version scripts
 365 dnl
 366 AC_MSG_CHECKING([if the linker supports version-scripts])
 367 save_LDFLAGS=$LDFLAGS
 368 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 369 cat > conftest.map <<EOF
 370 VERSION_1 {
 371      global:
 372          main;
 373
 374      local:
 375          *;
 376 };
 377 EOF
 378 AC_LINK_IFELSE(
 379     [AC_LANG_SOURCE([int main() { return 0;}])],
 380     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 381     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 382 LDFLAGS=$save_LDFLAGS
 383 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 384
 385 dnl
 386 dnl compatibility symlinks
 387 dnl
 388 case "$host_os" in
 389 linux* )
 390     HAVE_COMPAT_SYMLINKS=yes ;;
 391 * )
 392     HAVE_COMPAT_SYMLINKS=no ;;
 393 esac
 394
 395 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 396
 397 dnl
 398 dnl library names
 399 dnl
 400 case "$host_os" in
 401 darwin* )
 402     LIB_EXT='dylib' ;;
 403 cygwin* )
 404     LIB_EXT='dll' ;;
 405 aix* )
 406     LIB_EXT='a' ;;
 407 * )
 408     LIB_EXT='so' ;;
 409 esac
 410
 411 AC_SUBST([LIB_EXT])
 412
 413 AC_ARG_WITH([gl-lib-name],
 414   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 415     [specify GL library name @<:@default=GL@:>@])],
 416   [GL_LIB=$withval],
 417   [GL_LIB=GL])
 418 AC_ARG_WITH([osmesa-lib-name],
 419   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 420     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 421   [OSMESA_LIB=$withval],
 422   [OSMESA_LIB=OSMesa])
 423 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 424 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 425
 426 dnl
 427 dnl Mangled Mesa support
 428 dnl
 429 AC_ARG_ENABLE([mangling],
 430   [AS_HELP_STRING([--enable-mangling],
 431     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 432   [enable_mangling="${enableval}"],
 433   [enable_mangling=no]
 434 )
 435 if test "x${enable_mangling}" = "xyes" ; then
 436   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 437   GL_LIB="Mangled${GL_LIB}"
 438   OSMESA_LIB="Mangled${OSMESA_LIB}"
 439 fi
 440 AC_SUBST([GL_LIB])
 441 AC_SUBST([OSMESA_LIB])
 442
 443 dnl
 444 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 445 dnl
 446 AC_ARG_ENABLE([texture-float],
 447     [AS_HELP_STRING([--enable-texture-float],
 448         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 449     [enable_texture_float="$enableval"],
 450     [enable_texture_float=no]
 451 )
 452 if test "x$enable_texture_float" = xyes; then
 453     AC_MSG_WARN([Floating-point textures enabled.])
 454     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 455     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 456 fi
 457
 458 dnl
 459 dnl Arch/platform-specific settings
 460 dnl
 461 AC_ARG_ENABLE([asm],
 462     [AS_HELP_STRING([--disable-asm],
 463         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 464     [enable_asm="$enableval"],
 465     [enable_asm=yes]
 466 )
 467 asm_arch=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64 | amd64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         gnu*)
 488             asm_arch=x86
 489             ;;
 490         esac
 491         ;;
 492     x86_64|amd64)
 493         case "$host_os" in
 494         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 495             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 496             ;;
 497         esac
 498         ;;
 499     sparc*)
 500         case "$host_os" in
 501         linux*)
 502             asm_arch=sparc
 503             ;;
 504         esac
 505         ;;
 506     esac
 507
 508     case "$asm_arch" in
 509     x86)
 510         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 511         AC_MSG_RESULT([yes, x86])
 512         ;;
 513     x86_64|amd64)
 514         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 515         AC_MSG_RESULT([yes, x86_64])
 516         ;;
 517     sparc)
 518         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526
 527 dnl Check to see if dlopen is in default libraries (like Solaris, which
 528 dnl has it in libc), or if libdl is needed to get it.
 529 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 530     [AC_CHECK_LIB([dl], [dlopen],
 531        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 532 AC_SUBST([DLOPEN_LIBS])
 533
 534 dnl Check if that library also has dladdr
 535 save_LDFLAGS="$LDFLAGS"
 536 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 537 AC_CHECK_FUNCS([dladdr])
 538 LDFLAGS="$save_LDFLAGS"
 539
 540 case "$host_os" in
 541 darwin*|mingw*)
 542     ;;
 543 *)
 544     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 545                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 546                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 547     AC_SUBST([CLOCK_LIB])
 548     ;;
 549 esac
 550
 551 dnl See if posix_memalign is available
 552 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 553
 554 dnl Check for pthreads
 555 AX_PTHREAD
 556 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 557 dnl to -pthread, which causes problems if we need -lpthread to appear in
 558 dnl pkgconfig files.
 559 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 560
 561 dnl SELinux awareness.
 562 AC_ARG_ENABLE([selinux],
 563     [AS_HELP_STRING([--enable-selinux],
 564         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 565     [MESA_SELINUX="$enableval"],
 566     [MESA_SELINUX=no])
 567 if test "x$enable_selinux" = "xyes"; then
 568     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 569         [AC_CHECK_HEADER([selinux/selinux.h],[],
 570                          [AC_MSG_ERROR([SELinux headers not found])])
 571          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 572                       [AC_MSG_ERROR([SELinux library not found])])
 573          SELINUX_LIBS="-lselinux"])
 574     DEFINES="$DEFINES -DMESA_SELINUX"
 575 fi
 576 AC_SUBST([SELINUX_CFLAGS])
 577 AC_SUBST([SELINUX_LIBS])
 578
 579 dnl Options for APIs
 580 AC_ARG_ENABLE([opengl],
 581     [AS_HELP_STRING([--disable-opengl],
 582         [disable support for standard OpenGL API @<:@default=no@:>@])],
 583     [enable_opengl="$enableval"],
 584     [enable_opengl=yes])
 585 AC_ARG_ENABLE([gles1],
 586     [AS_HELP_STRING([--enable-gles1],
 587         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 588     [enable_gles1="$enableval"],
 589     [enable_gles1=no])
 590 AC_ARG_ENABLE([gles2],
 591     [AS_HELP_STRING([--enable-gles2],
 592         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 593     [enable_gles2="$enableval"],
 594     [enable_gles2=no])
 595 AC_ARG_ENABLE([openvg],
 596     [AS_HELP_STRING([--enable-openvg],
 597         [enable support for OpenVG API @<:@default=no@:>@])],
 598     [enable_openvg="$enableval"],
 599     [enable_openvg=no])
 600
 601 AC_ARG_ENABLE([dri],
 602     [AS_HELP_STRING([--enable-dri],
 603         [enable DRI modules @<:@default=enabled@:>@])],
 604     [enable_dri="$enableval"],
 605     [enable_dri=yes])
 606
 607 case "$host_os" in
 608 linux*)
 609     dri3_default=yes
 610     ;;
 611 *)
 612     dri3_default=no
 613     ;;
 614 esac
 615 AC_ARG_ENABLE([dri3],
 616     [AS_HELP_STRING([--enable-dri3],
 617         [enable DRI3 @<:@default=auto@:>@])],
 618     [enable_dri3="$enableval"],
 619     [enable_dri3="$dri3_default"])
 620 AC_ARG_ENABLE([glx],
 621     [AS_HELP_STRING([--enable-glx],
 622         [enable GLX library @<:@default=enabled@:>@])],
 623     [enable_glx="$enableval"],
 624     [enable_glx=yes])
 625 AC_ARG_ENABLE([osmesa],
 626     [AS_HELP_STRING([--enable-osmesa],
 627         [enable OSMesa library @<:@default=disabled@:>@])],
 628     [enable_osmesa="$enableval"],
 629     [enable_osmesa=no])
 630 AC_ARG_ENABLE([gallium-osmesa],
 631     [AS_HELP_STRING([--enable-gallium-osmesa],
 632         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 633     [enable_gallium_osmesa="$enableval"],
 634     [enable_gallium_osmesa=no])
 635 AC_ARG_ENABLE([egl],
 636     [AS_HELP_STRING([--disable-egl],
 637         [disable EGL library @<:@default=enabled@:>@])],
 638     [enable_egl="$enableval"],
 639     [enable_egl=yes])
 640
 641 AC_ARG_ENABLE([xa],
 642     [AS_HELP_STRING([--enable-xa],
 643         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 644     [enable_xa="$enableval"],
 645     [enable_xa=no])
 646 AC_ARG_ENABLE([gbm],
 647    [AS_HELP_STRING([--enable-gbm],
 648          [enable gbm library @<:@default=auto@:>@])],
 649    [enable_gbm="$enableval"],
 650    [enable_gbm=auto])
 651
 652 AC_ARG_ENABLE([xvmc],
 653    [AS_HELP_STRING([--enable-xvmc],
 654          [enable xvmc library @<:@default=auto@:>@])],
 655    [enable_xvmc="$enableval"],
 656    [enable_xvmc=no])
 657 AC_ARG_ENABLE([vdpau],
 658    [AS_HELP_STRING([--enable-vdpau],
 659          [enable vdpau library @<:@default=auto@:>@])],
 660    [enable_vdpau="$enableval"],
 661    [enable_vdpau=auto])
 662 AC_ARG_ENABLE([omx],
 663    [AS_HELP_STRING([--enable-omx],
 664          [enable OpenMAX library @<:@default=no@:>@])],
 665    [enable_omx="$enableval"],
 666    [enable_omx=no])
 667 AC_ARG_ENABLE([opencl],
 668    [AS_HELP_STRING([--enable-opencl],
 669          [enable OpenCL library @<:@default=no@:>@])],
 670    [enable_opencl="$enableval"],
 671    [enable_opencl=no])
 672 AC_ARG_ENABLE([opencl_icd],
 673    [AS_HELP_STRING([--enable-opencl-icd],
 674           [Build an OpenCL ICD library to be loaded by an ICD implementation
 675            @<:@default=no@:>@])],
 676     [enable_opencl_icd="$enableval"],
 677     [enable_opencl_icd=no])
 678 AC_ARG_ENABLE([xlib-glx],
 679     [AS_HELP_STRING([--enable-xlib-glx],
 680         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 681     [enable_xlib_glx="$enableval"],
 682     [enable_xlib_glx=no])
 683 AC_ARG_ENABLE([gallium-egl],
 684     [AS_HELP_STRING([--enable-gallium-egl],
 685         [enable optional EGL state tracker (not required
 686          for EGL support in Gallium with OpenGL and OpenGL ES)
 687          @<:@default=disable@:>@])],
 688     [enable_gallium_egl="$enableval"],
 689     [enable_gallium_egl=no])
 690 AC_ARG_ENABLE([gallium-gbm],
 691     [AS_HELP_STRING([--enable-gallium-gbm],
 692         [enable optional gbm state tracker (not required for
 693          gbm support in Gallium)
 694          @<:@default=auto@:>@])],
 695     [enable_gallium_gbm="$enableval"],
 696     [enable_gallium_gbm=auto])
 697
 698 AC_ARG_ENABLE([r600-llvm-compiler],
 699     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 700         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 701     [enable_r600_llvm="$enableval"],
 702     [enable_r600_llvm=no])
 703
 704 AC_ARG_ENABLE([gallium-tests],
 705     [AS_HELP_STRING([--enable-gallium-tests],
 706         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 707     [enable_gallium_tests="$enableval"],
 708     [enable_gallium_tests=no])
 709
 710 # Option for Gallium drivers
 711
 712 # Keep this in sync with the --with-gallium-drivers help string default value
 713 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 714
 715 AC_ARG_WITH([gallium-drivers],
 716     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 717         [comma delimited Gallium drivers list, e.g.
 718         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 719         @<:@default=r300,r600,svga,swrast@:>@])],
 720     [with_gallium_drivers="$withval"],
 721     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 722
 723 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 724 # here so that the script doesn't choke on an unknown driver name later.
 725 case "$with_gallium_drivers" in
 726     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 727     no) with_gallium_drivers='' ;;
 728 esac
 729
 730 if test "x$enable_opengl" = xno -a \
 731         "x$enable_gles1" = xno -a \
 732         "x$enable_gles2" = xno -a \
 733         "x$enable_openvg" = xno -a \
 734         "x$enable_xa" = xno -a \
 735         "x$enable_xvmc" = xno -a \
 736         "x$enable_vdpau" = xno -a \
 737         "x$enable_omx" = xno -a \
 738         "x$enable_opencl" = xno; then
 739     AC_MSG_ERROR([at least one API should be enabled])
 740 fi
 741
 742 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 743 if test "x$enable_opengl" = xno -a \
 744         "x$enable_gles1" = xyes; then
 745     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 746 fi
 747
 748 if test "x$enable_opengl" = xno -a \
 749         "x$enable_gles2" = xyes; then
 750     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 751 fi
 752
 753 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 754 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 755 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 756 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 757                                         "x$enable_gles1" = xyes -o \
 758                                         "x$enable_gles2" = xyes)
 759
 760 if test "x$enable_glx" = xno; then
 761     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 762     enable_xlib_glx=no
 763 fi
 764
 765 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 766     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 767 fi
 768
 769 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 770     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 771 fi
 772
 773 # Disable GLX if OpenGL is not enabled
 774 if test "x$enable_glx$enable_opengl" = xyesno; then
 775     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 776     enable_glx=no
 777 fi
 778
 779 # Disable GLX if DRI and Xlib-GLX are not enabled
 780 if test "x$enable_glx" = xyes -a \
 781         "x$enable_dri" = xno -a \
 782         "x$enable_xlib_glx" = xno; then
 783     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 784     enable_glx=no
 785 fi
 786
 787 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 788                                   "x$enable_dri" = xyes)
 789
 790 # Select which platform-dependent DRI code gets built
 791 case "$host_os" in
 792 darwin*)
 793     dri_platform='apple' ;;
 794 gnu*|mingw*|cygwin*)
 795     dri_platform='none' ;;
 796 *)
 797     dri_platform='drm' ;;
 798 esac
 799
 800 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 801 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 802 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 803 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 804 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 805
 806 AC_ARG_ENABLE([shared-glapi],
 807     [AS_HELP_STRING([--enable-shared-glapi],
 808         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 809     [enable_shared_glapi="$enableval"],
 810     [enable_shared_glapi=yes])
 811
 812 case "x$enable_opengl$enable_gles1$enable_gles2" in
 813 x*yes*yes*)
 814     if test "x$enable_shared_glapi" = xno; then
 815         AC_MSG_ERROR([shared GLAPI required when building two or more of
 816                       the following APIs - opengl, gles1 gles2])
 817     fi
 818     ;;
 819 esac
 820
 821 # Building Xlib-GLX requires shared glapi to be disabled.
 822 if test "x$enable_xlib_glx" = xyes; then
 823     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 824     enable_shared_glapi=no
 825 fi
 826
 827 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 828
 829 dnl
 830 dnl Driver specific build directories
 831 dnl
 832 GALLIUM_TARGET_DIRS=""
 833 GALLIUM_WINSYS_DIRS="sw"
 834 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 835 GALLIUM_STATE_TRACKERS_DIRS=""
 836
 837 case "x$enable_glx$enable_xlib_glx" in
 838 xyesyes)
 839     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 840     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 841     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 842     NEED_WINSYS_XLIB="yes"
 843     ;;
 844 esac
 845
 846 if test "x$enable_dri" = xyes; then
 847     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 848     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 849 fi
 850
 851 if test "x$enable_gallium_osmesa" = xyes; then
 852     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 853         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 854     fi
 855     if test "x$enable_osmesa" = xyes; then
 856         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 857     fi
 858     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 859     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 860 fi
 861
 862 AC_SUBST([MESA_LLVM])
 863
 864 # Check for libdrm
 865 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 866                   [have_libdrm=yes], [have_libdrm=no])
 867 if test "x$have_libdrm" = xyes; then
 868         DEFINES="$DEFINES -DHAVE_LIBDRM"
 869 fi
 870
 871 case "$host_os" in
 872 linux*)
 873     need_pci_id=yes ;;
 874 *)
 875     need_pci_id=no ;;
 876 esac
 877
 878 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 879                   have_libudev=yes, have_libudev=no)
 880
 881 AC_ARG_ENABLE([sysfs],
 882     [AS_HELP_STRING([--enable-sysfs],
 883         [enable /sys PCI identification @<:@default=disabled@:>@])],
 884     [have_sysfs="$enableval"],
 885     [have_sysfs=no]
 886 )
 887
 888 if test "x$enable_dri" = xyes; then
 889     if test "$enable_static" = yes; then
 890         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 891     fi
 892
 893     # not a hard requirement as swrast does not depend on it
 894     if test "x$have_libdrm" = xyes; then
 895         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 896     fi
 897 fi
 898
 899 dnl Direct rendering or just indirect rendering
 900 case "$host_os" in
 901 gnu*)
 902     dnl Disable by default on GNU/Hurd
 903     driglx_direct_default="no"
 904     ;;
 905 cygwin*)
 906     dnl Disable by default on cygwin
 907     driglx_direct_default="no"
 908     ;;
 909 *)
 910     driglx_direct_default="yes"
 911     ;;
 912 esac
 913 AC_ARG_ENABLE([driglx-direct],
 914     [AS_HELP_STRING([--disable-driglx-direct],
 915         [disable direct rendering in GLX and EGL for DRI \
 916             @<:@default=auto@:>@])],
 917     [driglx_direct="$enableval"],
 918     [driglx_direct="$driglx_direct_default"])
 919
 920 dnl
 921 dnl libGL configuration per driver
 922 dnl
 923 case "x$enable_glx$enable_xlib_glx" in
 924 xyesyes)
 925     # Xlib-based GLX
 926     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 927     GL_PC_REQ_PRIV="x11 xext"
 928     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 929     GL_LIB_DEPS="$XLIBGL_LIBS"
 930     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 931     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 932     ;;
 933 xyesno)
 934     # DRI-based GLX
 935     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 936
 937     # find the DRI deps for libGL
 938     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 939
 940     if test x"$driglx_direct" = xyes; then
 941         if test x"$dri_platform" = xdrm ; then
 942             if test "x$have_libdrm" != xyes; then
 943                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 944             fi
 945
 946             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 947             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 948             if test x"$enable_dri3" = xyes; then
 949                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 950                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 951             fi
 952
 953             if test x"$enable_dri" = xyes; then
 954                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 955             fi
 956
 957             if test x"$enable_dri3" = xyes; then
 958                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 959             fi
 960         fi
 961         if test x"$dri_platform" = xapple ; then
 962             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 963         fi
 964     fi
 965
 966     # add xf86vidmode if available
 967     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 968     if test "$HAVE_XF86VIDMODE" = yes ; then
 969         dri_modules="$dri_modules xxf86vm"
 970     fi
 971
 972     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 973     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 974     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 975     GL_LIB_DEPS="$DRIGL_LIBS"
 976
 977     # need DRM libs, $PTHREAD_LIBS, etc.
 978     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 979     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 980     ;;
 981 esac
 982
 983 have_pci_id=no
 984 if test "$have_libudev" = yes; then
 985     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 986     have_pci_id=yes
 987 fi
 988
 989 if test "$have_sysfs" = yes; then
 990     DEFINES="$DEFINES -DHAVE_SYSFS"
 991     have_pci_id=yes
 992 fi
 993
 994 # This is outside the case (above) so that it is invoked even for non-GLX
 995 # builds.
 996 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 997
 998 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 999 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1000 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1001 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1002
1003 AC_SUBST([X11_INCLUDES])
1004 AC_SUBST([GL_LIB_DEPS])
1005 AC_SUBST([GL_PC_REQ_PRIV])
1006 AC_SUBST([GL_PC_LIB_PRIV])
1007 AC_SUBST([GL_PC_CFLAGS])
1008 AC_SUBST([DRI_PC_REQ_PRIV])
1009 AC_SUBST([GLESv1_CM_LIB_DEPS])
1010 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1011 AC_SUBST([GLESv2_LIB_DEPS])
1012 AC_SUBST([GLESv2_PC_LIB_PRIV])
1013
1014 AC_SUBST([HAVE_XF86VIDMODE])
1015
1016 dnl
1017 dnl More GLX setup
1018 dnl
1019 case "x$enable_glx$enable_xlib_glx" in
1020 xyesyes)
1021     DEFINES="$DEFINES -DUSE_XSHM"
1022     ;;
1023 xyesno)
1024     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1025     if test "x$driglx_direct" = xyes; then
1026         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1027     fi
1028     ;;
1029 esac
1030
1031 dnl
1032 dnl TLS detection
1033 dnl
1034
1035 AC_ARG_ENABLE([glx-tls],
1036     [AS_HELP_STRING([--enable-glx-tls],
1037         [enable TLS support in GLX @<:@default=disabled@:>@])],
1038     [GLX_USE_TLS="$enableval"],
1039     [GLX_USE_TLS=no])
1040 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1041
1042 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1043       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1044
1045 dnl
1046 dnl More DRI setup
1047 dnl
1048 dnl Directory for DRI drivers
1049 AC_ARG_WITH([dri-driverdir],
1050     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1051         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1052     [DRI_DRIVER_INSTALL_DIR="$withval"],
1053     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1054 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1055 dnl Extra search path for DRI drivers
1056 AC_ARG_WITH([dri-searchpath],
1057     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1058         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1059     [DRI_DRIVER_SEARCH_DIR="$withval"],
1060     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1061 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1062 dnl Which drivers to build - default is chosen by platform
1063 AC_ARG_WITH([dri-drivers],
1064     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1065         [comma delimited classic DRI drivers list, e.g.
1066         "swrast,i965,radeon" @<:@default=auto@:>@])],
1067     [with_dri_drivers="$withval"],
1068     [with_dri_drivers=auto])
1069
1070 if test "x$with_dri_drivers" = xauto; then
1071     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1072         with_dri_drivers="yes"
1073     else
1074         with_dri_drivers="no"
1075     fi
1076 fi
1077 if test "x$with_dri_drivers" = xno; then
1078     with_dri_drivers=''
1079 fi
1080
1081 dnl If $with_dri_drivers is yes, drivers will be added through
1082 dnl platform checks. Set DEFINES and LIB_DEPS
1083 if test "x$enable_dri" = xyes; then
1084     # Platform specific settings and drivers to build
1085     case "$host_os" in
1086     linux*)
1087         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1088         DEFINES="$DEFINES -DHAVE_ALIAS"
1089         if test "x$enable_dri3" = xyes; then
1090             DEFINES="$DEFINES -DHAVE_DRI3"
1091         fi
1092
1093         if test "x$have_pci_id" != xyes; then
1094             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1095         fi
1096
1097         case "$host_cpu" in
1098         powerpc* | sparc*)
1099             # Build only the drivers for cards that exist on PowerPC/sparc
1100             if test "x$with_dri_drivers" = "xyes"; then
1101                 with_dri_drivers="r200 radeon swrast"
1102             fi
1103             ;;
1104         esac
1105         ;;
1106     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1107         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1108         DEFINES="$DEFINES -DHAVE_ALIAS"
1109         ;;
1110     gnu*)
1111         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1112         DEFINES="$DEFINES -DHAVE_ALIAS"
1113         ;;
1114     solaris*)
1115         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1116         ;;
1117     cygwin*)
1118         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1119         if test "x$with_dri_drivers" = "xyes"; then
1120             with_dri_drivers="swrast"
1121         fi
1122         ;;
1123     darwin*)
1124         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DGLX_ALIAS_UNSUPPORTED"
1125         if test "x$with_dri_drivers" = "xyes"; then
1126             with_dri_drivers="swrast"
1127         fi
1128         ;;
1129     esac
1130
1131     # default drivers
1132     if test "x$with_dri_drivers" = "xyes"; then
1133         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1134     fi
1135
1136     # Check for expat
1137     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1138     if test "x$have_expat" = "xyes"; then
1139        PKG_CHECK_MODULES([EXPAT], [expat], [],
1140                          AC_MSG_ERROR([Expat required for DRI.]))
1141     else
1142        # expat version 2.0 and earlier do not provide expat.pc
1143        EXPAT_LIBS=-lexpat
1144     fi
1145
1146     # If we are building any DRI driver other than swrast.
1147     if test -n "$with_dri_drivers"; then
1148         if test "x$with_dri_drivers" != xswrast; then
1149             # ... libdrm is required
1150             if test "x$have_libdrm" != xyes; then
1151                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1152             fi
1153             DRICOMMON_NEED_LIBDRM=yes
1154         else
1155             DRICOMMON_NEED_LIBDRM=no
1156         fi
1157     fi
1158
1159     # put all the necessary libs together
1160     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1161 fi
1162
1163 AC_SUBST([DRI_LIB_DEPS])
1164
1165 DRI_DIRS=''
1166 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1167 if test -n "$with_dri_drivers"; then
1168     if test "x$enable_opengl" != xyes; then
1169         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1170     fi
1171
1172     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1173     for driver in $dri_drivers; do
1174         DRI_DIRS="$DRI_DIRS $driver"
1175         case "x$driver" in
1176         xi915)
1177             HAVE_I915_DRI=yes;
1178             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1179             ;;
1180         xi965)
1181             HAVE_I965_DRI=yes;
1182             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1183             ;;
1184         xnouveau)
1185             HAVE_NOUVEAU_DRI=yes;
1186             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1187             ;;
1188         xradeon)
1189             HAVE_RADEON_DRI=yes;
1190             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1191             ;;
1192         xr200)
1193             HAVE_R200_DRI=yes;
1194             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1195             ;;
1196         xswrast)
1197             HAVE_SWRAST_DRI=yes;
1198             ;;
1199         *)
1200             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1201             ;;
1202         esac
1203     done
1204     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1205 fi
1206
1207 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1208 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1209                                   "x$enable_osmesa" = xyes -o \
1210                                   -n "$DRI_DIRS")
1211
1212 dnl
1213 dnl OSMesa configuration
1214 dnl
1215
1216 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1217 AC_ARG_WITH([osmesa-bits],
1218     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1219         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1220     [osmesa_bits="$withval"],
1221     [osmesa_bits=8])
1222 if test "x$osmesa_bits" != x8; then
1223     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1224         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1225         osmesa_bits=8
1226     fi
1227 fi
1228 case "x$osmesa_bits" in
1229 x8)
1230     OSMESA_LIB="${OSMESA_LIB}"
1231     ;;
1232 x16|x32)
1233     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1234     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1235     ;;
1236 *)
1237     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1238     ;;
1239 esac
1240
1241 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1242     # only link libraries with osmesa if shared
1243     if test "$enable_static" = no; then
1244         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1245     else
1246         OSMESA_LIB_DEPS=""
1247     fi
1248     OSMESA_MESA_DEPS=""
1249     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1250 fi
1251
1252 AC_SUBST([OSMESA_LIB_DEPS])
1253 AC_SUBST([OSMESA_MESA_DEPS])
1254 AC_SUBST([OSMESA_PC_REQ])
1255 AC_SUBST([OSMESA_PC_LIB_PRIV])
1256
1257 dnl
1258 dnl gbm configuration
1259 dnl
1260 if test "x$enable_gbm" = xauto; then
1261     case "$with_egl_platforms" in
1262         *drm*)
1263             enable_gbm=yes ;;
1264          *)
1265             enable_gbm=no ;;
1266     esac
1267 fi
1268 if test "x$enable_gbm" = xyes; then
1269     if test "x$need_pci_id$have_pci_id" = xyesno; then
1270         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1271     fi
1272
1273     if test "x$enable_dri" = xyes; then
1274         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1275         if test "x$enable_shared_glapi" = xno; then
1276             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1277         fi
1278     else
1279         # Strictly speaking libgbm does not require --enable-dri, although
1280         # both of its backends do. Thus one can build libgbm without any
1281         # backends if --disable-dri is set.
1282         # To avoid unnecessary complexity of checking if at least one backend
1283         # is available when building, just mandate --enable-dri.
1284         AC_MSG_ERROR([gbm requires --enable-dri])
1285     fi
1286 fi
1287 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1288 if test "x$need_pci_id$have_libudev" = xyesyes; then
1289     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1290 else
1291     GBM_PC_REQ_PRIV=""
1292 fi
1293 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1294 AC_SUBST([GBM_PC_REQ_PRIV])
1295 AC_SUBST([GBM_PC_LIB_PRIV])
1296
1297 dnl
1298 dnl EGL configuration
1299 dnl
1300 EGL_CLIENT_APIS=""
1301
1302 if test "x$enable_egl" = xyes; then
1303     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1304
1305     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1306
1307     if test "$enable_static" != yes; then
1308         if test "x$enable_dri" = xyes; then
1309             HAVE_EGL_DRIVER_DRI2=1
1310         fi
1311
1312     fi
1313 fi
1314 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1315 AC_SUBST([EGL_LIB_DEPS])
1316
1317 dnl
1318 dnl EGL Gallium configuration
1319 dnl
1320 if test "x$enable_gallium_egl" = xyes; then
1321     if test -z "$with_gallium_drivers"; then
1322         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1323     fi
1324     if test "x$enable_egl" = xno; then
1325         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1326     fi
1327     if test "x$have_libdrm" != xyes; then
1328         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1329     fi
1330
1331     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1332     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1333 fi
1334 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1335
1336 dnl
1337 dnl gbm Gallium configuration
1338 dnl
1339 if test "x$enable_gallium_gbm" = xauto; then
1340     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1341         yesyesyes*drm*)
1342             enable_gallium_gbm=yes ;;
1343          *)
1344             enable_gallium_gbm=no ;;
1345     esac
1346 fi
1347 if test "x$enable_gallium_gbm" = xyes; then
1348     if test -z "$with_gallium_drivers"; then
1349         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1350     fi
1351     if test "x$enable_gbm" = xno; then
1352         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1353     fi
1354     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1355     if test "x$enable_dri" = xno; then
1356         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1357     fi
1358
1359     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1360     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1361     enable_gallium_loader=yes
1362 fi
1363 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1364
1365 dnl
1366 dnl XA configuration
1367 dnl
1368 if test "x$enable_xa" = xyes; then
1369     if test "x$with_gallium_drivers" = xswrast; then
1370        AC_MSG_ERROR([
1371           Building xa requires at least one non swrast gallium driver.
1372           If you are looking to use libxatracker.so with vmware's virtual gpu,
1373           make sure to include svga in the gallium drivers list, apart from
1374           enabling XA.
1375           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1376     fi
1377     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1378     enable_gallium_loader=yes
1379 fi
1380 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1381
1382 dnl
1383 dnl OpenVG configuration
1384 dnl
1385 VG_LIB_DEPS=""
1386
1387 if test "x$enable_openvg" = xyes; then
1388     if test "x$enable_egl" = xno; then
1389         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1390     fi
1391     if test -z "$with_gallium_drivers"; then
1392         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1393     fi
1394     if test "x$enable_gallium_egl" = xno; then
1395         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1396     fi
1397
1398     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1399     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1400     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1401     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1402     AC_SUBST([VG_PC_LIB_PRIV])
1403 fi
1404 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1405
1406 dnl
1407 dnl Gallium G3DVL configuration
1408 dnl
1409 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1410     if test "x$enable_xvmc" = xauto; then
1411         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1412     fi
1413
1414     if test "x$enable_vdpau" = xauto; then
1415         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1416     fi
1417
1418     if test "x$enable_omx" = xauto; then
1419         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1420     fi
1421 fi
1422
1423 if test "x$enable_xvmc" = xyes; then
1424     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1425     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1426 fi
1427 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1428
1429 if test "x$enable_vdpau" = xyes; then
1430     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1431                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1432     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1433 fi
1434 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1435
1436 if test "x$enable_omx" = xyes; then
1437     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1438     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1439 fi
1440 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1441
1442 dnl
1443 dnl OpenCL configuration
1444 dnl
1445
1446 AC_ARG_WITH([libclc-path],
1447    [AS_HELP_STRING([--with-libclc-path],
1448          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1449    [LIBCLC_PATH="$withval"],
1450    [LIBCLC_PATH=''])
1451
1452 if test -n "$LIBCLC_PATH"; then
1453    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1454                   Please review the updated build instructions for clover:
1455                   http://dri.freedesktop.org/wiki/GalliumCompute])
1456 fi
1457
1458
1459 AC_ARG_WITH([clang-libdir],
1460    [AS_HELP_STRING([--with-clang-libdir],
1461          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1462    [CLANG_LIBDIR="$withval"],
1463    [CLANG_LIBDIR=''])
1464
1465 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1466
1467 if test "x$enable_opencl" = xyes; then
1468     if test -z "$with_gallium_drivers"; then
1469         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1470     fi
1471
1472     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1473         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1474     fi
1475
1476     if test "x$have_libclc" = xno; then
1477         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1478                     Make sure the directory containing libclc.pc is specified in your
1479                     PKG_CONFIG_PATH environment variable.
1480                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1481     else
1482         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1483         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1484         AC_SUBST([LIBCLC_INCLUDEDIR])
1485         AC_SUBST([LIBCLC_LIBEXECDIR])
1486     fi
1487
1488     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1489     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1490     enable_gallium_loader=yes
1491
1492     if test "x$enable_opencl_icd" = xyes; then
1493         OPENCL_LIBNAME="MesaOpenCL"
1494     else
1495         OPENCL_LIBNAME="OpenCL"
1496     fi
1497 fi
1498 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1499 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1500 AC_SUBST([OPENCL_LIBNAME])
1501
1502 dnl
1503 dnl Gallium configuration
1504 dnl
1505 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1506
1507 AC_SUBST([LLVM_BINDIR])
1508 AC_SUBST([LLVM_CFLAGS])
1509 AC_SUBST([LLVM_CPPFLAGS])
1510 AC_SUBST([LLVM_CXXFLAGS])
1511 AC_SUBST([LLVM_LIBDIR])
1512 AC_SUBST([LLVM_LIBS])
1513 AC_SUBST([LLVM_LDFLAGS])
1514 AC_SUBST([LLVM_INCLUDEDIR])
1515 AC_SUBST([LLVM_VERSION])
1516 AC_SUBST([CLANG_RESOURCE_DIR])
1517
1518 case "x$enable_opengl$enable_gles1$enable_gles2" in
1519 x*yes*)
1520     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1521     ;;
1522 esac
1523
1524 AC_SUBST([VG_LIB_DEPS])
1525 AC_SUBST([EGL_CLIENT_APIS])
1526
1527 dnl
1528 dnl EGL Platforms configuration
1529 dnl
1530 AC_ARG_WITH([egl-platforms],
1531     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1532         [comma delimited native platforms libEGL supports, e.g.
1533         "x11,drm" @<:@default=auto@:>@])],
1534     [with_egl_platforms="$withval"],
1535     [if test "x$enable_egl" = xyes; then
1536         with_egl_platforms="x11"
1537     else
1538         with_egl_platforms=""
1539     fi])
1540
1541 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1542     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1543 fi
1544
1545 # Do per-EGL platform setups and checks
1546 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1547 for plat in $egl_platforms; do
1548         case "$plat" in
1549         wayland)
1550                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1551                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1552
1553                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1554                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1555                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1556                 ;;
1557
1558         x11)
1559                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1560                 ;;
1561
1562         drm)
1563                 test "x$enable_gbm" = "xno" &&
1564                         AC_MSG_ERROR([EGL platform drm needs gbm])
1565                 test "x$have_libdrm" != xyes &&
1566                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1567                 ;;
1568
1569         android|fbdev|gdi|null)
1570                 ;;
1571
1572         *)
1573                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1574                 ;;
1575         esac
1576
1577         case "$plat$need_pci_id$have_pci_id" in
1578                 waylandyesno|drmyesno)
1579                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1580         esac
1581 done
1582
1583 # libEGL wants to default to the first platform specified in
1584 # ./configure.  parse that here.
1585 if test "x$egl_platforms" != "x"; then
1586     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1587     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1588 else
1589     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1590 fi
1591
1592 if echo "$egl_platforms" | grep -q 'x11'; then
1593     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1594     NEED_WINSYS_XLIB=yes
1595 fi
1596 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1597 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1598 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1599 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1600 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1601
1602 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1603
1604 AC_SUBST([EGL_NATIVE_PLATFORM])
1605 AC_SUBST([EGL_CFLAGS])
1606
1607 # If we don't have the X11 platform, set this define so we don't try to include
1608 # the X11 headers.
1609 if ! echo "$egl_platforms" | grep -q 'x11'; then
1610     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1611     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1612 fi
1613
1614 AC_ARG_WITH([egl-driver-dir],
1615     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1616                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1617     [EGL_DRIVER_INSTALL_DIR="$withval"],
1618     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1619 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1620
1621 AC_ARG_WITH([max-width],
1622     [AS_HELP_STRING([--with-max-width=N],
1623                     [Maximum framebuffer width (4096)])],
1624     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1625      AS_IF([test "${withval}" -gt "4096"],
1626            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1627 )
1628 AC_ARG_WITH([max-height],
1629     [AS_HELP_STRING([--with-max-height=N],
1630                     [Maximum framebuffer height (4096)])],
1631     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1632      AS_IF([test "${withval}" -gt "4096"],
1633            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1634 )
1635
1636 dnl
1637 dnl Gallium LLVM
1638 dnl
1639 AC_ARG_ENABLE([gallium-llvm],
1640     [AS_HELP_STRING([--enable-gallium-llvm],
1641         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1642     [enable_gallium_llvm="$enableval"],
1643     [enable_gallium_llvm=auto])
1644
1645 AC_ARG_ENABLE([llvm-shared-libs],
1646     [AS_HELP_STRING([--enable-llvm-shared-libs],
1647         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1648     [enable_llvm_shared_libs="$enableval"],
1649     [enable_llvm_shared_libs=yes])
1650
1651 AC_ARG_WITH([llvm-prefix],
1652     [AS_HELP_STRING([--with-llvm-prefix],
1653         [Prefix for LLVM installations in non-standard locations])],
1654     [llvm_prefix="$withval"],
1655     [llvm_prefix=''])
1656
1657
1658 # Call this inside ` ` to get the return value.
1659 # $1 is the llvm-config command with arguments.
1660 strip_unwanted_llvm_flags() {
1661     # Use \> (marks the end of the word)
1662     echo `$1` | sed \
1663         -e 's/-DNDEBUG\>//g' \
1664         -e 's/-pedantic\>//g' \
1665         -e 's/-Wcovered-switch-default\>//g' \
1666         -e 's/-O.\>//g' \
1667         -e 's/-g\>//g' \
1668         -e 's/-Wall\>//g' \
1669         -e 's/-Wcast-qual\>//g' \
1670         -e 's/-Woverloaded-virtual\>//g' \
1671         -e 's/-fcolor-diagnostics\>//g' \
1672         -e 's/-fdata-sections\>//g' \
1673         -e 's/-ffunction-sections\>//g' \
1674         -e 's/-fno-exceptions\>//g' \
1675         -e 's/-fomit-frame-pointer\>//g' \
1676         -e 's/-fvisibility-inlines-hidden\>//g' \
1677         -e 's/-fPIC\>//g' \
1678         -e 's/-fstack-protector-strong\>//g'
1679 }
1680
1681
1682 if test -z "$with_gallium_drivers"; then
1683     enable_gallium_llvm=no
1684 fi
1685 if test "x$enable_gallium_llvm" = xauto; then
1686     case "$host_cpu" in
1687     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1688     esac
1689 fi
1690 if test "x$enable_gallium_llvm" = xyes; then
1691     if test -n "$llvm_prefix"; then
1692         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1693     else
1694         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1695     fi
1696
1697     if test "x$LLVM_CONFIG" != xno; then
1698         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1699         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1700         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1701         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1702         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1703         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1704         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1705         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1706
1707         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1708             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1709         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1710             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1711
1712         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1713         dnl llvm-config.h
1714         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1715             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1716             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1717
1718         if test -n "${LLVM_VERSION_MAJOR}"; then
1719             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1720         else
1721             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1722         fi
1723
1724         LLVM_REQUIRED_VERSION_MAJOR="3"
1725         LLVM_REQUIRED_VERSION_MINOR="1"
1726         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1727             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1728         fi
1729
1730         LLVM_COMPONENTS="engine bitwriter"
1731         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1732             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1733         fi
1734
1735         if test "x$enable_opencl" = xyes; then
1736             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1737             # LLVM 3.3 >= 177971 requires IRReader
1738             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1739                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1740             fi
1741             # LLVM 3.4 requires Option
1742             if $LLVM_CONFIG --components | grep -qw 'option'; then
1743                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1744             fi
1745             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1746             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1747                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1748             fi
1749             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1750                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1751             fi
1752         fi
1753         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1754         MESA_LLVM=1
1755
1756         dnl Check for Clang internal headers
1757         if test "x$enable_opencl" = xyes; then
1758             if test -z "$CLANG_LIBDIR"; then
1759                 CLANG_LIBDIR=${LLVM_LIBDIR}
1760             fi
1761             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1762             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1763                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1764         fi
1765     else
1766         MESA_LLVM=0
1767         LLVM_VERSION_INT=0
1768     fi
1769 else
1770     MESA_LLVM=0
1771     LLVM_VERSION_INT=0
1772 fi
1773
1774 dnl Directory for XVMC libs
1775 AC_ARG_WITH([xvmc-libdir],
1776     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1777         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1778     [XVMC_LIB_INSTALL_DIR="$withval"],
1779     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1780 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1781
1782 dnl
1783 dnl Gallium Tests
1784 dnl
1785 if test "x$enable_gallium_tests" = xyes; then
1786     enable_gallium_loader=yes
1787 fi
1788 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1789
1790 if test "x$enable_gallium_loader" = xyes; then
1791     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1792 fi
1793 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1794
1795 dnl Directory for VDPAU libs
1796 AC_ARG_WITH([vdpau-libdir],
1797     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1798         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1799     [VDPAU_LIB_INSTALL_DIR="$withval"],
1800     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1801 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1802
1803 OMX_LIB_INSTALL_DIR_DEFAULT=''
1804 if test "x$enable_omx" = xyes; then
1805     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1806 fi
1807
1808 AC_ARG_WITH([omx-libdir],
1809     [AS_HELP_STRING([--with-omx-libdir=DIR],
1810         [directory for the OMX libraries])],
1811     [OMX_LIB_INSTALL_DIR="$withval"],
1812     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1813 AC_SUBST([OMX_LIB_INSTALL_DIR])
1814
1815 dnl Directory for OpenCL libs
1816 AC_ARG_WITH([opencl-libdir],
1817     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1818         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1819     [OPENCL_LIB_INSTALL_DIR="$withval"],
1820     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1821 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1822
1823 dnl
1824 dnl Gallium helper functions
1825 dnl
1826 gallium_check_st() {
1827     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1828          if test "x$have_libdrm" != xyes; then
1829             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1830          fi
1831          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1832     fi
1833     if test "x$enable_dri" = xyes && test -n "$2"; then
1834          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1835     fi
1836     if test "x$enable_xa" = xyes && test -n "$3"; then
1837          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1838     fi
1839     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1840          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1841     fi
1842     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1843          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1844     fi
1845     if test "x$enable_omx" = xyes && test "x$6" != x; then
1846          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1847     fi
1848 }
1849
1850 gallium_require_llvm() {
1851     if test "x$MESA_LLVM" = x0; then
1852         case "$host_cpu" in
1853         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1854         esac
1855     fi
1856 }
1857
1858 gallium_require_drm_loader() {
1859     if test "x$enable_gallium_loader" = xyes; then
1860         if test "x$need_pci_id$have_pci_id" = xyesno; then
1861             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1862         fi
1863         if test "x$have_libdrm" != xyes; then
1864             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1865         fi
1866         enable_gallium_drm_loader=yes
1867     fi
1868 }
1869
1870 require_egl_drm() {
1871     case "$with_egl_platforms" in
1872         *drm*)
1873             ;;
1874          *)
1875             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1876             ;;
1877     esac
1878     if test "x$enable_gbm" != xyes; then
1879             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1880     fi
1881 }
1882
1883 radeon_llvm_check() {
1884     if test "x$enable_gallium_llvm" != "xyes"; then
1885         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1886     fi
1887     LLVM_REQUIRED_VERSION_MAJOR="3"
1888     LLVM_REQUIRED_VERSION_MINOR="3"
1889     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1890         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1891     fi
1892     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1893         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1894                       sources with the --enable-experimental-targets=R600
1895                       configure flag])
1896     fi
1897     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1898     NEED_RADEON_LLVM=yes
1899     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1900                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1901 }
1902
1903 dnl Gallium drivers
1904 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1905         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1906     NEED_NONNULL_WINSYS=yes
1907 fi
1908 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1909
1910 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1911 if test -n "$with_gallium_drivers"; then
1912     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1913     for driver in $gallium_drivers; do
1914         case "x$driver" in
1915         xsvga)
1916             HAVE_GALLIUM_SVGA=yes
1917             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1918             gallium_require_drm_loader
1919             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1920             ;;
1921         xi915)
1922             HAVE_GALLIUM_I915=yes
1923             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1924             gallium_require_drm_loader
1925             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1926             if test "x$MESA_LLVM" = x1; then
1927                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1928             fi
1929             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1930             gallium_check_st "i915/drm" "dri-i915"
1931             DRICOMMON_NEED_LIBDRM=yes
1932             ;;
1933         xilo)
1934             HAVE_GALLIUM_ILO=yes
1935             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1936             gallium_require_drm_loader
1937             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1938             gallium_check_st "intel/drm" "dri-ilo"
1939             DRICOMMON_NEED_LIBDRM=yes
1940             ;;
1941         xr300)
1942             HAVE_GALLIUM_R300=yes
1943             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1944             gallium_require_drm_loader
1945             gallium_require_llvm "Gallium R300"
1946             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1947             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1948             DRICOMMON_NEED_LIBDRM=yes
1949             ;;
1950         xr600)
1951             HAVE_GALLIUM_R600=yes
1952             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1953             gallium_require_drm_loader
1954             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1955             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1956                 radeon_llvm_check "r600g"
1957                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1958             fi
1959             if test "x$enable_r600_llvm" = xyes; then
1960                 USE_R600_LLVM_COMPILER=yes;
1961             fi
1962             if test "x$enable_opencl" = xyes; then
1963                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1964             fi
1965             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1966             DRICOMMON_NEED_LIBDRM=yes
1967             ;;
1968         xradeonsi)
1969             HAVE_GALLIUM_RADEONSI=yes
1970             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1971             gallium_require_drm_loader
1972             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1973             radeon_llvm_check "radeonsi"
1974             require_egl_drm "radeonsi"
1975             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1976             DRICOMMON_NEED_LIBDRM=yes
1977             ;;
1978         xnouveau)
1979             HAVE_GALLIUM_NOUVEAU=yes
1980             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1981             gallium_require_drm_loader
1982             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1983             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1984             DRICOMMON_NEED_LIBDRM=yes
1985             ;;
1986         xfreedreno)
1987             HAVE_GALLIUM_FREEDRENO=yes
1988             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1989             gallium_require_drm_loader
1990             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1991             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1992             DRICOMMON_NEED_LIBDRM=yes
1993             ;;
1994         xswrast)
1995             HAVE_GALLIUM_SOFTPIPE=yes
1996             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1997             if test "x$MESA_LLVM" = x1; then
1998                 HAVE_GALLIUM_LLVMPIPE=yes
1999                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2000             fi
2001
2002             if test "x$enable_dri" = xyes; then
2003                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2004             fi
2005             ;;
2006         *)
2007             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2008             ;;
2009         esac
2010     done
2011 fi
2012
2013 dnl Set LLVM_LIBS - This is done after the driver configuration so
2014 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2015 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2016 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2017 dnl this was causing the same libraries to be appear multiple times
2018 dnl in LLVM_LIBS.
2019
2020 if test "x$MESA_LLVM" != x0; then
2021
2022     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2023
2024     if test "x$enable_llvm_shared_libs" = xyes; then
2025         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2026         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2027         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2028
2029         if test "x$llvm_have_one_so" = xyes; then
2030             dnl LLVM was built using auto*, so there is only one shared object.
2031             LLVM_LIBS="-l$LLVM_SO_NAME"
2032         else
2033             dnl If LLVM was built with CMake, there will be one shared object per
2034             dnl component.
2035             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2036                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2037         Please make sure you have built llvm with the --enable-shared option
2038         and that your llvm libraries are installed in $LLVM_LIBDIR
2039         If you have installed your llvm libraries to a different directory you
2040         can use the --with-llvm-prefix= configure flag to specify this directory.
2041         NOTE: Mesa is attempting to use llvm shared libraries by default.
2042         If you do not want to build with llvm shared libraries and instead want to
2043         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2044         invocation and rebuild.])])
2045
2046            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2047            dnl install uses a shared object for each compoenent and we have
2048            dnl already added all of these objects to LLVM_LIBS.
2049         fi
2050     else
2051         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2052     fi
2053 fi
2054
2055 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2056 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2057 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2058 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2059 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2060 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2061 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2062                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2063 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2064 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2065 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2066 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2067
2068 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2069                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
2070                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2071 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2072                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2073                                                   && test "x$MESA_LLVM" = x1)
2074
2075 # NOTE: anything using xcb or other client side libs ends up in separate
2076 #       _CLIENT variables.  The pipe loader is built in two variants,
2077 #       one that is standalone and does not link any x client libs (for
2078 #       use by XA tracker in particular, but could be used in any case
2079 #       where communication with xserver is not desired).
2080 if test "x$enable_gallium_loader" = xyes; then
2081     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2082
2083     if test "x$NEED_WINSYS_XLIB" = xyes; then
2084         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2085     fi
2086
2087     if test "x$enable_dri" = xyes; then
2088         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2089     fi
2090
2091     if test "x$enable_gallium_drm_loader" = xyes; then
2092         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2093         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2094                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2095         if test "x$pipe_loader_have_xcb" = xyes; then
2096             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2097             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2098         fi
2099     fi
2100
2101     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2102     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2103
2104     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2105     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2106     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2107     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2108 fi
2109
2110 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2111 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2112 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2113 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2114 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2115 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2116
2117 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2118                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2119                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2120                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2121 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2122                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2123 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2124 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2125 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2126 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2127 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2128 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2129 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2130
2131 AC_SUBST([ELF_LIB])
2132
2133 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2134 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2135 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2136 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2137 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2138
2139 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2140 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2141 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2142
2143 AC_SUBST([VDPAU_MAJOR], 1)
2144 AC_SUBST([VDPAU_MINOR], 0)
2145
2146 AC_SUBST([XVMC_MAJOR], 1)
2147 AC_SUBST([XVMC_MINOR], 0)
2148
2149 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2150 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2151 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2152 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2153
2154 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2155 AC_SUBST([XA_MINOR], $XA_MINOR)
2156 AC_SUBST([XA_TINY], $XA_TINY)
2157 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2158
2159 dnl Restore LDFLAGS and CPPFLAGS
2160 LDFLAGS="$_SAVE_LDFLAGS"
2161 CPPFLAGS="$_SAVE_CPPFLAGS"
2162
2163 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2164 if test "x$acv_mesa_CLANG" = xyes; then
2165     CFLAGS="$CFLAGS -Qunused-arguments"
2166     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2167 fi
2168
2169 dnl Add user CFLAGS and CXXFLAGS
2170 CFLAGS="$CFLAGS $USER_CFLAGS"
2171 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2172
2173 dnl Substitute the config
2174 AC_CONFIG_FILES([Makefile
2175                 src/Makefile
2176                 src/egl/drivers/dri2/Makefile
2177                 src/egl/main/Makefile
2178                 src/egl/main/egl.pc
2179                 src/egl/wayland/Makefile
2180                 src/egl/wayland/wayland-drm/Makefile
2181                 src/egl/wayland/wayland-egl/Makefile
2182                 src/egl/wayland/wayland-egl/wayland-egl.pc
2183                 src/gallium/auxiliary/Makefile
2184                 src/gallium/auxiliary/pipe-loader/Makefile
2185                 src/gallium/drivers/Makefile
2186                 src/gallium/drivers/freedreno/Makefile
2187                 src/gallium/drivers/galahad/Makefile
2188                 src/gallium/drivers/i915/Makefile
2189                 src/gallium/drivers/identity/Makefile
2190                 src/gallium/drivers/ilo/Makefile
2191                 src/gallium/drivers/llvmpipe/Makefile
2192                 src/gallium/drivers/noop/Makefile
2193                 src/gallium/drivers/nouveau/Makefile
2194                 src/gallium/drivers/r300/Makefile
2195                 src/gallium/drivers/r600/Makefile
2196                 src/gallium/drivers/radeon/Makefile
2197                 src/gallium/drivers/radeonsi/Makefile
2198                 src/gallium/drivers/rbug/Makefile
2199                 src/gallium/drivers/softpipe/Makefile
2200                 src/gallium/drivers/svga/Makefile
2201                 src/gallium/drivers/trace/Makefile
2202                 src/gallium/state_trackers/Makefile
2203                 src/gallium/state_trackers/clover/Makefile
2204                 src/gallium/state_trackers/dri/Makefile
2205                 src/gallium/state_trackers/dri/drm/Makefile
2206                 src/gallium/state_trackers/dri/sw/Makefile
2207                 src/gallium/state_trackers/egl/Makefile
2208                 src/gallium/state_trackers/gbm/Makefile
2209                 src/gallium/state_trackers/glx/xlib/Makefile
2210                 src/gallium/state_trackers/omx/Makefile
2211                 src/gallium/state_trackers/osmesa/Makefile
2212                 src/gallium/state_trackers/vdpau/Makefile
2213                 src/gallium/state_trackers/vega/Makefile
2214                 src/gallium/state_trackers/xa/Makefile
2215                 src/gallium/state_trackers/xvmc/Makefile
2216                 src/gallium/targets/Makefile
2217                 src/gallium/targets/dri-freedreno/Makefile
2218                 src/gallium/targets/dri-i915/Makefile
2219                 src/gallium/targets/dri-ilo/Makefile
2220                 src/gallium/targets/dri-nouveau/Makefile
2221                 src/gallium/targets/dri-swrast/Makefile
2222                 src/gallium/targets/dri-vmwgfx/Makefile
2223                 src/gallium/targets/egl-static/Makefile
2224                 src/gallium/targets/gbm/Makefile
2225                 src/gallium/targets/opencl/Makefile
2226                 src/gallium/targets/xa/Makefile
2227                 src/gallium/targets/xa/xatracker.pc
2228                 src/gallium/targets/omx-nouveau/Makefile
2229                 src/gallium/targets/osmesa/Makefile
2230                 src/gallium/targets/osmesa/osmesa.pc
2231                 src/gallium/targets/pipe-loader/Makefile
2232                 src/gallium/targets/radeonsi/dri/Makefile
2233                 src/gallium/targets/radeonsi/omx/Makefile
2234                 src/gallium/targets/radeonsi/vdpau/Makefile
2235                 src/gallium/targets/r300/dri/Makefile
2236                 src/gallium/targets/r600/dri/Makefile
2237                 src/gallium/targets/r600/omx/Makefile
2238                 src/gallium/targets/r600/vdpau/Makefile
2239                 src/gallium/targets/r600/xvmc/Makefile
2240                 src/gallium/targets/libgl-xlib/Makefile
2241                 src/gallium/targets/vdpau-nouveau/Makefile
2242                 src/gallium/targets/xvmc-nouveau/Makefile
2243                 src/gallium/tests/trivial/Makefile
2244                 src/gallium/tests/unit/Makefile
2245                 src/gallium/winsys/Makefile
2246                 src/gallium/winsys/freedreno/drm/Makefile
2247                 src/gallium/winsys/i915/drm/Makefile
2248                 src/gallium/winsys/i915/sw/Makefile
2249                 src/gallium/winsys/intel/drm/Makefile
2250                 src/gallium/winsys/nouveau/drm/Makefile
2251                 src/gallium/winsys/radeon/drm/Makefile
2252                 src/gallium/winsys/svga/drm/Makefile
2253                 src/gallium/winsys/sw/dri/Makefile
2254                 src/gallium/winsys/sw/fbdev/Makefile
2255                 src/gallium/winsys/sw/null/Makefile
2256                 src/gallium/winsys/sw/wayland/Makefile
2257                 src/gallium/winsys/sw/wrapper/Makefile
2258                 src/gallium/winsys/sw/xlib/Makefile
2259                 src/gbm/Makefile
2260                 src/gbm/main/gbm.pc
2261                 src/glsl/Makefile
2262                 src/glx/Makefile
2263                 src/glx/apple/Makefile
2264                 src/glx/tests/Makefile
2265                 src/gtest/Makefile
2266                 src/loader/Makefile
2267                 src/mapi/Makefile
2268                 src/mapi/es1api/Makefile
2269                 src/mapi/es1api/glesv1_cm.pc
2270                 src/mapi/es2api/Makefile
2271                 src/mapi/es2api/glesv2.pc
2272                 src/mapi/glapi/Makefile
2273                 src/mapi/glapi/gen/Makefile
2274                 src/mapi/glapi/tests/Makefile
2275                 src/mapi/shared-glapi/Makefile
2276                 src/mapi/shared-glapi/tests/Makefile
2277                 src/mapi/vgapi/Makefile
2278                 src/mapi/vgapi/vg.pc
2279                 src/mesa/Makefile
2280                 src/mesa/gl.pc
2281                 src/mesa/drivers/dri/dri.pc
2282                 src/mesa/drivers/dri/common/Makefile
2283                 src/mesa/drivers/dri/common/xmlpool/Makefile
2284                 src/mesa/drivers/dri/i915/Makefile
2285                 src/mesa/drivers/dri/i965/Makefile
2286                 src/mesa/drivers/dri/Makefile
2287                 src/mesa/drivers/dri/nouveau/Makefile
2288                 src/mesa/drivers/dri/r200/Makefile
2289                 src/mesa/drivers/dri/radeon/Makefile
2290                 src/mesa/drivers/dri/swrast/Makefile
2291                 src/mesa/drivers/osmesa/Makefile
2292                 src/mesa/drivers/osmesa/osmesa.pc
2293                 src/mesa/drivers/x11/Makefile
2294                 src/mesa/main/tests/Makefile
2295                 src/mesa/main/tests/hash_table/Makefile])
2296
2297 dnl Sort the dirs alphabetically
2298 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2299 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2300 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2301 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2302
2303 AC_OUTPUT
2304
2305 dnl
2306 dnl Output some configuration info for the user
2307 dnl
2308 echo ""
2309 echo "        prefix:          $prefix"
2310 echo "        exec_prefix:     $exec_prefix"
2311 echo "        libdir:          $libdir"
2312 echo "        includedir:      $includedir"
2313
2314 dnl API info
2315 echo ""
2316 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2317 echo "        OpenVG:          $enable_openvg"
2318
2319 dnl Driver info
2320 echo ""
2321 case "x$enable_osmesa$enable_gallium_osmesa" in
2322 xnoyes)
2323         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2324         ;;
2325 xyesno)
2326         echo "        OSMesa:          lib$OSMESA_LIB"
2327         ;;
2328 xnono)
2329         echo "        OSMesa:          no"
2330         ;;
2331 esac
2332
2333 echo ""
2334 if test "x$enable_dri" != xno; then
2335         echo "        DRI platform:    $dri_platform"
2336         if test -z "$DRI_DIRS"; then
2337             echo "        DRI drivers:     no"
2338         else
2339             echo "        DRI drivers:     $DRI_DIRS"
2340         fi
2341         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2342 fi
2343
2344 case "x$enable_glx$enable_xlib_glx" in
2345 xyesyes)
2346     echo "        GLX:             Xlib-based"
2347     ;;
2348 xyesno)
2349     echo "        GLX:             DRI-based"
2350     ;;
2351 *)
2352     echo "        GLX:             $enable_glx"
2353     ;;
2354 esac
2355
2356 dnl EGL
2357 echo ""
2358 echo "        EGL:             $enable_egl"
2359 if test "$enable_egl" = yes; then
2360     echo "        EGL platforms:   $egl_platforms"
2361
2362     egl_drivers=""
2363     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2364         egl_drivers="$egl_drivers builtin:egl_dri2"
2365     fi
2366
2367     if test "x$enable_gallium_egl" = xyes; then
2368         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2369         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2370     else
2371         echo "        EGL drivers:    $egl_drivers"
2372     fi
2373 fi
2374
2375 echo ""
2376 if test "x$MESA_LLVM" = x1; then
2377     echo "        llvm:            yes"
2378     echo "        llvm-config:     $LLVM_CONFIG"
2379     echo "        llvm-version:    $LLVM_VERSION"
2380 else
2381     echo "        llvm:            no"
2382 fi
2383
2384 echo ""
2385 if test -n "$with_gallium_drivers"; then
2386     echo "        Gallium:         yes"
2387     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2388     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2389     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2390     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2391 else
2392     echo "        Gallium:         no"
2393 fi
2394
2395
2396 dnl Libraries
2397 echo ""
2398 echo "        Shared libs:     $enable_shared"
2399 echo "        Static libs:     $enable_static"
2400 echo "        Shared-glapi:    $enable_shared_glapi"
2401
2402 dnl Compiler options
2403 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2404 cflags=`echo $CFLAGS | \
2405     $SED 's/^ *//;s/  */ /;s/ *$//'`
2406 cxxflags=`echo $CXXFLAGS | \
2407     $SED 's/^ *//;s/  */ /;s/ *$//'`
2408 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2409 echo ""
2410 echo "        CFLAGS:          $cflags"
2411 echo "        CXXFLAGS:        $cxxflags"
2412 echo "        Macros:          $defines"
2413 echo ""
2414 if test "x$MESA_LLVM" = x1; then
2415     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2416     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2417     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2418     echo ""
2419 fi
2420 echo "        PYTHON2:         $PYTHON2"
2421
2422 echo ""
2423 echo "        Run '${MAKE-make}' to build Mesa"
2424 echo ""