OSDN Git Service

libdrm: Remove typedef for non-existing enum
[android-x86/external-libdrm.git] / configure.ac
1 #  Copyright 2005 Adam Jackson.
2 #
3 #  Permission is hereby granted, free of charge, to any person obtaining a
4 #  copy of this software and associated documentation files (the "Software"),
5 #  to deal in the Software without restriction, including without limitation
6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
7 #  license, and/or sell copies of the Software, and to permit persons to whom
8 #  the Software is furnished to do so, subject to the following conditions:
9 #
10 #  The above copyright notice and this permission notice (including the next
11 #  paragraph) shall be included in all copies or substantial portions of the
12 #  Software.
13 #
14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20
21 AC_PREREQ(2.57)
22 AC_INIT([libdrm], 2.4.11, [dri-devel@lists.sourceforge.net], libdrm)
23 AC_CONFIG_SRCDIR([Makefile.am])
24 AM_INIT_AUTOMAKE([dist-bzip2])
25
26 AM_CONFIG_HEADER([libdrm/config.h])
27
28 AC_DISABLE_STATIC
29 AC_PROG_LIBTOOL
30 AC_PROG_CC
31
32 AC_HEADER_STDC
33 AC_SYS_LARGEFILE
34
35 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
36 AC_SUBST(PTHREADSTUBS_CFLAGS)
37 AC_SUBST(PTHREADSTUBS_LIBS)
38
39 pkgconfigdir=${libdir}/pkgconfig
40 AC_SUBST(pkgconfigdir)
41 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
42                                 [Enable support for using udev instead of mknod (default: disabled)]),
43                                 [UDEV=$enableval], [UDEV=no])
44
45 AC_ARG_ENABLE(nouveau-experimental-api,
46               AS_HELP_STRING([--enable-nouveau-experimental-api],
47               [Enable support for nouveau's experimental API (default: disabled)]),
48               [NOUVEAU=$enableval], [NOUVEAU=no])
49
50 AC_ARG_ENABLE(radeon-experimental-api,
51               AS_HELP_STRING([--enable-radeon-experimental-api],
52               [Enable support for radeon's KMS API (default: disabled)]),
53               [RADEON=$enableval], [RADEON=no])
54
55 dnl ===========================================================================
56 dnl check compiler flags
57 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
58   AC_MSG_CHECKING([whether $CC supports $1])
59
60   libdrm_save_CFLAGS="$CFLAGS"
61   CFLAGS="$CFLAGS $1"
62
63   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
64   CFLAGS="$libdrm_save_CFLAGS"
65
66   if test "x$libdrm_cc_flag" = "xyes"; then
67     ifelse([$2], , :, [$2])
68   else
69     ifelse([$3], , :, [$3])
70   fi
71   AC_MSG_RESULT([$libdrm_cc_flag])
72 ])
73
74 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
75
76 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
77                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
78                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
79 AC_SUBST([CLOCK_LIB])
80
81 dnl Use lots of warning flags with with gcc and compatible compilers
82
83 dnl Note: if you change the following variable, the cache is automatically
84 dnl skipped and all flags rechecked.  So there's no need to do anything
85 dnl else.  If for any reason you need to force a recheck, just change
86 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
87
88 MAYBE_WARN="-Wall -Wextra \
89 -Wsign-compare -Werror-implicit-function-declaration \
90 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
91 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
92 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
93 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
94 -Wdeclaration-after-statement -Wold-style-definition \
95 -Wno-missing-field-initializers -Wno-unused-parameter \
96 -Wno-attributes -Wno-long-long -Winline"
97
98 # invalidate cached value if MAYBE_WARN has changed
99 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
100         unset libdrm_cv_warn_cflags
101 fi
102 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
103         echo
104         WARN_CFLAGS=""
105
106         # Some warning options are not supported by all versions of
107         # gcc, so test all desired options against the current
108         # compiler.
109         #
110         # Note that there are some order dependencies
111         # here. Specifically, an option that disables a warning will
112         # have no net effect if a later option then enables that
113         # warnings, (perhaps implicitly). So we put some grouped
114         # options (-Wall and -Wextra) up front and the -Wno options
115         # last.
116
117         for W in $MAYBE_WARN; do
118                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
119         done
120
121         libdrm_cv_warn_cflags=$WARN_CFLAGS
122         libdrm_cv_warn_maybe=$MAYBE_WARN
123
124         AC_MSG_CHECKING([which warning flags were supported])])
125 WARN_CFLAGS="$libdrm_cv_warn_cflags"
126
127 if test "x$UDEV" = xyes; then
128         AC_DEFINE(UDEV, 1, [Have UDEV support])
129 fi
130
131 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
132
133 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
134
135 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
136 if test "x$HAVE_CAIRO" = xyes; then
137         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
138 fi
139 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
140
141 # For enumerating devices in test case
142 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
143 if test "x$HAVE_LIBUDEV" = xyes; then
144         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
145 fi
146 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
147
148
149 AC_SUBST(WARN_CFLAGS)
150 AC_OUTPUT([
151         Makefile
152         libdrm/Makefile
153         libdrm/intel/Makefile
154         libdrm/radeon/Makefile
155         libdrm/radeon/libdrm_radeon.pc
156         libdrm/nouveau/Makefile
157         libdrm/nouveau/libdrm_nouveau.pc
158         shared-core/Makefile
159         tests/Makefile
160         tests/modeprint/Makefile
161         tests/modetest/Makefile
162         libdrm.pc
163         libdrm_intel.pc])