configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.88
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 WAYLAND_PROTOCOLS_REQUIRED=1.8
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.9.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 dnl add this here, so the help for this environmnet variable is close to
 115 dnl other CC/CXX flags related help
 116 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 117                               enabled by default and different  from -std=c++11)])
 118 AM_PROG_CC_C_O
 119 AM_PROG_AS
 120 AX_CHECK_GNU_MAKE
 121 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 122 AC_PROG_SED
 123 AC_PROG_MKDIR_P
 124
 125 AC_SYS_LARGEFILE
 126
 127
 128 LT_PREREQ([2.2])
 129 LT_INIT([disable-static])
 130
 131 AC_CHECK_PROG(RM, rm, [rm -f])
 132
 133 AX_PROG_BISON([],
 134               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 135                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 136 AX_PROG_FLEX([],
 137              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 138                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 139
 140 AC_CHECK_PROG(INDENT, indent, indent, cat)
 141 if test "x$INDENT" != "xcat"; then
 142     # Only GNU indent is supported
 143     INDENT_VERSION=`indent --version | grep GNU`
 144     if test $? -eq 0; then
 145        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 146     else
 147        INDENT="cat"
 148     fi
 149 fi
 150
 151 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 152
 153 if test -z "$PYTHON2"; then
 154     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 155         AC_MSG_ERROR([Python not found - unable to generate sources])
 156     fi
 157 else
 158     if test "x$acv_mako_found" = xno; then
 159         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 160             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 161         fi
 162     fi
 163 fi
 164
 165 AC_PROG_INSTALL
 166
 167 dnl We need a POSIX shell for parts of the build. Assume we have one
 168 dnl in most cases.
 169 case "$host_os" in
 170 solaris*)
 171     # Solaris /bin/sh is too old/non-POSIX compliant
 172     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 173     SHELL="$POSIX_SHELL"
 174     ;;
 175 esac
 176
 177 dnl clang is mostly GCC-compatible, but its version is much lower,
 178 dnl so we have to check for it.
 179 AC_MSG_CHECKING([if compiling with clang])
 180
 181 AC_COMPILE_IFELSE(
 182 [AC_LANG_PROGRAM([], [[
 183 #ifndef __clang__
 184        not clang
 185 #endif
 186 ]])],
 187 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 188
 189 AC_MSG_RESULT([$acv_mesa_CLANG])
 190
 191 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 192 dnl versions are explictly not supported.
 193 GEN_ASM_OFFSETS=no
 194 USE_GNU99=no
 195 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 196     AC_MSG_CHECKING([whether gcc version is sufficient])
 197     major=0
 198     minor=0
 199
 200     GCC_VERSION=`$CC -dumpversion`
 201     if test $? -eq 0; then
 202         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 203         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 204     fi
 205
 206     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 207         AC_MSG_RESULT([no])
 208         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 209     else
 210         AC_MSG_RESULT([yes])
 211     fi
 212
 213     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 214         USE_GNU99=yes
 215     fi
 216     if test "x$cross_compiling" = xyes; then
 217         GEN_ASM_OFFSETS=yes
 218     fi
 219 fi
 220
 221 dnl We don't support building Mesa with Sun C compiler
 222 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 223 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 224 if test "x$SUNCC" = xyes; then
 225     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 226 fi
 227
 228 dnl Check for compiler builtins
 229 AX_GCC_BUILTIN([__builtin_bswap32])
 230 AX_GCC_BUILTIN([__builtin_bswap64])
 231 AX_GCC_BUILTIN([__builtin_clz])
 232 AX_GCC_BUILTIN([__builtin_clzll])
 233 AX_GCC_BUILTIN([__builtin_ctz])
 234 AX_GCC_BUILTIN([__builtin_expect])
 235 AX_GCC_BUILTIN([__builtin_ffs])
 236 AX_GCC_BUILTIN([__builtin_ffsll])
 237 AX_GCC_BUILTIN([__builtin_popcount])
 238 AX_GCC_BUILTIN([__builtin_popcountll])
 239 AX_GCC_BUILTIN([__builtin_unreachable])
 240
 241 AX_GCC_FUNC_ATTRIBUTE([const])
 242 AX_GCC_FUNC_ATTRIBUTE([flatten])
 243 AX_GCC_FUNC_ATTRIBUTE([format])
 244 AX_GCC_FUNC_ATTRIBUTE([malloc])
 245 AX_GCC_FUNC_ATTRIBUTE([packed])
 246 AX_GCC_FUNC_ATTRIBUTE([pure])
 247 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 248 AX_GCC_FUNC_ATTRIBUTE([unused])
 249 AX_GCC_FUNC_ATTRIBUTE([visibility])
 250 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 251 AX_GCC_FUNC_ATTRIBUTE([weak])
 252 AX_GCC_FUNC_ATTRIBUTE([alias])
 253
 254 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 255
 256 dnl Make sure the pkg-config macros are defined
 257 m4_ifndef([PKG_PROG_PKG_CONFIG],
 258     [m4_fatal([Could not locate the pkg-config autoconf macros.
 259   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 260   are in a different location, try setting the environment variable
 261   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 262 PKG_PROG_PKG_CONFIG()
 263
 264 dnl LIB_DIR - library basename
 265 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 266 AC_SUBST([LIB_DIR])
 267
 268 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 269 _SAVE_LDFLAGS="$LDFLAGS"
 270 _SAVE_CPPFLAGS="$CPPFLAGS"
 271
 272 dnl Compiler macros
 273 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 274 AC_SUBST([DEFINES])
 275 android=no
 276 case "$host_os" in
 277 *-android*)
 278     android=yes
 279     ;;
 280 linux*|*-gnu*|gnu*|cygwin*)
 281     DEFINES="$DEFINES -D_GNU_SOURCE"
 282     ;;
 283 solaris*)
 284     DEFINES="$DEFINES -DSVR4"
 285     ;;
 286 esac
 287
 288 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 289
 290 dnl
 291 dnl Check compiler flags
 292 dnl
 293 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 294 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 295 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 296 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 297 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 298 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 299 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 300
 301 dnl
 302 dnl Check C++ compiler flags
 303 dnl
 304 AC_LANG_PUSH([C++])
 305 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 306 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 307 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 308 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 309 AC_LANG_POP([C++])
 310
 311 # Flags to help ensure that certain portions of the code -- and only those
 312 # portions -- can be built with MSVC:
 313 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 314 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 315 #   supports most of C99)
 316 # - the rest has no compiler compiler restrictions
 317 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 318 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 319 AC_LANG_PUSH([C++])
 320 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 321 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 322 AC_LANG_POP([C++])
 323
 324 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 325 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 326
 327 if test "x$GCC" = xyes; then
 328     if test "x$USE_GNU99" = xyes; then
 329         CFLAGS="$CFLAGS -std=gnu99"
 330     else
 331         CFLAGS="$CFLAGS -std=c99"
 332     fi
 333 fi
 334
 335 dnl
 336 dnl Check whether C++11 is supported, if the environment variable
 337 dnl CXX11_CXXFLAGS is set it takes precedence.
 338 dnl
 339
 340 AC_LANG_PUSH([C++])
 341
 342 check_cxx11_available() {
 343     output_support=$1
 344     AC_COMPILE_IFELSE(
 345         [AC_LANG_PROGRAM([
 346              #if !(__cplusplus >= 201103L)
 347              #error
 348              #endif
 349              #include <tuple>
 350         ])
 351     ], [
 352          AC_MSG_RESULT(yes)
 353          cxx11_support=yes
 354     ], AC_MSG_RESULT(no))
 355     eval "$output_support=\$cxx11_support"
 356 }
 357
 358 HAVE_CXX11=no
 359 save_CXXFLAGS="$CXXFLAGS"
 360
 361 dnl If the user provides a flag to enable c++11, then we test only this
 362 if test "x$CXX11_CXXFLAGS" != "x"; then
 363    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 364    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 365    check_cxx11_available HAVE_CXX11
 366 else
 367    dnl test whether c++11 is enabled by default
 368    AC_MSG_CHECKING(whether c++11 is enabled by default)
 369    check_cxx11_available HAVE_CXX11
 370
 371    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 372    if test "x$HAVE_CXX11" != "xyes"; then
 373        CXX11_CXXFLAGS=-std=c++11
 374        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 375        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 376        check_cxx11_available HAVE_CXX11
 377    fi
 378 fi
 379
 380 CXXFLAGS="$save_CXXFLAGS"
 381 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 382 AC_SUBST(CXX11_CXXFLAGS)
 383 AC_LANG_POP([C++])
 384
 385 dnl even if the compiler appears to support it, using visibility attributes isn't
 386 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 387 case "$host_os" in
 388 cygwin*)
 389     VISIBILITY_CFLAGS=""
 390     VISIBILITY_CXXFLAGS=""
 391     ;;
 392 esac
 393
 394 AC_SUBST([VISIBILITY_CFLAGS])
 395 AC_SUBST([VISIBILITY_CXXFLAGS])
 396
 397 AX_CHECK_COMPILE_FLAG([-Wno-override-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 398 AX_CHECK_COMPILE_FLAG([-Wno-initializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 399 AC_SUBST([WNO_OVERRIDE_INIT])
 400
 401 dnl
 402 dnl Optional flags, check for compiler support
 403 dnl
 404 SSE41_CFLAGS="-msse4.1"
 405 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 406 dnl stack, but on x86-32 such alignment is not guaranteed.
 407 case "$target_cpu" in
 408 i?86)
 409     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 410     ;;
 411 esac
 412 save_CFLAGS="$CFLAGS"
 413 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 414 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 415 #include <smmintrin.h>
 416 int param;
 417 int main () {
 418     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 419     c = _mm_max_epu32(a, b);
 420     return _mm_cvtsi128_si32(c);
 421 }]])], SSE41_SUPPORTED=1)
 422 CFLAGS="$save_CFLAGS"
 423 if test "x$SSE41_SUPPORTED" = x1; then
 424     DEFINES="$DEFINES -DUSE_SSE41"
 425 fi
 426 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 427 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 428
 429 dnl Check for new-style atomic builtins
 430 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 431 int main() {
 432     int n;
 433     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 434 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 435 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 436     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 437     dnl On some platforms, new-style atomics need a helper library
 438     AC_MSG_CHECKING(whether -latomic is needed)
 439     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 440     #include <stdint.h>
 441     uint64_t v;
 442     int main() {
 443         return (int)__atomic_load_n(&v, __ATOMIC_ACQUIRE);
 444     }]])], GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=no, GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=yes)
 445     AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC)
 446     if test "x$GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC" = xyes; then
 447         LIBATOMIC_LIBS="-latomic"
 448     fi
 449 fi
 450 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 451 AC_SUBST([LIBATOMIC_LIBS])
 452
 453 dnl Check if host supports 64-bit atomics
 454 dnl note that lack of support usually results in link (not compile) error
 455 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 456 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 457 #include <stdint.h>
 458 uint64_t v;
 459 int main() {
 460     return __sync_add_and_fetch(&v, (uint64_t)1);
 461 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 462 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 463     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 464 fi
 465 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 466
 467 dnl Check for Endianness
 468 AC_C_BIGENDIAN(
 469    little_endian=no,
 470    little_endian=yes,
 471    little_endian=no,
 472    little_endian=no
 473 )
 474
 475 dnl Check for POWER8 Architecture
 476 PWR8_CFLAGS="-mpower8-vector"
 477 have_pwr8_intrinsics=no
 478 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 479 save_CFLAGS=$CFLAGS
 480 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 481 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 482 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 483 #error "Need GCC >= 4.8 for sane POWER8 support"
 484 #endif
 485 #include <altivec.h>
 486 int main () {
 487     vector unsigned char r;
 488     vector unsigned int v = vec_splat_u32 (1);
 489     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 490     return 0;
 491 }]])], have_pwr8_intrinsics=yes)
 492 CFLAGS=$save_CFLAGS
 493
 494 AC_ARG_ENABLE(pwr8,
 495    [AS_HELP_STRING([--disable-pwr8],
 496                    [disable POWER8-specific instructions])],
 497    [enable_pwr8=$enableval], [enable_pwr8=auto])
 498
 499 if test "x$enable_pwr8" = xno ; then
 500    have_pwr8_intrinsics=disabled
 501 fi
 502
 503 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 504    DEFINES="$DEFINES -D_ARCH_PWR8"
 505    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 506    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 507 else
 508    PWR8_CFLAGS=
 509 fi
 510
 511 AC_MSG_RESULT($have_pwr8_intrinsics)
 512 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 513    AC_MSG_ERROR([POWER8 compiler support not detected])
 514 fi
 515
 516 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 517    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 518 fi
 519
 520 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 521
 522 dnl Can't have static and shared libraries, default to static if user
 523 dnl explicitly requested. If both disabled, set to static since shared
 524 dnl was explicitly requested.
 525 case "x$enable_static$enable_shared" in
 526 xyesyes)
 527     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 528     ;;
 529 xnono)
 530     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 531     ;;
 532 esac
 533
 534 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 535
 536 dnl
 537 dnl other compiler options
 538 dnl
 539 AC_ARG_ENABLE([debug],
 540     [AS_HELP_STRING([--enable-debug],
 541         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 542     [enable_debug="$enableval"],
 543     [enable_debug=no]
 544 )
 545
 546 AC_ARG_ENABLE([profile],
 547     [AS_HELP_STRING([--enable-profile],
 548         [enable profiling of code @<:@default=disabled@:>@])],
 549     [enable_profile="$enableval"],
 550     [enable_profile=no]
 551 )
 552
 553 AC_ARG_ENABLE([sanitize],
 554     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 555         [enable code sanitizer @<:@default=disabled@:>@])],
 556     [enable_sanitize="$enableval"],
 557     [enable_sanitize=no])
 558
 559 if test "x$enable_profile" = xyes; then
 560     DEFINES="$DEFINES -DPROFILE"
 561     if test "x$GCC" = xyes; then
 562         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 563     fi
 564     if test "x$GXX" = xyes; then
 565         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 566     fi
 567 fi
 568
 569 if test "x$enable_debug" = xyes; then
 570     DEFINES="$DEFINES -DDEBUG"
 571     if test "x$enable_profile" = xyes; then
 572         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 573     fi
 574     if test "x$GCC" = xyes; then
 575         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 576             CFLAGS="$CFLAGS -g"
 577         fi
 578         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 579             CFLAGS="$CFLAGS -O0"
 580         fi
 581     fi
 582     if test "x$GXX" = xyes; then
 583         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 584             CXXFLAGS="$CXXFLAGS -g"
 585         fi
 586         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 587             CXXFLAGS="$CXXFLAGS -O0"
 588         fi
 589     fi
 590 else
 591    DEFINES="$DEFINES -DNDEBUG"
 592 fi
 593
 594 if test "x$enable_sanitize" != xno; then
 595     if test "x$enable_profile" = xyes; then
 596         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 597     fi
 598
 599     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 600     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 601     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 602
 603     AC_LINK_IFELSE(
 604         [AC_LANG_SOURCE([int main(){return 0;}])],
 605         [],
 606         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 607 fi
 608
 609 dnl
 610 dnl Check if linker supports -Bsymbolic
 611 dnl
 612 save_LDFLAGS=$LDFLAGS
 613 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 614 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 615 AC_LINK_IFELSE(
 616     [AC_LANG_SOURCE([int main() { return 0;}])],
 617     [AC_MSG_RESULT([yes])
 618         BSYMBOLIC="-Wl,-Bsymbolic";],
 619     [AC_MSG_RESULT([no])
 620         BSYMBOLIC="";])
 621 LDFLAGS=$save_LDFLAGS
 622
 623 AC_SUBST([BSYMBOLIC])
 624
 625 dnl
 626 dnl Check if linker supports garbage collection
 627 dnl
 628 save_LDFLAGS=$LDFLAGS
 629 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 630 AC_MSG_CHECKING([whether ld supports --gc-sections])
 631 AC_LINK_IFELSE(
 632     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 633     [AC_MSG_RESULT([yes])
 634         GC_SECTIONS="-Wl,--gc-sections";],
 635     [AC_MSG_RESULT([no])
 636         GC_SECTIONS="";])
 637 LDFLAGS=$save_LDFLAGS
 638
 639 AC_SUBST([GC_SECTIONS])
 640
 641 dnl
 642 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 643 dnl so when these flags are passed to ld via libtool the checks will fail
 644 dnl
 645 case "$host_os" in
 646 openbsd* | darwin* )
 647     LD_NO_UNDEFINED="" ;;
 648 *)
 649     if test "x$enable_sanitize" = xno; then
 650         LD_NO_UNDEFINED="-Wl,--no-undefined"
 651     else
 652         LD_NO_UNDEFINED=""
 653     fi
 654     ;;
 655 esac
 656
 657 AC_SUBST([LD_NO_UNDEFINED])
 658
 659 dnl
 660 dnl Check if linker supports version scripts
 661 dnl
 662 AC_MSG_CHECKING([if the linker supports version-scripts])
 663 save_LDFLAGS=$LDFLAGS
 664 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 665 AC_LINK_IFELSE(
 666     [AC_LANG_SOURCE([int main() { return 0;}])],
 667     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 668     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 669 LDFLAGS=$save_LDFLAGS
 670 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 671
 672 dnl
 673 dnl Check if linker supports dynamic list files
 674 dnl
 675 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 676 save_LDFLAGS=$LDFLAGS
 677 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 678 AC_LINK_IFELSE(
 679     [AC_LANG_SOURCE([int main() { return 0;}])],
 680     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 681     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 682 LDFLAGS=$save_LDFLAGS
 683 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 684
 685 dnl
 686 dnl compatibility symlinks
 687 dnl
 688 case "$host_os" in
 689 linux* )
 690     HAVE_COMPAT_SYMLINKS=yes ;;
 691 * )
 692     HAVE_COMPAT_SYMLINKS=no ;;
 693 esac
 694
 695 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 696
 697 dnl
 698 dnl library names
 699 dnl
 700 dnl Unfortunately we need to do a few things that libtool can't help us with,
 701 dnl so we need some knowledge of shared library filenames:
 702 dnl
 703 dnl LIB_EXT is the extension used when creating symlinks for alternate
 704 dnl filenames for a shared library which will be dynamically loaded
 705 dnl
 706 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 707 dnl the file for a shared library we wish to link with
 708 dnl
 709 case "$host_os" in
 710 darwin* )
 711     LIB_EXT='dylib'
 712     IMP_LIB_EXT=$LIB_EXT
 713     ;;
 714 cygwin* )
 715     LIB_EXT='dll'
 716     IMP_LIB_EXT='dll.a'
 717     ;;
 718 aix* )
 719     LIB_EXT='a'
 720     IMP_LIB_EXT=$LIB_EXT
 721     ;;
 722 * )
 723     LIB_EXT='so'
 724     IMP_LIB_EXT=$LIB_EXT
 725     ;;
 726 esac
 727
 728 AC_SUBST([LIB_EXT])
 729
 730 dnl
 731 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 732 dnl
 733 AC_ARG_ENABLE([texture-float],
 734     [AS_HELP_STRING([--enable-texture-float],
 735         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 736     [enable_texture_float="$enableval"],
 737     [enable_texture_float=no]
 738 )
 739 if test "x$enable_texture_float" = xyes; then
 740     AC_MSG_WARN([Floating-point textures enabled.])
 741     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 742     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 743 fi
 744
 745 dnl
 746 dnl Arch/platform-specific settings
 747 dnl
 748 AC_ARG_ENABLE([asm],
 749     [AS_HELP_STRING([--disable-asm],
 750         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 751     [enable_asm="$enableval"],
 752     [enable_asm=yes]
 753 )
 754 asm_arch=""
 755 AC_MSG_CHECKING([whether to enable assembly])
 756 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 757 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 758 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 759     case "$host_cpu" in
 760     i?86 | x86_64 | amd64)
 761         if test "x$host_cpu" != "x$target_cpu"; then
 762             enable_asm=no
 763             AC_MSG_RESULT([no, cross compiling])
 764         fi
 765         ;;
 766     esac
 767 fi
 768 # check for supported arches
 769 if test "x$enable_asm" = xyes; then
 770     case "$host_cpu" in
 771     i?86)
 772         case "$host_os" in
 773         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 774             asm_arch=x86
 775             ;;
 776         esac
 777         ;;
 778     x86_64|amd64)
 779         case "$host_os" in
 780         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 781             asm_arch=x86_64
 782             ;;
 783         esac
 784         ;;
 785     sparc*)
 786         case "$host_os" in
 787         linux*)
 788             asm_arch=sparc
 789             ;;
 790         esac
 791         ;;
 792     powerpc64le)
 793         case "$host_os" in
 794         linux*)
 795             asm_arch=ppc64le
 796             ;;
 797         esac
 798         ;;
 799     aarch64)
 800         case "$host_os" in
 801         linux*)
 802             asm_arch=aarch64
 803             ;;
 804         esac
 805         ;;
 806     arm)
 807         case "$host_os" in
 808         linux*)
 809             asm_arch=arm
 810             ;;
 811         esac
 812         ;;
 813     esac
 814
 815     case "$asm_arch" in
 816     x86)
 817         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 818         AC_MSG_RESULT([yes, x86])
 819         ;;
 820     x86_64|amd64)
 821         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 822         AC_MSG_RESULT([yes, x86_64])
 823         ;;
 824     sparc)
 825         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 826         AC_MSG_RESULT([yes, sparc])
 827         ;;
 828     ppc64le)
 829         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 830         AC_MSG_RESULT([yes, ppc64le])
 831         ;;
 832     aarch64)
 833         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 834         AC_MSG_RESULT([yes, aarch64])
 835         ;;
 836     arm)
 837         DEFINES="$DEFINES -DUSE_ARM_ASM"
 838         AC_MSG_RESULT([yes, arm])
 839         ;;
 840     *)
 841         AC_MSG_RESULT([no, platform not supported])
 842         ;;
 843     esac
 844 fi
 845
 846 AC_HEADER_MAJOR
 847 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 848 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 849 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 850 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 851 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 852
 853 AC_MSG_CHECKING([whether strtod has locale support])
 854 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 855     #define _GNU_SOURCE
 856     #include <stdlib.h>
 857     #include <locale.h>
 858     #ifdef HAVE_XLOCALE_H
 859     #include <xlocale.h>
 860     #endif
 861     int main() {
 862        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 863        const char *s = "1.0";
 864        char *end;
 865        double d = strtod_l(s, end, loc);
 866        float f = strtof_l(s, end, loc);
 867        freelocale(loc);
 868        return 0;
 869     }]])],
 870   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 871    AC_MSG_RESULT([yes]),
 872    AC_MSG_RESULT([no]))
 873
 874 dnl Check to see if dlopen is in default libraries (like Solaris, which
 875 dnl has it in libc), or if libdl is needed to get it.
 876 AC_CHECK_FUNC([dlopen], [],
 877     [AC_CHECK_LIB([dl], [dlopen],
 878        [DLOPEN_LIBS="-ldl"])])
 879 AC_SUBST([DLOPEN_LIBS])
 880
 881 dnl Check if that library also has dladdr
 882 save_LIBS="$LIBS"
 883 LIBS="$LIBS $DLOPEN_LIBS"
 884 AC_CHECK_FUNCS([dladdr])
 885 LIBS="$save_LIBS"
 886
 887 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 888
 889 case "$host_os" in
 890 darwin*)
 891     ;;
 892 *)
 893     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 894                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 895                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 896     AC_SUBST([CLOCK_LIB])
 897     ;;
 898 esac
 899
 900 dnl See if posix_memalign is available
 901 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 902
 903 dnl Check for zlib
 904 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 905
 906 dnl Check for pthreads
 907 AX_PTHREAD
 908 if test "x$ax_pthread_ok" = xno; then
 909     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 910 fi
 911 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 912 dnl to -pthread, which causes problems if we need -lpthread to appear in
 913 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 914 dnl is not valid for that platform.
 915 if test "x$android" = xno; then
 916     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 917 fi
 918 dnl According to the manual when using pthreads, one should add -pthread to
 919 dnl both compile and link-time arguments.
 920 dnl In practise that should be sufficient for all platforms, since any
 921 dnl platforms build with GCC and Clang support the flag.
 922 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 923
 924 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 925 dnl project. Even then there's a notable issue as described in the project README
 926 case "$host_os" in
 927 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 928     pthread_stubs_possible="no"
 929     ;;
 930 * )
 931     pthread_stubs_possible="yes"
 932     ;;
 933 esac
 934
 935 if test "x$pthread_stubs_possible" = xyes; then
 936     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 937 fi
 938
 939 dnl Check for futex for fast inline simple_mtx_t.
 940 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
 941
 942 dnl SELinux awareness.
 943 AC_ARG_ENABLE([selinux],
 944     [AS_HELP_STRING([--enable-selinux],
 945         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 946     [MESA_SELINUX="$enableval"],
 947     [MESA_SELINUX=no])
 948 if test "x$enable_selinux" = "xyes"; then
 949     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 950         [AC_CHECK_HEADER([selinux/selinux.h],[],
 951                          [AC_MSG_ERROR([SELinux headers not found])])
 952          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 953                       [AC_MSG_ERROR([SELinux library not found])])
 954          SELINUX_LIBS="-lselinux"])
 955     DEFINES="$DEFINES -DMESA_SELINUX"
 956 fi
 957 AC_SUBST([SELINUX_CFLAGS])
 958 AC_SUBST([SELINUX_LIBS])
 959
 960 dnl
 961 dnl LLVM
 962 dnl
 963 AC_ARG_ENABLE([llvm-shared-libs],
 964     [AS_HELP_STRING([--enable-llvm-shared-libs],
 965         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 966     [enable_llvm_shared_libs="$enableval"],
 967     [enable_llvm_shared_libs=yes])
 968
 969 AC_ARG_WITH([llvm-prefix],
 970     [AS_HELP_STRING([--with-llvm-prefix],
 971         [Prefix for LLVM installations in non-standard locations])],
 972     [llvm_prefix="$withval"],
 973     [llvm_prefix=''])
 974
 975 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 976 if test "x$have_libelf" = xno; then
 977    LIBELF_LIBS=''
 978    LIBELF_CFLAGS=''
 979    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 980    AC_SUBST([LIBELF_LIBS])
 981    AC_SUBST([LIBELF_CFLAGS])
 982 fi
 983
 984 if test -z "$LLVM_CONFIG"; then
 985     if test -n "$llvm_prefix"; then
 986         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 987     else
 988         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 989     fi
 990 fi
 991
 992 llvm_add_component() {
 993     new_llvm_component=$1
 994     driver_name=$2
 995
 996     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 997         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 998     else
 999         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1000     fi
1001 }
1002
1003 llvm_add_optional_component() {
1004     new_llvm_component=$1
1005     driver_name=$2
1006
1007     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1008         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1009     fi
1010 }
1011
1012 llvm_add_default_components() {
1013     driver_name=$1
1014
1015     # Required default components
1016     llvm_add_component "bitwriter" $driver_name
1017     llvm_add_component "engine" $driver_name
1018     llvm_add_component "mcdisassembler" $driver_name
1019     llvm_add_component "mcjit" $driver_name
1020
1021     # Optional default components
1022     llvm_add_optional_component "inteljitevents" $driver_name
1023 }
1024
1025 llvm_add_target() {
1026     new_llvm_target=$1
1027     driver_name=$2
1028
1029     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1030         llvm_add_component $new_llvm_target $driver_name
1031     else
1032         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1033     fi
1034 }
1035
1036 # Call this inside ` ` to get the return value.
1037 # $1 is the llvm-config command with arguments.
1038 strip_unwanted_llvm_flags() {
1039     echo " `$1` " | sed -E \
1040         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1041         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1042         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1043         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1044         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1045         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1046         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1047         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1048         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1049         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1050         -e 's/^[[[:space:]]]//' \
1051         -e 's/[[[:space:]]]$//'
1052 }
1053
1054 llvm_set_environment_variables() {
1055     if test "x$LLVM_CONFIG" != xno; then
1056         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1057         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1058         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1059         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1060
1061         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1062         save_CFLAGS="$CFLAGS"
1063         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1064
1065         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1066             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1067         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1068             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1069         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1070             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1071
1072         CFLAGS="$save_CFLAGS"
1073
1074         # Only needed for LLVM < 3.6.0
1075         if test -z "$LLVM_VERSION_PATCH"; then
1076             LLVM_VERSION_PATCH=0
1077         fi
1078
1079         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1080
1081         FOUND_LLVM=yes
1082     else
1083         FOUND_LLVM=no
1084         LLVM_VERSION_INT=0
1085     fi
1086 }
1087
1088 require_llvm() {
1089     if test "x$enable_llvm" != "xyes"; then
1090         AC_MSG_ERROR([--enable-llvm is required when building $1])
1091     fi
1092 }
1093
1094 llvm_require_version() {
1095     require_llvm $2
1096
1097     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1098     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1099     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1100
1101     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1102         # major > required major
1103         #  --> OK
1104         return
1105     fi
1106
1107     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1108         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1109             # major = required major and
1110             # minor > required minor
1111             #  --> OK
1112             return
1113         else
1114             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1115                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1116                     # major = required major and
1117                     # minor = required minor and
1118                     # patch >= required patch
1119                     #  --> OK
1120                     return
1121                 fi
1122             fi
1123         fi
1124     fi
1125
1126     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1127 }
1128
1129 radeon_llvm_check() {
1130     if test ${LLVM_VERSION_INT} -lt 307; then
1131         amdgpu_llvm_target_name='r600'
1132     else
1133         amdgpu_llvm_target_name='amdgpu'
1134     fi
1135
1136     llvm_require_version $*
1137
1138     llvm_add_target $amdgpu_llvm_target_name $2
1139
1140     llvm_add_default_components $2
1141     llvm_add_component "bitreader" $2
1142     llvm_add_component "ipo" $2
1143
1144     if test "x$have_libelf" != xyes; then
1145        AC_MSG_ERROR([$2 requires libelf when using llvm])
1146     fi
1147 }
1148
1149 llvm_set_environment_variables
1150
1151 AC_SUBST([LLVM_CFLAGS])
1152 AC_SUBST([LLVM_CXXFLAGS])
1153 AC_SUBST([LLVM_LIBS])
1154 AC_SUBST([LLVM_LDFLAGS])
1155 AC_SUBST([LLVM_INCLUDEDIR])
1156
1157 dnl
1158 dnl libunwind
1159 dnl
1160 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1161 AC_ARG_ENABLE([libunwind],
1162     [AS_HELP_STRING([--enable-libunwind],
1163             [Use libunwind for backtracing (default: auto)])],
1164         [LIBUNWIND="$enableval"],
1165         [LIBUNWIND="$HAVE_LIBUNWIND"])
1166
1167 if test "x$LIBUNWIND" = "xyes"; then
1168     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1169     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1170 fi
1171
1172
1173 dnl Options for APIs
1174 AC_ARG_ENABLE([opengl],
1175     [AS_HELP_STRING([--disable-opengl],
1176         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1177     [enable_opengl="$enableval"],
1178     [enable_opengl=yes])
1179 AC_ARG_ENABLE([gles1],
1180     [AS_HELP_STRING([--disable-gles1],
1181         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1182     [enable_gles1="$enableval"],
1183     [enable_gles1=yes])
1184 AC_ARG_ENABLE([gles2],
1185     [AS_HELP_STRING([--disable-gles2],
1186         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1187     [enable_gles2="$enableval"],
1188     [enable_gles2=yes])
1189
1190 AC_ARG_ENABLE([dri],
1191     [AS_HELP_STRING([--enable-dri],
1192         [enable DRI modules @<:@default=enabled@:>@])],
1193     [enable_dri="$enableval"],
1194     [enable_dri=yes])
1195
1196 AC_ARG_ENABLE([gallium-extra-hud],
1197     [AS_HELP_STRING([--enable-gallium-extra-hud],
1198         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1199     [enable_gallium_extra_hud="$enableval"],
1200     [enable_gallium_extra_hud=no])
1201 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1202 if test "x$enable_gallium_extra_hud" = xyes ; then
1203     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1204 fi
1205
1206 #TODO: no pkgconfig .pc available for libsensors.
1207 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1208 AC_ARG_ENABLE([lmsensors],
1209     [AS_HELP_STRING([--enable-lmsensors],
1210         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1211     [enable_lmsensors="$enableval"],
1212     [enable_lmsensors=no])
1213 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1214 if test "x$enable_lmsensors" = xyes ; then
1215     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1216     LIBSENSORS_LIBS="-lsensors"
1217 else
1218     LIBSENSORS_LIBS=""
1219 fi
1220 AC_SUBST(LIBSENSORS_LIBS)
1221
1222 case "$host_os" in
1223 linux*)
1224     dri3_default=yes
1225     ;;
1226 *)
1227     dri3_default=no
1228     ;;
1229 esac
1230
1231 if test "x$enable_dri" = xno; then
1232     dri3_default=no
1233 fi
1234
1235 AC_ARG_ENABLE([dri3],
1236     [AS_HELP_STRING([--enable-dri3],
1237         [enable DRI3 @<:@default=auto@:>@])],
1238     [enable_dri3="$enableval"],
1239     [enable_dri3="$dri3_default"])
1240 AC_ARG_ENABLE([glx],
1241     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1242         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1243     [enable_glx="$enableval"],
1244     [enable_glx=yes])
1245 AC_ARG_ENABLE([osmesa],
1246     [AS_HELP_STRING([--enable-osmesa],
1247         [enable OSMesa library @<:@default=disabled@:>@])],
1248     [enable_osmesa="$enableval"],
1249     [enable_osmesa=no])
1250 AC_ARG_ENABLE([gallium-osmesa],
1251     [AS_HELP_STRING([--enable-gallium-osmesa],
1252         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1253     [enable_gallium_osmesa="$enableval"],
1254     [enable_gallium_osmesa=no])
1255 AC_ARG_ENABLE([egl],
1256     [AS_HELP_STRING([--disable-egl],
1257         [disable EGL library @<:@default=enabled@:>@])],
1258     [enable_egl="$enableval"],
1259     [enable_egl=yes])
1260
1261 AC_ARG_ENABLE([xa],
1262     [AS_HELP_STRING([--enable-xa],
1263         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1264     [enable_xa="$enableval"],
1265     [enable_xa=no])
1266 AC_ARG_ENABLE([gbm],
1267    [AS_HELP_STRING([--enable-gbm],
1268          [enable gbm library @<:@default=yes except cygwin@:>@])],
1269    [enable_gbm="$enableval"],
1270    [case "$host_os" in
1271        cygwin*)
1272           enable_gbm=no
1273           ;;
1274        *)
1275           enable_gbm=yes
1276           ;;
1277     esac])
1278 AC_ARG_ENABLE([nine],
1279     [AS_HELP_STRING([--enable-nine],
1280         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1281     [enable_nine="$enableval"],
1282     [enable_nine=no])
1283
1284 AC_ARG_ENABLE([xvmc],
1285    [AS_HELP_STRING([--enable-xvmc],
1286          [enable xvmc library @<:@default=auto@:>@])],
1287    [enable_xvmc="$enableval"],
1288    [enable_xvmc=auto])
1289 AC_ARG_ENABLE([vdpau],
1290    [AS_HELP_STRING([--enable-vdpau],
1291          [enable vdpau library @<:@default=auto@:>@])],
1292    [enable_vdpau="$enableval"],
1293    [enable_vdpau=auto])
1294 AC_ARG_ENABLE([omx],
1295    [AS_HELP_STRING([--enable-omx],
1296          [DEPRECATED: Use --enable-omx-bellagio instead @<:@default=auto@:>@])],
1297    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio instead.])],
1298    [])
1299 AC_ARG_ENABLE([omx-bellagio],
1300    [AS_HELP_STRING([--enable-omx-bellagio],
1301          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1302    [enable_omx_bellagio="$enableval"],
1303    [enable_omx_bellagio=no])
1304 AC_ARG_ENABLE([va],
1305    [AS_HELP_STRING([--enable-va],
1306          [enable va library @<:@default=auto@:>@])],
1307    [enable_va="$enableval"],
1308    [enable_va=auto])
1309 AC_ARG_ENABLE([opencl],
1310    [AS_HELP_STRING([--enable-opencl],
1311          [enable OpenCL library @<:@default=disabled@:>@])],
1312    [enable_opencl="$enableval"],
1313    [enable_opencl=no])
1314 AC_ARG_ENABLE([opencl_icd],
1315    [AS_HELP_STRING([--enable-opencl-icd],
1316           [Build an OpenCL ICD library to be loaded by an ICD implementation
1317            @<:@default=enabled@:>@])],
1318     [enable_opencl_icd="$enableval"],
1319     [enable_opencl_icd=yes])
1320
1321 AC_ARG_ENABLE([gallium-tests],
1322     [AS_HELP_STRING([--enable-gallium-tests],
1323         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1324     [enable_gallium_tests="$enableval"],
1325     [enable_gallium_tests=no])
1326
1327 # Option for Gallium drivers
1328
1329 # Keep this in sync with the --with-gallium-drivers help string default value
1330 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1331
1332 AC_ARG_WITH([gallium-drivers],
1333     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1334         [comma delimited Gallium drivers list, e.g.
1335         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,vc5,virgl,etnaviv,imx"
1336         @<:@default=r300,r600,svga,swrast@:>@])],
1337     [with_gallium_drivers="$withval"],
1338     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1339
1340 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1341 # here so that the script doesn't choke on an unknown driver name later.
1342 case "$with_gallium_drivers" in
1343     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1344     no) with_gallium_drivers='' ;;
1345 esac
1346
1347 if test "x$enable_opengl" = xno -a \
1348         "x$enable_gles1" = xno -a \
1349         "x$enable_gles2" = xno -a \
1350         "x$enable_nine" = xno -a \
1351         "x$enable_xa" = xno -a \
1352         "x$enable_xvmc" = xno -a \
1353         "x$enable_vdpau" = xno -a \
1354         "x$enable_omx_bellagio" = xno -a \
1355         "x$enable_va" = xno -a \
1356         "x$enable_opencl" = xno; then
1357     AC_MSG_ERROR([at least one API should be enabled])
1358 fi
1359
1360 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1361 if test "x$enable_opengl" = xno -a \
1362         "x$enable_gles1" = xyes; then
1363     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1364 fi
1365
1366 if test "x$enable_opengl" = xno -a \
1367         "x$enable_gles2" = xyes; then
1368     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1369 fi
1370
1371 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1372 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1373 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1374 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1375                                         "x$enable_gles1" = xyes -o \
1376                                         "x$enable_gles2" = xyes)
1377 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1378                                       "x$enable_gles1" = xyes -o \
1379                                       "x$enable_gles2" = xyes)
1380
1381 # Validate GLX options
1382 if test "x$enable_glx" = xyes; then
1383     if test "x$enable_dri" = xyes; then
1384         enable_glx=dri
1385     elif test -n "$with_gallium_drivers"; then
1386         enable_glx=gallium-xlib
1387     else
1388         enable_glx=xlib
1389     fi
1390 fi
1391 case "x$enable_glx" in
1392 xdri | xxlib | xgallium-xlib)
1393     # GLX requires OpenGL
1394     if test "x$enable_opengl" = xno; then
1395         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1396     fi
1397
1398     # Check individual dependencies
1399     case "x$enable_glx" in
1400     xdri)
1401         if test "x$enable_dri" = xno; then
1402             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1403         fi
1404         ;;
1405     xxlib)
1406         if test "x$enable_dri" = xyes; then
1407             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1408         fi
1409         ;;
1410     xgallium-xlib )
1411         if test "x$enable_dri" = xyes; then
1412             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1413         fi
1414         if test -z "$with_gallium_drivers"; then
1415             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1416         fi
1417         ;;
1418     esac
1419     ;;
1420 xno)
1421     ;;
1422 *)
1423     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1424     ;;
1425 esac
1426
1427 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1428 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1429 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1430 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1431
1432 DEFAULT_GL_LIB_NAME=GL
1433
1434 dnl
1435 dnl Libglvnd configuration
1436 dnl
1437 AC_ARG_ENABLE([libglvnd],
1438     [AS_HELP_STRING([--enable-libglvnd],
1439         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1440     [enable_libglvnd="$enableval"],
1441     [enable_libglvnd=no])
1442 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1443
1444 if test "x$enable_libglvnd" = xyes ; then
1445     case "x$enable_glx" in
1446     xxlib | xgallium-xlib )
1447         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1448         ;;
1449     esac
1450
1451     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1452     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1453     AC_SUBST([LIBGLVND_DATADIR])
1454
1455     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1456     DEFAULT_GL_LIB_NAME=GLX_mesa
1457
1458     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1459         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1460     fi
1461 fi
1462
1463 AC_ARG_WITH([gl-lib-name],
1464   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1465     [specify GL library name @<:@default=GL@:>@])],
1466   [GL_LIB=$withval],
1467   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1468 AC_ARG_WITH([osmesa-lib-name],
1469   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1470     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1471   [OSMESA_LIB=$withval],
1472   [OSMESA_LIB=OSMesa])
1473 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1474 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1475
1476 dnl
1477 dnl Mangled Mesa support
1478 dnl
1479 AC_ARG_ENABLE([mangling],
1480   [AS_HELP_STRING([--enable-mangling],
1481     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1482   [enable_mangling="${enableval}"],
1483   [enable_mangling=no]
1484 )
1485 if test "x${enable_mangling}" = "xyes" ; then
1486   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1487   GL_LIB="Mangled${GL_LIB}"
1488   OSMESA_LIB="Mangled${OSMESA_LIB}"
1489 fi
1490 AC_SUBST([GL_LIB])
1491 AC_SUBST([OSMESA_LIB])
1492
1493 # Check for libdrm
1494 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1495                   [have_libdrm=yes], [have_libdrm=no])
1496 if test "x$have_libdrm" = xyes; then
1497     DEFINES="$DEFINES -DHAVE_LIBDRM"
1498 fi
1499
1500 require_libdrm() {
1501     if test "x$have_libdrm" != xyes; then
1502        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1503     fi
1504 }
1505
1506
1507 # Select which platform-dependent DRI code gets built
1508 case "$host_os" in
1509 darwin*)
1510     dri_platform='apple' ;;
1511 cygwin*)
1512     dri_platform='windows' ;;
1513 gnu*)
1514     dri_platform='none' ;;
1515 *)
1516     dri_platform='drm' ;;
1517 esac
1518
1519 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1520     have_drisw_kms='yes'
1521 fi
1522
1523 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1524 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1525 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1526 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1527 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1528 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1529 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1530 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1531 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1532
1533 AC_ARG_ENABLE([shared-glapi],
1534     [AS_HELP_STRING([--enable-shared-glapi],
1535         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1536     [enable_shared_glapi="$enableval"],
1537     [enable_shared_glapi=yes])
1538
1539 case "x$enable_opengl$enable_gles1$enable_gles2" in
1540 x*yes*yes*)
1541     if test "x$enable_shared_glapi" = xno; then
1542         AC_MSG_ERROR([shared GLAPI required when building two or more of
1543                       the following APIs - opengl, gles1 gles2])
1544     fi
1545     ;;
1546 esac
1547
1548 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1549
1550 # Build the pipe-drivers as separate libraries/modules.
1551 # Do not touch this unless you know what you are doing.
1552 # XXX: Expose via configure option ?
1553 enable_shared_pipe_drivers=no
1554
1555 dnl
1556 dnl Driver specific build directories
1557 dnl
1558
1559 if test "x$enable_gallium_osmesa" = xyes; then
1560     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1561         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1562     fi
1563     if test "x$enable_osmesa" = xyes; then
1564         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1565     fi
1566 fi
1567
1568 require_dri_shared_libs_and_glapi() {
1569     if test "x$enable_static" = xyes; then
1570         AC_MSG_ERROR([$1 cannot be build as static library])
1571     fi
1572
1573     if test "x$enable_dri" != xyes; then
1574         # There is only a single backend which won't be build/used otherwise.
1575         # XXX: Revisit this as the egl/haiku is a thing.
1576         AC_MSG_ERROR([$1 requires --enable-dri])
1577     fi
1578
1579     if test "x$enable_shared_glapi" != xyes; then
1580         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1581     fi
1582 }
1583
1584 if test "x$enable_dri" = xyes; then
1585     require_dri_shared_libs_and_glapi "DRI"
1586
1587     # not a hard requirement as swrast does not depend on it
1588     if test "x$have_libdrm" = xyes; then
1589         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1590     fi
1591 fi
1592
1593 AC_ARG_ENABLE([driglx-direct],
1594     [AS_HELP_STRING([--disable-driglx-direct],
1595         [disable direct rendering in GLX and EGL for DRI \
1596             @<:@default=auto@:>@])],
1597     [driglx_direct="$enableval"],
1598     [driglx_direct="yes"])
1599
1600 dnl
1601 dnl libGL configuration per driver
1602 dnl
1603 if test "x$enable_glx" != xno; then
1604     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1605 fi
1606 case "x$enable_glx" in
1607 xxlib | xgallium-xlib)
1608     # Xlib-based GLX
1609     dri_modules="x11 xext xcb"
1610     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1611     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1612     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1613     GL_LIB_DEPS="$XLIBGL_LIBS"
1614     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1615     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1616     ;;
1617 xdri)
1618     # DRI-based GLX
1619
1620     # find the DRI deps for libGL
1621     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1622
1623     if test x"$driglx_direct" = xyes; then
1624         if test x"$dri_platform" = xdrm ; then
1625             DEFINES="$DEFINES -DGLX_USE_DRM"
1626             require_libdrm "Direct rendering"
1627
1628             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1629             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1630
1631             if test x"$enable_dri" = xyes; then
1632                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1633             fi
1634         fi
1635         if test x"$dri_platform" = xapple ; then
1636             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1637         fi
1638         if test x"$dri_platform" = xwindows ; then
1639             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1640         fi
1641     fi
1642
1643     # add xf86vidmode if available
1644     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1645     if test "$HAVE_XF86VIDMODE" = yes ; then
1646         dri_modules="$dri_modules xxf86vm"
1647     fi
1648
1649     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1650     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1651     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1652     GL_LIB_DEPS="$DRIGL_LIBS"
1653
1654     # need DRM libs, $PTHREAD_LIBS, etc.
1655     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1656     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1657     ;;
1658 esac
1659
1660 # This is outside the case (above) so that it is invoked even for non-GLX
1661 # builds.
1662 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1663
1664 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1665 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1666 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1667 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1668
1669 AC_SUBST([X11_INCLUDES])
1670 AC_SUBST([GL_LIB_DEPS])
1671 AC_SUBST([GL_PC_REQ_PRIV])
1672 AC_SUBST([GL_PC_LIB_PRIV])
1673 AC_SUBST([GL_PC_CFLAGS])
1674 AC_SUBST([DRI_PC_REQ_PRIV])
1675 AC_SUBST([GLESv1_CM_LIB_DEPS])
1676 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1677 AC_SUBST([GLESv2_LIB_DEPS])
1678 AC_SUBST([GLESv2_PC_LIB_PRIV])
1679
1680 AC_SUBST([HAVE_XF86VIDMODE])
1681
1682 dnl
1683 dnl More GLX setup
1684 dnl
1685 case "x$enable_glx" in
1686 xxlib | xgallium-xlib)
1687     DEFINES="$DEFINES -DUSE_XSHM"
1688     ;;
1689 xdri)
1690     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1691     if test "x$driglx_direct" = xyes; then
1692         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1693     fi
1694     ;;
1695 esac
1696
1697 dnl
1698 dnl TLS detection
1699 dnl
1700
1701 AC_ARG_ENABLE([glx-tls],
1702     [AS_HELP_STRING([--enable-glx-tls],
1703         [enable TLS support in GLX @<:@default=enabled@:>@])],
1704     [GLX_USE_TLS="$enableval"],
1705     [GLX_USE_TLS=yes])
1706 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1707
1708 if test "x$GLX_USE_TLS" = xyes; then
1709     DEFINES="$DEFINES -DGLX_USE_TLS"
1710 fi
1711
1712 dnl Read-only text section on x86 hardened platforms
1713 AC_ARG_ENABLE([glx-read-only-text],
1714     [AS_HELP_STRING([--enable-glx-read-only-text],
1715         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1716     [enable_glx_read_only_text="$enableval"],
1717     [enable_glx_read_only_text=no])
1718 if test "x$enable_glx_read_only_text" = xyes; then
1719     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1720 fi
1721
1722 dnl
1723 dnl DEPRECATED: EGL Platforms configuration
1724 dnl
1725 AC_ARG_WITH([egl-platforms],
1726     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1727         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1728     [with_egl_platforms="$withval"],
1729     [with_egl_platforms=auto])
1730
1731 if test "x$with_egl_platforms" = xauto; then
1732     with_egl_platforms="x11,surfaceless"
1733     if test "x$enable_gbm" = xyes; then
1734         with_egl_platforms="$with_egl_platforms,drm"
1735     fi
1736 else
1737     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1738 fi
1739
1740 dnl
1741 dnl Platforms configuration
1742 dnl
1743 AC_ARG_WITH([platforms],
1744     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1745         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1746         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1747     [with_platforms="$withval"],
1748     [with_platforms=auto])
1749
1750 # Reuse the autodetection rather than duplicating it.
1751 if test "x$with_platforms" = xauto; then
1752     with_platforms=$with_egl_platforms
1753 fi
1754
1755 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1756         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1757         WAYLAND_SCANNER='')
1758 if test "x$WAYLAND_SCANNER" = x; then
1759     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1760 fi
1761
1762 PKG_CHECK_EXISTS([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED], [have_wayland_protocols=yes], [have_wayland_protocols=no])
1763 if test "x$have_wayland_protocols" = xyes; then
1764     ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1765 fi
1766 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
1767
1768 # Do per platform setups and checks
1769 platforms=`IFS=', '; echo $with_platforms`
1770 for plat in $platforms; do
1771     case "$plat" in
1772     wayland)
1773
1774         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1775         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1776
1777         if test "x$WAYLAND_SCANNER" = "x:"; then
1778                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1779         fi
1780         if test "x$have_wayland_protocols" = xno; then
1781                 AC_MSG_ERROR([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED is needed to compile the wayland platform])
1782         fi
1783         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1784         ;;
1785
1786     x11)
1787         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1788         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1789         ;;
1790
1791     drm)
1792         test "x$enable_gbm" = "xno" &&
1793                 AC_MSG_ERROR([EGL platform drm needs gbm])
1794         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1795         ;;
1796
1797     surfaceless)
1798         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1799         ;;
1800
1801     android)
1802         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1803         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1804         ;;
1805
1806     *)
1807         AC_MSG_ERROR([platform '$plat' does not exist])
1808         ;;
1809     esac
1810
1811     case "$plat" in
1812     wayland|drm|surfaceless)
1813         require_libdrm "Platform $plat"
1814         ;;
1815     esac
1816 done
1817
1818 if test "x$enable_glx" != xno; then
1819     if ! echo "$platforms" | grep -q 'x11'; then
1820         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1821     fi
1822 fi
1823
1824 if test x"$enable_dri3" = xyes; then
1825     DEFINES="$DEFINES -DHAVE_DRI3"
1826
1827     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1828     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1829 fi
1830
1831 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1832 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1833 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1834 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1835 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1836
1837 dnl
1838 dnl More DRI setup
1839 dnl
1840 dnl Directory for DRI drivers
1841 AC_ARG_WITH([dri-driverdir],
1842     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1843         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1844     [DRI_DRIVER_INSTALL_DIR="$withval"],
1845     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1846 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1847 dnl Extra search path for DRI drivers
1848 AC_ARG_WITH([dri-searchpath],
1849     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1850         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1851     [DRI_DRIVER_SEARCH_DIR="$withval"],
1852     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1853 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1854 dnl Which drivers to build - default is chosen by platform
1855 AC_ARG_WITH([dri-drivers],
1856     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1857         [comma delimited classic DRI drivers list, e.g.
1858         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1859     [with_dri_drivers="$withval"],
1860     [with_dri_drivers=auto])
1861
1862 if test "x$with_dri_drivers" = xauto; then
1863     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1864         with_dri_drivers="yes"
1865     else
1866         with_dri_drivers="no"
1867     fi
1868 fi
1869 if test "x$with_dri_drivers" = xno; then
1870     with_dri_drivers=''
1871 fi
1872
1873 # Check for expat
1874 PKG_CHECK_MODULES([EXPAT], [expat],,
1875     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1876 )
1877
1878 dnl If $with_dri_drivers is yes, drivers will be added through
1879 dnl platform checks. Set DEFINES and LIB_DEPS
1880 if test "x$enable_dri" = xyes; then
1881     # Platform specific settings and drivers to build
1882     case "$host_os" in
1883     linux*)
1884         case "$host_cpu" in
1885         powerpc* | sparc*)
1886             # Build only the drivers for cards that exist on PowerPC/sparc
1887             if test "x$with_dri_drivers" = "xyes"; then
1888                 with_dri_drivers="r200 radeon swrast"
1889             fi
1890             ;;
1891         esac
1892         ;;
1893     cygwin*)
1894         if test "x$with_dri_drivers" = "xyes"; then
1895             with_dri_drivers="swrast"
1896         fi
1897         ;;
1898     darwin*)
1899         DEFINES="$DEFINES -DBUILDING_MESA"
1900         if test "x$with_dri_drivers" = "xyes"; then
1901             with_dri_drivers="swrast"
1902         fi
1903         ;;
1904     esac
1905
1906     # default drivers
1907     if test "x$with_dri_drivers" = "xyes"; then
1908         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1909     fi
1910
1911     # put all the necessary libs together
1912     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1913 fi
1914
1915 AC_SUBST([DRI_LIB_DEPS])
1916
1917 DRI_DIRS=''
1918 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1919 if test -n "$with_dri_drivers"; then
1920     if test "x$enable_opengl" != xyes; then
1921         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1922     fi
1923
1924     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1925     for driver in $dri_drivers; do
1926         DRI_DIRS="$DRI_DIRS $driver"
1927         case "x$driver" in
1928         xi915)
1929             require_libdrm "i915"
1930             HAVE_I915_DRI=yes
1931             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1932             ;;
1933         xi965)
1934             require_libdrm "i965"
1935             HAVE_I965_DRI=yes
1936             ;;
1937         xnouveau)
1938             require_libdrm "nouveau"
1939             HAVE_NOUVEAU_DRI=yes
1940             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1941             ;;
1942         xradeon)
1943             require_libdrm "radeon"
1944             HAVE_RADEON_DRI=yes;
1945             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1946             ;;
1947         xr200)
1948             require_libdrm "r200"
1949             HAVE_R200_DRI=yes
1950             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1951             ;;
1952         xswrast)
1953             HAVE_SWRAST_DRI=yes
1954             ;;
1955         *)
1956             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1957             ;;
1958         esac
1959     done
1960     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1961 fi
1962
1963
1964 dnl
1965 dnl Gallium LLVM
1966 dnl Deprecated: kept for backwards compatibility
1967 dnl
1968 AC_ARG_ENABLE([gallium-llvm],
1969     [AS_HELP_STRING([--enable-gallium-llvm],
1970         [DEPRECATED: use --enable-llvm instead])],
1971     [enable_gallium_llvm="$enableval"],
1972     [enable_gallium_llvm=auto])
1973
1974 if test "x$enable_gallium_llvm" != xauto; then
1975    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1976    enable_llvm=$enable_gallium_llvm
1977 fi
1978
1979 dnl
1980 dnl LLVM
1981 dnl
1982 AC_ARG_ENABLE([llvm],
1983     [AS_HELP_STRING([--enable-llvm],
1984         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1985     [enable_llvm="$enableval"],
1986     [enable_llvm=auto])
1987
1988 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1989     if test "x$FOUND_LLVM" = xyes; then
1990         case "$host_cpu" in
1991         i*86|x86_64|amd64) enable_llvm=yes;;
1992         *) enable_llvm=no;;
1993         esac
1994     else
1995         enable_llvm=no
1996     fi
1997 fi
1998
1999 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2000     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2001 fi
2002
2003 #
2004 # Vulkan driver configuration
2005 #
2006
2007 AC_ARG_WITH([vulkan-drivers],
2008     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2009         [comma delimited Vulkan drivers list, e.g.
2010         "intel,radeon"
2011         @<:@default=no@:>@])],
2012     [with_vulkan_drivers="$withval"],
2013     [with_vulkan_drivers="no"])
2014
2015 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2016 # here so that the script doesn't choke on an unknown driver name later.
2017 case "x$with_vulkan_drivers" in
2018     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2019     xno) with_vulkan_drivers='' ;;
2020 esac
2021
2022 AC_ARG_WITH([vulkan-icddir],
2023     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2024         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2025     [VULKAN_ICD_INSTALL_DIR="$withval"],
2026     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2027 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2028
2029 require_x11_dri3() {
2030     if echo "$platforms" | grep -q 'x11'; then
2031         if test "x$enable_dri3" != xyes; then
2032             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2033         fi
2034     fi
2035 }
2036
2037 if test -n "$with_vulkan_drivers"; then
2038     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2039         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2040     fi
2041
2042     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2043     for driver in $VULKAN_DRIVERS; do
2044         case "x$driver" in
2045         xintel)
2046             require_libdrm "ANV"
2047             require_x11_dri3 "ANV"
2048             HAVE_INTEL_VULKAN=yes
2049             ;;
2050         xradeon)
2051             require_libdrm "radv"
2052             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2053             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2054             require_x11_dri3 "radv"
2055             HAVE_RADEON_VULKAN=yes
2056             ;;
2057         *)
2058             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2059             ;;
2060         esac
2061     done
2062     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2063 fi
2064
2065
2066 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2067 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2068 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2069                                   "x$enable_osmesa" = xyes -o \
2070                                   -n "$DRI_DIRS")
2071
2072 dnl
2073 dnl OSMesa configuration
2074 dnl
2075
2076 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2077 AC_ARG_WITH([osmesa-bits],
2078     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2079         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2080     [osmesa_bits="$withval"],
2081     [osmesa_bits=8])
2082 if test "x$osmesa_bits" != x8; then
2083     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2084         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2085         osmesa_bits=8
2086     fi
2087 fi
2088 case "x$osmesa_bits" in
2089 x8)
2090     OSMESA_LIB="${OSMESA_LIB}"
2091     ;;
2092 x16|x32)
2093     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2094     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2095     ;;
2096 *)
2097     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2098     ;;
2099 esac
2100
2101 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2102     # only link libraries with osmesa if shared
2103     if test "$enable_static" = no; then
2104         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2105     else
2106         OSMESA_LIB_DEPS=""
2107     fi
2108     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2109 fi
2110
2111 AC_SUBST([OSMESA_LIB_DEPS])
2112 AC_SUBST([OSMESA_PC_REQ])
2113 AC_SUBST([OSMESA_PC_LIB_PRIV])
2114
2115 dnl
2116 dnl gbm configuration
2117 dnl
2118 if test "x$enable_gbm" = xyes; then
2119     require_dri_shared_libs_and_glapi "gbm"
2120 fi
2121 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2122 # FINISHME: GBM has a number of dependencies which we should add below
2123 GBM_PC_REQ_PRIV=""
2124 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2125 AC_SUBST([GBM_PC_REQ_PRIV])
2126 AC_SUBST([GBM_PC_LIB_PRIV])
2127
2128 dnl
2129 dnl EGL configuration
2130 dnl
2131
2132 if test "x$enable_egl" = xyes; then
2133     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2134
2135     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2136
2137     require_dri_shared_libs_and_glapi "egl"
2138 fi
2139 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2140 AC_SUBST([EGL_LIB_DEPS])
2141
2142 gallium_st="mesa"
2143
2144 dnl
2145 dnl XA configuration
2146 dnl
2147 if test "x$enable_xa" = xyes; then
2148     if test "x$with_gallium_drivers" = xswrast; then
2149        AC_MSG_ERROR([
2150           Building xa requires at least one non swrast gallium driver.
2151           If you are looking to use libxatracker.so with the VMware driver,
2152           make sure to include svga in the gallium drivers list, apart from
2153           enabling XA.
2154           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2155     fi
2156     gallium_st="$gallium_st xa"
2157 fi
2158 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2159
2160 if echo $platforms | grep -q "x11"; then
2161     have_xvmc_platform=yes
2162 else
2163     have_xvmc_platform=no
2164 fi
2165
2166 if echo $platforms | grep -q "x11"; then
2167     have_vdpau_platform=yes
2168 else
2169     have_vdpau_platform=no
2170 fi
2171
2172 if echo $platforms | grep -q "x11\|drm"; then
2173     have_omx_platform=yes
2174 else
2175     have_omx_platform=no
2176 fi
2177
2178 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2179     have_va_platform=yes
2180 else
2181     have_va_platform=no
2182 fi
2183
2184 dnl
2185 dnl Gallium G3DVL configuration
2186 dnl
2187 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2188     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2189         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2190     fi
2191
2192     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2193         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2194     fi
2195
2196     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2197         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2198     fi
2199
2200     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2201         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2202     fi
2203 fi
2204
2205 if test "x$enable_dri" = xyes -o \
2206         "x$enable_xvmc" = xyes -o \
2207         "x$enable_vdpau" = xyes -o \
2208         "x$enable_omx_bellagio" = xyes -o \
2209         "x$enable_va" = xyes; then
2210     need_gallium_vl=yes
2211 fi
2212 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2213
2214 if test "x$enable_xvmc" = xyes -o \
2215         "x$enable_vdpau" = xyes -o \
2216         "x$enable_omx_bellagio" = xyes -o \
2217         "x$enable_va" = xyes; then
2218     if echo $platforms | grep -q "x11"; then
2219         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2220     fi
2221     need_gallium_vl_winsys=yes
2222 fi
2223 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2224
2225 if test "x$enable_xvmc" = xyes; then
2226     if test "x$have_xvmc_platform" != xyes; then
2227         AC_MSG_ERROR([XVMC requires the x11 platforms])
2228     fi
2229     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2230     gallium_st="$gallium_st xvmc"
2231 fi
2232 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2233
2234 if test "x$enable_vdpau" = xyes; then
2235     if test "x$have_vdpau_platform" != xyes; then
2236         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2237     fi
2238     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2239     gallium_st="$gallium_st vdpau"
2240     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2241 fi
2242 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2243
2244 if test "x$enable_omx_bellagio" = xyes; then
2245     if test "x$have_omx_platform" != xyes; then
2246         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2247     fi
2248     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2249     gallium_st="$gallium_st omx_bellagio"
2250 fi
2251 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2252
2253 if test "x$enable_va" = xyes; then
2254     if test "x$have_va_platform" != xyes; then
2255         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2256     fi
2257     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2258     gallium_st="$gallium_st va"
2259 fi
2260 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2261
2262 dnl
2263 dnl Nine Direct3D9 configuration
2264 dnl
2265 if test "x$enable_nine" = xyes; then
2266     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2267         AC_MSG_ERROR([nine requires the gallium swrast driver])
2268     fi
2269     if test "x$with_gallium_drivers" = xswrast; then
2270         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2271     fi
2272     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2273         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2274     fi
2275
2276     if test "x$enable_dri3" = xno; then
2277         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2278     fi
2279
2280     gallium_st="$gallium_st nine"
2281 fi
2282 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2283
2284 dnl
2285 dnl OpenCL configuration
2286 dnl
2287
2288 AC_ARG_WITH([clang-libdir],
2289    [AS_HELP_STRING([--with-clang-libdir],
2290          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2291    [CLANG_LIBDIR="$withval"],
2292    [CLANG_LIBDIR=''])
2293
2294 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2295
2296 if test "x$enable_opencl" = xyes; then
2297     if test -z "$with_gallium_drivers"; then
2298         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2299     fi
2300
2301     if test "x$HAVE_CXX11" != "xyes"; then
2302        AC_MSG_ERROR([clover requires c++11 support])
2303     fi
2304
2305     if test "x$have_libclc" = xno; then
2306         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2307                     Make sure the directory containing libclc.pc is specified in your
2308                     PKG_CONFIG_PATH environment variable.
2309                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2310     else
2311         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2312         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2313         AC_SUBST([LIBCLC_INCLUDEDIR])
2314         AC_SUBST([LIBCLC_LIBEXECDIR])
2315     fi
2316
2317     gallium_st="$gallium_st clover"
2318
2319     if test "x$enable_opencl_icd" = xyes; then
2320         OPENCL_LIBNAME="MesaOpenCL"
2321     else
2322         OPENCL_LIBNAME="OpenCL"
2323     fi
2324
2325     if test "x$have_libelf" != xyes; then
2326        AC_MSG_ERROR([Clover requires libelf])
2327     fi
2328
2329     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2330         altivec_enabled=no
2331         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2332         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2333         #error "AltiVec not enabled"
2334         #endif
2335         ])], altivec_enabled=yes)
2336
2337         if test "$altivec_enabled" = yes; then
2338             CLOVER_STD_OVERRIDE="-std=gnu++11"
2339         fi
2340         AC_SUBST([CLOVER_STD_OVERRIDE])
2341     fi
2342
2343     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2344
2345     llvm_add_default_components "opencl"
2346     llvm_add_component "all-targets" "opencl"
2347     llvm_add_component "coverage" "opencl"
2348     llvm_add_component "linker" "opencl"
2349     llvm_add_component "instrumentation" "opencl"
2350     llvm_add_component "ipo" "opencl"
2351     llvm_add_component "irreader" "opencl"
2352     llvm_add_component "lto" "opencl"
2353     llvm_add_component "option" "opencl"
2354     llvm_add_component "objcarcopts" "opencl"
2355     llvm_add_component "profiledata" "opencl"
2356     llvm_add_optional_component "coroutines" "opencl"
2357
2358     dnl Check for Clang internal headers
2359     if test -z "$CLANG_LIBDIR"; then
2360         CLANG_LIBDIR=${LLVM_LIBDIR}
2361     fi
2362     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2363     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2364         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2365 fi
2366 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2367 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2368 AC_SUBST([OPENCL_LIBNAME])
2369 AC_SUBST([CLANG_RESOURCE_DIR])
2370
2371 dnl
2372 dnl Gallium configuration
2373 dnl
2374 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2375
2376 # libEGL wants to default to the first platform specified in
2377 # ./configure.  parse that here.
2378 if test "x$platforms" != "x"; then
2379     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2380     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2381 else
2382     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2383 fi
2384
2385 AC_SUBST([EGL_NATIVE_PLATFORM])
2386 AC_SUBST([EGL_CFLAGS])
2387
2388 # If we don't have the X11 platform, set this define so we don't try to include
2389 # the X11 headers.
2390 if ! echo "$platforms" | grep -q 'x11'; then
2391     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2392     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2393 fi
2394
2395 dnl Directory for XVMC libs
2396 AC_ARG_WITH([xvmc-libdir],
2397     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2398         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2399     [XVMC_LIB_INSTALL_DIR="$withval"],
2400     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2401 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2402
2403 dnl
2404 dnl Gallium Tests
2405 dnl
2406 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2407
2408 dnl Directory for VDPAU libs
2409 AC_ARG_WITH([vdpau-libdir],
2410     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2411         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2412     [VDPAU_LIB_INSTALL_DIR="$withval"],
2413     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2414 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2415
2416 dnl Directory for OMX_BELLAGIO libs
2417
2418 AC_ARG_WITH([omx-bellagio-libdir],
2419     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2420         [directory for the OMX_BELLAGIO libraries])],
2421     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2422     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2423                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2424 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2425
2426 dnl Directory for VA libs
2427
2428 AC_ARG_WITH([va-libdir],
2429     [AS_HELP_STRING([--with-va-libdir=DIR],
2430         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2431     [VA_LIB_INSTALL_DIR="$withval"],
2432     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2433 AC_SUBST([VA_LIB_INSTALL_DIR])
2434
2435 AC_ARG_WITH([d3d-libdir],
2436     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2437         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2438     [D3D_DRIVER_INSTALL_DIR="$withval"],
2439     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2440 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2441
2442 dnl Architectures to build SWR library for
2443
2444 AC_ARG_WITH([swr-archs],
2445     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2446         [comma delimited swr architectures list, e.g.
2447         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2448     [with_swr_archs="$withval"],
2449     [with_swr_archs="avx,avx2"])
2450
2451 dnl
2452 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2453 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2454 dnl architectures.
2455 dnl
2456 r300_require_llvm() {
2457     case "$host" in *gnux32) return;; esac
2458     case "$host_cpu" in
2459     i*86|x86_64|amd64) require_llvm $1
2460         ;;
2461     esac
2462 }
2463
2464 dnl
2465 dnl DRM is needed by X, Wayland, and offscreen rendering.
2466 dnl Surfaceless is an alternative for the last one.
2467 dnl
2468 require_basic_egl() {
2469     case "$with_platforms" in
2470         *drm*|*surfaceless*|*android*)
2471             ;;
2472         *)
2473             AC_MSG_ERROR([$1 requires one of these:
2474                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2475                   2) --with-platforms=surfaceless (offscreen only)
2476                   3) --with-platforms=android (Android only)
2477                   Recommended options: drm,x11])
2478             ;;
2479     esac
2480 }
2481
2482 swr_require_cxx_feature_flags() {
2483     feature_name="$1"
2484     preprocessor_test="$2"
2485     option_list="$3"
2486     output_var="$4"
2487
2488     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2489     AC_LANG_PUSH([C++])
2490     save_CXXFLAGS="$CXXFLAGS"
2491     save_IFS="$IFS"
2492     IFS=","
2493     found=0
2494     for opts in $option_list
2495     do
2496         unset IFS
2497         CXXFLAGS="$opts $save_CXXFLAGS"
2498         AC_COMPILE_IFELSE(
2499             [AC_LANG_PROGRAM(
2500                 [   #if !($preprocessor_test)
2501                     #error
2502                     #endif
2503                 ])],
2504             [found=1; break],
2505             [])
2506         IFS=","
2507     done
2508     IFS="$save_IFS"
2509     CXXFLAGS="$save_CXXFLAGS"
2510     AC_LANG_POP([C++])
2511     if test $found -eq 1; then
2512         AC_MSG_RESULT([$opts])
2513         eval "$output_var=\$opts"
2514         return 0
2515     fi
2516     AC_MSG_RESULT([no])
2517     AC_MSG_ERROR([swr requires $feature_name support])
2518     return 1
2519 }
2520
2521 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2522 if test -n "$with_gallium_drivers"; then
2523     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2524     for driver in $gallium_drivers; do
2525         case "x$driver" in
2526         xsvga)
2527             HAVE_GALLIUM_SVGA=yes
2528             require_libdrm "svga"
2529             ;;
2530         xi915)
2531             HAVE_GALLIUM_I915=yes
2532             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2533             require_libdrm "Gallium i915"
2534             ;;
2535         xr300)
2536             HAVE_GALLIUM_R300=yes
2537             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2538             require_libdrm "r300"
2539             r300_require_llvm "r300"
2540             ;;
2541         xr600)
2542             HAVE_GALLIUM_R600=yes
2543             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2544             require_libdrm "r600"
2545             if test "x$enable_llvm" = xyes; then
2546                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2547
2548                 llvm_add_component "asmparser" "r600"
2549                 llvm_add_component "bitreader" "r600"
2550             fi
2551             ;;
2552         xradeonsi)
2553             HAVE_GALLIUM_RADEONSI=yes
2554             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2555             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2556             require_libdrm "radeonsi"
2557             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2558             if test "x$enable_egl" = xyes; then
2559                 require_basic_egl "radeonsi"
2560             fi
2561             ;;
2562         xnouveau)
2563             HAVE_GALLIUM_NOUVEAU=yes
2564             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2565             require_libdrm "nouveau"
2566             ;;
2567         xfreedreno)
2568             HAVE_GALLIUM_FREEDRENO=yes
2569             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2570             require_libdrm "freedreno"
2571             ;;
2572         xetnaviv)
2573             HAVE_GALLIUM_ETNAVIV=yes
2574             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2575             require_libdrm "etnaviv"
2576             ;;
2577        ximx)
2578             HAVE_GALLIUM_IMX=yes
2579             ;;
2580         xswrast)
2581             HAVE_GALLIUM_SOFTPIPE=yes
2582             if test "x$enable_llvm" = xyes; then
2583                 HAVE_GALLIUM_LLVMPIPE=yes
2584             fi
2585             ;;
2586         xswr)
2587             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2588
2589             if test "x$HAVE_CXX11" != "xyes"; then
2590                 AC_MSG_ERROR([swr requires c++11 support])
2591             fi
2592
2593             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2594                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2595                 SWR_AVX_CXXFLAGS
2596             AC_SUBST([SWR_AVX_CXXFLAGS])
2597
2598             swr_archs=`IFS=', '; echo $with_swr_archs`
2599             for arch in $swr_archs; do
2600                 case "x$arch" in
2601                 xavx)
2602                     HAVE_SWR_AVX=yes
2603                     ;;
2604                 xavx2)
2605                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2606                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2607                         SWR_AVX2_CXXFLAGS
2608                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2609                     HAVE_SWR_AVX2=yes
2610                     ;;
2611                 xknl)
2612                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2613                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2614                         SWR_KNL_CXXFLAGS
2615                     AC_SUBST([SWR_KNL_CXXFLAGS])
2616                     HAVE_SWR_KNL=yes
2617                     ;;
2618                 xskx)
2619                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2620                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2621                         SWR_SKX_CXXFLAGS
2622                     AC_SUBST([SWR_SKX_CXXFLAGS])
2623                     HAVE_SWR_SKX=yes
2624                     ;;
2625                 *)
2626                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2627                     ;;
2628                 esac
2629             done
2630
2631             if test "x$HAVE_SWR_AVX" != xyes -a \
2632                     "x$HAVE_SWR_AVX2" != xyes -a \
2633                     "x$HAVE_SWR_KNL" != xyes -a \
2634                     "x$HAVE_SWR_SKX" != xyes; then
2635                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2636             fi
2637
2638             HAVE_GALLIUM_SWR=yes
2639             ;;
2640         xvc4)
2641             HAVE_GALLIUM_VC4=yes
2642             require_libdrm "vc4"
2643
2644             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2645                               [USE_VC4_SIMULATOR=yes;
2646                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2647                               [USE_VC4_SIMULATOR=no])
2648             ;;
2649         xvc5)
2650             HAVE_GALLIUM_VC5=yes
2651
2652             PKG_CHECK_MODULES([VC5_SIMULATOR], [v3dv3],
2653                               [USE_VC5_SIMULATOR=yes;
2654                                DEFINES="$DEFINES -DUSE_VC5_SIMULATOR"],
2655                               [AC_MSG_ERROR([vc5 requires the simulator])])
2656             ;;
2657         xpl111)
2658             HAVE_GALLIUM_PL111=yes
2659             ;;
2660         xvirgl)
2661             HAVE_GALLIUM_VIRGL=yes
2662             require_libdrm "virgl"
2663             if test "x$enable_egl" = xyes; then
2664                 require_basic_egl "virgl"
2665             fi
2666             ;;
2667         *)
2668             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2669             ;;
2670         esac
2671     done
2672 fi
2673
2674 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2675 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2676                                               "x$LLVM_VERSION" != x3.9.1)
2677
2678 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2679     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2680     llvm_add_default_components "gallium"
2681 fi
2682
2683 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2684 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2685 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2686 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2687
2688 dnl We need to validate some needed dependencies for renderonly drivers.
2689
2690 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2691     AC_MSG_ERROR([Building with imx requires etnaviv])
2692 fi
2693
2694 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2695     AC_MSG_ERROR([Building with pl111 requires vc4])
2696 fi
2697
2698
2699 detect_old_buggy_llvm() {
2700     dnl llvm-config may not give the right answer when llvm is a built as a
2701     dnl single shared library, so we must work the library name out for
2702     dnl ourselves.
2703     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2704     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2705     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2706     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2707
2708     if test "x$llvm_have_one_so" = xyes; then
2709         dnl LLVM was built using auto*, so there is only one shared object.
2710         LLVM_LIBS="-l$LLVM_SO_NAME"
2711     else
2712         dnl If LLVM was built with CMake, there will be one shared object per
2713         dnl component.
2714         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2715                [AC_MSG_ERROR([Could not find llvm shared libraries:
2716                 Please make sure you have built llvm with the --enable-shared option
2717                 and that your llvm libraries are installed in $LLVM_LIBDIR
2718                 If you have installed your llvm libraries to a different directory you
2719                 can use the --with-llvm-prefix= configure flag to specify this directory.
2720                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2721                 If you do not want to build with llvm shared libraries and instead want to
2722                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2723                 invocation and rebuild.])])
2724
2725         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2726         dnl install uses a shared object for each component and we have
2727         dnl already added all of these objects to LLVM_LIBS.
2728     fi
2729 }
2730
2731 dnl
2732 dnl Set defines and buildtime variables only when using LLVM.
2733 dnl
2734 if test "x$enable_llvm" = xyes; then
2735     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2736
2737     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2738     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2739     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2740
2741     dnl Set LLVM_LIBS - This is done after the driver configuration so
2742     dnl that drivers can add additional components to LLVM_COMPONENTS.
2743     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2744     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2745     dnl this was causing the same libraries to be appear multiple times
2746     dnl in LLVM_LIBS.
2747
2748     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2749         if test "x$enable_llvm_shared_libs" = xyes; then
2750             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2751         else
2752             dnl Invoking llvm-config with both -libs and --system-libs produces the
2753             dnl two separate lines - each for the set of libraries.
2754                 dnl Call the program twice, effectively folding them into a single line.
2755             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2756             dnl We need to link to llvm system libs when using static libs
2757             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2758         fi
2759     else
2760         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2761         if test "x$enable_llvm_shared_libs" = xyes; then
2762             detect_old_buggy_llvm
2763         else
2764             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2765             dnl We need to link to llvm system libs when using static libs
2766             dnl However, only llvm 3.5+ provides --system-libs
2767             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2768                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2769             fi
2770         fi
2771     fi
2772 fi
2773
2774 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2775 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2776 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2777 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2778 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2779 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2780 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2781 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2782 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2783 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2784 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2785 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2786 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2787 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2788 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2789                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2790                                          "x$HAVE_GALLIUM_SWR" = xyes)
2791 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2792 AM_CONDITIONAL(HAVE_GALLIUM_VC5, test "x$HAVE_GALLIUM_VC5" = xyes)
2793 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2794
2795 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2796
2797 if test "x$enable_dri" = xyes; then
2798     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2799 fi
2800
2801 if test "x$have_drisw_kms" = xyes; then
2802     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2803 fi
2804 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2805
2806 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2807 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2808 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2809 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2810 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2811 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2812
2813 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2814 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2815
2816 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2817                                       "x$HAVE_RADEON_VULKAN" = xyes)
2818
2819 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2820                                       "x$HAVE_GALLIUM_VC5" = xyes)
2821
2822 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2823                                         "x$HAVE_I965_DRI" = xyes)
2824
2825 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2826                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2827                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2828 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2829 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2830 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2831 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2832 AM_CONDITIONAL(USE_VC5_SIMULATOR, test x$USE_VC5_SIMULATOR = xyes)
2833
2834 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2835 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2836 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2837 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2838                                         "x$enable_gallium_osmesa" = xyes)
2839
2840 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2841 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2842 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2843 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2844 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2845 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2846
2847 AC_SUBST([NINE_MAJOR], 1)
2848 AC_SUBST([NINE_MINOR], 0)
2849 AC_SUBST([NINE_TINY], 0)
2850 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2851
2852 AC_SUBST([VDPAU_MAJOR], 1)
2853 AC_SUBST([VDPAU_MINOR], 0)
2854
2855 if test "x$enable_va" = xyes; then
2856     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2857     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2858 fi
2859 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2860 AC_SUBST([VA_MINOR], $VA_MINOR)
2861
2862 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2863
2864 AC_SUBST([XVMC_MAJOR], 1)
2865 AC_SUBST([XVMC_MINOR], 0)
2866
2867 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2868 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2869 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2870 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2871
2872 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2873 AC_SUBST([XA_MINOR], $XA_MINOR)
2874 AC_SUBST([XA_TINY], $XA_TINY)
2875 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2876
2877 AC_ARG_ENABLE(valgrind,
2878               [AS_HELP_STRING([--enable-valgrind],
2879                              [Build mesa with valgrind support (default: auto)])],
2880                              [VALGRIND=$enableval], [VALGRIND=auto])
2881 if test "x$VALGRIND" != xno; then
2882     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2883 fi
2884 AC_MSG_CHECKING([whether to enable Valgrind support])
2885 if test "x$VALGRIND" = xauto; then
2886     VALGRIND="$have_valgrind"
2887 fi
2888
2889 if test "x$VALGRIND" = "xyes"; then
2890     if ! test "x$have_valgrind" = xyes; then
2891         AC_MSG_ERROR([Valgrind support required but not present])
2892     fi
2893     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2894 fi
2895
2896 AC_MSG_RESULT([$VALGRIND])
2897
2898 dnl Restore LDFLAGS and CPPFLAGS
2899 LDFLAGS="$_SAVE_LDFLAGS"
2900 CPPFLAGS="$_SAVE_CPPFLAGS"
2901
2902 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2903 if test "x$acv_mesa_CLANG" = xyes; then
2904     CFLAGS="$CFLAGS -Qunused-arguments"
2905     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2906 fi
2907
2908 dnl Add user CFLAGS and CXXFLAGS
2909 CFLAGS="$CFLAGS $USER_CFLAGS"
2910 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2911
2912 dnl Substitute the config
2913 AC_CONFIG_FILES([Makefile
2914                  src/Makefile
2915                  src/amd/Makefile
2916                  src/amd/vulkan/Makefile
2917                  src/broadcom/Makefile
2918                  src/compiler/Makefile
2919                  src/egl/Makefile
2920                  src/egl/main/egl.pc
2921                  src/egl/wayland/wayland-drm/Makefile
2922                  src/egl/wayland/wayland-egl/Makefile
2923                  src/egl/wayland/wayland-egl/wayland-egl.pc
2924                  src/gallium/Makefile
2925                  src/gallium/auxiliary/Makefile
2926                  src/gallium/auxiliary/pipe-loader/Makefile
2927                  src/gallium/drivers/freedreno/Makefile
2928                  src/gallium/drivers/ddebug/Makefile
2929                  src/gallium/drivers/i915/Makefile
2930                  src/gallium/drivers/llvmpipe/Makefile
2931                  src/gallium/drivers/noop/Makefile
2932                  src/gallium/drivers/nouveau/Makefile
2933                  src/gallium/drivers/pl111/Makefile
2934                  src/gallium/drivers/r300/Makefile
2935                  src/gallium/drivers/r600/Makefile
2936                  src/gallium/drivers/radeon/Makefile
2937                  src/gallium/drivers/radeonsi/Makefile
2938                  src/gallium/drivers/rbug/Makefile
2939                  src/gallium/drivers/softpipe/Makefile
2940                  src/gallium/drivers/svga/Makefile
2941                  src/gallium/drivers/swr/Makefile
2942                  src/gallium/drivers/trace/Makefile
2943                  src/gallium/drivers/etnaviv/Makefile
2944                  src/gallium/drivers/imx/Makefile
2945                  src/gallium/drivers/vc4/Makefile
2946                  src/gallium/drivers/vc5/Makefile
2947                  src/gallium/drivers/virgl/Makefile
2948                  src/gallium/state_trackers/clover/Makefile
2949                  src/gallium/state_trackers/dri/Makefile
2950                  src/gallium/state_trackers/glx/xlib/Makefile
2951                  src/gallium/state_trackers/nine/Makefile
2952                  src/gallium/state_trackers/omx_bellagio/Makefile
2953                  src/gallium/state_trackers/osmesa/Makefile
2954                  src/gallium/state_trackers/va/Makefile
2955                  src/gallium/state_trackers/vdpau/Makefile
2956                  src/gallium/state_trackers/xa/Makefile
2957                  src/gallium/state_trackers/xvmc/Makefile
2958                  src/gallium/targets/d3dadapter9/Makefile
2959                  src/gallium/targets/d3dadapter9/d3d.pc
2960                  src/gallium/targets/dri/Makefile
2961                  src/gallium/targets/libgl-xlib/Makefile
2962                  src/gallium/targets/omx-bellagio/Makefile
2963                  src/gallium/targets/opencl/Makefile
2964                  src/gallium/targets/opencl/mesa.icd
2965                  src/gallium/targets/osmesa/Makefile
2966                  src/gallium/targets/osmesa/osmesa.pc
2967                  src/gallium/targets/pipe-loader/Makefile
2968                  src/gallium/targets/va/Makefile
2969                  src/gallium/targets/vdpau/Makefile
2970                  src/gallium/targets/xa/Makefile
2971                  src/gallium/targets/xa/xatracker.pc
2972                  src/gallium/targets/xvmc/Makefile
2973                  src/gallium/tests/trivial/Makefile
2974                  src/gallium/tests/unit/Makefile
2975                  src/gallium/winsys/etnaviv/drm/Makefile
2976                  src/gallium/winsys/imx/drm/Makefile
2977                  src/gallium/winsys/freedreno/drm/Makefile
2978                  src/gallium/winsys/i915/drm/Makefile
2979                  src/gallium/winsys/nouveau/drm/Makefile
2980                  src/gallium/winsys/pl111/drm/Makefile
2981                  src/gallium/winsys/radeon/drm/Makefile
2982                  src/gallium/winsys/amdgpu/drm/Makefile
2983                  src/gallium/winsys/svga/drm/Makefile
2984                  src/gallium/winsys/sw/dri/Makefile
2985                  src/gallium/winsys/sw/kms-dri/Makefile
2986                  src/gallium/winsys/sw/null/Makefile
2987                  src/gallium/winsys/sw/wrapper/Makefile
2988                  src/gallium/winsys/sw/xlib/Makefile
2989                  src/gallium/winsys/vc4/drm/Makefile
2990                  src/gallium/winsys/vc5/drm/Makefile
2991                  src/gallium/winsys/virgl/drm/Makefile
2992                  src/gallium/winsys/virgl/vtest/Makefile
2993                  src/gbm/Makefile
2994                  src/gbm/main/gbm.pc
2995                  src/glx/Makefile
2996                  src/glx/apple/Makefile
2997                  src/glx/tests/Makefile
2998                  src/glx/windows/Makefile
2999                  src/glx/windows/windowsdriproto.pc
3000                  src/gtest/Makefile
3001                  src/intel/Makefile
3002                  src/loader/Makefile
3003                  src/mapi/Makefile
3004                  src/mapi/es1api/glesv1_cm.pc
3005                  src/mapi/es2api/glesv2.pc
3006                  src/mapi/glapi/gen/Makefile
3007                  src/mesa/Makefile
3008                  src/mesa/gl.pc
3009                  src/mesa/drivers/dri/dri.pc
3010                  src/mesa/drivers/dri/common/Makefile
3011                  src/mesa/drivers/dri/i915/Makefile
3012                  src/mesa/drivers/dri/i965/Makefile
3013                  src/mesa/drivers/dri/Makefile
3014                  src/mesa/drivers/dri/nouveau/Makefile
3015                  src/mesa/drivers/dri/r200/Makefile
3016                  src/mesa/drivers/dri/radeon/Makefile
3017                  src/mesa/drivers/dri/swrast/Makefile
3018                  src/mesa/drivers/osmesa/Makefile
3019                  src/mesa/drivers/osmesa/osmesa.pc
3020                  src/mesa/drivers/x11/Makefile
3021                  src/mesa/main/tests/Makefile
3022                  src/mesa/state_tracker/tests/Makefile
3023                  src/util/Makefile
3024                  src/util/tests/hash_table/Makefile
3025                  src/util/tests/string_buffer/Makefile
3026                  src/util/xmlpool/Makefile
3027                  src/vulkan/Makefile])
3028
3029 AC_OUTPUT
3030
3031 # Fix up dependencies in *.Plo files, where we changed the extension of a
3032 # source file
3033 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3034
3035 rm -f src/compiler/spirv/spirv_info.lo
3036 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3037
3038 dnl
3039 dnl Output some configuration info for the user
3040 dnl
3041 echo ""
3042 echo "        prefix:          $prefix"
3043 echo "        exec_prefix:     $exec_prefix"
3044 echo "        libdir:          $libdir"
3045 echo "        includedir:      $includedir"
3046
3047 dnl API info
3048 echo ""
3049 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3050
3051 dnl Driver info
3052 echo ""
3053 case "x$enable_osmesa$enable_gallium_osmesa" in
3054 xnoyes)
3055         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3056         ;;
3057 xyesno)
3058         echo "        OSMesa:          lib$OSMESA_LIB"
3059         ;;
3060 xnono)
3061         echo "        OSMesa:          no"
3062         ;;
3063 esac
3064
3065 echo ""
3066 if test "x$enable_dri" != xno; then
3067         echo "        DRI platform:    $dri_platform"
3068         if test -z "$DRI_DIRS"; then
3069             echo "        DRI drivers:     no"
3070         else
3071             echo "        DRI drivers:     $DRI_DIRS"
3072         fi
3073         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3074 fi
3075
3076 case "x$enable_glx" in
3077 xdri)
3078     echo "        GLX:             DRI-based"
3079     ;;
3080 xxlib)
3081     echo "        GLX:             Xlib-based"
3082     ;;
3083 xgallium-xlib)
3084     echo "        GLX:             Xlib-based (Gallium)"
3085     ;;
3086 *)
3087     echo "        GLX:             $enable_glx"
3088     ;;
3089 esac
3090
3091 dnl EGL
3092 echo ""
3093 echo "        EGL:             $enable_egl"
3094 if test "$enable_egl" = yes; then
3095
3096     egl_drivers=""
3097     if test "x$enable_dri" != "xno"; then
3098         egl_drivers="$egl_drivers builtin:egl_dri2"
3099     fi
3100     if test "x$enable_dri3" != "xno"; then
3101         egl_drivers="$egl_drivers builtin:egl_dri3"
3102     fi
3103
3104     echo "        EGL drivers:    $egl_drivers"
3105 fi
3106 if test "x$enable_gbm" = xyes; then
3107     echo "        GBM:             yes"
3108 else
3109     echo "        GBM:             no"
3110 fi
3111
3112     echo "        EGL/Vulkan/VL platforms:   $platforms"
3113
3114 # Vulkan
3115 echo ""
3116 if test "x$VULKAN_DRIVERS" != x; then
3117     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3118     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3119 else
3120     echo "        Vulkan drivers:  no"
3121 fi
3122
3123 echo ""
3124 if test "x$enable_llvm" = xyes; then
3125     echo "        llvm:            yes"
3126     echo "        llvm-config:     $LLVM_CONFIG"
3127     echo "        llvm-version:    $LLVM_VERSION"
3128 else
3129     echo "        llvm:            no"
3130 fi
3131
3132 echo ""
3133 if test -n "$with_gallium_drivers"; then
3134     echo "        Gallium drivers: $gallium_drivers"
3135     echo "        Gallium st:      $gallium_st"
3136 else
3137     echo "        Gallium:         no"
3138 fi
3139
3140 echo ""
3141 if test "x$enable_gallium_extra_hud" != xyes; then
3142     echo "        HUD extra stats: no"
3143 else
3144     echo "        HUD extra stats: yes"
3145 fi
3146
3147 if test "x$enable_lmsensors" != xyes; then
3148     echo "        HUD lmsensors:   no"
3149 else
3150     echo "        HUD lmsensors:   yes"
3151 fi
3152
3153 echo ""
3154 if test "x$HAVE_GALLIUM_SWR" != x; then
3155     echo "        SWR archs:       $swr_archs"
3156 fi
3157
3158 dnl Libraries
3159 echo ""
3160 echo "        Shared libs:     $enable_shared"
3161 echo "        Static libs:     $enable_static"
3162 echo "        Shared-glapi:    $enable_shared_glapi"
3163
3164 dnl Compiler options
3165 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3166 cflags=`echo $CFLAGS | \
3167     $SED 's/^ *//;s/  */ /;s/ *$//'`
3168 cxxflags=`echo $CXXFLAGS | \
3169     $SED 's/^ *//;s/  */ /;s/ *$//'`
3170 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3171 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3172 echo ""
3173 echo "        CFLAGS:          $cflags"
3174 echo "        CXXFLAGS:        $cxxflags"
3175 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3176 echo "        LDFLAGS:         $ldflags"
3177 echo "        Macros:          $defines"
3178 echo ""
3179 if test "x$enable_llvm" = xyes; then
3180     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3181     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3182     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3183     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3184     echo ""
3185 fi
3186 echo "        PYTHON2:         $PYTHON2"
3187
3188 echo ""
3189 echo "        Run '${MAKE-make}' to build Mesa"
3190 echo ""