configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.67
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 102 AC_PROG_SED
 103 AC_PROG_MKDIR_P
 104
 105 AC_SYS_LARGEFILE
 106
 107 LT_PREREQ([2.2])
 108 LT_INIT([disable-static])
 109
 110 AC_CHECK_PROG(RM, rm, [rm -f])
 111
 112 AX_PROG_BISON([],
 113               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 114                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 115 AX_PROG_FLEX([],
 116              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 117                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 118
 119 AC_CHECK_PROG(INDENT, indent, indent, cat)
 120 if test "x$INDENT" != "xcat"; then
 121     # Only GNU indent is supported
 122     INDENT_VERSION=`indent --version | grep GNU`
 123     if test $? -eq 0; then
 124        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 125     else
 126        INDENT="cat"
 127     fi
 128 fi
 129
 130 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 131
 132 if test -z "$PYTHON2"; then
 133     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 134         AC_MSG_ERROR([Python not found - unable to generate sources])
 135     fi
 136 else
 137     if test "x$acv_mako_found" = xno; then
 138         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 139             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 140         fi
 141     fi
 142 fi
 143
 144 AC_PROG_INSTALL
 145
 146 dnl We need a POSIX shell for parts of the build. Assume we have one
 147 dnl in most cases.
 148 case "$host_os" in
 149 solaris*)
 150     # Solaris /bin/sh is too old/non-POSIX compliant
 151     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 152     SHELL="$POSIX_SHELL"
 153     ;;
 154 esac
 155
 156 dnl clang is mostly GCC-compatible, but its version is much lower,
 157 dnl so we have to check for it.
 158 AC_MSG_CHECKING([if compiling with clang])
 159
 160 AC_COMPILE_IFELSE(
 161 [AC_LANG_PROGRAM([], [[
 162 #ifndef __clang__
 163        not clang
 164 #endif
 165 ]])],
 166 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 167
 168 AC_MSG_RESULT([$acv_mesa_CLANG])
 169
 170 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 171 dnl versions are explictly not supported.
 172 GEN_ASM_OFFSETS=no
 173 USE_GNU99=no
 174 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 175     AC_MSG_CHECKING([whether gcc version is sufficient])
 176     major=0
 177     minor=0
 178
 179     GCC_VERSION=`$CC -dumpversion`
 180     if test $? -eq 0; then
 181         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 182         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 183     fi
 184
 185     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 186         AC_MSG_RESULT([no])
 187         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 188     else
 189         AC_MSG_RESULT([yes])
 190     fi
 191
 192     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 193         USE_GNU99=yes
 194     fi
 195     if test "x$cross_compiling" = xyes; then
 196         GEN_ASM_OFFSETS=yes
 197     fi
 198 fi
 199
 200 dnl We don't support building Mesa with Sun C compiler
 201 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 202 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 203 if test "x$SUNCC" = xyes; then
 204     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 205 fi
 206
 207 dnl Check for compiler builtins
 208 AX_GCC_BUILTIN([__builtin_bswap32])
 209 AX_GCC_BUILTIN([__builtin_bswap64])
 210 AX_GCC_BUILTIN([__builtin_clz])
 211 AX_GCC_BUILTIN([__builtin_clzll])
 212 AX_GCC_BUILTIN([__builtin_ctz])
 213 AX_GCC_BUILTIN([__builtin_expect])
 214 AX_GCC_BUILTIN([__builtin_ffs])
 215 AX_GCC_BUILTIN([__builtin_ffsll])
 216 AX_GCC_BUILTIN([__builtin_popcount])
 217 AX_GCC_BUILTIN([__builtin_popcountll])
 218 AX_GCC_BUILTIN([__builtin_unreachable])
 219
 220 AX_GCC_FUNC_ATTRIBUTE([const])
 221 AX_GCC_FUNC_ATTRIBUTE([flatten])
 222 AX_GCC_FUNC_ATTRIBUTE([format])
 223 AX_GCC_FUNC_ATTRIBUTE([malloc])
 224 AX_GCC_FUNC_ATTRIBUTE([packed])
 225 AX_GCC_FUNC_ATTRIBUTE([pure])
 226 AX_GCC_FUNC_ATTRIBUTE([unused])
 227 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 228
 229 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 230
 231 dnl Make sure the pkg-config macros are defined
 232 m4_ifndef([PKG_PROG_PKG_CONFIG],
 233     [m4_fatal([Could not locate the pkg-config autoconf macros.
 234   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 235   are in a different location, try setting the environment variable
 236   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 237 PKG_PROG_PKG_CONFIG()
 238
 239 dnl LIB_DIR - library basename
 240 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 241 AC_SUBST([LIB_DIR])
 242
 243 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 244 _SAVE_LDFLAGS="$LDFLAGS"
 245 _SAVE_CPPFLAGS="$CPPFLAGS"
 246
 247 dnl Compiler macros
 248 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 249 AC_SUBST([DEFINES])
 250 case "$host_os" in
 251 linux*|*-gnu*|gnu*)
 252     DEFINES="$DEFINES -D_GNU_SOURCE"
 253     ;;
 254 solaris*)
 255     DEFINES="$DEFINES -DSVR4"
 256     ;;
 257 cygwin*)
 258     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 259     ;;
 260 esac
 261
 262 dnl Add flags for gcc and g++
 263 if test "x$GCC" = xyes; then
 264     CFLAGS="$CFLAGS -Wall"
 265
 266     if test "x$USE_GNU99" = xyes; then
 267         CFLAGS="$CFLAGS -std=gnu99"
 268     else
 269         CFLAGS="$CFLAGS -std=c99"
 270     fi
 271
 272     # Enable -Werror=implicit-function-declaration and
 273     # -Werror=missing-prototypes, if available, or otherwise, just
 274     # -Wmissing-prototypes.  This is particularly useful to avoid
 275     # generating a loadable driver module that has undefined symbols.
 276     save_CFLAGS="$CFLAGS"
 277     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 278     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 279     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 280     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 281                    AC_MSG_RESULT([yes]),
 282                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 283                     AC_MSG_RESULT([no])]);
 284
 285     # Enable -fvisibility=hidden if using a gcc that supports it
 286     save_CFLAGS="$CFLAGS"
 287     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 288     VISIBILITY_CFLAGS="-fvisibility=hidden"
 289     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 290     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 291                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 292
 293     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 294     CFLAGS=$save_CFLAGS
 295
 296     # Work around aliasing bugs - developers should comment this out
 297     CFLAGS="$CFLAGS -fno-strict-aliasing"
 298
 299     # We don't want floating-point math functions to set errno or trap
 300     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 301
 302     # gcc's builtin memcmp is slower than glibc's
 303     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 304     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 305
 306     # Flags to help ensure that certain portions of the code -- and only those
 307     # portions -- can be built with MSVC:
 308     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 309     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 310     #   supports most of C99)
 311     # - the rest has no compiler compiler restrictions
 312     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 313     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 314
 315     # Enable -Werror=vla if compiler supports it
 316     save_CFLAGS="$CFLAGS"
 317     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 318     CFLAGS="$CFLAGS -Werror=vla"
 319     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 320                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 321                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 322                     AC_MSG_RESULT([yes])],
 323                     AC_MSG_RESULT([no]));
 324     CFLAGS="$save_CFLAGS"
 325 fi
 326 if test "x$GXX" = xyes; then
 327     CXXFLAGS="$CXXFLAGS -Wall"
 328
 329     # Enable -fvisibility=hidden if using a gcc that supports it
 330     save_CXXFLAGS="$CXXFLAGS"
 331     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 332     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 333     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 334     AC_LANG_PUSH([C++])
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 336                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 337     AC_LANG_POP([C++])
 338
 339     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 340     CXXFLAGS=$save_CXXFLAGS
 341
 342     # Work around aliasing bugs - developers should comment this out
 343     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 344
 345     # gcc's builtin memcmp is slower than glibc's
 346     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 347     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 348 fi
 349
 350 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 351 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 352
 353 dnl even if the compiler appears to support it, using visibility attributes isn't
 354 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 355 case "$host_os" in
 356 cygwin*)
 357     VISIBILITY_CFLAGS=""
 358     VISIBILITY_CXXFLAGS=""
 359     ;;
 360 esac
 361
 362 AC_SUBST([VISIBILITY_CFLAGS])
 363 AC_SUBST([VISIBILITY_CXXFLAGS])
 364
 365 dnl
 366 dnl Optional flags, check for compiler support
 367 dnl
 368 SSE41_CFLAGS="-msse4.1"
 369 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 370 dnl stack, but on x86-32 such alignment is not guaranteed.
 371 case "$target_cpu" in
 372 i?86)
 373     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 374     ;;
 375 esac
 376 save_CFLAGS="$CFLAGS"
 377 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 378 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 379 #include <smmintrin.h>
 380 int param;
 381 int main () {
 382     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 383     c = _mm_max_epu32(a, b);
 384     return _mm_cvtsi128_si32(c);
 385 }]])], SSE41_SUPPORTED=1)
 386 CFLAGS="$save_CFLAGS"
 387 if test "x$SSE41_SUPPORTED" = x1; then
 388     DEFINES="$DEFINES -DUSE_SSE41"
 389 fi
 390 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 391 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 392
 393 dnl Check for Endianness
 394 AC_C_BIGENDIAN(
 395    little_endian=no,
 396    little_endian=yes,
 397    little_endian=no,
 398    little_endian=no
 399 )
 400
 401 dnl Check for POWER8 Architecture
 402 PWR8_CFLAGS="-mpower8-vector"
 403 have_pwr8_intrinsics=no
 404 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 405 save_CFLAGS=$CFLAGS
 406 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 407 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 408 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 409 #error "Need GCC >= 4.8 for sane POWER8 support"
 410 #endif
 411 #include <altivec.h>
 412 int main () {
 413     vector unsigned char r;
 414     vector unsigned int v = vec_splat_u32 (1);
 415     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 416     return 0;
 417 }]])], have_pwr8_intrinsics=yes)
 418 CFLAGS=$save_CFLAGS
 419
 420 AC_ARG_ENABLE(pwr8,
 421    [AC_HELP_STRING([--disable-pwr8-inst],
 422                    [disable POWER8-specific instructions])],
 423    [enable_pwr8=$enableval], [enable_pwr8=auto])
 424
 425 if test "x$enable_pwr8" = xno ; then
 426    have_pwr8_intrinsics=disabled
 427 fi
 428
 429 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 430    DEFINES="$DEFINES -D_ARCH_PWR8"
 431    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 432    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 433 else
 434    PWR8_CFLAGS=
 435 fi
 436
 437 AC_MSG_RESULT($have_pwr8_intrinsics)
 438 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 439    AC_MSG_ERROR([POWER8 compiler support not detected])
 440 fi
 441
 442 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 443    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 444 fi
 445
 446 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 447
 448 dnl Can't have static and shared libraries, default to static if user
 449 dnl explicitly requested. If both disabled, set to static since shared
 450 dnl was explicitly requested.
 451 case "x$enable_static$enable_shared" in
 452 xyesyes)
 453     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 454     enable_shared=no
 455     ;;
 456 xnono)
 457     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 458     enable_shared=yes
 459     ;;
 460 esac
 461
 462 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 463
 464 dnl
 465 dnl other compiler options
 466 dnl
 467 AC_ARG_ENABLE([debug],
 468     [AS_HELP_STRING([--enable-debug],
 469         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 470     [enable_debug="$enableval"],
 471     [enable_debug=no]
 472 )
 473
 474 AC_ARG_ENABLE([profile],
 475     [AS_HELP_STRING([--enable-profile],
 476         [enable profiling of code @<:@default=disabled@:>@])],
 477     [enable_profile="$enableval"],
 478     [enable_profile=no]
 479 )
 480
 481 if test "x$enable_profile" = xyes; then
 482     DEFINES="$DEFINES -DPROFILE"
 483     if test "x$GCC" = xyes; then
 484         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 485     fi
 486     if test "x$GXX" = xyes; then
 487         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 488     fi
 489 fi
 490
 491 if test "x$enable_debug" = xyes; then
 492     DEFINES="$DEFINES -DDEBUG"
 493     if test "x$enable_profile" = xyes; then
 494         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 495     fi
 496     if test "x$GCC" = xyes; then
 497         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 498             CFLAGS="$CFLAGS -g"
 499         fi
 500         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 501             CFLAGS="$CFLAGS -O0"
 502         fi
 503     fi
 504     if test "x$GXX" = xyes; then
 505         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 506             CXXFLAGS="$CXXFLAGS -g"
 507         fi
 508         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 509             CXXFLAGS="$CXXFLAGS -O0"
 510         fi
 511     fi
 512 else
 513    DEFINES="$DEFINES -DNDEBUG"
 514 fi
 515
 516 dnl
 517 dnl Check if linker supports -Bsymbolic
 518 dnl
 519 save_LDFLAGS=$LDFLAGS
 520 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 521 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 522 AC_LINK_IFELSE(
 523     [AC_LANG_SOURCE([int main() { return 0;}])],
 524     [AC_MSG_RESULT([yes])
 525         BSYMBOLIC="-Wl,-Bsymbolic";],
 526     [AC_MSG_RESULT([no])
 527         BSYMBOLIC="";])
 528 LDFLAGS=$save_LDFLAGS
 529
 530 AC_SUBST([BSYMBOLIC])
 531
 532 dnl
 533 dnl Check if linker supports garbage collection
 534 dnl
 535 save_LDFLAGS=$LDFLAGS
 536 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 537 AC_MSG_CHECKING([whether ld supports --gc-sections])
 538 AC_LINK_IFELSE(
 539     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 540     [AC_MSG_RESULT([yes])
 541         GC_SECTIONS="-Wl,--gc-sections";],
 542     [AC_MSG_RESULT([no])
 543         GC_SECTIONS="";])
 544 LDFLAGS=$save_LDFLAGS
 545
 546 AC_SUBST([GC_SECTIONS])
 547
 548 dnl
 549 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 550 dnl so when these flags are passed to ld via libtool the checks will fail
 551 dnl
 552 case "$host_os" in
 553 openbsd* | darwin* )
 554     LD_NO_UNDEFINED="" ;;
 555 *)
 556     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 557 esac
 558
 559 AC_SUBST([LD_NO_UNDEFINED])
 560
 561 dnl
 562 dnl Check if linker supports version scripts
 563 dnl
 564 AC_MSG_CHECKING([if the linker supports version-scripts])
 565 save_LDFLAGS=$LDFLAGS
 566 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 567 cat > conftest.map <<EOF
 568 VERSION_1 {
 569      global:
 570          main;
 571
 572      local:
 573          *;
 574 };
 575 EOF
 576 AC_LINK_IFELSE(
 577     [AC_LANG_SOURCE([int main() { return 0;}])],
 578     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 579     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 580 LDFLAGS=$save_LDFLAGS
 581 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 582
 583 dnl
 584 dnl Check if linker supports dynamic list files
 585 dnl
 586 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 587 save_LDFLAGS=$LDFLAGS
 588 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 589 cat > conftest.dyn <<EOF
 590 {
 591         radeon_drm_winsys_create;
 592 };
 593 EOF
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([int main() { return 0;}])],
 596     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 597     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 598 LDFLAGS=$save_LDFLAGS
 599 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 600
 601 dnl
 602 dnl compatibility symlinks
 603 dnl
 604 case "$host_os" in
 605 linux* )
 606     HAVE_COMPAT_SYMLINKS=yes ;;
 607 * )
 608     HAVE_COMPAT_SYMLINKS=no ;;
 609 esac
 610
 611 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 612
 613 dnl
 614 dnl library names
 615 dnl
 616 dnl Unfortunately we need to do a few things that libtool can't help us with,
 617 dnl so we need some knowledge of shared library filenames:
 618 dnl
 619 dnl LIB_EXT is the extension used when creating symlinks for alternate
 620 dnl filenames for a shared library which will be dynamically loaded
 621 dnl
 622 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 623 dnl the file for a shared library we wish to link with
 624 dnl
 625 case "$host_os" in
 626 darwin* )
 627     LIB_EXT='dylib'
 628     IMP_LIB_EXT=$LIB_EXT
 629     ;;
 630 cygwin* )
 631     LIB_EXT='dll'
 632     IMP_LIB_EXT='dll.a'
 633     ;;
 634 aix* )
 635     LIB_EXT='a'
 636     IMP_LIB_EXT=$LIB_EXT
 637     ;;
 638 * )
 639     LIB_EXT='so'
 640     IMP_LIB_EXT=$LIB_EXT
 641     ;;
 642 esac
 643
 644 AC_SUBST([LIB_EXT])
 645
 646 AC_ARG_WITH([gl-lib-name],
 647   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 648     [specify GL library name @<:@default=GL@:>@])],
 649   [GL_LIB=$withval],
 650   [GL_LIB=GL])
 651 AC_ARG_WITH([osmesa-lib-name],
 652   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 653     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 654   [OSMESA_LIB=$withval],
 655   [OSMESA_LIB=OSMesa])
 656 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 657 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 658
 659 dnl
 660 dnl Mangled Mesa support
 661 dnl
 662 AC_ARG_ENABLE([mangling],
 663   [AS_HELP_STRING([--enable-mangling],
 664     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 665   [enable_mangling="${enableval}"],
 666   [enable_mangling=no]
 667 )
 668 if test "x${enable_mangling}" = "xyes" ; then
 669   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 670   GL_LIB="Mangled${GL_LIB}"
 671   OSMESA_LIB="Mangled${OSMESA_LIB}"
 672 fi
 673 AC_SUBST([GL_LIB])
 674 AC_SUBST([OSMESA_LIB])
 675
 676 dnl
 677 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 678 dnl
 679 AC_ARG_ENABLE([texture-float],
 680     [AS_HELP_STRING([--enable-texture-float],
 681         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 682     [enable_texture_float="$enableval"],
 683     [enable_texture_float=no]
 684 )
 685 if test "x$enable_texture_float" = xyes; then
 686     AC_MSG_WARN([Floating-point textures enabled.])
 687     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 688     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 689 fi
 690
 691 dnl
 692 dnl Arch/platform-specific settings
 693 dnl
 694 AC_ARG_ENABLE([asm],
 695     [AS_HELP_STRING([--disable-asm],
 696         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 697     [enable_asm="$enableval"],
 698     [enable_asm=yes]
 699 )
 700 asm_arch=""
 701 AC_MSG_CHECKING([whether to enable assembly])
 702 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 703 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 704 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 705     case "$host_cpu" in
 706     i?86 | x86_64 | amd64)
 707         if test "x$host_cpu" != "x$target_cpu"; then
 708             enable_asm=no
 709             AC_MSG_RESULT([no, cross compiling])
 710         fi
 711         ;;
 712     esac
 713 fi
 714 # check for supported arches
 715 if test "x$enable_asm" = xyes; then
 716     case "$host_cpu" in
 717     i?86)
 718         case "$host_os" in
 719         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 720             asm_arch=x86
 721             ;;
 722         esac
 723         ;;
 724     x86_64|amd64)
 725         case "$host_os" in
 726         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 727             asm_arch=x86_64
 728             ;;
 729         esac
 730         ;;
 731     sparc*)
 732         case "$host_os" in
 733         linux*)
 734             asm_arch=sparc
 735             ;;
 736         esac
 737         ;;
 738     esac
 739
 740     case "$asm_arch" in
 741     x86)
 742         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 743         AC_MSG_RESULT([yes, x86])
 744         ;;
 745     x86_64|amd64)
 746         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 747         AC_MSG_RESULT([yes, x86_64])
 748         ;;
 749     sparc)
 750         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 751         AC_MSG_RESULT([yes, sparc])
 752         ;;
 753     *)
 754         AC_MSG_RESULT([no, platform not supported])
 755         ;;
 756     esac
 757 fi
 758
 759 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 760 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 761 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 762 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 763
 764 dnl Check to see if dlopen is in default libraries (like Solaris, which
 765 dnl has it in libc), or if libdl is needed to get it.
 766 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 767     [AC_CHECK_LIB([dl], [dlopen],
 768        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 769 AC_SUBST([DLOPEN_LIBS])
 770
 771 dnl Check if that library also has dladdr
 772 save_LIBS="$LIBS"
 773 LIBS="$LIBS $DLOPEN_LIBS"
 774 AC_CHECK_FUNCS([dladdr])
 775 LIBS="$save_LIBS"
 776
 777 case "$host_os" in
 778 darwin*)
 779     ;;
 780 *)
 781     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 782                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 783                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 784     AC_SUBST([CLOCK_LIB])
 785     ;;
 786 esac
 787
 788 dnl See if posix_memalign is available
 789 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 790
 791 dnl Check for pthreads
 792 AX_PTHREAD
 793 if test "x$ax_pthread_ok" = xno; then
 794     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 795 fi
 796 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 797 dnl to -pthread, which causes problems if we need -lpthread to appear in
 798 dnl pkgconfig files.
 799 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 800
 801 dnl SELinux awareness.
 802 AC_ARG_ENABLE([selinux],
 803     [AS_HELP_STRING([--enable-selinux],
 804         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 805     [MESA_SELINUX="$enableval"],
 806     [MESA_SELINUX=no])
 807 if test "x$enable_selinux" = "xyes"; then
 808     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 809         [AC_CHECK_HEADER([selinux/selinux.h],[],
 810                          [AC_MSG_ERROR([SELinux headers not found])])
 811          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 812                       [AC_MSG_ERROR([SELinux library not found])])
 813          SELINUX_LIBS="-lselinux"])
 814     DEFINES="$DEFINES -DMESA_SELINUX"
 815 fi
 816 AC_SUBST([SELINUX_CFLAGS])
 817 AC_SUBST([SELINUX_LIBS])
 818
 819 dnl Options for APIs
 820 AC_ARG_ENABLE([opengl],
 821     [AS_HELP_STRING([--disable-opengl],
 822         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 823     [enable_opengl="$enableval"],
 824     [enable_opengl=yes])
 825 AC_ARG_ENABLE([gles1],
 826     [AS_HELP_STRING([--disable-gles1],
 827         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 828     [enable_gles1="$enableval"],
 829     [enable_gles1=yes])
 830 AC_ARG_ENABLE([gles2],
 831     [AS_HELP_STRING([--disable-gles2],
 832         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 833     [enable_gles2="$enableval"],
 834     [enable_gles2=yes])
 835
 836 AC_ARG_ENABLE([dri],
 837     [AS_HELP_STRING([--enable-dri],
 838         [enable DRI modules @<:@default=enabled@:>@])],
 839     [enable_dri="$enableval"],
 840     [enable_dri=yes])
 841
 842 case "$host_os" in
 843 linux*)
 844     dri3_default=yes
 845     ;;
 846 *)
 847     dri3_default=no
 848     ;;
 849 esac
 850
 851 if test "x$enable_dri" = xno; then
 852     dri3_default=no
 853 fi
 854
 855 AC_ARG_ENABLE([dri3],
 856     [AS_HELP_STRING([--enable-dri3],
 857         [enable DRI3 @<:@default=auto@:>@])],
 858     [enable_dri3="$enableval"],
 859     [enable_dri3="$dri3_default"])
 860 AC_ARG_ENABLE([glx],
 861     [AS_HELP_STRING([--enable-glx],
 862         [enable GLX library @<:@default=enabled@:>@])],
 863     [enable_glx="$enableval"],
 864     [enable_glx=yes])
 865 AC_ARG_ENABLE([osmesa],
 866     [AS_HELP_STRING([--enable-osmesa],
 867         [enable OSMesa library @<:@default=disabled@:>@])],
 868     [enable_osmesa="$enableval"],
 869     [enable_osmesa=no])
 870 AC_ARG_ENABLE([gallium-osmesa],
 871     [AS_HELP_STRING([--enable-gallium-osmesa],
 872         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 873     [enable_gallium_osmesa="$enableval"],
 874     [enable_gallium_osmesa=no])
 875 AC_ARG_ENABLE([egl],
 876     [AS_HELP_STRING([--disable-egl],
 877         [disable EGL library @<:@default=enabled@:>@])],
 878     [enable_egl="$enableval"],
 879     [enable_egl=yes])
 880
 881 AC_ARG_ENABLE([xa],
 882     [AS_HELP_STRING([--enable-xa],
 883         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 884     [enable_xa="$enableval"],
 885     [enable_xa=no])
 886 AC_ARG_ENABLE([gbm],
 887    [AS_HELP_STRING([--enable-gbm],
 888          [enable gbm library @<:@default=auto@:>@])],
 889    [enable_gbm="$enableval"],
 890    [enable_gbm=auto])
 891 AC_ARG_ENABLE([nine],
 892     [AS_HELP_STRING([--enable-nine],
 893         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 894     [enable_nine="$enableval"],
 895     [enable_nine=no])
 896
 897 AC_ARG_ENABLE([xvmc],
 898    [AS_HELP_STRING([--enable-xvmc],
 899          [enable xvmc library @<:@default=auto@:>@])],
 900    [enable_xvmc="$enableval"],
 901    [enable_xvmc=auto])
 902 AC_ARG_ENABLE([vdpau],
 903    [AS_HELP_STRING([--enable-vdpau],
 904          [enable vdpau library @<:@default=auto@:>@])],
 905    [enable_vdpau="$enableval"],
 906    [enable_vdpau=auto])
 907 AC_ARG_ENABLE([omx],
 908    [AS_HELP_STRING([--enable-omx],
 909          [enable OpenMAX library @<:@default=disabled@:>@])],
 910    [enable_omx="$enableval"],
 911    [enable_omx=no])
 912 AC_ARG_ENABLE([va],
 913    [AS_HELP_STRING([--enable-va],
 914          [enable va library @<:@default=auto@:>@])],
 915    [enable_va="$enableval"],
 916    [enable_va=auto])
 917 AC_ARG_ENABLE([opencl],
 918    [AS_HELP_STRING([--enable-opencl],
 919          [enable OpenCL library @<:@default=disabled@:>@])],
 920    [enable_opencl="$enableval"],
 921    [enable_opencl=no])
 922 AC_ARG_ENABLE([opencl_icd],
 923    [AS_HELP_STRING([--enable-opencl-icd],
 924           [Build an OpenCL ICD library to be loaded by an ICD implementation
 925            @<:@default=disabled@:>@])],
 926     [enable_opencl_icd="$enableval"],
 927     [enable_opencl_icd=no])
 928 AC_ARG_ENABLE([xlib-glx],
 929     [AS_HELP_STRING([--enable-xlib-glx],
 930         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 931     [enable_xlib_glx="$enableval"],
 932     [enable_xlib_glx=no])
 933
 934 AC_ARG_ENABLE([gallium-tests],
 935     [AS_HELP_STRING([--enable-gallium-tests],
 936         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 937     [enable_gallium_tests="$enableval"],
 938     [enable_gallium_tests=no])
 939
 940 # Option for Gallium drivers
 941
 942 # Keep this in sync with the --with-gallium-drivers help string default value
 943 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 944
 945 AC_ARG_WITH([gallium-drivers],
 946     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 947         [comma delimited Gallium drivers list, e.g.
 948         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 949         @<:@default=r300,r600,svga,swrast@:>@])],
 950     [with_gallium_drivers="$withval"],
 951     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 952
 953 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 954 # here so that the script doesn't choke on an unknown driver name later.
 955 case "$with_gallium_drivers" in
 956     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 957     no) with_gallium_drivers='' ;;
 958 esac
 959
 960 if test "x$enable_opengl" = xno -a \
 961         "x$enable_gles1" = xno -a \
 962         "x$enable_gles2" = xno -a \
 963         "x$enable_nine" = xno -a \
 964         "x$enable_xa" = xno -a \
 965         "x$enable_xvmc" = xno -a \
 966         "x$enable_vdpau" = xno -a \
 967         "x$enable_omx" = xno -a \
 968         "x$enable_va" = xno -a \
 969         "x$enable_opencl" = xno; then
 970     AC_MSG_ERROR([at least one API should be enabled])
 971 fi
 972
 973 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 974 if test "x$enable_opengl" = xno -a \
 975         "x$enable_gles1" = xyes; then
 976     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 977 fi
 978
 979 if test "x$enable_opengl" = xno -a \
 980         "x$enable_gles2" = xyes; then
 981     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 982 fi
 983
 984 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 985 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 986 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 987 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 988                                         "x$enable_gles1" = xyes -o \
 989                                         "x$enable_gles2" = xyes)
 990
 991 if test "x$enable_glx" = xno; then
 992     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 993     enable_xlib_glx=no
 994 fi
 995
 996 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 997     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 998 fi
 999
1000 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
1001     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
1002 fi
1003
1004 # Disable GLX if OpenGL is not enabled
1005 if test "x$enable_glx$enable_opengl" = xyesno; then
1006     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
1007     enable_glx=no
1008 fi
1009
1010 # Disable GLX if DRI and Xlib-GLX are not enabled
1011 if test "x$enable_glx" = xyes -a \
1012         "x$enable_dri" = xno -a \
1013         "x$enable_xlib_glx" = xno; then
1014     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
1015     enable_glx=no
1016 fi
1017
1018 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
1019                                   "x$enable_dri" = xyes)
1020
1021 # Check for libdrm
1022 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1023                   [have_libdrm=yes], [have_libdrm=no])
1024 if test "x$have_libdrm" = xyes; then
1025         DEFINES="$DEFINES -DHAVE_LIBDRM"
1026 fi
1027
1028 # Select which platform-dependent DRI code gets built
1029 case "$host_os" in
1030 darwin*)
1031     dri_platform='apple' ;;
1032 gnu*|cygwin*)
1033     dri_platform='none' ;;
1034 *)
1035     dri_platform='drm' ;;
1036 esac
1037
1038 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1039     have_drisw_kms='yes'
1040 fi
1041
1042 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1043 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1044 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1045 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1046 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1047 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1048
1049 AC_ARG_ENABLE([shared-glapi],
1050     [AS_HELP_STRING([--enable-shared-glapi],
1051         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1052     [enable_shared_glapi="$enableval"],
1053     [enable_shared_glapi=yes])
1054
1055 case "x$enable_opengl$enable_gles1$enable_gles2" in
1056 x*yes*yes*)
1057     if test "x$enable_shared_glapi" = xno; then
1058         AC_MSG_ERROR([shared GLAPI required when building two or more of
1059                       the following APIs - opengl, gles1 gles2])
1060     fi
1061     ;;
1062 esac
1063
1064 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1065
1066 # Build the pipe-drivers as separate libraries/modules.
1067 # Do not touch this unless you know what you are doing.
1068 # XXX: Expose via configure option ?
1069 enable_shared_pipe_drivers=no
1070
1071 dnl
1072 dnl Driver specific build directories
1073 dnl
1074
1075 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
1076     NEED_WINSYS_XLIB="yes"
1077 fi
1078
1079 if test "x$enable_gallium_osmesa" = xyes; then
1080     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1081         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1082     fi
1083     if test "x$enable_osmesa" = xyes; then
1084         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1085     fi
1086 fi
1087
1088 AC_SUBST([MESA_LLVM])
1089
1090 # SHA1 hashing
1091 AC_ARG_WITH([sha1],
1092         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1093         [choose SHA1 implementation])])
1094 case "x$with_sha1" in
1095 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1096   ;;
1097 *)
1098         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1099 esac
1100
1101 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1102 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1103         with_sha1=libc
1104 fi
1105 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1106         AC_MSG_ERROR([sha1 in libc requested but not found])
1107 fi
1108 if test "x$with_sha1" = xlibc; then
1109         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1110                 [Use libc SHA1 functions])
1111         SHA1_LIBS=""
1112 fi
1113 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1114 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1115         with_sha1=CommonCrypto
1116 fi
1117 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1118         AC_MSG_ERROR([CommonCrypto requested but not found])
1119 fi
1120 if test "x$with_sha1" = xCommonCrypto; then
1121         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1122                 [Use CommonCrypto SHA1 functions])
1123         SHA1_LIBS=""
1124 fi
1125 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1126 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1127 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1128         with_sha1=CryptoAPI
1129 fi
1130 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1131         AC_MSG_ERROR([CryptoAPI requested but not found])
1132 fi
1133 if test "x$with_sha1" = xCryptoAPI; then
1134         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1135                 [Use CryptoAPI SHA1 functions])
1136         SHA1_LIBS=""
1137 fi
1138 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1139 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1140         with_sha1=libmd
1141 fi
1142 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1143         AC_MSG_ERROR([libmd requested but not found])
1144 fi
1145 if test "x$with_sha1" = xlibmd; then
1146         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1147                   [Use libmd SHA1 functions])
1148         SHA1_LIBS=-lmd
1149 fi
1150 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1151 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1152    with_sha1=libsha1
1153 fi
1154 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1155         AC_MSG_ERROR([libsha1 requested but not found])
1156 fi
1157 if test "x$with_sha1" = xlibsha1; then
1158         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1159                   [Use libsha1 for SHA1])
1160         SHA1_LIBS=-lsha1
1161 fi
1162 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1163 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1164         with_sha1=libnettle
1165 fi
1166 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1167         AC_MSG_ERROR([libnettle requested but not found])
1168 fi
1169 if test "x$with_sha1" = xlibnettle; then
1170         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1171                   [Use libnettle SHA1 functions])
1172         SHA1_LIBS=-lnettle
1173 fi
1174 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1175 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1176         with_sha1=libgcrypt
1177 fi
1178 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1179         AC_MSG_ERROR([libgcrypt requested but not found])
1180 fi
1181 if test "x$with_sha1" = xlibgcrypt; then
1182         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1183                   [Use libgcrypt SHA1 functions])
1184         SHA1_LIBS=-lgcrypt
1185 fi
1186 # We don't need all of the OpenSSL libraries, just libcrypto
1187 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1188 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1189                   [HAVE_OPENSSL_PKC=no])
1190 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1191         if test "x$with_sha1" = x; then
1192                 with_sha1=libcrypto
1193         fi
1194 else
1195         if test "x$with_sha1" = xlibcrypto; then
1196                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1197         fi
1198 fi
1199 if test "x$with_sha1" = xlibcrypto; then
1200         if test "x$HAVE_LIBCRYPTO" = xyes; then
1201                 SHA1_LIBS=-lcrypto
1202         else
1203                 SHA1_LIBS="$OPENSSL_LIBS"
1204                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1205         fi
1206 fi
1207 AC_MSG_CHECKING([for SHA1 implementation])
1208 AC_MSG_RESULT([$with_sha1])
1209 AC_SUBST(SHA1_LIBS)
1210 AC_SUBST(SHA1_CFLAGS)
1211
1212 # Enable a define for SHA1
1213 if test "x$with_sha1" != "x"; then
1214         DEFINES="$DEFINES -DHAVE_SHA1"
1215 fi
1216
1217 # Allow user to configure out the shader-cache feature
1218 AC_ARG_ENABLE([shader-cache],
1219     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1220     [enable_shader_cache="$enableval"],
1221     [if test "x$with_sha1" != "x"; then
1222         enable_shader_cache=yes
1223      else
1224         enable_shader_cache=no
1225      fi])
1226 if test "x$with_sha1" = "x"; then
1227     if test "x$enable_shader_cache" = "xyes"; then
1228         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1229     fi
1230 fi
1231 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1232
1233 case "$host_os" in
1234 linux*)
1235     need_pci_id=yes ;;
1236 *)
1237     need_pci_id=no ;;
1238 esac
1239
1240 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1241                   have_libudev=yes, have_libudev=no)
1242
1243 AC_ARG_ENABLE([sysfs],
1244     [AS_HELP_STRING([--enable-sysfs],
1245         [enable /sys PCI identification @<:@default=disabled@:>@])],
1246     [have_sysfs="$enableval"],
1247     [have_sysfs=no]
1248 )
1249
1250 if test "x$enable_dri" = xyes; then
1251     if test "$enable_static" = yes; then
1252         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1253     fi
1254
1255     # not a hard requirement as swrast does not depend on it
1256     if test "x$have_libdrm" = xyes; then
1257         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1258     fi
1259 fi
1260
1261 AC_ARG_ENABLE([driglx-direct],
1262     [AS_HELP_STRING([--disable-driglx-direct],
1263         [disable direct rendering in GLX and EGL for DRI \
1264             @<:@default=auto@:>@])],
1265     [driglx_direct="$enableval"],
1266     [driglx_direct="yes"])
1267
1268 dnl
1269 dnl libGL configuration per driver
1270 dnl
1271 case "x$enable_glx$enable_xlib_glx" in
1272 xyesyes)
1273     # Xlib-based GLX
1274     dri_modules="x11 xext xcb"
1275     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1276     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1277     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1278     GL_LIB_DEPS="$XLIBGL_LIBS"
1279     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1280     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1281     ;;
1282 xyesno)
1283     # DRI-based GLX
1284     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1285
1286     # find the DRI deps for libGL
1287     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1288
1289     if test x"$driglx_direct" = xyes; then
1290         if test x"$dri_platform" = xdrm ; then
1291             DEFINES="$DEFINES -DGLX_USE_DRM"
1292             if test "x$have_libdrm" != xyes; then
1293                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1294             fi
1295
1296             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1297             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1298             if test x"$enable_dri3" = xyes; then
1299                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1300                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1301             fi
1302
1303             if test x"$enable_dri" = xyes; then
1304                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1305             fi
1306
1307             if test x"$enable_dri3" = xyes; then
1308                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1309                dri3_modules="xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1310                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1311             fi
1312         fi
1313         if test x"$dri_platform" = xapple ; then
1314             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1315         fi
1316     fi
1317
1318     # add xf86vidmode if available
1319     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1320     if test "$HAVE_XF86VIDMODE" = yes ; then
1321         dri_modules="$dri_modules xxf86vm"
1322     fi
1323
1324     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1325     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1326     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1327     GL_LIB_DEPS="$DRIGL_LIBS"
1328
1329     # need DRM libs, $PTHREAD_LIBS, etc.
1330     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1331     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1332     ;;
1333 esac
1334
1335 have_pci_id=no
1336 if test "$have_libudev" = yes; then
1337     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1338     have_pci_id=yes
1339 fi
1340
1341 if test "$have_sysfs" = yes; then
1342     DEFINES="$DEFINES -DHAVE_SYSFS"
1343     have_pci_id=yes
1344 fi
1345
1346 # This is outside the case (above) so that it is invoked even for non-GLX
1347 # builds.
1348 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1349
1350 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1351 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1352 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1353 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1354
1355 AC_SUBST([X11_INCLUDES])
1356 AC_SUBST([GL_LIB_DEPS])
1357 AC_SUBST([GL_PC_REQ_PRIV])
1358 AC_SUBST([GL_PC_LIB_PRIV])
1359 AC_SUBST([GL_PC_CFLAGS])
1360 AC_SUBST([DRI_PC_REQ_PRIV])
1361 AC_SUBST([GLESv1_CM_LIB_DEPS])
1362 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1363 AC_SUBST([GLESv2_LIB_DEPS])
1364 AC_SUBST([GLESv2_PC_LIB_PRIV])
1365
1366 AC_SUBST([HAVE_XF86VIDMODE])
1367
1368 dnl
1369 dnl More GLX setup
1370 dnl
1371 case "x$enable_glx$enable_xlib_glx" in
1372 xyesyes)
1373     DEFINES="$DEFINES -DUSE_XSHM"
1374     ;;
1375 xyesno)
1376     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1377     if test "x$driglx_direct" = xyes; then
1378         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1379     fi
1380     ;;
1381 esac
1382
1383 dnl
1384 dnl TLS detection
1385 dnl
1386
1387 AC_ARG_ENABLE([glx-tls],
1388     [AS_HELP_STRING([--enable-glx-tls],
1389         [enable TLS support in GLX @<:@default=disabled@:>@])],
1390     [GLX_USE_TLS="$enableval"],
1391     [GLX_USE_TLS=no])
1392 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1393
1394 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1395       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1396
1397 dnl Read-only text section on x86 hardened platforms
1398 AC_ARG_ENABLE([glx-read-only-text],
1399     [AS_HELP_STRING([--enable-glx-read-only-text],
1400         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1401     [enable_glx_read_only_text="$enableval"],
1402     [enable_glx_read_only_text=no])
1403 if test "x$enable_glx_read_only_text" = xyes; then
1404     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1405 fi
1406
1407 dnl
1408 dnl More DRI setup
1409 dnl
1410 dnl Directory for DRI drivers
1411 AC_ARG_WITH([dri-driverdir],
1412     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1413         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1414     [DRI_DRIVER_INSTALL_DIR="$withval"],
1415     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1416 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1417 dnl Extra search path for DRI drivers
1418 AC_ARG_WITH([dri-searchpath],
1419     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1420         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1421     [DRI_DRIVER_SEARCH_DIR="$withval"],
1422     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1423 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1424 dnl Which drivers to build - default is chosen by platform
1425 AC_ARG_WITH([dri-drivers],
1426     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1427         [comma delimited classic DRI drivers list, e.g.
1428         "swrast,i965,radeon" @<:@default=auto@:>@])],
1429     [with_dri_drivers="$withval"],
1430     [with_dri_drivers=auto])
1431
1432 if test "x$with_dri_drivers" = xauto; then
1433     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1434         with_dri_drivers="yes"
1435     else
1436         with_dri_drivers="no"
1437     fi
1438 fi
1439 if test "x$with_dri_drivers" = xno; then
1440     with_dri_drivers=''
1441 fi
1442
1443 dnl If $with_dri_drivers is yes, drivers will be added through
1444 dnl platform checks. Set DEFINES and LIB_DEPS
1445 if test "x$enable_dri" = xyes; then
1446     # Platform specific settings and drivers to build
1447     case "$host_os" in
1448     linux*)
1449         DEFINES="$DEFINES -DHAVE_ALIAS"
1450         if test "x$enable_dri3" = xyes; then
1451             DEFINES="$DEFINES -DHAVE_DRI3"
1452         fi
1453
1454         if test "x$have_pci_id" != xyes; then
1455             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1456         fi
1457
1458         case "$host_cpu" in
1459         powerpc* | sparc*)
1460             # Build only the drivers for cards that exist on PowerPC/sparc
1461             if test "x$with_dri_drivers" = "xyes"; then
1462                 with_dri_drivers="r200 radeon swrast"
1463             fi
1464             ;;
1465         esac
1466         ;;
1467     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1468         DEFINES="$DEFINES -DHAVE_ALIAS"
1469         ;;
1470     gnu*)
1471         DEFINES="$DEFINES -DHAVE_ALIAS"
1472         ;;
1473     cygwin*)
1474         if test "x$with_dri_drivers" = "xyes"; then
1475             with_dri_drivers="swrast"
1476         fi
1477         ;;
1478     darwin*)
1479         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1480         if test "x$with_dri_drivers" = "xyes"; then
1481             with_dri_drivers="swrast"
1482         fi
1483         ;;
1484     esac
1485
1486     # default drivers
1487     if test "x$with_dri_drivers" = "xyes"; then
1488         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1489     fi
1490
1491     # Check for expat
1492     PKG_CHECK_MODULES([EXPAT], [expat], [],
1493         # expat version 2.0 and earlier do not provide expat.pc
1494         [AC_CHECK_HEADER([expat.h],[],
1495                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1496          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1497                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1498          EXPAT_LIBS="-lexpat"])
1499
1500     # put all the necessary libs together
1501     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1502 fi
1503
1504 AC_SUBST([DRI_LIB_DEPS])
1505
1506 DRI_DIRS=''
1507 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1508 if test -n "$with_dri_drivers"; then
1509     if test "x$enable_opengl" != xyes; then
1510         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1511     fi
1512
1513     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1514     for driver in $dri_drivers; do
1515         DRI_DIRS="$DRI_DIRS $driver"
1516         case "x$driver" in
1517         xi915)
1518             HAVE_I915_DRI=yes;
1519             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1520             ;;
1521         xi965)
1522             HAVE_I965_DRI=yes;
1523             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1524             ;;
1525         xnouveau)
1526             HAVE_NOUVEAU_DRI=yes;
1527             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1528             ;;
1529         xradeon)
1530             HAVE_RADEON_DRI=yes;
1531             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1532             ;;
1533         xr200)
1534             HAVE_R200_DRI=yes;
1535             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1536             ;;
1537         xswrast)
1538             HAVE_SWRAST_DRI=yes;
1539             ;;
1540         *)
1541             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1542             ;;
1543         esac
1544     done
1545     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1546 fi
1547
1548
1549 #
1550 # Vulkan driver configuration
1551 #
1552
1553 AC_ARG_WITH([vulkan-drivers],
1554     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1555         [comma delimited Vulkan drivers list, e.g.
1556         "intel"
1557         @<:@default=no@:>@])],
1558     [with_vulkan_drivers="$withval"],
1559     [with_vulkan_drivers="no"])
1560
1561 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1562 # here so that the script doesn't choke on an unknown driver name later.
1563 case "x$with_vulkan_drivers" in
1564     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1565     xno) with_vulkan_drivers='' ;;
1566 esac
1567
1568 AC_ARG_WITH([vulkan-icddir],
1569     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1570         [directory for the Vulkan driver icd files @<:@${sysconfdir}/vulkan/icd.d@:>@])],
1571     [VULKAN_ICD_INSTALL_DIR="$withval"],
1572     [VULKAN_ICD_INSTALL_DIR='${sysconfdir}/vulkan/icd.d'])
1573 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1574
1575 if test -n "$with_vulkan_drivers"; then
1576     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1577     for driver in $VULKAN_DRIVERS; do
1578         case "x$driver" in
1579         xintel)
1580             if test "x$HAVE_I965_DRI" != xyes; then
1581                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1582             fi
1583             if test "x$with_sha1" == "x"; then
1584                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1585             fi
1586             HAVE_INTEL_VULKAN=yes;
1587
1588             ;;
1589         *)
1590             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1591             ;;
1592         esac
1593     done
1594     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1595 fi
1596
1597
1598 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1599 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1600                                   "x$enable_osmesa" = xyes -o \
1601                                   -n "$DRI_DIRS")
1602
1603 dnl
1604 dnl OSMesa configuration
1605 dnl
1606
1607 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1608 AC_ARG_WITH([osmesa-bits],
1609     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1610         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1611     [osmesa_bits="$withval"],
1612     [osmesa_bits=8])
1613 if test "x$osmesa_bits" != x8; then
1614     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1615         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1616         osmesa_bits=8
1617     fi
1618 fi
1619 case "x$osmesa_bits" in
1620 x8)
1621     OSMESA_LIB="${OSMESA_LIB}"
1622     ;;
1623 x16|x32)
1624     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1625     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1626     ;;
1627 *)
1628     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1629     ;;
1630 esac
1631
1632 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1633     # only link libraries with osmesa if shared
1634     if test "$enable_static" = no; then
1635         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1636     else
1637         OSMESA_LIB_DEPS=""
1638     fi
1639     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1640 fi
1641
1642 AC_SUBST([OSMESA_LIB_DEPS])
1643 AC_SUBST([OSMESA_PC_REQ])
1644 AC_SUBST([OSMESA_PC_LIB_PRIV])
1645
1646 dnl
1647 dnl gbm configuration
1648 dnl
1649 if test "x$enable_gbm" = xauto; then
1650     case "$with_egl_platforms" in
1651         *drm*)
1652             enable_gbm=yes ;;
1653          *)
1654             enable_gbm=no ;;
1655     esac
1656 fi
1657 if test "x$enable_gbm" = xyes; then
1658     if test "x$need_pci_id$have_pci_id" = xyesno; then
1659         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1660     fi
1661
1662     if test "x$enable_dri" = xyes; then
1663         if test "x$enable_shared_glapi" = xno; then
1664             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1665         fi
1666     else
1667         # Strictly speaking libgbm does not require --enable-dri, although
1668         # both of its backends do. Thus one can build libgbm without any
1669         # backends if --disable-dri is set.
1670         # To avoid unnecessary complexity of checking if at least one backend
1671         # is available when building, just mandate --enable-dri.
1672         AC_MSG_ERROR([gbm requires --enable-dri])
1673     fi
1674 fi
1675 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1676 if test "x$need_pci_id$have_libudev" = xyesyes; then
1677     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1678 else
1679     GBM_PC_REQ_PRIV=""
1680 fi
1681 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1682 AC_SUBST([GBM_PC_REQ_PRIV])
1683 AC_SUBST([GBM_PC_LIB_PRIV])
1684
1685 dnl
1686 dnl EGL configuration
1687 dnl
1688 EGL_CLIENT_APIS=""
1689
1690 if test "x$enable_egl" = xyes; then
1691     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1692
1693     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1694
1695     if test "$enable_static" != yes; then
1696         if test "x$enable_dri" = xyes; then
1697             HAVE_EGL_DRIVER_DRI2=1
1698             if test "x$enable_shared_glapi" = xno; then
1699                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1700             fi
1701             if test "x$enable_dri3" = xyes; then
1702                 HAVE_EGL_DRIVER_DRI3=1
1703                 if test "x$enable_shared_glapi" = xno; then
1704                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1705                 fi
1706             fi
1707         else
1708             # Avoid building an "empty" libEGL. Drop/update this
1709             # when other backends (haiku?) come along.
1710             AC_MSG_ERROR([egl requires --enable-dri])
1711         fi
1712
1713     fi
1714 fi
1715 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1716 AC_SUBST([EGL_LIB_DEPS])
1717
1718 gallium_st="mesa"
1719
1720 dnl
1721 dnl XA configuration
1722 dnl
1723 if test "x$enable_xa" = xyes; then
1724     if test "x$with_gallium_drivers" = xswrast; then
1725        AC_MSG_ERROR([
1726           Building xa requires at least one non swrast gallium driver.
1727           If you are looking to use libxatracker.so with the VMware driver,
1728           make sure to include svga in the gallium drivers list, apart from
1729           enabling XA.
1730           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1731     fi
1732     gallium_st="$gallium_st xa"
1733 fi
1734 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1735
1736 dnl
1737 dnl Gallium G3DVL configuration
1738 dnl
1739 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1740     if test "x$enable_xvmc" = xauto; then
1741         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1742     fi
1743
1744     if test "x$enable_vdpau" = xauto; then
1745         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1746     fi
1747
1748     if test "x$enable_omx" = xauto; then
1749         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1750     fi
1751
1752     if test "x$enable_va" = xauto; then
1753         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1754     fi
1755 fi
1756
1757 if test "x$enable_dri" = xyes -o \
1758         "x$enable_xvmc" = xyes -o \
1759         "x$enable_vdpau" = xyes -o \
1760         "x$enable_omx" = xyes -o \
1761         "x$enable_va" = xyes; then
1762     need_gallium_vl=yes
1763 fi
1764 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1765
1766 if test "x$enable_xvmc" = xyes -o \
1767         "x$enable_vdpau" = xyes -o \
1768         "x$enable_omx" = xyes -o \
1769         "x$enable_va" = xyes; then
1770     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1771     need_gallium_vl_winsys=yes
1772 fi
1773 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1774
1775 if test "x$enable_xvmc" = xyes; then
1776     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1777     gallium_st="$gallium_st xvmc"
1778 fi
1779 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1780
1781 if test "x$enable_vdpau" = xyes; then
1782     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1783     gallium_st="$gallium_st vdpau"
1784     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1785 fi
1786 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1787
1788 if test "x$enable_omx" = xyes; then
1789     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1790     gallium_st="$gallium_st omx"
1791 fi
1792 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1793
1794 if test "x$enable_va" = xyes; then
1795     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1796     gallium_st="$gallium_st va"
1797 fi
1798 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1799
1800 dnl
1801 dnl Nine Direct3D9 configuration
1802 dnl
1803 if test "x$enable_nine" = xyes; then
1804     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1805         AC_MSG_ERROR([nine requires the gallium swrast driver])
1806     fi
1807     if test "x$with_gallium_drivers" = xswrast; then
1808         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1809     fi
1810     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1811         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1812     fi
1813
1814     if test "x$enable_dri3" = xno; then
1815         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1816     fi
1817
1818     gallium_st="$gallium_st nine"
1819 fi
1820 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1821
1822 dnl
1823 dnl OpenCL configuration
1824 dnl
1825
1826 AC_ARG_WITH([clang-libdir],
1827    [AS_HELP_STRING([--with-clang-libdir],
1828          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1829    [CLANG_LIBDIR="$withval"],
1830    [CLANG_LIBDIR=''])
1831
1832 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1833 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1834
1835 if test "x$have_libelf" = xno; then
1836    LIBELF_LIBS=''
1837    LIBELF_CFLAGS=''
1838    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1839    AC_SUBST([LIBELF_LIBS])
1840    AC_SUBST([LIBELF_CFLAGS])
1841 fi
1842
1843 if test "x$enable_opencl" = xyes; then
1844     if test -z "$with_gallium_drivers"; then
1845         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1846     fi
1847
1848     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1849         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1850     fi
1851
1852     if test "x$have_libclc" = xno; then
1853         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1854                     Make sure the directory containing libclc.pc is specified in your
1855                     PKG_CONFIG_PATH environment variable.
1856                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1857     else
1858         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1859         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1860         AC_SUBST([LIBCLC_INCLUDEDIR])
1861         AC_SUBST([LIBCLC_LIBEXECDIR])
1862     fi
1863
1864     gallium_st="$gallium_st clover"
1865
1866     if test "x$enable_opencl_icd" = xyes; then
1867         OPENCL_LIBNAME="MesaOpenCL"
1868     else
1869         OPENCL_LIBNAME="OpenCL"
1870     fi
1871
1872     if test "x$have_libelf" != xyes; then
1873        AC_MSG_ERROR([Clover requires libelf])
1874     fi
1875 fi
1876 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1877 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1878 AC_SUBST([OPENCL_LIBNAME])
1879
1880 dnl
1881 dnl Gallium configuration
1882 dnl
1883 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1884
1885 AC_SUBST([LLVM_BINDIR])
1886 AC_SUBST([LLVM_CFLAGS])
1887 AC_SUBST([LLVM_CPPFLAGS])
1888 AC_SUBST([LLVM_CXXFLAGS])
1889 AC_SUBST([LLVM_LIBDIR])
1890 AC_SUBST([LLVM_LIBS])
1891 AC_SUBST([LLVM_LDFLAGS])
1892 AC_SUBST([LLVM_INCLUDEDIR])
1893 AC_SUBST([LLVM_VERSION])
1894 AC_SUBST([CLANG_RESOURCE_DIR])
1895
1896 case "x$enable_opengl$enable_gles1$enable_gles2" in
1897 x*yes*)
1898     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1899     ;;
1900 esac
1901
1902 AC_SUBST([VG_LIB_DEPS])
1903 AC_SUBST([EGL_CLIENT_APIS])
1904
1905 dnl
1906 dnl EGL Platforms configuration
1907 dnl
1908 AC_ARG_WITH([egl-platforms],
1909     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1910         [comma delimited native platforms libEGL supports, e.g.
1911         "x11,drm" @<:@default=auto@:>@])],
1912     [with_egl_platforms="$withval"],
1913     [if test "x$enable_egl" = xyes; then
1914         with_egl_platforms="x11"
1915     else
1916         with_egl_platforms=""
1917     fi])
1918
1919 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1920     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1921 fi
1922
1923 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1924         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1925         WAYLAND_SCANNER='')
1926 if test "x$WAYLAND_SCANNER" = x; then
1927     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1928 fi
1929
1930 # Do per-EGL platform setups and checks
1931 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1932 for plat in $egl_platforms; do
1933         case "$plat" in
1934         wayland)
1935                 test "x$have_libdrm" != xyes &&
1936                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1937
1938                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1939
1940                 if test "x$WAYLAND_SCANNER" = x; then
1941                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1942                 fi
1943                 ;;
1944
1945         x11)
1946                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1947                 ;;
1948
1949         drm)
1950                 test "x$enable_gbm" = "xno" &&
1951                         AC_MSG_ERROR([EGL platform drm needs gbm])
1952                 test "x$have_libdrm" != xyes &&
1953                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1954                 ;;
1955
1956         surfaceless)
1957                 test "x$have_libdrm" != xyes &&
1958                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1959                 ;;
1960
1961         *)
1962                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1963                 ;;
1964         esac
1965
1966         case "$plat$need_pci_id$have_pci_id" in
1967                 waylandyesno|drmyesno)
1968                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1969         esac
1970 done
1971
1972 # libEGL wants to default to the first platform specified in
1973 # ./configure.  parse that here.
1974 if test "x$egl_platforms" != "x"; then
1975     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1976     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1977 else
1978     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1979 fi
1980
1981 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1982 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1983 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1984 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1985 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1986
1987 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1988
1989 AC_SUBST([EGL_NATIVE_PLATFORM])
1990 AC_SUBST([EGL_CFLAGS])
1991
1992 # If we don't have the X11 platform, set this define so we don't try to include
1993 # the X11 headers.
1994 if ! echo "$egl_platforms" | grep -q 'x11'; then
1995     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1996     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1997 fi
1998
1999 dnl
2000 dnl Gallium LLVM
2001 dnl
2002 AC_ARG_ENABLE([gallium-llvm],
2003     [AS_HELP_STRING([--enable-gallium-llvm],
2004         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2005     [enable_gallium_llvm="$enableval"],
2006     [enable_gallium_llvm=auto])
2007
2008 AC_ARG_ENABLE([llvm-shared-libs],
2009     [AS_HELP_STRING([--enable-llvm-shared-libs],
2010         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2011     [enable_llvm_shared_libs="$enableval"],
2012     [enable_llvm_shared_libs=yes])
2013
2014 AC_ARG_WITH([llvm-prefix],
2015     [AS_HELP_STRING([--with-llvm-prefix],
2016         [Prefix for LLVM installations in non-standard locations])],
2017     [llvm_prefix="$withval"],
2018     [llvm_prefix=''])
2019
2020
2021 # Call this inside ` ` to get the return value.
2022 # $1 is the llvm-config command with arguments.
2023 strip_unwanted_llvm_flags() {
2024     # Use \> (marks the end of the word)
2025     echo `$1` | sed \
2026         -e 's/-DNDEBUG\>//g' \
2027         -e 's/-D_GNU_SOURCE\>//g' \
2028         -e 's/-pedantic\>//g' \
2029         -e 's/-Wcovered-switch-default\>//g' \
2030         -e 's/-O.\>//g' \
2031         -e 's/-g\>//g' \
2032         -e 's/-Wall\>//g' \
2033         -e 's/-Wcast-qual\>//g' \
2034         -e 's/-Woverloaded-virtual\>//g' \
2035         -e 's/-fcolor-diagnostics\>//g' \
2036         -e 's/-fdata-sections\>//g' \
2037         -e 's/-ffunction-sections\>//g' \
2038         -e 's/-fno-exceptions\>//g' \
2039         -e 's/-fomit-frame-pointer\>//g' \
2040         -e 's/-fvisibility-inlines-hidden\>//g' \
2041         -e 's/-fPIC\>//g' \
2042         -e 's/-fstack-protector-strong\>//g'
2043 }
2044
2045 llvm_check_version_for() {
2046     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2047         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2048     fi
2049 }
2050
2051
2052
2053 if test -z "$with_gallium_drivers"; then
2054     enable_gallium_llvm=no
2055 fi
2056 if test "x$enable_gallium_llvm" = xauto; then
2057     case "$host_cpu" in
2058     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2059     esac
2060 fi
2061 if test "x$enable_gallium_llvm" = xyes; then
2062     if test -n "$llvm_prefix"; then
2063         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2064     else
2065         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2066     fi
2067
2068     if test "x$LLVM_CONFIG" != xno; then
2069         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2070         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2071         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2072         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2073         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2074         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2075         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2076         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2077
2078         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2079             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2080         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2081             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2082
2083         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2084         if test -z "$LLVM_VERSION_PATCH"; then
2085             LLVM_VERSION_PATCH=0
2086         fi
2087
2088         if test -n "${LLVM_VERSION_MAJOR}"; then
2089             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2090         else
2091             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2092         fi
2093
2094         LLVM_REQUIRED_VERSION_MAJOR="3"
2095         LLVM_REQUIRED_VERSION_MINOR="3"
2096         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2097             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2098         fi
2099
2100         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2101
2102         if test "x$enable_opencl" = xyes; then
2103             llvm_check_version_for "3" "5" "0" "opencl"
2104
2105             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2106             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2107         fi
2108         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2109         MESA_LLVM=1
2110
2111         dnl Check for Clang internal headers
2112         if test "x$enable_opencl" = xyes; then
2113             if test -z "$CLANG_LIBDIR"; then
2114                 CLANG_LIBDIR=${LLVM_LIBDIR}
2115             fi
2116             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2117             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2118                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2119         fi
2120     else
2121         MESA_LLVM=0
2122         LLVM_VERSION_INT=0
2123     fi
2124 else
2125     MESA_LLVM=0
2126     LLVM_VERSION_INT=0
2127
2128     if test "x$enable_opencl" = xyes; then
2129         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2130     fi
2131 fi
2132
2133 dnl Directory for XVMC libs
2134 AC_ARG_WITH([xvmc-libdir],
2135     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2136         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2137     [XVMC_LIB_INSTALL_DIR="$withval"],
2138     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2139 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2140
2141 dnl
2142 dnl Gallium Tests
2143 dnl
2144 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2145
2146 dnl Directory for VDPAU libs
2147 AC_ARG_WITH([vdpau-libdir],
2148     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2149         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2150     [VDPAU_LIB_INSTALL_DIR="$withval"],
2151     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2152 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2153
2154 dnl Directory for OMX libs
2155
2156 AC_ARG_WITH([omx-libdir],
2157     [AS_HELP_STRING([--with-omx-libdir=DIR],
2158         [directory for the OMX libraries])],
2159     [OMX_LIB_INSTALL_DIR="$withval"],
2160     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2161 AC_SUBST([OMX_LIB_INSTALL_DIR])
2162
2163 dnl Directory for VA libs
2164
2165 AC_ARG_WITH([va-libdir],
2166     [AS_HELP_STRING([--with-va-libdir=DIR],
2167         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2168     [VA_LIB_INSTALL_DIR="$withval"],
2169     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2170 AC_SUBST([VA_LIB_INSTALL_DIR])
2171
2172 AC_ARG_WITH([d3d-libdir],
2173     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2174         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2175     [D3D_DRIVER_INSTALL_DIR="$withval"],
2176     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2177 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2178
2179 dnl
2180 dnl Gallium helper functions
2181 dnl
2182 gallium_require_drm() {
2183     if test "x$have_libdrm" != xyes; then
2184        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2185     fi
2186 }
2187
2188 gallium_require_llvm() {
2189     if test "x$MESA_LLVM" = x0; then
2190         case "$host" in *gnux32) return;; esac
2191         case "$host_cpu" in
2192         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2193         esac
2194     fi
2195 }
2196
2197 gallium_require_drm_loader() {
2198     if test "x$need_pci_id$have_pci_id" = xyesno; then
2199         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2200     fi
2201 }
2202
2203 dnl This is for Glamor. Skip this if OpenGL is disabled.
2204 require_egl_drm() {
2205     if test "x$enable_opengl" = xno; then
2206         return 0
2207     fi
2208
2209     case "$with_egl_platforms" in
2210         *drm*)
2211             ;;
2212          *)
2213             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2214             ;;
2215     esac
2216     if test "x$enable_gbm" != xyes; then
2217             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2218     fi
2219 }
2220
2221 radeon_llvm_check() {
2222     if test ${LLVM_VERSION_INT} -lt 307; then
2223         amdgpu_llvm_target_name='r600'
2224     else
2225         amdgpu_llvm_target_name='amdgpu'
2226     fi
2227     if test "x$enable_gallium_llvm" != "xyes"; then
2228         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2229     fi
2230     llvm_check_version_for "3" "6" "0" $1
2231     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2232         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2233     fi
2234     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2235     NEED_RADEON_LLVM=yes
2236     if test "x$have_libelf" != xyes; then
2237        AC_MSG_ERROR([$1 requires libelf when using llvm])
2238     fi
2239 }
2240
2241 swr_llvm_check() {
2242     gallium_require_llvm $1
2243     if test ${LLVM_VERSION_INT} -lt 306; then
2244         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2245     fi
2246     if test "x$enable_gallium_llvm" != "xyes"; then
2247         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2248     fi
2249 }
2250
2251 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2252 if test -n "$with_gallium_drivers"; then
2253     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2254     for driver in $gallium_drivers; do
2255         case "x$driver" in
2256         xsvga)
2257             HAVE_GALLIUM_SVGA=yes
2258             gallium_require_drm "svga"
2259             gallium_require_drm_loader
2260             ;;
2261         xi915)
2262             HAVE_GALLIUM_I915=yes
2263             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2264             gallium_require_drm "Gallium i915"
2265             gallium_require_drm_loader
2266             ;;
2267         xilo)
2268             HAVE_GALLIUM_ILO=yes
2269             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2270             gallium_require_drm "Gallium i965/ilo"
2271             gallium_require_drm_loader
2272             ;;
2273         xr300)
2274             HAVE_GALLIUM_R300=yes
2275             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2276             gallium_require_drm "Gallium R300"
2277             gallium_require_drm_loader
2278             gallium_require_llvm "Gallium R300"
2279             ;;
2280         xr600)
2281             HAVE_GALLIUM_R600=yes
2282             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2283             gallium_require_drm "Gallium R600"
2284             gallium_require_drm_loader
2285             if test "x$enable_opencl" = xyes; then
2286                 radeon_llvm_check "r600g"
2287                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2288             fi
2289             ;;
2290         xradeonsi)
2291             HAVE_GALLIUM_RADEONSI=yes
2292             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2293             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2294             gallium_require_drm "radeonsi"
2295             gallium_require_drm_loader
2296             radeon_llvm_check "radeonsi"
2297             require_egl_drm "radeonsi"
2298             ;;
2299         xnouveau)
2300             HAVE_GALLIUM_NOUVEAU=yes
2301             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2302             gallium_require_drm "nouveau"
2303             gallium_require_drm_loader
2304             ;;
2305         xfreedreno)
2306             HAVE_GALLIUM_FREEDRENO=yes
2307             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2308             gallium_require_drm "freedreno"
2309             gallium_require_drm_loader
2310             ;;
2311         xswrast)
2312             HAVE_GALLIUM_SOFTPIPE=yes
2313             if test "x$MESA_LLVM" = x1; then
2314                 HAVE_GALLIUM_LLVMPIPE=yes
2315             fi
2316             ;;
2317         xswr)
2318             swr_llvm_check "swr"
2319
2320             AC_MSG_CHECKING([whether $CXX supports c++11/AVX/AVX2])
2321             AVX_CXXFLAGS="-march=core-avx-i"
2322             AVX2_CXXFLAGS="-march=core-avx2"
2323
2324             AC_LANG_PUSH([C++])
2325             save_CXXFLAGS="$CXXFLAGS"
2326             CXXFLAGS="-std=c++11 $CXXFLAGS"
2327             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2328                               [AC_MSG_ERROR([c++11 compiler support not detected])])
2329             CXXFLAGS="$save_CXXFLAGS"
2330
2331             save_CXXFLAGS="$CXXFLAGS"
2332             CXXFLAGS="$AVX_CXXFLAGS $CXXFLAGS"
2333             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2334                               [AC_MSG_ERROR([AVX compiler support not detected])])
2335             CXXFLAGS="$save_CXXFLAGS"
2336
2337             save_CFLAGS="$CXXFLAGS"
2338             CXXFLAGS="$AVX2_CXXFLAGS $CXXFLAGS"
2339             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2340                               [AC_MSG_ERROR([AVX2 compiler support not detected])])
2341             CXXFLAGS="$save_CXXFLAGS"
2342             AC_LANG_POP([C++])
2343
2344             HAVE_GALLIUM_SWR=yes
2345             ;;
2346         xvc4)
2347             HAVE_GALLIUM_VC4=yes
2348             gallium_require_drm "vc4"
2349             gallium_require_drm_loader
2350
2351             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2352                               [USE_VC4_SIMULATOR=yes;
2353                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2354                               [USE_VC4_SIMULATOR=no])
2355             ;;
2356         xvirgl)
2357             HAVE_GALLIUM_VIRGL=yes
2358             gallium_require_drm "virgl"
2359             gallium_require_drm_loader
2360             require_egl_drm "virgl"
2361             ;;
2362         *)
2363             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2364             ;;
2365         esac
2366     done
2367 fi
2368
2369 dnl Set LLVM_LIBS - This is done after the driver configuration so
2370 dnl that drivers can add additional components to LLVM_COMPONENTS.
2371 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2372 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2373 dnl this was causing the same libraries to be appear multiple times
2374 dnl in LLVM_LIBS.
2375
2376 if test "x$MESA_LLVM" != x0; then
2377
2378     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2379        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2380     fi
2381     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2382
2383     dnl llvm-config may not give the right answer when llvm is a built as a
2384     dnl single shared library, so we must work the library name out for
2385     dnl ourselves.
2386     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2387     if test "x$enable_llvm_shared_libs" = xyes; then
2388         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2389         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2390         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2391
2392         if test "x$llvm_have_one_so" = xyes; then
2393             dnl LLVM was built using auto*, so there is only one shared object.
2394             LLVM_LIBS="-l$LLVM_SO_NAME"
2395         else
2396             dnl If LLVM was built with CMake, there will be one shared object per
2397             dnl component.
2398             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2399                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2400         Please make sure you have built llvm with the --enable-shared option
2401         and that your llvm libraries are installed in $LLVM_LIBDIR
2402         If you have installed your llvm libraries to a different directory you
2403         can use the --with-llvm-prefix= configure flag to specify this directory.
2404         NOTE: Mesa is attempting to use llvm shared libraries by default.
2405         If you do not want to build with llvm shared libraries and instead want to
2406         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2407         invocation and rebuild.])])
2408
2409            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2410            dnl install uses a shared object for each component and we have
2411            dnl already added all of these objects to LLVM_LIBS.
2412         fi
2413     else
2414         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2415         dnl We need to link to llvm system libs when using static libs
2416         dnl However, only llvm 3.5+ provides --system-libs
2417         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2418             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2419         fi
2420     fi
2421 fi
2422
2423 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2424 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2425 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2426 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2427 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2428 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2429 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2430                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2431 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2432 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2433 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2434 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2435 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2436 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2437                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2438                                          "x$HAVE_GALLIUM_SWR" = xyes)
2439 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2440 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2441
2442 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2443
2444 if test "x$enable_dri" = xyes; then
2445     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2446 fi
2447
2448 if test "x$have_drisw_kms" = xyes; then
2449     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2450 fi
2451 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2452
2453 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2454 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2455 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2456 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2457 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2458 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2459
2460 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2461
2462 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2463                                         "x$HAVE_I965_DRI" = xyes)
2464
2465 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2466                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2467                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2468 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2469 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2470 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2471 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2472 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2473 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2474     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2475 fi
2476
2477 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2478 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2479 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2480 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2481
2482 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2483 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2484 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2485
2486 AC_SUBST([NINE_MAJOR], 1)
2487 AC_SUBST([NINE_MINOR], 0)
2488 AC_SUBST([NINE_TINY], 0)
2489 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2490
2491 AC_SUBST([VDPAU_MAJOR], 1)
2492 AC_SUBST([VDPAU_MINOR], 0)
2493
2494 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2495 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2496 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2497 AC_SUBST([VA_MINOR], $VA_MINOR)
2498
2499 AC_SUBST([XVMC_MAJOR], 1)
2500 AC_SUBST([XVMC_MINOR], 0)
2501
2502 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2503 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2504 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2505 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2506
2507 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2508 AC_SUBST([XA_MINOR], $XA_MINOR)
2509 AC_SUBST([XA_TINY], $XA_TINY)
2510 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2511
2512 AC_ARG_ENABLE(valgrind,
2513               [AS_HELP_STRING([--enable-valgrind],
2514                              [Build mesa with valgrind support (default: auto)])],
2515                              [VALGRIND=$enableval], [VALGRIND=auto])
2516 if test "x$VALGRIND" != xno; then
2517         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2518 fi
2519 AC_MSG_CHECKING([whether to enable Valgrind support])
2520 if test "x$VALGRIND" = xauto; then
2521         VALGRIND="$have_valgrind"
2522 fi
2523
2524 if test "x$VALGRIND" = "xyes"; then
2525         if ! test "x$have_valgrind" = xyes; then
2526                 AC_MSG_ERROR([Valgrind support required but not present])
2527         fi
2528         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2529 fi
2530
2531 AC_MSG_RESULT([$VALGRIND])
2532
2533 dnl Restore LDFLAGS and CPPFLAGS
2534 LDFLAGS="$_SAVE_LDFLAGS"
2535 CPPFLAGS="$_SAVE_CPPFLAGS"
2536
2537 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2538 if test "x$acv_mesa_CLANG" = xyes; then
2539     CFLAGS="$CFLAGS -Qunused-arguments"
2540     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2541 fi
2542
2543 dnl Add user CFLAGS and CXXFLAGS
2544 CFLAGS="$CFLAGS $USER_CFLAGS"
2545 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2546
2547 dnl Substitute the config
2548 AC_CONFIG_FILES([Makefile
2549                 src/Makefile
2550                 src/compiler/Makefile
2551                 src/egl/Makefile
2552                 src/egl/main/egl.pc
2553                 src/egl/wayland/wayland-drm/Makefile
2554                 src/egl/wayland/wayland-egl/Makefile
2555                 src/egl/wayland/wayland-egl/wayland-egl.pc
2556                 src/gallium/Makefile
2557                 src/gallium/auxiliary/Makefile
2558                 src/gallium/auxiliary/pipe-loader/Makefile
2559                 src/gallium/drivers/freedreno/Makefile
2560                 src/gallium/drivers/ddebug/Makefile
2561                 src/gallium/drivers/i915/Makefile
2562                 src/gallium/drivers/ilo/Makefile
2563                 src/gallium/drivers/llvmpipe/Makefile
2564                 src/gallium/drivers/noop/Makefile
2565                 src/gallium/drivers/nouveau/Makefile
2566                 src/gallium/drivers/r300/Makefile
2567                 src/gallium/drivers/r600/Makefile
2568                 src/gallium/drivers/radeon/Makefile
2569                 src/gallium/drivers/radeonsi/Makefile
2570                 src/gallium/drivers/rbug/Makefile
2571                 src/gallium/drivers/softpipe/Makefile
2572                 src/gallium/drivers/svga/Makefile
2573                 src/gallium/drivers/swr/Makefile
2574                 src/gallium/drivers/trace/Makefile
2575                 src/gallium/drivers/vc4/Makefile
2576                 src/gallium/drivers/virgl/Makefile
2577                 src/gallium/state_trackers/clover/Makefile
2578                 src/gallium/state_trackers/dri/Makefile
2579                 src/gallium/state_trackers/glx/xlib/Makefile
2580                 src/gallium/state_trackers/nine/Makefile
2581                 src/gallium/state_trackers/omx/Makefile
2582                 src/gallium/state_trackers/osmesa/Makefile
2583                 src/gallium/state_trackers/va/Makefile
2584                 src/gallium/state_trackers/vdpau/Makefile
2585                 src/gallium/state_trackers/xa/Makefile
2586                 src/gallium/state_trackers/xvmc/Makefile
2587                 src/gallium/targets/d3dadapter9/Makefile
2588                 src/gallium/targets/d3dadapter9/d3d.pc
2589                 src/gallium/targets/dri/Makefile
2590                 src/gallium/targets/libgl-xlib/Makefile
2591                 src/gallium/targets/omx/Makefile
2592                 src/gallium/targets/opencl/Makefile
2593                 src/gallium/targets/opencl/mesa.icd
2594                 src/gallium/targets/osmesa/Makefile
2595                 src/gallium/targets/osmesa/osmesa.pc
2596                 src/gallium/targets/pipe-loader/Makefile
2597                 src/gallium/targets/va/Makefile
2598                 src/gallium/targets/vdpau/Makefile
2599                 src/gallium/targets/xa/Makefile
2600                 src/gallium/targets/xa/xatracker.pc
2601                 src/gallium/targets/xvmc/Makefile
2602                 src/gallium/tests/trivial/Makefile
2603                 src/gallium/tests/unit/Makefile
2604                 src/gallium/winsys/freedreno/drm/Makefile
2605                 src/gallium/winsys/i915/drm/Makefile
2606                 src/gallium/winsys/intel/drm/Makefile
2607                 src/gallium/winsys/nouveau/drm/Makefile
2608                 src/gallium/winsys/radeon/drm/Makefile
2609                 src/gallium/winsys/amdgpu/drm/Makefile
2610                 src/gallium/winsys/svga/drm/Makefile
2611                 src/gallium/winsys/sw/dri/Makefile
2612                 src/gallium/winsys/sw/kms-dri/Makefile
2613                 src/gallium/winsys/sw/null/Makefile
2614                 src/gallium/winsys/sw/wrapper/Makefile
2615                 src/gallium/winsys/sw/xlib/Makefile
2616                 src/gallium/winsys/vc4/drm/Makefile
2617                 src/gallium/winsys/virgl/drm/Makefile
2618                 src/gallium/winsys/virgl/vtest/Makefile
2619                 src/gbm/Makefile
2620                 src/gbm/main/gbm.pc
2621                 src/glx/Makefile
2622                 src/glx/apple/Makefile
2623                 src/glx/tests/Makefile
2624                 src/gtest/Makefile
2625                 src/intel/Makefile
2626                 src/intel/genxml/Makefile
2627                 src/intel/isl/Makefile
2628                 src/intel/vulkan/Makefile
2629                 src/intel/vulkan/tests/Makefile
2630                 src/loader/Makefile
2631                 src/mapi/Makefile
2632                 src/mapi/es1api/glesv1_cm.pc
2633                 src/mapi/es2api/glesv2.pc
2634                 src/mapi/glapi/gen/Makefile
2635                 src/mesa/Makefile
2636                 src/mesa/gl.pc
2637                 src/mesa/drivers/dri/dri.pc
2638                 src/mesa/drivers/dri/common/Makefile
2639                 src/mesa/drivers/dri/common/xmlpool/Makefile
2640                 src/mesa/drivers/dri/i915/Makefile
2641                 src/mesa/drivers/dri/i965/Makefile
2642                 src/mesa/drivers/dri/Makefile
2643                 src/mesa/drivers/dri/nouveau/Makefile
2644                 src/mesa/drivers/dri/r200/Makefile
2645                 src/mesa/drivers/dri/radeon/Makefile
2646                 src/mesa/drivers/dri/swrast/Makefile
2647                 src/mesa/drivers/osmesa/Makefile
2648                 src/mesa/drivers/osmesa/osmesa.pc
2649                 src/mesa/drivers/x11/Makefile
2650                 src/mesa/main/tests/Makefile
2651                 src/util/Makefile
2652                 src/util/tests/hash_table/Makefile])
2653
2654 AC_OUTPUT
2655
2656 dnl
2657 dnl Output some configuration info for the user
2658 dnl
2659 echo ""
2660 echo "        prefix:          $prefix"
2661 echo "        exec_prefix:     $exec_prefix"
2662 echo "        libdir:          $libdir"
2663 echo "        includedir:      $includedir"
2664
2665 dnl API info
2666 echo ""
2667 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2668
2669 dnl Driver info
2670 echo ""
2671 case "x$enable_osmesa$enable_gallium_osmesa" in
2672 xnoyes)
2673         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2674         ;;
2675 xyesno)
2676         echo "        OSMesa:          lib$OSMESA_LIB"
2677         ;;
2678 xnono)
2679         echo "        OSMesa:          no"
2680         ;;
2681 esac
2682
2683 echo ""
2684 if test "x$enable_dri" != xno; then
2685         echo "        DRI platform:    $dri_platform"
2686         if test -z "$DRI_DIRS"; then
2687             echo "        DRI drivers:     no"
2688         else
2689             echo "        DRI drivers:     $DRI_DIRS"
2690         fi
2691         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2692 fi
2693
2694 case "x$enable_glx$enable_xlib_glx" in
2695 xyesyes)
2696     echo "        GLX:             Xlib-based"
2697     ;;
2698 xyesno)
2699     echo "        GLX:             DRI-based"
2700     ;;
2701 *)
2702     echo "        GLX:             $enable_glx"
2703     ;;
2704 esac
2705
2706 dnl EGL
2707 echo ""
2708 echo "        EGL:             $enable_egl"
2709 if test "$enable_egl" = yes; then
2710     echo "        EGL platforms:   $egl_platforms"
2711
2712     egl_drivers=""
2713     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2714         egl_drivers="$egl_drivers builtin:egl_dri2"
2715     fi
2716     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2717         egl_drivers="$egl_drivers builtin:egl_dri3"
2718     fi
2719
2720     echo "        EGL drivers:    $egl_drivers"
2721 fi
2722
2723 # Vulkan
2724 echo ""
2725 if test "x$VULKAN_DRIVERS" != x; then
2726     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2727     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2728 else
2729     echo "        Vulkan drivers:  no"
2730 fi
2731
2732 echo ""
2733 if test "x$MESA_LLVM" = x1; then
2734     echo "        llvm:            yes"
2735     echo "        llvm-config:     $LLVM_CONFIG"
2736     echo "        llvm-version:    $LLVM_VERSION"
2737 else
2738     echo "        llvm:            no"
2739 fi
2740
2741 echo ""
2742 if test -n "$with_gallium_drivers"; then
2743     echo "        Gallium drivers: $gallium_drivers"
2744     echo "        Gallium st:      $gallium_st"
2745 else
2746     echo "        Gallium:         no"
2747 fi
2748
2749 dnl Shader cache
2750 echo ""
2751 echo "        Shader cache:    $enable_shader_cache"
2752 if test "x$enable_shader_cache" = "xyes"; then
2753     echo "        With SHA1 from:  $with_sha1"
2754 fi
2755
2756 dnl Libraries
2757 echo ""
2758 echo "        Shared libs:     $enable_shared"
2759 echo "        Static libs:     $enable_static"
2760 echo "        Shared-glapi:    $enable_shared_glapi"
2761
2762 dnl Compiler options
2763 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2764 cflags=`echo $CFLAGS | \
2765     $SED 's/^ *//;s/  */ /;s/ *$//'`
2766 cxxflags=`echo $CXXFLAGS | \
2767     $SED 's/^ *//;s/  */ /;s/ *$//'`
2768 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2769 echo ""
2770 echo "        CFLAGS:          $cflags"
2771 echo "        CXXFLAGS:        $cxxflags"
2772 echo "        Macros:          $defines"
2773 echo ""
2774 if test "x$MESA_LLVM" = x1; then
2775     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2776     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2777     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2778     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2779     echo ""
2780 fi
2781 echo "        PYTHON2:         $PYTHON2"
2782
2783 echo ""
2784 echo "        Run '${MAKE-make}' to build Mesa"
2785 echo ""